gettext-tools/gnulib-m4/sched_h.m4

   1 # sched_h.m4 serial 7
   2 dnl Copyright (C) 2008-2015 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Bruno Haible.
   8
   9 AC_DEFUN([gl_SCHED_H],
  10 [
  11   AC_COMPILE_IFELSE(
  12     [AC_LANG_PROGRAM([[
  13        #include <sched.h>
  14        struct sched_param a;
  15        int b[] = { SCHED_FIFO, SCHED_RR, SCHED_OTHER };
  16        pid_t t1;
  17      ]])],
  18     [SCHED_H=''],
  19     [SCHED_H='sched.h'
  20
  21      gl_CHECK_NEXT_HEADERS([sched.h])
  22
  23      if test $ac_cv_header_sched_h = yes; then
  24        HAVE_SCHED_H=1
  25      else
  26        HAVE_SCHED_H=0
  27      fi
  28      AC_SUBST([HAVE_SCHED_H])
  29
  30      if test "$HAVE_SCHED_H" = 1; then
  31        AC_CHECK_TYPE([struct sched_param],
  32          [HAVE_STRUCT_SCHED_PARAM=1], [HAVE_STRUCT_SCHED_PARAM=0],
  33          [#include <sched.h>])
  34      else
  35        dnl On OS/2 kLIBC, struct sched_param is in spawn.h.
  36        AC_CHECK_TYPE([struct sched_param],
  37          [HAVE_STRUCT_SCHED_PARAM=1], [HAVE_STRUCT_SCHED_PARAM=0],
  38          [#include <spawn.h>])
  39      fi
  40      AC_SUBST([HAVE_STRUCT_SCHED_PARAM])
  41
  42      dnl Ensure the type pid_t gets defined.
  43      AC_REQUIRE([AC_TYPE_PID_T])
  44     ])
  45   AC_SUBST([SCHED_H])
  46   AM_CONDITIONAL([GL_GENERATE_SCHED_H], [test -n "$SCHED_H"])
  47 ])