CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.4 FATAL_ERROR)
   2
   3 # ----------------------------------------------------------------------------
   4 # includes
   5 set (CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   6 include (utils)
   7
   8 # ----------------------------------------------------------------------------
   9 # package information
  10 set (PACKAGE_NAME      "gflags")
  11 set (PACKAGE_VERSION   "2.1.0")
  12 set (PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  13 set (PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  14 set (PACKAGE_BUGREPORT "https://code.google.com/p/gflags/issues/")
  15
  16 project (${PACKAGE_NAME} CXX)
  17
  18 version_numbers (
  19   ${PACKAGE_VERSION}
  20     PACKAGE_VERSION_MAJOR
  21     PACKAGE_VERSION_MINOR
  22     PACKAGE_VERSION_PATCH
  23 )
  24
  25 # ----------------------------------------------------------------------------
  26 # options
  27 set (GFLAGS_NAMESPACE "${PACKAGE_NAME}" CACHE STRING "C++ namespace identifier of gflags library.")
  28
  29 option (BUILD_SHARED_LIBS          "Request build of shared libraries."                                       OFF)
  30 option (BUILD_STATIC_LIBS          "Request build of static libraries (default if BUILD_SHARED_LIBS is OFF)." OFF)
  31 option (BUILD_gflags_LIB           "Request build of the multi-threaded gflags library."                      ON)
  32 option (BUILD_gflags_nothreads_LIB "Request build of the single-threaded gflags library."                     ON)
  33 option (BUILD_PACKAGING            "Enable build of distribution packages using CPack."                       OFF)
  34 option (BUILD_TESTING              "Enable build of the unit tests and their execution using CTest."          OFF)
  35 option (BUILD_NC_TESTS             "Request addition of negative compilation tests."                          OFF)
  36 option (INSTALL_HEADERS            "Request packaging of headers and other development files."                ON)
  37
  38 mark_as_advanced (CLEAR CMAKE_INSTALL_PREFIX)
  39 mark_as_advanced (CMAKE_CONFIGURATION_TYPES
  40                   GFLAGS_NAMESPACE
  41                   BUILD_STATIC_LIBS
  42                   BUILD_NC_TESTS
  43                   INSTALL_HEADERS)
  44 if (APPLE)
  45   mark_as_advanced(CMAKE_OSX_ARCHITECTURES
  46                    CMAKE_OSX_DEPLOYMENT_TARGET
  47                    CMAKE_OSX_SYSROOT)
  48 endif ()
  49
  50 if (NOT BUILD_SHARED_LIBS AND NOT BUILD_STATIC_LIBS)
  51   set (BUILD_STATIC_LIBS ON)
  52 endif ()
  53 if (NOT BUILD_gflags_LIB AND NOT BUILD_gflags_nothreads_LIB)
  54  message (FATAL_ERROR "At least one of BUILD_gflags_LIB and BUILD_gflags_nothreads_LIB must be ON.")
  55 endif ()
  56
  57 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CXX_FLAGS)
  58   set_property (CACHE CMAKE_BUILD_TYPE PROPERTY VALUE Release)
  59 endif ()
  60
  61 # ----------------------------------------------------------------------------
  62 # system checks
  63 include (CheckTypeSize)
  64 include (CheckIncludeFileCXX)
  65 include (CheckCXXSymbolExists)
  66
  67 if (WIN32 AND NOT CYGWIN)
  68   set (OS_WINDOWS 1)
  69 else ()
  70   set (OS_WINDOWS 0)
  71 endif ()
  72
  73 if (MSVC)
  74   set (HAVE_SYS_TYPES_H 1)
  75   set (HAVE_STDINT_H    1)
  76   set (HAVE_STDDEF_H    1) # used by CheckTypeSize module
  77   set (HAVE_INTTYPES_H  0)
  78   set (HAVE_UNISTD_H    0)
  79   set (HAVE_SYS_STAT_H  1)
  80   set (HAVE_SHLWAPI_H   1)
  81 else ()
  82   foreach (fname IN ITEMS unistd stdint inttypes sys/types sys/stat fnmatch)
  83     string (TOUPPER "${fname}" FNAME)
  84     string (REPLACE "/" "_" FNAME "${FNAME}")
  85     if (NOT HAVE_${FNAME}_H)
  86       check_include_file_cxx ("${fname}.h" HAVE_${FNAME}_H)
  87     endif ()
  88   endforeach ()
  89   # the following are used in #if directives not #ifdef
  90   bool_to_int (HAVE_STDINT_H)
  91   bool_to_int (HAVE_SYS_TYPES_H)
  92   bool_to_int (HAVE_INTTYPES_H)
  93   if (NOT HAVE_FNMATCH_H AND OS_WINDOWS)
  94     check_include_file_cxx ("shlwapi.h" HAVE_SHLWAPI_H)
  95   endif ()
  96 endif ()
  97
  98 set (GFLAGS_INTTYPES_FORMAT "" CACHE STRING "Format of integer types: \"C99\" (uint32_t), \"BSD\" (u_int32_t), \"VC7\" (__int32)")
  99 set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY STRINGS "C99;BSD;VC7")
 100 mark_as_advanced (GFLAGS_INTTYPES_FORMAT)
 101 if (NOT GFLAGS_INTTYPES_FORMAT)
 102   set (TYPES uint32_t u_int32_t)
 103   if (MSVC)
 104     list (INSERT TYPES 0 __int32)
 105   endif ()
 106   foreach (type IN LISTS TYPES)
 107     check_type_size (${type} ${type} LANGUAGE CXX)
 108     if (HAVE_${type})
 109       break ()
 110     endif ()
 111   endforeach ()
 112   if (HAVE_uint32_t)
 113     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE C99)
 114   elseif (HAVE_u_int32_t)
 115     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE BSD)
 116   elseif (HAVE___int32)
 117     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE VC7)
 118   else ()
 119     mark_as_advanced (CLEAR GFLAGS_INTTYPES_FORMAT)
 120     message (FATAL_ERROR "Do not know how to define a 32-bit integer quantity on your system!"
 121                          " Neither uint32_t, u_int32_t, nor __int32 seem to be available."
 122                          " Set GFLAGS_INTTYPES_FORMAT to either C99, BSD, or VC7 and try again.")
 123   endif ()
 124 endif ()
 125 # use of special characters in strings to circumvent bug #0008226
 126 if ("^${GFLAGS_INTTYPES_FORMAT}$" STREQUAL "^WIN$")
 127   set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE VC7)
 128 endif ()
 129 if (NOT GFLAGS_INTTYPES_FORMAT MATCHES "^(C99|BSD|VC7)$")
 130   message (FATAL_ERROR "Invalid value for GFLAGS_INTTYPES_FORMAT! Choose one of \"C99\", \"BSD\", or \"VC7\"")
 131 endif ()
 132 set (GFLAGS_INTTYPES_FORMAT_C99 0)
 133 set (GFLAGS_INTTYPES_FORMAT_BSD 0)
 134 set (GFLAGS_INTTYPES_FORMAT_VC7 0)
 135 set ("GFLAGS_INTTYPES_FORMAT_${GFLAGS_INTTYPES_FORMAT}" 1)
 136
 137 if (MSVC)
 138   set (HAVE_strtoll 0)
 139   set (HAVE_strtoq  0)
 140 else ()
 141   check_cxx_symbol_exists (strtoll stdlib.h HAVE_STRTOLL)
 142   if (NOT HAVE_STRTOLL)
 143     check_cxx_symbol_exists (strtoq stdlib.h HAVE_STRTOQ)
 144   endif ()
 145 endif ()
 146
 147 set (CMAKE_THREAD_PREFER_PTHREAD TRUE)
 148 find_package (ThreadsCXX)
 149 if (Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 150   set (HAVE_PTHREAD 1)
 151   check_type_size (pthread_rwlock_t RWLOCK LANGUAGE CXX)
 152 else ()
 153   set (HAVE_PTHREAD 0)
 154 endif ()
 155
 156 if (UNIX AND NOT HAVE_PTHREAD AND BUILD_gflags_LIB)
 157   if (CMAKE_HAVE_PTHREAD_H)
 158     set (what "library")
 159   else ()
 160     set (what ".h file")
 161   endif ()
 162   message (FATAL_ERROR "Could not find pthread${what}. Check the log file"
 163                        "\n\t${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 164                        "\nor disable the build of the multi-threaded gflags library (BUILD_gflags_LIB=OFF).")
 165 endif ()
 166
 167 # ----------------------------------------------------------------------------
 168 # source files - excluding root subdirectory and/or .in suffix
 169 set (PUBLIC_HDRS
 170   "gflags.h"
 171   "gflags_declare.h"
 172   "gflags_completions.h"
 173 )
 174
 175 set (PRIVATE_HDRS
 176   "config.h"
 177   "util.h"
 178   "mutex.h"
 179 )
 180
 181 set (GFLAGS_SRCS
 182   "gflags.cc"
 183   "gflags_reporting.cc"
 184   "gflags_completions.cc"
 185 )
 186
 187 if (OS_WINDOWS)
 188   list (APPEND PRIVATE_HDRS "windows_port.h")
 189   list (APPEND GFLAGS_SRCS  "windows_port.cc")
 190 endif ()
 191
 192 # ----------------------------------------------------------------------------
 193 # configure source files
 194 if (CMAKE_COMPILER_IS_GNUCXX)
 195   set (GFLAGS_ATTRIBUTE_UNUSED "__attribute((unused))")
 196 else ()
 197   set (GFLAGS_ATTRIBUTE_UNUSED)
 198 endif ()
 199
 200 configure_headers (PUBLIC_HDRS  ${PUBLIC_HDRS})
 201 configure_sources (PRIVATE_HDRS ${PRIVATE_HDRS})
 202 configure_sources (GFLAGS_SRCS  ${GFLAGS_SRCS})
 203
 204 include_directories ("${PROJECT_SOURCE_DIR}/src")
 205 include_directories ("${PROJECT_BINARY_DIR}/include")
 206 include_directories ("${PROJECT_BINARY_DIR}/include/${GFLAGS_NAMESPACE}")
 207
 208 # ----------------------------------------------------------------------------
 209 # output directories
 210 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "bin")
 211 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "lib")
 212 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "lib")
 213
 214 # ----------------------------------------------------------------------------
 215 # add library targets
 216 set (TARGETS)
 217 # static vs. shared
 218 foreach (TYPE IN ITEMS STATIC SHARED)
 219   if (BUILD_${TYPE}_LIBS)
 220     # whether or not targets are a DLL
 221     if (OS_WINDOWS AND "^${TYPE}$" STREQUAL "^SHARED$")
 222       set (GFLAGS_IS_A_DLL 1)
 223     else ()
 224       set (GFLAGS_IS_A_DLL 0)
 225     endif ()
 226     string (TOLOWER "${TYPE}" type)
 227     # multi-threaded vs. single-threaded
 228     foreach (opts IN ITEMS "" _nothreads)
 229       if (BUILD_gflags${opts}_LIB)
 230         add_library (gflags${opts}-${type} ${TYPE} ${GFLAGS_SRCS} ${PRIVATE_HDRS} ${PUBLIC_HDRS})
 231         if (opts MATCHES "nothreads")
 232           set (defines "GFLAGS_IS_A_DLL=${GFLAGS_IS_A_DLL};NOTHREADS")
 233         else ()
 234           set (defines "GFLAGS_IS_A_DLL=${GFLAGS_IS_A_DLL}")
 235           if (CMAKE_USE_PTHREADS_INIT)
 236             target_link_libraries (gflags${opts}-${type} ${CMAKE_THREAD_LIBS_INIT})
 237           endif ()
 238         endif ()
 239         set_target_properties (
 240           gflags${opts}-${type} PROPERTIES COMPILE_DEFINITIONS "${defines}"
 241                                            OUTPUT_NAME "gflags${opts}"
 242         )
 243         if (HAVE_SHLWAPI_H)
 244           target_link_libraries (gflags${opts}-${type} shlwapi.lib)
 245         endif ()
 246         if (NOT TARGET gflags${opts})
 247           add_custom_target (gflags${opts})
 248         endif ()
 249         add_dependencies (gflags${opts} gflags${opts}-${type})
 250         list (APPEND TARGETS gflags${opts}-${type})
 251       endif ()
 252     endforeach ()
 253   endif ()
 254 endforeach ()
 255
 256 # ----------------------------------------------------------------------------
 257 # installation
 258 if (OS_WINDOWS)
 259   set (RUNTIME_INSTALL_DIR Bin)
 260   set (LIBRARY_INSTALL_DIR Lib)
 261   set (INCLUDE_INSTALL_DIR Include)
 262   set (CONFIG_INSTALL_DIR  CMake)
 263 else ()
 264   set (RUNTIME_INSTALL_DIR bin)
 265   set (LIBRARY_INSTALL_DIR lib)
 266   set (INCLUDE_INSTALL_DIR include)
 267   set (CONFIG_INSTALL_DIR  lib/cmake/${PACKAGE_NAME})
 268 endif ()
 269
 270 file (RELATIVE_PATH INSTALL_PREFIX_REL2CONFIG_DIR "${CMAKE_INSTALL_PREFIX}/${CONFIG_INSTALL_DIR}" "${CMAKE_INSTALL_PREFIX}")
 271 configure_file (cmake/config.cmake.in  "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake" @ONLY)
 272 configure_file (cmake/version.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake" @ONLY)
 273
 274 install (TARGETS ${TARGETS} DESTINATION ${LIBRARY_INSTALL_DIR} EXPORT gflags-lib)
 275 if (INSTALL_HEADERS)
 276   install (FILES ${PUBLIC_HDRS} DESTINATION ${INCLUDE_INSTALL_DIR}/${GFLAGS_NAMESPACE})
 277   install (
 278     FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake"
 279     RENAME ${PACKAGE_NAME}-config.cmake
 280     DESTINATION ${CONFIG_INSTALL_DIR}
 281   )
 282   install (
 283     FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake"
 284     DESTINATION ${CONFIG_INSTALL_DIR}
 285   )
 286   install (EXPORT gflags-lib DESTINATION ${CONFIG_INSTALL_DIR} FILE ${PACKAGE_NAME}-export.cmake)
 287   if (UNIX)
 288     install (PROGRAMS src/gflags_completions.sh DESTINATION ${RUNTIME_INSTALL_DIR})
 289   endif ()
 290 endif ()
 291
 292 # ----------------------------------------------------------------------------
 293 # support direct use of build tree
 294 set (INSTALL_PREFIX_REL2CONFIG_DIR .)
 295 export (TARGETS ${TARGETS} FILE "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-export.cmake")
 296 export (PACKAGE gflags)
 297 configure_file (cmake/config.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config.cmake" @ONLY)
 298
 299 # ----------------------------------------------------------------------------
 300 # testing - MUST follow the generation of the build tree config file
 301 if (BUILD_TESTING)
 302   include (CTest)
 303   enable_testing ()
 304   add_subdirectory (test)
 305 endif ()
 306
 307 # ----------------------------------------------------------------------------
 308 # packaging
 309 if (BUILD_PACKAGING)
 310
 311   if (NOT BUILD_SHARED_LIBS AND NOT INSTALL_HEADERS)
 312     message (WARNING "Package will contain static libraries without headers!"
 313                      "\nRecommended options for generation of runtime package:"
 314                      "\n  BUILD_SHARED_LIBS=ON"
 315                      "\n  BUILD_STATIC_LIBS=OFF"
 316                      "\n  INSTALL_HEADERS=OFF"
 317                      "\nRecommended options for generation of development package:"
 318                      "\n  BUILD_SHARED_LIBS=ON"
 319                      "\n  BUILD_STATIC_LIBS=ON"
 320                      "\n  INSTALL_HEADERS=ON")
 321   endif ()
 322
 323   # default package generators
 324   if (APPLE)
 325     set (PACKAGE_GENERATOR        "PackageMaker")
 326     set (PACKAGE_SOURCE_GENERATOR "TGZ;ZIP")
 327   elseif (UNIX)
 328     set (PACKAGE_GENERATOR        "DEB;RPM")
 329     set (PACKAGE_SOURCE_GENERATOR "TGZ;ZIP")
 330   else ()
 331     set (PACKAGE_GENERATOR        "ZIP")
 332     set (PACKAGE_SOURCE_GENERATOR "ZIP")
 333   endif ()
 334
 335   # used package generators
 336   set (CPACK_GENERATOR        "${PACKAGE_GENERATOR}"        CACHE STRING "List of binary package generators (CPack).")
 337   set (CPACK_SOURCE_GENERATOR "${PACKAGE_SOURCE_GENERATOR}" CACHE STRING "List of source package generators (CPack).")
 338   mark_as_advanced (CPACK_GENERATOR CPACK_SOURCE_GENERATOR)
 339
 340   # common package information
 341   set (CPACK_PACKAGE_VENDOR              "Andreas Schuh")
 342   set (CPACK_PACKAGE_CONTACT             "google-gflags@googlegroups.com")
 343   set (CPACK_PACKAGE_NAME                "${PACKAGE_NAME}")
 344   set (CPACK_PACKAGE_VERSION             "${PACKAGE_VERSION}")
 345   set (CPACK_PACKAGE_VERSION_MAJOR       "${PACKAGE_VERSION_MAJOR}")
 346   set (CPACK_PACKAGE_VERSION_MINOR       "${PACKAGE_VERSION_MINOR}")
 347   set (CPACK_PACKAGE_VERSION_PATCH       "${PACKAGE_VERSION_PATCH}")
 348   set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "A commandline flags library that allows for distributed flags.")
 349   set (CPACK_RESOURCE_FILE_WELCOME       "${CMAKE_CURRENT_LIST_DIR}/README.txt")
 350   set (CPACK_RESOURCE_FILE_LICENSE       "${CMAKE_CURRENT_LIST_DIR}/COPYING.txt")
 351   set (CPACK_PACKAGE_DESCRIPTION_FILE    "${CMAKE_CURRENT_LIST_DIR}/README.txt")
 352   set (CPACK_INSTALL_PREFIX              "${CMAKE_INSTALL_PREFIX}")
 353   set (CPACK_OUTPUT_FILE_PREFIX          packages)
 354   set (CPACK_PACKAGE_RELOCATABLE         TRUE)
 355   set (CPACK_MONOLITHIC_INSTALL          TRUE)
 356
 357   # RPM package information -- used in cmake/package.cmake.in also for DEB
 358   set (CPACK_RPM_PACKAGE_GROUP   "Development/Libraries")
 359   set (CPACK_RPM_PACKAGE_LICENSE "BSD")
 360   set (CPACK_RPM_PACKAGE_URL     "http://code.google.com/p/gflags")
 361   set (CPACK_RPM_CHANGELOG_FILE  "${CMAKE_CURRENT_LIST_DIR}/ChangeLog.txt")
 362
 363   if (INSTALL_HEADERS)
 364     set (CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_LIST_DIR}/doc/gflags.html")
 365   else ()
 366     set (CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_LIST_DIR}/cmake/README_runtime.txt")
 367   endif ()
 368
 369   # system/architecture
 370   if (WINDOWS)
 371     if (CMAKE_CL_64)
 372       set (CPACK_SYSTEM_NAME "win64")
 373     else ()
 374       set (CPACK_SYSTEM_NAME "win32")
 375     endif ()
 376     set (CPACK_PACKAGE_ARCHITECTURE)
 377   else ()
 378     string (TOLOWER "${CMAKE_SYSTEM_NAME}" CPACK_SYSTEM_NAME)
 379     execute_process (
 380       COMMAND         dpkg --print-architecture
 381       RESULT_VARIABLE RV
 382       OUTPUT_VARIABLE CPACK_PACKAGE_ARCHITECTURE
 383     )
 384     if (RV EQUAL 0)
 385             string (STRIP "${CPACK_PACKAGE_ARCHITECTURE}" CPACK_PACKAGE_ARCHITECTURE)
 386     else ()
 387       execute_process (COMMAND uname -m OUTPUT_VARIABLE CPACK_PACKAGE_ARCHITECTURE)
 388       if (CPACK_PACKAGE_ARCHITECTURE MATCHES "x86_64")
 389               set (CPACK_PACKAGE_ARCHITECTURE amd64)
 390       else ()
 391         set (CPACK_PACKAGE_ARCHITECTURE i386)
 392       endif ()
 393     endif ()
 394   endif ()
 395
 396   # source package settings
 397   set (CPACK_SOURCE_TOPLEVEL_TAG      "source")
 398   set (CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 399   set (CPACK_SOURCE_IGNORE_FILES      "/\\\\.git/;\\\\.swp$;\\\\.#;/#;\\\\.*~;cscope\\\\.*;/[Bb]uild[.+-_a-zA-Z0-9]*/")
 400
 401   # default binary package settings
 402   set (CPACK_INCLUDE_TOPLEVEL_DIRECTORY TRUE)
 403   set (CPACK_PACKAGE_FILE_NAME          "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_SYSTEM_NAME}")
 404   if (CPACK_PACKAGE_ARCHITECTURE)
 405     set (CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_FILE_NAME}-${CPACK_PACKAGE_ARCHITECTURE}")
 406   endif ()
 407
 408   # generator specific configuration file
 409   #
 410   # allow package maintainers to use their own configuration file
 411   # $ cmake -DCPACK_PROJECT_CONFIG_FILE:FILE=/path/to/package/config
 412   if (NOT CPACK_PROJECT_CONFIG_FILE)
 413     configure_file (
 414       "${CMAKE_CURRENT_LIST_DIR}/cmake/package.cmake.in"
 415       "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-package.cmake" @ONLY
 416     )
 417     set (CPACK_PROJECT_CONFIG_FILE "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-package.cmake")
 418   endif ()
 419
 420   include (CPack)
 421
 422 endif () # BUILD_PACKAGING