gettext-tools/gnulib-m4/fopen.m4

   1 # fopen.m4 serial 5
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FOPEN],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST])
  11   case "$host_os" in
  12     mingw* | pw*)
  13       dnl Replace fopen, for handling of "/dev/null".
  14       REPLACE_FOPEN=1
  15       dnl fopen on mingw also has the trailing slash bug.
  16       gl_cv_func_fopen_slash="guessing no"
  17       ;;
  18     *)
  19       dnl fopen("foo/", "w") should not create a file when the file name has a
  20       dnl trailing slash.
  21       AC_CACHE_CHECK([whether fopen recognizes a trailing slash],
  22         [gl_cv_func_fopen_slash],
  23         [
  24           AC_TRY_RUN([
  25 #include <stddef.h>
  26 #include <stdio.h>
  27 int main ()
  28 {
  29   return fopen ("conftest.sl/", "w") != NULL;
  30 }], [gl_cv_func_fopen_slash=yes], [gl_cv_func_fopen_slash=no],
  31             [
  32 changequote(,)dnl
  33              case "$host_os" in
  34                solaris2.[0-9]*) gl_cv_func_fopen_slash="guessing no" ;;
  35                hpux*)           gl_cv_func_fopen_slash="guessing no" ;;
  36                *)               gl_cv_func_fopen_slash="guessing yes" ;;
  37              esac
  38 changequote([,])dnl
  39             ])
  40           rm -f conftest.sl
  41         ])
  42       ;;
  43   esac
  44   case "$gl_cv_func_fopen_slash" in
  45     *no)
  46       AC_DEFINE([FOPEN_TRAILING_SLASH_BUG], [1],
  47         [Define to 1 if fopen() fails to recognize a trailing slash.])
  48       REPLACE_FOPEN=1
  49       ;;
  50   esac
  51   if test $REPLACE_FOPEN = 1; then
  52     AC_LIBOBJ([fopen])
  53     gl_PREREQ_FOPEN
  54   fi
  55 ])
  56
  57 # Prerequisites of lib/fopen.c.
  58 AC_DEFUN([gl_PREREQ_FOPEN],
  59 [
  60   AC_REQUIRE([AC_C_INLINE])
  61 ])