configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [6])
   6 m4_define([dbus_micro_version], [5])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=10
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=7
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 154 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 155 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 156 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 157 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 158 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 159 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 160
 161 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 162 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 163 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 164 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 165 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 166 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 167 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 168 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 169 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 170 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 171 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 172
 173 AC_ARG_ENABLE([embedded-tests],
 174   AS_HELP_STRING([--enable-embedded-tests],
 175     [enable unit test code in the library and binaries]),
 176   [], [enable_embedded_tests=$enable_developer])
 177 AC_ARG_ENABLE([modular-tests],
 178   AS_HELP_STRING([--enable-modular-tests],
 179     [enable modular regression tests (requires GLib)]),
 180   [], [enable_modular_tests=auto])
 181 # --enable-tests overrides both --enable-embedded-tests and
 182 # --enable-modular-tests
 183 AC_ARG_ENABLE([tests],
 184   AS_HELP_STRING([--enable-tests],
 185     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 186   [
 187   if test "x$enableval" = xyes; then
 188     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 189     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 190   fi
 191   enable_embedded_tests=$enableval
 192   enable_modular_tests=$enableval
 193   ],
 194   [])
 195
 196 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 197 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 198 # name for this.
 199 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 200 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 201   [test "x$enable_embedded_tests" = xyes])
 202 if test "x$enable_embedded_tests" = xyes; then
 203     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 204       [Define to build test code into the library and binaries])
 205     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 206       [Define to build test code into the library and binaries])
 207 fi
 208
 209 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 210 # These use GTest, from GLib, because life's too short. They're enabled by
 211 # default (unless you don't have GLib), because they don't bloat the library
 212 # or binaries.
 213
 214 with_glib=yes
 215
 216 if test "x$enable_modular_tests" != xno; then
 217   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 218     [],
 219     [if test "x$enable_modular_tests" = xyes; then
 220       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 221       AC_MSG_ERROR([$GLIB_ERRORS])
 222     else # assumed to be "auto"
 223       with_glib=no
 224     fi])
 225   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 226   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 227     [],
 228     [if test "x$enable_modular_tests" = xyes; then
 229       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 230       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 231     else # assumed to be "auto"
 232       with_glib=no
 233     fi])
 234 fi
 235 if test "x$enable_modular_tests" != xno; then
 236   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 237     [Define to build independent test binaries])
 238 fi
 239 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 240   [test "x$enable_modular_tests" != xno])
 241
 242 if test "x$with_glib" != xno; then
 243   AC_DEFINE([DBUS_WITH_GLIB], [1],
 244     [Define if GLib, GObject, GIO are available])
 245 fi
 246 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 247
 248 AC_ARG_ENABLE([installed-tests],
 249   AS_HELP_STRING([--enable-installed-tests],
 250     [enable unit test code in the library and binaries]),
 251   [], [enable_installed_tests=no])
 252 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 253   [test "x$enable_installed_tests" = xyes])
 254
 255 if test "x$enable_tests" = xyes; then
 256   # full test coverage is required, Python is a hard dependency
 257   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 258   AM_PATH_PYTHON([2.6])
 259   AC_MSG_CHECKING([for Python modules for full test coverage])
 260   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 261     AC_MSG_RESULT([yes])
 262   else
 263     AC_MSG_RESULT([no])
 264     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 265   fi
 266 else
 267   # --enable-tests not given: do not abort if Python is missing
 268   AM_PATH_PYTHON([2.6], [], [:])
 269 fi
 270
 271 if test x$enable_verbose_mode = xyes; then
 272     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 273 fi
 274
 275 if test x$enable_asserts = xno; then
 276     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 277     DISABLE_UNUSED_WARNINGS="unused-label"
 278     R_DYNAMIC_LDFLAG=""
 279 else
 280     # -rdynamic is needed for glibc's backtrace_symbols to work.
 281     # No clue how much overhead this adds, but it's useful
 282     # to do this on any assertion failure,
 283     # so for now it's enabled anytime asserts are (currently not
 284     # in production builds).
 285
 286     # To get -rdynamic you pass -export-dynamic to libtool.
 287     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 288     R_DYNAMIC_LDFLAG=-export-dynamic
 289 fi
 290 AC_SUBST(R_DYNAMIC_LDFLAG)
 291
 292 if test x$enable_checks = xno; then
 293     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 294     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 295     DISABLE_UNUSED_WARNINGS="unused-label"
 296 fi
 297
 298 if test x$enable_userdb_cache = xyes; then
 299     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 300 fi
 301
 302 if test x$enable_compiler_coverage = xyes; then
 303      ## so that config.h changes when you toggle gcov support
 304      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 305 fi
 306
 307 # glibc21.m4 serial 3
 308 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 309 dnl This file is free software; the Free Software Foundation
 310 dnl gives unlimited permission to copy and/or distribute it,
 311 dnl with or without modifications, as long as this notice is preserved.
 312
 313 # Test for the GNU C Library, version 2.1 or newer.
 314 # From Bruno Haible.
 315
 316 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 317   ac_cv_gnu_library_2_1,
 318   [AC_EGREP_CPP([Lucky GNU user],
 319     [
 320 #include <features.h>
 321 #ifdef __GNU_LIBRARY__
 322  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 323   Lucky GNU user
 324  #endif
 325 #endif
 326     ],
 327     ac_cv_gnu_library_2_1=yes,
 328     ac_cv_gnu_library_2_1=no)
 329   ]
 330 )
 331
 332 #### Integer sizes
 333
 334 AC_CHECK_SIZEOF(char)
 335 AC_CHECK_SIZEOF(short)
 336 AC_CHECK_SIZEOF(long)
 337 AC_CHECK_SIZEOF(int)
 338 AC_CHECK_SIZEOF(void *)
 339 AC_CHECK_SIZEOF(long long)
 340 AC_CHECK_SIZEOF(__int64)
 341
 342 AC_ARG_WITH([64-bit],
 343   [AS_HELP_STRING([--without-64-bit],
 344     [If you have to use this option, please report it as a bug])],
 345   [],
 346   [with_64_bit=yes])
 347
 348 ### See what our 64 bit type is called
 349 AC_MSG_CHECKING([64-bit integer type])
 350
 351 case 8 in
 352 $ac_cv_sizeof_int)
 353   dbusint64=int
 354   dbusint64_constant='(val)'
 355   dbusuint64_constant='(val)'
 356   dbusint64_printf_modifier='""'
 357   ;;
 358 $ac_cv_sizeof_long)
 359   dbusint64=long
 360   dbusint64_constant='(val##L)'
 361   dbusuint64_constant='(val##UL)'
 362   dbusint64_printf_modifier='"l"'
 363   ;;
 364 $ac_cv_sizeof_long_long)
 365   dbusint64='long long'
 366   dbusint64_constant='(val##LL)'
 367   dbusuint64_constant='(val##ULL)'
 368   # Ideally we discover what the format is, but this is
 369   # only used in verbose mode, so eh...
 370   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 371     dbusint64_printf_modifier='"ll"'
 372   fi
 373   ;;
 374 $ac_cv_sizeof___int64)
 375   dbusint64=__int64
 376   dbusint64_constant='(val##i64)'
 377   dbusuint64_constant='(val##ui64)'
 378   # See above case
 379   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 380     dbusint64_printf_modifier='"ll"'
 381   fi
 382   ;;
 383 esac
 384
 385 AS_IF(
 386   [test "x$with_64_bit" = xno],
 387   [
 388         DBUS_INT64_TYPE="no_int64_type_detected"
 389         DBUS_HAVE_INT64=0
 390         DBUS_INT64_CONSTANT=
 391         DBUS_UINT64_CONSTANT=
 392         AC_MSG_RESULT([disabled via --without-64-bit])
 393   ],
 394   dnl else if
 395   [test -z "$dbusint64"],
 396   [AC_MSG_RESULT([not found])
 397   AC_MSG_ERROR([Could not find a 64-bit integer type.
 398
 399 Please report a bug here with details of your platform and compiler:
 400
 401     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 402
 403 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 404 the option "--without-64-bit".
 405
 406 This option is likely to be removed in future, unless you report that your
 407 platform needs it.])
 408   ],
 409   dnl else
 410   [
 411         DBUS_INT64_TYPE="$dbusint64"
 412         DBUS_HAVE_INT64=1
 413         DBUS_INT64_CONSTANT="$dbusint64_constant"
 414         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 415         if test x"$dbusint64_printf_modifier" != x; then
 416                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 417         fi
 418         AC_MSG_RESULT($DBUS_INT64_TYPE)
 419   ])
 420
 421 AC_SUBST(DBUS_INT64_TYPE)
 422 AC_SUBST(DBUS_INT64_CONSTANT)
 423 AC_SUBST(DBUS_UINT64_CONSTANT)
 424 AC_SUBST(DBUS_HAVE_INT64)
 425
 426 ### see what 32-bit int is called
 427 AC_MSG_CHECKING([32-bit integer type])
 428
 429 case 4 in
 430 $ac_cv_sizeof_short)
 431   dbusint32=short
 432   ;;
 433 $ac_cv_sizeof_int)
 434   dbusint32=int
 435   ;;
 436 $ac_cv_sizeof_long)
 437   dbusint32=long
 438   ;;
 439 esac
 440
 441 if test -z "$dbusint32" ; then
 442         DBUS_INT32_TYPE="no_int32_type_detected"
 443         AC_MSG_ERROR([No 32-bit integer type found])
 444 else
 445         DBUS_INT32_TYPE="$dbusint32"
 446         AC_MSG_RESULT($DBUS_INT32_TYPE)
 447 fi
 448
 449 AC_SUBST(DBUS_INT32_TYPE)
 450
 451 ### see what 16-bit int is called
 452 AC_MSG_CHECKING([16-bit integer type])
 453
 454 case 2 in
 455 $ac_cv_sizeof_short)
 456   dbusint16=short
 457   ;;
 458 $ac_cv_sizeof_int)
 459   dbusint16=int
 460   ;;
 461 esac
 462
 463 if test -z "$dbusint16" ; then
 464         DBUS_INT16_TYPE="no_int16_type_detected"
 465         AC_MSG_ERROR([No 16-bit integer type found])
 466 else
 467         DBUS_INT16_TYPE="$dbusint16"
 468         AC_MSG_RESULT($DBUS_INT16_TYPE)
 469 fi
 470
 471 AC_SUBST(DBUS_INT16_TYPE)
 472
 473 ## byte order
 474 case $host_os in
 475         darwin*)
 476                 # check at compile-time, so that it is possible to build universal
 477                 # (with multiple architectures at once on the compile line)
 478                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 479                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 480                         #if defined(__BIG_ENDIAN__)
 481                         #define WORDS_BIGENDIAN 1
 482                         #endif
 483                 ])
 484                 ;;
 485         *)
 486                 AC_C_BIGENDIAN
 487                 ;;
 488 esac
 489
 490 dnl **********************************
 491 dnl *** va_copy checks (from GLib) ***
 492 dnl **********************************
 493 dnl we currently check for all three va_copy possibilities, so we get
 494 dnl all results in config.log for bug reports.
 495 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 496         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 497 #include <stdlib.h>
 498         static void f (int i, ...) {
 499         va_list args1, args2;
 500         va_start (args1, i);
 501         va_copy (args2, args1);
 502         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 503           exit (1);
 504         va_end (args1); va_end (args2);
 505         }
 506         int main() {
 507           f (0, 42);
 508           return 0;
 509         }])],
 510         [dbus_cv_va_copy=yes],
 511         [dbus_cv_va_copy=no])
 512 ])
 513 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 514         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 515 #include <stdlib.h>
 516         static void f (int i, ...) {
 517         va_list args1, args2;
 518         va_start (args1, i);
 519         __va_copy (args2, args1);
 520         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 521           exit (1);
 522         va_end (args1); va_end (args2);
 523         }
 524         int main() {
 525           f (0, 42);
 526           return 0;
 527         }])],
 528         [dbus_cv___va_copy=yes],
 529         [dbus_cv___va_copy=no])
 530 ])
 531
 532 if test "x$dbus_cv_va_copy" = "xyes"; then
 533   dbus_va_copy_func=va_copy
 534 else if test "x$dbus_cv___va_copy" = "xyes"; then
 535   dbus_va_copy_func=__va_copy
 536 fi
 537 fi
 538
 539 if test -n "$dbus_va_copy_func"; then
 540   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 541 fi
 542
 543 AC_LANG_PUSH(C)
 544 AC_CACHE_CHECK([whether va_lists can be copied by value],
 545         dbus_cv_va_val_copy,
 546         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 547 [[
 548         #include <stdarg.h>
 549         #include <stdlib.h>
 550 ]],
 551 [[
 552         static void f (int i, ...) {
 553         va_list args1, args2;
 554         va_start (args1, i);
 555         args2 = args1;
 556         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 557           exit (1);
 558         va_end (args1); va_end (args2);
 559         }
 560         int main() {
 561           f (0, 42);
 562           return 0;
 563         }
 564 ]])],
 565         [dbus_cv_va_val_copy=yes],
 566         [dbus_cv_va_val_copy=no],
 567         [dbus_cv_va_val_copy=yes])
 568 ])
 569 AC_LANG_POP(C)
 570
 571 if test "x$dbus_cv_va_val_copy" = "xno"; then
 572   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 573 fi
 574
 575
 576 #### Atomic integers
 577
 578 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 579   dbus_cv_sync_sub_and_fetch,
 580   [AC_LINK_IFELSE([
 581      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 582      [dbus_cv_sync_sub_and_fetch=yes],
 583      [dbus_cv_sync_sub_and_fetch=no])
 584   ])
 585
 586 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 587    have_sync=1
 588 else
 589    have_sync=0
 590 fi
 591
 592 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 593
 594 #### Various functions
 595 AC_SEARCH_LIBS(socket,[socket network])
 596 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 597
 598 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 599
 600 AC_CHECK_HEADERS([syslog.h])
 601 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 602   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 603 fi
 604
 605 #### Check for broken poll; taken from Glib's configure
 606
 607 AC_MSG_CHECKING([for broken poll])
 608 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 609     #include <stdlib.h>
 610     #include <fcntl.h>
 611     #include <poll.h>
 612     #ifdef HAVE_SYS_POLL_H
 613     #include <sys/poll.h>
 614     #endif
 615     int main(void) {
 616       struct pollfd fds[1];
 617       int fd;
 618       fd = open("/dev/null", 1);
 619       fds[0].fd = fd;
 620       fds[0].events = POLLIN;
 621       fds[0].revents = 0;
 622       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 623             exit(1);  /* Does not work for devices -- fail */
 624       }
 625       exit(0);
 626     }]])],
 627   [broken_poll=no],
 628   [broken_poll=yes
 629    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 630   [broken_poll="no (cross compiling)"])
 631 AC_MSG_RESULT($broken_poll)
 632
 633 AC_MSG_CHECKING(for dirfd)
 634 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 635 #include <sys/types.h>
 636 #include <dirent.h>
 637 ]], [[
 638 DIR *dirp;
 639 dirp = opendir(".");
 640 dirfd(dirp);
 641 closedir(dirp);
 642 ]])],
 643 [dbus_have_dirfd=yes],
 644 [dbus_have_dirfd=no])
 645 AC_MSG_RESULT($dbus_have_dirfd)
 646 if test "$dbus_have_dirfd" = yes; then
 647         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 648 else
 649         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 650         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 651 #include <sys/types.h>
 652 #include <dirent.h>
 653         ]], [[
 654 DIR *dirp;
 655 int fd;
 656 dirp = opendir(".");
 657 fd = dirp->dd_fd;
 658 closedir(dirp);
 659         ]])],
 660         [dbus_have_ddfd=yes],
 661         [dbus_have_ddfd=no])
 662         AC_MSG_RESULT($dbus_have_ddfd)
 663         if test "$dbus_have_ddfd" = yes; then
 664                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 665         fi
 666 fi
 667
 668 AC_CHECK_HEADERS(sys/resource.h)
 669
 670 AC_CHECK_HEADERS(dirent.h)
 671
 672 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 673
 674 AC_CHECK_HEADERS(errno.h)
 675
 676 AC_CHECK_HEADERS(signal.h)
 677
 678 AC_CHECK_HEADERS(locale.h)
 679
 680 AC_CHECK_HEADERS(byteswap.h)
 681
 682 AC_CHECK_HEADERS(unistd.h)
 683
 684 AC_CHECK_HEADERS(ws2tcpip.h)
 685
 686 AC_CHECK_HEADERS(wspiapi.h)
 687
 688 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 689 #
 690 case $host_os in
 691     solaris*)
 692        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 693 esac
 694
 695 # checking for a posix version of getpwnam_r
 696 # if we are cross compiling and can not run the test
 697 # assume getpwnam_r is the posix version
 698 # it is up to the person cross compiling to change
 699 # this behavior if desired
 700 AC_LANG_PUSH(C)
 701 AC_CACHE_CHECK([for posix getpwnam_r],
 702                 ac_cv_func_posix_getpwnam_r,
 703                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 704 [[
 705 #include <errno.h>
 706 #include <pwd.h>
 707 ]],
 708 [[
 709     char buffer[10000];
 710     struct passwd pwd, *pwptr = &pwd;
 711     int error;
 712     errno = 0;
 713     error = getpwnam_r ("", &pwd, buffer,
 714                         sizeof (buffer), &pwptr);
 715    return (error < 0 && errno == ENOSYS)
 716            || error == ENOSYS;
 717 ]])],
 718         [ac_cv_func_posix_getpwnam_r=yes],
 719         [ac_cv_func_posix_getpwnam_r=no],
 720         [ac_cv_func_posix_getpwnam_r=yes]
 721 )])
 722 AC_LANG_POP(C)
 723
 724 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 725         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 726                 [Have POSIX function getpwnam_r])
 727 else
 728         AC_CACHE_CHECK([for nonposix getpwnam_r],
 729                 ac_cv_func_nonposix_getpwnam_r,
 730                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 731                         struct passwd pwd;
 732                         getpwnam_r ("", &pwd, buffer,
 733                                         sizeof (buffer));]])],
 734                         [ac_cv_func_nonposix_getpwnam_r=yes],
 735                         [ac_cv_func_nonposix_getpwnam_r=no])])
 736                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 737                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 738                         [Have non-POSIX function getpwnam_r])
 739         fi
 740 fi
 741
 742 dnl check for socklen_t
 743 AC_MSG_CHECKING(whether socklen_t is defined)
 744 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 745 #include <sys/types.h>
 746 #include <sys/socket.h>
 747 #include <netdb.h>
 748 ]], [[
 749 socklen_t foo;
 750 foo = 1;
 751 ]])],
 752 [dbus_have_socklen_t=yes],
 753 [dbus_have_socklen_t=no])
 754 AC_MSG_RESULT($dbus_have_socklen_t)
 755
 756 if test "x$dbus_have_socklen_t" = "xyes"; then
 757     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 758 fi
 759
 760 dnl check for writev header and writev function so we're
 761 dnl good to go if HAVE_WRITEV gets defined.
 762 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 763
 764 dnl needed on darwin for NAME_MAX
 765 AC_CHECK_HEADERS(sys/syslimits.h)
 766
 767 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 768 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 769
 770 dnl check for flavours of varargs macros (test from GLib)
 771 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 772 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 773 int a(int p1, int p2, int p3);
 774 #define call_a(...) a(1,__VA_ARGS__)
 775 call_a(2,3);
 776 ]])],
 777 [dbus_have_iso_c_varargs=yes],
 778 [dbus_have_iso_c_varargs=no])
 779 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 780
 781 AC_MSG_CHECKING(for GNUC varargs macros)
 782 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 783 int a(int p1, int p2, int p3);
 784 #define call_a(params...) a(1,params)
 785 call_a(2,3);
 786 ]])],
 787 [dbus_have_gnuc_varargs=yes],
 788 [dbus_have_gnuc_varargs=no])
 789 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 790
 791 dnl Output varargs tests
 792 if test x$dbus_have_iso_c_varargs = xyes; then
 793     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 794 fi
 795 if test x$dbus_have_gnuc_varargs = xyes; then
 796     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 797 fi
 798
 799 dnl Check for various credentials.
 800 AC_MSG_CHECKING(for struct cmsgcred)
 801 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 802 #include <sys/types.h>
 803 #include <sys/socket.h>
 804 ]], [[
 805 struct cmsgcred cred;
 806
 807 cred.cmcred_pid = 0;
 808 ]])],
 809 [dbus_have_struct_cmsgcred=yes],
 810 [dbus_have_struct_cmsgcred=no])
 811 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 812
 813 if test x$dbus_have_struct_cmsgcred = xyes; then
 814     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 815 fi
 816
 817 AC_CHECK_FUNCS(getpeerucred getpeereid)
 818
 819 AC_CHECK_FUNCS(pipe2 accept4)
 820
 821 #### Abstract sockets
 822
 823 if test x$enable_abstract_sockets = xauto; then
 824 AC_LANG_PUSH(C)
 825 warn_on_xcompile=no
 826 AC_CACHE_CHECK([abstract socket namespace],
 827                 ac_cv_have_abstract_sockets,
 828                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 829 [[
 830 #include <sys/types.h>
 831 #include <stdlib.h>
 832 #include <string.h>
 833 #include <stdio.h>
 834 #include <sys/socket.h>
 835 #include <sys/un.h>
 836 #include <errno.h>
 837 ]],
 838 [[
 839   size_t slen;
 840   int listen_fd;
 841   struct sockaddr_un addr;
 842
 843   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 844
 845   if (listen_fd < 0)
 846     {
 847       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 848       exit (1);
 849     }
 850
 851   memset (&addr, '\0', sizeof (addr));
 852   addr.sun_family = AF_UNIX;
 853   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 854   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 855    * beginning.
 856    */
 857   slen = SUN_LEN(&addr);
 858   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 859
 860   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 861     {
 862        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 863                 strerror (errno));
 864        exit (1);
 865     }
 866   else
 867     exit (0);
 868 ]])],
 869               [ac_cv_have_abstract_sockets=yes],
 870               [ac_cv_have_abstract_sockets=no],
 871               [
 872                 ac_cv_have_abstract_sockets=no
 873                 warn_on_xcompile=yes
 874               ]
 875 )])
 876 if test x$warn_on_xcompile = xyes ; then
 877   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 878 fi
 879 AC_LANG_POP(C)
 880 fi
 881
 882 if test x$enable_abstract_sockets = xyes; then
 883     if test x$ac_cv_have_abstract_sockets = xno; then
 884         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 885     fi
 886 fi
 887
 888 if test x$enable_abstract_sockets = xno; then
 889    ac_cv_have_abstract_sockets=no;
 890 fi
 891
 892 if test x$ac_cv_have_abstract_sockets = xyes ; then
 893    DBUS_PATH_OR_ABSTRACT=abstract
 894    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 895 else
 896    DBUS_PATH_OR_ABSTRACT=path
 897 fi
 898
 899 # this is used in addresses to prefer abstract, e.g.
 900 # unix:path=/foo or unix:abstract=/foo
 901 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 902
 903 PKG_PROG_PKG_CONFIG
 904
 905 #### Sort out XML library
 906
 907 # see what we have
 908 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 909              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 910              have_expat=false)
 911
 912 # see what we want to use
 913 dbus_use_libxml=false
 914 dbus_use_expat=false
 915 if test x$with_xml = xexpat; then
 916         if ! $have_expat ; then
 917            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 918         fi
 919         dbus_use_expat=true
 920 elif test x$with_xml = xlibxml; then
 921         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 922         if ! $have_libxml ; then
 923            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 924         fi
 925         dbus_use_libxml=true
 926 else
 927         ### expat is the default because libxml can't currently survive
 928         ### our brutal OOM-handling unit test setup.
 929         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 930         if test x$have_expat = xfalse; then
 931                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 932         fi
 933         ### By default, only use Expat since it's tested and known to work.  If you're a
 934         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 935         ### if your OS is built around libxml, that's another case.
 936         dbus_use_expat=true
 937 fi
 938
 939 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 940 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 941
 942 if $dbus_use_expat; then
 943    XML_LIBS=-lexpat
 944    XML_CFLAGS=
 945 fi
 946 if $dbus_use_libxml; then
 947    XML_LIBS=$LIBXML_LIBS
 948    XML_CFLAGS=$LIBXML_CFLAGS
 949 fi
 950 AC_SUBST([XML_CFLAGS])
 951 AC_SUBST([XML_LIBS])
 952
 953 # Thread lib detection
 954 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 955                                                     [THREAD_LIBS="-lpthread"])])
 956 save_libs="$LIBS"
 957 LIBS="$LIBS $THREAD_LIBS"
 958 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 959 if test x$have_pthread_condattr_setclock = xtrue; then
 960     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 961     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 962     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 963 #include <pthread.h>
 964 ]], [[
 965 struct timespec monotonic_timer;
 966 pthread_condattr_t attr;
 967 pthread_condattr_init (&attr);
 968 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 969 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 970 ]])],
 971 [have_clock_monotonic=true],
 972 [have_clock_monotonic=false])
 973 if test x$have_clock_monotonic = xtrue; then
 974     AC_MSG_RESULT([found])
 975     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 976 else
 977     AC_MSG_RESULT([not found])
 978 fi
 979 fi
 980 LIBS="$save_libs"
 981
 982 AC_SUBST([THREAD_LIBS])
 983
 984 # SELinux detection
 985 if test x$enable_selinux = xno ; then
 986     have_selinux=no;
 987 else
 988     # See if we have SELinux library
 989     AC_CHECK_LIB(selinux, is_selinux_enabled,
 990                  have_selinux=yes, have_selinux=no)
 991
 992     # see if we have the SELinux header with the new D-Bus stuff in it
 993     if test x$have_selinux = xyes ; then
 994         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 995         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 996                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 997                             #else
 998                             #error DBUS__ACQUIRE_SVC not defined
 999                             #endif]])],
