configure.ac

   1
   2 dnl Evolution-Data-Server version
   3 m4_define([eds_major_version], [3])
   4 m4_define([eds_minor_version], [7])
   5 m4_define([eds_micro_version], [5])
   6
   7 m4_define([eds_version],
   8         [eds_major_version.eds_minor_version.eds_micro_version])
   9
  10 dnl Base Version: This is for API/version tracking for things like
  11 dnl Bonobo server files.  This should always be the major/minor of
  12 dnl the stable version or stable version to be.  Note, this is set
  13 dnl the way it is so that GETTEXT_PACKAGE will be parsed correctly.
  14 BASE_VERSION=3.8
  15 m4_define([base_version], [3.8])
  16
  17 dnl This number is meaningless, but we're now stuck with it in our
  18 dnl library names for backward compatibility.
  19 m4_define([api_version], [1.2])
  20
  21 dnl Autoconf / Automake Initialization
  22 AC_PREREQ(2.62)
  23 AC_INIT([evolution-data-server],[eds_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=Evolution-Data-Server])
  24 AM_INIT_AUTOMAKE([gnu 1.10 tar-ustar dist-xz no-dist-gzip -Wall -Wno-portability foreign])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CONFIG_SRCDIR(README)
  27 AC_CONFIG_HEADERS(config.h)
  28
  29 dnl This is for the autoconf tests only - it set's the language we use
  30 AC_LANG(C)
  31
  32 dnl Automake 1.11 - Silent Build Rules
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34
  35 dnl Required Package Versions
  36
  37 dnl Keep these two definitions in agreement.
  38 m4_define([glib_minimum_version], [2.34])
  39 m4_define([glib_encoded_version], [GLIB_VERSION_2_34])
  40
  41 dnl Keep these two definitions in agreement.
  42 m4_define([gdk_minimum_version], [3.2])
  43 m4_define([gdk_encoded_version], [GDK_VERSION_3_2])
  44
  45 dnl Keep these two definitions in agreement.
  46 m4_define([soup_minimum_version], [2.38.1])
  47 m4_define([soup_encoded_version], [SOUP_VERSION_2_38])
  48
  49 m4_define([gcr_minimum_version], [3.4])
  50 m4_define([libsecret_minimum_version], [0.5])
  51 m4_define([libxml_minimum_version], [2.0.0])            dnl XXX Just a Guess
  52 m4_define([libgdata_minimum_version], [0.10])
  53 m4_define([sqlite_minimum_version], [3.5])
  54 m4_define([libical_minimum_version], [0.43])
  55
  56 dnl Optional Packages
  57 m4_define([goa_minimum_version], [3.2])
  58 m4_define([gweather_minimum_version], [3.5.0])
  59
  60 AC_SUBST([BASE_VERSION],[base_version])
  61 AC_SUBST([API_VERSION],[api_version])
  62 AC_DEFINE_UNQUOTED(BASE_VERSION, ["$BASE_VERSION"], [Base version (Major.Minor)])
  63 AC_DEFINE_UNQUOTED(API_VERSION, ["$API_VERSION"], [API version (Major.Minor)])
  64
  65 EDS_MAJOR_VERSION=eds_major_version
  66 EDS_MINOR_VERSION=eds_minor_version
  67 EDS_MICRO_VERSION=eds_micro_version
  68
  69 GLIB_GSETTINGS
  70
  71 dnl ******************************
  72 dnl D-Bus versioning
  73 dnl ******************************
  74 ADDRESS_BOOK_DBUS_SERVICE_NAME="org.gnome.evolution.dataserver.AddressBook4"
  75 CALENDAR_DBUS_SERVICE_NAME="org.gnome.evolution.dataserver.Calendar3"
  76 SOURCES_DBUS_SERVICE_NAME="org.gnome.evolution.dataserver.Sources1"
  77 USER_PROMPTER_DBUS_SERVICE_NAME="org.gnome.evolution.dataserver.UserPrompter0"
  78
  79 AC_DEFINE_UNQUOTED(
  80        ADDRESS_BOOK_DBUS_SERVICE_NAME,
  81        ["$ADDRESS_BOOK_DBUS_SERVICE_NAME"],
  82        [D-Bus service name for the address book factory])
  83
  84 AC_DEFINE_UNQUOTED(
  85        CALENDAR_DBUS_SERVICE_NAME,
  86        ["$CALENDAR_DBUS_SERVICE_NAME"],
  87        [D-Bus service name for the calendar factory])
  88
  89 AC_DEFINE_UNQUOTED(
  90         SOURCES_DBUS_SERVICE_NAME,
  91         ["$SOURCES_DBUS_SERVICE_NAME"],
  92         [D-Bus service name for the source registry])
  93
  94 AC_DEFINE_UNQUOTED(
  95         USER_PROMPTER_DBUS_SERVICE_NAME,
  96         ["$USER_PROMPTER_DBUS_SERVICE_NAME"],
  97         [D-Bus service name for the user prompter])
  98
  99 AC_SUBST(ADDRESS_BOOK_DBUS_SERVICE_NAME)
 100 AC_SUBST(CALENDAR_DBUS_SERVICE_NAME)
 101 AC_SUBST(SOURCES_DBUS_SERVICE_NAME)
 102 AC_SUBST(USER_PROMPTER_DBUS_SERVICE_NAME)
 103
 104 dnl ******************************
 105 dnl Libtool versioning
 106 dnl ******************************
 107 LIBEDATASERVER_CURRENT=17
 108 LIBEDATASERVER_REVISION=0
 109 LIBEDATASERVER_AGE=0
 110
 111 LIBECAL_CURRENT=15
 112 LIBECAL_REVISION=0
 113 LIBECAL_AGE=0
 114
 115 LIBEDATACAL_CURRENT=20
 116 LIBEDATACAL_REVISION=0
 117 LIBEDATACAL_AGE=0
 118
 119 LIBEDATABOOK_CURRENT=16
 120 LIBEDATABOOK_REVISION=0
 121 LIBEDATABOOK_AGE=0
 122
 123 LIBEBOOK_CURRENT=17
 124 LIBEBOOK_REVISION=1
 125 LIBEBOOK_AGE=3
 126
 127 LIBCAMEL_CURRENT=43
 128 LIBCAMEL_REVISION=0
 129 LIBCAMEL_AGE=0
 130
 131 LIBEBACKEND_CURRENT=6
 132 LIBEBACKEND_REVISION=0
 133 LIBEBACKEND_AGE=0
 134
 135 AC_SUBST(EDS_MAJOR_VERSION)
 136 AC_SUBST(EDS_MINOR_VERSION)
 137 AC_SUBST(EDS_MICRO_VERSION)
 138 AC_SUBST(LIBEDATASERVER_CURRENT)
 139 AC_SUBST(LIBEDATASERVER_REVISION)
 140 AC_SUBST(LIBEDATASERVER_AGE)
 141 AC_SUBST(LIBECAL_CURRENT)
 142 AC_SUBST(LIBECAL_REVISION)
 143 AC_SUBST(LIBECAL_AGE)
 144 AC_SUBST(LIBEDATACAL_CURRENT)
 145 AC_SUBST(LIBEDATACAL_REVISION)
 146 AC_SUBST(LIBEDATACAL_AGE)
 147 AC_SUBST(LIBEBOOK_CURRENT)
 148 AC_SUBST(LIBEBOOK_REVISION)
 149 AC_SUBST(LIBEBOOK_AGE)
 150 AC_SUBST(LIBEDATABOOK_CURRENT)
 151 AC_SUBST(LIBEDATABOOK_REVISION)
 152 AC_SUBST(LIBEDATABOOK_AGE)
 153 AC_SUBST(LIBCAMEL_CURRENT)
 154 AC_SUBST(LIBCAMEL_REVISION)
 155 AC_SUBST(LIBCAMEL_AGE)
 156 AC_SUBST(LIBEBACKEND_CURRENT)
 157 AC_SUBST(LIBEBACKEND_REVISION)
 158 AC_SUBST(LIBEBACKEND_AGE)
 159
 160 dnl **************************************
 161 dnl Put the ACLOCAL flags in the Makefile
 162 dnl **************************************
 163 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 164
 165 dnl ******************************
 166 dnl Compiler Warning Flags
 167 dnl ******************************
 168 AS_COMPILER_FLAGS(WARNING_FLAGS,
 169         "-Wall -Wextra
 170         -Wdeprecated-declarations
 171         -Wno-missing-field-initializers
 172         -Wno-sign-compare
 173         -Wno-unused-parameter
 174         -Wdeclaration-after-statement
 175         -Werror-implicit-function-declaration
 176         -Wformat-security -Winit-self
 177         -Wmissing-declarations -Wmissing-include-dirs
 178         -Wmissing-noreturn -Wnested-externs -Wpointer-arith
 179         -Wredundant-decls -Wundef -Wwrite-strings")
 180 AC_SUBST(WARNING_FLAGS)
 181
 182 dnl Other useful compiler warnings for test builds only.
 183 dnl These may produce warnings we have no control over,
 184 dnl or false positives we don't always want to see.
 185 dnl
 186 dnl     -Wformat-nonliteral
 187 dnl     -Wmissing-format-attribute
 188 dnl     -Wshadow
 189 dnl     -Wstrict-aliasing=2
 190
 191 AM_CPPFLAGS="$WARNING_FLAGS -fno-strict-aliasing"
 192
 193 dnl *******************************
 194 dnl Check for --enable-strict
 195 dnl *******************************
 196 AC_ARG_ENABLE([strict],
 197         [AS_HELP_STRING([--enable-strict],
 198         [enable strict building, like without deprecated symbols (default=auto); auto enables strict building only if .git subdirectory exists])],
 199         [enable_strict=$enableval], [enable_strict=auto])
 200
 201 AC_MSG_CHECKING([if strict building is enabled])
 202 if test "x$enable_strict" = xauto; then
 203         dnl Be strict when compiling with .git subdirectory
 204         if test -d .git ; then
 205                 enable_strict=yes
 206         else
 207                 enable_strict=no
 208         fi
 209 fi
 210 AC_MSG_RESULT([$enable_strict])
 211
 212 if test "x$enable_strict" = xyes; then
 213         AM_CPPFLAGS="$AM_CPPFLAGS -DG_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"
 214 fi
 215
 216 dnl Warn about API usage that violates our minimum requirements.
 217 AM_CPPFLAGS="$AM_CPPFLAGS -DGLIB_VERSION_MAX_ALLOWED=glib_encoded_version"
 218 AM_CPPFLAGS="$AM_CPPFLAGS -DGDK_VERSION_MAX_ALLOWED=gdk_encoded_version"
 219 AM_CPPFLAGS="$AM_CPPFLAGS -DSOUP_VERSION_MAX_ALLOWED=soup_encoded_version"
 220
 221 dnl These will suppress warnings about newly-deprecated symbols.  Ideally
 222 dnl these settings should match our minimum requirements and we will clean
 223 dnl up any new deprecation warnings after bumping our minimum requirements.
 224 dnl But if the warnings get to be overwhelming, use fixed versions instead.
 225 AM_CPPFLAGS="$AM_CPPFLAGS -DGLIB_VERSION_MIN_REQUIRED=glib_encoded_version"
 226 AM_CPPFLAGS="$AM_CPPFLAGS -DGDK_VERSION_MIN_REQUIRED=gdk_encoded_version"
 227 AM_CPPFLAGS="$AM_CPPFLAGS -DSOUP_VERSION_MIN_REQUIRED=soup_encoded_version"
 228
 229 AC_SUBST(AM_CPPFLAGS)
 230
 231 dnl ******************************
 232 dnl Initialize maintainer mode
 233 dnl ******************************
 234 AM_MAINTAINER_MODE([enable])
 235
 236 if test "x$enable_maintainer_mode" = "xyes" ; then
 237         AC_DEFINE(ENABLE_MAINTAINER_MODE, 1, [Configured with enabled maintainer mode])
 238 fi
 239
 240 AC_PROG_CC
 241 AC_PROG_CPP
 242 AC_C_INLINE
 243 AM_PROG_CC_C_O
 244 AC_PROG_INSTALL
 245 AC_PROG_LN_S
 246 AC_PROG_MAKE_SET
 247
 248 dnl For gen-western-table.py
 249 AM_PATH_PYTHON
 250
 251 dnl GCC 4.4 got more aggressive in its aliasing optimizations, changing
 252 dnl behavior that -- according to the C99 standard -- is supposed to be
 253 dnl undefined.  We may still have aliasing abuses lying around that rely
 254 dnl on GCC's previous "undefined" behavior, so disable strict-aliasing
 255 dnl optimization until we can find and fix all the abuses.
 256 dnl (AC_PROG_CC must run first to set the GCC variable.)
 257 dnl XXX This really belongs in AM_CFLAGS.
 258 if test "x${GCC}" = "xyes"; then
 259         CFLAGS="$CFLAGS -fno-strict-aliasing"
 260 fi
 261
 262 dnl ******************************
 263 dnl I18N stuff
 264 dnl ******************************
 265 IT_PROG_INTLTOOL([0.35.5])
 266
 267 GETTEXT_PACKAGE=evolution-data-server-$BASE_VERSION
 268 AC_SUBST(GETTEXT_PACKAGE)
 269 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Package name for gettext])
 270
 271 localedir='$(prefix)/$(DATADIRNAME)/locale'
 272 AC_SUBST(localedir)
 273
 274 dnl ******************************
 275 dnl Initialize libtool
 276 dnl ******************************
 277 LT_PREREQ(2.2)
 278 LT_INIT(disable-static win32-dll)
 279
 280 PKG_PROG_PKG_CONFIG
 281
 282 dnl This relies on $SED, which is defined in ltmain.sh, which
 283 dnl is invoked by LT_INIT (at least I think that's how it works).
 284 GNOME_CODE_COVERAGE
 285
 286 dnl ******************************
 287 dnl Gtk Doc stuff
 288 dnl ******************************
 289 GTK_DOC_CHECK([1.14],[--flavour no-tmpl])
 290
 291 dnl The private D-Bus documentation is for developers only.
 292 AC_ARG_WITH([private-docs],
 293         AS_HELP_STRING([--with-private-docs],
 294         [Build documentation for private libraries ]
 295         [(requires --enable-gtk-doc) [default=no]],),
 296         [with_private_docs="$withval"],[with_private_docs="no"])
 297 AM_CONDITIONAL(WITH_PRIVATE_DOCS, [test x$with_private_docs = xyes])
 298
 299 dnl This must appear after AC_CANONICAL_HOST, which defines $host.
 300 case "$host" in
 301 *openbsd*|*freebsd*)
 302         dnl Do not set '-Wl,--no-undefined' on freebsd/openbsd
 303         ;;
 304 *)
 305         LDFLAGS="$LDFLAGS -Wl,--no-undefined"
 306         ;;
 307 esac
 308
 309 dnl ******************************
 310 dnl Check for Win32
 311 dnl ******************************
 312 AC_MSG_CHECKING([for Win32])
 313 case "$host" in
 314 *-mingw*)
 315         os_win32='yes'
 316         NO_UNDEFINED='-no-undefined'
 317         SOCKET_LIBS='-lws2_32 -ldnsapi'
 318         DL_LIB=''
 319         LIBEXECDIR_IN_SERVER_FILE='../../../libexec'
 320         AC_CACHE_VAL(ac_cv_have_addrinfo, [ac_cv_have_addrinfo=yes])
 321         AC_DEFINE(_WIN32_WINNT, 0x501, [To get getaddrinfo etc declarations])
 322         ;;
 323 *openbsd*|*freebsd*)
 324         os_win32='no'
 325         NO_UNDEFINED=''
 326         SOCKET_LIBS=''
 327         DL_LIB=''
 328         LIBEXECDIR_IN_SERVER_FILE="$libexecdir"
 329         ;;
 330 *)
 331         os_win32='no'
 332         NO_UNDEFINED=''
 333         SOCKET_LIBS=''
 334         DL_LIB='-ldl'
 335         LIBEXECDIR_IN_SERVER_FILE="$libexecdir"
 336         ;;
 337 esac
 338 AC_MSG_RESULT([$os_win32])
 339 AM_CONDITIONAL(OS_WIN32, [test $os_win32 = yes])
 340 AC_SUBST(NO_UNDEFINED)
 341 AC_SUBST(SOCKET_LIBS)
 342 AC_SUBST(LIBEXECDIR_IN_SERVER_FILE)
 343
 344 dnl **************************************
 345 dnl Check for posix compatible sys/wait.h
 346 dnl **************************************
 347 AC_HEADER_SYS_WAIT
 348
 349 dnl ************************************
 350 dnl Check for posix compatible alloca()
 351 dnl ************************************
 352 AC_FUNC_ALLOCA
 353
 354 dnl ******************************
 355 dnl Checks for functions
 356 dnl ******************************
 357 AC_CHECK_FUNCS(fsync strptime strtok_r nl_langinfo)
 358
 359 dnl ***********************************
 360 dnl Check for base dependencies early.
 361 dnl ***********************************
 362 PKG_CHECK_MODULES(GNOME_PLATFORM,
 363         [gio-2.0 >= glib_minimum_version
 364         gmodule-2.0 >= glib_minimum_version
 365         gtk+-3.0 >= gdk_minimum_version
 366         libxml-2.0 >= libxml_minimum_version
 367         libsoup-2.4 >= soup_minimum_version
 368         libgdata >= libgdata_minimum_version])
 369
 370 if test x$os_win32 = xno; then
 371         PKG_CHECK_MODULES(GIO_UNIX, [gio-unix-2.0])
 372 fi
 373
 374 dnl *******************************
 375 dnl Check for GNOME Online Accounts
 376 dnl *******************************
 377 AC_ARG_ENABLE([goa],
 378         [AS_HELP_STRING([--enable-goa],
 379         [enable GNOME Online Accounts support (default=yes)])],
 380         [enable_goa=$enableval], [enable_goa=yes])
 381 AC_MSG_CHECKING([if GNOME Online Accounts support is enabled])
 382 AC_MSG_RESULT([$enable_goa])
 383 if test "x$enable_goa" = xyes; then
 384         PKG_CHECK_MODULES([GOA], [goa-1.0 >= goa_minimum_version],,
 385         [AC_MSG_ERROR([
 386
 387         goa-1.0 not found (or version < goa_minimum_version)
 388
 389         If you want to disable GNOME Online Accounts support,
 390         please append --disable-goa to configure.
 391         ])])
 392
 393         AC_DEFINE(HAVE_GOA, 1, [Define to 1 if you have the goa-1.0 package.])
 394 fi
 395 AM_CONDITIONAL(HAVE_GOA, [test x$enable_goa = xyes])
 396
 397 dnl GoaPasswordBased was introduced in version 3.5.
 398 if `$PKG_CONFIG --atleast-version=3.5 goa-1.0`; then
 399         AC_DEFINE(HAVE_GOA_PASSWORD_BASED,1,[Have GoaPasswordBased in goa-1.0])
 400 fi
 401
 402 dnl ***********************************
 403 dnl Check for GNOME Keyring.
 404 dnl ***********************************
 405 if test x$os_win32 = xno; then
 406         PKG_CHECK_MODULES(LIBSECRET,
 407                 [libsecret-unstable >= libsecret_minimum_version])
 408 fi
 409 AC_SUBST(LIBSECRET_CFLAGS)
 410 AC_SUBST(LIBSECRET_LIBS)
 411
 412 dnl **********************************************************
 413 dnl gcr-base is needed for secure password exchange over D-Bus
 414 dnl **********************************************************
 415 PKG_CHECK_MODULES(GCR_BASE, [gcr-base-3 >= gcr_minimum_version])
 416 AC_SUBST(GCR_BASE_CFLAGS)
 417 AC_SUBST(GCR_BASE_LIBS)
 418
 419 LIBICAL_REQUIRED=libical_minimum_version
 420 AC_SUBST(LIBICAL_REQUIRED)
 421
 422 dnl ******************************
 423 dnl regex check
 424 dnl ******************************
 425 AC_CHECK_FUNCS(regexec,,[AC_CHECK_LIB(regex,regexec,
 426                         [REGEX_LIBS=-lregex
 427                         AC_DEFINE(HAVE_REGEXEC,1,[Define to 1 if you have the regexec function.])],
 428                         [AC_MSG_ERROR([No regex library found])])])
 429 AC_SUBST(REGEX_LIBS)
 430
 431 dnl ******************************
 432 dnl libdb checking
 433 dnl ******************************
 434 AC_ARG_WITH([libdb],
 435         AS_HELP_STRING([--with-libdb=PREFIX],
 436         [Prefix where libdb is installed]),
 437         [libdb_prefix="$withval"], [libdb_prefix='${prefix}'])
 438
 439 DB_CFLAGS="-I$libdb_prefix/include"
 440 DB_LIBS="-L$libdb_prefix/lib -ldb"
 441
 442 AC_MSG_CHECKING([Berkeley DB])
 443 save_cflags=$CFLAGS; CFLAGS=$DB_CFLAGS
 444 save_libs=$LIBS; LIBS="$DB_LIBS"
 445 AC_LINK_IFELSE([AC_LANG_PROGRAM(
 446         [[#include <db.h>]],
 447         [[db_create(NULL, NULL, 0)]])],
 448         [AC_MSG_RESULT([yes])],
 449         [AC_MSG_ERROR([Cannot find libdb])])
 450 CFLAGS=$save_cflags
 451 LIBS=$save_libs
 452 AC_SUBST(DB_CFLAGS)
 453 AC_SUBST(DB_LIBS)
 454
 455 dnl ******************************
 456 dnl iconv checking
 457 dnl ******************************
 458 have_iconv="no"
 459 save_LIBS="$LIBS"
 460 LIBS="$LIBS -liconv"
 461 AC_CACHE_CHECK([for iconv in -liconv], [ac_cv_libiconv],
 462         AC_LINK_IFELSE([AC_LANG_PROGRAM(
 463         [[
 464                 #include <iconv.h>
 465                 #include <stdlib.h>
 466         ]],
 467         [[
 468                 iconv_t cd;
 469                 cd = iconv_open ("UTF-8", "ISO-8859-1");
 470         ]]
 471         )],[ac_cv_libiconv=yes],[ac_cv_libiconv=no]))
 472
 473 if test "x$ac_cv_libiconv" = "xyes"; then
 474         ICONV_LIBS="-liconv"
 475         if test "x$os_win32" = "xyes"; then
 476                 dnl Don't pointlessly auto-export the global symbols
 477                 dnl from a potentially static libiconv.a
 478                 ICONV_LIBS="$ICONV_LIBS -Wl,--exclude-libs=libiconv.a"
 479         fi
 480         have_iconv="yes"
 481 else
 482         LIBS="$save_LIBS"
 483         AC_CHECK_FUNC(iconv, [have_iconv=yes], [have_iconv=no])
 484 fi
 485
 486 if test "x$have_iconv" = "xyes"; then
 487         if test "x$ac_cv_libiconv" = "xno"; then
 488                 AC_CHECK_FUNCS(gnu_get_libc_version)
 489         fi
 490 AC_CACHE_CHECK([if iconv() handles UTF-8], [ac_cv_libiconv_utf8],
 491         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 492                 #include <iconv.h>
 493                 #include <stdlib.h>
 494                 #include <string.h>
 495                 #ifdef HAVE_GNU_GET_LIBC_VERSION
 496                 #include <gnu/libc-version.h>
 497                 #endif
 498                 int main() {
 499                         char *jp = "\x1B\x24\x42\x46\x7C\x4B\x5C\x38\x6C";
 500                         char *utf8 = "\xE6\x97\xA5\xE6\x9C\xAC\xE8\xAA\x9E";
 501                         char *transbuf = malloc (10), *trans = transbuf;
 502                         iconv_t cd;
 503                         size_t jp_len = strlen (jp), utf8_len = 10;
 504                         size_t utf8_real_len = strlen (utf8);
 505
 506                         #ifdef HAVE_GNU_GET_LIBC_VERSION
 507                         /* glibc 2.1.2's iconv is broken in hard to test ways. */
 508                         if (!strcmp (gnu_get_libc_version (), "2.1.2"))
 509                                 exit (1);
 510                         #endif
 511
 512                         cd = iconv_open ("UTF-8", "ISO-2022-JP");
 513                         if (cd == (iconv_t) -1)
 514                                 exit (1);
 515                         if (iconv (cd, &jp, &jp_len, &trans, &utf8_len) == -1 || jp_len != 0)
 516                                 exit (1);
 517                         if (memcmp (utf8, transbuf, utf8_real_len) != 0)
 518                                 exit (1);
 519                         return (0);}
 520                 ]])
 521         ],[ac_cv_libiconv_utf8=yes],[ac_cv_libiconv_utf8=no; have_iconv=no],[ac_cv_libiconv_utf8=hopefully]))
 522 fi
 523
 524 if test "x$have_iconv" = "xno"; then
 525         AC_MSG_ERROR([You need to install a working iconv implementation, such as ftp://ftp.gnu.org/pub/gnu/libiconv])
 526 fi
 527 AC_SUBST(ICONV_LIBS)
 528
 529 CFLAGS="$CFLAGS -I$srcdir"
 530
 531 AC_MSG_CHECKING([preferred charset name formats for system iconv])
 532 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 533         #define CONFIGURE_IN
 534         #include "iconv-detect.c"
 535         ]])],
 536         [AC_MSG_RESULT([found])],
 537         [AC_MSG_RESULT([not found])
 538                 AC_MSG_WARN([
 539                 *** The iconv-detect program was unable to determine the
 540                 *** preferred charset name formats recognized by your
 541                 *** iconv library. It is suggested that you install a
 542                 *** working iconv library such as the one found at
 543                 *** ftp://ftp.gnu.org/pub/gnu/libiconv
 544         ])],
 545         [if test "x$os_win32" = xyes; then
 546                 AC_MSG_RESULT([using known win32 result])
 547                 echo '/* This is an auto-generated header, DO NOT EDIT! */' > iconv-detect.h
 548                 echo  >>iconv-detect.h
 549                 echo '#define ICONV_ISO_D_FORMAT "iso-%d-%d"' >>iconv-detect.h
 550                 echo '#define ICONV_ISO_S_FORMAT "iso-%d-%s"' >>iconv-detect.h
 551                 echo '#define ICONV_10646 "UCS-4BE"' >>iconv-detect.h
 552         else
 553                 AC_MSG_RESULT([unknown])
 554                 AC_MSG_WARN([
 555                 *** We can't determine the preferred charset name formats
 556                 *** recognized by your iconv library. You are
 557                 *** cross-compiling and supposed to know what you are doing.
 558                 *** Please construct the iconv-detect.h file manually.
 559                 ])
 560         fi
 561 ])
 562
 563 CFLAGS="$save_CFLAGS"
 564 LIBS="$save_LIBS"
 565
 566 AC_ARG_ENABLE([backtraces],
 567         [AS_HELP_STRING([--enable-backtraces],
 568         [enable backtraces for camel_pointer_tracker (default=no)])],
 569         [enable_backtraces=$enableval], [enable_backtraces=no])
 570
 571 if test "x$enable_backtraces" = xyes; then
 572         dnl ****************************
 573         dnl Check for backtrace_symbols function and dwfl from elfutils
 574         dnl ****************************
 575         AC_MSG_CHECKING([libc backtrace_symbols function])
 576         AC_LINK_IFELSE([AC_LANG_PROGRAM(
 577                 [[#include <execinfo.h>]],
 578                 [[{ void *bt[1]; backtrace_symbols (bt, backtrace(bt, 1)); }]])],
 579                 [AC_DEFINE(HAVE_BACKTRACE_SYMBOLS, 1, [libc provides backtrace_symbols function]) ac_cv_have_bsf=yes],[ac_cv_have_bsf=no])
 580         AC_MSG_RESULT([$ac_cv_have_bsf])
 581
 582         if test "x$ac_cv_have_bsf" = xyes; then
 583                 LIBS="$LIBS -ldw"
 584
 585                 AC_MSG_CHECKING([elfutils/libdwfl])
 586                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
 587                         [[#include <elfutils/libdwfl.h>]],
 588                         [[{
 589                                 Dwfl *dwfl;
 590                                 Dwfl_Module *module;
 591                                 Dwarf_Addr module_low_addr;
 592                                 Dwfl_Line *line;
 593
 594                                 dwfl_standard_find_debuginfo;
 595                                 dwfl_linux_proc_find_elf;
 596                                 dwfl_begin (NULL);
 597                                 dwfl_linux_proc_report (NULL, 1);
 598                                 dwfl_report_end (NULL, NULL, NULL);
 599                                 dwfl_end (NULL);
 600                                 dwfl_module_addrname (NULL, NULL);
 601                                 dwfl_module_getsrc (NULL, NULL);
 602                                 dwfl_lineinfo (NULL, NULL, NULL, NULL, NULL, NULL);
 603                                 DWARF_CB_ABORT; DWARF_CB_OK;
 604                                 dwfl_getmodules (NULL, NULL, NULL, 0);
 605                         }]])],
 606                         [AC_DEFINE(HAVE_ELFUTILS_LIBDWFL, 1, [have elfutils/libdwfl.h functions]) ac_cv_have_elfdwfl=yes],[ac_cv_have_elfdwfl=no])
 607                 AC_MSG_RESULT([$ac_cv_have_elfdwfl])
 608
 609                 LIBS="$save_LIBS"
 610
 611                 if test "x$ac_cv_have_elfdwfl" = xyes; then
 612                         LIBDWFL_LIBS="-ldw"
 613                         AC_SUBST(LIBDWFL_LIBS)
 614                 fi
 615         fi
 616 fi
 617
 618 dnl ******************************
 619 dnl Check for nl_langinfo features
 620 dnl ******************************
 621 EVO_CHECK_LANGINFO([CODESET])
 622 EVO_CHECK_LANGINFO([_NL_ADDRESS_COUNTRY_AB2])
 623
 624 dnl *******************************************************
 625 dnl Check to see if strftime supports the use of %l and %k
 626 dnl *******************************************************
 627 AC_MSG_CHECKING([for %l and %k support in strftime])
 628 AC_RUN_IFELSE([AC_LANG_SOURCE(
 629         [[      #include <stdlib.h>
 630                 #include <string.h>
 631                 #include <time.h>
 632                 int main(int argc, char **argv) {
 633                 char buf[10];
 634                 time_t rawtime;
 635                 struct tm *timeinfo;
 636
 637                 time(&rawtime);
 638                 timeinfo=localtime(&rawtime);
 639                 buf[0] = '\0';
 640                 strftime(buf, 10, "%lx%k", timeinfo);
 641
 642                 if (buf[0] == '\0' || buf[0] == 'x' || strstr(buf, "l") || strstr(buf, "k"))
 643                         exit(1);
 644                 else
 645                         exit(0);
 646                 return 0;
 647                 }
 648         ]]
 649         )],[AC_DEFINE(HAVE_LKSTRFTIME, 1, [strftime supports use of l and k]) ac_cv_lkstrftime=yes],[ac_cv_lkstrftime=no],[ac_cv_lkstrftime=no])
 650 AC_MSG_RESULT([$ac_cv_lkstrftime])
 651
 652 dnl ********************************************************************************
 653 dnl security extension support (SSL and S/MIME)
 654 dnl
 655 dnl The following voodoo does detection of mozilla libraries (nspr and nss)
 656 dnl needed by Camel (SSL and S/MIME).
 657 dnl
 658 dnl The Evolution security extensions are only built if these libraries are found
 659 dnl ********************************************************************************
 660 msg_smime="no"
 661
 662 AC_ARG_ENABLE([smime],
 663         AS_HELP_STRING([--enable-smime],
 664         [Enable SMIME support through Mozilla nss @<:@default=yes@:>@ ]),
 665         [enable_smime="$enableval"],[enable_smime="yes"])
 666
 667 AC_ARG_WITH([nspr-includes],
 668         AS_HELP_STRING([--with-nspr-includes],
 669         [Prefix of Mozilla nspr4 includes.]),
 670         [with_nspr_includes="$withval"])
 671
 672 AC_ARG_WITH([nspr-libs],
 673         AS_HELP_STRING([--with-nspr-libs],
 674         [Prefix of Mozilla nspr4 libs.]),
 675         [with_nspr_libs="$withval"])
 676
 677 AC_ARG_WITH([nss-includes],
 678         AS_HELP_STRING([--with-nss-includes],
 679         [Prefix of Mozilla nss3 includes.]),
 680         [with_nss_includes="$withval"])
 681
 682 AC_ARG_WITH([nss-libs],
 683         AS_HELP_STRING([--with-nss-libs],
 684         [Prefix of Mozilla nss3 libs.]),
 685         [with_nss_libs="$withval"])
 686
 687 if test -n "${with_nspr_includes}" || test -n "${with_nspr_libs}" || test -n "${with_nss_includes}" || test -n "${with_nss_libs}"; then
 688         check_manually="yes"
 689 else
 690         check_manually="no"
 691 fi
 692
 693 dnl check if pkg-config files exist (which are only shipped by distributions, not upstream)
 694 if test "x${check_manually}" = "xno"; then
 695         AC_MSG_CHECKING(Mozilla NSPR pkg-config module name)
 696         mozilla_nspr_pcs="nspr mozilla-nspr firefox-nspr xulrunner-nspr seamonkey-nspr"
 697         for pc in $mozilla_nspr_pcs; do
 698                 if $PKG_CONFIG --exists $pc; then
 699                         AC_MSG_RESULT($pc)
 700                         mozilla_nspr=$pc
 701                         break;
 702                 fi
 703         done
 704
 705         AC_MSG_CHECKING(Mozilla NSS pkg-config module name)
 706         mozilla_nss_pcs="nss mozilla-nss firefox-nss xulrunner-nss seamonkey-nss"
 707         for pc in $mozilla_nss_pcs; do
 708                 if $PKG_CONFIG --exists $pc; then
 709                         AC_MSG_RESULT($pc)
 710                         mozilla_nss=$pc
 711                         break;
 712                 fi
 713         done
 714
 715         if test -n "$mozilla_nspr" -a -n "$mozilla_nss"; then
 716                 if test "x$enable_smime" = "xyes"; then
 717                         AC_DEFINE(ENABLE_SMIME,1,[Define if SMIME should be enabled])
 718                         msg_smime="yes"
 719                 fi
 720                 MANUAL_NSPR_CFLAGS=""
 721                 MANUAL_NSPR_LIBS=""
 722                 MANUAL_NSS_CFLAGS=""
 723                 MANUAL_NSS_LIBS=""
 724         else
 725                 check_manually="yes"
 726                 mozilla_nspr=""
 727                 mozilla_nss=""
 728         fi
 729 fi
 730
 731 if test "x${check_manually}" = "xyes"; then
 732 dnl ******************
 733 dnl Check for NSPR 4
 734 dnl ******************
 735         AC_MSG_CHECKING([for Mozilla nspr4 includes])
 736                 CPPFLAGS_save="$CPPFLAGS"
 737                 if test -n "$with_nspr_includes"; then
 738                         CPPFLAGS="$CPPFLAGS -I$with_nspr_includes"
 739                 fi
 740
 741                 AC_CHECK_HEADERS(nspr.h prio.h,
 742                 [moz_nspr_includes="yes"],[moz_nspr_includes="no"])
 743                 CPPFLAGS="$CPPFLAGS_save"
 744
 745                 if test "x${moz_nspr_includes}" = "xyes"; then
 746                         MANUAL_NSPR_CFLAGS="-I$with_nspr_includes"
 747                 else
 748                         AC_MSG_FAILURE([NSPR headers not found. Use --with-nspr-includes to specify the include dir of NSPR.])
 749                 fi
 750         AC_MSG_RESULT([$moz_nspr_includes])
 751
 752         AC_MSG_CHECKING([for Mozilla nspr libraries])
 753                 CFLAGS_save="$CFLAGS"
 754                 LDFLAGS_save="$LDFLAGS"
 755                 LIBS_save="$LIBS"
 756                 nsprlibs="$DL_LIB -lplc4 -lplds4 -lnspr4"
 757
 758                 CFLAGS="$CFLAGS $MANUAL_NSPR_CFLAGS"
 759                 LIBS="$nsprlibs"
 760                 dnl Test to protect from giving libtool an -L , which results in failure (used below,too)
 761                 if test -n "${with_nspr_libs}"; then
 762                         LDFLAGS="$LDFLAGS -L$with_nspr_libs"
 763                 else
 764                         LDFLAGS="$LDFLAGS"
 765                 fi
 766
 767                 AC_LINK_IFELSE([AC_LANG_CALL([],[PR_Init])],
 768                 [moz_nspr_libs="yes"],[moz_nspr_libs="no"])
 769
 770                 CFLAGS="$CFLAGS_save"
 771                 LDFLAGS="$LDFLAGS_save"
 772                 LIBS="$LIBS_save"
 773
 774                 if test "x${moz_nspr_libs}" = "xyes"; then
 775                         if test -n "${with_nspr_libs}"; then
 776                                 MANUAL_NSPR_LIBS="-L$with_nspr_libs $nsprlibs"
 777                         else
 778                                 MANUAL_NSPR_LIBS="$nsprlibs"
 779                         fi
 780                 else
 781                         AC_MSG_FAILURE([NSPR libs not found. Use --with-nspr-libs to specify the libdir of NSPR.])
 782                 fi
 783         AC_MSG_RESULT([$moz_nspr_libs])
 784
 785 dnl *****************
 786 dnl Check for NSS 3
 787 dnl *****************
 788         AC_MSG_CHECKING([for Mozilla nss3 includes])
 789                 CPPFLAGS_save="$CPPFLAGS"
 790                 CPPFLAGS="$CPPFLAGS -I$with_nspr_includes -I$with_nss_includes"
 791
 792                 AC_CHECK_HEADERS(nss.h ssl.h smime.h,
 793                 [moz_nss_includes="yes"],[moz_nss_includes="no"])
 794                 CPPFLAGS="$CPPFLAGS_save"
 795
 796                 if test "x${moz_nss_includes}" = "xyes"; then
 797                         MANUAL_NSS_CFLAGS="-I$with_nss_includes"
 798                 else
 799                         AC_MSG_FAILURE([NSS headers not found. Use --with-nss-includes to specify the include dir of NSS.])
 800                 fi
 801         AC_MSG_RESULT($moz_nss_includes)
 802
 803         AC_MSG_CHECKING([for Mozilla nss libraries])
 804                 LDFLAGS_save="$LDFLAGS"
 805                 LIBS_save="$LIBS"
 806                 nsslibs="-lssl3 -lsmime3 -lnss3"
 807
 808                 LIBS="$nsslibs $nsprlibs"
 809                 dnl Test to protect from giving libtool an -L , which results in failure (used below,too)
 810                 if test -n "${with_nss_libs}"; then
 811                         LDFLAGS="$LDFLAGS -L$with_nss_libs $MANUAL_NSPR_LIBS"
 812                 else
 813                         LDFLAGS="$LDFLAGS $LDFLAGS_NSPR $MANUAL_NSPR_LIBS"
 814                 fi
 815
 816                 AC_LINK_IFELSE([AC_LANG_CALL([],[NSS_Init])],
 817                 [moz_nss_libs="yes"],[moz_nss_libs="no"])
 818                 LDFLAGS="$LDFLAGS_save"
 819                 LIBS="$LIBS_save"
 820
 821                 if test "x${moz_nss_libs}" = "xyes"; then
 822                         if test "x${enable_smime}" = "xyes"; then
 823                                 AC_DEFINE(ENABLE_SMIME,1,[Define if SMIME should be enabled])
 824                                 msg_smime="yes"
 825                         fi
 826                         if test -n "${with_nss_libs}"; then
 827                                 MANUAL_NSS_LIBS="-L$with_nss_libs $nsslibs"
 828                         else
 829                                 MANUAL_NSS_LIBS="$nsslibs"
 830                         fi
 831                 else
 832                         AC_MSG_FAILURE([NSS libs not found. Use --with-nss-libs to specify the libdir of NSS.])
 833                 fi
 834         AC_MSG_RESULT([$moz_nss_libs])
 835
 836         MANUAL_NSS_CFLAGS="$MANUAL_NSPR_CFLAGS $MANUAL_NSS_CFLAGS"
 837         MANUAL_NSS_LIBS="$MANUAL_NSPR_LIBS $MANUAL_NSS_LIBS"
 838 fi
 839
 840 AM_CONDITIONAL(ENABLE_SMIME, test "x$msg_smime" != "xno")
 841
 842 dnl For pkgconfig files.
 843 AC_SUBST(mozilla_nss)
 844 AC_SUBST(mozilla_nspr)
 845
 846 AC_SUBST(MANUAL_NSPR_CFLAGS)
 847 AC_SUBST(MANUAL_NSPR_LIBS)
 848 AC_SUBST(MANUAL_NSS_CFLAGS)
 849 AC_SUBST(MANUAL_NSS_LIBS)
 850
 851 dnl ******************************
 852 dnl system mail stuff
 853 dnl ******************************
 854 AC_PATH_PROG(SENDMAIL, sendmail, [/usr/sbin/sendmail], [/usr/sbin:/usr/lib])
 855 AC_DEFINE_UNQUOTED(SENDMAIL_PATH, "$SENDMAIL", [Path to a sendmail binary, or equivalent])
 856
 857 AC_MSG_CHECKING([system mail directory])
 858 if test -d /var/mail -a '!' -h /var/mail ; then
 859         system_mail_dir="/var/mail"
 860 else
 861         system_mail_dir="/var/spool/mail"
 862 fi
 863 AC_DEFINE_UNQUOTED(SYSTEM_MAIL_DIR, "$system_mail_dir", [Directory local mail is delivered to])
 864
 865 case `ls -ld $system_mail_dir 2>&1 | awk '{print $1;}'` in
 866         d??????rw?)
 867                 CAMEL_LOCK_HELPER_USER=""
 868                 CAMEL_LOCK_HELPER_GROUP=""
 869                 system_mail_perm="world writable"
 870         ;;
 871         d???rw????)
 872                 CAMEL_LOCK_HELPER_USER=""
 873                 CAMEL_LOCK_HELPER_GROUP=`ls -ld $system_mail_dir 2>&1 | awk '{print $4;}'`
 874                 system_mail_perm="writable by group $CAMEL_LOCK_HELPER_GROUP"
 875         ;;
 876         drw???????)
 877                 CAMEL_LOCK_HELPER_USER=`ls -ld $system_mail_dir 2>&1 | awk '{print $3;}'`
 878                 CAMEL_LOCK_HELPER_GROUP=""
 879                 system_mail_perm="writable by user $CAMEL_LOCK_HELPER_USER"
 880         ;;
 881         *)
 882                 CAMEL_LOCK_HELPER_USER=""
 883                 CAMEL_LOCK_HELPER_GROUP=""
 884                 system_mail_perm="???"
 885         ;;
 886 esac
 887
 888 AC_MSG_RESULT([$system_mail_dir, $system_mail_perm])
 889 AC_SUBST(CAMEL_LOCK_HELPER_USER)
 890 AC_SUBST(CAMEL_LOCK_HELPER_GROUP)
 891
 892 dnl ******************************
 893 dnl Timezone checks
 894 dnl ******************************
 895 AC_CACHE_CHECK(for tm_gmtoff in struct tm, [ac_cv_struct_tm_gmtoff],
 896         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 897         [[      #include <time.h>       ]],
 898         [[
 899                 struct tm tm;
 900                 tm.tm_gmtoff = 1;
 901         ]]
 902         )],[ac_cv_struct_tm_gmtoff=yes],[ac_cv_struct_tm_gmtoff=no]))
 903 if test "x$ac_cv_struct_tm_gmtoff" = "xyes"; then
 904         AC_DEFINE(HAVE_TM_GMTOFF, 1, [Define if struct tm has a tm_gmtoff member])
 905 else
 906         AC_CACHE_CHECK(for timezone variable, [ac_cv_var_timezone],
 907                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 908                 [[      #include <time.h> ]],
 909                 [[      timezone = 1;   ]]
 910                 )],[ac_cv_var_timezone=yes],[ac_cv_var_timezone=no]))
 911         if test "x$ac_cv_var_timezone" = "xyes"; then
 912                 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if libc defines a timezone variable])
 913                 AC_CACHE_CHECK(for altzone variable, [ac_cv_var_altzone],
 914                         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 915                         [[      #include <time.h>       ]],
 916                         [[      altzone = 1; ]]
 917                         )],[ac_cv_var_altzone=yes],[ac_cv_var_altzone=no]))
 918                 if test "x$ac_cv_var_altzone" = "xyes"; then
 919                         AC_DEFINE(HAVE_ALTZONE, 1, [Define if libc defines an altzone variable])
 920                 fi
 921         else
 922                 AC_MSG_ERROR([unable to find a way to determine timezone])
 923         fi
 924 fi
 925
 926 dnl ******************************
 927 dnl ctime_r prototype
 928 dnl ******************************
 929 AC_CACHE_CHECK([if ctime_r wants three arguments], [ac_cv_ctime_r_three_args],
 930 [
 931         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 932         [[      #include <time.h> ]],
 933         [[      char *buf;
 934                 time_t date;
 935                 ctime_r (&date, buf, 100); ]]
 936         )],[ac_cv_ctime_r_three_args=yes],[ac_cv_ctime_r_three_args=no])
 937 ])
 938
 939 if test "x$ac_cv_ctime_r_three_args" = "xyes" ; then
 940         AC_DEFINE(CTIME_R_THREE_ARGS, 1, [Solaris-style ctime_r])
 941 fi
 942
 943 dnl ******************************
 944 dnl gethostbyname_r prototype
 945 dnl ******************************
 946 AC_CHECK_FUNCS(gethostbyname_r,[
 947 AC_CACHE_CHECK([if gethostbyname_r wants five arguments], [ac_cv_gethostbyname_r_five_args],
 948 [
 949         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 950         [[
 951                 #include "confdefs.h"
 952                 #include <sys/types.h>
 953                 #include <sys/socket.h>
 954                 #include <netinet/in.h>
 955                 #include <netdb.h>
 956                 #define BUFSIZE (sizeof(struct hostent)+10)
 957         ]],
 958         [[
 959                 struct hostent hent;
 960                 char buffer[BUFSIZE];
 961                 int bufsize=BUFSIZE;
 962                 int h_errno;
 963                 (void)gethostbyname_r ("www.ximian.com", &hent, buffer, bufsize, &h_errno);
 964         ]]
 965         )],[ac_cv_gethostbyname_r_five_args=yes],[ac_cv_gethostbyname_r_five_args=no])
 966 ])])
 967
 968 if test "x$ac_cv_gethostbyname_r_five_args" = "xyes" ; then
 969         AC_DEFINE(GETHOSTBYNAME_R_FIVE_ARGS, 1, [Solaris-style gethostbyname_r])
 970 fi
 971
 972 dnl ******************************
 973 dnl gethostbyaddr_r prototype
 974 dnl ******************************
 975 AC_CHECK_FUNCS(gethostbyaddr_r,[
 976 AC_CACHE_CHECK([if gethostbyaddr_r wants seven arguments], [ac_cv_gethostbyaddr_r_seven_args],
 977 [
 978         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 979         [[
 980                 #include "confdefs.h"
 981                 #include <sys/types.h>
 982                 #include <sys/socket.h>
 983                 #include <netinet/in.h>
 984                 #include <netdb.h>
 985                 #define BUFSIZE (sizeof(struct hostent)+10)
 986         ]],
 987         [[
 988                 struct hostent hent;
 989                 char buffer[BUFSIZE];
 990                 int bufsize=BUFSIZE;
 991                 int h_errno;
 992                 (void)gethostbyaddr_r ("www.ximian.com", 14, AF_INET, &hent, buffer, bufsize, &h_errno); ]]
 993         )],[ac_cv_gethostbyaddr_r_seven_args=yes],[ac_cv_gethostbyaddr_r_seven_args=no])
 994 ])])
 995
 996 if test "x$ac_cv_gethostbyaddr_r_seven_args" = "xyes" ; then
 997         AC_DEFINE(GETHOSTBYADDR_R_SEVEN_ARGS, 1, [Solaris-style gethostbyaddr_r])
 998 fi
 999
