gettext-runtime/gnulib-m4/signalblocking.m4

   1 # signalblocking.m4 serial 10
   2 dnl Copyright (C) 2001-2002, 2006-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # Determine available signal blocking primitives. Three different APIs exist:
   8 # 1) POSIX: sigemptyset, sigaddset, sigprocmask
   9 # 2) SYSV: sighold, sigrelse
  10 # 3) BSD: sigblock, sigsetmask
  11 # For simplicity, here we check only for the POSIX signal blocking.
  12 AC_DEFUN([gl_SIGNALBLOCKING],
  13 [
  14   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  15   signals_not_posix=
  16   AC_EGREP_HEADER([sigset_t], [signal.h], , [signals_not_posix=1])
  17   if test -z "$signals_not_posix"; then
  18     AC_CHECK_FUNC([sigprocmask], [gl_cv_func_sigprocmask=1])
  19   fi
  20   if test -z "$gl_cv_func_sigprocmask"; then
  21     HAVE_POSIX_SIGNALBLOCKING=0
  22     AC_LIBOBJ([sigprocmask])
  23     gl_PREREQ_SIGPROCMASK
  24   fi
  25 ])
  26
  27 # Prerequisites of the part of lib/signal.in.h and of lib/sigprocmask.c.
  28 AC_DEFUN([gl_PREREQ_SIGPROCMASK],
  29 [
  30   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  31   AC_CHECK_TYPES([sigset_t],
  32     [gl_cv_type_sigset_t=yes], [gl_cv_type_sigset_t=no],
  33     [#include <signal.h>
  34 /* Mingw defines sigset_t not in <signal.h>, but in <sys/types.h>.  */
  35 #include <sys/types.h>])
  36   if test $gl_cv_type_sigset_t != yes; then
  37     HAVE_SIGSET_T=0
  38   fi
  39   dnl HAVE_SIGSET_T is 1 if the system lacks the sigprocmask function but has
  40   dnl the sigset_t type.
  41   AC_SUBST([HAVE_SIGSET_T])
  42 ])