inference-engine/cmake/developer_package_config.cmake.in

   1 # Copyright (C) 2019 Intel Corporation
   2 # SPDX-License-Identifier: Apache-2.0
   3 #
   4
   5 set(OpenVINO_MAIN_SOURCE_DIR "@CMAKE_SOURCE_DIR@")
   6 set(IE_MAIN_SOURCE_DIR "@CMAKE_SOURCE_DIR@/inference-engine")
   7 file(TO_CMAKE_PATH "${CMAKE_CURRENT_LIST_DIR}" cache_path)
   8
   9 # inherit OpenCV from main IE project
  10 load_cache("${cache_path}" READ_WITH_PREFIX "" OpenCV_DIR)
  11 find_package(OpenCV COMPONENTS imgcodecs)
  12
  13 find_package(Threads REQUIRED)
  14 find_package(gflags REQUIRED PATHS "@InferenceEngine_BINARY_DIR@/samples/thirdparty/gflags")
  15
  16 if(ENABLE_GNA)
  17     set(GNA "@GNA@")
  18 endif()
  19
  20 # Targets
  21
  22 include("${CMAKE_CURRENT_LIST_DIR}/targets_developer.cmake")
  23
  24 # add additional interface include directories needed for plugin development
  25 if(NOT TARGET IE::inference_engine)
  26         message(FATAL_ERROR "The target IE::inference_engine does not exist")
  27 endif()
  28
  29 get_target_property(prepro_headers IE::inference_engine_preproc INTERFACE_INCLUDE_DIRECTORIES)
  30
  31 set(ie_plugin_headers "${IE_MAIN_SOURCE_DIR}/src/inference_engine;${prepro_headers}")
  32 set_property(TARGET IE::inference_engine APPEND PROPERTY INTERFACE_INCLUDE_DIRECTORIES "${ie_plugin_headers}")
  33 set_property(TARGET IE::inference_engine PROPERTY IMPORTED_GLOBAL TRUE)
  34
  35 get_target_property(InferenceEngine_INCLUDE_DIRS IE::inference_engine INTERFACE_INCLUDE_DIRECTORIES)
  36 set(InferenceEngine_LIBRARIES IE::inference_engine IE::inference_engine_nn_builder)
  37
  38 # Variables to export in plugin's projects
  39
  40 set(ie_options "@IE_OPTIONS@;CMAKE_BUILD_TYPE")
  41
  42 load_cache("${cache_path}" READ_WITH_PREFIX "" ${ie_options})
  43
  44 message(STATUS "The following CMake options are exported from Inference Engine Developer package")
  45 message("")
  46 foreach(option IN LISTS ie_options)
  47         message("    ${option}: ${${option}}")
  48 endforeach()
  49 message("")
  50
  51 #
  52 # Common cmake includes
  53 #
  54
  55 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake;${OpenVINO_MAIN_SOURCE_DIR}/cmake;${IE_MAIN_SOURCE_DIR}/cmake")
  56
  57 # generic stuff from developer package
  58 include(developer_package)
  59 include(developer_package_ie)