1000 dnl ******************************
1001 dnl stat(v)fs location/type
1002 dnl ******************************
1003 AC_CHECK_HEADER([sys/statvfs.h],
1004         [AC_DEFINE([HAVE_SYS_STATVFS_H], 1, [Have <sys/statvfs.h>])],,
1005         [[      #if HAVE_SYS_STATVFS_H
1006                 #include <sys/statvfs.h>
1007                 #endif
1008         ]])
1009 AC_CHECK_FUNCS(statvfs)
1010
1011 AC_CHECK_HEADER([sys/param.h],
1012         [AC_DEFINE([HAVE_SYS_PARAM_H], 1, [Have <sys/param.h>])],,
1013         [[      #if HAVE_SYS_PARAM_H
1014                 #include <sys/param.h>
1015                 #endif
1016         ]])
1017 AC_CHECK_HEADER([sys/mount.h],
1018         [AC_DEFINE([HAVE_SYS_MOUNT_H], 1, [Have <sys/mount.h>])],,
1019         [[      #if HAVE_SYS_MOUNT_H
1020                 #include <sys/mount.h>
1021                 #endif
1022         ]])
1023 AC_CHECK_FUNCS(statfs)
1024
1025 dnl ******************************
1026 dnl IPv6 support and getaddrinfo calls
1027 dnl ******************************
1028 AC_CACHE_CHECK([if system supports getaddrinfo and getnameinfo], [ac_cv_have_addrinfo],
1029 [
1030         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1031         [[      #include "confdefs.h"
1032                 #include <sys/types.h>
1033                 #include <sys/socket.h>
1034                 #include <netinet/in.h>
1035                 #include <netdb.h>
1036                 #include <stddef.h>
1037         ]],
1038         [[      #ifndef NI_MAXHOST
1039                 #define NI_MAXHOST      1025
1040                 #endif
1041
1042                 #ifndef NI_MAXSERV
1043                 #define NI_MAXSERV      32
1044                 #endif
1045
1046                 struct addrinfo hints, *res;
1047                 struct sockaddr_in6 sin6;
1048                 int af = AF_INET6;
1049                 char host[NI_MAXHOST];
1050                 char serv[NI_MAXSERV];
1051
1052                 getaddrinfo ("www.ximian.com", NULL, &hints, &res);
1053                 freeaddrinfo (res);
1054                 getnameinfo((struct sockaddr *)&sin6, sizeof(sin6), host, sizeof(host), serv, sizeof(serv), 0); ]]
1055         )],[ac_cv_have_addrinfo=yes],[ac_cv_have_addrinfo=no])
1056 ])
1057
1058 if test "x$ac_cv_have_addrinfo" = "xno" ; then
1059         AC_DEFINE(NEED_ADDRINFO,1,[Enable getaddrinfo emulation])
1060         if test "x$enable_ipv6" = "xyes" ; then
1061                 AC_MSG_ERROR([system doesn't support necessary interfaces for ipv6 support])
1062         fi
1063         msg_ipv6="no"
1064 else
1065         AC_ARG_ENABLE([ipv6],
1066         AS_HELP_STRING([--enable-ipv6=no/yes],
1067         [Enable support for resolving IPv6 addresses.]),
1068         [enable_ipv6=$enableval],[enable_ipv6=yes])
1069         if test "x$enable_ipv6" = "xyes"; then
1070                 msg_ipv6="yes"
1071                 AC_DEFINE(ENABLE_IPv6,1,[Enable IPv6 support])
1072                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1073                 [[      #include "confdefs.h"
1074                         #include <sys/types.h>
1075                         #include <sys/socket.h>
1076                         #include <netinet/in.h>
1077                         #include <netdb.h>
1078                 ]],
1079                 [[      struct addrinfo hints;
1080                         hints.ai_flags = AI_ADDRCONFIG;
1081                 ]]
1082                 )],[AC_DEFINE(HAVE_AI_ADDRCONFIG,1,[Define if the system defines the AI_ADDRCONFIG flag for getaddrinfo])],[])
1083         else
1084                 msg_ipv6="no"
1085         fi
1086 fi
1087
1088 AM_CONDITIONAL(ENABLE_IPv6, [test "x$enable_ipv6" = "xyes"])
1089
1090 AC_CHECK_HEADER([wspiapi.h],
1091         [AC_DEFINE([HAVE_WSPIAPI_H], 1, [Have <wspiapi.h>])],,)
1092
1093 dnl **********************************
1094 dnl Weather calendar backend support
1095 dnl **********************************
1096 AC_MSG_CHECKING([if we should build the weather calendar backend])
1097 AC_ARG_ENABLE([weather],
1098         [AS_HELP_STRING([--enable-weather],
1099         [Build the weather calendar backend (default=yes)])],
1100         [use_gweather=$enableval], [use_gweather=yes])
1101
1102 AC_MSG_RESULT([$use_gweather])
1103 if test "x$use_gweather" = "xyes"; then
1104         PKG_CHECK_MODULES([LIBGWEATHER], [gweather-3.0 >= gweather_minimum_version],[],
1105         [AC_MSG_ERROR([The weather calendar backend requires GWeather >= gweather_minimum_version. Alternatively, you may specify --disable-weather as a configure option to avoid building the backend.])])
1106 fi
1107 AM_CONDITIONAL(ENABLE_WEATHER, [test $use_gweather = yes])
1108
1109 dnl ******************************
1110 dnl NNTP support.
1111 dnl ******************************
1112 AC_ARG_ENABLE([nntp],
1113         AS_HELP_STRING([--enable-nntp],
1114         [Build Usenet news (NNTP) backend]),
1115         [enable_nntp=$enableval],[enable_nntp=yes])
1116 if test "x$enable_nntp" = "xyes"; then
1117         AC_DEFINE(ENABLE_NNTP,1,[Build NNTP backend])
1118         msg_nntp="yes"
1119 else
1120         msg_nntp="no"
1121 fi
1122 AM_CONDITIONAL(ENABLE_NNTP, [test x$enable_nntp = xyes])
1123
1124 AC_DEFINE(HANDLE_LIBICAL_MEMORY, 1, [Define it once memory returned by libical is free'ed properly])
1125
1126 dnl ******************************
1127 dnl File locking
1128 dnl ******************************
1129 AC_ARG_ENABLE([dot-locking],
1130         AS_HELP_STRING([--enable-dot-locking=yes/no],
1131         [Enable support for locking mail files with dot locking]),
1132         [enable_dot_locking=$enableval],[enable_dot_locking=yes])
1133
1134 if test "x$os_win32" != "xyes" -a "x$enable_dot_locking" = "xyes"; then
1135         AC_DEFINE(USE_DOT,1,[Define to use dot locking for mbox files])
1136         msg_dot="yes"
1137 else
1138         msg_dot="no"
1139 fi
1140
1141 AC_ARG_ENABLE([file-locking],
1142         AS_HELP_STRING([--enable-file-locking=fcntl/flock/no],
1143         [Enable support for locking mail files with file locking]),
1144         [],[enable_file_locking=fcntl])
1145
1146 if test "x$os_win32" != "xyes" -a "x$enable_file_locking" = "xfcntl"; then
1147         AC_DEFINE(USE_FCNTL,1,[Define to use fcntl locking for mbox files])
1148         msg_file="fcntl"
1149 else
1150         if test "x$os_win32" != "xyes" -a "x$enable_file_locking" = "xflock"; then
1151                 AC_DEFINE(USE_FLOCK,1,[Define to use flock locking for mbox files])
1152                 msg_file="flock"
1153         else
1154                 msg_file="no"
1155         fi
1156 fi
1157
1158 dnl ******************************
1159 dnl sendmail operation
1160 dnl ******************************
1161 AC_MSG_CHECKING([for SunOS broken spool format])
1162 if test "x$host_os" = "xsunos" ; then
1163         with_broken_spool="yes"
1164 fi
1165
1166 AC_ARG_WITH([broken-spool],
1167         AS_HELP_STRING([--with-broken-spool=yes/no],
1168         [Using SunOS/Solaris sendmail which has a broken spool format]),
1169         [with_broken_spool=$enableval],[with_broken_spool=${with_broken_spool:=no}])
1170
1171 if test "x$with_broken_spool" = "xyes"; then
1172         AC_DEFINE(HAVE_BROKEN_SPOOL,1,[Define if mail delivered to the system mail directory is in broken Content-Length format])
1173 fi
1174
1175 AC_MSG_RESULT([$with_broken_spool])
1176
1177 dnl ******************************
1178 dnl DBus call timeout
1179 dnl ******************************
1180
1181 AC_ARG_WITH([dbus-call-timeout],
1182         AS_HELP_STRING([--with-dbus-call-timeout=miliseconds],
1183         [Default timeout used when invoking g_dbus_proxy_call() family functions in EBook and ECal library (default=-1)]),
1184         [ac_cv_dbus_call_timeout=$withval],[ac_cv_dbus_call_timeout=-1])
1185
1186 DEFAULT_EDS_DBUS_TIMEOUT=$ac_cv_dbus_call_timeout
1187 AC_SUBST(DEFAULT_EDS_DBUS_TIMEOUT)
1188
1189 dnl ***********
1190 dnl Kerberos 5
1191 dnl ***********
1192 EVO_KRB5_SUPPORT(no)
1193
1194 dnl ******************************
1195 dnl Purify support
1196 dnl ******************************
1197 EVO_PURIFY_SUPPORT
1198
1199 dnl ******************************
1200 dnl LDAP support.
1201 dnl ******************************
1202 if test "x$os_win32" != "xyes"; then
1203         EVO_LDAP_CHECK(no)
1204         case $with_openldap in
1205         no)
1206                 msg_ldap="no"
1207         ;;
1208         *)
1209                 case $with_static_ldap in
1210                 yes)
1211                         msg_ldap="$with_openldap (static)"
1212                         ;;
1213                 *)
1214                         msg_ldap="$with_openldap (dynamic)"
1215                         ;;
1216                 esac
1217         esac
1218
1219 dnl SunLDAP support, but if OpenLDAP support, skip check SunLDAP.
1220         if test "x$with_openldap" = "xno" ; then
1221                 EVO_SUNLDAP_CHECK(no)
1222                 case $with_sunldap in
1223                 no)
1224                         msg_ldap="no"
1225                         ;;
1226                 *)
1227                         case $with_static_sunldap in
1228                         yes)
1229                                 msg_ldap="$with_sunldap (static)"
1230                                 ;;
1231                         *)
1232                                 msg_ldap="$with_sunldap (dynamic)"
1233                                 ;;
1234                 esac
1235         esac
1236         else
1237                 with_sunldap="no"
1238         fi
1239         AM_CONDITIONAL(SUNLDAP, [test "$with_sunldap" != no])
1240
1241         LDAP_CFLAGS="$LDAP_CFLAGS -DLDAP_DEPRECATED"
1242 else
1243         dnl Win32 LDAP support
1244         LDAP_CFLAGS="-DLDAP_DEPRECATED"
1245         LDAP_LIBS="-lwldap32"
1246         AC_SUBST(LDAP_CFLAGS)
1247         AC_SUBST(LDAP_LIBS)
1248         AC_DEFINE(HAVE_LDAP,1,[Define if you have LDAP support])
1249         AM_CONDITIONAL(ENABLE_LDAP, true)
1250         AM_CONDITIONAL(SUNLDAP, false)
1251         msg_ldap="yes"
1252 fi
1253
1254 dnl ******************************
1255 dnl GObject marshalling
1256 dnl ******************************
1257 AM_PATH_GLIB_2_0
1258
1259 dnl We use AC_SUBST_FILE because AC_SUBST won't deal with newlines
1260 EVO_MARSHAL_RULE=$srcdir/marshal.mk
1261 AC_SUBST_FILE(EVO_MARSHAL_RULE)
1262
1263 dnl ******************************
1264 dnl Utility macro to set compiler flags for a specific lib.
1265 dnl EVO_SET_COMPILE_FLAGS(VAR-PREFIX, DEPS, EXTRA-CFLAGS, EXTRA-LIBS)
1266 dnl ******************************
1267 AC_DEFUN([EVO_SET_COMPILE_FLAGS], [
1268         PKG_CHECK_MODULES([$1], [$2])
1269         $1_CFLAGS="[$]$1_CFLAGS $3 "
1270         $1_LIBS="[$]$1_LIBS $4 "
1271 ])
1272
1273 dnl ******************************
1274 dnl sqlite3 flags
1275 dnl ******************************
1276 PKG_CHECK_MODULES(SQLITE3, [sqlite3 >= sqlite_minimum_version])
1277
1278 if test "x$enable_maintainer_mode" = "xyes" ; then
1279         EVO_SET_COMPILE_FLAGS(FACTORY_GTK, "gtk+-3.0")
1280         AC_SUBST(FACTORY_GTK_CFLAGS)
1281         AC_SUBST(FACTORY_GTK_LIBS)
1282 fi
1283
1284 dnl ******************************
1285 dnl libedataserver flags
1286 dnl ******************************
1287 E_DATA_SERVER_DEPS="gio-2.0 gmodule-2.0 libsecret-1 libxml-2.0 libsoup-2.4 $mozilla_nspr"
1288
1289 EVO_SET_COMPILE_FLAGS(E_DATA_SERVER, $E_DATA_SERVER_DEPS, $MANUAL_NSPR_CFLAGS, $MANUAL_NSPR_LIBS)
1290 AC_SUBST(E_DATA_SERVER_CFLAGS)
1291 AC_SUBST(E_DATA_SERVER_LIBS)
1292
1293 dnl ******************************
1294 dnl libebackend flags
1295 dnl ******************************
1296 E_BACKEND_DEPS="gio-2.0 gmodule-2.0 libsecret-1 libsoup-2.4 libxml-2.0"
1297
1298 EVO_SET_COMPILE_FLAGS(E_BACKEND, $E_BACKEND_DEPS)
1299 AC_SUBST(E_BACKEND_CFLAGS)
1300 AC_SUBST(E_BACKEND_LIBS)
1301
1302 dnl ******************************
1303 dnl evolution-addressbook flags
1304 dnl ******************************
1305 EVOLUTION_ADDRESSBOOK_DEPS="gio-2.0 libxml-2.0 libsoup-2.4 libsecret-1"
1306
1307 EVO_SET_COMPILE_FLAGS(EVOLUTION_ADDRESSBOOK, $EVOLUTION_ADDRESSBOOK_DEPS)
1308 AC_SUBST(EVOLUTION_ADDRESSBOOK_CFLAGS)
1309 AC_SUBST(EVOLUTION_ADDRESSBOOK_LIBS)
1310
1311 dnl ******************************
1312 dnl evolution-calendar flags
1313 dnl ******************************
1314 EVOLUTION_CALENDAR_DEPS="gio-2.0 libical >= libical_minimum_version libsoup-2.4 libxml-2.0 libsecret-1"
1315
1316 dnl *****
1317 dnl libical.pc from libical-0.43 has a bug in it's CFlags.
1318 dnl It wants apps to include <libical/ical*.h> but it's CFlags make it difficult
1319 dnl to differentiate between <libical/ical.h> and <ical.h>
1320 dnl We have fixed all our instances to use <libical/ical.h>. Until the .pc from
1321 dnl libical is fixed, we have to work-around the buggy CFlags.
1322 dnl *****
1323         LIBICAL_EXTRA_CFLAGS=" -I`$PKG_CONFIG --variable=includedir libical` "
1324         LIBICAL_EXTRA_LIBS=""
1325         AC_SUBST(LIBICAL_EXTRA_CFLAGS)
1326         AC_SUBST(LIBICAL_EXTRA_LIBS)
1327
1328         EVO_SET_COMPILE_FLAGS(EVOLUTION_CALENDAR, $EVOLUTION_CALENDAR_DEPS, $LIBICAL_EXTRA_CFLAGS, $LIBICAL_EXTRA_LIBS)
1329         AC_SUBST(EVOLUTION_CALENDAR_CFLAGS)
1330         AC_SUBST(EVOLUTION_CALENDAR_LIBS)
1331
1332         dnl ****************************
1333         dnl Check for ical_set_unknown_token_handling_setting function
1334         dnl ****************************
1335         AC_MSG_CHECKING([ical_set_unknown_token_handling_setting function])
1336         save_cflags=$CFLAGS; CFLAGS=$EVOLUTION_CALENDAR_CFLAGS
1337         save_libs=$LIBS; LIBS="$EVOLUTION_CALENDAR_LIBS"
1338         AC_LINK_IFELSE([AC_LANG_PROGRAM(
1339                 [[#include <libical/ical.h>]],
1340                 [[ical_set_unknown_token_handling_setting (ICAL_DISCARD_TOKEN)]])],
1341                 [AC_DEFINE(HAVE_ICAL_UNKNOWN_TOKEN_HANDLING, 1, [libical provides ical_set_unknown_token_handling_setting function]) ac_cv_have_iuth=yes],[ac_cv_have_iuth=no])
1342         CFLAGS=$save_cflags
1343         LIBS=$save_libs
1344         AC_MSG_RESULT([$ac_cv_have_iuth])
1345
1346 dnl ******************************
1347 dnl Google flags
1348 dnl ******************************
1349 LIBGDATA_REQUIRED=libgdata_minimum_version
1350 AC_SUBST(LIBGDATA_REQUIRED)
1351
1352 EVO_SET_COMPILE_FLAGS(GDATA, libgdata)
1353 AC_SUBST(GDATA_CFLAGS)
1354 AC_SUBST(GDATA_LIBS)
1355
1356 EVO_SET_COMPILE_FLAGS(SOUP, libsoup-2.4)
1357 AC_SUBST(SOUP_CFLAGS)
1358 AC_SUBST(SOUP_LIBS)
1359
1360 dnl ******************************
1361 dnl Camel flags
1362 dnl ******************************
1363 SQLITE_REQUIRED=sqlite_minimum_version
1364 AC_SUBST(SQLITE_REQUIRED)
1365
1366 zlib_found="false"
1367 dnl deflateInit is a #define, use deflateEnd instead
1368 AC_CHECK_LIB([z], [deflateEnd], [AC_CHECK_HEADER(zlib.h, [zlib_found=true])])
1369
1370 if test "x$zlib_found" = "xfalse"; then
1371         AC_MSG_ERROR([*** zlib is required])
1372 fi
1373
1374 dnl ******************************
1375 dnl Checks for large file support
1376 dnl ******************************
1377 AC_ARG_ENABLE([largefile],
1378         AS_HELP_STRING([--enable-largefile],
1379         [enable support for large files [[default=no]]]),
1380         [],[enable_largefile="yes"])
1381
1382 if test "x$enable_largefile" != "xno"; then
1383         AC_SYS_LARGEFILE
1384         AC_CACHE_CHECK([for _LARGEFILE64_SOURCE value needed for large files], [ac_cv_largefile64_source],
1385         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1386         [[      #include <sys/types.h>
1387                 #include <sys/stat.h>
1388                 #include <fcntl.h>
1389         ]],
1390         [[      int fd = open ("__o_largefile", O_CREAT | O_RDWR | O_LARGEFILE, 0644);  ]]
1391         )],[ac_cv_largefile64_source="no"],
1392                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1393                 [[      #define _LARGEFILE64_SOURCE
1394                         #include <sys/types.h>
1395                         #include <sys/stat.h>
1396                         #include <fcntl.h>
1397                 ]],
1398                 [[ int fd = open ("__o_largefile", O_CREAT | O_RDWR | O_LARGEFILE, 0644); ]])],[ac_cv_largefile64_source="yes"],
1399                 [ac_cv_largefile64_source="unknown"])])
1400         ])
1401
1402         enable_largefile="no"
1403
1404         if test "x$ac_cv_largefile64_source" = "xyes"; then
1405                 LARGEFILE_CFLAGS="-D_LARGEFILE64_SOURCE"
1406                 enable_largefile="yes"
1407         elif test "x$ac_cv_largefile64_source" = "xunknown"; then
1408                 AC_DEFINE(O_LARGEFILE, 0, [Define to 0 if your system does not have the O_LARGEFILE flag])
1409         fi
1410
1411         if test -n "$ac_cv_sys_large_files" -a "x$ac_cv_sys_large_files" != "xno"; then
1412                 LARGEFILE_CFLAGS="$LARGEFILE_CFLAGS -D_LARGE_FILES"
1413                 enable_largefile="yes"
1414         fi
1415
1416         if test "x$ac_cv_sys_file_offset_bits" != "xno"; then
1417                 LARGEFILE_CFLAGS="$LARGEFILE_CFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits"
1418                 enable_largefile="yes"
1419         fi
1420 else
1421         AC_DEFINE(O_LARGEFILE, 0, [Define to 0 if your system does not have the O_LARGEFILE flag])
1422         LARGEFILE_CFLAGS=""
1423 fi
1424
1425 AM_CONDITIONAL(ENABLE_LARGEFILE, [test "x$enable_largefile" = "xyes"])
1426
1427 EVO_SET_COMPILE_FLAGS(CAMEL, gio-2.0 gmodule-2.0 $mozilla_nss sqlite3 >= sqlite_minimum_version, $KRB5_CFLAGS $MANUAL_NSS_CFLAGS $LARGEFILE_CFLAGS, -lz $KRB5_LIBS $MANUAL_NSS_LIBS)
1428 AC_SUBST(CAMEL_CFLAGS)
1429 AC_SUBST(CAMEL_LIBS)
1430
1431 dnl ******************************
1432 dnl Special directories
1433 dnl ******************************
1434
1435 dnl If you add something here, consider whether or not you also
1436 dnl need to add it to one or more .pc.in files (for Connector,
1437 dnl etc)
1438
1439 privdatadir='${datadir}'/evolution-data-server
1440 AC_SUBST(privdatadir)
1441
1442 privincludedir='${includedir}'/evolution-data-server
1443 AC_SUBST(privincludedir)
1444
1445 privlibdir='${libdir}'/evolution-data-server
1446 AC_SUBST(privlibdir)
1447
1448 imagesdir='${datadir}'/pixmaps/evolution-data-server
1449 AC_SUBST(imagesdir)
1450
1451 moduledir='${privlibdir}'/registry-modules
1452 AC_SUBST(moduledir)
1453
1454 ebook_backenddir='${privlibdir}'/addressbook-backends
1455 AC_SUBST(ebook_backenddir)
1456
1457 ecal_backenddir='${privlibdir}'/calendar-backends
1458 AC_SUBST(ecal_backenddir)
1459
1460 ro_sourcesdir='${privdatadir}'/ro-sources
1461 AC_SUBST(ro_sourcesdir)
1462
1463 rw_sourcesdir='${privdatadir}'/rw-sources
1464 AC_SUBST(rw_sourcesdir)
1465
1466 if test "x$use_gweather" = "xyes"; then
1467         weatherdatadir="$privdatadir/weather"
1468         AC_SUBST(weatherdatadir)
1469 fi
1470
1471 dnl separate camel from e-d-s? or should it be under the same spot? same for now.
1472 camel_providerdir='${privlibdir}'/camel-providers
1473 AC_SUBST(camel_providerdir)
1474
1475 dnl *******************
1476 dnl D-BUS service stuff
1477 dnl *******************
1478 m4_pattern_allow([AM_V_GEN])
1479 EVO_SUBST_SERVICE_RULE='%.service: %.service.in Makefile ; $(AM_V_GEN) sed -e "s|\@libexecdir\@|$(libexecdir)|" -e s"|\@ADDRESS_BOOK_DBUS_SERVICE_NAME\@|$(ADDRESS_BOOK_DBUS_SERVICE_NAME)|" -e "s|\@CALENDAR_DBUS_SERVICE_NAME\@|$(CALENDAR_DBUS_SERVICE_NAME)|" -e "s|\@SOURCES_DBUS_SERVICE_NAME\@|$(SOURCES_DBUS_SERVICE_NAME)|" -e "s|\@USER_PROMPTER_DBUS_SERVICE_NAME\@|$(USER_PROMPTER_DBUS_SERVICE_NAME)|" $< > $@'
1480 AC_SUBST(EVO_SUBST_SERVICE_RULE)
1481
1482 dnl ******************************
1483 dnl GLib stuff
1484 dnl ******************************
1485 GLIB_GSETTINGS
1486 AM_PATH_GLIB_2_0
1487
1488 dnl We use AC_SUBST_FILE because AC_SUBST won't deal with newlines
1489 EVO_MARSHAL_RULE=$srcdir/marshal.mk
1490 AC_SUBST_FILE(EVO_MARSHAL_RULE)
1491
1492 dnl ******************************
1493 dnl gperf stuff
1494 dnl ******************************
1495 AC_PATH_PROG(GPERF, gperf, [no])
1496 if test "x$GPERF" = "xno"; then
1497   AC_MSG_ERROR([You need gperf to build evolution-data-server])
1498 fi
1499
1500 GOBJECT_INTROSPECTION_CHECK([0.9.12])
1501
1502 dnl ******************************
1503 dnl Vala binding
1504 dnl ******************************
1505 AC_ARG_ENABLE(vala-bindings,
1506         AC_HELP_STRING([--enable-vala-bindings],
1507         [build the EXPERIMENTAL Vala bindings]),
1508         enable_vala_bindings=$enableval,
1509         enable_vala_bindings=no)
1510
1511 if test x$enable_vala_bindings = xyes; then
1512   if test "x$INTROSPECTION_SCANNER" = x; then
1513     AC_MSG_ERROR([GObject-Introspection must be enabled for Vala bindings])
1514   fi
1515
1516   AM_PROG_VALAC([0.13.0])
1517   have_vala=yes
1518
1519   AC_PATH_PROG(VALAC, valac, valac)
1520   AC_SUBST(VALAC)
1521   AC_SUBST(VALAFLAGS)
1522
1523   AC_PATH_PROG([VAPIGEN], [vapigen], [false])
1524
1525   if test "x$VAPIGEN" = "xfalse"; then
1526     AC_MSG_ERROR([vapigen not found. Was vala compiled with --enable-vapigen?])
1527   fi
1528
1529   AC_SUBST(VAPIGEN)
1530 fi
1531
1532 AM_CONDITIONAL([HAVE_VALA], [test "x$have_vala" = "xyes"])
1533 AC_SUBST(HAVE_VALA)
1534
1535 dnl ******************************
1536 dnl Makefiles
1537 dnl ******************************
1538 export privlibdir
1539 export privincludedir
1540 export privdatadir
1541
1542 AC_CONFIG_FILES([
1543 Makefile
1544 evolution-data-server-zip
1545 evolution-data-server.pc
1546 addressbook/Makefile
1547 addressbook/libebook/Makefile
1548 addressbook/libebook/libebook.pc
1549 addressbook/libedata-book/Makefile
1550 addressbook/libedata-book/libedata-book.pc
1551 addressbook/libegdbus/Makefile
1552 addressbook/backends/Makefile
1553 addressbook/backends/file/Makefile
1554 addressbook/backends/ldap/Makefile
1555 addressbook/backends/google/Makefile
1556 addressbook/backends/google/tests/Makefile
1557 addressbook/backends/webdav/Makefile
1558 art/Makefile
1559 calendar/Makefile
1560 calendar/libecal/Makefile
1561 calendar/libecal/libecal.pc
1562 calendar/libedata-cal/Makefile
1563 calendar/libedata-cal/libedata-cal.pc
1564 calendar/libegdbus/Makefile
1565 calendar/backends/Makefile
1566 calendar/backends/caldav/Makefile
1567 calendar/backends/file/Makefile
1568 calendar/backends/http/Makefile
1569 calendar/backends/contacts/Makefile
1570 calendar/backends/weather/Makefile
1571 camel/Makefile
1572 camel/providers/Makefile
1573 camel/providers/imapx/Makefile
1574 camel/providers/local/Makefile
1575 camel/providers/nntp/Makefile
1576 camel/providers/pop3/Makefile
1577 camel/providers/sendmail/Makefile
1578 camel/providers/smtp/Makefile
1579 camel/tests/Makefile
1580 camel/tests/folder/Makefile
1581 camel/tests/lib/Makefile
1582 camel/tests/message/Makefile
1583 camel/tests/mime-filter/Makefile
1584 camel/tests/misc/Makefile
1585 camel/tests/smime/Makefile
1586 camel/camel.pc
1587 data/Makefile
1588 data/sources/Makefile
1589 libebackend/Makefile
1590 libebackend/libebackend.pc
1591 libedataserver/Makefile
1592 libedataserver/eds-version.h
1593 libedataserver/libedataserver.pc
1594 modules/Makefile
1595 modules/cache-reaper/Makefile
1596 modules/gnome-online-accounts/Makefile
1597 modules/google-backend/Makefile
1598 modules/trust-prompt/Makefile
1599 modules/yahoo-backend/Makefile
1600 private/Makefile
1601 services/Makefile
1602 services/evolution-addressbook-factory/Makefile
1603 services/evolution-calendar-factory/Makefile
1604 services/evolution-source-registry/Makefile
1605 services/evolution-user-prompter/Makefile
1606 tests/Makefile
1607 tests/libebook/Makefile
1608 tests/libebook/client/Makefile
1609 tests/libebook/vcard/Makefile
1610 tests/libecal/Makefile
1611 tests/libecal/client/Makefile
1612 tests/libedata-cal/Makefile
1613 tests/libedataserver/Makefile
1614 tests/test-server-utils/Makefile
1615 tests/test-server-utils/services/Makefile
1616 tests/test-server-utils/services/org.gnome.evolution.dataserver.AddressBook.service
1617 tests/test-server-utils/services/org.gnome.evolution.dataserver.Calendar.service
1618 tests/test-server-utils/services/org.gnome.evolution.dataserver.Sources.service
1619 docs/Makefile
1620 docs/reference/Makefile
1621 docs/reference/addressbook/Makefile
1622 docs/reference/addressbook/libebook/Makefile
1623 docs/reference/addressbook/libedata-book/Makefile
1624 docs/reference/calendar/Makefile
1625 docs/reference/calendar/libecal/Makefile
1626 docs/reference/calendar/libedata-cal/Makefile
1627 docs/reference/camel/Makefile
1628 docs/reference/libedataserver/Makefile
1629 docs/reference/libebackend/Makefile
1630 docs/reference/private/Makefile
1631 po/Makefile.in
1632 vala/Makefile
1633 ])
1634 AC_OUTPUT
1635
1636 echo "
1637         evolution-data-server has been configured as follows:
1638         Weather calendar:       $use_gweather
1639         Mail Directory:         $system_mail_dir, $system_mail_perm
1640         LDAP support:           $msg_ldap
1641         NNTP support:           $msg_nntp
1642         Kerberos 5:             $msg_krb5
1643         SMIME support:          $msg_smime
1644         IPv6 support:           $msg_ipv6
1645         Dot Locking:            $msg_dot
1646         File Locking:           $msg_file
1647         Large files:            $enable_largefile
1648         Gtk Doc:                $enable_gtk_doc
1649         Introspection:          $enable_introspection
1650         Vala bindings:          $enable_vala_bindings
1651         GNOME Online Accounts   $enable_goa
1652         Code coverage (gcov):   $enable_code_coverage
1653         Strict building:        $enable_strict
1654 "