configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [7])
   5 m4_define([v_mic], [8])
   6 m4_define([v_rev], m4_esyscmd([(git rev-list --count HEAD 2>/dev/null || echo 0) | tr -d '\n']))dnl
   7 ##--   When released, remove the dnl on the below line
   8 m4_undefine([v_rev])
   9 ##--   When doing snapshots - change soname. remove dnl on below line
  10 dnl m4_define([relname], [ver-pre-svn-07])
  11 dnl m4_define([v_rel], [-release ver-pre-svn-07])
  12 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  13 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  14 m4_define([lt_cur], m4_eval(v_maj + v_min))
  15 m4_define([lt_rev], v_mic)
  16 m4_define([lt_age], v_min)
  17 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19
  20 AC_INIT([embryo], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  21 AC_PREREQ([2.52])
  22 AC_CONFIG_SRCDIR([configure.ac])
  23 AC_CONFIG_MACRO_DIR([m4])
  24
  25 AC_CONFIG_HEADERS([config.h])
  26 AH_TOP([
  27 #ifndef EFL_CONFIG_H__
  28 #define EFL_CONFIG_H__
  29 ])
  30 AH_BOTTOM([
  31 #endif /* EFL_CONFIG_H__ */
  32 ])
  33
  34 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_LIBTOOL_WIN32_DLL
  38 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  39 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  40 AC_PROG_LIBTOOL
  41
  42 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  43 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  44 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  45 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  46 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  47 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  48 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  49 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  50 version_info="lt_cur:lt_rev:lt_age"
  51 release_info="v_rel"
  52 AC_SUBST(version_info)
  53 AC_SUBST(release_info)
  54 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  55 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  56 VMAJ=v_maj
  57 AC_SUBST(VMAJ)
  58
  59 ### Default options with respect to host
  60
  61 AC_CANONICAL_BUILD
  62 AC_CANONICAL_HOST
  63
  64 requirement_embryo=""
  65 embryoincludedir="${datadir}/include"
  66
  67
  68 ### Additional options to configure
  69
  70 EFL_ENABLE_BIN([embryo-cc])
  71
  72
  73 ### Checks for programs
  74 AC_PROG_CC
  75
  76 # doxygen program for documentation building
  77
  78 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
  79
  80 # pkg-config
  81
  82 PKG_PROG_PKG_CONFIG
  83
  84 # Check whether pkg-config supports Requires.private
  85 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
  86    pkgconfig_requires_private="Requires.private"
  87 else
  88    pkgconfig_requires_private="Requires"
  89 fi
  90 AC_SUBST(pkgconfig_requires_private)
  91
  92
  93 ### Checks for libraries
  94
  95 # Evil library for compilation on Windows
  96
  97 EFL_EMBRYO_BUILD=""
  98 case "$host_os" in
  99    mingw*)
 100    PKG_CHECK_MODULES([EVIL], [evil >= 1.7.8])
 101    AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 102    requirement_embryo="evil ${requirement_embryo}"
 103    EFL_EMBRYO_BUILD="-DEFL_EMBRYO_BUILD"
 104    ;;
 105 esac
 106 AC_SUBST(EFL_EMBRYO_BUILD)
 107
 108 # For embryo_cc_prefix.c
 109 PKG_CHECK_MODULES([EINA], [eina >= 1.7.8])
 110
 111 ### Checks for portability layer
 112
 113 PKG_CHECK_MODULES([EXOTIC],
 114    [exotic],
 115    [enable_exotic="yes"],
 116    [enable_exotic="no"])
 117
 118 if test "x${enable_exotic}" = "xyes"; then
 119     requirement_embryo="exotic ${requirement_embryo}"
 120
 121     AC_DEFINE([HAVE_EXOTIC], [1], [Define to 1 if you have Exotic.])
 122 fi
 123
 124 ### Checks for header files
 125
 126 AC_CHECK_HEADERS([unistd.h])
 127 EFL_CHECK_PATH_MAX
 128
 129
 130 ### Checks for types
 131
 132
 133 ### Checks for structures
 134
 135
 136 ### Checks for compiler characteristics
 137 AC_C_BIGENDIAN
 138 AM_PROG_CC_C_O
 139 AC_C_CONST
 140 AC_C_INLINE
 141 AC_PROG_CC_STDC
 142 AC_HEADER_STDC
 143 AC_C___ATTRIBUTE__
 144
 145 EMBRYO_CPPFLAGS=""
 146 EMBRYO_CFLAGS=""
 147 case "$host_os" in
 148    mingw32ce*)
 149       EMBRYO_CPPFLAGS="-D_WIN32_WCE=0x0420"
 150       ;;
 151 esac
 152 AC_SUBST(EMBRYO_CPPFLAGS)
 153 AC_SUBST(EMBRYO_CFLAGS)
 154
 155
 156 ### Checks for linker characteristics
 157
 158 lt_enable_auto_import=""
 159 case "$host_os" in
 160    mingw*)
 161       lt_enable_auto_import="-Wl,--enable-auto-import"
 162       ;;
 163 esac
 164 AC_SUBST(lt_enable_auto_import)
 165
 166
 167 ### Checks for library functions
 168
 169 AC_ISC_POSIX
 170
 171 # alloca
 172 AC_FUNC_ALLOCA
 173
 174 # fnmatch
 175 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 176
 177 # gettimeofday
 178 EFL_CHECK_GETTIMEOFDAY([], [AC_MSG_ERROR([Cannot find gettimeofday()])])
 179
 180
 181 AC_SUBST(requirement_embryo)
 182 AC_SUBST(embryoincludedir)
 183
 184 AC_OUTPUT([
 185 Makefile
 186 doc/Makefile
 187 doc/Doxyfile
 188 doc/embryo.dox
 189 embryo.pc
 190 include/Makefile
 191 src/Makefile
 192 src/lib/Makefile
 193 src/bin/Makefile
 194 embryo.spec
 195 ])
 196
 197
 198 #####################################################################
 199 ## Info
 200
 201 echo
 202 echo
 203 echo
 204 echo "------------------------------------------------------------------------"
 205 echo "$PACKAGE $VERSION"
 206 echo "------------------------------------------------------------------------"
 207 echo
 208 echo "Configuration Options Summary:"
 209 echo
 210 echo "  Build embryo_cc......: $have_embryo_cc"
 211 echo
 212 echo "  Documentation........: ${build_doc}"
 213 if test "x${build_doc}" = "xyes" ; then
 214 echo "    Installation.......: make install-doc"
 215 fi
 216 echo
 217 echo "Compilation............: make (or gmake)"
 218 echo "  CPPFLAGS.............: $CPPFLAGS"
 219 echo "  CFLAGS...............: $CFLAGS"
 220 echo "  LDFLAGS..............: $LDFLAGS"
 221 echo
 222 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 223 echo "  prefix...............: $prefix"
 224 echo