configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [37])
  34 m4_define([glib_micro_version], [7])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 AC_MSG_CHECKING([for the BeOS])
 121 case $host in
 122   *-*-beos*)
 123     glib_native_beos="yes"
 124     ;;
 125   *)
 126     glib_native_beos="no"
 127     ;;
 128 esac
 129 AC_MSG_RESULT([$glib_native_beos])
 130
 131 dnl
 132
 133 AC_MSG_CHECKING([for Win32])
 134 LIB_EXE_MACHINE_FLAG=X86
 135 case "$host" in
 136   *-*-mingw*)
 137     glib_native_win32=yes
 138     glib_pid_type='void *'
 139     glib_cv_stack_grows=no
 140     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 141     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 142     # (Sorry, I don't know exactly what is the problem, but it is related to
 143     # floating point formatting and decimal point vs. comma.)
 144     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 145     # rigorous enough to notice, though.
 146     # So preset the autoconf cache variables.
 147     ac_cv_func_vsnprintf_c99=no
 148     ac_cv_func_snprintf_c99=no
 149     case "$host" in
 150     x86_64-*-*)
 151       LIB_EXE_MACHINE_FLAG=X64
 152       ;;
 153     esac
 154
 155     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 156     ;;
 157   *)
 158     glib_native_win32=no
 159     glib_pid_type=int
 160     ;;
 161 esac
 162 case $host in
 163   *-*-linux*)
 164     glib_os_linux=yes
 165     ;;
 166 esac
 167
 168 AC_MSG_RESULT([$glib_native_win32])
 169
 170 AC_MSG_CHECKING([for the Android])
 171 case $host in
 172   *android*)
 173     glib_native_android="yes"
 174     ;;
 175   *)
 176     glib_native_android="no"
 177     ;;
 178 esac
 179 AC_MSG_RESULT([$glib_native_android])
 180
 181 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 182
 183 glib_have_carbon=no
 184 AC_MSG_CHECKING([for Mac OS X Carbon support])
 185 AC_TRY_CPP([
 186 #include <Carbon/Carbon.h>
 187 #include <CoreServices/CoreServices.h>
 188 ], glib_have_carbon=yes)
 189
 190 AC_MSG_RESULT([$glib_have_carbon])
 191
 192 glib_have_cocoa=no
 193 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 194 AC_TRY_CPP([
 195 #include <Cocoa/Cocoa.h>
 196 #ifdef GNUSTEP_BASE_VERSION
 197 #error "Detected GNUstep, not Cocoa"
 198 #endif
 199 ], glib_have_cocoa=yes)
 200
 201 AC_MSG_RESULT([$glib_have_cocoa])
 202
 203 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 204 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 205 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 206 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 207 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 208 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 209
 210 AS_IF([test "$glib_native_win32" = "yes"], [
 211   AC_CHECK_TOOL(WINDRES, windres, no)
 212   if test "$WINDRES" = no; then
 213     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 214   fi
 215   AC_CHECK_TOOL(NM, nm, no)
 216   if test "$NM" = no; then
 217     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 218   fi
 219   AC_CHECK_TOOL(RANLIB, ranlib, :)
 220   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 221   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 222 ])
 223 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 224
 225 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 226   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 227   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 228 ])
 229
 230 if test "x$glib_have_cocoa" = "xyes"; then
 231   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 232   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 233 fi
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 239               enable_debug=glib_debug_default)
 240
 241 AC_ARG_ENABLE(gc_friendly,
 242               [AS_HELP_STRING([--enable-gc-friendly],
 243                               [turn on garbage collector friendliness [default=no]])],,
 244               [enable_gc_friendly=no])
 245 AC_ARG_ENABLE(mem_pools,
 246               [AS_HELP_STRING([--disable-mem-pools],
 247                               [disable all glib memory pools])],,
 248               [disable_mem_pools=no])
 249 AC_ARG_ENABLE(rebuilds,
 250               [AS_HELP_STRING([--disable-rebuilds],
 251                               [disable all source autogeneration rules])],,
 252               [enable_rebuilds=yes])
 253
 254 GLIB_TESTS
 255
 256 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 257 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 258   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 259   AC_MSG_RESULT([yes])
 260 ], [ AC_MSG_RESULT([no]) ])
 261
 262 AC_MSG_CHECKING([whether to disable memory pools])
 263 AS_IF([test "x$disable_mem_pools" = "xno"], [
 264   AC_MSG_RESULT([no])
 265 ], [
 266   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 267   AC_MSG_RESULT([yes])
 268 ])
 269
 270 dnl location to install runtime libraries, e.g. ../../lib to install
 271 dnl to /lib if libdir is /usr/lib
 272 AC_ARG_WITH(runtime-libdir,
 273            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 274                            [install runtime libraries relative to libdir])],
 275            [],
 276            [with_runtime_libdir=""])
 277 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 278 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 279 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 280 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 281 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 282
 283 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 284 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 285 AC_LANG_SAVE
 286 AC_LANG_CPLUSPLUS
 287 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 288 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 289 AC_LANG_RESTORE
 290
 291 AM_PROG_CC_C_O
 292 AC_PROG_INSTALL
 293
 294 AC_SYS_LARGEFILE
 295
 296 PKG_PROG_PKG_CONFIG(0.16)
 297
 298 if test "x$enable_debug" = "xyes"; then
 299   if test x$cflags_set != xset ; then
 300       case " $CFLAGS " in
 301       *[[\ \    ]]-g[[\ \       ]]*) ;;
 302       *) CFLAGS="$CFLAGS -g" ;;
 303       esac
 304   fi
 305   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 306 else
 307   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 308
 309   if test "x$enable_debug" = "xno"; then
 310     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 311   fi
 312 fi
 313
 314 # Ensure MSVC-compatible struct packing convention is used when
 315 # compiling for Win32 with gcc.
 316 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 317 # gcc2 uses "-fnative-struct".
 318 if test x"$glib_native_win32" = xyes; then
 319   if test x"$GCC" = xyes; then
 320     msnative_struct=''
 321     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 322     if test -z "$ac_cv_prog_CC"; then
 323       our_gcc="$CC"
 324     else
 325       our_gcc="$ac_cv_prog_CC"
 326     fi
 327     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 328       2.)
 329         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 330           msnative_struct='-fnative-struct'
 331         fi
 332         ;;
 333       *)
 334         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 335           msnative_struct='-mms-bitfields'
 336         fi
 337         ;;
 338     esac
 339     if test x"$msnative_struct" = x ; then
 340       AC_MSG_RESULT([no way])
 341       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 342     else
 343       CFLAGS="$CFLAGS $msnative_struct"
 344       AC_MSG_RESULT([${msnative_struct}])
 345     fi
 346   fi
 347 fi
 348 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 349 AC_SUBST(GLIB_EXTRA_CFLAGS)
 350
 351 AC_EXEEXT
 352
 353 # define a MAINT-like variable REBUILD which is set if Perl
 354 # and awk are found, so autogenerated sources can be rebuilt
 355 AC_PROG_AWK
 356 AC_CHECK_PROGS(PERL, [perl5 perl])
 357 # We would like indent, but don't require it.
 358 AC_CHECK_PROG(INDENT, indent, indent)
 359 REBUILD=\#
 360 if test "x$enable_rebuilds" = "xyes" && \
 361      test -n "$PERL" && \
 362      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 363      test -n "$AWK" ; then
 364   REBUILD=
 365 fi
 366 AC_SUBST(REBUILD)
 367
 368 # Need full path to Perl for glib-mkenums
 369 #
 370 if test "x$PERL" != x ; then
 371   AC_PATH_PROG(PERL_PATH, [$PERL])
 372 fi
 373 if test "x$PERL_PATH" = x ; then
 374   PERL_PATH="/usr/bin/env perl"
 375 fi
 376 AC_SUBST(PERL_PATH)
 377
 378 # option to specify python interpreter to use; this just sets $PYTHON, so that
 379 # we will fallback to reading $PYTHON if --with-python is not given, and
 380 # python.m4 will get the expected input
 381 AC_ARG_WITH(python,
 382             AS_HELP_STRING([--with-python=PATH],
 383                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 384             [PYTHON="$withval"], [])
 385 if test x"$PYTHON" = xyes; then
 386   AC_MSG_ERROR([--with-python option requires a path or program argument])
 387 fi
 388 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 389
 390
 391 dnl ***********************
 392 dnl *** Tests for iconv ***
 393 dnl ***********************
 394 dnl
 395 dnl We do this before the gettext checks, to avoid distortion
 396
 397 dnl On Windows we use a native implementation
 398
 399 AS_IF([ test x"$glib_native_win32" = xyes], [
 400   with_libiconv=native
 401 ], [
 402   AC_ARG_WITH(libiconv,
 403               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 404                               [use the libiconv library])],,
 405               [with_libiconv=maybe])
 406
 407   found_iconv=no
 408   case $with_libiconv in
 409     maybe)
 410       # Check in the C library first
 411       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 412       # Check if we have GNU libiconv
 413       if test $found_iconv = "no"; then
 414         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 415       fi
 416       # Check if we have a iconv in -liconv, possibly from vendor
 417       if test $found_iconv = "no"; then
 418         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 419       fi
 420       ;;
 421     no)
 422       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 423       ;;
 424     gnu|yes)
 425       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 426       ;;
 427     native)
 428       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 429       ;;
 430   esac
 431
 432   if test "x$found_iconv" = "xno" ; then
 433      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 434   fi
 435 ])
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 AS_IF([test "x$found_zlib" = "xno"], [
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 ])
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 AS_IF([test x"$glib_native_win32" != xyes], [
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 ])
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 AS_IF([test "$glib_native_win32" = "yes"], [
 509   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 510     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 511   fi
 512   if test x$enable_static = xyes; then
 513     glib_win32_static_compilation=yes
 514     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 515 #define GOBJECT_STATIC_COMPILATION 1"
 516     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 517   fi
 518 ])
 519 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 520
 521 dnl
 522 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 523 dnl
 524 AS_IF([test $cross_compiling != yes], [
 525     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 526     glib_save_LIBS=$LIBS
 527     LIBS="$LIBS -lm"
 528     AC_TRY_RUN([#include <math.h>
 529                  int main (void) { return (log(1) != log(1.)); }],
 530          AC_MSG_RESULT(none needed),
 531          glib_save_CFLAGS=$CFLAGS
 532          CFLAGS="$CFLAGS -std1"
 533          AC_TRY_RUN([#include <math.h>
 534                      int main (void) { return (log(1) != log(1.)); }],
 535              AC_MSG_RESULT(-std1),
 536              AC_MSG_RESULT()
 537              CFLAGS=$glib_save_CFLAGS
 538              AC_MSG_WARN(
 539                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 540          )
 541     )
 542     LIBS=$glib_save_LIBS
 543 ])
 544
 545 dnl NeXTStep cc seems to need this
 546 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 547 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 548   AC_MSG_RESULT(none needed),
 549   glib_save_CFLAGS=$CFLAGS
 550   CFLAGS="$CFLAGS -posix"
 551   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 552     AC_MSG_RESULT(-posix),
 553     AC_MSG_RESULT()
 554     CFLAGS=$glib_save_CFLAGS
 555     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 556
 557 # Checks for library functions.
 558 AC_FUNC_VPRINTF
 559 AC_FUNC_ALLOCA
 560 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 561 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 562
 563 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 564   [AC_TRY_LINK([#include <unistd.h>
 565     extern int __libc_enable_secure;],
 566     [return __libc_enable_secure;],
 567    glib_cv_have_libc_enable_secure=yes,
 568    glib_cv_have_libc_enable_secure=no)])
 569 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 570    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 571      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 572 ])
 573
 574 AC_CHECK_SIZEOF(char)
 575 AC_CHECK_SIZEOF(short)
 576 AC_CHECK_SIZEOF(long)
 577 AC_CHECK_SIZEOF(int)
 578 AC_CHECK_SIZEOF(void *)
 579 AC_CHECK_SIZEOF(long long)
 580 AC_CHECK_SIZEOF(__int64)
 581
 582 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 583   [AC_TRY_LINK([#include <signal.h>
 584      #include <sys/types.h>
 585      sig_atomic_t val = 42;],
 586     [return val == 42 ? 0 : 1],
 587    ac_cv_type_sig_atomic_t=yes,
 588    ac_cv_type_sig_atomic_t=no)])
 589 if test x$ac_cv_type_sig_atomic_t = xyes; then
 590    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 591      [Define if you have the 'sig_atomic_t' type.])
 592 fi
 593
 594 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 595   :
 596 else
 597   AC_MSG_ERROR([
 598 *** GLib requires a 64 bit type. You might want to consider
 599 *** using the GNU C compiler.
 600 ])
 601 fi
 602
 603 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 604         # long long is a 64 bit integer.
 605         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 606         AC_CACHE_VAL(glib_cv_long_long_format,[
 607                 for format in ll q I64; do
 608                   AC_TRY_RUN([#include <stdio.h>
 609                         int main()
 610                         {
 611                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 612                           char buffer[1000];
 613                           sprintf (buffer, "%${format}u", a);
 614                           sscanf (buffer, "%${format}u", &b);
 615                           exit (b!=a);
 616                         }
 617                         ],
 618                         [glib_cv_long_long_format=${format}
 619                         break],
 620                         [],[:])
 621                 done])
 622         AS_IF([ test -n "$glib_cv_long_long_format"], [
 623           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 624           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 625           if test x"$glib_cv_long_long_format" = xI64; then
 626             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 627           fi
 628         ], [AC_MSG_RESULT(none)])
 629 ],[ test x$ac_cv_sizeof___int64 = x8], [
 630         # __int64 is a 64 bit integer.
 631         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 632         # We know this is MSVCRT.DLL, and what the formats are
 633         glib_cv_long_long_format=I64
 634         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 635         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 636         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 637 ])
 638
 639 AC_C_CONST
 640
 641 dnl
 642 dnl check in which direction the stack grows
 643 dnl
 644 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 645         AC_TRY_RUN([
 646         volatile int *a = 0, *b = 0;
 647         void foo (void);
 648         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 649         void foo (void) { volatile int x = 5; b = &x; }
 650         ],
 651         glib_cv_stack_grows=no
 652         ,
 653         glib_cv_stack_grows=yes
 654         ,)
 655 ])
 656
 657 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 658 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 659 dnl actually supported.
 660 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 661         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 662         __inline int foo () { return 0; }
 663         int main () { return foo (); }
 664         ]])],
 665         glib_cv_has__inline=yes
 666         ,
 667         glib_cv_has__inline=no
 668         ,)
 669 ])
 670 case x$glib_cv_has__inline in
 671 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 672 esac
 673 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 674         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 675         __inline__ int foo () { return 0; }
 676         int main () { return foo (); }
 677         ]])],
 678         glib_cv_has__inline__=yes
 679         ,
 680         glib_cv_has__inline__=no
 681         ,)
 682 ])
 683 case x$glib_cv_has__inline__ in
 684 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 685 esac
 686 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 687         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 688         #undef inline
 689         inline int foo () { return 0; }
 690         int main () { return foo (); }
 691         ]])],
 692         glib_cv_hasinline=yes
 693         ,
 694         glib_cv_hasinline=no
 695         ,)
 696 ])
 697 case x$glib_cv_hasinline in
 698 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 699 esac
 700
 701 # if we can use inline functions in headers
 702 AC_MSG_CHECKING(if inline functions in headers work)
 703 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 704 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 705 #  undef inline
 706 #  define inline __inline__
 707 #elif !defined (G_HAVE_INLINE)
 708 #  undef inline
 709 #  if defined (G_HAVE___INLINE__)
 710 #    define inline __inline__
 711 #  elif defined (G_HAVE___INLINE)
 712 #    define inline __inline
 713 #  endif
 714 #endif
 715
 716 int glib_test_func2 (int);
 717
 718 static inline int
 719 glib_test_func1 (void) {
 720   return glib_test_func2 (1);
 721 }
 722
 723 int
 724 main (void) {
 725   int i = 1;
 726 }]])],[g_can_inline=yes],[g_can_inline=no])
 727 AC_MSG_RESULT($g_can_inline)
 728
 729 dnl *** check for working do while(0) macros ***
 730 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 731         AC_TRY_COMPILE([],[
 732         #define STMT_START do
 733         #define STMT_END while(0)
 734         #define STMT_TEST STMT_START { i = 0; } STMT_END
 735         int main(void) { int i = 1; STMT_TEST; return i; }],
 736         [g_cv_support_dowhile_macros=yes],
 737         [g_cv_support_dowhile_macros=no],
 738         [g_cv_support_dowhile_macros=yes])
 739 ])
 740 if test x$g_cv_support_dowhile_macros = xyes; then
 741   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 742 fi
 743
 744 # check for flavours of varargs macros
 745 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 746 AC_TRY_COMPILE([],[
 747 int a(int p1, int p2, int p3);
 748 #define call_a(...) a(1,__VA_ARGS__)
 749 call_a(2,3);
 750 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 751 AC_MSG_RESULT($g_have_iso_c_varargs)
 752
 753 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 754 AS_IF([test "$CXX" = ""], [
 755 dnl No C++ compiler
 756   g_have_iso_cxx_varargs=no
 757 else
 758   AC_LANG_CPLUSPLUS
 759   AC_TRY_COMPILE([],[
 760 int a(int p1, int p2, int p3);
 761 #define call_a(...) a(1,__VA_ARGS__)
 762 call_a(2,3);
 763 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 764   AC_LANG_C
 765 ])
 766 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 767
 768 AC_MSG_CHECKING(for GNUC varargs macros)
 769 AC_TRY_COMPILE([],[
 770 int a(int p1, int p2, int p3);
 771 #define call_a(params...) a(1,params)
 772 call_a(2,3);
 773 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 774 AC_MSG_RESULT($g_have_gnuc_varargs)
 775
 776 # check for GNUC visibility support
 777 AC_MSG_CHECKING(for GNUC visibility attribute)
 778 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 779 void
 780 __attribute__ ((visibility ("hidden")))
 781      f_hidden (void)
 782 {
 783 }
 784 void
 785 __attribute__ ((visibility ("internal")))
 786      f_internal (void)
 787 {
 788 }
 789 void
 790 __attribute__ ((visibility ("protected")))
 791      f_protected (void)
 792 {
 793 }
 794 void
 795 __attribute__ ((visibility ("default")))
 796      f_default (void)
 797 {
 798 }
 799 int main (void)
 800 {
 801         f_hidden();
 802         f_internal();
 803         f_protected();
 804         f_default();
 805         return 0;
 806 }
 807 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 808 AC_MSG_RESULT($g_have_gnuc_visibility)
 809 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 810
 811 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 812 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 813 #else
 814 # include "error: this is not Sun Studio."
 815 #endif
 816 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 817 AC_MSG_RESULT($g_have_sunstudio_visibility)
 818 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 819
 820 # check for bytesex stuff
 821 AC_C_BIGENDIAN
 822 if test x$ac_cv_c_bigendian = xuniversal ; then
 823 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 824 #else
 825 #error Not a big endian.
 826 #endif],
 827     ac_cv_c_bigendian=yes
 828     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 829 #else
 830 #error Not a little endian.
 831 #endif],
 832     ac_cv_c_bigendian=no
 833     ,AC_MSG_WARN([Could not determine endianness.])))
 834 fi
 835
 836
 837 # check for header files
 838 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 839 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 840 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 841 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 842 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 843 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 844 AC_CHECK_HEADERS([linux/magic.h])
 845 AC_CHECK_HEADERS([sys/prctl.h])
 846
 847 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 848 [#if HAVE_SYS_PARAM_H
 849  #include <sys/param.h>
 850  #endif
 851 ])
 852 AC_CHECK_FUNCS(sysctlbyname)
 853
 854 AC_CHECK_HEADERS([xlocale.h])
 855
 856 # check for structure fields
 857 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 858 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 859 #include <sys/stat.h>
 860 #include <unistd.h>
 861 #ifdef HAVE_SYS_STATFS_H
 862 #include <sys/statfs.h>
 863 #endif
 864 #ifdef HAVE_SYS_PARAM_H
 865 #include <sys/param.h>
 866 #endif
 867 #ifdef HAVE_SYS_MOUNT_H
 868 #include <sys/mount.h>
 869 #endif])
 870 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 871 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 872 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 873 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 874
 875 AC_STRUCT_DIRENT_D_TYPE
 876
 877 # Checks for libcharset
 878 AM_LANGINFO_CODESET
 879 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 880 AC_CHECK_FUNCS(setlocale)
 881
 882 # check additional type sizes
 883 AC_CHECK_SIZEOF(size_t)
 884
 885 dnl Try to figure out whether gsize should be long or int
 886 AC_MSG_CHECKING([for the appropriate definition for size_t])
 887
 888 case $ac_cv_sizeof_size_t in
 889   $ac_cv_sizeof_short)
 890       glib_size_type=short
 891       ;;
 892   $ac_cv_sizeof_int)
 893       glib_size_type=int
 894       ;;
 895   $ac_cv_sizeof_long)
 896       glib_size_type=long
 897       ;;
 898   $ac_cv_sizeof_long_long)
 899       glib_size_type='long long'
 900       ;;
 901   $ac_cv_sizeof__int64)
 902       glib_size_type='__int64'
 903       ;;
 904   *)  AC_MSG_ERROR([No type matching size_t in size])
 905       ;;
 906 esac
 907
 908 dnl If int/long are the same size, we see which one produces
 909 dnl warnings when used in the location as size_t. (This matters
 910 dnl on AIX with xlc)
 911 dnl
 912 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 913        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 914   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 915 #if defined(_AIX) && !defined(__GNUC__)
 916 #pragma options langlvl=stdc89
 917 #endif
 918 #include <stddef.h>
 919 int main ()
 920 {
 921   size_t s = 1;
 922   unsigned int *size_int = &s;
 923   return (int)*size_int;
 924 }
 925     ]])],glib_size_type=int,
 926       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 927 #if defined(_AIX) && !defined(__GNUC__)
 928 #pragma options langlvl=stdc89
 929 #endif
 930 #include <stddef.h>
 931 int main ()
 932 {
 933    size_t s = 1;
 934    unsigned long *size_long = &s;
 935    return (int)*size_long;
 936 }
 937         ]])],glib_size_type=long)])
 938 ])
 939
 940 AC_MSG_RESULT(unsigned $glib_size_type)
 941
 942 AC_CHECK_SIZEOF(ssize_t)
 943
 944 dnl Try to figure out whether gssize should be long or int
 945 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 946
 947 case $ac_cv_sizeof_ssize_t in
 948   $ac_cv_sizeof_short)
 949       glib_ssize_type=short
 950       ;;
 951   $ac_cv_sizeof_int)
 952       glib_ssize_type=int
 953       ;;
 954   $ac_cv_sizeof_long)
 955       glib_ssize_type=long
 956       ;;
 957   $ac_cv_sizeof_long_long)
 958       glib_ssize_type='long long'
 959       ;;
 960   $ac_cv_sizeof__int64)
 961       glib_ssize_type='__int64'
 962       ;;
 963   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 964       ;;
 965 esac
 966
 967 dnl If int/long are the same size, we see which one produces
 968 dnl warnings when used in the location as ssize_t. (This matters
 969 dnl on Android where ssize_t is long and size_t is unsigned int)
 970 dnl
 971 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 972        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 973   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 974 #if defined(_AIX) && !defined(__GNUC__)
 975 #pragma options langlvl=stdc89
 976 #endif
 977 #include <stddef.h>
 978 #ifdef HAVE_INTTYPES_H
 979 # include <inttypes.h>
 980 #endif
 981 #ifdef HAVE_STDINT_H
 982 # include <stdint.h>
 983 #endif
 984 #ifdef HAVE_UNISTD_H
 985 # include <unistd.h>
 986 #endif
 987 #ifdef HAVE_SYS_TYPES_H
 988 # include <sys/types.h>
 989 #endif
 990 int main ()
 991 {
 992   ssize_t s = 1;
 993   int *size_int = &s;
 994   return (int)*size_int;
 995 }
 996     ]])],glib_ssize_type=int,
 997       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 998 #if defined(_AIX) && !defined(__GNUC__)
 999 #pragma options langlvl=stdc89
