configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [7])
   5 m4_define([v_mic], [5])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([edje], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_LIBTOOL_WIN32_DLL
  39 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  40 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  41 AC_PROG_LIBTOOL
  42
  43 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  46 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  47 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  48 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  49 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  50 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  51 version_info="lt_cur:lt_rev:lt_age"
  52 release_info="v_rel"
  53 AC_SUBST(version_info)
  54 AC_SUBST(release_info)
  55 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 VMAJ=v_maj
  58 AC_SUBST(VMAJ)
  59
  60 AC_DEFINE_UNQUOTED([SHARED_LIB_SUFFIX], ["$shrext_cmds"], [Suffix for shared objects])
  61
  62 ### Default options with respect to host
  63 AC_CANONICAL_BUILD
  64 AC_CANONICAL_HOST
  65
  66
  67 case "$host_os" in
  68    mingw32ce*)
  69       MODULE_ARCH="$host_os-$host_cpu"
  70       install_vim="no"
  71       have_edje_cc="no"
  72       ;;
  73    *)
  74       MODULE_ARCH="$host_os-$host_cpu-v_maj.0.0"
  75       install_vim="yes"
  76       have_edje_cc="yes"
  77       ;;
  78 esac
  79
  80 requirement_edje=""
  81
  82 AC_SUBST(MODULE_ARCH)
  83 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  84
  85 ### Additional options to configure
  86
  87 AC_ARG_ENABLE([amalgamation],
  88    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
  89    [if test "x${enableval}" = "xyes"; then
  90        do_amalgamation="yes"
  91     else
  92        do_amalgamation="no"
  93     fi
  94    ],
  95    [do_amalgamation="no"]
  96 )
  97 AM_CONDITIONAL([EDJE_AMALGAMATION], [test "x${do_amalgamation}" = "xyes"])
  98
  99 EFL_WITH_BIN([edje], [edje-cc], [edje_cc])
 100
 101 EFL_ENABLE_BIN([edje-cc])
 102 EFL_ENABLE_BIN([edje-decc])
 103 EFL_ENABLE_BIN([edje-recc])
 104 EFL_ENABLE_BIN([edje-player])
 105 EFL_ENABLE_BIN([edje-inspector])
 106 EFL_ENABLE_BIN([edje-external-inspector])
 107 EFL_ENABLE_BIN([edje-watch])
 108
 109 # Optional EDJE_PROGRAM_CACHE (use much more ram, but increase speed in some cases)
 110 want_edje_program_cache="no"
 111
 112 AC_ARG_ENABLE([edje-program-cache],
 113    [AC_HELP_STRING(
 114        [--enable-edje-program-cache],
 115        [enable EDJE_PROGRAM_CACHE support. [[default=disabled]]]
 116     )],
 117    [want_edje_program_cache=$enableval]
 118 )
 119 AM_CONDITIONAL([EDJE_PROGRAM_CACHE], [test "x${want_edje_program_cache}" = "xyes"])
 120
 121 if test "x${want_edje_program_cache}" = "xyes" ; then
 122    AC_DEFINE([EDJE_PROGRAM_CACHE], [1], [Cache result of program glob matches - this uses up extra ram with the gain of faster program matching])
 123 fi
 124
 125 # Optional EDJE_CALC_CACHE (use more ram, but increase speed by reducing the need to recalculate static stuff)
 126 want_edje_calc_cache="yes"
 127
 128 AC_ARG_ENABLE([edje-calc-cache],
 129    [AC_HELP_STRING(
 130        [--enable-edje-calc-cache],
 131        [enable EDJE_CALC_CACHE support. [[default=disabled]]]
 132     )],
 133    [want_edje_calc_cache=$enableval]
 134 )
 135 AM_CONDITIONAL([EDJE_CALC_CACHE], [test "x${want_edje_calc_cache}" = "xyes"])
 136
 137 if test "x${want_edje_calc_cache}" = "xyes" ; then
 138    AC_DEFINE([EDJE_CALC_CACHE], [1], [Cache result of edje_part_recalc - this uses up extra ram with the gain of reducing CPU usage when edje object are not resized])
 139 fi
 140
 141 # Enable Fixed Point use
 142 want_fixed_point="no"
 143
 144 AC_ARG_ENABLE([fixed-point],
 145    [AC_HELP_STRING(
 146        [--enable-fixed-point],
 147        [reduce use of FPU by using Fixed Point provided by Eina and Eet, [[default=disabled]]]
 148     )],
 149     [want_fixed_point=$enableval]
 150 )
 151 AM_CONDITIONAL([BUILD_EDJE_FP], [test "x${want_fixed_point}" = "xyes"])
 152
 153 if test "x${want_fixed_point}" = "xyes" ; then
 154    AC_DEFINE([BUILD_EDJE_FP], [1], [Use Fixed Point instead of FPU])
 155 fi
 156
 157 install_vim="yes"
 158 AC_ARG_WITH([vim],
 159     [AC_HELP_STRING([--with-vim=DIR], [Location of Vim data files [[autodetect]]])],
 160     [
 161      if test -d "${withval}"; then
 162         vimdir="${withval}"
 163      fi
 164     ]
 165 )
 166
 167 if test "x${vimdir}" = "x" ; then
 168    if test -d "${prefix}/share/vim"; then
 169       vimdir="${prefix}/share/vim"
 170    elif test -d "/usr/share/vim"; then
 171       vimdir="/usr/share/vim"
 172    elif test -d "/usr/local/share/vim"; then
 173       vimdir="/usr/local/share/vim"
 174    elif test -d "/opt/share/vim"; then
 175       vimdir="/opt/share/vim"
 176    else
 177       install_vim="no"
 178    fi
 179 fi
 180
 181 AC_MSG_CHECKING([for location of Vim data files])
 182
 183 if test "${install_vim}" = "yes"; then
 184    AC_MSG_RESULT([$vimdir])
 185 else
 186    AC_MSG_RESULT([Not found, EDC syntax file will not be installed])
 187 fi
 188
 189 AC_SUBST(vimdir)
 190
 191 ### Checks for programs
 192 AC_PROG_CC
 193
 194 # doxygen program for documentation building
 195
 196 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 197
 198 # python
 199
 200 AM_PATH_PYTHON([2.5], , [:])
 201 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != : ])
 202
 203 # pkg-config
 204
 205 PKG_PROG_PKG_CONFIG
 206
 207 # Check whether pkg-config supports Requires.private
 208
 209 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 210    pkgconfig_requires_private="Requires.private"
 211 else
 212    pkgconfig_requires_private="Requires"
 213 fi
 214 AC_SUBST(pkgconfig_requires_private)
 215
 216
 217 ### Checks for libraries
 218
 219 # Evil library for compilation on Windows
 220
 221 EFL_EDJE_BUILD=""
 222 case "$host_os" in
 223    mingw*)
 224       PKG_CHECK_MODULES([EVIL], [evil >= 1.7.5])
 225       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if Evil library is installed])
 226       requirement_edje="evil ${requirement_edje}"
 227       EFL_EDJE_BUILD="-DEFL_EDJE_BUILD"
 228    ;;
 229 esac
 230 AC_SUBST(EFL_EDJE_BUILD)
 231
 232 # Dependencies for the library
 233
 234 # Lua pkg-config hack for different naming conventions
 235 have_lua="yes"
 236 requirement_lua=""
 237 lua_libs=""
 238 PKG_CHECK_MODULES([LUA], [lua >= 5.1.0], requirement_lua="lua",
 239    [PKG_CHECK_MODULES([LUA], [lua5.1 >= 5.1.0], requirement_lua="lua5.1",
 240       [PKG_CHECK_MODULES([LUA], [lua-5.1 >= 5.1.0], requirement_lua="lua-5.1",
 241          [PKG_CHECK_MODULES([LUA], [lua51 >= 5.1.0], requirement_lua="lua51",
 242             [have_lua="no"])])])])
 243
 244 if test "x${have_lua}" = "xno" ; then
 245    AC_MSG_CHECKING([whether lua_newstate() is in liblua])
 246    AC_CHECK_LIB([lua], [lua_newstate],
 247       [
 248        have_lua="yes"
 249        lua_libs="-llua"
 250       ],
 251       [have_lua="no"])
 252    AC_MSG_RESULT([${have_lua}])
 253 fi
 254 AC_SUBST(lua_libs)
 255
 256 if test "x${have_lua}" = "xno" ; then
 257    AC_MSG_ERROR([Cannot find lua library. Be sure that you have installed it and set CFLAGS and LDFLAGS correctly])
 258 fi
 259
 260 PKG_CHECK_MODULES([MINIMAL],
 261    [
 262     eina >= 1.7.5
 263     eet >= 1.7.5
 264    ])
 265
 266 PKG_CHECK_MODULES([EDJE],
 267    [
 268     eina >= 1.7.5
 269     eet >= 1.7.5
 270     evas >= 1.7.5
 271     ecore >= 1.7.5
 272     ecore-evas >= 1.7.5
 273     ecore-file >= 1.7.5
 274     ecore-input >= 1.7.5
 275     embryo >= 1.7.5
 276    ])
 277
 278 EDJE_LIBS="${EDJE_LIBS} ${LUA_LIBS} ${lua_libs}"
 279 EDJE_CFLAGS="${EDJE_CFLAGS} ${LUA_CFLAGS}"
 280
 281 requirement_edje="embryo >= 1.7.5 ecore-evas >= 1.7.5 ecore >= 1.7.5 evas >= 1.7.5 eet >= 1.7.5 eina >= 1.7.5 ${requirement_edje}"
 282 requirement_edje="${requirement_lua} ${requirement_edje}"
 283
 284 have_ecore_imf="no"
 285 PKG_CHECK_MODULES([ECORE_IMF],
 286    [
 287     ecore-imf >= 1.7.5
 288     ecore-imf-evas >= 1.7.5
 289    ],
 290    [
 291     AC_DEFINE([HAVE_ECORE_IMF], [1], [Input Method Support for Edje Entry])
 292     have_ecore_imf="yes"
 293     requirement_edje="ecore-imf-evas >= 1.7.5 ecore-imf >= 1.7.5 ${requirement_edje}"
 294    ],
 295    [have_ecore_imf="no"])
 296
 297 PKG_CHECK_MODULES([EIO],
 298    [eio >= 1.7.5],
 299    [
 300     AC_DEFINE([HAVE_EIO], [1], [Eio is available for monitoring file assynchronously])
 301     have_eio="yes"
 302     requirement_edje="eio >= 1.7.5 ${requirement_edje}"
 303    ],
 304    [have_eio="no"])
 305
 306 # Enable Multisense use
 307 want_multisense="no"
 308 dnl AC_ARG_ENABLE([multisense],
 309 dnl    [AC_HELP_STRING(
 310 dnl        [--enable-multisense],
 311 dnl        [multisense provides sound. tone and haptic effects support, [[default=disabled]]]
 312 dnl     )],
 313 dnl     [want_multisense=$enableval]
 314 dnl )
 315 AM_CONDITIONAL([ENABLE_MULTISENSE], [test "x${want_multisense}" = "xyes"])
 316
 317 ##sndfile library
 318 have_sndfile="no"
 319 want_sndfile="auto"
 320 AC_ARG_ENABLE([sndfile],
 321    [AC_HELP_STRING([--disable-sndfile], [disable sndfile support. @<:@default=detect@:>@])],
 322    [want_sndfile=$enableval], [])
 323
 324 if test "x${want_multisense}" = "xyes" -a  "x$want_sndfile" != "xno"; then
 325
 326            PKG_CHECK_MODULES([SNDFILE],
 327               [sndfile >= 1.0.21],
 328               [
 329                AC_DEFINE(HAVE_LIBSNDFILE, 1, [sndfile support for Edje])
 330                have_sndfile="yes"
 331                requirement_edje="sndfile >= 1.0.21 ${requirement_edje}"
 332                ],
 333               [have_sndfile="no"; want_multisense="no"]
 334            )
 335
 336         if test "x$want_sndfile" = "xyes" -a "x$have_sndfile" = "xno"; then
 337             AC_MSG_ERROR([sndfile support requested, but not found by pkg-config.])
 338         fi
 339 fi
 340 AM_CONDITIONAL([HAVE_LIBSNDFILE], [test "x${have_sndfile}" = "xyes"])
 341
 342 ##libremix library
 343 have_libremix="no"
 344 want_libremix="auto"
 345 AC_ARG_ENABLE([remix],
 346    [AC_HELP_STRING([--disable-remix], [disable remix support. @<:@default=detect@:>@])],
 347    [want_libremix=$enableval], [])
 348
 349 if test "x${want_multisense}" = "xyes" -a "x$want_libremix" != "xno"; then
 350    PKG_CHECK_MODULES([REMIX],
 351       [remix >= 0.2.4],
 352       [
 353        AC_DEFINE(HAVE_LIBREMIX, 1, [remix support for Edje])
 354        have_libremix="yes"
 355        requirement_edje="remix >= 0.2.4 ${requirement_edje}"
 356        AC_DEFINE(__REMIX_PLUGIN__, 1, "Set to REMIX Plugin type")
 357        REMIX_PLUGIN_DIR=`pkg-config --variable=libdir remix`"/remix"
 358        AC_SUBST(REMIX_PLUGIN_DIR)
 359        AC_DEFINE_UNQUOTED(REMIX_PLUGIN_DIR, "$REMIX_PLUGIN_DIR", [Set the remix plugin directory])
 360        ],
 361       [have_libremix="no"; want_multisense="no"]
 362    )
 363
 364         if test "x$want_libremix" = "xyes" -a "x$have_libremix" = "xno"; then
 365             AC_MSG_ERROR([remix support requested, but not found by pkg-config.])
 366         fi
 367 fi
 368 AM_CONDITIONAL([HAVE_LIBREMIX], [test "x${have_libremix}" = "xyes"])
 369
 370 ##vorbis/ogg library
 371 have_vorbis="no"
 372 want_vorbis="auto"
 373 AC_ARG_ENABLE([vorbisenc],
 374    [AC_HELP_STRING([--disable-vorbis], [disable ogg-vorbis support. @<:@default=detect@:>@])],
 375    [want_vorbis=$enableval], [])
 376
 377 if test "x${want_multisense}" = "xyes" -a "x$want_vorbis" != "xno"; then
 378    PKG_CHECK_MODULES([VORBISENC],
 379       [
 380        ogg >= 1.1.4
 381        vorbis >= 1.2.3
 382        vorbisenc >= 1.2.3
 383       ],
 384       [
 385        AC_DEFINE(HAVE_VORBIS, 1, [vorbis support for Edje])
 386        have_vorbis="yes"
 387        requirement_edje="ogg >= 1.1.4 vorbis >= 1.2.3 vorbisenc >= 1.2.3 ${requirement_edje}"
 388       ],
 389       [have_vorbis="no"; want_multisense="no"]
 390    )
 391
 392         if test "x$want_vorbis" = "xyes" -a "x$have_vorbis" = "xno"; then
 393             AC_MSG_ERROR([vorbisenc support requested, but not found by pkg-config.])
 394         fi
 395 fi
 396
 397 ##alsa library
 398 have_alsa_lib="no"
 399 want_alsa_lib="auto"
 400 AC_ARG_ENABLE([alsa],
 401    [AC_HELP_STRING([--disable-alsa], [disable alsa support. @<:@default=detect@:>@])],
 402    [want_alsa_lib=$enableval], [])
 403
 404 if test "x${want_multisense}" = "xyes" -a "x$want_alsa_lib" != "xno"; then
 405    PKG_CHECK_MODULES([ALSA],
 406       [
 407        alsa >= 1.0.21
 408       ],
 409       [
 410        AC_DEFINE(HAVE_LIBALSA, 1, [ALSA support for Edje])
 411        have_alsa_lib="yes"
 412        requirement_edje="alsa >= 1.0.21 ${requirement_edje}"
 413       ],
 414       [have_alsa_lib="no"; want_multisense="no"]
 415    )
 416
 417         if test "x$want_alsa_lib" = "xyes" -a "x$have_alsa_lib" = "xno"; then
 418             AC_MSG_ERROR([alsa support requested, but not found by pkg-config.])
 419         fi
 420 fi
 421 AM_CONDITIONAL([HAVE_LIBALSA], [test "x${have_alsa_lib}" = "xyes"])
 422
 423
 424 ##flac library
 425 have_flac_lib="no"
 426 want_flac_lib="auto"
 427 AC_ARG_ENABLE([flac],
 428    [AC_HELP_STRING([--disable-flac], [disable flac support. @<:@default=detect@:>@])],
 429    [want_flac_lib=$enableval], [])
 430
 431 if test "x${want_multisense}" = "xyes" -a "x$want_flac_lib" != "xno"; then
 432    PKG_CHECK_MODULES([FLAC],
 433       [
 434        flac >= 1.2.1
 435       ],
 436       [
 437        AC_DEFINE(HAVE_LIBFLAC, 1, [flac support for Edje])
 438        have_flac_lib="yes"
 439        # disabled because this adds flac include dirs to cflags... and
 440        # FLAC has an assert.h in its include dirs that ends up
 441        # overriding the system assert.h and thus causes all sorts of
 442        # mayhem
 443        #requirement_edje="flac >= 1.2.1 ${requirement_edje}"
 444       ],
 445       [have_flac_lib="no"; want_multisense="no"]
 446    )
 447         if test "x$want_flac_lib" = "xyes" -a "x$have_flac_lib" = "xno"; then
 448             AC_MSG_ERROR([flac support requested, but not found by pkg-config.])
 449         fi
 450 fi
 451
 452 if test "x${want_multisense}" = "xyes" ; then
 453    AC_DEFINE([ENABLE_MULTISENSE], [1], [Use Multisense])
 454 fi
 455 AC_SUBST([want_multisense])
 456
 457 # Dependencies for the binaries
 458
 459 if test "x${have_edje_cc}" = "xyes" ; then
 460    PKG_CHECK_MODULES([EDJE_CC],
 461       [ecore-file >= 1.7.5 ecore-evas >= 1.7.5 ecore >= 1.7.5 evas >= 1.7.5 eet >= 1.6.0 eina >= 1.7.5])
 462    EDJE_CC_LIBS="${EDJE_CC_LIBS} ${LUA_LIBS} ${lua_libs}"
 463 fi
 464
 465 AM_CONDITIONAL([BUILD_EPP], [test "x${have_edje_cc}" = "xyes"])
 466
 467 if test "x${have_edje_decc}" = "xyes" ; then
 468    PKG_CHECK_MODULES([EDJE_DECC],
 469       [ecore-file >= 1.7.5 ecore-evas >= 1.7.5 ecore >= 1.7.5 evas >= 1.7.5 eet >= 1.7.5 eina >= 1.7.5])
 470 fi
 471
 472 if test "x${have_edje_player}" = "xyes" ; then
 473    PKG_CHECK_MODULES([EDJE_PLAYER],
 474       [ecore-evas >= 1.7.5 ecore >= 1.7.5 evas >= 1.7.5 eina >= 1.7.5])
 475 fi
 476
 477 if test "x${have_edje_inspector}" = "xyes" ; then
 478    PKG_CHECK_MODULES([EDJE_INSPECTOR],
 479       [ecore-evas >= 1.7.5 ecore >= 1.7.5 evas >= 1.7.5 eina >= 1.7.5])
 480 fi
 481
 482 if test "x${have_edje_external_inspector}" = "xyes" ; then
 483    PKG_CHECK_MODULES([EDJE_EXTERNAL_INSPECTOR],
 484       [ecore >= 1.7.5 evas >= 1.7.5 eina >= 1.7.5])
 485 fi
 486
 487 if test "x${have_edje_watch}" = "xyes" ; then
 488    PKG_CHECK_MODULES([EDJE_WATCH],
 489       [ecore >= 1.7.5 eina >= 1.7.5 eio >= 1.7.5],
 490       [have_edje_watch="yes"],
 491       [have_edje_watch="no"])
 492 fi
 493
 494 AM_CONDITIONAL([BUILD_EDJE_WATCH], [test "x${have_edje_watch}" = "xyes"])
 495
 496 ### Checks for header files
 497 AC_CHECK_HEADERS([locale.h sys/resource.h])
 498
 499 EFL_CHECK_PATH_MAX
 500
 501
 502 ### Checks for types
 503
 504
 505 ### Checks for structures
 506
 507
 508 ### Checks for compiler characteristics
 509 AM_PROG_CC_C_O
 510 AC_C_CONST
 511 AC_PROG_CC_STDC
 512 AC_HEADER_STDC
 513 AC_C___ATTRIBUTE__
 514
 515 case "$host_os" in
 516    mingw32ce*)
 517       EDJE_CFLAGS="${EDJE_CFLAGS} -D_WIN32_WCE=0x0420"
 518       ;;
 519 esac
 520
 521
 522 ### Checks for linker characteristics
 523
 524 lt_enable_auto_import=""
 525 case "$host_os" in
 526    mingw*)
 527       lt_enable_auto_import="-Wl,--enable-auto-import"
 528       ;;
 529 esac
 530 AC_SUBST(lt_enable_auto_import)
 531
 532
 533 ### Checks for library functions
 534
 535 AC_ISC_POSIX
 536
 537 AC_FUNC_ALLOCA
 538
 539 case "$host_os" in
 540    mingw*)
 541       AC_DEFINE([HAVE_REALPATH], [1], [Define to 1 if you have the `realpath' function.])
 542       ;;
 543    *)
 544       AC_CHECK_FUNCS([realpath])
 545       ;;
 546 esac
 547
 548 ### Unit tests, coverage and benchmarking
 549
 550 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 551
 552 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 553 EDJE_CFLAGS="${EDJE_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 554 EDJE_LIBS="${EDJE_LIBS} ${EFL_COVERAGE_LIBS}"
 555 if test "x$enable_coverage" = "xyes" ; then
 556    EDJE_CFLAGS="${EDJE_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 557 fi
 558
 559 ## Examples
 560
 561 build_examples="no"
 562 AC_ARG_ENABLE([build-examples],
 563    AC_HELP_STRING([--enable-build-examples],
 564                   [Enable building examples. This requires extra dependencies. If you don't have them installed yet, don't build with this option or it will fail. Build again when you have it, overriding the previous installation). @<:@default==disabled@:>@]),
 565    [
 566     if test "x${enableval}" = "xyes" ; then
 567        build_examples="yes"
 568     else
 569        build_examples="no"
 570     fi
 571    ],
 572    [build_examples="no"])
 573 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x${build_examples}" = "xyes"])
 574
 575 AC_SUBST(requirement_edje)
 576
 577 AC_OUTPUT([
 578 edje.pc
 579 edje.spec
 580 Makefile
 581 data/Makefile
 582 data/include/Makefile
 583 doc/Makefile
 584 doc/Doxyfile
 585 src/Makefile
 586 src/lib/Makefile
 587 src/bin/Makefile
 588 src/bin/epp/Makefile
 589 src/modules/Makefile
 590 src/modules/alsa_snd_player/Makefile
 591 src/modules/eet_snd_reader/Makefile
 592 src/modules/multisense_factory/Makefile
 593 src/tests/Makefile
 594 utils/Makefile
 595 src/examples/Makefile
 596 ])
 597
 598
 599 #####################################################################
 600 ## Info
 601
 602 echo
 603 echo
 604 echo
 605 echo "------------------------------------------------------------------------"
 606 echo "$PACKAGE $VERSION"
 607 echo "------------------------------------------------------------------------"
 608 echo
 609 echo "Configuration Options Summary:"
 610 echo
 611 echo "  Amalgamation.........: ${do_amalgamation}"
 612 echo "  Ecore IMF............: $have_ecore_imf"
 613 dnl echo "  Multisense...........: $want_multisense"
 614
 615 if test "x${want_multisense}" = "xyes" ; then
 616 echo "  LibRemix.............: $have_libremix"
 617 echo "  Libsndfile...........: $have_sndfile"
 618 echo "  Ogg/Vorbis...........: $have_vorbis"
 619 echo "  LibFLAC..............: $have_flac_lib"
 620 echo "  LibALSA..............: $have_alsa_lib"
 621 fi
 622
 623 echo "  EDJE_PROGRAM_CACHE...: $want_edje_program_cache"
 624 echo "  EDJE_CALC_CACHE......: $want_edje_calc_cache"
 625 echo "  Fixed point..........: $want_fixed_point"
 626 echo "  Documentation........: ${build_doc}"
 627 if test "x${build_doc}" = "xyes" ; then
 628 echo "    Installation.......: make install-doc"
 629 fi
 630 echo "  Tests................: ${enable_tests}"
 631 echo "  Coverage.............: ${enable_coverage}"
 632 echo "  Examples.............: install:${install_examples} build:${build_examples}"
 633 echo
 634 echo "Programs:"
 635 echo
 636 echo "  Build edje_cc................: $have_edje_cc"
 637 echo "  Build edje_decc..............: $have_edje_decc"
 638 echo "  Build edje_recc..............: $have_edje_recc"
 639 echo "  Build edje_player............: $have_edje_player"
 640 echo "  Build edje_inspector.........: $have_edje_inspector"
 641 echo "  Build edje_external_inspector: $have_edje_external_inspector"
 642 echo "  Build edje_watch.............: $have_edje_watch"
 643 echo
 644 echo "Compilation............: make (or gmake)"
 645 echo "  CPPFLAGS.............: $CPPFLAGS"
 646 echo "  CFLAGS...............: $CFLAGS"
 647 echo "  LDFLAGS..............: $LDFLAGS"
 648 echo
 649 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 650 echo "  prefix...............: $prefix"
 651 echo