configure.ac

   1 EFL_VERSION([1], [16], [0], [release])
   2 AC_INIT([elementary], [efl_version], [enlightenment-devel@lists.sourceforge.net])
   3
   4 AC_PREREQ(2.63)
   5 AC_CONFIG_SRCDIR([configure.ac])
   6 AC_CONFIG_MACRO_DIR([m4])
   7 AC_CANONICAL_BUILD
   8 AC_CANONICAL_HOST
   9
  10 AC_CONFIG_HEADERS([elementary_config.h])
  11 AH_TOP([
  12 #ifndef EFL_CONFIG_H__
  13 #define EFL_CONFIG_H__
  14 ])
  15 AH_BOTTOM([
  16 #endif /* EFL_CONFIG_H__ */
  17 ])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_INIT_AUTOMAKE([1.11 dist-bzip2 dist-xz -Wall])
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 LT_INIT([win32-dll disable-static pic-only])
  26 EFL_INIT
  27
  28
  29 ### Additional options to configure
  30
  31 # C++ bindings
  32
  33 AC_ARG_ENABLE([cxx-bindings],
  34    [AS_HELP_STRING([--disable-cxx-bindings],
  35        [Disable C++11 bindings. @<:@default=enabled@:>@])],
  36    [want_cxx11="${enableval}"],
  37    [want_cxx11="yes"])
  38
  39 # Tests
  40
  41 AC_ARG_WITH([tests],
  42    [AS_HELP_STRING([--with-tests=none|regular|coverage],
  43                    [choose elementary testing method: regular, coverage or none @<:@default=none@:>@])],
  44    [build_tests=${withval}],
  45    [build_tests=auto])
  46
  47 want_coverage="no"
  48 want_tests="no"
  49 case "${build_tests}" in
  50    auto)
  51      if test "${build_profile}" = "dev"; then
  52         want_tests="yes"
  53      fi
  54      ;;
  55    regular)
  56      want_tests="yes"
  57      ;;
  58    coverage)
  59      want_tests="yes"
  60      want_coverage="yes"
  61      ;;
  62    no*)
  63      ;;
  64    *)
  65      AC_MSG_ERROR([Unknown build tests option: --with-tests=${build_tests}])
  66      ;;
  67 esac
  68
  69 # Elementary base dir
  70
  71 AC_ARG_WITH([elementary-base-dir],
  72    [AS_HELP_STRING([--with-elementary-base-dir=PATH], [specify the subdirectory for all elementary data @<:@default=${elementary_base_dir}@:>@])],
  73    [elementary_base_dir=${withval}],
  74    [elementary_base_dir=".elementary"])
  75
  76 AC_MSG_NOTICE([ELEMENTARY_BASE_DIR set to ${elementary_base_dir}])
  77 AC_DEFINE_UNQUOTED([ELEMENTARY_BASE_DIR], ["${elementary_base_dir}"], ["subdirectory for all elementary data"])
  78
  79 # Build and install examples
  80
  81 EFL_CHECK_BUILD_EXAMPLES(
  82    [enable_build_examples="yes"],
  83    [enable_build_examples="no"])
  84
  85 EFL_CHECK_INSTALL_EXAMPLES(
  86    [enable_install_examples="yes"],
  87    [enable_install_examples="no"])
  88
  89 # Debug mode
  90
  91 AC_ARG_ENABLE([debug],
  92    [AS_HELP_STRING([--enable-debug], [enable elementary debug support. @<:@default=disabled@:>@])],
  93    [want_elementary_debug=$enableval],
  94    [want_elementary_debug="no"])
  95
  96 ELM_DEBUG_DEF="#undef"
  97 if test "x$want_elementary_debug" = "xyes"; then
  98    AC_DEFINE([HAVE_ELEMENTARY_DEBUG], [1], [Elementary debug.])
  99    ELM_DEBUG_DEF="#define"
 100 fi
 101 AC_SUBST([ELM_DEBUG_DEF])
 102
 103 # quicklaunch support
 104
 105 AC_ARG_ENABLE([quick-launch],
 106    [AS_HELP_STRING([--disable-quick-launch], [disable quick-launch support, @<:@default=detect@:>@])],
 107    [want_quicklaunch=$enableval],
 108    [want_quicklaunch="auto"])
 109
 110
 111 ### Default options with respect to host and default values
 112
 113 ELM_VERSION_MAJOR="v_maj"
 114 ELM_VERSION_MINOR="v_min"
 115 AC_SUBST([ELM_VERSION_MAJOR])
 116 AC_SUBST([ELM_VERSION_MINOR])
 117
 118 MODULE_ARCH="v-v_maj.v_min.v_mic"
 119 AC_SUBST([MODULE_ARCH])
 120 AC_DEFINE_UNQUOTED([MODULE_ARCH], ["$MODULE_ARCH"], ["Module architecture"])
 121
 122 ELM_UNIX_DEF="#undef"
 123 ELM_WIN32_DEF="#undef"
 124 have_windows="no"
 125 have_freebsd="no"
 126
 127 case "$host_os" in
 128    mingw*)
 129       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if evil package is installed.])
 130       ELM_WIN32_DEF="#define"
 131       have_windows="yes"
 132       ;;
 133    *solaris*)
 134       ELM_UNIX_DEF="#define"
 135       ;;
 136    freebsd*)
 137       ELM_UNIX_DEF="#define"
 138       have_freebsd="yes"
 139       ;;
 140    darwin*)
 141       ELM_UNIX_DEF="#define"
 142       ;;
 143    *)
 144       ELM_UNIX_DEF="#define"
 145       ;;
 146 esac
 147
 148 AM_CONDITIONAL([ELEMENTARY_WINDOWS_BUILD], [test "x${have_windows}" = "xyes"])
 149 AM_CONDITIONAL([HAVE_FREEBSD], [test "x${have_freebsd}" = "xyes"])
 150 AC_SUBST([ELM_UNIX_DEF])
 151 AC_SUBST([ELM_WIN32_DEF])
 152
 153 ### Checks for programs
 154
 155 # compilers
 156 AC_PROG_CC
 157 AC_PROG_CC_STDC
 158 AC_PROG_CXX
 159
 160 EFL_CXX_COMPILE_STDCXX_11([ext])
 161
 162 # pkg-config
 163 PKG_PROG_PKG_CONFIG
 164
 165 # gettext
 166 m4_ifdef([AM_GNU_GETTEXT_VERSION], [
 167 AM_GNU_GETTEXT_VERSION([0.18])
 168 ])
 169
 170 m4_ifdef([AM_GNU_GETTEXT], [
 171 AM_GNU_GETTEXT([external])
 172 po_makefile_in=po/Makefile.in
 173 have_po="yes"
 174 ],[
 175 have_po="no"
 176 ])
 177 AC_SUBST([LTLIBINTL])
 178
 179 if test "x${POSUB}" = "x" ; then
 180    have_po="no"
 181 fi
 182
 183 AM_CONDITIONAL([HAVE_PO], [test "x${have_po}" = "xyes"])
 184
 185 # doxygen
 186 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 187
 188 # EFL binaries
 189 EFL_WITH_BIN([eet], [eet-eet], [eet])
 190 EFL_WITH_BIN([edje], [edje-cc], [edje_cc])
 191 EFL_WITH_BIN([elementary], [elementary-codegen], [elementary_codegen])
 192 EFL_WITH_BIN([elementary], [elm-prefs-cc], [elm_prefs_cc])
 193 EFL_WITH_BIN([eolian], [eolian-gen], [eolian_gen])
 194 EFL_WITH_BIN([eolian-cxx], [eolian-cxx], [eolian_cxx])
 195 EFL_WITH_BIN([eldbus], [eldbus_codegen], [eldbus-codegen])
 196 # Force the helper to try external eolian generators
 197 AM_CONDITIONAL([HAVE_EOLIAN_GEN], [true])
 198 AM_CONDITIONAL([HAVE_EOLIAN_CXX], [true])
 199
 200 EFL_ENABLE_BIN([elementary-test])
 201 EFL_ENABLE_BIN([elementary-codegen])
 202 EFL_ENABLE_BIN([elm-prefs-cc])
 203 EFL_ENABLE_BIN([elementary-config])
 204
 205
 206 ### Checks for libraries
 207
 208 requirement_elm_pc=""
 209
 210 case "$host_os" in
 211    mingw*)
 212       requirement_elm_pc="evil >= efl_version"
 213       ;;
 214 esac
 215
 216 requirement_elm_pc_only="\
 217     efl >= efl_version \
 218     eina >= efl_version \
 219     eet >= efl_version \
 220     evas >= efl_version \
 221     ecore >= efl_version \
 222     ecore-evas >= efl_version \
 223     ecore-file >= efl_version \
 224     ecore-input >= efl_version \
 225     edje >= efl_version \
 226     eo >= efl_version \
 227     ethumb_client >= efl_version \
 228     emotion >= efl_version \
 229     ecore-imf >= efl_version \
 230     ecore-con >= efl_version \
 231     eio >= efl_version \
 232     eldbus >= efl_version \
 233     efreet >= efl_version \
 234     efreet-mime >= efl_version \
 235     efreet-trash >= efl_version \
 236     eio >= efl_version \
 237     "
 238
 239 requirement_elm_pc="\
 240     ${requirement_elm_pc} \
 241     ${requirement_elm_pc_only} \
 242     "
 243
 244 ELM_CHECK_BACKEND([X])
 245 ELM_CHECK_BACKEND([FB])
 246 ELM_CHECK_BACKEND([PSL1GHT])
 247 ELM_CHECK_BACKEND([SDL])
 248 ELM_CHECK_BACKEND([Cocoa])
 249 ELM_CHECK_BACKEND([Win32])
 250 ELM_CHECK_BACKEND([Wayland])
 251 ELM_CHECK_BACKEND([DRM])
 252
 253 ELM_CHECK_OPTION([elocation], [0.1.0])
 254 ELM_CHECK_OPTION([eweather], [0.2.0])
 255 # emap is in svn : trunk/PROTO
 256 ELM_CHECK_OPTION([emap], [0.1.0])
 257 ELM_CHECK_OPTION([eweb])
 258
 259 PKG_CHECK_MODULES([ELEMENTARY], [${requirement_elm_pc}])
 260 PKG_CHECK_MODULES([ELEMENTARY_PC], [${requirement_elm_pc_only}])
 261
 262 EFL_ENABLE_EO_API_SUPPORT
 263 EFL_ENABLE_BETA_API_SUPPORT
 264
 265
 266 if test "x${HAVE_CXX11}" = "x1" -a "x${want_cxx11}" = "xyes"; then
 267    PKG_CHECK_MODULES([ELEMENTARY_CXX],
 268       [
 269         efl-cxx >= efl_version
 270         eo-cxx >= efl_version
 271         eina-cxx >= efl_version
 272         evas-cxx >= efl_version
 273         eio-cxx >= efl_version
 274         edje-cxx >= efl_version
 275       ],
 276       [
 277         requirement_elm_pc="${requirement_elm_pc} \
 278           efl-cxx >= efl_version \
 279           eo-cxx >= efl_version \
 280           eina-cxx >= efl_version \
 281           evas-cxx >= efl_version \
 282           eio-cxx >= efl_version \
 283           edje-cxx >= efl_version \
 284         "
 285         have_cxx11="yes"
 286         LDFLAGS="${LDFLAGS} -fPIC -DPIC"
 287         CXXFLAGS="${CXXFLAGS} -fPIC -DPIC"
 288         AC_CONFIG_FILES([src/lib/Elementary.hh])
 289       ],
 290       [have_cxx11="no"]
 291    )
 292 else
 293    have_cxx11="no"
 294 fi
 295 AM_CONDITIONAL([HAVE_CXX11], [test "x${have_cxx11}" = "xyes"])
 296
 297
 298 MODULE_EDJE=`${PKG_CONFIG} --variable=module_arch edje`
 299 AC_SUBST([MODULE_EDJE])
 300 AC_DEFINE_UNQUOTED([MODULE_EDJE], ["$MODULE_EDJE"], ["Edje module architecture"])
 301
 302 # Needs to be moved into a macro, and also, needs a way to automatically fetch
 303 # from all the dependencies using the Requires.
 304 DEPS_EOLIAN_FLAGS=`${PKG_CONFIG} --variable=eolian_flags eo evas edje ecore efl`
 305 AC_SUBST([DEPS_EOLIAN_FLAGS])
 306
 307 requirement_elm_libs="-lm"
 308
 309 # sockets
 310
 311 case "$host_os" in
 312    mingw*)
 313       have_socket="no"
 314       ;;
 315    *solaris*)
 316       AC_CHECK_LIB([socket], [connect],
 317          [
 318           have_socket="yes"
 319           requirement_elm_libs="-lsocket ${requirement_elm_libs}"
 320          ],
 321          [have_socket="no"])
 322       ;;
 323    darwin*)
 324       have_socket="yes"
 325       ;;
 326    *)
 327       have_socket="yes"
 328       ;;
 329 esac
 330
 331 AM_CONDITIONAL([BUILD_RUN], [test "x$have_socket" = "xyes"])
 332
 333 # dlopen
 334
 335 have_dlopen="no"
 336 case "$host_os" in
 337    mingw*)
 338 dnl managed by evil
 339       AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if you have the `dladdr' function.])
 340       have_dlopen="yes"
 341       requirement_elm_libs="-ldl ${requirement_elm_libs}"
 342       ;;
 343    linux*)
 344       AC_CHECK_LIB([dl], [dlopen], [res=yes], [res=no])
 345       if test "x$res" = "xyes"; then
 346          AC_CHECK_LIB([dl], [dladdr], AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if you have the `dladdr' function.]))
 347          requirement_elm_libs="-ldl ${requirement_elm_libs}"
 348          have_dlopen="yes"
 349       fi
 350       ;;
 351    *)
 352       have_dlopen="yes"
 353       ;;
 354 esac
 355
 356 AM_CONDITIONAL([BUILD_MODULES], [test "x$have_dlopen" = "xyes"])
 357
 358 ELEMENTARY_LIBS="${ELEMENTARY_LIBS} ${requirement_elm_libs}"
 359 ELEMENTARY_PC_LIBS="${ELEMENTARY_PC_LIBS} ${requirement_elm_libs}"
 360
 361 AC_SUBST([requirement_elm_pc])
 362
 363 # check unit testing library
 364 if test "${want_tests}" = "yes"; then
 365    PKG_CHECK_MODULES([CHECK], [check >= 0.9.5])
 366 fi
 367 AM_CONDITIONAL([ELEMENTARY_ENABLE_TESTS], [test "${want_tests}" = "yes"])
 368
 369 # lcov
 370 if test "${want_coverage}" = "yes" ; then
 371    AC_CHECK_PROG([have_lcov], [lcov], [yes], [no])
 372    if test "x${have_lcov}" = "xyes" ; then
 373       ELEMENTARY_CFLAGS="${ELEMENTARY_CFLAGS} -fprofile-arcs -ftest-coverage"
 374       ELEMENTARY_LIBS="${ELEMENTARY_LIBS} -lgcov"
 375       if test "x${prefer_assert}" = "xno"; then
 376          ELEMENTARY_CFLAGS="${ELEMENTARY_CFLAGS} -DNDEBUG"
 377       else
 378          ELEMENTARY_CFLAGS="${ELEMENTARY_CFLAGS} -g -O0 -DDEBUG"
 379       fi
 380    else
 381       AC_MSG_ERROR([lcov is not found])
 382    fi
 383 fi
 384
 385 AM_CONDITIONAL([ELEMENTARY_ENABLE_COVERAGE], [test "${want_coverage}" = "yes"])
 386
 387
 388 ### Checks for header files
 389
 390 # Check for ttrace
 391 PKG_CHECK_MODULES(TTRACE,
 392                   [ttrace],
 393                   [have_ttrace="yes"], [have_ttrace="no"])
 394 if test "x$have_ttrace" = "xyes"; then
 395   AC_DEFINE(ENABLE_TTRACE, 1, [ttrace available])
 396 fi
 397
 398 ELM_ALLOCA_H_DEF="#undef"
 399 AC_CHECK_HEADER([alloca.h], [ELM_ALLOCA_H_DEF="#define"])
 400 AC_SUBST([ELM_ALLOCA_H_DEF])
 401
 402 ELM_LIBINTL_H_DEF="#undef"
 403 AC_CHECK_HEADER([libintl.h], [ELM_LIBINTL_H_DEF="#define"])
 404 AC_SUBST([ELM_LIBINTL_H_DEF])
 405
 406 ELM_DIRENT_H_DEF="#undef"
 407 AC_CHECK_HEADER([dirent.h], [ELM_DIRENT_H_DEF="#define"])
 408 AC_SUBST([ELM_DIRENT_H_DEF])
 409
 410 AC_CHECK_HEADER([sys/mman.h], [have_mman="yes"], [have_mman="no"])
 411 if test "x${have_mman}" = "xyes"; then
 412    AC_DEFINE([HAVE_MMAN_H], [1], [Have sys/mman.h header file])
 413 fi
 414
 415 AC_CHECK_HEADERS([locale.h langinfo.h sys/times.h])
 416
 417 case "$host_os" in
 418    darwin*)
 419       AC_CHECK_HEADERS([crt_externs.h])
 420       ;;
 421 esac
 422
 423
 424 ### Checks for types
 425
 426
 427 ### Checks for structures
 428
 429
 430 ### Checks for compiler characteristics
 431
 432 AC_C_BIGENDIAN
 433
 434 m4_ifdef([v_mic],
 435    [
 436     EFL_COMPILER_FLAG([-Wshadow])
 437     EFL_COMPILER_FLAG([-Wall])
 438     EFL_COMPILER_FLAG([-W])
 439    ])
 440
 441 EFL_COMPILER_FLAG([-Wall -Wextra -Wpointer-arith -Wno-missing-field-initializers -fvisibility=hidden -fdata-sections -ffunction-sections])
 442
 443 EFL_CHECK_PATH_MAX
 444
 445
 446 ### Checks for linker characteristics
 447
 448 EFL_LINKER_FLAG([-fvisibility=hidden -fdata-sections -ffunction-sections -Wl,--gc-sections -fno-strict-aliasing -Wl,--as-needed -Wl,--no-copy-dt-needed-entries])
 449
 450 # Check if we can build binary with quicklaunch support
 451 ELM_QUICKLAUNCH
 452
 453
 454 ### Checks for library functions
 455
 456 AC_FUNC_ALLOCA
 457
 458 AC_CHECK_FUNCS([geteuid getuid getpwent])
 459
 460 if test "x${want_quicklaunch}" != "xno"; then
 461    AC_CHECK_FUNCS([fork clearenv])
 462 fi
 463
 464 if test "x${have_dlopen}" = "xno"; then
 465    AC_CHECK_FUNCS([dlopen dladdr])
 466 fi
 467
 468 if test "x${ac_cv_func_dlopen}" = "xyes"; then
 469    have_dlopen="yes"
 470 fi
 471
 472 AM_CONDITIONAL([BUILD_QUICKLAUNCH], [test "x${ac_cv_func_fork}" = "xyes" && test "x${have_dlopen}" = "xyes"])
 473
 474 # environ variable
 475
 476 AC_COMPILE_IFELSE(
 477    [AC_LANG_PROGRAM(
 478       [[
 479 # define _GNU_SOURCE 1
 480 #include <unistd.h>
 481       ]],
 482       [[
 483 extern char **environ;
 484       ]])
 485    ],
 486    [AC_DEFINE([HAVE_ENVIRON], [1], [extern environ exists])])
 487
 488 case "$host_os" in
 489    darwin*)
 490       AC_DEFINE([environ], [(*_NSGetEnviron())], ["apple doesn't follow POSIX in this case."])
 491       ;;
 492 esac
 493
 494
 495 AC_CONFIG_FILES([
 496 Makefile
 497 elementary.spec
 498 doc/Makefile
 499 doc/Doxyfile
 500 doc/widgets/Makefile
 501 src/Makefile
 502 src/lib/Makefile
 503 src/lib/Elementary.h
 504 src/lib/elm_intro.h
 505 src/bin/Makefile
 506 src/modules/Makefile
 507 src/modules/prefs/Makefile
 508 src/modules/access_output/Makefile
 509 src/modules/copypasteUI_ctxpopup/Makefile
 510 src/modules/datetime_input_ctxpopup/Makefile
 511 src/modules/test_entry/Makefile
 512 src/modules/test_map/Makefile
 513 src/edje_externals/Makefile
 514 src/examples/Makefile
 515 src/examples/sphere_hunter/Makefile
 516 src/examples/performance/Makefile
 517 src/tests/Makefile
 518 src/imported/Makefile
 519 src/imported/atspi/Makefile
 520 data/Makefile
 521 data/themes/Makefile
 522 data/images/Makefile
 523 data/objects/Makefile
 524 data/desktop/Makefile
 525 data/edje_externals/Makefile
 526 config/Makefile
 527 config/default/Makefile
 528 config/default/base.src
 529 config/standard/Makefile
 530 config/standard/base.src
 531 config/mobile/Makefile
 532 config/mobile/base.src
 533 $po_makefile_in
 534 cmakeconfig/ElementaryConfig.cmake
 535 cmakeconfig/ElementaryConfigVersion.cmake
 536 ])
 537
 538 AC_OUTPUT
 539
 540 #####################################################################
 541 ## Info
 542
 543 echo
 544 echo
 545 echo
 546 echo "------------------------------------------------------------------------"
 547 echo "$PACKAGE $VERSION"
 548 echo "------------------------------------------------------------------------"
 549 echo
 550 echo "Configuration Options Summary:"
 551 echo
 552 echo "  Engines:"
 553 echo "    X11....................: ${have_elementary_x}"
 554 echo "    Framebuffer............: ${have_elementary_fb}"
 555 echo "    DRM....................: ${have_elementary_drm}"
 556 echo "    PSL1GHT................: ${have_elementary_psl1ght}"
 557 echo "    SDL....................: ${have_elementary_sdl}"
 558 echo "    Cocoa..................: ${have_elementary_cocoa}"
 559 echo "    Windows XP.............: ${have_elementary_win32}"
 560 echo "    Wayland................: ${have_elementary_wayland}"
 561 echo
 562 echo "  Features:"
 563 echo "    EWeather...............: ${have_elementary_eweather}"
 564 echo "    EMap...................: ${have_elementary_emap}"
 565 echo "    Web (WebKit)...........: ${elementary_web}"
 566 echo "    Quick Launch...........: ${ac_cv_func_fork}"
 567 echo "    Elocation..............: ${have_elementary_elocation}"
 568 echo
 569 echo "  eet......................: ${eet_eet}"
 570 echo "  edje_cc..................: ${edje_cc}"
 571 echo "  elementary_codegen.......: ${elementary_codegen}"
 572 echo "  elm_prefs_cc.............: ${elm_prefs_cc}"
 573 echo "  eolian_gen...............: ${eolian_gen}"
 574 echo "  eolian_cxx...............: ${eolian_cxx}"
 575 echo "  eldbus_codegen...........: ${eldbus_codegen}"
 576 echo
 577 echo "  Build elementary_test....: ${have_elementary_test}"
 578 echo "  Build elementary_codegen.: ${have_elementary_codegen}"
 579 echo "  Build elm_prefs_cc.......: ${have_elm_prefs_cc}"
 580 echo "  Examples.................: ${enable_build_examples}"
 581 echo "  Examples installed.......: ${enable_install_examples}"
 582 echo "  Build elementary_config..: ${have_elementary_config}"
 583 echo "  Enable debug.............: ${want_elementary_debug}"
 584 echo "  Enable C++...............: ${have_cxx11}"
 585 echo
 586 echo "Compilation................: make (or gmake)"
 587 echo "  CPPFLAGS.................: $CPPFLAGS"
 588 echo "  CFLAGS...................: $CFLAGS"
 589 if test "x${have_cxx11}" = "xyes"; then
 590 echo "  CXXFLAGS.................: $CXXFLAGS"
 591 fi
 592 echo "  LDFLAGS..................: $LDFLAGS"
 593 echo
 594 if test "${build_tests}" = "none"; then
 595 echo "Tests......................: no"
 596 else
 597 echo "Tests......................: make check"
 598 fi
 599 if test "${build_doc}" = "no"; then
 600 echo "Docs.......................: no (doxygen not found)"
 601 else
 602 echo "Docs.......................: make doc"
 603 fi
 604 echo
 605 echo "Installation...............: make install (as root if needed, with 'su' or 'sudo')"
 606 echo "  prefix...................: $prefix"
 607 echo