CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.4 FATAL_ERROR)
   2
   3 # ----------------------------------------------------------------------------
   4 # includes
   5 set (CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   6 include (utils)
   7
   8 # ----------------------------------------------------------------------------
   9 # package information
  10 set (PACKAGE_NAME      "gflags")
  11 set (PACKAGE_VERSION   "2.1.1")
  12 set (PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  13 set (PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  14 set (PACKAGE_BUGREPORT "https://code.google.com/p/gflags/issues/")
  15
  16 project (${PACKAGE_NAME} CXX)
  17
  18 version_numbers (
  19   ${PACKAGE_VERSION}
  20     PACKAGE_VERSION_MAJOR
  21     PACKAGE_VERSION_MINOR
  22     PACKAGE_VERSION_PATCH
  23 )
  24
  25 set (PACKAGE_SOVERSION "${PACKAGE_VERSION_MAJOR}")
  26
  27 # ----------------------------------------------------------------------------
  28 # options
  29 if (NOT GFLAGS_NAMESPACE)
  30   # maintain binary backwards compatibility with gflags library version <= 2.0,
  31   # but at the same time enable the use of the preferred new "gflags" namespace
  32   set (GFLAGS_NAMESPACE "google;${PACKAGE_NAME}" CACHE STRING "Name(s) of library namespace (separate multiple options by semicolon)")
  33   mark_as_advanced (GFLAGS_NAMESPACE)
  34 endif ()
  35 set (GFLAGS_NAMESPACE_SECONDARY "${GFLAGS_NAMESPACE}")
  36 list (REMOVE_DUPLICATES GFLAGS_NAMESPACE_SECONDARY)
  37 if (NOT GFLAGS_NAMESPACE_SECONDARY)
  38   message (FATAL_ERROR "GFLAGS_NAMESPACE must be set to one (or more) valid C++ namespace identifier(s separated by semicolon \";\").")
  39 endif ()
  40 foreach (ns IN LISTS GFLAGS_NAMESPACE_SECONDARY)
  41   if (NOT ns MATCHES "^[a-zA-Z][a-zA-Z0-9_]*$")
  42     message (FATAL_ERROR "GFLAGS_NAMESPACE contains invalid namespace identifier: ${ns}")
  43   endif ()
  44 endforeach ()
  45 list (GET       GFLAGS_NAMESPACE_SECONDARY 0 GFLAGS_NAMESPACE)
  46 list (REMOVE_AT GFLAGS_NAMESPACE_SECONDARY 0)
  47
  48 option (BUILD_SHARED_LIBS          "Request build of shared libraries."                                       OFF)
  49 option (BUILD_STATIC_LIBS          "Request build of static libraries (default if BUILD_SHARED_LIBS is OFF)." OFF)
  50 option (BUILD_gflags_LIB           "Request build of the multi-threaded gflags library."                      ON)
  51 option (BUILD_gflags_nothreads_LIB "Request build of the single-threaded gflags library."                     ON)
  52 option (BUILD_PACKAGING            "Enable build of distribution packages using CPack."                       OFF)
  53 option (BUILD_TESTING              "Enable build of the unit tests and their execution using CTest."          OFF)
  54 option (BUILD_NC_TESTS             "Request addition of negative compilation tests."                          OFF)
  55 option (INSTALL_HEADERS            "Request packaging of headers and other development files."                ON)
  56
  57 mark_as_advanced (CLEAR CMAKE_INSTALL_PREFIX)
  58 mark_as_advanced (CMAKE_CONFIGURATION_TYPES
  59                   BUILD_STATIC_LIBS
  60                   BUILD_NC_TESTS
  61                   INSTALL_HEADERS)
  62 if (APPLE)
  63   mark_as_advanced(CMAKE_OSX_ARCHITECTURES
  64                    CMAKE_OSX_DEPLOYMENT_TARGET
  65                    CMAKE_OSX_SYSROOT)
  66 endif ()
  67
  68 if (NOT BUILD_SHARED_LIBS AND NOT BUILD_STATIC_LIBS)
  69   set (BUILD_STATIC_LIBS ON)
  70 endif ()
  71 if (NOT BUILD_gflags_LIB AND NOT BUILD_gflags_nothreads_LIB)
  72  message (FATAL_ERROR "At least one of BUILD_gflags_LIB and BUILD_gflags_nothreads_LIB must be ON.")
  73 endif ()
  74
  75 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CXX_FLAGS)
  76   set_property (CACHE CMAKE_BUILD_TYPE PROPERTY VALUE Release)
  77 endif ()
  78
  79 if (NOT GFLAGS_INCLUDE_DIR)
  80   set (GFLAGS_INCLUDE_DIR "${PACKAGE_NAME}" CACHE STRING "Name of include directory of installed header files")
  81   mark_as_advanced (GFLAGS_INCLUDE_DIR)
  82 else ()
  83   if (IS_ABSOLUTE GFLAGS_INCLUDE_DIR)
  84     message (FATAL_ERROR "GFLAGS_INCLUDE_DIR must be a path relative to CMAKE_INSTALL_PREFIX/include")
  85   endif ()
  86   if (GFLAGS_INCLUDE_DIR MATCHES "^\\.\\.[/\\]")
  87     message (FATAL_ERROR "GFLAGS_INCLUDE_DIR must not start with parent directory reference (../)")
  88   endif ()
  89 endif ()
  90
  91 # ----------------------------------------------------------------------------
  92 # system checks
  93 include (CheckTypeSize)
  94 include (CheckIncludeFileCXX)
  95 include (CheckCXXSymbolExists)
  96
  97 if (WIN32 AND NOT CYGWIN)
  98   set (OS_WINDOWS 1)
  99 else ()
 100   set (OS_WINDOWS 0)
 101 endif ()
 102
 103 if (MSVC)
 104   set (HAVE_SYS_TYPES_H 1)
 105   set (HAVE_STDINT_H    1)
 106   set (HAVE_STDDEF_H    1) # used by CheckTypeSize module
 107   set (HAVE_INTTYPES_H  0)
 108   set (HAVE_UNISTD_H    0)
 109   set (HAVE_SYS_STAT_H  1)
 110   set (HAVE_SHLWAPI_H   1)
 111 else ()
 112   foreach (fname IN ITEMS unistd stdint inttypes sys/types sys/stat fnmatch)
 113     string (TOUPPER "${fname}" FNAME)
 114     string (REPLACE "/" "_" FNAME "${FNAME}")
 115     if (NOT HAVE_${FNAME}_H)
 116       check_include_file_cxx ("${fname}.h" HAVE_${FNAME}_H)
 117     endif ()
 118   endforeach ()
 119   # the following are used in #if directives not #ifdef
 120   bool_to_int (HAVE_STDINT_H)
 121   bool_to_int (HAVE_SYS_TYPES_H)
 122   bool_to_int (HAVE_INTTYPES_H)
 123   if (NOT HAVE_FNMATCH_H AND OS_WINDOWS)
 124     check_include_file_cxx ("shlwapi.h" HAVE_SHLWAPI_H)
 125   endif ()
 126 endif ()
 127
 128 set (GFLAGS_INTTYPES_FORMAT "" CACHE STRING "Format of integer types: \"C99\" (uint32_t), \"BSD\" (u_int32_t), \"VC7\" (__int32)")
 129 set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY STRINGS "C99;BSD;VC7")
 130 mark_as_advanced (GFLAGS_INTTYPES_FORMAT)
 131 if (NOT GFLAGS_INTTYPES_FORMAT)
 132   set (TYPES uint32_t u_int32_t)
 133   if (MSVC)
 134     list (INSERT TYPES 0 __int32)
 135   endif ()
 136   foreach (type IN LISTS TYPES)
 137     check_type_size (${type} ${type} LANGUAGE CXX)
 138     if (HAVE_${type})
 139       break ()
 140     endif ()
 141   endforeach ()
 142   if (HAVE_uint32_t)
 143     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE C99)
 144   elseif (HAVE_u_int32_t)
 145     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE BSD)
 146   elseif (HAVE___int32)
 147     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE VC7)
 148   else ()
 149     mark_as_advanced (CLEAR GFLAGS_INTTYPES_FORMAT)
 150     message (FATAL_ERROR "Do not know how to define a 32-bit integer quantity on your system!"
 151                          " Neither uint32_t, u_int32_t, nor __int32 seem to be available."
 152                          " Set GFLAGS_INTTYPES_FORMAT to either C99, BSD, or VC7 and try again.")
 153   endif ()
 154 endif ()
 155 # use of special characters in strings to circumvent bug #0008226
 156 if ("^${GFLAGS_INTTYPES_FORMAT}$" STREQUAL "^WIN$")
 157   set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE VC7)
 158 endif ()
 159 if (NOT GFLAGS_INTTYPES_FORMAT MATCHES "^(C99|BSD|VC7)$")
 160   message (FATAL_ERROR "Invalid value for GFLAGS_INTTYPES_FORMAT! Choose one of \"C99\", \"BSD\", or \"VC7\"")
 161 endif ()
 162 set (GFLAGS_INTTYPES_FORMAT_C99 0)
 163 set (GFLAGS_INTTYPES_FORMAT_BSD 0)
 164 set (GFLAGS_INTTYPES_FORMAT_VC7 0)
 165 set ("GFLAGS_INTTYPES_FORMAT_${GFLAGS_INTTYPES_FORMAT}" 1)
 166
 167 if (MSVC)
 168   set (HAVE_strtoll 0)
 169   set (HAVE_strtoq  0)
 170 else ()
 171   check_cxx_symbol_exists (strtoll stdlib.h HAVE_STRTOLL)
 172   if (NOT HAVE_STRTOLL)
 173     check_cxx_symbol_exists (strtoq stdlib.h HAVE_STRTOQ)
 174   endif ()
 175 endif ()
 176
 177 set (CMAKE_THREAD_PREFER_PTHREAD TRUE)
 178 find_package (ThreadsCXX)
 179 if (Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 180   set (HAVE_PTHREAD 1)
 181   check_type_size (pthread_rwlock_t RWLOCK LANGUAGE CXX)
 182 else ()
 183   set (HAVE_PTHREAD 0)
 184 endif ()
 185
 186 if (UNIX AND NOT HAVE_PTHREAD AND BUILD_gflags_LIB)
 187   if (CMAKE_HAVE_PTHREAD_H)
 188     set (what "library")
 189   else ()
 190     set (what ".h file")
 191   endif ()
 192   message (FATAL_ERROR "Could not find pthread${what}. Check the log file"
 193                        "\n\t${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 194                        "\nor disable the build of the multi-threaded gflags library (BUILD_gflags_LIB=OFF).")
 195 endif ()
 196
 197 # ----------------------------------------------------------------------------
 198 # source files - excluding root subdirectory and/or .in suffix
 199 set (PUBLIC_HDRS
 200   "gflags.h"
 201   "gflags_declare.h"
 202   "gflags_completions.h"
 203 )
 204
 205 if (GFLAGS_NAMESPACE_SECONDARY)
 206   set (INCLUDE_GFLAGS_NS_H "// Import gflags library symbols into alternative/deprecated namespace(s)")
 207   foreach (ns IN LISTS GFLAGS_NAMESPACE_SECONDARY)
 208     string (TOUPPER "${ns}" NS)
 209     set (gflags_ns_h "${PROJECT_BINARY_DIR}/include/${GFLAGS_INCLUDE_DIR}/gflags_${ns}.h")
 210     configure_file ("${PROJECT_SOURCE_DIR}/src/gflags_ns.h.in" "${gflags_ns_h}" @ONLY)
 211     list (APPEND PUBLIC_HDRS "${gflags_ns_h}")
 212     set (INCLUDE_GFLAGS_NS_H "${INCLUDE_GFLAGS_NS_H}\n#include \"gflags_${ns}.h\"")
 213   endforeach ()
 214 else ()
 215   set (INCLUDE_GFLAGS_NS_H)
 216 endif ()
 217
 218 set (PRIVATE_HDRS
 219   "config.h"
 220   "util.h"
 221   "mutex.h"
 222 )
 223
 224 set (GFLAGS_SRCS
 225   "gflags.cc"
 226   "gflags_reporting.cc"
 227   "gflags_completions.cc"
 228 )
 229
 230 if (OS_WINDOWS)
 231   list (APPEND PRIVATE_HDRS "windows_port.h")
 232   list (APPEND GFLAGS_SRCS  "windows_port.cc")
 233 endif ()
 234
 235 # ----------------------------------------------------------------------------
 236 # configure source files
 237 if (CMAKE_COMPILER_IS_GNUCXX)
 238   set (GFLAGS_ATTRIBUTE_UNUSED "__attribute((unused))")
 239 else ()
 240   set (GFLAGS_ATTRIBUTE_UNUSED)
 241 endif ()
 242
 243 # whenever we build a shared library (DLL on Windows), configure the public
 244 # headers of the API for use of this library rather than the optionally
 245 # also build statically linked library; users can override GFLAGS_DLL_DECL
 246 if (BUILD_SHARED_LIBS)
 247   set (GFLAGS_IS_A_DLL 1)
 248 else ()
 249   set (GFLAGS_IS_A_DLL 0)
 250 endif ()
 251
 252 configure_headers (PUBLIC_HDRS  ${PUBLIC_HDRS})
 253 configure_sources (PRIVATE_HDRS ${PRIVATE_HDRS})
 254 configure_sources (GFLAGS_SRCS  ${GFLAGS_SRCS})
 255
 256 include_directories ("${PROJECT_SOURCE_DIR}/src")
 257 include_directories ("${PROJECT_BINARY_DIR}/include")
 258 include_directories ("${PROJECT_BINARY_DIR}/include/${GFLAGS_INCLUDE_DIR}")
 259
 260 # ----------------------------------------------------------------------------
 261 # output directories
 262 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "bin")
 263 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "lib")
 264 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "lib")
 265
 266 # ----------------------------------------------------------------------------
 267 # add library targets
 268 set (TARGETS)
 269 # static vs. shared
 270 foreach (TYPE IN ITEMS STATIC SHARED)
 271   if (BUILD_${TYPE}_LIBS)
 272     # whether or not targets are a DLL
 273     if (OS_WINDOWS AND "^${TYPE}$" STREQUAL "^SHARED$")
 274       set (GFLAGS_IS_A_DLL 1)
 275     else ()
 276       set (GFLAGS_IS_A_DLL 0)
 277     endif ()
 278     string (TOLOWER "${TYPE}" type)
 279     # multi-threaded vs. single-threaded
 280     foreach (opts IN ITEMS "" _nothreads)
 281       if (BUILD_gflags${opts}_LIB)
 282         add_library (gflags${opts}-${type} ${TYPE} ${GFLAGS_SRCS} ${PRIVATE_HDRS} ${PUBLIC_HDRS})
 283         if (opts MATCHES "nothreads")
 284           set (defines "GFLAGS_IS_A_DLL=${GFLAGS_IS_A_DLL};NOTHREADS")
 285         else ()
 286           set (defines "GFLAGS_IS_A_DLL=${GFLAGS_IS_A_DLL}")
 287           if (CMAKE_USE_PTHREADS_INIT)
 288             target_link_libraries (gflags${opts}-${type} ${CMAKE_THREAD_LIBS_INIT})
 289           endif ()
 290         endif ()
 291         set_target_properties (
 292           gflags${opts}-${type} PROPERTIES COMPILE_DEFINITIONS "${defines}"
 293                                            OUTPUT_NAME         "gflags${opts}"
 294                                            VERSION             "${PACKAGE_VERSION}"
 295                                            SOVERSION           "${PACKAGE_SOVERSION}"
 296         )
 297         if (HAVE_SHLWAPI_H)
 298           target_link_libraries (gflags${opts}-${type} shlwapi.lib)
 299         endif ()
 300         if (NOT TARGET gflags${opts})
 301           add_custom_target (gflags${opts})
 302         endif ()
 303         add_dependencies (gflags${opts} gflags${opts}-${type})
 304         list (APPEND TARGETS gflags${opts}-${type})
 305       endif ()
 306     endforeach ()
 307   endif ()
 308 endforeach ()
 309
 310 # ----------------------------------------------------------------------------
 311 # installation
 312 if (OS_WINDOWS)
 313   set (RUNTIME_INSTALL_DIR Bin)
 314   set (LIBRARY_INSTALL_DIR Lib)
 315   set (INCLUDE_INSTALL_DIR Include)
 316   set (CONFIG_INSTALL_DIR  CMake)
 317 else ()
 318   set (RUNTIME_INSTALL_DIR bin)
 319   # The LIB_INSTALL_DIR and LIB_SUFFIX variables are used by the Fedora
 320   # package maintainers. Also package maintainers of other distribution
 321   # packages need to be able to specify the name of the library directory.
 322   if (NOT LIB_INSTALL_DIR)
 323     set (LIB_INSTALL_DIR "lib${LIB_SUFFIX}")
 324   endif ()
 325   set (LIBRARY_INSTALL_DIR "${LIB_INSTALL_DIR}"
 326     CACHE PATH "Directory of installed libraries, e.g., \"lib64\""
 327   )
 328   mark_as_advanced (LIBRARY_INSTALL_DIR)
 329   set (INCLUDE_INSTALL_DIR include)
 330   set (CONFIG_INSTALL_DIR  ${LIBRARY_INSTALL_DIR}/cmake/${PACKAGE_NAME})
 331 endif ()
 332
 333 file (RELATIVE_PATH INSTALL_PREFIX_REL2CONFIG_DIR "${CMAKE_INSTALL_PREFIX}/${CONFIG_INSTALL_DIR}" "${CMAKE_INSTALL_PREFIX}")
 334 configure_file (cmake/config.cmake.in  "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake" @ONLY)
 335 configure_file (cmake/version.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake" @ONLY)
 336
 337 install (TARGETS ${TARGETS} DESTINATION ${LIBRARY_INSTALL_DIR} EXPORT gflags-lib)
 338 if (INSTALL_HEADERS)
 339   install (FILES ${PUBLIC_HDRS} DESTINATION ${INCLUDE_INSTALL_DIR}/${GFLAGS_INCLUDE_DIR})
 340   install (
 341     FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake"
 342     RENAME ${PACKAGE_NAME}-config.cmake
 343     DESTINATION ${CONFIG_INSTALL_DIR}
 344   )
 345   install (
 346     FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake"
 347     DESTINATION ${CONFIG_INSTALL_DIR}
 348   )
 349   install (EXPORT gflags-lib DESTINATION ${CONFIG_INSTALL_DIR} FILE ${PACKAGE_NAME}-export.cmake)
 350   if (UNIX)
 351     install (PROGRAMS src/gflags_completions.sh DESTINATION ${RUNTIME_INSTALL_DIR})
 352   endif ()
 353 endif ()
 354
 355 # ----------------------------------------------------------------------------
 356 # support direct use of build tree
 357 set (INSTALL_PREFIX_REL2CONFIG_DIR .)
 358 export (TARGETS ${TARGETS} FILE "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-export.cmake")
 359 export (PACKAGE gflags)
 360 configure_file (cmake/config.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config.cmake" @ONLY)
 361
 362 # ----------------------------------------------------------------------------
 363 # testing - MUST follow the generation of the build tree config file
 364 if (BUILD_TESTING)
 365   include (CTest)
 366   enable_testing ()
 367   add_subdirectory (test)
 368 endif ()
 369
 370 # ----------------------------------------------------------------------------
 371 # packaging
 372 if (BUILD_PACKAGING)
 373
 374   if (NOT BUILD_SHARED_LIBS AND NOT INSTALL_HEADERS)
 375     message (WARNING "Package will contain static libraries without headers!"
 376                      "\nRecommended options for generation of runtime package:"
 377                      "\n  BUILD_SHARED_LIBS=ON"
 378                      "\n  BUILD_STATIC_LIBS=OFF"
 379                      "\n  INSTALL_HEADERS=OFF"
 380                      "\nRecommended options for generation of development package:"
 381                      "\n  BUILD_SHARED_LIBS=ON"
 382                      "\n  BUILD_STATIC_LIBS=ON"
 383                      "\n  INSTALL_HEADERS=ON")
 384   endif ()
 385
 386   # default package generators
 387   if (APPLE)
 388     set (PACKAGE_GENERATOR        "PackageMaker")
 389     set (PACKAGE_SOURCE_GENERATOR "TGZ;ZIP")
 390   elseif (UNIX)
 391     set (PACKAGE_GENERATOR        "DEB;RPM")
 392     set (PACKAGE_SOURCE_GENERATOR "TGZ;ZIP")
 393   else ()
 394     set (PACKAGE_GENERATOR        "ZIP")
 395     set (PACKAGE_SOURCE_GENERATOR "ZIP")
 396   endif ()
 397
 398   # used package generators
 399   set (CPACK_GENERATOR        "${PACKAGE_GENERATOR}"        CACHE STRING "List of binary package generators (CPack).")
 400   set (CPACK_SOURCE_GENERATOR "${PACKAGE_SOURCE_GENERATOR}" CACHE STRING "List of source package generators (CPack).")
 401   mark_as_advanced (CPACK_GENERATOR CPACK_SOURCE_GENERATOR)
 402
 403   # common package information
 404   set (CPACK_PACKAGE_VENDOR              "Andreas Schuh")
 405   set (CPACK_PACKAGE_CONTACT             "google-gflags@googlegroups.com")
 406   set (CPACK_PACKAGE_NAME                "${PACKAGE_NAME}")
 407   set (CPACK_PACKAGE_VERSION             "${PACKAGE_VERSION}")
 408   set (CPACK_PACKAGE_VERSION_MAJOR       "${PACKAGE_VERSION_MAJOR}")
 409   set (CPACK_PACKAGE_VERSION_MINOR       "${PACKAGE_VERSION_MINOR}")
 410   set (CPACK_PACKAGE_VERSION_PATCH       "${PACKAGE_VERSION_PATCH}")
 411   set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "A commandline flags library that allows for distributed flags.")
 412   set (CPACK_RESOURCE_FILE_WELCOME       "${CMAKE_CURRENT_LIST_DIR}/README.txt")
 413   set (CPACK_RESOURCE_FILE_LICENSE       "${CMAKE_CURRENT_LIST_DIR}/COPYING.txt")
 414   set (CPACK_PACKAGE_DESCRIPTION_FILE    "${CMAKE_CURRENT_LIST_DIR}/README.txt")
 415   set (CPACK_INSTALL_PREFIX              "${CMAKE_INSTALL_PREFIX}")
 416   set (CPACK_OUTPUT_FILE_PREFIX          packages)
 417   set (CPACK_PACKAGE_RELOCATABLE         TRUE)
 418   set (CPACK_MONOLITHIC_INSTALL          TRUE)
 419
 420   # RPM package information -- used in cmake/package.cmake.in also for DEB
 421   set (CPACK_RPM_PACKAGE_GROUP   "Development/Libraries")
 422   set (CPACK_RPM_PACKAGE_LICENSE "BSD")
 423   set (CPACK_RPM_PACKAGE_URL     "http://code.google.com/p/gflags")
 424   set (CPACK_RPM_CHANGELOG_FILE  "${CMAKE_CURRENT_LIST_DIR}/ChangeLog.txt")
 425
 426   if (INSTALL_HEADERS)
 427     set (CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_LIST_DIR}/doc/gflags.html")
 428   else ()
 429     set (CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_LIST_DIR}/cmake/README_runtime.txt")
 430   endif ()
 431
 432   # system/architecture
 433   if (WINDOWS)
 434     if (CMAKE_CL_64)
 435       set (CPACK_SYSTEM_NAME "win64")
 436     else ()
 437       set (CPACK_SYSTEM_NAME "win32")
 438     endif ()
 439     set (CPACK_PACKAGE_ARCHITECTURE)
 440   elseif (APPLE)
 441     set (CPACK_PACKAGE_ARCHITECTURE darwin)
 442   else ()
 443     string (TOLOWER "${CMAKE_SYSTEM_NAME}" CPACK_SYSTEM_NAME)
 444     if (CMAKE_CXX_FLAGS MATCHES "-m32")
 445       set (CPACK_PACKAGE_ARCHITECTURE i386)
 446     else ()
 447       execute_process (
 448         COMMAND         dpkg --print-architecture
 449         RESULT_VARIABLE RV
 450         OUTPUT_VARIABLE CPACK_PACKAGE_ARCHITECTURE
 451       )
 452       if (RV EQUAL 0)
 453               string (STRIP "${CPACK_PACKAGE_ARCHITECTURE}" CPACK_PACKAGE_ARCHITECTURE)
 454       else ()
 455         execute_process (COMMAND uname -m OUTPUT_VARIABLE CPACK_PACKAGE_ARCHITECTURE)
 456         if (CPACK_PACKAGE_ARCHITECTURE MATCHES "x86_64")
 457                 set (CPACK_PACKAGE_ARCHITECTURE amd64)
 458         else ()
 459           set (CPACK_PACKAGE_ARCHITECTURE i386)
 460         endif ()
 461       endif ()
 462     endif ()
 463   endif ()
 464
 465   # source package settings
 466   set (CPACK_SOURCE_TOPLEVEL_TAG      "source")
 467   set (CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 468   set (CPACK_SOURCE_IGNORE_FILES      "/\\\\.git/;\\\\.swp$;\\\\.#;/#;\\\\.*~;cscope\\\\.*;/[Bb]uild[.+-_a-zA-Z0-9]*/")
 469
 470   # default binary package settings
 471   set (CPACK_INCLUDE_TOPLEVEL_DIRECTORY TRUE)
 472   set (CPACK_PACKAGE_FILE_NAME          "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_SYSTEM_NAME}")
 473   if (CPACK_PACKAGE_ARCHITECTURE)
 474     set (CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_FILE_NAME}-${CPACK_PACKAGE_ARCHITECTURE}")
 475   endif ()
 476
 477   # generator specific configuration file
 478   #
 479   # allow package maintainers to use their own configuration file
 480   # $ cmake -DCPACK_PROJECT_CONFIG_FILE:FILE=/path/to/package/config
 481   if (NOT CPACK_PROJECT_CONFIG_FILE)
 482     configure_file (
 483       "${CMAKE_CURRENT_LIST_DIR}/cmake/package.cmake.in"
 484       "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-package.cmake" @ONLY
 485     )
 486     set (CPACK_PROJECT_CONFIG_FILE "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-package.cmake")
 487   endif ()
 488
 489   include (CPack)
 490
 491 endif () # BUILD_PACKAGING