configure.ac

   1 ##                                               -*- Autoconf -*-
   2 ## Process this file with autoconf to produce a configure script.
   3 ## Use autoupdate to update this file for newer versions of autoconf.
   4 ## Use autoscan to check if you need to add something to this file.
   5 ##############################################################################
   6 ## $Id: configure.ac,v 1.29 2011-01-21 22:49:59 behdad Exp $
   7 ## $Auther: behdad $
   8 ## $Date: 2011-01-21 22:49:59 $
   9 ## $Revision: 1.29 $
  10 ## $Source: /home/behdad/src/fdo/fribidi/togit/git/../fribidi/fribidi2/configure.ac,v $
  11 ##############################################################################
  12
  13 AC_PREREQ([2.64])
  14
  15 dnl Define different version variables.
  16 dnl
  17 dnl Making releases:
  18 dnl   FRIBIDI_MICRO_VERSION++;
  19 dnl   FRIBIDI_INTERFACE_AGE++;
  20 dnl
  21 dnl If any functions have been added:
  22 dnl   FRIBIDI_INTERFACE_AGE = 0;
  23 dnl   FRIBIDI_INTERFACE_VERSION++;
  24 dnl   FRIBIDI_BINARY_AGE++;
  25 dnl
  26 dnl If binary backwards compatibility has been broken:
  27 dnl   FRIBIDI_BINARY_AGE = FRIBIDI_INTERFACE_AGE = 0;
  28 dnl
  29 m4_define(fribidi_major_version, 0)dnl
  30 m4_define(fribidi_minor_version, 19)dnl
  31 m4_define(fribidi_micro_version, 7)dnl
  32 m4_define(fribidi_interface_version, 3)dnl
  33 m4_define(fribidi_interface_age, 6)dnl
  34 m4_define(fribidi_binary_age, 3)dnl
  35 dnl
  36 m4_define(fribidi_version,
  37           m4_if(m4_eval(fribidi_micro_version()),0,
  38             fribidi_major_version.fribidi_minor_version,
  39             fribidi_major_version.fribidi_minor_version.fribidi_micro_version))dnl
  40
  41 AC_INIT([GNU FriBidi],
  42         fribidi_version(),
  43         [http://bugs.freedesktop.org/enter_bug.cgi?product=fribidi],
  44         [fribidi],
  45         [http://fribidi.org/])
  46
  47 AC_CONFIG_SRCDIR([fribidi.pc.in])
  48 AC_CONFIG_HEADERS([config.h])
  49 AC_CONFIG_MACRO_DIRS([m4])
  50
  51 AM_INIT_AUTOMAKE([1.11.1 gnits dist-bzip2 no-dist-gzip -Wall no-define])
  52 AM_SILENT_RULES([yes])
  53
  54 AM_PROG_AR
  55
  56 # Initialize libtool
  57 LT_PREREQ([2.2])
  58 LT_INIT([disable-static])
  59
  60 FRIBIDI_MAJOR_VERSION=fribidi_major_version()
  61 FRIBIDI_MINOR_VERSION=fribidi_minor_version()
  62 FRIBIDI_MICRO_VERSION=fribidi_micro_version()
  63 FRIBIDI_VERSION=fribidi_version()
  64 FRIBIDI_INTERFACE_VERSION=fribidi_interface_version()
  65 FRIBIDI_INTERFACE_AGE=fribidi_interface_age()
  66 FRIBIDI_BINARY_AGE=fribidi_binary_age()
  67
  68 AC_SUBST(FRIBIDI_MAJOR_VERSION)
  69 AC_SUBST(FRIBIDI_MINOR_VERSION)
  70 AC_SUBST(FRIBIDI_MICRO_VERSION)
  71 AC_SUBST(FRIBIDI_VERSION)
  72 AC_SUBST(FRIBIDI_INTERFACE_VERSION)
  73 AC_SUBST(FRIBIDI_INTERFACE_AGE)
  74 AC_SUBST(FRIBIDI_BINARY_AGE)
  75
  76 dnl libtool versioning.
  77 m4_define(lt_current, fribidi_interface_version())dnl
  78 m4_define(lt_revision, fribidi_interface_age())dnl
  79 m4_define(lt_age, fribidi_binary_age())dnl
  80 LT_VERSION_INFO=lt_current():lt_revision():lt_age()
  81 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
  82
  83 AC_SUBST(LT_VERSION_INFO)
  84 AC_SUBST(LT_CURRENT_MINUS_AGE)
  85
  86 dnl ==========================================================================
  87
  88 # Checks for programs.
  89 AC_PROG_CC
  90 AC_PROG_INSTALL
  91 PKG_PROG_PKG_CONFIG
  92 AC_MSG_CHECKING([for native Win32])
  93   case $build_os in
  94     mingw*) os_win32=yes ;;
  95     *) os_win32=no ;;
  96   esac
  97 AC_MSG_RESULT([$os_win32])
  98 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  99 AC_MSG_CHECKING([for some Win32 platform])
 100   case $build_os in
 101     mingw*|cygwin*) platform_win32=yes ;;
 102     *) platform_win32=no ;;
 103   esac
 104 AC_MSG_RESULT([$platform_win32])
 105 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 106
 107
 108 # Checks for header files.
 109 AC_HEADER_STDC
 110 AC_CHECK_HEADERS([stdlib.h string.h strings.h inttypes.h wchar.h asm/page.h sys/times.h])
 111
 112 # Checks for typedefs and structures.
 113 AC_C_CONST
 114 AC_C_STRINGIZE
 115 AC_CHECK_SIZEOF(int)
 116 SIZEOF_INT=$ac_cv_sizeof_int
 117 AC_SUBST(SIZEOF_INT)
 118 AC_CHECK_SIZEOF(short)
 119 AC_CHECK_SIZEOF(void *)
 120 AC_CHECK_SIZEOF(wchar_t)
 121
 122 # Checks for compiler characteristics.
 123 changequote(,)dnl
 124 if test "x$GCC" = "xyes"; then
 125   CFLAGS="$CFLAGS -Wall -ansi "
 126 fi
 127 changequote([,])dnl
 128
 129 # Checks for library functions.
 130 AC_CHECK_FUNCS([memmove memset strdup])
 131 AC_TYPE_SIGNAL
 132
 133 # Checks for configure options
 134
 135 # --enable-debug
 136 m4_define(debug_default,
 137           m4_if(m4_eval(fribidi_minor_version() % 2),1,yes,no))
 138 AC_ARG_ENABLE(debug,
 139               AC_HELP_STRING([--enable-debug],
 140                              [turn on debugging @<:@default=debug_default()@:>@]),,
 141               enable_debug=debug_default())
 142 if test x$enable_debug = xyes; then
 143         AC_DEFINE(DEBUG,1,
 144                   [Define to 1 if you want to include debug code in the library])
 145 fi
 146
 147 # --disable-deprecated
 148 AC_ARG_ENABLE(deprecated,
 149               AC_HELP_STRING([--disable-deprecated],
 150                              [do not build deprecated functionality]))
 151 if test x$enable_deprecated = xno; then
 152         FRIBIDI_NO_DEPRECATED=1
 153 else
 154         FRIBIDI_NO_DEPRECATED=0
 155 fi
 156 AC_SUBST(FRIBIDI_NO_DEPRECATED)
 157
 158 AC_DEFINE(USE_SIMPLE_MALLOC,1,
 159           [Define to 1 if you want to use simple mallocs instead of memory chunks])
 160
 161 # --disable-charsets
 162 AC_ARG_ENABLE(charsets,
 163               AC_HELP_STRING([--disable-charsets],
 164                              [exclude charset conversion routines from library]))
 165 if test x$enable_charsets = xno; then
 166         FRIBIDI_CHARSETS=0
 167 else
 168         FRIBIDI_CHARSETS=1
 169 fi
 170 AC_SUBST(FRIBIDI_CHARSETS)
 171 AM_CONDITIONAL(FRIBIDI_CHARSETS, test x$FRIBIDI_CHARSETS = x1)
 172
 173 # --with[out]-glib
 174 AC_ARG_WITH(glib,
 175               AC_HELP_STRING([--with-glib=@<:@no/auto/yes@:>@],
 176                              [use Glib @<:@default=auto@:>@]))
 177 GLIB_PACKAGE=glib-2.0
 178 GLIB_MINVERSION=2.4
 179 GLIB_LIBS=
 180 GLIB_CFLAGS=
 181 if test x$with_glib = xyes; then
 182         PKG_CHECK_MODULES(GLIB,$GLIB_PACKAGE >= $GLIB_MINVERSION)
 183         FRIBIDI_USE_GLIB=1
 184 else
 185 if test x$with_glib = xno; then
 186         FRIBIDI_USE_GLIB=0
 187 else
 188         PKG_CHECK_MODULES(GLIB,$GLIB_PACKAGE >= $GLIB_MINVERSION,
 189                 FRIBIDI_USE_GLIB=1,
 190                 FRIBIDI_USE_GLIB=0)
 191 fi
 192 fi
 193 if test x$FRIBIDI_USE_GLIB = x0; then
 194         GLIB_PACKAGE=
 195 fi
 196 AC_SUBST(FRIBIDI_USE_GLIB)
 197 AM_CONDITIONAL(FRIBIDI_USE_GLIB, test x$FRIBIDI_USE_GLIB = x1)
 198
 199
 200 MISC_CFLAGS="$GLIB_CFLAGS"
 201 MISC_LIBS="$GLIB_LIBS"
 202 MISC_PACKAGES="$GLIB_PACKAGE"
 203 AC_SUBST(MISC_CFLAGS)
 204 AC_SUBST(MISC_LIBS)
 205 AC_SUBST(MISC_PACKAGES)
 206
 207 # Generate output
 208 AC_CONFIG_FILES([fribidi.pc
 209                  lib/fribidi-config.h
 210                  Makefile
 211                  charset/Makefile
 212                  gen.tab/Makefile
 213                  lib/Makefile
 214                  bin/Makefile
 215                  doc/Makefile
 216                  test/Makefile])
 217 AC_OUTPUT