1000 #endif
1001 #include <stddef.h>
1002 #ifdef HAVE_INTTYPES_H
1003 # include <inttypes.h>
1004 #endif
1005 #ifdef HAVE_STDINT_H
1006 # include <stdint.h>
1007 #endif
1008 #ifdef HAVE_UNISTD_H
1009 # include <unistd.h>
1010 #endif
1011 #ifdef HAVE_SYS_TYPES_H
1012 # include <sys/types.h>
1013 #endif
1014 int main ()
1015 {
1016    ssize_t s = 1;
1017    long *size_long = &s;
1018    return (int)*size_long;
1019 }
1020         ]])],glib_ssize_type=long)])
1021 ])
1022
1023 AC_MSG_RESULT($glib_ssize_type)
1024
1025 # Check for some functions
1026 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1027 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
1028 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
1029 # Check for high-resolution sleep functions
1030 AC_CHECK_FUNCS(splice)
1031 AC_CHECK_FUNCS(prlimit)
1032
1033 # To avoid finding a compatibility unusable statfs, which typically
1034 # successfully compiles, but warns to use the newer statvfs interface:
1035 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1036 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1037
1038 AC_MSG_CHECKING([whether to use statfs or statvfs])
1039 # Some systems have both statfs and statvfs, pick the most "native" for these
1040 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1041    [
1042    # on solaris and irix, statfs doesn't even have the f_bavail field
1043    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1044       [ac_cv_func_statfs=no],
1045    # else, at least on linux, statfs is the actual syscall
1046       [ac_cv_func_statvfs=no])
1047    ])
1048
1049 AS_IF([test x$ac_cv_func_statfs = xyes],
1050       [
1051          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1052          AC_MSG_RESULT([statfs])
1053       ],
1054       [test x$ac_cv_func_statvfs = xyes],
1055       [
1056          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1057          AC_MSG_RESULT([statvfs])
1058       ],
1059       [  AC_MSG_RESULT([neither])])
1060
1061 AC_CHECK_HEADERS(crt_externs.h)
1062 AC_CHECK_FUNCS(_NSGetEnviron)
1063
1064 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1065
1066 AC_FUNC_VSNPRINTF_C99
1067 AC_FUNC_PRINTF_UNIX98
1068
1069 # Internet address families
1070 if test $glib_native_win32 = yes; then
1071   glib_inet_includes=["
1072 #include <winsock2.h>
1073   "]
1074 else
1075   glib_inet_includes=["
1076 #include <sys/types.h>
1077 #include <sys/socket.h>
1078   "]
1079 fi
1080
1081 glib_failed=false
1082 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1083 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1084 # winsock defines this even though it doesn't support it
1085 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1086 if $glib_failed ; then
1087   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1088 fi
1089
1090 glib_failed=false
1091 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1092 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1093 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1094 if $glib_failed ; then
1095   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1096 fi
1097
1098 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1099
1100 AS_IF([test $glib_native_win32 = yes], [
1101   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1102   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1103   # they aren't present at run-time (on Windows 2000).
1104   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1105   AC_SUBST(WSPIAPI_INCLUDE)
1106 ], [
1107   # Android does not have C_IN in public headers, we define it wherever necessary
1108   AS_IF([test $glib_native_android != yes], [
1109     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1110     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1111                                         #include <arpa/nameser.h>],
1112                                        [int qclass = C_IN;])],
1113                       [AC_MSG_RESULT([no])],
1114                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1115                                                            #include <arpa/nameser.h>
1116                                                            #include <arpa/nameser_compat.h>],
1117                                                           [int qclass = C_IN;])],
1118                                          [AC_MSG_RESULT([yes])
1119                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1120                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1121   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1122
1123   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1124   NETWORK_LIBS=""
1125   AC_MSG_CHECKING([for res_query])
1126   AC_TRY_LINK([#include <sys/types.h>
1127                #include <netinet/in.h>
1128                #include <arpa/nameser.h>
1129                #include <resolv.h>
1130               ],[
1131                res_query("test", 0, 0, (void *)0, 0);
1132               ],[AC_MSG_RESULT([yes])],
1133               [save_libs="$LIBS"
1134                LIBS="-lresolv $LIBS"
1135                AC_TRY_LINK([#include <sys/types.h>
1136                             #include <netinet/in.h>
1137                             #include <arpa/nameser.h>
1138                             #include <resolv.h>
1139                            ],[
1140                             res_query("test", 0, 0, (void *)0, 0);
1141                            ],[AC_MSG_RESULT([in -lresolv])
1142                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1143                            [LIBS="-lbind $save_libs"
1144                             AC_TRY_LINK([#include <resolv.h>],
1145                                         [res_query("test", 0, 0, (void *)0, 0);],
1146                                         [AC_MSG_RESULT([in -lbind])
1147                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1148                                         [AC_MSG_ERROR(not found)])])
1149                LIBS="$save_libs"])
1150   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1151                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1152                                         [AC_MSG_ERROR(Could not find socket())]))
1153   save_libs="$LIBS"
1154   LIBS="$LIBS $NETWORK_LIBS"
1155   AC_MSG_CHECKING([for res_init])
1156   AC_TRY_LINK([#include <sys/types.h>
1157                #include <netinet/in.h>
1158                #include <arpa/nameser.h>
1159                #include <resolv.h>
1160               ],[
1161                res_init();
1162               ],[AC_MSG_RESULT([yes])
1163                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1164               ],[AC_MSG_RESULT([no])])
1165   LIBS="$save_libs"
1166 ])
1167 AC_SUBST(NETWORK_LIBS)
1168
1169 AC_CHECK_HEADER([linux/netlink.h],
1170                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1171                 [#include <sys/socket.h>])
1172 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1173
1174 AC_CHECK_TYPE([struct ip_mreqn], [
1175               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1176               [#include <netinet/in.h>])
1177
1178 case $host in
1179   *-*-solaris* )
1180      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1181      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1182      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1183      ;;
1184 esac
1185
1186 dnl
1187 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1188 dnl
1189 AS_IF([test "$ac_cv_func_statfs" = yes], [
1190   AC_MSG_CHECKING([number of arguments to statfs()])
1191   AC_TRY_COMPILE([#include <unistd.h>
1192   #ifdef HAVE_SYS_PARAM_H
1193   #include <sys/param.h>
1194   #endif
1195   #ifdef HAVE_SYS_VFS_H
1196   #include <sys/vfs.h>
1197   #endif
1198   #ifdef HAVE_SYS_MOUNT_H
1199   #include <sys/mount.h>
1200   #endif
1201   #ifdef HAVE_SYS_STATFS_H
1202   #include <sys/statfs.h>
1203   #endif], [struct statfs st;
1204   statfs(NULL, &st);],[
1205     AC_MSG_RESULT([2])
1206     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1207     AC_TRY_COMPILE([#include <unistd.h>
1208   #ifdef HAVE_SYS_PARAM_H
1209   #include <sys/param.h>
1210   #endif
1211   #ifdef HAVE_SYS_VFS_H
1212   #include <sys/vfs.h>
1213   #endif
1214   #ifdef HAVE_SYS_MOUNT_H
1215   #include <sys/mount.h>
1216   #endif
1217   #ifdef HAVE_SYS_STATFS_H
1218   #include <sys/statfs.h>
1219   #endif], [struct statfs st;
1220   statfs(NULL, &st, sizeof (st), 0);],[
1221       AC_MSG_RESULT([4])
1222       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1223       AC_MSG_RESULT(unknown)
1224       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1225 ])
1226
1227 #
1228 # Check whether to use an included printf
1229 #
1230
1231 AC_ARG_ENABLE(included-printf,
1232               [AS_HELP_STRING([--enable-included-printf],
1233                               [use included printf [default=auto]])],
1234               enable_included_printf="$enableval")
1235
1236 need_included_printf=no
1237 if test "x$enable_included_printf" = "xyes" ; then
1238   need_included_printf=yes
1239 fi
1240 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1241   need_included_printf=yes
1242 fi
1243 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1244   need_included_printf=yes
1245 fi
1246 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1247    test -z "$glib_cv_long_long_format" ; then
1248   need_included_printf=yes
1249 fi
1250
1251 if test "x$enable_included_printf" = "xno" &&
1252    test "x$need_included_printf" = "xyes" ; then
1253   AC_MSG_ERROR([
1254 *** Your C library's printf doesn't appear to have the features that
1255 *** GLib needs, but you specified --enable-included-printf=no.])
1256 fi
1257
1258 enable_included_printf=$need_included_printf
1259
1260 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1261 AS_IF([test "$enable_included_printf" != "yes"], [
1262   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1263 ], [
1264   if test -z "$glib_cv_long_long_format" ; then
1265     glib_cv_long_long_format="ll"
1266   fi
1267   AC_DEFINE(HAVE_VASPRINTF,1)
1268 ])
1269
1270 # Checks needed for gnulib vasnprintf
1271 bh_C_SIGNED
1272 jm_AC_TYPE_LONG_LONG
1273 gt_TYPE_LONGDOUBLE
1274 gt_TYPE_WCHAR_T
1275 gt_TYPE_WINT_T
1276 AC_TYPE_SIZE_T
1277 AC_CHECK_TYPES(ptrdiff_t)
1278 jm_AC_TYPE_INTMAX_T
1279 AC_CHECK_FUNCS([snprintf wcslen])
1280 AC_FUNC_SNPRINTF_C99
1281
1282 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1283 # The check is borrowed from the PERL Configure script.
1284 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1285   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1286     glib_cv_working_bcopy,[AC_TRY_RUN([
1287       int main() {
1288         char buf[128], abc[128], *b;
1289         int len, off, align;
1290         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1291         for (align = 7; align >= 0; align--) {
1292           for (len = 36; len; len--) {
1293             b = buf+align; bcopy(abc, b, len);
1294             for (off = 1; off <= len; off++) {
1295               bcopy(b, b+off, len); bcopy(b+off, b, len);
1296                 if (bcmp(b, abc, len)) return(1);
1297             }
1298           }
1299         }
1300         return(0);
1301       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1302
1303   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1304   if test "$glib_cv_working_bcopy" = "yes"; then
1305     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1306   fi
1307 ])
1308
1309 # Check if <sys/select.h> needs to be included for fd_set
1310 AC_MSG_CHECKING([for fd_set])
1311 AC_TRY_COMPILE([#include <sys/types.h>],
1312         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1313 AS_IF([test "$gtk_ok" = "yes"], [
1314     AC_MSG_RESULT([yes, found in sys/types.h])
1315 ], [
1316     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1317     if test "$gtk_ok" = "yes"; then
1318         # *** FIXME: give it a different name
1319         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1320         AC_MSG_RESULT([yes, found in sys/select.h])
1321     else
1322         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1323         AC_MSG_RESULT(no)
1324     fi
1325 ])
1326
1327 dnl Check for nl_langinfo and CODESET
1328 AC_LANG_SAVE
1329 AC_LANG_C
1330 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1331         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1332                        [char *codeset = nl_langinfo (CODESET);])],
1333                 [glib_cv_langinfo_codeset=yes],
1334                 [glib_cv_langinfo_codeset=no])])
1335 if test x$glib_cv_langinfo_codeset = xyes; then
1336   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1337 fi
1338
1339 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1340 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1341         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1342                  [char *str;
1343                  str = nl_langinfo (PM_STR);
1344                  str = nl_langinfo (D_T_FMT);
1345                  str = nl_langinfo (D_FMT);
1346                  str = nl_langinfo (T_FMT);
1347                  str = nl_langinfo (T_FMT_AMPM);
1348                  str = nl_langinfo (MON_1);
1349                  str = nl_langinfo (ABMON_12);
1350                  str = nl_langinfo (DAY_1);
1351                  str = nl_langinfo (ABDAY_7);])],
1352                 [glib_cv_langinfo_time=yes],
1353                 [glib_cv_langinfo_time=no])])
1354 if test x$glib_cv_langinfo_time = xyes; then
1355   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1356 fi
1357
1358 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1359 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1360         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1361                 [char *str;
1362                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1363                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1364                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1365                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1366                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1367                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1368                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1369                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1370                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1371                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1372                 [glib_cv_langinfo_outdigit=yes],
1373                 [glib_cv_langinfo_outdigit=no])])
1374 if test x$glib_cv_langinfo_outdigit = xyes; then
1375   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1376 fi
1377 AC_LANG_RESTORE
1378
1379 dnl ****************************************
1380 dnl *** posix_memalign                   ***
1381 dnl ****************************************
1382 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1383 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1384     glib_cv_compliant_posix_memalign=0
1385     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1386         AC_TRY_RUN([
1387                 #define _XOPEN_SOURCE 600
1388                 #include <stdlib.h> /* posix_memalign() should be defined here */
1389                 /* some systems break if #include <malloc.h> used */
1390                 static void test_memalign (size_t boundary, size_t size) {
1391                     void *mem = 0;
1392                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1393                         exit (1);
1394                     else
1395                       free (mem);
1396                 }
1397                 int main() {
1398                     test_memalign (  128,   128 - 2 * sizeof (void*));
1399                     test_memalign (  256,   256 - 2 * sizeof (void*));
1400                     test_memalign (  512,   512 - 2 * sizeof (void*));
1401                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1402                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1403                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1404                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1405                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1406                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1407                     exit (0); /* success */
1408                 }
1409                 ],
1410             [glib_cv_compliant_posix_memalign=1], [], [:])
1411       :
1412     fi
1413     ])
1414 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1415     AC_MSG_RESULT(yes)
1416     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1417 ], [
1418     AC_MSG_RESULT(no)
1419 ])
1420
1421
1422 dnl ****************************************
1423 dnl *** strlcpy/strlcat                  ***
1424 dnl ****************************************
1425 # Check for strlcpy
1426 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1427 AC_TRY_RUN([#include <stdlib.h>
1428 #include <string.h>
1429 int main() {
1430   char p[10];
1431   (void) strlcpy (p, "hi", 10);
1432   if (strlcat (p, "bye", 0) != 3)
1433     return 1;
1434   return 0;
1435 }], glib_cv_have_strlcpy=yes,
1436     glib_cv_have_strlcpy=no,
1437     glib_cv_have_strlcpy=no)])
1438 if test "$glib_cv_have_strlcpy" = "yes"; then
1439     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1440 fi
1441
1442
1443 dnl **********************
1444 dnl *** va_copy checks ***
1445 dnl **********************
1446 dnl we currently check for all three va_copy possibilities, so we get
1447 dnl all results in config.log for bug reports.
1448 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1449         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1450 #include <stdlib.h>
1451         void f (int i, ...) {
1452         va_list args1, args2;
1453         va_start (args1, i);
1454         va_copy (args2, args1);
1455         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1456           exit (1);
1457         va_end (args1); va_end (args2);
1458         }
1459         int main() {
1460           f (0, 42);
1461           return 0;
1462         }]])],
1463         [glib_cv_va_copy=yes],
1464         [glib_cv_va_copy=no])
1465 ])
1466 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1467         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1468 #include <stdlib.h>
1469         void f (int i, ...) {
1470         va_list args1, args2;
1471         va_start (args1, i);
1472         __va_copy (args2, args1);
1473         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1474           exit (1);
1475         va_end (args1); va_end (args2);
1476         }
1477         int main() {
1478           f (0, 42);
1479           return 0;
1480         }]])],
1481         [glib_cv___va_copy=yes],
1482         [glib_cv___va_copy=no])
1483 ])
1484
1485 if test "x$glib_cv_va_copy" = "xyes"; then
1486   g_va_copy_func=va_copy
1487 else if test "x$glib_cv___va_copy" = "xyes"; then
1488   g_va_copy_func=__va_copy
1489 fi
1490 fi
1491
1492 if test -n "$g_va_copy_func"; then
1493   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1494 fi
1495
1496 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1497         AC_TRY_RUN([#include <stdarg.h>
1498 #include <stdlib.h>
1499         void f (int i, ...) {
1500         va_list args1, args2;
1501         va_start (args1, i);
1502         args2 = args1;
1503         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1504           exit (1);
1505         va_end (args1); va_end (args2);
1506         }
1507         int main() {
1508           f (0, 42);
1509           return 0;
1510         }],
1511         [glib_cv_va_val_copy=yes],
1512         [glib_cv_va_val_copy=no],
1513         [glib_cv_va_val_copy=yes])
1514 ])
1515
1516 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1517   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1518 ])
1519
1520 dnl ***********************
1521 dnl *** g_module checks ***
1522 dnl ***********************
1523 G_MODULE_LIBS=
1524 G_MODULE_LIBS_EXTRA=
1525 G_MODULE_PLUGIN_LIBS=
1526 if test x"$glib_native_win32" = xyes; then
1527   dnl No use for this on Win32
1528   G_MODULE_LDFLAGS=
1529 else
1530   export SED
1531   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1532 fi
1533 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1534 G_MODULE_NEED_USCORE=0
1535 G_MODULE_BROKEN_RTLD_GLOBAL=0
1536 G_MODULE_HAVE_DLERROR=0
1537 dnl *** force native WIN32 shared lib loader
1538 if test -z "$G_MODULE_IMPL"; then
1539   case "$host" in
1540   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1541   esac
1542 fi
1543 dnl *** force native AIX library loader
1544 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1545 if test -z "$G_MODULE_IMPL"; then
1546   case "$host" in
1547   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1548   esac
1549 fi
1550 dnl *** dlopen() and dlsym() in system libraries
1551 AS_IF([ test -z "$G_MODULE_IMPL"], [
1552         AC_CHECK_FUNC(dlopen,
1553                       [AC_CHECK_FUNC(dlsym,
1554                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1555                       [])
1556 ])
1557 dnl *** load_image (BeOS)
1558 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1559   AC_CHECK_LIB(root, load_image,
1560       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1561       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1562       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1563       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1564       [])
1565 ])
1566 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1567 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1568         AC_CHECK_FUNC(NSLinkModule,
1569                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1570                        G_MODULE_NEED_USCORE=1],
1571                       [])
1572 ])
1573 dnl *** dlopen() and dlsym() in libdl
1574 AS_IF([ test -z "$G_MODULE_IMPL"], [
1575         AC_CHECK_LIB(dl, dlopen,
1576                      [AC_CHECK_LIB(dl, dlsym,
1577                                    [G_MODULE_LIBS=-ldl
1578                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1579                      [])
1580 ])
1581 dnl *** shl_load() in libdld (HP-UX)
1582 AS_IF([ test -z "$G_MODULE_IMPL"], [
1583         AC_CHECK_LIB(dld, shl_load,
1584                 [G_MODULE_LIBS=-ldld
1585                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1586                 [])
1587 ])
1588 dnl *** additional checks for G_MODULE_IMPL_DL
1589 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1590         LIBS_orig="$LIBS"
1591         LDFLAGS_orig="$LDFLAGS"
1592         LIBS="$G_MODULE_LIBS $LIBS"
1593         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1594 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1595         echo "void glib_plugin_test(void) { }" > plugin.c
1596         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1597                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1598         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1599                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1600                 -shrext ".o" -avoid-version plugin.lo \
1601                 -rpath /dont/care >/dev/null 2>&1
1602         eval `./libtool --config | grep ^objdir`
1603         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1604                 glib_cv_rtldglobal_broken,[
1605                 AC_TRY_RUN([
1606 #include <dlfcn.h>
1607 #ifndef RTLD_GLOBAL
1608 #  define RTLD_GLOBAL 0
1609 #endif
1610 #ifndef RTLD_LAZY
1611 #  define RTLD_LAZY 0
1612 #endif
1613 int glib_plugin_test;
1614 int main () {
1615     void *handle, *global, *local;
1616     global = &glib_plugin_test;
1617     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1618     if (!handle) return 0;
1619     local = dlsym (handle, "glib_plugin_test");
1620     return global == local;
1621 }                       ],
1622                         [glib_cv_rtldglobal_broken=no],
1623                         [glib_cv_rtldglobal_broken=yes],
1624                         [glib_cv_rtldglobal_broken=no])
1625                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1626                 rmdir ${objdir} 2>/dev/null
1627         ])
1628         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1629                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1630         else
1631                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1632         fi
1633 dnl *** check whether we need preceeding underscores
1634         AC_CACHE_CHECK([for preceeding underscore in symbols],
1635                 glib_cv_uscore,[
1636                 AC_TRY_RUN([#include <dlfcn.h>
1637                 int glib_underscore_test (void) { return 42; }
1638                 int main() {
1639                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1640                   handle = dlopen ((void*)0, 0);
1641                   if (handle) {
1642                     f1 = dlsym (handle, "glib_underscore_test");
1643                     f2 = dlsym (handle, "_glib_underscore_test");
1644                   } return (!f2 || f1);
1645                 }],
1646                         [glib_cv_uscore=yes],
1647                         [glib_cv_uscore=no],
1648                         [])
1649                 rm -f plugin.c plugin.$ac_objext plugin.lo
1650         ])
1651         GLIB_ASSERT_SET(glib_cv_uscore)
1652         if test "x$glib_cv_uscore" = "xyes"; then
1653                 G_MODULE_NEED_USCORE=1
1654         else
1655                 G_MODULE_NEED_USCORE=0
1656         fi
1657
1658         LDFLAGS="$LDFLAGS_orig"
1659 dnl *** check for having dlerror()
1660         AC_CHECK_FUNC(dlerror,
1661                 [G_MODULE_HAVE_DLERROR=1],
1662                 [G_MODULE_HAVE_DLERROR=0])
1663         LIBS="$LIBS_orig"
1664 ])
1665 dnl *** done, have we got an implementation?
1666 if test -z "$G_MODULE_IMPL"; then
1667         G_MODULE_IMPL=0
1668         G_MODULE_SUPPORTED=false
1669 else
1670         G_MODULE_SUPPORTED=true
1671 fi
1672
1673 AC_MSG_CHECKING(for the suffix of module shared libraries)
1674 export SED
1675 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1676 eval $shrext_cmds
1677 module=yes eval std_shrext=$shrext_cmds
1678 # chop the initial dot
1679 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1680 AC_MSG_RESULT(.$glib_gmodule_suffix)
1681 # any reason it may fail?
1682 if test "x$glib_gmodule_suffix" = x; then
1683         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1684 fi
1685
1686 AC_SUBST(G_MODULE_SUPPORTED)
1687 AC_SUBST(G_MODULE_IMPL)
1688 AC_SUBST(G_MODULE_LIBS)
1689 AC_SUBST(G_MODULE_LIBS_EXTRA)
1690 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1691 AC_SUBST(G_MODULE_LDFLAGS)
1692 AC_SUBST(G_MODULE_HAVE_DLERROR)
1693 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1694 AC_SUBST(G_MODULE_NEED_USCORE)
1695 AC_SUBST(GLIB_DEBUG_FLAGS)
1696
1697 dnl **********************
1698 dnl *** g_spawn checks ***
1699 dnl **********************
1700
1701 AC_MSG_CHECKING(for gspawn implementation)
1702 case "$host" in
1703   *-*-mingw*)
1704     GSPAWN=gspawn-win32.lo
1705     ;;
1706   *)
1707     GSPAWN=gspawn.lo
1708     ;;
1709 esac
1710 AC_MSG_RESULT($GSPAWN)
1711 AC_SUBST(GSPAWN)
1712
1713 dnl *************************
1714 dnl *** GIOChannel checks ***
1715 dnl *************************
1716
1717 AC_MSG_CHECKING(for GIOChannel implementation)
1718 case "$host" in
1719   *-*-mingw*)
1720     GIO=giowin32.lo
1721     ;;
1722   *)
1723     GIO=giounix.lo
1724     ;;
1725 esac
1726 AC_MSG_RESULT($GIO)
1727 AC_SUBST(GIO)
1728
1729 dnl *********************************
1730 dnl *** Directory for GIO modules ***
1731 dnl *********************************
1732
1733 AC_ARG_WITH(gio-module-dir,
1734            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1735                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1736            [],
1737            [with_gio_module_dir='${libdir}/gio/modules'])
1738 GIO_MODULE_DIR=$with_gio_module_dir
1739 AC_SUBST(GIO_MODULE_DIR)
1740
1741 dnl **********************************
1742 dnl *** Check for libselinux (GIO) ***
1743 dnl **********************************
1744 AC_ARG_ENABLE(selinux,
1745               AS_HELP_STRING([--disable-selinux],
1746                              [build without selinux support]))
1747 msg_selinux=no
1748 SELINUX_LIBS=
1749 AS_IF([ test "x$enable_selinux" != "xno"], [
1750
1751  AC_CHECK_LIB(selinux, is_selinux_enabled,
1752    [AC_CHECK_HEADERS(selinux/selinux.h,
1753      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1754        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1755         SELINUX_LIBS="-lselinux"
1756         msg_selinux=yes])
1757      ])
1758    ])
1759 ])
1760 AC_SUBST(SELINUX_LIBS)
1761
1762 dnl *****************************
1763 dnl ** Check for inotify (GIO) **
1764 dnl *****************************
1765 inotify_support=no
1766 AC_CHECK_HEADERS([sys/inotify.h],
1767 [
1768         inotify_support=yes
1769         AC_CHECK_FUNCS(inotify_init1)
1770 ])
1771
1772 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1773
1774 dnl ****************************
1775 dnl ** Check for kqueue (GIO) **
1776 dnl ****************************
1777 kqueue_support=no
1778 AC_CHECK_HEADERS([sys/event.h],
1779 [
1780         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1781 ])
1782
1783 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1784
1785 dnl *********************************
1786 dnl ** Check for Solaris FEN (GIO) **
1787 dnl *********************************
1788 fen_support=no
1789 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1790 #include <port.h>
1791 #ifndef PORT_SOURCE_FILE
1792 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1793 #endif
1794 int main() { return 0; } ]])],
1795 [
1796         fen_support=yes
1797 ],)
1798
1799 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1800
1801 dnl ****************************
1802 dnl *** Checks for FAM (GIO) ***
1803 dnl ****************************
1804
1805 should_disable_fam=no
1806
1807 AC_ARG_ENABLE(fam,
1808               AS_HELP_STRING([--disable-fam],
1809                              [don't use fam for file system monitoring]),
1810                          [
1811                                 if test "x$enable_fam" = "xno"; then
1812                                         should_disable_fam=yes
1813                                 fi
1814                          ]
1815                          )
1816 fam_support=no
1817 FAM_LIBS=
1818 if test "x$should_disable_fam" = "xno"; then
1819 AC_CHECK_LIB(fam, FAMOpen,
1820   [AC_CHECK_HEADERS(fam.h,
1821     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1822      AC_CHECK_LIB(fam, FAMNoExists,
1823                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1824      FAM_LIBS="-lfam"]
1825      fam_support=yes,
1826     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1827   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1828 AC_SUBST(FAM_LIBS)
1829 fi
1830 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1831
1832
1833 dnl *****************************
1834 dnl *** Check for xattr (GIO) ***
1835 dnl *****************************
1836 AC_ARG_ENABLE(xattr,
1837               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1838 msg_xattr=no
1839 XATTR_LIBS=
1840 AS_IF([ test "x$enable_xattr" != "xno"], [
1841
1842 dnl either glibc or libattr can provide xattr support
1843
1844 dnl for both of them, we check for getxattr being in
1845 dnl the library and a valid xattr header.
1846
1847 dnl try glibc
1848  AC_CHECK_LIB(c, getxattr,
1849    [AC_CHECK_HEADERS(sys/xattr.h,
1850      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1851       msg_xattr=yes])
1852    ])
1853
1854   AS_IF([ test "x$msg_xattr" != "xyes"], [
1855 dnl   failure. try libattr
1856    AC_CHECK_LIB(attr, getxattr,
1857       [AC_CHECK_HEADERS(attr/xattr.h,
1858        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1859         XATTR_LIBS="-lattr"
1860         msg_xattr=yes])
1861       ])
1862   ])
1863
1864   AS_IF([ test "x$msg_xattr" = "xyes"], [
1865     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1866     AC_TRY_COMPILE([
1867       #include <stdio.h>
1868       #ifdef HAVE_SYS_TYPES_H
1869       #include <sys/types.h>
1870       #endif
1871       #ifdef HAVE_SYS_XATTR_H
1872       #include <sys/xattr.h>
1873       #elif HAVE_ATTR_XATTR_H
1874       #include <attr/xattr.h>
1875       #endif
1876     ],
1877     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1878     [
1879       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1880       AC_MSG_RESULT([yes])
1881     ],
1882     [AC_MSG_RESULT([no])]
1883     )
1884   ])
1885 ])
1886 AC_SUBST(XATTR_LIBS)
1887
1888 dnl ************************
1889 dnl *** check for libelf ***
1890 dnl ************************
1891 AC_ARG_ENABLE(libelf,
1892               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1893 AS_IF([ test "x$enable_libelf" != "xno"],[
1894 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1895 AS_IF([ test $have_libelf = maybe ], [
1896   glib_save_LIBS=$LIBS
1897   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1898   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1899   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1900   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1901   LIBS=$glib_save_LIBS
1902
1903   if test $have_libelf != no; then
1904     LIBELF_LIBS=-lelf
1905     have_libelf=yes
1906   fi
1907 ])
1908 ])
1909
1910 if test x$have_libelf = xyes; then
1911   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1912 fi
1913
1914 dnl ****************************************
1915 dnl *** platform dependent source checks ***
1916 dnl ****************************************
1917
1918 AC_MSG_CHECKING(for platform-dependent source)
1919 case "$host" in
1920   *-*-cygwin*|*-*-mingw*)
1921     PLATFORMDEP=gwin32.lo
1922     ;;
1923   *)
1924     PLATFORMDEP=
1925     ;;
1926 esac
1927 AC_MSG_RESULT($PLATFORMDEP)
1928 AC_SUBST(PLATFORMDEP)
1929
1930 AC_MSG_CHECKING([whether to compile timeloop])
1931 case "$host" in
1932   *-*-cygwin*|*-*-mingw*|*-*-minix)
1933     enable_timeloop=no
1934     ;;
1935   *)
1936     enable_timeloop=yes
1937     ;;
1938 esac
1939 AC_MSG_RESULT($enable_timeloop)
1940 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1941
1942 AC_MSG_CHECKING([if building for some Win32 platform])
1943 case "$host" in
1944   *-*-mingw*|*-*-cygwin*)
1945     platform_win32=yes
1946     ;;
1947   *)
1948     platform_win32=no
1949     ;;
1950 esac
1951 AC_MSG_RESULT($platform_win32)
1952 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1953
1954 dnl ***********************
1955 dnl *** g_thread checks ***
1956 dnl ***********************
1957
1958 AC_ARG_WITH(threads,
1959            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1960                            [specify a thread implementation to use])],
1961            [],
1962            [with_threads=yes])
1963
1964 dnl error and warning message
1965 dnl *************************
1966
1967 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1968
1969 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1970                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1971                 compilation now, but then your programs might not work.
1972                 Please provide information on how it is done on your system."
1973
1974 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1975                  "
1976
1977 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1978                   provide information on your thread implementation."
1979
1980 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1981                 functions will not be MT-safe during their first call because
1982                 there is no working 'getpwuid_r' on your system."
1983
1984 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1985                 because there is no 'localtime_r' on your system."
1986
1987 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1988                 linking threaded applications. As GLib cannot do that
1989                 automatically, you will get an linkg error everytime you are
1990                 not using the right compiler. In that case you have to relink
1991                 with the right compiler. Ususally just '_r' is appended
1992                 to the compiler name."
1993
1994 dnl determination of thread implementation
1995 dnl ***************************************
1996
1997 AC_MSG_CHECKING(for thread implementation)
1998
1999 have_threads=no
2000 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
2001         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
2002         # -U_OSF_SOURCE is for Digital UNIX 4.0d
2003         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
2004         glib_save_CPPFLAGS="$CPPFLAGS"
2005         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2006         AS_IF([ test "x$have_threads" = xno], [
2007                 AC_TRY_COMPILE([#include <pthread.h>],
2008                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2009                         have_threads=posix)
2010         ])
2011         # Tru64Unix requires -pthread to find pthread.h. See #103020
2012         CPPFLAGS="$CPPFLAGS -pthread"
2013         if test "x$have_threads" = xno; then
2014         AC_TRY_COMPILE([#include <pthread.h>],
2015                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2016                        have_threads=posix)
2017         fi
2018         CPPFLAGS="$glib_save_CPPFLAGS"
2019 ])
2020 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
2021         case $host in
2022                 *-*-mingw*)
2023                 have_threads=win32
2024                 ;;
2025         esac
2026 fi
2027
2028 if test "x$have_threads" = xno; then
2029         AC_MSG_RESULT(none available)
2030         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
2031 else
2032         AC_MSG_RESULT($have_threads)
2033 fi
2034
2035
2036 dnl determination of G_THREAD_CFLAGS
2037 dnl ********************************
2038
2039 G_THREAD_LIBS=
2040 G_THREAD_LIBS_EXTRA=
2041 G_THREAD_CFLAGS=
2042
2043 dnl
2044 dnl Test program for basic POSIX threads functionality
2045 dnl
2046 m4_define([glib_thread_test],[
2047 #include <pthread.h>
2048 int check_me = 0;
2049 void* func(void* data) {check_me = 42; return &check_me;}
2050 int main()
2051  { pthread_t t;
2052    void *ret;
2053    pthread_create (&t, $1, func, 0);
2054    pthread_join (t, &ret);
2055    return (check_me != 42 || ret != &check_me);
2056 }])
2057
2058 AS_IF([ test x"$have_threads" = xposix], [
2059   # First we test for posix, whether -pthread or -pthreads do the trick as
2060   # both CPPFLAG and LIBS.
2061   # One of them does for most gcc versions and some other platforms/compilers
2062   # too and could be considered as the canonical way to go.
2063   case $host in
2064     *-*-cygwin*|*-*-darwin*)
2065        # skip cygwin and darwin -pthread or -pthreads test
2066        ;;
2067     *-solaris*)
2068       # These compiler/linker flags work with both Sun Studio and gcc
2069       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2070       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2071       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2072       G_THREAD_LIBS="-lpthread -lthread"
2073       ;;
2074     *)
2075       for flag in pthread pthreads mt; do
2076         glib_save_CFLAGS="$CFLAGS"
2077         CFLAGS="$CFLAGS -$flag"
2078         AC_TRY_RUN(glib_thread_test(0),
2079                    glib_flag_works=yes,
2080                    glib_flag_works=no,
2081                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2082                                    glib_flag_works=yes,
2083                                    glib_flag_works=no)])
2084         CFLAGS="$glib_save_CFLAGS"
2085         if test $glib_flag_works = yes ; then
2086            G_THREAD_CFLAGS=-$flag
2087         G_THREAD_LIBS=-$flag
2088         break;
2089         fi
2090       done
2091        ;;
2092   esac
2093 ])
2094
2095 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2096
2097   # The canonical -pthread[s] does not work. Try something different.
2098
2099   case $host in
2100         *-aix*)
2101                 if test x"$GCC" = xyes; then
2102                         # GCC 3.0 and above needs -pthread.
2103                         # Should be coverd by the case above.
2104                         # GCC 2.x and below needs -mthreads
2105                         G_THREAD_CFLAGS="-mthreads"
2106                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2107                 else
2108                         # We are probably using the aix compiler. Normaly a
2109                         # program would have to be compiled with the _r variant
2110                         # of the corresponding compiler, but we as GLib cannot
2111                         # do that: but the good news is that for compiling the
2112                         # only difference is the added -D_THREAD_SAFE compile
2113                         # option. This is according to the "C for AIX User's
2114                         # Guide".
2115                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2116                 fi
2117                 ;;
2118         *-dg-dgux*)  # DG/UX
2119                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2120                 ;;
2121         *-sysv5uw7*) # UnixWare 7
2122                 # We are not using gcc with -pthread. Catched above.
2123                 G_THREAD_CFLAGS="-Kthread"
2124                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2125                 ;;
2126         *-mingw*)
2127                 # No flag needed when using MSVCRT.DLL
2128                 G_THREAD_CFLAGS=""
2129                 ;;
2130         *)
2131                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2132                 ;;
2133   esac
2134 ])
2135
2136 # if we are not finding the localtime_r function, then we probably are
2137 # not using the proper multithread flag
2138
2139 glib_save_CPPFLAGS="$CPPFLAGS"
2140 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2141
2142 # First we test, whether localtime_r is declared in time.h
2143 # directly. Then we test whether a macro localtime_r exists, in
2144 # which case localtime_r in the test program is replaced and thus
2145 # if we still find localtime_r in the output, it is not defined as
2146 # a macro.
2147
2148 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2149   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2150                                                            localtime_r(a,b)],
2151                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2152
2153 CPPFLAGS="$glib_save_CPPFLAGS"
2154
2155 AC_MSG_CHECKING(thread related cflags)
2156 AC_MSG_RESULT($G_THREAD_CFLAGS)
2157 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2158
2159 dnl determination of G_THREAD_LIBS
2160 dnl ******************************
2161
2162 AS_IF([test x$have_threads = xposix], [
2163           glib_save_CPPFLAGS="$CPPFLAGS"
2164           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2165           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2166             case $host in
2167               *-aix*)
2168                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2169                 # probably using the aix compiler.
2170                 AC_MSG_WARN($AIX_COMPILE_INFO)
2171                 ;;
2172               *)
2173                 G_THREAD_LIBS=error
2174                 glib_save_LIBS="$LIBS"
2175                 for thread_lib in "" pthread pthread32 pthreads thread; do
2176                         if test x"$thread_lib" = x; then
2177                                 add_thread_lib=""
2178                                 IN=""
2179                         else
2180                                 add_thread_lib="-l$thread_lib"
2181                                 IN=" in -l$thread_lib"
2182                         fi
2183                         if test x"$have_threads" = xposix; then
2184                                 defattr=0
2185                         else
2186                                 defattr=pthread_attr_default
2187                         fi
2188
2189                         LIBS="$add_thread_lib $glib_save_LIBS"
2190
2191                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2192                         AC_TRY_RUN(glib_thread_test($defattr),
2193                                    glib_result=yes,
2194                                    glib_result=no,
2195                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2196                                                    glib_result=yes,
2197                                                    glib_result=no)])
2198                         AC_MSG_RESULT($glib_result)
2199
2200                         if test "$glib_result" = "yes" ; then
2201                           G_THREAD_LIBS="$add_thread_lib"
2202                           break
2203                         fi
2204                 done
2205                 if test "x$G_THREAD_LIBS" = xerror; then
2206                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2207                 fi
2208                 LIBS="$glib_save_LIBS"
2209                 ;;
2210             esac
2211           ])
2212
2213           g_threads_impl="POSIX"
2214           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2215           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2216           CPPFLAGS="$glib_save_CPPFLAGS"
2217 ], [test x$have_threads = xwin32], [
2218            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2219            g_threads_impl="WIN32"
2220 ], [
2221            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2222            g_threads_impl="NONE"
2223            G_THREAD_LIBS=error
2224 ])
2225 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2226 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2227 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2228
2229 if test "x$G_THREAD_LIBS" = xerror; then
2230         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2231 fi
2232
2233 case $host in
2234   *-*-beos*)
2235     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2236     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2237     ;;
2238   *)
2239     ;;
2240 esac
2241
2242 AC_MSG_CHECKING(thread related libraries)
2243 AC_MSG_RESULT($G_THREAD_LIBS)
2244
2245 dnl check for mt safe function variants and some posix functions
2246 dnl ************************************************************
2247
2248 glib_save_LIBS="$LIBS"
2249 # we are not doing the following for now, as this might require glib
2250 # to always be linked with the thread libs on some platforms.
2251 # LIBS="$LIBS $G_THREAD_LIBS"
2252 AC_CHECK_FUNCS(localtime_r gmtime_r)
2253 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2254         AC_CACHE_CHECK([for posix getpwuid_r],
2255                 ac_cv_func_posix_getpwuid_r,
2256                 [AC_TRY_RUN([
2257 #include <errno.h>
2258 #include <pwd.h>
2259 int main () {
2260     char buffer[10000];
2261     struct passwd pwd, *pwptr = &pwd;
2262     int error;
2263     errno = 0;
2264     error = getpwuid_r (0, &pwd, buffer,
2265                         sizeof (buffer), &pwptr);
2266    return (error < 0 && errno == ENOSYS)
2267            || error == ENOSYS;
2268 }                               ],
2269                         [ac_cv_func_posix_getpwuid_r=yes],
2270                         [ac_cv_func_posix_getpwuid_r=no])])
2271         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2272         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2273                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2274                         [Have POSIX function getpwuid_r])
2275         else
2276                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2277                         ac_cv_func_nonposix_getpwuid_r,
2278                         [AC_TRY_LINK([#include <pwd.h>],
2279                                 [char buffer[10000];
2280                                 struct passwd pwd;
2281                                 getpwuid_r (0, &pwd, buffer,
2282                                                 sizeof (buffer));],
2283                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2284                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2285                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2286                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2287                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2288                                 [Have non-POSIX function getpwuid_r])
2289                 fi
2290         fi
2291 ])
2292 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2293         AC_CACHE_CHECK([for posix getgrgid_r],
2294                 ac_cv_func_posix_getgrgid_r,
2295                 [AC_TRY_RUN([
2296 #include <errno.h>
2297 #include <grp.h>
2298 int main () {
2299     char buffer[10000];
2300     struct group grp, *grpptr = &grp;
2301     int error;
2302     errno = 0;
2303     error = getgrgid_r (0, &grp, buffer,
2304                         sizeof (buffer), &grpptr);
2305    return (error < 0 && errno == ENOSYS)
2306            || error == ENOSYS;
2307 }                              ],
2308                        [ac_cv_func_posix_getgrgid_r=yes],
2309                        [ac_cv_func_posix_getgrgid_r=no])])
2310         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2311         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2312                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2313                         [Have POSIX function getgrgid_r])
2314         ], [
2315                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2316                         ac_cv_func_nonposix_getgrgid_r,
2317                         [AC_TRY_LINK([#include <grp.h>],
2318                                 [char buffer[10000];
2319                                 struct group grp;
2320                                 getgrgid_r (0, &grp, buffer,
2321                                 sizeof (buffer));],
2322                         [ac_cv_func_nonposix_getgrgid_r=yes],
2323                         [ac_cv_func_nonposix_getgrgid_r=no])])
2324                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2325                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2326                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2327                                 [Have non-POSIX function getgrgid_r])
2328                 fi
2329         ])
2330 ])
2331 LIBS="$G_THREAD_LIBS $LIBS"
2332 AS_IF([ test x"$have_threads" = xposix], [
2333         glib_save_CPPFLAGS="$CPPFLAGS"
2334         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2335         # This is not AC_CHECK_FUNC to also work with function
2336         # name mangling in header files.
2337         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2338         AC_LINK_IFELSE(
2339             [AC_LANG_PROGRAM(
2340                 [#include <pthread.h>],
2341                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2342             [AC_MSG_RESULT(yes)
2343              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2344                 [Have function pthread_attr_setstacksize])],
2345             [AC_MSG_RESULT(no)])
2346         AC_MSG_CHECKING(for pthread_condattr_setclock)
2347         AC_LINK_IFELSE(
2348             [AC_LANG_PROGRAM(
2349                 [#include <pthread.h>],
2350                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2351             [AC_MSG_RESULT(yes)
2352              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2353                 [Have function pthread_condattr_setclock])],
2354             [AC_MSG_RESULT(no)])
2355         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic)
2356         AC_LINK_IFELSE(
2357             [AC_LANG_PROGRAM(
2358                 [#include <pthread.h>],
2359                 [pthread_cond_timedwait_monotonic(NULL, NULL, NULL)])],
2360             [AC_MSG_RESULT(yes)
2361              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC,1,
2362                 [Have function pthread_cond_timedwait_monotonic])],
2363             [AC_MSG_RESULT(no)])
2364         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic_np)
2365         AC_LINK_IFELSE(
2366             [AC_LANG_PROGRAM(
2367                 [#include <pthread.h>],
2368                 [pthread_cond_timedwait_monotonic_np(NULL, NULL, NULL)])],
2369             [AC_MSG_RESULT(yes)
2370              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC_NP,1,
2371                 [Have function pthread_cond_timedwait_monotonic_np])],
2372             [AC_MSG_RESULT(no)])
2373         CPPFLAGS="$glib_save_CPPFLAGS"
2374 ])
2375
2376 LIBS="$glib_save_LIBS"
2377
2378 # now spit out all the warnings.
2379 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2380    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2381         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2382 fi
2383 if test "$ac_cv_func_localtime_r" != "yes"; then
2384         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2385 fi
2386
2387 #
2388 # Hack to deal with:
2389 #
2390 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2391 #     building shared libraries with linux.
2392 #  b) FreeBSD doesn't do this either.
2393 #
2394 case $host in
2395   *android*)
2396     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2397     ;;
2398   *-*-freebsd*|*-*-linux*)
2399     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2400     ;;
2401   *-*-openbsd*)
2402     LDFLAGS="$LDFLAGS -pthread"
2403     ;;
2404   *)
2405     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2406     ;;
2407 esac
2408
2409 AC_SUBST(G_THREAD_CFLAGS)
2410 AC_SUBST(G_THREAD_LIBS)
2411 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2412 AC_SUBST(G_THREAD_LIBS_EXTRA)
2413
2414 AC_CHECK_FUNCS(clock_gettime, [], [
2415   AC_CHECK_LIB(rt, clock_gettime, [
2416     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2417     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2418     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2419   ])
2420 ])
2421
2422
2423 dnl ************************
2424 dnl *** g_atomic_* tests ***
2425 dnl ************************
2426
2427 dnl We need to decide at configure time if GLib will use real atomic
2428 dnl operations ("lock free") or emulated ones with a mutex.  This is
2429 dnl because we must put this information in glibconfig.h so we know if
2430 dnl it is safe or not to inline using compiler intrinsics directly from
2431 dnl the header.
2432 dnl
2433 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2434 dnl user is interested in knowing if they can use the atomic ops across
2435 dnl processes.
2436 dnl
2437 dnl We can currently support the atomic ops natively when building GLib
2438 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2439 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2440 dnl we are using GCC (and not mingw*).
2441 dnl
2442 dnl Note that the atomic ops are only available with GCC on x86 when
2443 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2444 dnl not available but would be available given the right flags, we want
2445 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2446 dnl that then to silently fall back on emulated atomic ops just because
2447 dnl the user had the wrong build environment.
2448
2449 dnl We may add other compilers here in the future...
2450
2451 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2452   case $host in
2453     *-*-mingw*)
2454       glib_cv_g_atomic_lock_free=yes
2455       ;;
2456     *)
2457       AC_TRY_COMPILE([],
2458                      [volatile int atomic = 2;\
2459                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2460                      [glib_cv_g_atomic_lock_free=yes],
2461                      [glib_cv_g_atomic_lock_free=no])
2462       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2463         SAVE_CFLAGS="${CFLAGS}"
2464         CFLAGS="-march=i486"
2465         AC_TRY_COMPILE([],
2466                        [volatile int atomic = 2;\
2467                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2468                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2469                        [])
2470         CFLAGS="${SAVE_CFLAGS}"
2471       fi
2472       ;;
2473   esac])
2474
2475
2476 case $host in
2477   *-*-mingw*)
2478     ;;
2479   *)
2480     # Some compilers support atomic operations but do not define
2481     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2482     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2483       AC_TRY_COMPILE([],
2484                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2485                      [],
2486                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2487     fi
2488     ;;
2489  esac
2490
2491 dnl We need a more robust approach here...
2492 case $host_cpu in
2493   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2494     glib_memory_barrier_needed=no
2495     ;;
2496   sparc*|alpha*|powerpc*|ia64)
2497     glib_memory_barrier_needed=yes
2498     ;;
2499   *)
2500     glib_memory_barrier_needed=yes
2501     ;;
2502 esac
2503
2504 dnl ************************
2505 dnl ** Check for futex(2) **
2506 dnl ************************
2507 AC_CACHE_CHECK(for futex(2) system call,
2508     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2509 #include <linux/futex.h>
2510 #include <sys/syscall.h>
2511 #include <unistd.h>
2512 ],[
2513 int
2514 main (void)
2515 {
2516   /* it is not like this actually runs or anything... */
2517   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2518   return 0;
2519 }
2520 ])],glib_cv_futex=yes,glib_cv_futex=no))
2521 if test x"$glib_cv_futex" = xyes; then
2522   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2523 fi
2524
2525 AC_CACHE_CHECK(for eventfd(2) system call,
2526     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2527 #include <sys/eventfd.h>
2528 #include <unistd.h>
2529 ],[
2530 int
2531 main (void)
2532 {
2533   eventfd (0, EFD_CLOEXEC);
2534   return 0;
2535 }
2536 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2537 if test x"$glib_cv_eventfd" = x"yes"; then
2538   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2539 fi
2540 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2541
2542 dnl ****************************************
2543 dnl *** GLib POLL* compatibility defines ***
2544 dnl ****************************************
2545
2546 glib_poll_includes=["
2547 #include <sys/types.h>
2548 #include <sys/poll.h>
2549 "]
2550
2551 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2552    test $ac_cv_header_sys_poll_h = yes ], [
2553   glib_failed=false
2554   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2555   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2556   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2557   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2558   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2559   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2560   if $glib_failed ; then
2561     AC_MSG_ERROR([Could not determine values for POLL* constants])
2562   fi
2563 ], [
2564   glib_cv_value_POLLIN=1
2565   glib_cv_value_POLLOUT=4
2566   glib_cv_value_POLLPRI=2
2567   glib_cv_value_POLLERR=8
2568   glib_cv_value_POLLHUP=16
2569   glib_cv_value_POLLNVAL=32
2570 ])
2571
2572 AC_MSG_CHECKING([for broken poll])
2573 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2574         #include <stdlib.h>
2575         #include <fcntl.h>
2576         #include <poll.h>
2577         #ifdef HAVE_SYS_POLL_H
2578         #include <sys/poll.h>
2579         #endif
2580         int main(void) {
2581           struct pollfd fds[1];
2582           int fd;
2583           fd = open("/dev/null", 1);
2584           fds[0].fd = fd;
2585           fds[0].events = POLLIN;
2586           fds[0].revents = 0;
2587           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2588                 exit(1);  /* Does not work for devices -- fail */
2589           }
2590           exit(0);
2591         }]])],
2592   [broken_poll=no],
2593   [broken_poll=yes
2594    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2595   [broken_poll="no (cross compiling)"])
2596 AC_MSG_RESULT($broken_poll)
2597
2598 dnl *********************
2599 dnl *** GRegex checks ***
2600 dnl *********************
2601
2602 PCRE_REQUIRED_VERSION=8.13
2603
2604 # Check if we should use the internal or the system-supplied pcre
2605 AC_ARG_WITH(pcre,
2606             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2607                             [whether to use system PCRE [default=internal]])])
2608
2609 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2610
2611 AS_IF([ test "x$with_pcre" = xsystem], [
2612   PKG_CHECK_MODULES(PCRE,
2613                     libpcre >= $PCRE_REQUIRED_VERSION)
2614   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2615                   glib_save_CFLAGS="$CFLAGS"
2616                   glib_save_LIBS="$LIBS"
2617                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2618                   AC_TRY_RUN([#include <pcre.h>
2619                               int main () {
2620                                 int support;
2621                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2622                                 if (!support)
2623                                   return 1;
2624                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2625                                 if (!support)
2626                                   return 1;
2627                                 return 0;
2628                               }],
2629                   glib_cv_pcre_has_unicode=yes,
2630                   glib_cv_pcre_has_unicode=no,
2631                   glib_cv_pcre_has_unicode=yes)
2632                   CFLAGS="$glib_save_CFLAGS"
2633                   LIBS="$glib_save_LIBS"
2634       ])
2635   if test "$glib_cv_pcre_has_unicode" = "no"; then
2636     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2637   fi
2638   AC_SUBST(PCRE_CFLAGS)
2639   AC_SUBST(PCRE_LIBS)
2640   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2641   PCRE_REQUIRES=libpcre
2642   AC_SUBST(PCRE_REQUIRES)
2643 ], [
2644   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2645   AS_IF([ test x"$GCC" = xyes], [
2646     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2647     save_CFLAGS="$CFLAGS"
2648     CFLAGS="$CFLAGS -Wno-pointer-sign"
2649     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2650                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2651     CFLAGS="$save_CFLAGS"
2652   ])
2653 ])
2654 AC_SUBST(PCRE_WARN_CFLAGS)
2655
2656 dnl **********************
2657 dnl *** Win32 API libs ***
2658 dnl **********************
2659
2660 case $host in
2661   *-*-cygwin*)
2662         G_LIBS_EXTRA="-luser32 -lkernel32"
2663     ;;
2664   *-*-mingw*)
2665         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2666     ;;
2667   *)
2668         G_LIBS_EXTRA=""
2669     ;;
2670 esac
2671 AC_SUBST(G_LIBS_EXTRA)
2672
2673 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2674 dnl since we need it for g_iconv()
2675
2676 AC_MSG_CHECKING([for EILSEQ])
2677 AC_TRY_COMPILE([
2678 #include <errno.h>
2679 ],
2680 [
2681 int error = EILSEQ;
2682 ], have_eilseq=yes, have_eilseq=no);
2683 AC_MSG_RESULT($have_eilseq)
2684
2685 dnl ******************************************************************
2686 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2687 dnl *** glib-compile-schemas in PATH                               ***
2688 dnl ******************************************************************
2689
2690 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2691
2692 AS_IF([ test $cross_compiling = yes ], [
2693   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2694   if test x$GLIB_GENMARSHAL = xno; then
2695     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2696   fi
2697
2698   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2699   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2700     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2701   fi
2702
2703   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2704   if test x$GLIB_COMPILE_RESOURCES = xno; then
2705     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2706   fi
2707 ])
2708
2709 dnl **************************
2710 dnl *** Checks for gtk-doc ***
2711 dnl **************************
2712 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2713 # it on it's own line.
2714 m4_ifdef([GTK_DOC_CHECK], [
2715 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2716 ],[
2717 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2718 ])
2719
2720 AC_ARG_ENABLE(man,
2721               [AS_HELP_STRING([--enable-man],
2722                               [generate man pages [default=auto]])],,
2723               enable_man=maybe)
2724
2725 AS_IF([test "$enable_man" != no], [
2726   AC_PATH_PROG([XSLTPROC], [xsltproc])
2727   AS_IF([test -z "$XSLTPROC"], [
2728     AS_IF([test "$enable_man" = yes], [
2729       AC_MSG_ERROR([xsltproc is required for --enable-man])
2730     ])
2731     enable_man=no
2732   ])
2733 ])
2734
2735 AS_IF([ test "$enable_man" != no ], [
2736   dnl check for DocBook DTD in the local catalog
2737   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2738      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2739   AS_IF([test "$have_docbook_dtd" != yes], [
2740     AS_IF([test "$enable_man" = yes ], [
2741       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2742     ])
2743     enable_man=no
2744   ])
2745 ])
2746
2747 AS_IF([test "$enable_man" != no], [
2748   dnl check for DocBook XSL stylesheets in the local catalog
2749   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2750      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2751   AS_IF([ test "$have_docbook_dtd" != yes ], [
2752     AS_IF([ test "$enable_man" = yes ], [
2753       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2754     ])
2755     enable_man=no
2756   ])
2757 ])
2758
2759 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2760
2761 AC_MSG_CHECKING([whether to generate man pages])
2762 AS_IF([ test "$enable_man" != no ], [
2763   AC_MSG_RESULT([yes])
2764 ], [
2765   AC_MSG_RESULT([no])
2766 ])
2767
2768 dnl
2769 dnl Tracing
2770 dnl
2771
2772 AC_ARG_ENABLE([dtrace],
2773              [AS_HELP_STRING([--enable-dtrace],
2774                               [include tracing support for dtrace])])
2775 have_dtrace=no
2776 AC_MSG_CHECKING([whether to include dtrace tracing support])
2777 AS_IF([ test "x$enable_dtrace" != xno], [
2778   if test x$glib_have_carbon = xyes; then
2779     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2780   else
2781     AC_MSG_RESULT([yes])
2782     AC_CHECK_PROGS(DTRACE, dtrace)
2783     if test -z "$DTRACE"; then
2784       if test "x$enable_dtrace" = xyes; then
2785         AC_MSG_ERROR([dtrace not found])
2786       fi
2787     else
2788       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2789                       [if test "x$enable_dtrace" = xyes; then
2790                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2791                        fi])
2792     fi
2793   fi
2794 ], [
2795   AC_MSG_RESULT([no])
2796 ])
2797 if test "x$have_dtrace" = xyes; then
2798   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2799 fi
2800 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2801
2802 AC_MSG_CHECKING([whether to include systemtap tracing support])
2803 AC_ARG_ENABLE([systemtap],
2804              [AS_HELP_STRING([--enable-systemtap],
2805                               [include tracing support for systemtap])])
2806 have_systemtap=no
2807 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2808   have_systemtap=yes
2809 fi
2810 AC_MSG_RESULT(${have_systemtap})
2811
2812 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2813
2814 AC_ARG_WITH([tapset-install-dir],
2815             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2816                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2817             [if test "x${withval}" = x; then
2818                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2819              else
2820                ABS_TAPSET_DIR="${withval}"
2821               fi],
2822             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2823 AC_SUBST(ABS_TAPSET_DIR)
2824
2825 dnl ************************************
2826 dnl *** Enable lcov coverage reports ***
2827 dnl ************************************
2828
2829 AC_ARG_ENABLE(gcov,
2830   AS_HELP_STRING([--enable-gcov],
2831                  [enable coverage testing with gcov]),
2832   [use_gcov=$enableval], [use_gcov=no])
2833
2834 AS_IF([ test "x$use_gcov" = "xyes"], [
2835   dnl we need gcc:
2836   if test "$GCC" != "yes"; then
2837     AC_MSG_ERROR([GCC is required for --enable-gcov])
2838   fi
2839
2840   dnl Check if ccache is being used
2841   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2842   case `$SHTOOL path $CC` in
2843     *ccache*[)] gcc_ccache=yes;;
2844     *[)] gcc_ccache=no;;
2845   esac
2846
2847   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2848     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2849   fi
2850
2851   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2852   AC_CHECK_PROG(LTP, lcov, lcov)
2853   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2854
2855   AS_IF([ test "$LTP" ], [
2856     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2857       glib_cv_ltp_version=invalid
2858       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2859       for ltp_check_version in $ltp_version_list; do
2860         if test "$ltp_version" = "$ltp_check_version"; then
2861           glib_cv_ltp_version="$ltp_check_version (ok)"
2862         fi
2863       done
2864     ])
2865   ], [
2866     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2867     AC_MSG_ERROR([$ltp_msg])
2868   ])
2869
2870   case $glib_cv_ltp_version in
2871     ""|invalid[)]
2872       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2873       AC_MSG_ERROR([$ltp_msg])
2874       LTP="exit 0;"
2875       ;;
2876   esac
2877
2878   if test -z "$LTP_GENHTML"; then
2879     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2880   fi
2881
2882   dnl Remove all optimization flags from CFLAGS
2883   changequote({,})
2884   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2885   changequote([,])
2886
2887   dnl Add the special gcc flags
2888   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2889   LDFLAGS="$LDFLAGS -lgcov"
2890 ])
2891
2892 dnl ******************************
2893 dnl *** output the whole stuff ***
2894 dnl ******************************
2895
2896 dnl this section will only be run if config.status is invoked with no
2897 dnl arguments, or with "glib/glibconfig.h" as an argument.
2898 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2899 [
2900         outfile=glib/glibconfig.h-tmp
2901         cat > $outfile <<\_______EOF
2902 /* glibconfig.h
2903  *
2904  * This is a generated file.  Please modify 'configure.ac'
2905  */
2906
2907 #ifndef __GLIBCONFIG_H__
2908 #define __GLIBCONFIG_H__
2909
2910 #include <glib/gmacros.h>
2911
2912 _______EOF
2913
2914         if test x$glib_limits_h = xyes; then
2915           echo '#include <limits.h>' >> $outfile
2916         fi
2917         if test x$glib_float_h = xyes; then
2918           echo '#include <float.h>' >> $outfile
2919         fi
2920         if test x$glib_values_h = xyes; then
2921           echo '#include <values.h>' >> $outfile
2922         fi
2923         if test "$glib_header_alloca_h" = "yes"; then
2924           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2925         fi
2926         if test x$glib_sys_poll_h = xyes; then
2927           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2928         fi
2929         if test x$glib_included_printf != xyes; then
2930           echo "
2931 /* Specifies that GLib's g_print*() functions wrap the
2932  * system printf functions.  This is useful to know, for example,
2933  * when using glibc's register_printf_function().
2934  */" >> $outfile
2935           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2936         fi
2937
2938         cat >> $outfile <<_______EOF
2939
2940 G_BEGIN_DECLS
2941
2942 #define G_MINFLOAT      $glib_mf
2943 #define G_MAXFLOAT      $glib_Mf
2944 #define G_MINDOUBLE     $glib_md
2945 #define G_MAXDOUBLE     $glib_Md
2946 #define G_MINSHORT      $glib_ms
2947 #define G_MAXSHORT      $glib_Ms
2948 #define G_MAXUSHORT     $glib_Mus
2949 #define G_MININT        $glib_mi
2950 #define G_MAXINT        $glib_Mi
2951 #define G_MAXUINT       $glib_Mui
2952 #define G_MINLONG       $glib_ml
2953 #define G_MAXLONG       $glib_Ml
2954 #define G_MAXULONG      $glib_Mul
2955
2956 _______EOF
2957
2958
2959         ### this should always be true in a modern C/C++ compiler
2960         cat >>$outfile <<_______EOF
2961 typedef signed char gint8;
2962 typedef unsigned char guint8;
2963 _______EOF
2964
2965
2966         if test -n "$gint16"; then
2967           cat >>$outfile <<_______EOF
2968 typedef signed $gint16 gint16;
2969 typedef unsigned $gint16 guint16;
2970 #define G_GINT16_MODIFIER $gint16_modifier
2971 #define G_GINT16_FORMAT $gint16_format
2972 #define G_GUINT16_FORMAT $guint16_format
2973 _______EOF
2974         fi
2975
2976
2977         if test -n "$gint32"; then
2978           cat >>$outfile <<_______EOF
2979 typedef signed $gint32 gint32;
2980 typedef unsigned $gint32 guint32;
2981 #define G_GINT32_MODIFIER $gint32_modifier
2982 #define G_GINT32_FORMAT $gint32_format
2983 #define G_GUINT32_FORMAT $guint32_format
2984 _______EOF
2985         fi
2986
2987         cat >>$outfile <<_______EOF
2988 #define G_HAVE_GINT64 1          /* deprecated, always true */
2989
2990 ${glib_extension}typedef signed $gint64 gint64;
2991 ${glib_extension}typedef unsigned $gint64 guint64;
2992
2993 #define G_GINT64_CONSTANT(val)  $gint64_constant
2994 #define G_GUINT64_CONSTANT(val) $guint64_constant
2995 _______EOF
2996
2997         if test x$gint64_format != x ; then
2998           cat >>$outfile <<_______EOF
2999 #define G_GINT64_MODIFIER $gint64_modifier
3000 #define G_GINT64_FORMAT $gint64_format
3001 #define G_GUINT64_FORMAT $guint64_format
3002 _______EOF
3003         else
3004           cat >>$outfile <<_______EOF
3005 #undef G_GINT64_MODIFIER
3006 #undef G_GINT64_FORMAT
3007 #undef G_GUINT64_FORMAT
3008 _______EOF
3009         fi
3010
3011         cat >>$outfile <<_______EOF
3012
3013 #define GLIB_SIZEOF_VOID_P $glib_void_p
3014 #define GLIB_SIZEOF_LONG   $glib_long
3015 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3016 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
3017
3018 _______EOF
3019
3020         cat >>$outfile <<_______EOF
3021 typedef signed $glib_ssize_type_define gssize;
3022 typedef unsigned $glib_size_type_define gsize;
3023 #define G_GSIZE_MODIFIER $gsize_modifier
3024 #define G_GSSIZE_MODIFIER $gssize_modifier
3025 #define G_GSIZE_FORMAT $gsize_format
3026 #define G_GSSIZE_FORMAT $gssize_format
3027
3028 #define G_MAXSIZE       G_MAXU$glib_msize_type
3029 #define G_MINSSIZE      G_MIN$glib_mssize_type
3030 #define G_MAXSSIZE      G_MAX$glib_mssize_type
3031
3032 typedef gint64 goffset;
3033 #define G_MINOFFSET     G_MININT64
3034 #define G_MAXOFFSET     G_MAXINT64
3035
3036 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3037 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3038 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3039
3040 _______EOF
3041
3042         if test -z "$glib_unknown_void_p"; then
3043           cat >>$outfile <<_______EOF
3044
3045 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3046 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3047
3048 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3049 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3050
3051 typedef signed $glib_intptr_type_define gintptr;
3052 typedef unsigned $glib_intptr_type_define guintptr;
3053
3054 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3055 #define G_GINTPTR_FORMAT        $gintptr_format
3056 #define G_GUINTPTR_FORMAT       $guintptr_format
3057 _______EOF
3058         else
3059           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3060         fi
3061
3062
3063
3064         cat >>$outfile <<_______EOF
3065 $glib_atexit
3066 $glib_memmove
3067 $glib_defines
3068 $glib_os
3069 $glib_static_compilation
3070
3071 $glib_vacopy
3072
3073 #ifdef  __cplusplus
3074 #define G_HAVE_INLINE   1
3075 #else   /* !__cplusplus */
3076 $glib_inline
3077 #endif  /* !__cplusplus */
3078
3079 #ifdef  __cplusplus
3080 #define G_CAN_INLINE    1
3081 _______EOF
3082
3083         if test x$g_can_inline = xyes ; then
3084                 cat >>$outfile <<_______EOF
3085 #else   /* !__cplusplus */
3086 #define G_CAN_INLINE    1
3087 _______EOF
3088         fi
3089
3090         cat >>$outfile <<_______EOF
3091 #endif
3092
3093 _______EOF
3094
3095         if test x$g_have_iso_c_varargs = xyes ; then
3096                 cat >>$outfile <<_______EOF
3097 #ifndef __cplusplus
3098 # define G_HAVE_ISO_VARARGS 1
3099 #endif
3100 _______EOF
3101         fi
3102         if test x$g_have_iso_cxx_varargs = xyes ; then
3103                 cat >>$outfile <<_______EOF
3104 #ifdef __cplusplus
3105 # define G_HAVE_ISO_VARARGS 1
3106 #endif
3107 _______EOF
3108         fi
3109         if test x$g_have_gnuc_varargs = xyes ; then
3110                 cat >>$outfile <<_______EOF
3111
3112 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3113  * is passed ISO vararg support is turned off, and there is no work
3114  * around to turn it on, so we unconditionally turn it off.
3115  */
3116 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3117 #  undef G_HAVE_ISO_VARARGS
3118 #endif
3119
3120 #define G_HAVE_GNUC_VARARGS 1
3121 _______EOF
3122         fi
3123
3124         case x$g_stack_grows in
3125         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3126         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3127         esac
3128
3129
3130         echo >>$outfile
3131         if test x$g_have_eilseq = xno; then
3132                 cat >>$outfile <<_______EOF
3133 #ifndef EILSEQ
3134 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3135  * The correspondence between this and the corresponding definition
3136  * in libiconv is essential.
3137  */
3138 #  define EILSEQ ENOENT
3139 #endif
3140 _______EOF
3141
3142         fi
3143
3144         if test x$g_have_gnuc_visibility = xyes; then
3145                 cat >>$outfile <<_______EOF
3146 #define G_HAVE_GNUC_VISIBILITY 1
3147 _______EOF
3148         fi
3149                 cat >>$outfile <<_______EOF
3150 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3151 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3152 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3153 #define G_GNUC_INTERNAL __hidden
3154 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3155 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3156 #else
3157 #define G_GNUC_INTERNAL
3158 #endif
3159 _______EOF
3160
3161         echo >>$outfile
3162         cat >>$outfile <<_______EOF
3163 #define G_THREADS_ENABLED
3164 #define G_THREADS_IMPL_$g_threads_impl_def
3165 _______EOF
3166
3167         if test x"$g_memory_barrier_needed" != xno; then
3168           echo >>$outfile
3169           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3170         fi
3171         if test x"$g_atomic_lock_free" = xyes; then
3172           echo >>$outfile
3173           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3174         fi
3175         echo >>$outfile
3176         g_bit_sizes="16 32 64"
3177         for bits in $g_bit_sizes; do
3178           cat >>$outfile <<_______EOF
3179 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3180 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3181 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3182 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3183 _______EOF
3184         done
3185
3186         cat >>$outfile <<_______EOF
3187 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3188 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3189 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3190 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3191 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3192 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3193 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3194 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3195 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3196 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3197 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3198 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3199 #define G_BYTE_ORDER $g_byte_order
3200
3201 #define GLIB_SYSDEF_POLLIN =$g_pollin
3202 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3203 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3204 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3205 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3206 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3207
3208 #define G_MODULE_SUFFIX "$g_module_suffix"
3209
3210 typedef $g_pid_type GPid;
3211
3212 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3213 #define GLIB_SYSDEF_AF_INET $g_af_inet
3214 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3215
3216 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3217 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3218 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3219
3220 G_END_DECLS
3221
3222 #endif /* __GLIBCONFIG_H__ */
3223 _______EOF
3224
3225
3226         if cmp -s $outfile glib/glibconfig.h; then
3227           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3228           rm -f $outfile
3229         else
3230           mv $outfile glib/glibconfig.h
3231         fi
3232 ],[
3233
3234 # Note that if two cases are the same, case goes with the first one.
3235 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3236 # on variable expansion in case labels.  Look at the generated config.status
3237 # for a hint.
3238
3239 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3240   glib_header_alloca_h="$ac_cv_working_alloca_h"
3241 else
3242   glib_header_alloca_h="$ac_cv_header_alloca_h"
3243 fi
3244
3245 case xyes in
3246 x$ac_cv_header_float_h)
3247   glib_float_h=yes
3248   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3249   glib_md=DBL_MIN glib_Md=DBL_MAX
3250   ;;
3251 x$ac_cv_header_values_h)
3252   glib_values_h=yes
3253   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3254   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3255   ;;
3256 esac
3257
3258 case xyes in
3259 x$ac_cv_header_limits_h)
3260   glib_limits_h=yes
3261   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3262   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3263   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3264   ;;
3265 x$ac_cv_header_values_h)
3266   glib_values_h=yes
3267   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3268   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3269   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3270   ;;
3271 esac
3272
3273 if test x$ac_cv_header_sys_poll_h = xyes ; then
3274   glib_sys_poll_h=yes
3275 fi
3276
3277 if test x$enable_included_printf = xyes ; then
3278   glib_included_printf=yes
3279 fi
3280
3281 case 2 in
3282 $ac_cv_sizeof_short)
3283   gint16=short
3284   gint16_modifier='"h"'
3285   gint16_format='"hi"'
3286   guint16_format='"hu"'
3287   ;;
3288 $ac_cv_sizeof_int)
3289   gint16=int
3290   gint16_modifier='""'
3291   gint16_format='"i"'
3292   guint16_format='"u"'
3293   ;;
3294 esac
3295 case 4 in
3296 $ac_cv_sizeof_short)
3297   gint32=short
3298   gint32_modifier='"h"'
3299   gint32_format='"hi"'
3300   guint32_format='"hu"'
3301   ;;
3302 $ac_cv_sizeof_int)
3303   gint32=int
3304   gint32_modifier='""'
3305   gint32_format='"i"'
3306   guint32_format='"u"'
3307   ;;
3308 $ac_cv_sizeof_long)
3309   gint32=long
3310   gint32_modifier='"l"'
3311   gint32_format='"li"'
3312   guint32_format='"lu"'
3313   ;;
3314 esac
3315 case 8 in
3316 $ac_cv_sizeof_int)
3317   gint64=int
3318   gint64_modifier='""'
3319   gint64_format='"i"'
3320   guint64_format='"u"'
3321   glib_extension=
3322   gint64_constant='(val)'
3323   guint64_constant='(val)'
3324   ;;
3325 $ac_cv_sizeof_long)
3326   gint64=long
3327   gint64_modifier='"l"'
3328   gint64_format='"li"'
3329   guint64_format='"lu"'
3330   glib_extension=
3331   gint64_constant='(val##L)'
3332   guint64_constant='(val##UL)'
3333   ;;
3334 $ac_cv_sizeof_long_long)
3335   gint64='long long'
3336   if test -n "$glib_cv_long_long_format"; then
3337     gint64_modifier='"'$glib_cv_long_long_format'"'
3338     gint64_format='"'$glib_cv_long_long_format'i"'
3339     guint64_format='"'$glib_cv_long_long_format'u"'
3340   fi
3341   glib_extension='G_GNUC_EXTENSION '
3342   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3343   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3344   ;;
3345 $ac_cv_sizeof___int64)
3346   gint64='__int64'
3347   if test -n "$glib_cv_long_long_format"; then
3348     gint64_modifier='"'$glib_cv_long_long_format'"'
3349     gint64_format='"'$glib_cv_long_long_format'i"'
3350     guint64_format='"'$glib_cv_long_long_format'u"'
3351   fi
3352   glib_extension=
3353   gint64_constant='(val##i64)'
3354   guint64_constant='(val##ui64)'
3355   ;;
3356 esac
3357 glib_size_t=$ac_cv_sizeof_size_t
3358 glib_ssize_t=$ac_cv_sizeof_ssize_t
3359 glib_size_type_define="$glib_size_type"
3360 glib_ssize_type_define="$glib_ssize_type"
3361 glib_void_p=$ac_cv_sizeof_void_p
3362 glib_long=$ac_cv_sizeof_long
3363
3364 case "$glib_size_type" in
3365 short)
3366   gsize_modifier='"h"'
3367   gsize_format='"hu"'
3368   glib_msize_type='SHRT'
3369   ;;
3370 int)
3371   gsize_modifier='""'
3372   gsize_format='"u"'
3373   glib_msize_type='INT'
3374   ;;
3375 long)
3376   gsize_modifier='"l"'
3377   gsize_format='"lu"'
3378   glib_msize_type='LONG'
3379   ;;
3380 "long long"|__int64)
3381   gsize_modifier='"I64"'
3382   gsize_format='"I64u"'
3383   glib_msize_type='INT64'
3384   ;;
3385 esac
3386
3387 case "$glib_ssize_type" in
3388 short)
3389   gssize_modifier='"h"'
3390   gssize_format='"hi"'
3391   glib_mssize_type='SHRT'
3392   ;;
3393 int)
3394   gssize_modifier='""'
3395   gssize_format='"i"'
3396   glib_mssize_type='INT'
3397   ;;
3398 long)
3399   gssize_modifier='"l"'
3400   gssize_format='"li"'
3401   glib_mssize_type='LONG'
3402   ;;
3403 "long long"|__int64)
3404   gssize_modifier='"I64"'
3405   gssize_format='"I64i"'
3406   glib_mssize_type='INT64'
3407   ;;
3408 esac
3409
3410 gintbits=`expr $ac_cv_sizeof_int \* 8`
3411 glongbits=`expr $ac_cv_sizeof_long \* 8`
3412 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3413 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3414
3415 case $ac_cv_sizeof_void_p in
3416 $ac_cv_sizeof_int)
3417   glib_intptr_type_define=int
3418   gintptr_modifier='""'
3419   gintptr_format='"i"'
3420   guintptr_format='"u"'
3421   glib_gpi_cast='(gint)'
3422   glib_gpui_cast='(guint)'
3423   ;;
3424 $ac_cv_sizeof_long)
3425   glib_intptr_type_define=long
3426   gintptr_modifier='"l"'
3427   gintptr_format='"li"'
3428   guintptr_format='"lu"'
3429   glib_gpi_cast='(glong)'
3430   glib_gpui_cast='(gulong)'
3431   ;;
3432 $ac_cv_sizeof_long_long)
3433   glib_intptr_type_define='long long'
3434   gintptr_modifier='"I64"'
3435   gintptr_format='"I64i"'
3436   guintptr_format='"I64u"'
3437   glib_gpi_cast='(gint64)'
3438   glib_gpui_cast='(guint64)'
3439   ;;
3440 $ac_cv_sizeof___int64)
3441   glib_intptr_type_define=__int64
3442   gintptr_modifier='"I64"'
3443   gintptr_format='"I64i"'
3444   guintptr_format='"I64u"'
3445   glib_gpi_cast='(gint64)'
3446   glib_gpui_cast='(guint64)'
3447   ;;
3448 *)
3449   glib_unknown_void_p=yes
3450   ;;
3451 esac
3452
3453
3454 case xyes in
3455 x$ac_cv_func_atexit)
3456   glib_atexit="
3457 #ifdef NeXT /* @#%@! NeXTStep */
3458 # define g_ATEXIT(proc) (!atexit (proc))
3459 #else
3460 # define g_ATEXIT(proc) (atexit (proc))
3461 #endif"
3462   ;;
3463 x$ac_cv_func_on_exit)
3464   glib_atexit="
3465 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3466   ;;
3467 esac
3468
3469 case xyes in
3470 x$ac_cv_func_memmove)
3471   glib_memmove='
3472 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3473   ;;
3474 x$glib_cv_working_bcopy)
3475   glib_memmove="
3476 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3477 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3478   ;;
3479 *)
3480   glib_memmove="
3481 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3482  * so we have to roll our own copy routine. */
3483 void g_memmove (void* dest, const void * src, unsigned long len);"
3484   ;;
3485 esac
3486
3487 glib_defines="
3488 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3489 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3490 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3491 "
3492
3493 case xyes in
3494 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3495 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3496 *)                      glib_vacopy=''
3497 esac
3498
3499 if test x$glib_cv_va_val_copy = xno; then
3500   glib_vacopy="\$glib_vacopy
3501 #define G_VA_COPY_AS_ARRAY 1"
3502 fi
3503
3504 if test x$glib_cv_hasinline = xyes; then
3505     glib_inline='#define G_HAVE_INLINE 1'
3506 fi
3507 if test x$glib_cv_has__inline = xyes; then
3508     glib_inline="\$glib_inline
3509 #define G_HAVE___INLINE 1"
3510 fi
3511 if test x$glib_cv_has__inline__ = xyes; then
3512     glib_inline="\$glib_inline
3513 #define G_HAVE___INLINE__ 1"
3514 fi
3515
3516 g_have_gnuc_varargs=$g_have_gnuc_varargs
3517 g_have_iso_c_varargs=$g_have_iso_c_varargs
3518 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3519
3520 g_can_inline=$g_can_inline
3521 g_have_gnuc_visibility=$g_have_gnuc_visibility
3522 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3523
3524 if test x$ac_cv_c_bigendian = xyes; then
3525   g_byte_order=G_BIG_ENDIAN
3526   g_bs_native=BE
3527   g_bs_alien=LE
3528 else
3529   g_byte_order=G_LITTLE_ENDIAN
3530   g_bs_native=LE
3531   g_bs_alien=BE
3532 fi
3533
3534 g_pollin=$glib_cv_value_POLLIN
3535 g_pollout=$glib_cv_value_POLLOUT
3536 g_pollpri=$glib_cv_value_POLLPRI
3537 g_pollhup=$glib_cv_value_POLLHUP
3538 g_pollerr=$glib_cv_value_POLLERR
3539 g_pollnval=$glib_cv_value_POLLNVAL
3540
3541 # If a family is not found on the system, define that family to
3542 # a negative value, picking a different one for each undefined
3543 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3544 # This is needed because glib-mkenums doesn't handle optional
3545 # values in enums, and thus we have to have all existing values
3546 # defined in the enum.
3547 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3548   g_af_unix=$glib_cv_value_AF_UNIX
3549 else
3550   g_af_unix=-1
3551 fi
3552 g_af_inet=$glib_cv_value_AF_INET
3553 g_af_inet6=$glib_cv_value_AF_INET6
3554
3555 g_msg_peek=$glib_cv_value_MSG_PEEK
3556 g_msg_oob=$glib_cv_value_MSG_OOB
3557 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3558
3559 g_stack_grows=$glib_cv_stack_grows
3560
3561 g_have_eilseq=$have_eilseq
3562
3563 g_threads_impl_def=$g_threads_impl
3564
3565 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3566 g_memory_barrier_needed="$glib_memory_barrier_needed"
3567 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3568
3569 g_module_suffix="$glib_gmodule_suffix"
3570
3571 g_pid_type="$glib_pid_type"
3572 case $host in
3573   *-*-beos*)
3574     glib_os="#define G_OS_BEOS"
3575     ;;
3576   *-*-cygwin*)
3577     glib_os="#define G_OS_UNIX
3578 #define G_PLATFORM_WIN32
3579 #define G_WITH_CYGWIN"
3580     ;;
3581   *-*-mingw*)
3582     glib_os="#define G_OS_WIN32
3583 #define G_PLATFORM_WIN32"
3584     ;;
3585   *)
3586     glib_os="#define G_OS_UNIX"
3587     ;;
3588 esac
3589 glib_static_compilation=""
3590 if test x$glib_win32_static_compilation = xyes; then
3591   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3592 #define GOBJECT_STATIC_COMPILATION 1"
3593 fi
3594 ])
3595
3596 # Redo enough to get guint32 and guint64 for the alignment checks below
3597 case 4 in
3598 $ac_cv_sizeof_short)
3599   gint32=short
3600   ;;
3601 $ac_cv_sizeof_int)
3602   gint32=int
3603   ;;
3604 $ac_cv_sizeof_long)
3605   gint32=long
3606   ;;
3607 esac
3608 case 8 in
3609 $ac_cv_sizeof_int)
3610   gint64=int
3611   ;;
3612 $ac_cv_sizeof_long)
3613   gint64=long
3614   ;;
3615 $ac_cv_sizeof_long_long)
3616   gint64='long long'
3617   ;;
3618 $ac_cv_sizeof___int64)
3619   gint64='__int64'
3620   ;;
3621 esac
3622
3623 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3624 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3625 typedef unsigned $gint32 guint32;])
3626 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3627 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3628 typedef unsigned $gint64 guint64;])
3629 AC_CHECK_TYPE([unsigned long])
3630 AC_CHECK_ALIGNOF([unsigned long])
3631
3632 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3633 #
3634 # 1.2.14 required for dbus_message_set_serial
3635 PKG_CHECK_MODULES(DBUS1,
3636      dbus-1 >= 1.2.14,
3637      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3638      have_dbus1=no)
3639 AC_SUBST(DBUS1_CFLAGS)
3640 AC_SUBST(DBUS1_LIBS)
3641 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3642
3643 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3644 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3645
3646 dnl
3647 dnl Check for -Bsymbolic-functions linker flag used to avoid
3648 dnl intra-library PLT jumps, if available.
3649 dnl
3650
3651 AC_ARG_ENABLE(Bsymbolic,
3652               [AS_HELP_STRING([--disable-Bsymbolic],
3653                               [avoid linking with -Bsymbolic])],,
3654               [SAVED_LDFLAGS="${LDFLAGS}"
3655                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3656                LDFLAGS=-Wl,-Bsymbolic-functions
3657                AC_TRY_LINK([], [int main (void) { return 0; }],
3658                            AC_MSG_RESULT(yes)
3659                            enable_Bsymbolic=yes,
3660                            AC_MSG_RESULT(no)
3661                            enable_Bsymbolic=no)
3662                LDFLAGS="${SAVED_LDFLAGS}"])
3663
3664 if test "x${enable_Bsymbolic}" = "xyes"; then
3665   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3666 fi
3667
3668 AC_SUBST(GLIB_LINK_FLAGS)
3669
3670 dnl
3671 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3672 dnl visibility attributes for symbol export control
3673 dnl
3674 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3675 case "$host" in
3676   *-*-mingw*)
3677     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3678     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3679               [defines how to decorate public symbols while building])
3680     CFLAGS="${CFLAGS} -fvisibility=hidden"
3681     ;;
3682   *)
3683     dnl on other compilers, check if we can do -fvisibility=hidden
3684     SAVED_CFLAGS="${CFLAGS}"
3685     CFLAGS="-fvisibility=hidden"
3686     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3687     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3688                    AC_MSG_RESULT(yes)
3689                    enable_fvisibility_hidden=yes,
3690                    AC_MSG_RESULT(no)
3691                    enable_fvisibility_hidden=no)
3692     CFLAGS="${SAVED_CFLAGS}"
3693
3694     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3695       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3696                 [defines how to decorate public symbols while building])
3697       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3698     ])
3699     ;;
3700 esac
3701 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3702
3703 dnl Compiler flags; macro originates from systemd
3704 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3705 AC_ARG_ENABLE(compile-warnings,
3706               [AS_HELP_STRING([--disable-compile-warnings],
3707                               [Don't use builtin compiler warnings])],,
3708                               enable_compile_warnings=yes)
3709 AS_IF([test "x$enable_compile_warnings" = xyes], [
3710   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3711    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3712    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3713    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3714    -Werror=format=2 -Werror=missing-include-dirs])
3715 ])
3716 AC_SUBST(GLIB_WARN_CFLAGS)
3717
3718 #
3719 # Define variables corresponding to the correct include paths to use for
3720 # in-tree building.
3721 #
3722
3723 # for config.h:
3724 config_h_INCLUDES='-I$(top_builddir)'
3725 AC_SUBST(config_h_INCLUDES)
3726
3727 # glib:
3728 #   config.h
3729 #   $(top_builddir)/glib: for glibconfig.h
3730 #   $(top_srcdir)/glib:   for glib.h
3731 #   $(top_srcdir):        for everything
3732 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3733 AC_SUBST(glib_INCLUDES)
3734
3735 # gobject:
3736 #   same as glib
3737 gobject_INCLUDES='$(glib_INCLUDES)'
3738 AC_SUBST(gobject_INCLUDES)
3739
3740 # gmodule:
3741 #   glib includes
3742 #   $(top_srcdir)/gmodule: for gmodule.h
3743 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3744 AC_SUBST(gmodule_INCLUDES)
3745
3746 # gio:
3747 #   same as gmodule
3748 gio_INCLUDES='$(gmodule_INCLUDES)'
3749 AC_SUBST(gio_INCLUDES)
3750
3751
3752 AC_CONFIG_FILES([
3753 glib-2.0.pc
3754 gmodule-2.0.pc
3755 gmodule-export-2.0.pc
3756 gmodule-no-export-2.0.pc
3757 gthread-2.0.pc
3758 gobject-2.0.pc
3759 gio-2.0.pc
3760 gio-unix-2.0.pc
3761 gio-windows-2.0.pc
3762 glib-zip
3763 glib-gettextize
3764 Makefile
3765 build/Makefile
3766 build/win32/Makefile
3767 build/win32/dirent/Makefile
3768 build/win32/vs9/Makefile
3769 build/win32/vs10/Makefile
3770 build/win32/vs11/Makefile
3771 glib/Makefile
3772 glib/glib.stp
3773 glib/libcharset/Makefile
3774 glib/gnulib/Makefile
3775 glib/pcre/Makefile
3776 glib/update-pcre/Makefile
3777 glib/tests/Makefile
3778 gmodule/Makefile
3779 gmodule/gmoduleconf.h
3780 gobject/Makefile
3781 gobject/gobject.stp
3782 gobject/glib-mkenums
3783 gobject/tests/Makefile
3784 gthread/Makefile
3785 gio/Makefile
3786 gio/gdbus-2.0/codegen/Makefile
3787 gio/gdbus-2.0/codegen/config.py
3788 gio/gnetworking.h
3789 gio/xdgmime/Makefile
3790 gio/inotify/Makefile
3791 gio/kqueue/Makefile
3792 gio/fen/Makefile
3793 gio/fam/Makefile
3794 gio/win32/Makefile
3795 gio/tests/Makefile
3796 gio/tests/gdbus-object-manager-example/Makefile
3797 gio/tests/services/Makefile
3798 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3799 po/Makefile.in
3800 docs/Makefile
3801 docs/reference/Makefile
3802 docs/reference/glib/Makefile
3803 docs/reference/glib/version.xml
3804 docs/reference/gobject/Makefile
3805 docs/reference/gobject/version.xml
3806 docs/reference/gio/Makefile
3807 docs/reference/gio/gdbus-object-manager-example/Makefile
3808 docs/reference/gio/version.xml
3809 tests/Makefile
3810 tests/gobject/Makefile
3811 tests/refcount/Makefile
3812 m4macros/Makefile
3813 ])
3814
3815 AC_CONFIG_COMMANDS([chmod-scripts],
3816 [chmod 0755 glib-zip
3817 chmod 0755 glib-gettextize
3818 chmod 0755 gobject/glib-mkenums])
3819
3820 # we want to invoke this macro solely so that the config.status script
3821 # and automake generated makefiles know about these generated files.
3822 # They are only needed to distcheck the package
3823 if false; then
3824   AC_CONFIG_FILES([
3825     INSTALL
3826     README
3827     config.h.win32
3828     glib/glibconfig.h.win32
3829     glib/makefile.msc
3830     glib/glib.rc
3831     gmodule/makefile.msc
3832     gmodule/gmodule.rc
3833     gobject/makefile.msc
3834     gobject/gobject.rc
3835     gthread/makefile.msc
3836     gthread/gthread.rc
3837     gio/gio.rc
3838     tests/makefile.msc
3839   ])
3840 fi
3841
3842 AC_OUTPUT