configure.ac

   1
   2 dnl Evolution-Data-Server version
   3 m4_define([eds_major_version], [3])
   4 m4_define([eds_minor_version], [7])
   5 m4_define([eds_micro_version], [4])
   6
   7 m4_define([eds_version],
   8         [eds_major_version.eds_minor_version.eds_micro_version])
   9
  10 dnl Base Version: This is for API/version tracking for things like
  11 dnl Bonobo server files.  This should always be the major/minor of
  12 dnl the stable version or stable version to be.  Note, this is set
  13 dnl the way it is so that GETTEXT_PACKAGE will be parsed correctly.
  14 BASE_VERSION=3.8
  15 m4_define([base_version], [3.8])
  16
  17 dnl This number is meaningless, but we're now stuck with it in our
  18 dnl library names for backward compatibility.
  19 m4_define([api_version], [1.2])
  20
  21 dnl Autoconf / Automake Initialization
  22 AC_PREREQ(2.62)
  23 AC_INIT([evolution-data-server],[eds_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=Evolution-Data-Server])
  24 AM_INIT_AUTOMAKE([gnu 1.10 tar-ustar dist-xz no-dist-gzip -Wall -Wno-portability foreign])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CONFIG_SRCDIR(README)
  27 AC_CONFIG_HEADERS(config.h)
  28
  29 dnl This is for the autoconf tests only - it set's the language we use
  30 AC_LANG(C)
  31
  32 dnl Automake 1.11 - Silent Build Rules
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34
  35 dnl Required Package Versions
  36
  37 dnl Keep these two definitions in agreement.
  38 m4_define([glib_minimum_version], [2.34])
  39 m4_define([glib_encoded_version], [GLIB_VERSION_2_34])
  40
  41 dnl Keep these two definitions in agreement.
  42 m4_define([gdk_minimum_version], [3.2])
  43 m4_define([gdk_encoded_version], [GDK_VERSION_3_2])
  44
  45 dnl Keep these two definitions in agreement.
  46 m4_define([soup_minimum_version], [2.38.1])
  47 m4_define([soup_encoded_version], [SOUP_VERSION_2_38])
  48
  49 m4_define([gcr_minimum_version], [3.4])
  50 m4_define([libsecret_minimum_version], [0.5])
  51 m4_define([libxml_minimum_version], [2.0.0])            dnl XXX Just a Guess
  52 m4_define([libgdata_minimum_version], [0.10])
  53 m4_define([sqlite_minimum_version], [3.5])
  54 m4_define([libical_minimum_version], [0.43])
  55
  56 dnl Optional Packages
  57 m4_define([goa_minimum_version], [3.2])
  58 m4_define([gweather_minimum_version], [3.5.0])
  59
  60 AC_SUBST([BASE_VERSION],[base_version])
  61 AC_SUBST([API_VERSION],[api_version])
  62 AC_DEFINE_UNQUOTED(BASE_VERSION, ["$BASE_VERSION"], [Base version (Major.Minor)])
  63 AC_DEFINE_UNQUOTED(API_VERSION, ["$API_VERSION"], [API version (Major.Minor)])
  64
  65 EDS_MAJOR_VERSION=eds_major_version
  66 EDS_MINOR_VERSION=eds_minor_version
  67 EDS_MICRO_VERSION=eds_micro_version
  68
  69 GLIB_GSETTINGS
  70
  71 dnl ******************************
  72 dnl D-Bus versioning
  73 dnl ******************************
  74 ADDRESS_BOOK_DBUS_SERVICE_NAME="org.gnome.evolution.dataserver.AddressBook4"
  75 CALENDAR_DBUS_SERVICE_NAME="org.gnome.evolution.dataserver.Calendar3"
  76 SOURCES_DBUS_SERVICE_NAME="org.gnome.evolution.dataserver.Sources1"
  77 USER_PROMPTER_DBUS_SERVICE_NAME="org.gnome.evolution.dataserver.UserPrompter0"
  78
  79 AC_DEFINE_UNQUOTED(
  80        ADDRESS_BOOK_DBUS_SERVICE_NAME,
  81        ["$ADDRESS_BOOK_DBUS_SERVICE_NAME"],
  82        [D-Bus service name for the address book factory])
  83
  84 AC_DEFINE_UNQUOTED(
  85        CALENDAR_DBUS_SERVICE_NAME,
  86        ["$CALENDAR_DBUS_SERVICE_NAME"],
  87        [D-Bus service name for the calendar factory])
  88
  89 AC_DEFINE_UNQUOTED(
  90         SOURCES_DBUS_SERVICE_NAME,
  91         ["$SOURCES_DBUS_SERVICE_NAME"],
  92         [D-Bus service name for the source registry])
  93
  94 AC_DEFINE_UNQUOTED(
  95         USER_PROMPTER_DBUS_SERVICE_NAME,
  96         ["$USER_PROMPTER_DBUS_SERVICE_NAME"],
  97         [D-Bus service name for the user prompter])
  98
  99 AC_SUBST(ADDRESS_BOOK_DBUS_SERVICE_NAME)
 100 AC_SUBST(CALENDAR_DBUS_SERVICE_NAME)
 101 AC_SUBST(SOURCES_DBUS_SERVICE_NAME)
 102 AC_SUBST(USER_PROMPTER_DBUS_SERVICE_NAME)
 103
 104 dnl ******************************
 105 dnl Libtool versioning
 106 dnl ******************************
 107 LIBEDATASERVER_CURRENT=17
 108 LIBEDATASERVER_REVISION=0
 109 LIBEDATASERVER_AGE=0
 110
 111 LIBECAL_CURRENT=15
 112 LIBECAL_REVISION=0
 113 LIBECAL_AGE=0
 114
 115 LIBEDATACAL_CURRENT=20
 116 LIBEDATACAL_REVISION=0
 117 LIBEDATACAL_AGE=0
 118
 119 LIBEDATABOOK_CURRENT=16
 120 LIBEDATABOOK_REVISION=0
 121 LIBEDATABOOK_AGE=0
 122
 123 LIBEBOOK_CURRENT=17
 124 LIBEBOOK_REVISION=1
 125 LIBEBOOK_AGE=3
 126
 127 LIBCAMEL_CURRENT=43
 128 LIBCAMEL_REVISION=0
 129 LIBCAMEL_AGE=0
 130
 131 LIBEBACKEND_CURRENT=6
 132 LIBEBACKEND_REVISION=0
 133 LIBEBACKEND_AGE=0
 134
 135 AC_SUBST(EDS_MAJOR_VERSION)
 136 AC_SUBST(EDS_MINOR_VERSION)
 137 AC_SUBST(EDS_MICRO_VERSION)
 138 AC_SUBST(LIBEDATASERVER_CURRENT)
 139 AC_SUBST(LIBEDATASERVER_REVISION)
 140 AC_SUBST(LIBEDATASERVER_AGE)
 141 AC_SUBST(LIBECAL_CURRENT)
 142 AC_SUBST(LIBECAL_REVISION)
 143 AC_SUBST(LIBECAL_AGE)
 144 AC_SUBST(LIBEDATACAL_CURRENT)
 145 AC_SUBST(LIBEDATACAL_REVISION)
 146 AC_SUBST(LIBEDATACAL_AGE)
 147 AC_SUBST(LIBEBOOK_CURRENT)
 148 AC_SUBST(LIBEBOOK_REVISION)
 149 AC_SUBST(LIBEBOOK_AGE)
 150 AC_SUBST(LIBEDATABOOK_CURRENT)
 151 AC_SUBST(LIBEDATABOOK_REVISION)
 152 AC_SUBST(LIBEDATABOOK_AGE)
 153 AC_SUBST(LIBCAMEL_CURRENT)
 154 AC_SUBST(LIBCAMEL_REVISION)
 155 AC_SUBST(LIBCAMEL_AGE)
 156 AC_SUBST(LIBEBACKEND_CURRENT)
 157 AC_SUBST(LIBEBACKEND_REVISION)
 158 AC_SUBST(LIBEBACKEND_AGE)
 159
 160 dnl **************************************
 161 dnl Put the ACLOCAL flags in the Makefile
 162 dnl **************************************
 163 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 164
 165 dnl ******************************
 166 dnl Compiler Warning Flags
 167 dnl ******************************
 168 AS_COMPILER_FLAGS(WARNING_FLAGS,
 169         "-Wall -Wextra
 170         -Wdeprecated-declarations
 171         -Wno-missing-field-initializers
 172         -Wno-sign-compare
 173         -Wno-unused-parameter
 174         -Wdeclaration-after-statement
 175         -Werror-implicit-function-declaration
 176         -Wformat-security -Winit-self
 177         -Wmissing-declarations -Wmissing-include-dirs
 178         -Wmissing-noreturn -Wnested-externs -Wpointer-arith
 179         -Wredundant-decls -Wundef -Wwrite-strings")
 180 AC_SUBST(WARNING_FLAGS)
 181
 182 dnl Other useful compiler warnings for test builds only.
 183 dnl These may produce warnings we have no control over,
 184 dnl or false positives we don't always want to see.
 185 dnl
 186 dnl     -Wformat-nonliteral
 187 dnl     -Wmissing-format-attribute
 188 dnl     -Wshadow
 189 dnl     -Wstrict-aliasing=2
 190
 191 AM_CPPFLAGS="$WARNING_FLAGS -fno-strict-aliasing"
 192
 193 dnl *******************************
 194 dnl Check for --enable-strict
 195 dnl *******************************
 196 AC_ARG_ENABLE([strict],
 197         [AS_HELP_STRING([--enable-strict],
 198         [enable strict building, like without deprecated symbols (default=auto); auto enables strict building only if .git subdirectory exists])],
 199         [enable_strict=$enableval], [enable_strict=auto])
 200
 201 AC_MSG_CHECKING([if strict building is enabled])
 202 if test "x$enable_strict" = xauto; then
 203         dnl Be strict when compiling with .git subdirectory
 204         if test -d .git ; then
 205                 enable_strict=yes
 206         else
 207                 enable_strict=no
 208         fi
 209 fi
 210 AC_MSG_RESULT([$enable_strict])
 211
 212 if test "x$enable_strict" = xyes; then
 213         AM_CPPFLAGS="$AM_CPPFLAGS -DG_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"
 214 fi
 215
 216 dnl Warn about API usage that violates our minimum requirements.
 217 AM_CPPFLAGS="$AM_CPPFLAGS -DGLIB_VERSION_MAX_ALLOWED=glib_encoded_version"
 218 AM_CPPFLAGS="$AM_CPPFLAGS -DGDK_VERSION_MAX_ALLOWED=gdk_encoded_version"
 219 AM_CPPFLAGS="$AM_CPPFLAGS -DSOUP_VERSION_MAX_ALLOWED=soup_encoded_version"
 220
 221 dnl These will suppress warnings about newly-deprecated symbols.  Ideally
 222 dnl these settings should match our minimum requirements and we will clean
 223 dnl up any new deprecation warnings after bumping our minimum requirements.
 224 dnl But if the warnings get to be overwhelming, use fixed versions instead.
 225 AM_CPPFLAGS="$AM_CPPFLAGS -DGLIB_VERSION_MIN_REQUIRED=glib_encoded_version"
 226 AM_CPPFLAGS="$AM_CPPFLAGS -DGDK_VERSION_MIN_REQUIRED=gdk_encoded_version"
 227 AM_CPPFLAGS="$AM_CPPFLAGS -DSOUP_VERSION_MIN_REQUIRED=soup_encoded_version"
 228
 229 AC_SUBST(AM_CPPFLAGS)
 230
 231 dnl ******************************
 232 dnl Initialize maintainer mode
 233 dnl ******************************
 234 AM_MAINTAINER_MODE([enable])
 235
 236 if test "x$enable_maintainer_mode" = "xyes" ; then
 237         AC_DEFINE(ENABLE_MAINTAINER_MODE, 1, [Configured with enabled maintainer mode])
 238 fi
 239
 240 AC_PROG_CC
 241 AC_PROG_CPP
 242 AC_C_INLINE
 243 AM_PROG_CC_C_O
 244 AC_PROG_INSTALL
 245 AC_PROG_LN_S
 246 AC_PROG_MAKE_SET
 247
 248 dnl For gen-western-table.py
 249 AM_PATH_PYTHON
 250
 251 dnl GCC 4.4 got more aggressive in its aliasing optimizations, changing
 252 dnl behavior that -- according to the C99 standard -- is supposed to be
 253 dnl undefined.  We may still have aliasing abuses lying around that rely
 254 dnl on GCC's previous "undefined" behavior, so disable strict-aliasing
 255 dnl optimization until we can find and fix all the abuses.
 256 dnl (AC_PROG_CC must run first to set the GCC variable.)
 257 dnl XXX This really belongs in AM_CFLAGS.
 258 if test "x${GCC}" = "xyes"; then
 259         CFLAGS="$CFLAGS -fno-strict-aliasing"
 260 fi
 261
 262 dnl ******************************
 263 dnl I18N stuff
 264 dnl ******************************
 265 IT_PROG_INTLTOOL([0.35.5])
 266
 267 GETTEXT_PACKAGE=evolution-data-server-$BASE_VERSION
 268 AC_SUBST(GETTEXT_PACKAGE)
 269 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Package name for gettext])
 270
 271 localedir='$(prefix)/$(DATADIRNAME)/locale'
 272 AC_SUBST(localedir)
 273
 274 dnl ******************************
 275 dnl Initialize libtool
 276 dnl ******************************
 277 LT_PREREQ(2.2)
 278 LT_INIT(disable-static win32-dll)
 279
 280 PKG_PROG_PKG_CONFIG
 281
 282 dnl This relies on $SED, which is defined in ltmain.sh, which
 283 dnl is invoked by LT_INIT (at least I think that's how it works).
 284 GNOME_CODE_COVERAGE
 285
 286 dnl ******************************
 287 dnl Gtk Doc stuff
 288 dnl ******************************
 289 GTK_DOC_CHECK([1.14],[--flavour no-tmpl])
 290
 291 dnl The private D-Bus documentation is for developers only.
 292 AC_ARG_WITH([private-docs],
 293         AS_HELP_STRING([--with-private-docs],
 294         [Build documentation for private libraries ]
 295         [(requires --enable-gtk-doc) [default=no]],),
 296         [with_private_docs="$withval"],[with_private_docs="no"])
 297 AM_CONDITIONAL(WITH_PRIVATE_DOCS, [test x$with_private_docs = xyes])
 298
 299 dnl This must appear after AC_CANONICAL_HOST, which defines $host.
 300 case "$host" in
 301 *openbsd*|*freebsd*)
 302         dnl Do not set '-Wl,--no-undefined' on freebsd/openbsd
 303         ;;
 304 *)
 305         LDFLAGS="$LDFLAGS -Wl,--no-undefined"
 306         ;;
 307 esac
 308
 309 dnl ******************************
 310 dnl Check for Win32
 311 dnl ******************************
 312 AC_MSG_CHECKING([for Win32])
 313 case "$host" in
 314 *-mingw*)
 315         os_win32='yes'
 316         NO_UNDEFINED='-no-undefined'
 317         SOCKET_LIBS='-lws2_32 -ldnsapi'
 318         DL_LIB=''
 319         LIBEXECDIR_IN_SERVER_FILE='../../../libexec'
 320         AC_CACHE_VAL(ac_cv_have_addrinfo, [ac_cv_have_addrinfo=yes])
 321         AC_DEFINE(_WIN32_WINNT, 0x501, [To get getaddrinfo etc declarations])
 322         ;;
 323 *openbsd*|*freebsd*)
 324         os_win32='no'
 325         NO_UNDEFINED=''
 326         SOCKET_LIBS=''
 327         DL_LIB=''
 328         LIBEXECDIR_IN_SERVER_FILE="$libexecdir"
 329         ;;
 330 *)
 331         os_win32='no'
 332         NO_UNDEFINED=''
 333         SOCKET_LIBS=''
 334         DL_LIB='-ldl'
 335         LIBEXECDIR_IN_SERVER_FILE="$libexecdir"
 336         ;;
 337 esac
 338 AC_MSG_RESULT([$os_win32])
 339 AM_CONDITIONAL(OS_WIN32, [test $os_win32 = yes])
 340 AC_SUBST(NO_UNDEFINED)
 341 AC_SUBST(SOCKET_LIBS)
 342 AC_SUBST(LIBEXECDIR_IN_SERVER_FILE)
 343
 344 dnl **************************************
 345 dnl Check for posix compatible sys/wait.h
 346 dnl **************************************
 347 AC_HEADER_SYS_WAIT
 348
 349 dnl ************************************
 350 dnl Check for posix compatible alloca()
 351 dnl ************************************
 352 AC_FUNC_ALLOCA
 353
 354 dnl ******************************
 355 dnl Checks for functions
 356 dnl ******************************
 357 AC_CHECK_FUNCS(fsync strptime strtok_r nl_langinfo)
 358
 359 dnl ***********************************
 360 dnl Check for base dependencies early.
 361 dnl ***********************************
 362 PKG_CHECK_MODULES(GNOME_PLATFORM,
 363         [gio-2.0 >= glib_minimum_version
 364         gmodule-2.0 >= glib_minimum_version
 365         gtk+-3.0 >= gdk_minimum_version
 366         libxml-2.0 >= libxml_minimum_version
 367         libsoup-2.4 >= soup_minimum_version
 368         libgdata >= libgdata_minimum_version])
 369
 370 if test x$os_win32 = xno; then
 371         PKG_CHECK_MODULES(GIO_UNIX, [gio-unix-2.0])
 372 fi
 373
 374 dnl *******************************
 375 dnl Check for GNOME Online Accounts
 376 dnl *******************************
 377 AC_ARG_ENABLE([goa],
 378         [AS_HELP_STRING([--enable-goa],
 379         [enable GNOME Online Accounts support (default=yes)])],
 380         [enable_goa=$enableval], [enable_goa=yes])
 381 AC_MSG_CHECKING([if GNOME Online Accounts support is enabled])
 382 AC_MSG_RESULT([$enable_goa])
 383 if test "x$enable_goa" = xyes; then
 384         PKG_CHECK_MODULES([GOA], [goa-1.0 >= goa_minimum_version],,
 385         [AC_MSG_ERROR([
 386
 387         goa-1.0 not found (or version < goa_minimum_version)
 388
 389         If you want to disable GNOME Online Accounts support,
 390         please append --disable-goa to configure.
 391         ])])
 392
 393         AC_DEFINE(HAVE_GOA, 1, [Define to 1 if you have the goa-1.0 package.])
 394 fi
 395 AM_CONDITIONAL(HAVE_GOA, [test x$enable_goa = xyes])
 396
 397 dnl GoaPasswordBased was introduced in version 3.5.
 398 if `$PKG_CONFIG --atleast-version=3.5 goa-1.0`; then
 399         AC_DEFINE(HAVE_GOA_PASSWORD_BASED,1,[Have GoaPasswordBased in goa-1.0])
 400 fi
 401
 402 dnl ***********************************
 403 dnl Check for GNOME Keyring.
 404 dnl ***********************************
 405 if test x$os_win32 = xno; then
 406         PKG_CHECK_MODULES(LIBSECRET,
 407                 [libsecret-unstable >= libsecret_minimum_version])
 408 fi
 409 AC_SUBST(LIBSECRET_CFLAGS)
 410 AC_SUBST(LIBSECRET_LIBS)
 411
 412 dnl **********************************************************
 413 dnl gcr-base is needed for secure password exchange over D-Bus
 414 dnl **********************************************************
 415 PKG_CHECK_MODULES(GCR_BASE, [gcr-base-3 >= gcr_minimum_version])
 416 AC_SUBST(GCR_BASE_CFLAGS)
 417 AC_SUBST(GCR_BASE_LIBS)
 418
 419 LIBICAL_REQUIRED=libical_minimum_version
 420 AC_SUBST(LIBICAL_REQUIRED)
 421
 422 dnl ******************************
 423 dnl regex check
 424 dnl ******************************
 425 AC_CHECK_FUNCS(regexec,,[AC_CHECK_LIB(regex,regexec,
 426                         [REGEX_LIBS=-lregex
 427                         AC_DEFINE(HAVE_REGEXEC,1,[Define to 1 if you have the regexec function.])],
 428                         [AC_MSG_ERROR([No regex library found])])])
 429 AC_SUBST(REGEX_LIBS)
 430
 431 dnl ******************************
 432 dnl libdb checking
 433 dnl ******************************
 434 AC_ARG_WITH([libdb],
 435         AS_HELP_STRING([--with-libdb=PREFIX],
 436         [Prefix where libdb is installed]),
 437         [libdb_prefix="$withval"], [libdb_prefix='${prefix}'])
 438
 439 DB_CFLAGS="-I$libdb_prefix/include"
 440 DB_LIBS="-L$libdb_prefix/lib -ldb"
 441
 442 AC_MSG_CHECKING([Berkeley DB])
 443 save_cflags=$CFLAGS; CFLAGS=$DB_CFLAGS
 444 save_libs=$LIBS; LIBS="$DB_LIBS"
 445 AC_LINK_IFELSE([AC_LANG_PROGRAM(
 446         [[#include <db.h>]],
 447         [[db_create(NULL, NULL, 0)]])],
 448         [AC_MSG_RESULT([yes])],
 449         [AC_MSG_ERROR([Cannot find libdb])])
 450 CFLAGS=$save_cflags
 451 LIBS=$save_libs
 452 AC_SUBST(DB_CFLAGS)
 453 AC_SUBST(DB_LIBS)
 454
 455 dnl ******************************
 456 dnl iconv checking
 457 dnl ******************************
 458 have_iconv="no"
 459 save_LIBS="$LIBS"
 460 LIBS="$LIBS -liconv"
 461 AC_CACHE_CHECK([for iconv in -liconv], [ac_cv_libiconv],
 462         AC_LINK_IFELSE([AC_LANG_PROGRAM(
 463         [[
 464                 #include <iconv.h>
 465                 #include <stdlib.h>
 466         ]],
 467         [[
 468                 iconv_t cd;
 469                 cd = iconv_open ("UTF-8", "ISO-8859-1");
 470         ]]
 471         )],[ac_cv_libiconv=yes],[ac_cv_libiconv=no]))
 472
 473 if test "x$ac_cv_libiconv" = "xyes"; then
 474         ICONV_LIBS="-liconv"
 475         if test "x$os_win32" = "xyes"; then
 476                 dnl Don't pointlessly auto-export the global symbols
 477                 dnl from a potentially static libiconv.a
 478                 ICONV_LIBS="$ICONV_LIBS -Wl,--exclude-libs=libiconv.a"
 479         fi
 480         have_iconv="yes"
 481 else
 482         LIBS="$save_LIBS"
 483         AC_CHECK_FUNC(iconv, [have_iconv=yes], [have_iconv=no])
 484 fi
 485
 486 if test "x$have_iconv" = "xyes"; then
 487         if test "x$ac_cv_libiconv" = "xno"; then
 488                 AC_CHECK_FUNCS(gnu_get_libc_version)
 489         fi
 490 AC_CACHE_CHECK([if iconv() handles UTF-8], [ac_cv_libiconv_utf8],
 491         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 492                 #include <iconv.h>
 493                 #include <stdlib.h>
 494                 #include <string.h>
 495                 #ifdef HAVE_GNU_GET_LIBC_VERSION
 496                 #include <gnu/libc-version.h>
 497                 #endif
 498                 int main() {
 499                         char *jp = "\x1B\x24\x42\x46\x7C\x4B\x5C\x38\x6C";
 500                         char *utf8 = "\xE6\x97\xA5\xE6\x9C\xAC\xE8\xAA\x9E";
 501                         char *transbuf = malloc (10), *trans = transbuf;
 502                         iconv_t cd;
 503                         size_t jp_len = strlen (jp), utf8_len = 10;
 504                         size_t utf8_real_len = strlen (utf8);
 505
 506                         #ifdef HAVE_GNU_GET_LIBC_VERSION
 507                         /* glibc 2.1.2's iconv is broken in hard to test ways. */
 508                         if (!strcmp (gnu_get_libc_version (), "2.1.2"))
 509                                 exit (1);
 510                         #endif
 511
 512                         cd = iconv_open ("UTF-8", "ISO-2022-JP");
 513                         if (cd == (iconv_t) -1)
 514                                 exit (1);
 515                         if (iconv (cd, &jp, &jp_len, &trans, &utf8_len) == -1 || jp_len != 0)
 516                                 exit (1);
 517                         if (memcmp (utf8, transbuf, utf8_real_len) != 0)
 518                                 exit (1);
 519                         return (0);}
 520                 ]])
 521         ],[ac_cv_libiconv_utf8=yes],[ac_cv_libiconv_utf8=no; have_iconv=no],[ac_cv_libiconv_utf8=hopefully]))
 522 fi
 523
 524 if test "x$have_iconv" = "xno"; then
 525         AC_MSG_ERROR([You need to install a working iconv implementation, such as ftp://ftp.gnu.org/pub/gnu/libiconv])
 526 fi
 527 AC_SUBST(ICONV_LIBS)
 528
 529 CFLAGS="$CFLAGS -I$srcdir"
 530
 531 AC_MSG_CHECKING([preferred charset name formats for system iconv])
 532 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 533         #define CONFIGURE_IN
 534         #include "iconv-detect.c"
 535         ]])],
 536         [AC_MSG_RESULT([found])],
 537         [AC_MSG_RESULT([not found])
 538                 AC_MSG_WARN([
 539                 *** The iconv-detect program was unable to determine the
 540                 *** preferred charset name formats recognized by your
 541                 *** iconv library. It is suggested that you install a
 542                 *** working iconv library such as the one found at
 543                 *** ftp://ftp.gnu.org/pub/gnu/libiconv
 544         ])],
 545         [if test "x$os_win32" = xyes; then
 546                 AC_MSG_RESULT([using known win32 result])
 547                 echo '/* This is an auto-generated header, DO NOT EDIT! */' > iconv-detect.h
 548                 echo  >>iconv-detect.h
 549                 echo '#define ICONV_ISO_D_FORMAT "iso-%d-%d"' >>iconv-detect.h
 550                 echo '#define ICONV_ISO_S_FORMAT "iso-%d-%s"' >>iconv-detect.h
 551                 echo '#define ICONV_10646 "UCS-4BE"' >>iconv-detect.h
 552         else
 553                 AC_MSG_RESULT([unknown])
 554                 AC_MSG_WARN([
 555                 *** We can't determine the preferred charset name formats
 556                 *** recognized by your iconv library. You are
 557                 *** cross-compiling and supposed to know what you are doing.
 558                 *** Please construct the iconv-detect.h file manually.
 559                 ])
 560         fi
 561 ])
 562
 563 CFLAGS="$save_CFLAGS"
 564 LIBS="$save_LIBS"
 565
 566 AC_ARG_ENABLE([backtraces],
 567         [AS_HELP_STRING([--enable-backtraces],
 568         [enable backtraces for camel_pointer_tracker (default=no)])],
 569         [enable_backtraces=$enableval], [enable_backtraces=no])
 570
 571 if test "x$enable_backtraces" = xyes; then
 572         dnl ****************************
 573         dnl Check for backtrace_symbols function and dwfl from elfutils
 574         dnl ****************************
 575         AC_MSG_CHECKING([libc backtrace_symbols function])
 576         AC_LINK_IFELSE([AC_LANG_PROGRAM(
 577                 [[#include <execinfo.h>]],
 578                 [[{ void *bt[1]; backtrace_symbols (bt, backtrace(bt, 1)); }]])],
 579                 [AC_DEFINE(HAVE_BACKTRACE_SYMBOLS, 1, [libc provides backtrace_symbols function]) ac_cv_have_bsf=yes],[ac_cv_have_bsf=no])
 580         AC_MSG_RESULT([$ac_cv_have_bsf])
 581
 582         if test "x$ac_cv_have_bsf" = xyes; then
 583                 LIBS="$LIBS -ldw"
 584
 585                 AC_MSG_CHECKING([elfutils/libdwfl])
 586                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
 587                         [[#include <elfutils/libdwfl.h>]],
 588                         [[{
 589                                 Dwfl *dwfl;
 590                                 Dwfl_Module *module;
 591                                 Dwarf_Addr module_low_addr;
 592                                 Dwfl_Line *line;
 593
 594                                 dwfl_standard_find_debuginfo;
 595                                 dwfl_linux_proc_find_elf;
 596                                 dwfl_begin (NULL);
 597                                 dwfl_linux_proc_report (NULL, 1);
 598                                 dwfl_report_end (NULL, NULL, NULL);
 599                                 dwfl_end (NULL);
 600                                 dwfl_module_addrname (NULL, NULL);
 601                                 dwfl_module_getsrc (NULL, NULL);
 602                                 dwfl_lineinfo (NULL, NULL, NULL, NULL, NULL, NULL);
 603                                 DWARF_CB_ABORT; DWARF_CB_OK;
 604                                 dwfl_getmodules (NULL, NULL, NULL, 0);
 605                         }]])],
 606                         [AC_DEFINE(HAVE_ELFUTILS_LIBDWFL, 1, [have elfutils/libdwfl.h functions]) ac_cv_have_elfdwfl=yes],[ac_cv_have_elfdwfl=no])
 607                 AC_MSG_RESULT([$ac_cv_have_elfdwfl])
 608
 609                 LIBS="$save_LIBS"
 610
 611                 if test "x$ac_cv_have_elfdwfl" = xyes; then
 612                         LIBDWFL_LIBS="-ldw"
 613                         AC_SUBST(LIBDWFL_LIBS)
 614                 fi
 615         fi
 616 fi
 617
 618 dnl **********************************
 619 dnl Check for nl_langinfo and CODESET
 620 dnl **********************************
 621 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 622 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 623         [[#include <langinfo.h>]],
 624         [[char *codeset = nl_langinfo (CODESET);]]
 625         )],[ac_cv_langinfo_codeset=yes],[ac_cv_langinfo_codeset=no])
 626 if test "x$ac_cv_langinfo_codeset" = "xyes"; then
 627         AC_DEFINE(HAVE_CODESET, 1, [Have nl_langinfo (CODESET)])
 628 fi
 629 AC_MSG_RESULT([$ac_cv_langinfo_codeset])
 630
 631 dnl *******************************************************
 632 dnl Check to see if strftime supports the use of %l and %k
 633 dnl *******************************************************
 634 AC_MSG_CHECKING([for %l and %k support in strftime])
 635 AC_RUN_IFELSE([AC_LANG_SOURCE(
 636         [[      #include <stdlib.h>
 637                 #include <string.h>
 638                 #include <time.h>
 639                 int main(int argc, char **argv) {
 640                 char buf[10];
 641                 time_t rawtime;
 642                 struct tm *timeinfo;
 643
 644                 time(&rawtime);
 645                 timeinfo=localtime(&rawtime);
 646                 buf[0] = '\0';
 647                 strftime(buf, 10, "%lx%k", timeinfo);
 648
 649                 if (buf[0] == '\0' || buf[0] == 'x' || strstr(buf, "l") || strstr(buf, "k"))
 650                         exit(1);
 651                 else
 652                         exit(0);
 653                 return 0;
 654                 }
 655         ]]
 656         )],[AC_DEFINE(HAVE_LKSTRFTIME, 1, [strftime supports use of l and k]) ac_cv_lkstrftime=yes],[ac_cv_lkstrftime=no],[ac_cv_lkstrftime=no])
 657 AC_MSG_RESULT([$ac_cv_lkstrftime])
 658
 659 dnl ********************************************************************************
 660 dnl security extension support (SSL and S/MIME)
 661 dnl
 662 dnl The following voodoo does detection of mozilla libraries (nspr and nss)
 663 dnl needed by Camel (SSL and S/MIME).
 664 dnl
 665 dnl The Evolution security extensions are only built if these libraries are found
 666 dnl ********************************************************************************
 667 msg_smime="no"
 668
 669 AC_ARG_ENABLE([smime],
 670         AS_HELP_STRING([--enable-smime],
 671         [Enable SMIME support through Mozilla nss @<:@default=yes@:>@ ]),
 672         [enable_smime="$enableval"],[enable_smime="yes"])
 673
 674 AC_ARG_WITH([nspr-includes],
 675         AS_HELP_STRING([--with-nspr-includes],
 676         [Prefix of Mozilla nspr4 includes.]),
 677         [with_nspr_includes="$withval"])
 678
 679 AC_ARG_WITH([nspr-libs],
 680         AS_HELP_STRING([--with-nspr-libs],
 681         [Prefix of Mozilla nspr4 libs.]),
 682         [with_nspr_libs="$withval"])
 683
 684 AC_ARG_WITH([nss-includes],
 685         AS_HELP_STRING([--with-nss-includes],
 686         [Prefix of Mozilla nss3 includes.]),
 687         [with_nss_includes="$withval"])
 688
 689 AC_ARG_WITH([nss-libs],
 690         AS_HELP_STRING([--with-nss-libs],
 691         [Prefix of Mozilla nss3 libs.]),
 692         [with_nss_libs="$withval"])
 693
 694 if test -n "${with_nspr_includes}" || test -n "${with_nspr_libs}" || test -n "${with_nss_includes}" || test -n "${with_nss_libs}"; then
 695         check_manually="yes"
 696 else
 697         check_manually="no"
 698 fi
 699
 700 dnl check if pkg-config files exist (which are only shipped by distributions, not upstream)
 701 if test "x${check_manually}" = "xno"; then
 702         AC_MSG_CHECKING(Mozilla NSPR pkg-config module name)
 703         mozilla_nspr_pcs="nspr mozilla-nspr firefox-nspr xulrunner-nspr seamonkey-nspr"
 704         for pc in $mozilla_nspr_pcs; do
 705                 if $PKG_CONFIG --exists $pc; then
 706                         AC_MSG_RESULT($pc)
 707                         mozilla_nspr=$pc
 708                         break;
 709                 fi
 710         done
 711
 712         AC_MSG_CHECKING(Mozilla NSS pkg-config module name)
 713         mozilla_nss_pcs="nss mozilla-nss firefox-nss xulrunner-nss seamonkey-nss"
 714         for pc in $mozilla_nss_pcs; do
 715                 if $PKG_CONFIG --exists $pc; then
 716                         AC_MSG_RESULT($pc)
 717                         mozilla_nss=$pc
 718                         break;
 719                 fi
 720         done
 721
 722         if test -n "$mozilla_nspr" -a -n "$mozilla_nss"; then
 723                 if test "x$enable_smime" = "xyes"; then
 724                         AC_DEFINE(ENABLE_SMIME,1,[Define if SMIME should be enabled])
 725                         msg_smime="yes"
 726                 fi
 727                 MANUAL_NSPR_CFLAGS=""
 728                 MANUAL_NSPR_LIBS=""
 729                 MANUAL_NSS_CFLAGS=""
 730                 MANUAL_NSS_LIBS=""
 731         else
 732                 check_manually="yes"
 733                 mozilla_nspr=""
 734                 mozilla_nss=""
 735         fi
 736 fi
 737
 738 if test "x${check_manually}" = "xyes"; then
 739 dnl ******************
 740 dnl Check for NSPR 4
 741 dnl ******************
 742         AC_MSG_CHECKING([for Mozilla nspr4 includes])
 743                 CPPFLAGS_save="$CPPFLAGS"
 744                 if test -n "$with_nspr_includes"; then
 745                         CPPFLAGS="$CPPFLAGS -I$with_nspr_includes"
 746                 fi
 747
 748                 AC_CHECK_HEADERS(nspr.h prio.h,
 749                 [moz_nspr_includes="yes"],[moz_nspr_includes="no"])
 750                 CPPFLAGS="$CPPFLAGS_save"
 751
 752                 if test "x${moz_nspr_includes}" = "xyes"; then
 753                         MANUAL_NSPR_CFLAGS="-I$with_nspr_includes"
 754                 else
 755                         AC_MSG_FAILURE([NSPR headers not found. Use --with-nspr-includes to specify the include dir of NSPR.])
 756                 fi
 757         AC_MSG_RESULT([$moz_nspr_includes])
 758
 759         AC_MSG_CHECKING([for Mozilla nspr libraries])
 760                 CFLAGS_save="$CFLAGS"
 761                 LDFLAGS_save="$LDFLAGS"
 762                 LIBS_save="$LIBS"
 763                 nsprlibs="$DL_LIB -lplc4 -lplds4 -lnspr4"
 764
 765                 CFLAGS="$CFLAGS $MANUAL_NSPR_CFLAGS"
 766                 LIBS="$nsprlibs"
 767                 dnl Test to protect from giving libtool an -L , which results in failure (used below,too)
 768                 if test -n "${with_nspr_libs}"; then
 769                         LDFLAGS="$LDFLAGS -L$with_nspr_libs"
 770                 else
 771                         LDFLAGS="$LDFLAGS"
 772                 fi
 773
 774                 AC_LINK_IFELSE([AC_LANG_CALL([],[PR_Init])],
 775                 [moz_nspr_libs="yes"],[moz_nspr_libs="no"])
 776
 777                 CFLAGS="$CFLAGS_save"
 778                 LDFLAGS="$LDFLAGS_save"
 779                 LIBS="$LIBS_save"
 780
 781                 if test "x${moz_nspr_libs}" = "xyes"; then
 782                         if test -n "${with_nspr_libs}"; then
 783                                 MANUAL_NSPR_LIBS="-L$with_nspr_libs $nsprlibs"
 784                         else
 785                                 MANUAL_NSPR_LIBS="$nsprlibs"
 786                         fi
 787                 else
 788                         AC_MSG_FAILURE([NSPR libs not found. Use --with-nspr-libs to specify the libdir of NSPR.])
 789                 fi
 790         AC_MSG_RESULT([$moz_nspr_libs])
 791
 792 dnl *****************
 793 dnl Check for NSS 3
 794 dnl *****************
 795         AC_MSG_CHECKING([for Mozilla nss3 includes])
 796                 CPPFLAGS_save="$CPPFLAGS"
 797                 CPPFLAGS="$CPPFLAGS -I$with_nspr_includes -I$with_nss_includes"
 798
 799                 AC_CHECK_HEADERS(nss.h ssl.h smime.h,
 800                 [moz_nss_includes="yes"],[moz_nss_includes="no"])
 801                 CPPFLAGS="$CPPFLAGS_save"
 802
 803                 if test "x${moz_nss_includes}" = "xyes"; then
 804                         MANUAL_NSS_CFLAGS="-I$with_nss_includes"
 805                 else
 806                         AC_MSG_FAILURE([NSS headers not found. Use --with-nss-includes to specify the include dir of NSS.])
 807                 fi
 808         AC_MSG_RESULT($moz_nss_includes)
 809
 810         AC_MSG_CHECKING([for Mozilla nss libraries])
 811                 LDFLAGS_save="$LDFLAGS"
 812                 LIBS_save="$LIBS"
 813                 nsslibs="-lssl3 -lsmime3 -lnss3"
 814
 815                 LIBS="$nsslibs $nsprlibs"
 816                 dnl Test to protect from giving libtool an -L , which results in failure (used below,too)
 817                 if test -n "${with_nss_libs}"; then
 818                         LDFLAGS="$LDFLAGS -L$with_nss_libs $MANUAL_NSPR_LIBS"
 819                 else
 820                         LDFLAGS="$LDFLAGS $LDFLAGS_NSPR $MANUAL_NSPR_LIBS"
 821                 fi
 822
 823                 AC_LINK_IFELSE([AC_LANG_CALL([],[NSS_Init])],
 824                 [moz_nss_libs="yes"],[moz_nss_libs="no"])
 825                 LDFLAGS="$LDFLAGS_save"
 826                 LIBS="$LIBS_save"
 827
 828                 if test "x${moz_nss_libs}" = "xyes"; then
 829                         if test "x${enable_smime}" = "xyes"; then
 830                                 AC_DEFINE(ENABLE_SMIME,1,[Define if SMIME should be enabled])
 831                                 msg_smime="yes"
 832                         fi
 833                         if test -n "${with_nss_libs}"; then
 834                                 MANUAL_NSS_LIBS="-L$with_nss_libs $nsslibs"
 835                         else
 836                                 MANUAL_NSS_LIBS="$nsslibs"
 837                         fi
 838                 else
 839                         AC_MSG_FAILURE([NSS libs not found. Use --with-nss-libs to specify the libdir of NSS.])
 840                 fi
 841         AC_MSG_RESULT([$moz_nss_libs])
 842
 843         MANUAL_NSS_CFLAGS="$MANUAL_NSPR_CFLAGS $MANUAL_NSS_CFLAGS"
 844         MANUAL_NSS_LIBS="$MANUAL_NSPR_LIBS $MANUAL_NSS_LIBS"
 845 fi
 846
 847 AM_CONDITIONAL(ENABLE_SMIME, test "x$msg_smime" != "xno")
 848
 849 dnl For pkgconfig files.
 850 AC_SUBST(mozilla_nss)
 851 AC_SUBST(mozilla_nspr)
 852
 853 AC_SUBST(MANUAL_NSPR_CFLAGS)
 854 AC_SUBST(MANUAL_NSPR_LIBS)
 855 AC_SUBST(MANUAL_NSS_CFLAGS)
 856 AC_SUBST(MANUAL_NSS_LIBS)
 857
 858 dnl ******************************
 859 dnl system mail stuff
 860 dnl ******************************
 861 AC_PATH_PROG(SENDMAIL, sendmail, [/usr/sbin/sendmail], [/usr/sbin:/usr/lib])
 862 AC_DEFINE_UNQUOTED(SENDMAIL_PATH, "$SENDMAIL", [Path to a sendmail binary, or equivalent])
 863
 864 AC_MSG_CHECKING([system mail directory])
 865 if test -d /var/mail -a '!' -h /var/mail ; then
 866         system_mail_dir="/var/mail"
 867 else
 868         system_mail_dir="/var/spool/mail"
 869 fi
 870 AC_DEFINE_UNQUOTED(SYSTEM_MAIL_DIR, "$system_mail_dir", [Directory local mail is delivered to])
 871
 872 case `ls -ld $system_mail_dir 2>&1 | awk '{print $1;}'` in
 873         d??????rw?)
 874                 CAMEL_LOCK_HELPER_USER=""
 875                 CAMEL_LOCK_HELPER_GROUP=""
 876                 system_mail_perm="world writable"
 877         ;;
 878         d???rw????)
 879                 CAMEL_LOCK_HELPER_USER=""
 880                 CAMEL_LOCK_HELPER_GROUP=`ls -ld $system_mail_dir 2>&1 | awk '{print $4;}'`
 881                 system_mail_perm="writable by group $CAMEL_LOCK_HELPER_GROUP"
 882         ;;
 883         drw???????)
 884                 CAMEL_LOCK_HELPER_USER=`ls -ld $system_mail_dir 2>&1 | awk '{print $3;}'`
 885                 CAMEL_LOCK_HELPER_GROUP=""
 886                 system_mail_perm="writable by user $CAMEL_LOCK_HELPER_USER"
 887         ;;
 888         *)
 889                 CAMEL_LOCK_HELPER_USER=""
 890                 CAMEL_LOCK_HELPER_GROUP=""
 891                 system_mail_perm="???"
 892         ;;
 893 esac
 894
 895 AC_MSG_RESULT([$system_mail_dir, $system_mail_perm])
 896 AC_SUBST(CAMEL_LOCK_HELPER_USER)
 897 AC_SUBST(CAMEL_LOCK_HELPER_GROUP)
 898
 899 dnl ******************************
 900 dnl Timezone checks
 901 dnl ******************************
 902 AC_CACHE_CHECK(for tm_gmtoff in struct tm, [ac_cv_struct_tm_gmtoff],
 903         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 904         [[      #include <time.h>       ]],
 905         [[
 906                 struct tm tm;
 907                 tm.tm_gmtoff = 1;
 908         ]]
 909         )],[ac_cv_struct_tm_gmtoff=yes],[ac_cv_struct_tm_gmtoff=no]))
 910 if test "x$ac_cv_struct_tm_gmtoff" = "xyes"; then
 911         AC_DEFINE(HAVE_TM_GMTOFF, 1, [Define if struct tm has a tm_gmtoff member])
 912 else
 913         AC_CACHE_CHECK(for timezone variable, [ac_cv_var_timezone],
 914                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 915                 [[      #include <time.h> ]],
 916                 [[      timezone = 1;   ]]
 917                 )],[ac_cv_var_timezone=yes],[ac_cv_var_timezone=no]))
 918         if test "x$ac_cv_var_timezone" = "xyes"; then
 919                 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if libc defines a timezone variable])
 920                 AC_CACHE_CHECK(for altzone variable, [ac_cv_var_altzone],
 921                         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 922                         [[      #include <time.h>       ]],
 923                         [[      altzone = 1; ]]
 924                         )],[ac_cv_var_altzone=yes],[ac_cv_var_altzone=no]))
 925                 if test "x$ac_cv_var_altzone" = "xyes"; then
 926                         AC_DEFINE(HAVE_ALTZONE, 1, [Define if libc defines an altzone variable])
 927                 fi
 928         else
 929                 AC_MSG_ERROR([unable to find a way to determine timezone])
 930         fi
 931 fi
 932
 933 dnl ******************************
 934 dnl ctime_r prototype
 935 dnl ******************************
 936 AC_CACHE_CHECK([if ctime_r wants three arguments], [ac_cv_ctime_r_three_args],
 937 [
 938         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 939         [[      #include <time.h> ]],
 940         [[      char *buf;
 941                 time_t date;
 942                 ctime_r (&date, buf, 100); ]]
 943         )],[ac_cv_ctime_r_three_args=yes],[ac_cv_ctime_r_three_args=no])
 944 ])
 945
 946 if test "x$ac_cv_ctime_r_three_args" = "xyes" ; then
 947         AC_DEFINE(CTIME_R_THREE_ARGS, 1, [Solaris-style ctime_r])
 948 fi
 949
 950 dnl ******************************
 951 dnl gethostbyname_r prototype
 952 dnl ******************************
 953 AC_CHECK_FUNCS(gethostbyname_r,[
 954 AC_CACHE_CHECK([if gethostbyname_r wants five arguments], [ac_cv_gethostbyname_r_five_args],
 955 [
 956         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 957         [[
 958                 #include "confdefs.h"
 959                 #include <sys/types.h>
 960                 #include <sys/socket.h>
 961                 #include <netinet/in.h>
 962                 #include <netdb.h>
 963                 #define BUFSIZE (sizeof(struct hostent)+10)
 964         ]],
 965         [[
 966                 struct hostent hent;
 967                 char buffer[BUFSIZE];
 968                 int bufsize=BUFSIZE;
 969                 int h_errno;
 970                 (void)gethostbyname_r ("www.ximian.com", &hent, buffer, bufsize, &h_errno);
 971         ]]
 972         )],[ac_cv_gethostbyname_r_five_args=yes],[ac_cv_gethostbyname_r_five_args=no])
 973 ])])
 974
 975 if test "x$ac_cv_gethostbyname_r_five_args" = "xyes" ; then
 976         AC_DEFINE(GETHOSTBYNAME_R_FIVE_ARGS, 1, [Solaris-style gethostbyname_r])
 977 fi
 978
 979 dnl ******************************
 980 dnl gethostbyaddr_r prototype
 981 dnl ******************************
 982 AC_CHECK_FUNCS(gethostbyaddr_r,[
 983 AC_CACHE_CHECK([if gethostbyaddr_r wants seven arguments], [ac_cv_gethostbyaddr_r_seven_args],
 984 [
 985         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 986         [[
 987                 #include "confdefs.h"
 988                 #include <sys/types.h>
 989                 #include <sys/socket.h>
 990                 #include <netinet/in.h>
 991                 #include <netdb.h>
 992                 #define BUFSIZE (sizeof(struct hostent)+10)
 993         ]],
 994         [[
 995                 struct hostent hent;
 996                 char buffer[BUFSIZE];
 997                 int bufsize=BUFSIZE;
 998                 int h_errno;
 999                 (void)gethostbyaddr_r ("www.ximian.com", 14, AF_INET, &hent, buffer, bufsize, &h_errno); ]]
1000         )],[ac_cv_gethostbyaddr_r_seven_args=yes],[ac_cv_gethostbyaddr_r_seven_args=no])
1001 ])])
1002
1003 if test "x$ac_cv_gethostbyaddr_r_seven_args" = "xyes" ; then
1004         AC_DEFINE(GETHOSTBYADDR_R_SEVEN_ARGS, 1, [Solaris-style gethostbyaddr_r])
1005 fi
1006
1007 dnl ******************************
1008 dnl stat(v)fs location/type
1009 dnl ******************************
1010 AC_CHECK_HEADER([sys/statvfs.h],
1011         [AC_DEFINE([HAVE_SYS_STATVFS_H], 1, [Have <sys/statvfs.h>])],,
1012         [[      #if HAVE_SYS_STATVFS_H
1013                 #include <sys/statvfs.h>
1014                 #endif
1015         ]])
1016 AC_CHECK_FUNCS(statvfs)
1017
1018 AC_CHECK_HEADER([sys/param.h],
1019         [AC_DEFINE([HAVE_SYS_PARAM_H], 1, [Have <sys/param.h>])],,
1020         [[      #if HAVE_SYS_PARAM_H
1021                 #include <sys/param.h>
1022                 #endif
1023         ]])
1024 AC_CHECK_HEADER([sys/mount.h],
1025         [AC_DEFINE([HAVE_SYS_MOUNT_H], 1, [Have <sys/mount.h>])],,
1026         [[      #if HAVE_SYS_MOUNT_H
1027                 #include <sys/mount.h>
1028                 #endif
1029         ]])
1030 AC_CHECK_FUNCS(statfs)
1031
1032 dnl ******************************
1033 dnl IPv6 support and getaddrinfo calls
1034 dnl ******************************
1035 AC_CACHE_CHECK([if system supports getaddrinfo and getnameinfo], [ac_cv_have_addrinfo],
1036 [
1037         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1038         [[      #include "confdefs.h"
1039                 #include <sys/types.h>
1040                 #include <sys/socket.h>
1041                 #include <netinet/in.h>
1042                 #include <netdb.h>
1043                 #include <stddef.h>
1044         ]],
1045         [[      #ifndef NI_MAXHOST
1046                 #define NI_MAXHOST      1025
1047                 #endif
1048
1049                 #ifndef NI_MAXSERV
1050                 #define NI_MAXSERV      32
1051                 #endif
1052
1053                 struct addrinfo hints, *res;
1054                 struct sockaddr_in6 sin6;
1055                 int af = AF_INET6;
1056                 char host[NI_MAXHOST];
1057                 char serv[NI_MAXSERV];
1058
1059                 getaddrinfo ("www.ximian.com", NULL, &hints, &res);
1060                 freeaddrinfo (res);
1061                 getnameinfo((struct sockaddr *)&sin6, sizeof(sin6), host, sizeof(host), serv, sizeof(serv), 0); ]]
1062         )],[ac_cv_have_addrinfo=yes],[ac_cv_have_addrinfo=no])
1063 ])
1064
1065 if test "x$ac_cv_have_addrinfo" = "xno" ; then
1066         AC_DEFINE(NEED_ADDRINFO,1,[Enable getaddrinfo emulation])
1067         if test "x$enable_ipv6" = "xyes" ; then
1068                 AC_MSG_ERROR([system doesn't support necessary interfaces for ipv6 support])
1069         fi
1070         msg_ipv6="no"
1071 else
1072         AC_ARG_ENABLE([ipv6],
1073         AS_HELP_STRING([--enable-ipv6=no/yes],
1074         [Enable support for resolving IPv6 addresses.]),
1075         [enable_ipv6=$enableval],[enable_ipv6=yes])
1076         if test "x$enable_ipv6" = "xyes"; then
1077                 msg_ipv6="yes"
1078                 AC_DEFINE(ENABLE_IPv6,1,[Enable IPv6 support])
1079                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1080                 [[      #include "confdefs.h"
1081                         #include <sys/types.h>
1082                         #include <sys/socket.h>
1083                         #include <netinet/in.h>
1084                         #include <netdb.h>
1085                 ]],
1086                 [[      struct addrinfo hints;
1087                         hints.ai_flags = AI_ADDRCONFIG;
1088                 ]]
1089                 )],[AC_DEFINE(HAVE_AI_ADDRCONFIG,1,[Define if the system defines the AI_ADDRCONFIG flag for getaddrinfo])],[])
1090         else
1091                 msg_ipv6="no"
1092         fi
1093 fi
1094
1095 AM_CONDITIONAL(ENABLE_IPv6, [test "x$enable_ipv6" = "xyes"])
1096
1097 AC_CHECK_HEADER([wspiapi.h],
1098         [AC_DEFINE([HAVE_WSPIAPI_H], 1, [Have <wspiapi.h>])],,)
1099
1100 dnl **********************************
1101 dnl Weather calendar backend support
1102 dnl **********************************
1103 AC_MSG_CHECKING([if we should build the weather calendar backend])
1104 AC_ARG_ENABLE([weather],
1105         [AS_HELP_STRING([--enable-weather],
1106         [Build the weather calendar backend (default=yes)])],
1107         [use_gweather=$enableval], [use_gweather=yes])
1108
1109 AC_MSG_RESULT([$use_gweather])
1110 if test "x$use_gweather" = "xyes"; then
1111         PKG_CHECK_MODULES([LIBGWEATHER], [gweather-3.0 >= gweather_minimum_version],[],
1112         [AC_MSG_ERROR([The weather calendar backend requires GWeather >= gweather_minimum_version. Alternatively, you may specify --disable-weather as a configure option to avoid building the backend.])])
1113 fi
1114 AM_CONDITIONAL(ENABLE_WEATHER, [test $use_gweather = yes])
1115
1116 dnl ******************************
1117 dnl NNTP support.
1118 dnl ******************************
1119 AC_ARG_ENABLE([nntp],
1120         AS_HELP_STRING([--enable-nntp],
1121         [Build Usenet news (NNTP) backend]),
1122         [enable_nntp=$enableval],[enable_nntp=yes])
1123 if test "x$enable_nntp" = "xyes"; then
1124         AC_DEFINE(ENABLE_NNTP,1,[Build NNTP backend])
1125         msg_nntp="yes"
1126 else
1127         msg_nntp="no"
1128 fi
1129 AM_CONDITIONAL(ENABLE_NNTP, [test x$enable_nntp = xyes])
1130
1131 AC_DEFINE(HANDLE_LIBICAL_MEMORY, 1, [Define it once memory returned by libical is free'ed properly])
1132
1133 dnl ******************************
1134 dnl File locking
1135 dnl ******************************
1136 AC_ARG_ENABLE([dot-locking],
1137         AS_HELP_STRING([--enable-dot-locking=yes/no],
1138         [Enable support for locking mail files with dot locking]),
1139         [enable_dot_locking=$enableval],[enable_dot_locking=yes])
1140
1141 if test "x$os_win32" != "xyes" -a "x$enable_dot_locking" = "xyes"; then
1142         AC_DEFINE(USE_DOT,1,[Define to use dot locking for mbox files])
1143         msg_dot="yes"
1144 else
1145         msg_dot="no"
1146 fi
1147
1148 AC_ARG_ENABLE([file-locking],
1149         AS_HELP_STRING([--enable-file-locking=fcntl/flock/no],
1150         [Enable support for locking mail files with file locking]),
1151         [],[enable_file_locking=fcntl])
1152
1153 if test "x$os_win32" != "xyes" -a "x$enable_file_locking" = "xfcntl"; then
1154         AC_DEFINE(USE_FCNTL,1,[Define to use fcntl locking for mbox files])
1155         msg_file="fcntl"
1156 else
1157         if test "x$os_win32" != "xyes" -a "x$enable_file_locking" = "xflock"; then
1158                 AC_DEFINE(USE_FLOCK,1,[Define to use flock locking for mbox files])
1159                 msg_file="flock"
1160         else
1161                 msg_file="no"
1162         fi
1163 fi
1164
1165 dnl ******************************
1166 dnl sendmail operation
1167 dnl ******************************
1168 AC_MSG_CHECKING([for SunOS broken spool format])
1169 if test "x$host_os" = "xsunos" ; then
1170         with_broken_spool="yes"
1171 fi
1172
1173 AC_ARG_WITH([broken-spool],
1174         AS_HELP_STRING([--with-broken-spool=yes/no],
1175         [Using SunOS/Solaris sendmail which has a broken spool format]),
1176         [with_broken_spool=$enableval],[with_broken_spool=${with_broken_spool:=no}])
1177
1178 if test "x$with_broken_spool" = "xyes"; then
1179         AC_DEFINE(HAVE_BROKEN_SPOOL,1,[Define if mail delivered to the system mail directory is in broken Content-Length format])
1180 fi
1181
1182 AC_MSG_RESULT([$with_broken_spool])
1183
1184 dnl ******************************
1185 dnl DBus call timeout
1186 dnl ******************************
1187
1188 AC_ARG_WITH([dbus-call-timeout],
1189         AS_HELP_STRING([--with-dbus-call-timeout=miliseconds],
1190         [Default timeout used when invoking g_dbus_proxy_call() family functions in EBook and ECal library (default=-1)]),
1191         [ac_cv_dbus_call_timeout=$withval],[ac_cv_dbus_call_timeout=-1])
1192
1193 DEFAULT_EDS_DBUS_TIMEOUT=$ac_cv_dbus_call_timeout
1194 AC_SUBST(DEFAULT_EDS_DBUS_TIMEOUT)
1195
1196 dnl ***********
1197 dnl Kerberos 5
1198 dnl ***********
1199 EVO_KRB5_SUPPORT(no)
1200
1201 dnl ******************************
1202 dnl Purify support
1203 dnl ******************************
1204 EVO_PURIFY_SUPPORT
1205
1206 dnl ******************************
1207 dnl LDAP support.
1208 dnl ******************************
1209 if test "x$os_win32" != "xyes"; then
1210         EVO_LDAP_CHECK(no)
1211         case $with_openldap in
1212         no)
1213                 msg_ldap="no"
1214         ;;
1215         *)
1216                 case $with_static_ldap in
1217                 yes)
1218                         msg_ldap="$with_openldap (static)"
1219                         ;;
1220                 *)
1221                         msg_ldap="$with_openldap (dynamic)"
1222                         ;;
1223                 esac
1224         esac
1225
1226 dnl SunLDAP support, but if OpenLDAP support, skip check SunLDAP.
1227         if test "x$with_openldap" = "xno" ; then
1228                 EVO_SUNLDAP_CHECK(no)
1229                 case $with_sunldap in
1230                 no)
1231                         msg_ldap="no"
1232                         ;;
1233                 *)
1234                         case $with_static_sunldap in
1235                         yes)
1236                                 msg_ldap="$with_sunldap (static)"
1237                                 ;;
1238                         *)
1239                                 msg_ldap="$with_sunldap (dynamic)"
1240                                 ;;
1241                 esac
1242         esac
1243         else
1244                 with_sunldap="no"
1245         fi
1246         AM_CONDITIONAL(SUNLDAP, [test "$with_sunldap" != no])
1247
1248         LDAP_CFLAGS="$LDAP_CFLAGS -DLDAP_DEPRECATED"
1249 else
1250         dnl Win32 LDAP support
1251         LDAP_CFLAGS="-DLDAP_DEPRECATED"
1252         LDAP_LIBS="-lwldap32"
1253         AC_SUBST(LDAP_CFLAGS)
1254         AC_SUBST(LDAP_LIBS)
1255         AC_DEFINE(HAVE_LDAP,1,[Define if you have LDAP support])
1256         AM_CONDITIONAL(ENABLE_LDAP, true)
1257         AM_CONDITIONAL(SUNLDAP, false)
1258         msg_ldap="yes"
1259 fi
1260
1261 dnl ******************************
1262 dnl GObject marshalling
1263 dnl ******************************
1264 AM_PATH_GLIB_2_0
1265
1266 dnl We use AC_SUBST_FILE because AC_SUBST won't deal with newlines
1267 EVO_MARSHAL_RULE=$srcdir/marshal.mk
1268 AC_SUBST_FILE(EVO_MARSHAL_RULE)
1269
1270 dnl ******************************
1271 dnl Utility macro to set compiler flags for a specific lib.
1272 dnl EVO_SET_COMPILE_FLAGS(VAR-PREFIX, DEPS, EXTRA-CFLAGS, EXTRA-LIBS)
1273 dnl ******************************
1274 AC_DEFUN([EVO_SET_COMPILE_FLAGS], [
1275         PKG_CHECK_MODULES([$1], [$2])
1276         $1_CFLAGS="[$]$1_CFLAGS $3 "
1277         $1_LIBS="[$]$1_LIBS $4 "
1278 ])
1279
1280 dnl ******************************
1281 dnl sqlite3 flags
1282 dnl ******************************
1283 PKG_CHECK_MODULES(SQLITE3, [sqlite3 >= sqlite_minimum_version])
1284
1285 if test "x$enable_maintainer_mode" = "xyes" ; then
1286         EVO_SET_COMPILE_FLAGS(FACTORY_GTK, "gtk+-3.0")
1287         AC_SUBST(FACTORY_GTK_CFLAGS)
1288         AC_SUBST(FACTORY_GTK_LIBS)
1289 fi
1290
1291 dnl ******************************
1292 dnl libedataserver flags
1293 dnl ******************************
1294 E_DATA_SERVER_DEPS="gio-2.0 gmodule-2.0 libsecret-1 libxml-2.0 libsoup-2.4 $mozilla_nspr"
1295
1296 EVO_SET_COMPILE_FLAGS(E_DATA_SERVER, $E_DATA_SERVER_DEPS, $MANUAL_NSPR_CFLAGS, $MANUAL_NSPR_LIBS)
1297 AC_SUBST(E_DATA_SERVER_CFLAGS)
1298 AC_SUBST(E_DATA_SERVER_LIBS)
1299
1300 dnl ******************************
1301 dnl libebackend flags
1302 dnl ******************************
1303 E_BACKEND_DEPS="gio-2.0 gmodule-2.0 libsecret-1 libsoup-2.4 libxml-2.0"
1304
1305 EVO_SET_COMPILE_FLAGS(E_BACKEND, $E_BACKEND_DEPS)
1306 AC_SUBST(E_BACKEND_CFLAGS)
1307 AC_SUBST(E_BACKEND_LIBS)
1308
1309 dnl ******************************
1310 dnl evolution-addressbook flags
1311 dnl ******************************
1312 EVOLUTION_ADDRESSBOOK_DEPS="gio-2.0 libxml-2.0 libsoup-2.4 libsecret-1"
1313
1314 EVO_SET_COMPILE_FLAGS(EVOLUTION_ADDRESSBOOK, $EVOLUTION_ADDRESSBOOK_DEPS)
1315 AC_SUBST(EVOLUTION_ADDRESSBOOK_CFLAGS)
1316 AC_SUBST(EVOLUTION_ADDRESSBOOK_LIBS)
1317
1318 dnl ******************************
1319 dnl evolution-calendar flags
1320 dnl ******************************
1321 EVOLUTION_CALENDAR_DEPS="gio-2.0 libical >= libical_minimum_version libsoup-2.4 libxml-2.0 libsecret-1"
1322
1323 dnl *****
1324 dnl libical.pc from libical-0.43 has a bug in it's CFlags.
1325 dnl It wants apps to include <libical/ical*.h> but it's CFlags make it difficult
1326 dnl to differentiate between <libical/ical.h> and <ical.h>
1327 dnl We have fixed all our instances to use <libical/ical.h>. Until the .pc from
1328 dnl libical is fixed, we have to work-around the buggy CFlags.
1329 dnl *****
1330         LIBICAL_EXTRA_CFLAGS=" -I`$PKG_CONFIG --variable=includedir libical` "
1331         LIBICAL_EXTRA_LIBS=""
1332         AC_SUBST(LIBICAL_EXTRA_CFLAGS)
1333         AC_SUBST(LIBICAL_EXTRA_LIBS)
1334
1335         EVO_SET_COMPILE_FLAGS(EVOLUTION_CALENDAR, $EVOLUTION_CALENDAR_DEPS, $LIBICAL_EXTRA_CFLAGS, $LIBICAL_EXTRA_LIBS)
1336         AC_SUBST(EVOLUTION_CALENDAR_CFLAGS)
1337         AC_SUBST(EVOLUTION_CALENDAR_LIBS)
1338
1339         dnl ****************************
1340         dnl Check for ical_set_unknown_token_handling_setting function
1341         dnl ****************************
1342         AC_MSG_CHECKING([ical_set_unknown_token_handling_setting function])
1343         save_cflags=$CFLAGS; CFLAGS=$EVOLUTION_CALENDAR_CFLAGS
1344         save_libs=$LIBS; LIBS="$EVOLUTION_CALENDAR_LIBS"
1345         AC_LINK_IFELSE([AC_LANG_PROGRAM(
1346                 [[#include <libical/ical.h>]],
1347                 [[ical_set_unknown_token_handling_setting (ICAL_DISCARD_TOKEN)]])],
1348                 [AC_DEFINE(HAVE_ICAL_UNKNOWN_TOKEN_HANDLING, 1, [libical provides ical_set_unknown_token_handling_setting function]) ac_cv_have_iuth=yes],[ac_cv_have_iuth=no])
1349         CFLAGS=$save_cflags
1350         LIBS=$save_libs
1351         AC_MSG_RESULT([$ac_cv_have_iuth])
1352
1353 dnl ******************************
1354 dnl Google flags
1355 dnl ******************************
1356 LIBGDATA_REQUIRED=libgdata_minimum_version
1357 AC_SUBST(LIBGDATA_REQUIRED)
1358
1359 EVO_SET_COMPILE_FLAGS(GDATA, libgdata)
1360 AC_SUBST(GDATA_CFLAGS)
1361 AC_SUBST(GDATA_LIBS)
1362
1363 EVO_SET_COMPILE_FLAGS(SOUP, libsoup-2.4)
1364 AC_SUBST(SOUP_CFLAGS)
1365 AC_SUBST(SOUP_LIBS)
1366
1367 dnl ******************************
1368 dnl Camel flags
1369 dnl ******************************
1370 SQLITE_REQUIRED=sqlite_minimum_version
1371 AC_SUBST(SQLITE_REQUIRED)
1372
1373 zlib_found="false"
1374 dnl deflateInit is a #define, use deflateEnd instead
1375 AC_CHECK_LIB([z], [deflateEnd], [AC_CHECK_HEADER(zlib.h, [zlib_found=true])])
1376
1377 if test "x$zlib_found" = "xfalse"; then
1378         AC_MSG_ERROR([*** zlib is required])
1379 fi
1380
1381 dnl ******************************
1382 dnl Checks for large file support
1383 dnl ******************************
1384 AC_ARG_ENABLE([largefile],
1385         AS_HELP_STRING([--enable-largefile],
1386         [enable support for large files [[default=no]]]),
1387         [],[enable_largefile="yes"])
1388
1389 if test "x$enable_largefile" != "xno"; then
1390         AC_SYS_LARGEFILE
1391         AC_CACHE_CHECK([for _LARGEFILE64_SOURCE value needed for large files], [ac_cv_largefile64_source],
1392         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1393         [[      #include <sys/types.h>
1394                 #include <sys/stat.h>
1395                 #include <fcntl.h>
1396         ]],
1397         [[      int fd = open ("__o_largefile", O_CREAT | O_RDWR | O_LARGEFILE, 0644);  ]]
1398         )],[ac_cv_largefile64_source="no"],
1399                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1400                 [[      #define _LARGEFILE64_SOURCE
1401                         #include <sys/types.h>
1402                         #include <sys/stat.h>
1403                         #include <fcntl.h>
1404                 ]],
1405                 [[ int fd = open ("__o_largefile", O_CREAT | O_RDWR | O_LARGEFILE, 0644); ]])],[ac_cv_largefile64_source="yes"],
1406                 [ac_cv_largefile64_source="unknown"])])
1407         ])
1408
1409         enable_largefile="no"
1410
1411         if test "x$ac_cv_largefile64_source" = "xyes"; then
1412                 LARGEFILE_CFLAGS="-D_LARGEFILE64_SOURCE"
1413                 enable_largefile="yes"
1414         elif test "x$ac_cv_largefile64_source" = "xunknown"; then
1415                 AC_DEFINE(O_LARGEFILE, 0, [Define to 0 if your system does not have the O_LARGEFILE flag])
1416         fi
1417
1418         if test -n "$ac_cv_sys_large_files" -a "x$ac_cv_sys_large_files" != "xno"; then
1419                 LARGEFILE_CFLAGS="$LARGEFILE_CFLAGS -D_LARGE_FILES"
1420                 enable_largefile="yes"
1421         fi
1422
1423         if test "x$ac_cv_sys_file_offset_bits" != "xno"; then
1424                 LARGEFILE_CFLAGS="$LARGEFILE_CFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
1425                 enable_largefile="yes"
1426         fi
1427 else
1428         AC_DEFINE(O_LARGEFILE, 0, [Define to 0 if your system does not have the O_LARGEFILE flag])
1429         LARGEFILE_CFLAGS=""
1430 fi
1431
1432 AM_CONDITIONAL(ENABLE_LARGEFILE, [test "x$enable_largefile" = "xyes"])
1433
1434 EVO_SET_COMPILE_FLAGS(CAMEL, gio-2.0 gmodule-2.0 $mozilla_nss sqlite3 >= sqlite_minimum_version, $KRB5_CFLAGS $MANUAL_NSS_CFLAGS $LARGEFILE_CFLAGS, -lz $KRB5_LIBS $MANUAL_NSS_LIBS)
1435 AC_SUBST(CAMEL_CFLAGS)
1436 AC_SUBST(CAMEL_LIBS)
1437
1438 dnl ******************************
1439 dnl Special directories
1440 dnl ******************************
1441
1442 dnl If you add something here, consider whether or not you also
1443 dnl need to add it to one or more .pc.in files (for Connector,
1444 dnl etc)
1445
1446 privdatadir='${datadir}'/evolution-data-server
1447 AC_SUBST(privdatadir)
1448
1449 privincludedir='${includedir}'/evolution-data-server
1450 AC_SUBST(privincludedir)
1451
1452 privlibdir='${libdir}'/evolution-data-server
1453 AC_SUBST(privlibdir)
1454
1455 imagesdir='${datadir}'/pixmaps/evolution-data-server
1456 AC_SUBST(imagesdir)
1457
1458 moduledir='${privlibdir}'/registry-modules
1459 AC_SUBST(moduledir)
1460
1461 ebook_backenddir='${privlibdir}'/addressbook-backends
1462 AC_SUBST(ebook_backenddir)
1463
1464 ecal_backenddir='${privlibdir}'/calendar-backends
1465 AC_SUBST(ecal_backenddir)
1466
1467 ro_sourcesdir='${privdatadir}'/ro-sources
1468 AC_SUBST(ro_sourcesdir)
1469
1470 rw_sourcesdir='${privdatadir}'/rw-sources
1471 AC_SUBST(rw_sourcesdir)
1472
1473 if test "x$use_gweather" = "xyes"; then
1474         weatherdatadir="$privdatadir/weather"
1475         AC_SUBST(weatherdatadir)
1476 fi
1477
1478 dnl separate camel from e-d-s? or should it be under the same spot? same for now.
1479 camel_providerdir='${privlibdir}'/camel-providers
1480 AC_SUBST(camel_providerdir)
1481
1482 dnl *******************
1483 dnl D-BUS service stuff
1484 dnl *******************
1485 m4_pattern_allow([AM_V_GEN])
1486 EVO_SUBST_SERVICE_RULE='%.service: %.service.in Makefile ; $(AM_V_GEN) sed -e "s|\@libexecdir\@|$(libexecdir)|" -e s"|\@ADDRESS_BOOK_DBUS_SERVICE_NAME\@|$(ADDRESS_BOOK_DBUS_SERVICE_NAME)|" -e "s|\@CALENDAR_DBUS_SERVICE_NAME\@|$(CALENDAR_DBUS_SERVICE_NAME)|" -e "s|\@SOURCES_DBUS_SERVICE_NAME\@|$(SOURCES_DBUS_SERVICE_NAME)|" -e "s|\@USER_PROMPTER_DBUS_SERVICE_NAME\@|$(USER_PROMPTER_DBUS_SERVICE_NAME)|" $< > $@'
1487 AC_SUBST(EVO_SUBST_SERVICE_RULE)
1488
1489 dnl ******************************
1490 dnl GLib stuff
1491 dnl ******************************
1492 GLIB_GSETTINGS
1493 AM_PATH_GLIB_2_0
1494
1495 dnl We use AC_SUBST_FILE because AC_SUBST won't deal with newlines
1496 EVO_MARSHAL_RULE=$srcdir/marshal.mk
1497 AC_SUBST_FILE(EVO_MARSHAL_RULE)
1498
1499 dnl ******************************
1500 dnl gperf stuff
1501 dnl ******************************
1502 AC_PATH_PROG(GPERF, gperf, [no])
1503 if test "x$GPERF" = "xno"; then
1504   AC_MSG_ERROR([You need gperf to build evolution-data-server])
1505 fi
1506
1507 GOBJECT_INTROSPECTION_CHECK([0.9.12])
1508
1509 dnl ******************************
1510 dnl Vala binding
1511 dnl ******************************
1512 AC_ARG_ENABLE(vala-bindings,
1513         AC_HELP_STRING([--enable-vala-bindings],
1514         [build the EXPERIMENTAL Vala bindings]),
1515         enable_vala_bindings=$enableval,
1516         enable_vala_bindings=no)
1517
1518 if test x$enable_vala_bindings = xyes; then
1519   if test "x$INTROSPECTION_SCANNER" = x; then
1520     AC_MSG_ERROR([GObject-Introspection must be enabled for Vala bindings])
1521   fi
1522
1523   AM_PROG_VALAC([0.13.0])
1524   have_vala=yes
1525
1526   AC_PATH_PROG(VALAC, valac, valac)
1527   AC_SUBST(VALAC)
1528   AC_SUBST(VALAFLAGS)
1529
1530   AC_PATH_PROG([VAPIGEN], [vapigen], [false])
1531
1532   if test "x$VAPIGEN" = "xfalse"; then
1533     AC_MSG_ERROR([vapigen not found. Was vala compiled with --enable-vapigen?])
1534   fi
1535
1536   AC_SUBST(VAPIGEN)
1537 fi
1538
1539 AM_CONDITIONAL([HAVE_VALA], [test "x$have_vala" = "xyes"])
1540 AC_SUBST(HAVE_VALA)
1541
1542 dnl ******************************
1543 dnl Makefiles
1544 dnl ******************************
1545 export privlibdir
1546 export privincludedir
1547 export privdatadir
1548
1549 AC_CONFIG_FILES([
1550 Makefile
1551 evolution-data-server-zip
1552 evolution-data-server.pc
1553 addressbook/Makefile
1554 addressbook/libebook/Makefile
1555 addressbook/libebook/libebook.pc
1556 addressbook/libedata-book/Makefile
1557 addressbook/libedata-book/libedata-book.pc
1558 addressbook/libegdbus/Makefile
1559 addressbook/backends/Makefile
1560 addressbook/backends/file/Makefile
1561 addressbook/backends/ldap/Makefile
1562 addressbook/backends/google/Makefile
1563 addressbook/backends/google/tests/Makefile
1564 addressbook/backends/webdav/Makefile
1565 art/Makefile
1566 calendar/Makefile
1567 calendar/libecal/Makefile
1568 calendar/libecal/libecal.pc
1569 calendar/libedata-cal/Makefile
1570 calendar/libedata-cal/libedata-cal.pc
1571 calendar/libegdbus/Makefile
1572 calendar/backends/Makefile
1573 calendar/backends/caldav/Makefile
1574 calendar/backends/file/Makefile
1575 calendar/backends/http/Makefile
1576 calendar/backends/contacts/Makefile
1577 calendar/backends/weather/Makefile
1578 camel/Makefile
1579 camel/providers/Makefile
1580 camel/providers/imapx/Makefile
1581 camel/providers/local/Makefile
1582 camel/providers/nntp/Makefile
1583 camel/providers/pop3/Makefile
1584 camel/providers/sendmail/Makefile
1585 camel/providers/smtp/Makefile
1586 camel/tests/Makefile
1587 camel/tests/folder/Makefile
1588 camel/tests/lib/Makefile
1589 camel/tests/message/Makefile
1590 camel/tests/mime-filter/Makefile
1591 camel/tests/misc/Makefile
1592 camel/tests/smime/Makefile
1593 camel/camel.pc
1594 data/Makefile
1595 data/sources/Makefile
1596 libebackend/Makefile
1597 libebackend/libebackend.pc
1598 libedataserver/Makefile
1599 libedataserver/eds-version.h
1600 libedataserver/libedataserver.pc
1601 modules/Makefile
1602 modules/cache-reaper/Makefile
1603 modules/gnome-online-accounts/Makefile
1604 modules/google-backend/Makefile
1605 modules/trust-prompt/Makefile
1606 modules/yahoo-backend/Makefile
1607 private/Makefile
1608 services/Makefile
1609 services/evolution-addressbook-factory/Makefile
1610 services/evolution-calendar-factory/Makefile
1611 services/evolution-source-registry/Makefile
1612 services/evolution-user-prompter/Makefile
1613 tests/Makefile
1614 tests/libebook/Makefile
1615 tests/libebook/client/Makefile
1616 tests/libebook/vcard/Makefile
1617 tests/libecal/Makefile
1618 tests/libecal/client/Makefile
1619 tests/libedata-cal/Makefile
1620 tests/libedataserver/Makefile
1621 tests/test-server-utils/Makefile
1622 tests/test-server-utils/services/Makefile
1623 tests/test-server-utils/services/org.gnome.evolution.dataserver.AddressBook.service
1624 tests/test-server-utils/services/org.gnome.evolution.dataserver.Calendar.service
1625 tests/test-server-utils/services/org.gnome.evolution.dataserver.Sources.service
1626 docs/Makefile
1627 docs/reference/Makefile
1628 docs/reference/addressbook/Makefile
1629 docs/reference/addressbook/libebook/Makefile
1630 docs/reference/addressbook/libedata-book/Makefile
1631 docs/reference/calendar/Makefile
1632 docs/reference/calendar/libecal/Makefile
1633 docs/reference/calendar/libedata-cal/Makefile
1634 docs/reference/camel/Makefile
1635 docs/reference/libedataserver/Makefile
1636 docs/reference/libebackend/Makefile
1637 docs/reference/private/Makefile
1638 po/Makefile.in
1639 vala/Makefile
1640 ])
1641 AC_OUTPUT
1642
1643 echo "
1644         evolution-data-server has been configured as follows:
1645         Weather calendar:       $use_gweather
1646         Mail Directory:         $system_mail_dir, $system_mail_perm
1647         LDAP support:           $msg_ldap
1648         NNTP support:           $msg_nntp
1649         Kerberos 5:             $msg_krb5
1650         SMIME support:          $msg_smime
1651         IPv6 support:           $msg_ipv6
1652         Dot Locking:            $msg_dot
1653         File Locking:           $msg_file
1654         Large files:            $enable_largefile
1655         Gtk Doc:                $enable_gtk_doc
1656         Introspection:          $enable_introspection
1657         Vala bindings:          $enable_vala_bindings
1658         GNOME Online Accounts   $enable_goa
1659         Code coverage (gcov):   $enable_code_coverage
1660         Strict building:        $enable_strict
1661 "