configure.ac

   1 dnl   configuration script for expat
   2 dnl   Process this file with autoconf to produce a configure script.
   3 dnl
   4 dnl   Copyright 2000 Clark Cooper
   5 dnl
   6 dnl   This file is part of EXPAT.
   7 dnl
   8 dnl   EXPAT is free software; you can redistribute it and/or modify it
   9 dnl   under the terms of the License (based on the MIT/X license) contained
  10 dnl   in the file COPYING that comes with this distribution.
  11 dnl
  12
  13 dnl Ensure that Expat is configured with autoconf 2.58 or newer
  14 AC_PREREQ(2.58)
  15
  16 dnl Get the version number of Expat, using m4's esyscmd() command to run
  17 dnl the command at m4-generation time. This allows us to create an m4
  18 dnl symbol holding the correct version number. AC_INIT() requires the
  19 dnl version number at m4-time, rather than when ./configure is run, so
  20 dnl all this must happen as part of m4, not as part of the shell code
  21 dnl contained in ./configure.
  22 dnl
  23 dnl NOTE: esyscmd() is a GNU M4 extension. Thus, we wrap it in an appropriate
  24 dnl test. I believe this test will work, but I don't have a place with non-
  25 dnl GNU M4 to test it right now.
  26 define([expat_version], ifdef([__gnu__],
  27                               [esyscmd(conftools/get-version.sh lib/expat.h)],
  28                               [2.1.x]))
  29 AC_INIT(expat, expat_version, expat-bugs@libexpat.org)
  30 undefine([expat_version])
  31
  32 AC_CONFIG_SRCDIR(Makefile.in)
  33 AC_CONFIG_AUX_DIR(conftools)
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36
  37 dnl
  38 dnl Increment LIBREVISION if source code has changed at all
  39 dnl
  40 dnl If the API has changed, increment LIBCURRENT and set LIBREVISION to 0
  41 dnl
  42 dnl If the API changes compatibly (i.e. simply adding a new function
  43 dnl without changing or removing earlier interfaces), then increment LIBAGE.
  44 dnl
  45 dnl If the API changes incompatibly set LIBAGE back to 0
  46 dnl
  47
  48 LIBCURRENT=7
  49 LIBREVISION=0
  50 LIBAGE=6
  51
  52 AC_CONFIG_HEADER(expat_config.h)
  53
  54 sinclude(conftools/ac_c_bigendian_cross.m4)
  55
  56 sinclude(conftools/visibility.m4)
  57
  58 AC_SUBST(LIBCURRENT)
  59 AC_SUBST(LIBREVISION)
  60 AC_SUBST(LIBAGE)
  61
  62 dnl Checks for programs.
  63 AC_PROG_CC_STDC
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_SYS_LARGEFILE
  66 gl_VISIBILITY
  67 AC_LIBTOOL_WIN32_DLL
  68 AC_PROG_LIBTOOL
  69 AC_PROG_CXX
  70 AC_PROG_INSTALL
  71
  72 if test "$GCC" = yes ; then
  73     dnl
  74     dnl Be careful about adding the -fexceptions option; some versions of
  75     dnl GCC don't support it and it causes extra warnings that are only
  76     dnl distracting; avoid.
  77     dnl
  78     OLDCFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wstrict-prototypes"
  79     CFLAGS="$OLDCFLAGS -fexceptions"
  80     AC_MSG_CHECKING(whether $CC accepts -fexceptions)
  81     AC_TRY_LINK( , ,
  82                    AC_MSG_RESULT(yes),
  83                    AC_MSG_RESULT(no); CFLAGS="$OLDCFLAGS")
  84     CXXFLAGS=`echo "$CFLAGS" | sed 's/ -Wmissing-prototypes -Wstrict-prototypes//'`
  85 fi
  86
  87 dnl Checks for header files.
  88 AC_HEADER_STDC
  89
  90 dnl Checks for typedefs, structures, and compiler characteristics.
  91
  92 dnl Note: Avoid using AC_C_BIGENDIAN because it does not
  93 dnl work in a cross compile.
  94 AC_C_BIGENDIAN_CROSS
  95
  96 AC_C_CONST
  97 AC_TYPE_SIZE_T
  98 AC_CHECK_FUNCS(memmove bcopy)
  99
 100 dnl Only needed for xmlwf:
 101 AC_CHECK_HEADERS(fcntl.h unistd.h)
 102 AC_TYPE_OFF_T
 103 AC_FUNC_MMAP
 104
 105 if test "$ac_cv_func_mmap_fixed_mapped" = "yes"; then
 106     FILEMAP=unixfilemap
 107 else
 108     FILEMAP=readfilemap
 109 fi
 110 AC_SUBST(FILEMAP)
 111
 112 dnl Needed for the test support code; this was found at
 113 dnl http://lists.gnu.org/archive/html/bug-autoconf/2002-07/msg00028.html
 114
 115 # AC_CPP_FUNC
 116 # ------------------ #
 117 # Checks to see if ANSI C99 CPP variable __func__ works.
 118 # If not, perhaps __FUNCTION__ works instead.
 119 # If not, we'll just define __func__ to "".
 120 AC_DEFUN([AC_CPP_FUNC],
 121 [AC_REQUIRE([AC_PROG_CC_STDC])dnl
 122 AC_CACHE_CHECK([for an ANSI C99-conforming __func__], ac_cv_cpp_func,
 123 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
 124 [[char *foo = __func__;]])],
 125   [ac_cv_cpp_func=yes],
 126   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
 127 [[char *foo = __FUNCTION__;]])],
 128   [ac_cv_cpp_func=__FUNCTION__],
 129   [ac_cv_cpp_func=no])])])
 130 if test $ac_cv_cpp_func = __FUNCTION__; then
 131   AC_DEFINE(__func__,__FUNCTION__,
 132             [Define to __FUNCTION__ or "" if `__func__' does not conform to
 133 ANSI C.])
 134 elif test $ac_cv_cpp_func = no; then
 135   AC_DEFINE(__func__,"",
 136             [Define to __FUNCTION__ or "" if `__func__' does not conform to
 137 ANSI C.])
 138 fi
 139 ])# AC_CPP_FUNC
 140
 141 AC_CPP_FUNC
 142
 143
 144 dnl Some basic configuration:
 145 AC_DEFINE([XML_NS], 1,
 146           [Define to make XML Namespaces functionality available.])
 147 AC_DEFINE([XML_DTD], 1,
 148           [Define to make parameter entity parsing functionality available.])
 149 AC_DEFINE([XML_CONTEXT_BYTES], 1024,
 150           [Define to specify how much context to retain around the current parse point.])
 151
 152 AC_CONFIG_FILES([Makefile expat.pc])
 153 AC_OUTPUT
 154
 155 abs_srcdir="`cd $srcdir && pwd`"
 156 abs_builddir="`pwd`"
 157 if test "$abs_srcdir" != "$abs_builddir"; then
 158   make mkdir-init
 159 fi