1000                           [have_selinux=yes],
1001                           [have_selinux=no])
1002         AC_MSG_RESULT($have_selinux)
1003     fi
1004
1005     if test x$enable_selinux = xauto ; then
1006         if test x$have_selinux = xno ; then
1007                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1008         fi
1009     else
1010         if test x$have_selinux = xno ; then
1011                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1012         fi
1013     fi
1014 fi
1015
1016 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1017
1018 if test x$have_selinux = xyes ; then
1019     # the selinux code creates threads
1020     # which requires libpthread even on linux
1021     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1022                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1023
1024     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1025     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1026 else
1027     SELINUX_LIBS=
1028 fi
1029
1030 # inotify checks
1031 if test x$enable_inotify = xno ; then
1032     have_inotify=no;
1033 else
1034     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1035 fi
1036
1037 dnl check if inotify backend is enabled
1038 if test x$have_inotify = xyes; then
1039    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1040    AC_CHECK_FUNCS(inotify_init1)
1041 fi
1042
1043 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1044
1045 # dnotify checks
1046 if test x$enable_dnotify = xno ; then
1047     have_dnotify=no;
1048 else
1049     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1050         have_dnotify=yes;
1051     else
1052         have_dnotify=no;
1053     fi
1054 fi
1055
1056 dnl check if dnotify backend is enabled
1057 if test x$have_dnotify = xyes; then
1058    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1059 fi
1060
1061 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1062
1063 # For simplicity, we require the userland API for epoll_create1 at
1064 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1065 # not to have it at runtime.
1066 AC_ARG_ENABLE([epoll],
1067               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1068               [enable_epoll=$enableval], [enable_epoll=auto])
1069 if test x$enable_epoll = xno; then
1070     have_linux_epoll=no
1071 else
1072     AC_MSG_CHECKING([for Linux epoll(4)])
1073     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1074         [
1075         #ifndef __linux__
1076         #error This is not Linux
1077         #endif
1078         #include <sys/epoll.h>
1079         ],
1080         [epoll_create1 (EPOLL_CLOEXEC);])],
1081         [have_linux_epoll=yes],
1082         [have_linux_epoll=no])
1083     AC_MSG_RESULT([$have_linux_epoll])
1084 fi
1085 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1086     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1087 fi
1088 if test x$have_linux_epoll = xyes; then
1089   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1090 fi
1091 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1092
1093 # kqueue checks
1094 if test x$enable_kqueue = xno ; then
1095     have_kqueue=no
1096 else
1097     have_kqueue=yes
1098     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1099     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1100
1101     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1102         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1103     fi
1104 fi
1105
1106 dnl check if kqueue backend is enabled
1107 if test x$have_kqueue = xyes; then
1108    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1109 fi
1110
1111 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1112
1113 # launchd checks
1114 if test x$enable_launchd = xno ; then
1115     have_launchd=no
1116 else
1117     have_launchd=yes
1118     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1119     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1120     if test "x$LAUNCHCTL" = "x"; then
1121         have_launchd=no
1122     fi
1123
1124     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1125         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1126     fi
1127 fi
1128
1129 dnl check if launchd is enabled
1130 if test x$have_launchd = xyes; then
1131     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1132 fi
1133
1134 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1135
1136 #### Directory to place launchd agent file
1137 if test "x$with_launchd_agent_dir" = "x"; then
1138    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1139 else
1140    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1141 fi
1142
1143 AC_SUBST(LAUNCHD_AGENT_DIR)
1144
1145 dnl console owner file
1146 if test x$enable_console_owner_file = xno ; then
1147     have_console_owner_file=no;
1148 else
1149     case $host_os in
1150     solaris*)
1151         have_console_owner_file=yes;
1152         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1153         ;;
1154     *)
1155         have_console_owner_file=no;;
1156     esac
1157 fi
1158
1159 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1160
1161 dnl systemd detection
1162 if test x$enable_systemd = xno ; then
1163     have_systemd=no;
1164 else
1165     PKG_CHECK_MODULES(SYSTEMD,
1166         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1167         have_systemd=yes,
1168         have_systemd=no)
1169 fi
1170
1171 if test x$have_systemd = xyes; then
1172     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1173 fi
1174
1175 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1176     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1177 fi
1178
1179 # libaudit detection
1180 if test x$enable_libaudit = xno ; then
1181     have_libaudit=no;
1182 else
1183     # See if we have audit daemon & capabilities library
1184     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1185                  have_libaudit=yes, have_libaudit=no)
1186     if test x$have_libaudit = xyes ; then
1187         AC_CHECK_LIB(cap-ng, capng_clear,
1188                  have_libaudit=yes, have_libaudit=no)
1189     fi
1190 fi
1191
1192 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1193
1194 if test x$have_libaudit = xyes ; then
1195     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1196     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1197 fi
1198
1199 AC_SUBST([SELINUX_LIBS])
1200
1201 # Check for ADT API (Solaris Basic Security Mode auditing)
1202 AC_MSG_CHECKING(for ADT API)
1203 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1204 #include <bsm/adt.h>
1205 adt_user_context = ADT_USER;
1206 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1207
1208 if test ${check_adt_audit} = yes
1209 then
1210    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1211    ADT_LIBS="-lbsm"
1212    LIBS="-lbsm $LIBS"
1213    AC_MSG_RESULT(yes)
1214 else
1215    AC_MSG_RESULT(no)
1216 fi
1217 AC_SUBST([ADT_LIBS])
1218
1219 # Check for SCM_RIGHTS
1220 AC_MSG_CHECKING([for SCM_RIGHTS])
1221 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1222 #include <sys/socket.h>
1223 #include <sys/un.h>
1224 static int x = SCM_RIGHTS;
1225 ]], [[]])],
1226 [ AC_MSG_RESULT([supported])
1227   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1228 [ AC_MSG_RESULT([not supported]) ])
1229
1230 NETWORK_libs=
1231 if test x$dbus_win = xyes ; then
1232   if test x$dbus_wince = xyes ; then
1233     NETWORK_libs="-lws2"
1234   else
1235     NETWORK_libs="-lws2_32"
1236   fi
1237 fi
1238
1239 AC_SUBST([NETWORK_libs])
1240
1241 AC_ARG_WITH([valgrind],
1242   [AS_HELP_STRING([--with-valgrind],
1243      [Add instrumentation to help valgrind to understand our allocator])],
1244   [],
1245   [with_valgrind=no])
1246
1247 if test x$with_valgrind != xno; then
1248   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1249   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1250 fi
1251
1252 #### Set up final flags
1253 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1254 AC_SUBST([LIBDBUS_LIBS])
1255
1256 ### X11 detection
1257 DBUS_X_LIBS=
1258 DBUS_X_CFLAGS=
1259
1260 AC_ARG_ENABLE([x11-autolaunch],
1261   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1262   [], [enable_x11_autolaunch=auto])
1263
1264 if test "x$dbus_win" = xyes; then
1265     if test "x$enable_x11_autolaunch" = xyes; then
1266         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1267     fi
1268
1269     enable_x11_autolaunch=no
1270     have_x11=no
1271 else
1272     AC_PATH_XTRA
1273
1274     if test "x$no_x" = xyes; then
1275         have_x11=no
1276     else
1277         have_x11=yes
1278         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1279         DBUS_X_CFLAGS="$X_CFLAGS"
1280     fi
1281 fi
1282
1283 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1284     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1285 else
1286     # move from "auto" to "yes" or "no" if necessary
1287     if test "x$enable_x11_autolaunch" != xno; then
1288         enable_x11_autolaunch="$have_x11"
1289     fi
1290 fi
1291
1292 if test "x$have_x11" = xyes ; then
1293    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1294 fi
1295
1296 if test "x$enable_x11_autolaunch" = xyes ; then
1297    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1298 fi
1299
1300 AC_SUBST([DBUS_X_CFLAGS])
1301 AC_SUBST([DBUS_X_LIBS])
1302
1303 #### gcc warning flags
1304
1305 cc_supports_flag() {
1306   AC_MSG_CHECKING(whether $CC supports "$*")
1307   save_CFLAGS="$CFLAGS"
1308   CFLAGS="$*"
1309   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1310   CFLAGS="$save_CFLAGS"
1311   AC_MSG_RESULT([$rc])
1312   test "x$rc" = xyes
1313 }
1314
1315 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1316   dnl Use -Werror by default if:
1317   dnl - we're not on Windows (too many warnings), and
1318   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1319   dnl Override with --enable-Werror or --disable-Werror
1320   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1321
1322   dnl Enable these warnings if possible:
1323   [all \
1324    extra \
1325    char-subscripts \
1326    missing-declarations \
1327    missing-prototypes \
1328    nested-externs \
1329    pointer-arith \
1330    cast-align \
1331    no-address \
1332    float-equal \
1333    declaration-after-statement \
1334   ],
1335
1336   dnl Disable these warnings if possible, make them non-fatal if possible,
1337   dnl and don't enable -Werror unless we succeeded.
1338   dnl
1339   dnl Intentional:
1340   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1341   dnl   checking or not asserting
1342   dnl - missing field initializers being 0 is a C feature, not a bug
1343   dnl - unused-parameter is to make writing callbacks less annoying
1344   dnl
1345   dnl To be fixed one day:
1346   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1347   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1348   dnl   is better than nothing
1349   [$DISABLE_UNUSED_WARNINGS \
1350    missing-field-initializers \
1351    unused-parameter \
1352    sign-compare \
1353    pointer-sign \
1354    type-limits \
1355   ])
1356
1357 if test "x$GCC" = "xyes"; then
1358   # We're treating -fno-common like a warning: it makes the linker more
1359   # strict, because on some systems the linker is *always* this strict
1360   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1361
1362   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1363   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1364
1365   if test "x$enable_ansi" = "xyes"; then
1366     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1367       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1368   fi
1369 fi
1370
1371 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1372 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1373 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1374 dnl is the next best thing
1375 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1376
1377 case $host_os in
1378     solaris*)
1379         # Solaris' C library apparently needs these runes to be threadsafe...
1380         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1381         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1382         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1383         # ... and this opt-in to get file descriptor passing support
1384         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1385         ;;
1386 esac
1387
1388 ### Doxygen Documentation
1389
1390 AC_PATH_PROG(DOXYGEN, doxygen, no)
1391
1392 AC_MSG_CHECKING([whether to build Doxygen documentation])
1393
1394 if test x$DOXYGEN = xno ; then
1395     have_doxygen=no
1396 else
1397     have_doxygen=yes
1398 fi
1399
1400 if test x$enable_doxygen_docs = xauto ; then
1401     if test x$have_doxygen = xno ; then
1402         enable_doxygen_docs=no
1403     else
1404         enable_doxygen_docs=yes
1405     fi
1406 fi
1407
1408 if test x$enable_doxygen_docs = xyes; then
1409     if test x$have_doxygen = xno; then
1410         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1411     fi
1412 fi
1413
1414 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1415 AC_MSG_RESULT($enable_doxygen_docs)
1416
1417 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1418 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1419
1420 ### XML Documentation
1421
1422 AC_PATH_PROG(XMLTO, xmlto, no)
1423
1424 AC_MSG_CHECKING([whether to build XML documentation])
1425
1426 if test x$XMLTO = xno ; then
1427     have_xmlto=no
1428 else
1429     have_xmlto=yes
1430 fi
1431
1432 if test x$enable_xml_docs = xauto ; then
1433     if test x$have_xmlto = xno ; then
1434         enable_xml_docs=no
1435     else
1436         enable_xml_docs=yes
1437     fi
1438 fi
1439
1440 if test x$enable_xml_docs = xyes; then
1441     if test x$have_xmlto = xno; then
1442         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1443     fi
1444 fi
1445
1446 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1447 AC_MSG_RESULT($enable_xml_docs)
1448
1449 AC_PATH_PROG([MAN2HTML], [man2html])
1450 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1451 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1452
1453 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1454     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1455          x$MAN2HTML != x)
1456
1457 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1458
1459 #### find the actual value for $prefix that we'll end up with
1460 ##   (I know this is broken and should be done in the Makefile, but
1461 ##    that's a major pain and almost nobody actually seems to care)
1462 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1463 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1464 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1465 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1466 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1467 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1468 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1469
1470 #### Check our operating system
1471 operating_system=unknown
1472 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1473    operating_system=redhat
1474 fi
1475
1476 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1477    operating_system=slackware
1478 fi
1479
1480 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1481    operating_system=cygwin
1482 fi
1483
1484 #### Sort out init scripts
1485
1486 if test x$with_init_scripts = x; then
1487     case x$operating_system in
1488         xredhat)        with_init_scripts=redhat ;;
1489         xslackware)     with_init_scripts=slackware ;;
1490         xcygwin)        with_init_scripts=cygwin ;;
1491         *)                      with_init_scripts=none ;;
1492     esac
1493 fi
1494
1495 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1496 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1497 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1498
1499 ##### systemd unit files
1500 AC_ARG_WITH([systemdsystemunitdir],
1501 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1502     [],
1503     [
1504     PKG_CHECK_EXISTS([systemd],
1505       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1506       [with_systemdsystemunitdir=no])
1507     ])
1508 if test "x$with_systemdsystemunitdir" != xno; then
1509    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1510 fi
1511 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1512
1513 ##### Set up location for system bus socket
1514 if ! test -z "$with_system_socket"; then
1515    DBUS_SYSTEM_SOCKET=$with_system_socket
1516 else
1517    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1518 fi
1519
1520 AC_SUBST(DBUS_SYSTEM_SOCKET)
1521 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1522
1523 ## System bus only listens on local domain sockets, and never
1524 ## on an abstract socket (so only root can create the socket).
1525 ##
1526 ## This won't work on Windows. It's not meant to - the system bus is
1527 ## meaningless on Windows anyway.
1528 ##
1529 ## This has to be suitable for hard-coding in client libraries as well as
1530 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1531 ## and also to connect to. If this ever changes, it'll need to be split into
1532 ## two variables, one for the listening address and one for the connecting
1533 ## address.
1534 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1535 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1536 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1537
1538 #### Set up the pid file
1539 if ! test -z "$with_system_pid_file"; then
1540    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1541 elif test x$with_init_scripts = xredhat ; then
1542    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1543 else
1544    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1545 fi
1546
1547 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1548
1549 #### Directory to check for console ownership
1550 if ! test -z "$with_console_auth_dir"; then
1551    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1552 else
1553    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1554 fi
1555
1556 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1557 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1558
1559 #### File to check for console ownership
1560 if test x$have_console_owner_file = xyes; then
1561    if ! test -z "$with_console_owner_file"; then
1562       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1563    else
1564       DBUS_CONSOLE_OWNER_FILE=/dev/console
1565    fi
1566 else
1567   DBUS_CONSOLE_OWNER_FILE=
1568 fi
1569
1570 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1571 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1572
1573 #### User to start the system bus as
1574 if test -z "$with_dbus_user" ; then
1575     DBUS_USER=messagebus
1576 else
1577     DBUS_USER=$with_dbus_user
1578 fi
1579 AC_SUBST(DBUS_USER)
1580 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1581
1582 #### Prefix to install into
1583 DBUS_PREFIX=$EXPANDED_PREFIX
1584 AC_SUBST(DBUS_PREFIX)
1585 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1586
1587 #### Direcotry to install data files into
1588 DBUS_DATADIR=$EXPANDED_DATADIR
1589 AC_SUBST(DBUS_DATADIR)
1590 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1591
1592 #### Directory to install dbus-daemon
1593 if test -z "$with_dbus_daemondir" ; then
1594     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1595 else
1596     DBUS_DAEMONDIR=$with_dbus_daemondir
1597 fi
1598 AC_SUBST(DBUS_DAEMONDIR)
1599 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1600
1601 #### Directory to install the other binaries
1602 DBUS_BINDIR="$EXPANDED_BINDIR"
1603 AC_SUBST(DBUS_BINDIR)
1604 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1605
1606 #### Directory to install the libexec binaries
1607 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1608 AC_SUBST(DBUS_LIBEXECDIR)
1609 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1610
1611 #### Tell tests where to find certain stuff in builddir
1612
1613 DBUS_PWD=`pwd`
1614 # Useful in a cross-compilation environment, where the tests are run on the host system.
1615 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1616                            DBUS_PWD=$withval)
1617
1618 DBUS_TEST_EXEC="$DBUS_PWD/test"
1619 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1620
1621 AC_SUBST([DBUS_TEST_DATA])
1622 AC_SUBST([DBUS_TEST_EXEC])
1623
1624 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1625                    [Full path to the daemon in the builddir])
1626 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1627                    [Extension for executables, typically empty or .exe])
1628
1629 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1630                    [Full path to the daemon in the builddir])
1631 AC_SUBST(TEST_BUS_BINARY)
1632
1633 ## Export the non-setuid external helper
1634 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1635 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1636 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1637                    [Full path to the launch helper test program in the builddir])
1638
1639 #### Find socket directories
1640 if ! test -z "$TMPDIR" ; then
1641    DEFAULT_SOCKET_DIR=$TMPDIR
1642 elif ! test -z "$TEMP" ; then
1643    DEFAULT_SOCKET_DIR=$TEMP
1644 elif ! test -z "$TMP" ; then
1645    DEFAULT_SOCKET_DIR=$TMP
1646 else
1647    DEFAULT_SOCKET_DIR=/tmp
1648 fi
1649
1650 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1651
1652 if ! test -z "$with_test_socket_dir" ; then
1653    TEST_SOCKET_DIR="$with_test_socket_dir"
1654 else
1655    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1656 fi
1657 AC_SUBST(TEST_SOCKET_DIR)
1658 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1659
1660 if test "x$dbus_unix" = xyes; then
1661   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1662 else
1663   TEST_LISTEN="tcp:host=localhost"
1664 fi
1665 AC_SUBST([TEST_LISTEN])
1666 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1667   [Listening address for regression tests])
1668
1669 if ! test -z "$with_session_socket_dir" ; then
1670    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1671 else
1672    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1673 fi
1674 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1675 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1676
1677 # This must be a listening address. It doesn't necessarily need to be an
1678 # address you can connect to - it can be something vague like
1679 # "nonce-tcp:".
1680 #
1681 # The default varies by platform.
1682 AC_ARG_WITH([dbus_session_bus_listen_address],
1683             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1684                            [default address for a session bus to listen on (see configure.ac)]),
1685             [with_dbus_session_bus_listen_address=$withval],
1686             [with_dbus_session_bus_listen_address=])
1687
1688 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1689         # the user specified something, trust them
1690         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1691 elif test x$dbus_win = xyes; then
1692         # On Windows, you can (and should) listen on autolaunch addresses,
1693         # because autolaunching is different.
1694         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1695         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1696 elif test x$have_launchd = xyes; then
1697         # Mac OS X default is to use launchd
1698         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1699 else
1700         # The default on all other Unix platforms (notably Linux)
1701         # is to create a randomly named socket in /tmp or similar
1702         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1703 fi
1704 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1705
1706 # This must be an address you can connect to. It doesn't necessarily
1707 # need to be an address you can listen on - it can be "autolaunch:",
1708 # even on Unix.
1709 #
1710 # The default varies by platform.
1711 AC_ARG_WITH([dbus_session_bus_connect_address],
1712             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1713                            [fallback address for a session bus client to connect to (see configure.ac)]),
1714             [with_dbus_session_bus_connect_address=$withval],
1715             [with_dbus_session_bus_connect_address=])
1716
1717 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1718         # the user specified something, trust them
1719         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1720 elif test x$dbus_win = xyes; then
1721         # Windows autolaunching is a bit different; leaving it in its own
1722         # branch of the conditional because the default might conceivably
1723         # change (see #38201)
1724         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1725 else
1726         # The default on all other Unix platforms (notably Linux)
1727         # is to use auto-launching - this works a bit differently on Mac OS X
1728         # but comes out basically the same in the end
1729         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1730 fi
1731 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1732 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1733   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1734   [Fallback address for session bus clients])
1735
1736 # darwin needs this to initialize the environment
1737 AC_CHECK_HEADERS(crt_externs.h)
1738 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1739 AH_VERBATIM(_DARWIN_ENVIRON,
1740 [
1741 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1742 # include <sys/time.h>
1743 # include <crt_externs.h>
1744 # define environ (*_NSGetEnviron())
1745 #endif
1746 ])
1747
1748 AC_ARG_ENABLE([stats],
1749   [AS_HELP_STRING([--enable-stats],
1750     [enable bus daemon usage statistics])],
1751   [], [enable_stats=no])
1752 if test "x$enable_stats" = xyes; then
1753   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1754     [Define to enable bus daemon usage statistics])
1755 fi
1756
1757 AC_CONFIG_FILES([
1758 Doxyfile
1759 dbus/versioninfo.rc
1760 dbus/dbus-arch-deps.h
1761 bus/system.conf
1762 bus/session.conf
1763 bus/messagebus
1764 bus/messagebus-config
1765 bus/org.freedesktop.dbus-session.plist
1766 bus/rc.messagebus
1767 bus/dbus.service
1768 bus/dbus.socket
1769 Makefile
1770 dbus/Makefile
1771 bus/Makefile
1772 tools/Makefile
1773 test/Makefile
1774 test/name-test/Makefile
1775 doc/Makefile
1776 doc/dbus-daemon.1
1777 dbus-1.pc
1778 dbus-1-uninstalled.pc
1779 test/data/valid-config-files/debug-allow-all.conf
1780 test/data/valid-config-files/debug-allow-all-sha1.conf
1781 test/data/valid-config-files-system/debug-allow-all-pass.conf
1782 test/data/valid-config-files-system/debug-allow-all-fail.conf
1783 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1784 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1785 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1786 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1787 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1788 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1789 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1790 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1791 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1792 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1793 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1794 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1795 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1796 ])
1797 AC_OUTPUT
1798
1799 dnl ==========================================================================
1800 echo "
1801                     D-Bus $VERSION
1802                   ==============
1803
1804         prefix:                   ${EXPANDED_PREFIX}
1805         exec_prefix:              ${exec_prefix}
1806         libdir:                   ${EXPANDED_LIBDIR}
1807         libexecdir:               ${EXPANDED_LIBEXECDIR}
1808         bindir:                   ${EXPANDED_BINDIR}
1809         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1810         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1811         datadir:                  ${EXPANDED_DATADIR}
1812         source code location:     ${srcdir}
1813         compiler:                 ${CC}
1814         cflags:                   ${CFLAGS}
1815         cppflags:                 ${CPPFLAGS}
1816         cxxflags:                 ${CXXFLAGS}
1817         64-bit int:               ${DBUS_INT64_TYPE}
1818         32-bit int:               ${DBUS_INT32_TYPE}
1819         16-bit int:               ${DBUS_INT16_TYPE}
1820         Doxygen:                  ${DOXYGEN:-not found}
1821         xmlto:                    ${XMLTO:-not found}
1822         man2html:                 ${MAN2HTML:-not found}"
1823
1824 echo "
1825         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1826         gcc coverage profiling:   ${enable_compiler_coverage}
1827         Building embedded tests:  ${enable_embedded_tests}
1828         Building modular tests:   ${enable_modular_tests}
1829             - with GLib:          ${with_glib}
1830         Building verbose mode:    ${enable_verbose_mode}
1831         Building assertions:      ${enable_asserts}
1832         Building checks:          ${enable_checks}
1833         Building bus stats API:   ${enable_stats}
1834         Building SELinux support: ${have_selinux}
1835         Building inotify support: ${have_inotify}
1836         Building dnotify support: ${have_dnotify}
1837         Building kqueue support:  ${have_kqueue}
1838         Building systemd support: ${have_systemd}
1839         Building X11 code:        ${enable_x11}
1840         Building Doxygen docs:    ${enable_doxygen_docs}
1841         Building XML docs:        ${enable_xml_docs}
1842         Building cache support:   ${enable_userdb_cache}
1843         Building launchd support: ${have_launchd}
1844         Using XML parser:         ${with_xml}
1845         Init scripts style:       ${with_init_scripts}
1846         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1847         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1848         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1849         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1850         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1851         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1852         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1853         Console owner file:       ${have_console_owner_file}
1854         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1855         System bus user:          ${DBUS_USER}
1856         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1857         'make check' socket dir:  ${TEST_SOCKET_DIR}
1858 "
1859 if test x$have_launchd = xyes; then
1860         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1861 fi
1862 echo
1863
1864 if test x$enable_embedded_tests = xyes; then
1865         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1866 fi
1867 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1868         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1869 fi
1870 if test x$enable_compiler_coverage = xyes; then
1871         echo "NOTE: building with coverage profiling is definitely for developers only."
1872 fi
1873 if test x$enable_verbose_mode = xyes; then
1874         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1875 fi
1876 if test x$enable_asserts = xyes; then
1877         echo "NOTE: building with assertions increases library size and decreases performance."
1878 fi
1879 if test x$enable_checks = xno; then
1880         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1881 fi
1882 if test x$dbus_use_libxml = xtrue; then
1883         echo
1884         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1885 fi
1886
1887 if test "x$DBUS_HAVE_INT64" = x0; then
1888   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1889
1890   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1891   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1892   used if your compiler lacks support for 64-bit integers. Please report a bug
1893   with details of your platform and compiler.
1894
1895   This option is likely to be removed in future, unless the D-Bus developers
1896   receive reports that it is still needed.
1897   ])
1898 fi