configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [7])
   6 m4_define([dbus_micro_version], [1])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=11
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=0
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=8
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 154 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 155 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 156 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 157 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 158 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 159 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 160
 161 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 162 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 163 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 164 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 165 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 166 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 167 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 168 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 169 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 170 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 171 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 172
 173 AC_ARG_ENABLE([embedded-tests],
 174   AS_HELP_STRING([--enable-embedded-tests],
 175     [enable unit test code in the library and binaries]),
 176   [], [enable_embedded_tests=$enable_developer])
 177 AC_ARG_ENABLE([modular-tests],
 178   AS_HELP_STRING([--enable-modular-tests],
 179     [enable modular regression tests (requires GLib)]),
 180   [], [enable_modular_tests=auto])
 181 # --enable-tests overrides both --enable-embedded-tests and
 182 # --enable-modular-tests
 183 AC_ARG_ENABLE([tests],
 184   AS_HELP_STRING([--enable-tests],
 185     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 186   [
 187   if test "x$enableval" = xyes; then
 188     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 189     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 190   fi
 191   enable_embedded_tests=$enableval
 192   enable_modular_tests=$enableval
 193   ],
 194   [])
 195
 196 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 197 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 198 # name for this.
 199 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 200 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 201   [test "x$enable_embedded_tests" = xyes])
 202 if test "x$enable_embedded_tests" = xyes; then
 203     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 204       [Define to build test code into the library and binaries])
 205     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 206       [Define to build test code into the library and binaries])
 207 fi
 208
 209 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 210 # These use GTest, from GLib, because life's too short. They're enabled by
 211 # default (unless you don't have GLib), because they don't bloat the library
 212 # or binaries.
 213
 214 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_26], [Ignore post-2.26 deprecations])
 215 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_26], [Prevent post-2.26 APIs])
 216
 217 with_glib=yes
 218
 219 if test "x$enable_modular_tests" != xno; then
 220   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 221     [],
 222     [if test "x$enable_modular_tests" = xyes; then
 223       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 224       AC_MSG_ERROR([$GLIB_ERRORS])
 225     else # assumed to be "auto"
 226       with_glib=no
 227     fi])
 228   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 229   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 230     [],
 231     [if test "x$enable_modular_tests" = xyes; then
 232       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 233       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 234     else # assumed to be "auto"
 235       with_glib=no
 236     fi])
 237 fi
 238 if test "x$enable_modular_tests" != xno; then
 239   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 240     [Define to build independent test binaries])
 241 fi
 242 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 243   [test "x$enable_modular_tests" != xno])
 244
 245 if test "x$with_glib" != xno; then
 246   AC_DEFINE([DBUS_WITH_GLIB], [1],
 247     [Define if GLib, GObject, GIO are available])
 248 fi
 249 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 250
 251 AC_ARG_ENABLE([installed-tests],
 252   AS_HELP_STRING([--enable-installed-tests],
 253     [enable unit test code in the library and binaries]),
 254   [], [enable_installed_tests=no])
 255 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 256   [test "x$enable_installed_tests" = xyes])
 257
 258 if test "x$enable_tests" = xyes; then
 259   # full test coverage is required, Python is a hard dependency
 260   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 261   AM_PATH_PYTHON([2.6])
 262   AC_MSG_CHECKING([for Python modules for full test coverage])
 263   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 264     AC_MSG_RESULT([yes])
 265   else
 266     AC_MSG_RESULT([no])
 267     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 268   fi
 269 else
 270   # --enable-tests not given: do not abort if Python is missing
 271   AM_PATH_PYTHON([2.6], [], [:])
 272 fi
 273
 274 if test x$enable_verbose_mode = xyes; then
 275     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 276 fi
 277
 278 if test x$enable_asserts = xno; then
 279     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 280     DISABLE_UNUSED_WARNINGS="unused-label"
 281     R_DYNAMIC_LDFLAG=""
 282 else
 283     # -rdynamic is needed for glibc's backtrace_symbols to work.
 284     # No clue how much overhead this adds, but it's useful
 285     # to do this on any assertion failure,
 286     # so for now it's enabled anytime asserts are (currently not
 287     # in production builds).
 288
 289     # To get -rdynamic you pass -export-dynamic to libtool.
 290     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 291     R_DYNAMIC_LDFLAG=-export-dynamic
 292 fi
 293 AC_SUBST(R_DYNAMIC_LDFLAG)
 294
 295 if test x$enable_checks = xno; then
 296     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 297     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 298     DISABLE_UNUSED_WARNINGS="unused-label"
 299 fi
 300
 301 if test x$enable_userdb_cache = xyes; then
 302     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 303 fi
 304
 305 if test x$enable_compiler_coverage = xyes; then
 306      ## so that config.h changes when you toggle gcov support
 307      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 308 fi
 309
 310 # glibc21.m4 serial 3
 311 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 312 dnl This file is free software; the Free Software Foundation
 313 dnl gives unlimited permission to copy and/or distribute it,
 314 dnl with or without modifications, as long as this notice is preserved.
 315
 316 # Test for the GNU C Library, version 2.1 or newer.
 317 # From Bruno Haible.
 318
 319 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 320   ac_cv_gnu_library_2_1,
 321   [AC_EGREP_CPP([Lucky GNU user],
 322     [
 323 #include <features.h>
 324 #ifdef __GNU_LIBRARY__
 325  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 326   Lucky GNU user
 327  #endif
 328 #endif
 329     ],
 330     ac_cv_gnu_library_2_1=yes,
 331     ac_cv_gnu_library_2_1=no)
 332   ]
 333 )
 334
 335 #### Integer sizes
 336
 337 AC_CHECK_SIZEOF(char)
 338 AC_CHECK_SIZEOF(short)
 339 AC_CHECK_SIZEOF(long)
 340 AC_CHECK_SIZEOF(int)
 341 AC_CHECK_SIZEOF(void *)
 342 AC_CHECK_SIZEOF(long long)
 343 AC_CHECK_SIZEOF(__int64)
 344
 345 AC_ARG_WITH([64-bit],
 346   [AS_HELP_STRING([--without-64-bit],
 347     [If you have to use this option, please report it as a bug])],
 348   [],
 349   [with_64_bit=yes])
 350
 351 ### See what our 64 bit type is called
 352 AC_MSG_CHECKING([64-bit integer type])
 353
 354 case 8 in
 355 $ac_cv_sizeof_int)
 356   dbusint64=int
 357   dbusint64_constant='(val)'
 358   dbusuint64_constant='(val)'
 359   dbusint64_printf_modifier='""'
 360   ;;
 361 $ac_cv_sizeof_long)
 362   dbusint64=long
 363   dbusint64_constant='(val##L)'
 364   dbusuint64_constant='(val##UL)'
 365   dbusint64_printf_modifier='"l"'
 366   ;;
 367 $ac_cv_sizeof_long_long)
 368   dbusint64='long long'
 369   dbusint64_constant='(val##LL)'
 370   dbusuint64_constant='(val##ULL)'
 371   # Ideally we discover what the format is, but this is
 372   # only used in verbose mode, so eh...
 373   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 374     dbusint64_printf_modifier='"ll"'
 375   fi
 376   ;;
 377 $ac_cv_sizeof___int64)
 378   dbusint64=__int64
 379   dbusint64_constant='(val##i64)'
 380   dbusuint64_constant='(val##ui64)'
 381   # See above case
 382   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 383     dbusint64_printf_modifier='"ll"'
 384   fi
 385   ;;
 386 esac
 387
 388 AS_IF(
 389   [test "x$with_64_bit" = xno],
 390   [
 391         DBUS_INT64_TYPE="no_int64_type_detected"
 392         DBUS_HAVE_INT64=0
 393         DBUS_INT64_CONSTANT=
 394         DBUS_UINT64_CONSTANT=
 395         AC_MSG_RESULT([disabled via --without-64-bit])
 396   ],
 397   dnl else if
 398   [test -z "$dbusint64"],
 399   [AC_MSG_RESULT([not found])
 400   AC_MSG_ERROR([Could not find a 64-bit integer type.
 401
 402 Please report a bug here with details of your platform and compiler:
 403
 404     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 405
 406 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 407 the option "--without-64-bit".
 408
 409 This option is likely to be removed in future, unless you report that your
 410 platform needs it.])
 411   ],
 412   dnl else
 413   [
 414         DBUS_INT64_TYPE="$dbusint64"
 415         DBUS_HAVE_INT64=1
 416         DBUS_INT64_CONSTANT="$dbusint64_constant"
 417         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 418         if test x"$dbusint64_printf_modifier" != x; then
 419                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 420         fi
 421         AC_MSG_RESULT($DBUS_INT64_TYPE)
 422   ])
 423
 424 AC_SUBST(DBUS_INT64_TYPE)
 425 AC_SUBST(DBUS_INT64_CONSTANT)
 426 AC_SUBST(DBUS_UINT64_CONSTANT)
 427 AC_SUBST(DBUS_HAVE_INT64)
 428
 429 ### see what 32-bit int is called
 430 AC_MSG_CHECKING([32-bit integer type])
 431
 432 case 4 in
 433 $ac_cv_sizeof_short)
 434   dbusint32=short
 435   ;;
 436 $ac_cv_sizeof_int)
 437   dbusint32=int
 438   ;;
 439 $ac_cv_sizeof_long)
 440   dbusint32=long
 441   ;;
 442 esac
 443
 444 if test -z "$dbusint32" ; then
 445         DBUS_INT32_TYPE="no_int32_type_detected"
 446         AC_MSG_ERROR([No 32-bit integer type found])
 447 else
 448         DBUS_INT32_TYPE="$dbusint32"
 449         AC_MSG_RESULT($DBUS_INT32_TYPE)
 450 fi
 451
 452 AC_SUBST(DBUS_INT32_TYPE)
 453
 454 ### see what 16-bit int is called
 455 AC_MSG_CHECKING([16-bit integer type])
 456
 457 case 2 in
 458 $ac_cv_sizeof_short)
 459   dbusint16=short
 460   ;;
 461 $ac_cv_sizeof_int)
 462   dbusint16=int
 463   ;;
 464 esac
 465
 466 if test -z "$dbusint16" ; then
 467         DBUS_INT16_TYPE="no_int16_type_detected"
 468         AC_MSG_ERROR([No 16-bit integer type found])
 469 else
 470         DBUS_INT16_TYPE="$dbusint16"
 471         AC_MSG_RESULT($DBUS_INT16_TYPE)
 472 fi
 473
 474 AC_SUBST(DBUS_INT16_TYPE)
 475
 476 ## byte order
 477 case $host_os in
 478         darwin*)
 479                 # check at compile-time, so that it is possible to build universal
 480                 # (with multiple architectures at once on the compile line)
 481                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 482                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 483                         #if defined(__BIG_ENDIAN__)
 484                         #define WORDS_BIGENDIAN 1
 485                         #endif
 486                 ])
 487                 ;;
 488         *)
 489                 AC_C_BIGENDIAN
 490                 ;;
 491 esac
 492
 493 dnl **********************************
 494 dnl *** va_copy checks (from GLib) ***
 495 dnl **********************************
 496 dnl we currently check for all three va_copy possibilities, so we get
 497 dnl all results in config.log for bug reports.
 498 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 499         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 500 #include <stdlib.h>
 501         static void f (int i, ...) {
 502         va_list args1, args2;
 503         va_start (args1, i);
 504         va_copy (args2, args1);
 505         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 506           exit (1);
 507         va_end (args1); va_end (args2);
 508         }
 509         int main() {
 510           f (0, 42);
 511           return 0;
 512         }])],
 513         [dbus_cv_va_copy=yes],
 514         [dbus_cv_va_copy=no])
 515 ])
 516 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 517         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 518 #include <stdlib.h>
 519         static void f (int i, ...) {
 520         va_list args1, args2;
 521         va_start (args1, i);
 522         __va_copy (args2, args1);
 523         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 524           exit (1);
 525         va_end (args1); va_end (args2);
 526         }
 527         int main() {
 528           f (0, 42);
 529           return 0;
 530         }])],
 531         [dbus_cv___va_copy=yes],
 532         [dbus_cv___va_copy=no])
 533 ])
 534
 535 if test "x$dbus_cv_va_copy" = "xyes"; then
 536   dbus_va_copy_func=va_copy
 537 else if test "x$dbus_cv___va_copy" = "xyes"; then
 538   dbus_va_copy_func=__va_copy
 539 fi
 540 fi
 541
 542 if test -n "$dbus_va_copy_func"; then
 543   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 544 fi
 545
 546 AC_LANG_PUSH(C)
 547 AC_CACHE_CHECK([whether va_lists can be copied by value],
 548         dbus_cv_va_val_copy,
 549         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 550 [[
 551         #include <stdarg.h>
 552         #include <stdlib.h>
 553 ]],
 554 [[
 555         static void f (int i, ...) {
 556         va_list args1, args2;
 557         va_start (args1, i);
 558         args2 = args1;
 559         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 560           exit (1);
 561         va_end (args1); va_end (args2);
 562         }
 563         int main() {
 564           f (0, 42);
 565           return 0;
 566         }
 567 ]])],
 568         [dbus_cv_va_val_copy=yes],
 569         [dbus_cv_va_val_copy=no],
 570         [dbus_cv_va_val_copy=yes])
 571 ])
 572 AC_LANG_POP(C)
 573
 574 if test "x$dbus_cv_va_val_copy" = "xno"; then
 575   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 576 fi
 577
 578
 579 #### Atomic integers
 580
 581 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 582   dbus_cv_sync_sub_and_fetch,
 583   [AC_LINK_IFELSE([
 584      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 585      [dbus_cv_sync_sub_and_fetch=yes],
 586      [dbus_cv_sync_sub_and_fetch=no])
 587   ])
 588
 589 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 590    have_sync=1
 591 else
 592    have_sync=0
 593 fi
 594
 595 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 596
 597 #### Various functions
 598 AC_SEARCH_LIBS(socket,[socket network])
 599 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 600
 601 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
 602
 603 AC_CHECK_HEADERS([syslog.h])
 604 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 605   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 606 fi
 607
 608 #### Check for broken poll; taken from Glib's configure
 609
 610 AC_MSG_CHECKING([for broken poll])
 611 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 612     #include <stdlib.h>
 613     #include <fcntl.h>
 614     #include <poll.h>
 615     #ifdef HAVE_SYS_POLL_H
 616     #include <sys/poll.h>
 617     #endif
 618     int main(void) {
 619       struct pollfd fds[1];
 620       int fd;
 621       fd = open("/dev/null", 1);
 622       fds[0].fd = fd;
 623       fds[0].events = POLLIN;
 624       fds[0].revents = 0;
 625       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 626             exit(1);  /* Does not work for devices -- fail */
 627       }
 628       exit(0);
 629     }]])],
 630   [broken_poll=no],
 631   [broken_poll=yes
 632    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 633   [broken_poll="no (cross compiling)"])
 634 AC_MSG_RESULT($broken_poll)
 635
 636 AC_MSG_CHECKING(for dirfd)
 637 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 638 #include <sys/types.h>
 639 #include <dirent.h>
 640 ]], [[
 641 DIR *dirp;
 642 dirp = opendir(".");
 643 dirfd(dirp);
 644 closedir(dirp);
 645 ]])],
 646 [dbus_have_dirfd=yes],
 647 [dbus_have_dirfd=no])
 648 AC_MSG_RESULT($dbus_have_dirfd)
 649 if test "$dbus_have_dirfd" = yes; then
 650         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 651 else
 652         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 653         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 654 #include <sys/types.h>
 655 #include <dirent.h>
 656         ]], [[
 657 DIR *dirp;
 658 int fd;
 659 dirp = opendir(".");
 660 fd = dirp->dd_fd;
 661 closedir(dirp);
 662         ]])],
 663         [dbus_have_ddfd=yes],
 664         [dbus_have_ddfd=no])
 665         AC_MSG_RESULT($dbus_have_ddfd)
 666         if test "$dbus_have_ddfd" = yes; then
 667                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 668         fi
 669 fi
 670
 671 AC_CHECK_HEADERS(sys/resource.h)
 672
 673 AC_CHECK_HEADERS(dirent.h)
 674
 675 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 676
 677 AC_CHECK_HEADERS(errno.h)
 678
 679 AC_CHECK_HEADERS(signal.h)
 680
 681 AC_CHECK_HEADERS(locale.h)
 682
 683 AC_CHECK_HEADERS(byteswap.h)
 684
 685 AC_CHECK_HEADERS(unistd.h)
 686
 687 AC_CHECK_HEADERS(ws2tcpip.h)
 688
 689 AC_CHECK_HEADERS(wspiapi.h)
 690
 691 AC_CHECK_HEADERS(alloca.h)
 692
 693 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 694 #
 695 case $host_os in
 696     solaris*)
 697        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 698 esac
 699
 700 # checking for a posix version of getpwnam_r
 701 # if we are cross compiling and can not run the test
 702 # assume getpwnam_r is the posix version
 703 # it is up to the person cross compiling to change
 704 # this behavior if desired
 705 AC_LANG_PUSH(C)
 706 AC_CACHE_CHECK([for posix getpwnam_r],
 707                 ac_cv_func_posix_getpwnam_r,
 708                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 709 [[
 710 #include <errno.h>
 711 #include <pwd.h>
 712 ]],
 713 [[
 714     char buffer[10000];
 715     struct passwd pwd, *pwptr = &pwd;
 716     int error;
 717     errno = 0;
 718     error = getpwnam_r ("", &pwd, buffer,
 719                         sizeof (buffer), &pwptr);
 720    return (error < 0 && errno == ENOSYS)
 721            || error == ENOSYS;
 722 ]])],
 723         [ac_cv_func_posix_getpwnam_r=yes],
 724         [ac_cv_func_posix_getpwnam_r=no],
 725         [ac_cv_func_posix_getpwnam_r=yes]
 726 )])
 727 AC_LANG_POP(C)
 728
 729 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 730         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 731                 [Have POSIX function getpwnam_r])
 732 else
 733         AC_CACHE_CHECK([for nonposix getpwnam_r],
 734                 ac_cv_func_nonposix_getpwnam_r,
 735                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 736                         struct passwd pwd;
 737                         getpwnam_r ("", &pwd, buffer,
 738                                         sizeof (buffer));]])],
 739                         [ac_cv_func_nonposix_getpwnam_r=yes],
 740                         [ac_cv_func_nonposix_getpwnam_r=no])])
 741                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 742                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 743                         [Have non-POSIX function getpwnam_r])
 744         fi
 745 fi
 746
 747 dnl check for socklen_t
 748 AC_MSG_CHECKING(whether socklen_t is defined)
 749 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 750 #include <sys/types.h>
 751 #include <sys/socket.h>
 752 #include <netdb.h>
 753 ]], [[
 754 socklen_t foo;
 755 foo = 1;
 756 ]])],
 757 [dbus_have_socklen_t=yes],
 758 [dbus_have_socklen_t=no])
 759 AC_MSG_RESULT($dbus_have_socklen_t)
 760
 761 if test "x$dbus_have_socklen_t" = "xyes"; then
 762     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 763 fi
 764
 765 dnl check for writev header and writev function so we're
 766 dnl good to go if HAVE_WRITEV gets defined.
 767 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 768
 769 dnl needed on darwin for NAME_MAX
 770 AC_CHECK_HEADERS(sys/syslimits.h)
 771
 772 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 773 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 774 #include <sys/socket.h> ]])
 775
 776 dnl check for flavours of varargs macros (test from GLib)
 777 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 778 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 779 int a(int p1, int p2, int p3);
 780 #define call_a(...) a(1,__VA_ARGS__)
 781 call_a(2,3);
 782 ]])],
 783 [dbus_have_iso_c_varargs=yes],
 784 [dbus_have_iso_c_varargs=no])
 785 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 786
 787 AC_MSG_CHECKING(for GNUC varargs macros)
 788 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 789 int a(int p1, int p2, int p3);
 790 #define call_a(params...) a(1,params)
 791 call_a(2,3);
 792 ]])],
 793 [dbus_have_gnuc_varargs=yes],
 794 [dbus_have_gnuc_varargs=no])
 795 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 796
 797 dnl Output varargs tests
 798 if test x$dbus_have_iso_c_varargs = xyes; then
 799     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 800 fi
 801 if test x$dbus_have_gnuc_varargs = xyes; then
 802     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 803 fi
 804
 805 dnl Check for various credentials.
 806 AC_MSG_CHECKING(for struct cmsgcred)
 807 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 808 #include <sys/types.h>
 809 #include <sys/socket.h>
 810 ]], [[
 811 struct cmsgcred cred;
 812
 813 cred.cmcred_pid = 0;
 814 ]])],
 815 [dbus_have_struct_cmsgcred=yes],
 816 [dbus_have_struct_cmsgcred=no])
 817 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 818
 819 if test x$dbus_have_struct_cmsgcred = xyes; then
 820     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 821 fi
 822
 823 AC_CHECK_FUNCS(getpeerucred getpeereid)
 824
 825 AC_CHECK_FUNCS(pipe2 accept4)
 826
 827 #### Abstract sockets
 828
 829 if test x$enable_abstract_sockets = xauto; then
 830 AC_LANG_PUSH(C)
 831 warn_on_xcompile=no
 832 AC_CACHE_CHECK([abstract socket namespace],
 833                 ac_cv_have_abstract_sockets,
 834                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 835 [[
 836 #include <sys/types.h>
 837 #include <stdlib.h>
 838 #include <string.h>
 839 #include <stdio.h>
 840 #include <sys/socket.h>
 841 #include <sys/un.h>
 842 #include <errno.h>
 843 ]],
 844 [[
 845   size_t slen;
 846   int listen_fd;
 847   struct sockaddr_un addr;
 848
 849   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 850
 851   if (listen_fd < 0)
 852     {
 853       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 854       exit (1);
 855     }
 856
 857   memset (&addr, '\0', sizeof (addr));
 858   addr.sun_family = AF_UNIX;
 859   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 860   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 861    * beginning.
 862    */
 863   slen = SUN_LEN(&addr);
 864   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 865
 866   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 867     {
 868        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 869                 strerror (errno));
 870        exit (1);
 871     }
 872   else
 873     exit (0);
 874 ]])],
 875               [ac_cv_have_abstract_sockets=yes],
 876               [ac_cv_have_abstract_sockets=no],
 877               [
 878                 ac_cv_have_abstract_sockets=no
 879                 warn_on_xcompile=yes
 880               ]
 881 )])
 882 if test x$warn_on_xcompile = xyes ; then
 883   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 884 fi
 885 AC_LANG_POP(C)
 886 fi
 887
 888 if test x$enable_abstract_sockets = xyes; then
 889     if test x$ac_cv_have_abstract_sockets = xno; then
 890         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 891     fi
 892 fi
 893
 894 if test x$enable_abstract_sockets = xno; then
 895    ac_cv_have_abstract_sockets=no;
 896 fi
 897
 898 if test x$ac_cv_have_abstract_sockets = xyes ; then
 899    DBUS_PATH_OR_ABSTRACT=abstract
 900    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 901 else
 902    DBUS_PATH_OR_ABSTRACT=path
 903 fi
 904
 905 # this is used in addresses to prefer abstract, e.g.
 906 # unix:path=/foo or unix:abstract=/foo
 907 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 908
 909 PKG_PROG_PKG_CONFIG
 910
 911 #### Sort out XML library
 912
 913 # see what we have
 914 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 915              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 916              have_expat=false)
 917
 918 # see what we want to use
 919 dbus_use_libxml=false
 920 dbus_use_expat=false
 921 if test x$with_xml = xexpat; then
 922         if ! $have_expat ; then
 923            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 924         fi
 925         dbus_use_expat=true
 926 elif test x$with_xml = xlibxml; then
 927         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 928         if ! $have_libxml ; then
 929            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 930         fi
 931         dbus_use_libxml=true
 932 else
 933         ### expat is the default because libxml can't currently survive
 934         ### our brutal OOM-handling unit test setup.
 935         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 936         if test x$have_expat = xfalse; then
 937                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 938         fi
 939         ### By default, only use Expat since it's tested and known to work.  If you're a
 940         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 941         ### if your OS is built around libxml, that's another case.
 942         dbus_use_expat=true
 943 fi
 944
 945 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 946 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 947
 948 if $dbus_use_expat; then
 949    XML_LIBS=-lexpat
 950    XML_CFLAGS=
 951 fi
 952 if $dbus_use_libxml; then
 953    XML_LIBS=$LIBXML_LIBS
 954    XML_CFLAGS=$LIBXML_CFLAGS
 955 fi
 956 AC_SUBST([XML_CFLAGS])
 957 AC_SUBST([XML_LIBS])
 958
 959 # Thread lib detection
 960 AC_ARG_VAR([THREAD_LIBS])
 961 save_libs="$LIBS"
 962 LIBS="$LIBS $THREAD_LIBS"
 963
 964 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 965
 966 # Don't do these automatic checks if the user set THREAD_LIBS on the
 967 # configure command-line. If they did, we assume they're right.
 968 #
 969 # We also don't do these checks on Windows, because you don't need magical
 970 # linker flags to have threading support there.
 971 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 972   [
 973     # Mandatory pthread functions. In principle, some of these could be made
 974     # optional if there are platforms that don't have them.
 975     #
 976     # Currently, we only look in -lpthread.
 977     # In principle we might need to look in -lpthreads, -lthreads, ...
 978     # as well - please file a bug if your platform needs this.
 979     AC_SEARCH_LIBS([pthread_cond_timedwait],
 980         [pthread],
 981         [THREAD_LIBS="$LIBS"],
 982         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 983         [])
 984     AC_SEARCH_LIBS([pthread_mutexattr_init],
 985         [pthread],
 986         [THREAD_LIBS="$LIBS"],
 987         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 988         [])
 989     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 990         [pthread],
 991         [THREAD_LIBS="$LIBS"],
 992         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 993         [])
 994
 995     # Optional, for monotonic clocks. Because it's optional, this check
 996     # is non-fatal if we don't find it.
 997     AC_SEARCH_LIBS([pthread_condattr_setclock],
 998         [pthread],
 999         [THREAD_LIBS="$LIBS"])
1000
1001     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
1002       [
1003         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
1004         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1005         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1006 [[#include <time.h>
1007 #include <pthread.h>
1008 ]], [[
1009 struct timespec monotonic_timer;
1010 pthread_condattr_t attr;
1011 pthread_condattr_init (&attr);
1012 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
1013 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
1014 ]])],
1015             [have_clock_monotonic=true],
1016             [have_clock_monotonic=false])
1017         AS_IF([test x$have_clock_monotonic = xtrue],
1018           [
1019             AC_MSG_RESULT([found])
1020             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
1021           ],
1022           [AC_MSG_RESULT([not found])])
1023       ]) dnl have pthread_condattr_setclock
1024   ]) dnl on Unix
1025
1026 LIBS="$save_libs"
1027
1028 AC_SUBST([THREAD_LIBS])
1029
1030 # SELinux detection
1031 if test x$enable_selinux = xno ; then
1032     have_selinux=no;
1033 else
1034     # See if we have SELinux library
1035     AC_CHECK_LIB(selinux, is_selinux_enabled,
1036                  have_selinux=yes, have_selinux=no)
1037
1038     # see if we have the SELinux header with the new D-Bus stuff in it
1039     if test x$have_selinux = xyes ; then
1040         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1041         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1042                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1043                             #else
1044                             #error DBUS__ACQUIRE_SVC not defined
1045                             #endif]])],
1046                           [have_selinux=yes],
1047                           [have_selinux=no])
1048         AC_MSG_RESULT($have_selinux)
1049     fi
1050
1051     if test x$enable_selinux = xauto ; then
1052         if test x$have_selinux = xno ; then
1053                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1054         fi
1055     else
1056         if test x$have_selinux = xno ; then
1057                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1058         fi
1059     fi
1060 fi
1061
1062 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1063
1064 if test x$have_selinux = xyes ; then
1065     # the selinux code creates threads
1066     # which requires libpthread even on linux
1067     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1068                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1069
1070     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1071     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1072 else
1073     SELINUX_LIBS=
1074 fi
1075
1076 # inotify checks
1077 if test x$enable_inotify = xno ; then
1078     have_inotify=no;
1079 else
1080     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1081 fi
1082
1083 dnl check if inotify backend is enabled
1084 if test x$have_inotify = xyes; then
1085    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1086    AC_CHECK_FUNCS(inotify_init1)
1087 fi
1088
1089 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1090
1091 # dnotify checks
1092 if test x$enable_dnotify = xno ; then
1093     have_dnotify=no;
1094 else
1095     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1096         have_dnotify=yes;
1097     else
1098         have_dnotify=no;
1099     fi
1100 fi
1101
1102 dnl check if dnotify backend is enabled
1103 if test x$have_dnotify = xyes; then
1104    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1105 fi
1106
1107 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1108
1109 # For simplicity, we require the userland API for epoll_create1 at
1110 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1111 # not to have it at runtime.
1112 AC_ARG_ENABLE([epoll],
1113               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1114               [enable_epoll=$enableval], [enable_epoll=auto])
1115 if test x$enable_epoll = xno; then
1116     have_linux_epoll=no
1117 else
1118     AC_MSG_CHECKING([for Linux epoll(4)])
1119     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1120         [
1121         #ifndef __linux__
1122         #error This is not Linux
1123         #endif
1124         #include <sys/epoll.h>
1125         ],
1126         [epoll_create1 (EPOLL_CLOEXEC);])],
1127         [have_linux_epoll=yes],
1128         [have_linux_epoll=no])
1129     AC_MSG_RESULT([$have_linux_epoll])
1130 fi
1131 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1132     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1133 fi
1134 if test x$have_linux_epoll = xyes; then
1135   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1136 fi
1137 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1138
1139 # kqueue checks
1140 if test x$enable_kqueue = xno ; then
1141     have_kqueue=no
1142 else
1143     have_kqueue=yes
1144     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1145     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1146
1147     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1148         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1149     fi
1150 fi
1151
1152 dnl check if kqueue backend is enabled
1153 if test x$have_kqueue = xyes; then
1154    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1155 fi
1156
1157 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1158
1159 # launchd checks
1160 if test x$enable_launchd = xno ; then
1161     have_launchd=no
1162 else
1163     have_launchd=yes
1164     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1165     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1166     if test "x$LAUNCHCTL" = "x"; then
1167         have_launchd=no
1168     fi
1169
1170     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1171         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1172     fi
1173 fi
1174
1175 dnl check if launchd is enabled
1176 if test x$have_launchd = xyes; then
1177     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1178 fi
1179
1180 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1181
1182 #### Directory to place launchd agent file
1183 if test "x$with_launchd_agent_dir" = "x"; then
1184    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1185 else
1186    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1187 fi
1188
1189 AC_SUBST(LAUNCHD_AGENT_DIR)
1190
1191 dnl console owner file
1192 if test x$enable_console_owner_file = xno ; then
1193     have_console_owner_file=no;
1194 else
1195     case $host_os in
1196     solaris*)
1197         have_console_owner_file=yes;
1198         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1199         ;;
1200     *)
1201         have_console_owner_file=no;;
1202     esac
1203 fi
1204
1205 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1206
1207 dnl systemd detection
1208 if test x$enable_systemd = xno ; then
1209     have_systemd=no;
1210 else
1211     PKG_CHECK_MODULES(SYSTEMD,
1212         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1213         have_systemd=yes,
1214         have_systemd=no)
1215 fi
1216
1217 if test x$have_systemd = xyes; then
1218     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1219 fi
1220
1221 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1222     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1223 fi
1224
1225 # libaudit detection
1226 if test x$enable_libaudit = xno ; then
1227     have_libaudit=no;
1228 else
1229     # See if we have audit daemon & capabilities library
1230     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1231                  have_libaudit=yes, have_libaudit=no)
1232     if test x$have_libaudit = xyes ; then
1233         AC_CHECK_LIB(cap-ng, capng_clear,
1234                  have_libaudit=yes, have_libaudit=no)
1235     fi
1236 fi
1237
1238 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1239
1240 if test x$have_libaudit = xyes ; then
1241     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1242     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1243 fi
1244
1245 AC_SUBST([SELINUX_LIBS])
1246
1247 # Check for ADT API (Solaris Basic Security Mode auditing)
1248 AC_MSG_CHECKING(for ADT API)
1249 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1250 #include <bsm/adt.h>
1251 adt_user_context = ADT_USER;
1252 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1253
1254 if test ${check_adt_audit} = yes
1255 then
1256    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1257    ADT_LIBS="-lbsm"
1258    LIBS="-lbsm $LIBS"
1259    AC_MSG_RESULT(yes)
1260 else
1261    AC_MSG_RESULT(no)
1262 fi
1263 AC_SUBST([ADT_LIBS])
1264
1265 # Check for SCM_RIGHTS
1266 AC_MSG_CHECKING([for SCM_RIGHTS])
1267 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1268 #include <sys/types.h>
1269 #include <sys/socket.h>
1270 #include <sys/un.h>
1271 static int x = SCM_RIGHTS;
1272 ]], [[]])],
1273 [ AC_MSG_RESULT([supported])
1274   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1275 [ AC_MSG_RESULT([not supported]) ])
1276
1277 NETWORK_libs=
1278 if test x$dbus_win = xyes ; then
1279   if test x$dbus_wince = xyes ; then
1280     NETWORK_libs="-lws2"
1281   else
1282     NETWORK_libs="-lws2_32"
1283   fi
1284 fi
1285
1286 AC_SUBST([NETWORK_libs])
1287
1288 AC_ARG_WITH([valgrind],
1289   [AS_HELP_STRING([--with-valgrind],
1290      [Add instrumentation to help valgrind to understand our allocator])],
1291   [],
1292   [with_valgrind=no])
1293
1294 if test x$with_valgrind != xno; then
1295   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1296   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1297 fi
1298
1299 #### Set up final flags
1300 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1301 AC_SUBST([LIBDBUS_LIBS])
1302
1303 ### X11 detection
1304 DBUS_X_LIBS=
1305 DBUS_X_CFLAGS=
1306
1307 AC_ARG_ENABLE([x11-autolaunch],
1308   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1309   [], [enable_x11_autolaunch=auto])
1310
1311 if test "x$dbus_win" = xyes; then
1312     if test "x$enable_x11_autolaunch" = xyes; then
1313         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1314     fi
1315
1316     enable_x11_autolaunch=no
1317     have_x11=no
1318 else
1319     AC_PATH_XTRA
1320
1321     if test "x$no_x" = xyes; then
1322         have_x11=no
1323     else
1324         have_x11=yes
1325         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1326         DBUS_X_CFLAGS="$X_CFLAGS"
1327     fi
1328 fi
1329
1330 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1331     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1332 else
1333     # move from "auto" to "yes" or "no" if necessary
1334     if test "x$enable_x11_autolaunch" != xno; then
1335         enable_x11_autolaunch="$have_x11"
1336     fi
1337 fi
1338
1339 if test "x$have_x11" = xyes ; then
1340    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1341 fi
1342
1343 if test "x$enable_x11_autolaunch" = xyes ; then
1344    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1345 fi
1346
1347 AC_SUBST([DBUS_X_CFLAGS])
1348 AC_SUBST([DBUS_X_LIBS])
1349
1350 #### gcc warning flags
1351
1352 cc_supports_flag() {
1353   AC_MSG_CHECKING(whether $CC supports "$*")
1354   save_CFLAGS="$CFLAGS"
1355   CFLAGS="$*"
1356   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1357   CFLAGS="$save_CFLAGS"
1358   AC_MSG_RESULT([$rc])
1359   test "x$rc" = xyes
1360 }
1361
1362 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1363   dnl Use -Werror by default if:
1364   dnl - we're not on Windows (too many warnings), and
1365   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1366   dnl Override with --enable-Werror or --disable-Werror
1367   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1368
1369   dnl Enable these warnings if possible:
1370   [all \
1371    extra \
1372    char-subscripts \
1373    missing-declarations \
1374    missing-prototypes \
1375    nested-externs \
1376    pointer-arith \
1377    cast-align \
1378    no-address \
1379    float-equal \
1380    declaration-after-statement \
1381   ],
1382
1383   dnl Disable these warnings if possible, make them non-fatal if possible,
1384   dnl and don't enable -Werror unless we succeeded.
1385   dnl
1386   dnl Intentional:
1387   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1388   dnl   checking or not asserting
1389   dnl - missing field initializers being 0 is a C feature, not a bug
1390   dnl - unused-parameter is to make writing callbacks less annoying
1391   dnl
1392   dnl To be fixed one day:
1393   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1394   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1395   dnl   is better than nothing
1396   [$DISABLE_UNUSED_WARNINGS \
1397    missing-field-initializers \
1398    unused-parameter \
1399    sign-compare \
1400    pointer-sign \
1401    type-limits \
1402   ])
1403
1404 if test "x$GCC" = "xyes"; then
1405   # We're treating -fno-common like a warning: it makes the linker more
1406   # strict, because on some systems the linker is *always* this strict
1407   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1408
1409   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1410   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1411
1412   if test "x$enable_ansi" = "xyes"; then
1413     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1414       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1415   fi
1416 fi
1417
1418 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1419 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1420 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1421 dnl is the next best thing
1422 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1423
1424 case $host_os in
1425     solaris*)
1426         # Solaris' C library apparently needs these runes to be threadsafe...
1427         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1428         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1429         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1430         # ... and this opt-in to get file descriptor passing support
1431         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1432         ;;
1433 esac
1434
1435 ### Doxygen Documentation
1436
1437 AC_PATH_PROG(DOXYGEN, doxygen, no)
1438
1439 AC_MSG_CHECKING([whether to build Doxygen documentation])
1440
1441 if test x$DOXYGEN = xno ; then
1442     have_doxygen=no
1443 else
1444     have_doxygen=yes
1445 fi
1446
1447 if test x$enable_doxygen_docs = xauto ; then
1448     if test x$have_doxygen = xno ; then
1449         enable_doxygen_docs=no
1450     else
1451         enable_doxygen_docs=yes
1452     fi
1453 fi
1454
1455 if test x$enable_doxygen_docs = xyes; then
1456     if test x$have_doxygen = xno; then
1457         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1458     fi
1459 fi
1460
1461 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1462 AC_MSG_RESULT($enable_doxygen_docs)
1463
1464 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1465 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1466
1467 ### XML Documentation
1468
1469 AC_PATH_PROG(XMLTO, xmlto, no)
1470
1471 AC_MSG_CHECKING([whether to build XML documentation])
1472
1473 if test x$XMLTO = xno ; then
1474     have_xmlto=no
1475 else
1476     have_xmlto=yes
1477 fi
1478
1479 if test x$enable_xml_docs = xauto ; then
1480     if test x$have_xmlto = xno ; then
1481         enable_xml_docs=no
1482     else
1483         enable_xml_docs=yes
1484     fi
1485 fi
1486
1487 if test x$enable_xml_docs = xyes; then
1488     if test x$have_xmlto = xno; then
1489         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1490     fi
1491 fi
1492
1493 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1494 AC_MSG_RESULT($enable_xml_docs)
1495
1496 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1497     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes])
1498
1499 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1500
1501 #### find the actual value for $prefix that we'll end up with
1502 ##   (I know this is broken and should be done in the Makefile, but
1503 ##    that's a major pain and almost nobody actually seems to care)
1504 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1505 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1506 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1507 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1508 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1509 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1510 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1511
1512 #### Check our operating system
1513 operating_system=unknown
1514 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1515    operating_system=redhat
1516 fi
1517
1518 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1519    operating_system=slackware
1520 fi
1521
1522 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1523    operating_system=cygwin
1524 fi
1525
1526 #### Sort out init scripts
1527
1528 if test x$with_init_scripts = x; then
1529     case x$operating_system in
1530         xredhat)        with_init_scripts=redhat ;;
1531         xslackware)     with_init_scripts=slackware ;;
1532         xcygwin)        with_init_scripts=cygwin ;;
1533         *)                      with_init_scripts=none ;;
1534     esac
1535 fi
1536
1537 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1538 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1539 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1540
1541 ##### systemd unit files
1542 AC_ARG_WITH([systemdsystemunitdir],
1543 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1544     [],
1545     [
1546     PKG_CHECK_EXISTS([systemd],
1547       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1548       [with_systemdsystemunitdir=no])
1549     ])
1550 if test "x$with_systemdsystemunitdir" != xno; then
1551    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1552 fi
1553 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1554
1555 ##### Set up location for system bus socket
1556 if ! test -z "$with_system_socket"; then
1557    DBUS_SYSTEM_SOCKET=$with_system_socket
1558 else
1559    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1560 fi
1561
1562 AC_SUBST(DBUS_SYSTEM_SOCKET)
1563 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1564
1565 ## System bus only listens on local domain sockets, and never
1566 ## on an abstract socket (so only root can create the socket).
1567 ##
1568 ## This won't work on Windows. It's not meant to - the system bus is
1569 ## meaningless on Windows anyway.
1570 ##
1571 ## This has to be suitable for hard-coding in client libraries as well as
1572 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1573 ## and also to connect to. If this ever changes, it'll need to be split into
1574 ## two variables, one for the listening address and one for the connecting
1575 ## address.
1576 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1577 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1578 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1579
1580 #### Set up the pid file
1581 if ! test -z "$with_system_pid_file"; then
1582    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1583 elif test x$with_init_scripts = xredhat ; then
1584    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1585 else
1586    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1587 fi
1588
1589 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1590
1591 #### Directory to check for console ownership
1592 if ! test -z "$with_console_auth_dir"; then
1593    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1594 else
1595    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1596 fi
1597
1598 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1599 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1600
1601 #### File to check for console ownership
1602 if test x$have_console_owner_file = xyes; then
1603    if ! test -z "$with_console_owner_file"; then
1604       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1605    else
1606       DBUS_CONSOLE_OWNER_FILE=/dev/console
1607    fi
1608 else
1609   DBUS_CONSOLE_OWNER_FILE=
1610 fi
1611
1612 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1613 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1614
1615 #### User to start the system bus as
1616 if test -z "$with_dbus_user" ; then
1617     DBUS_USER=messagebus
1618 else
1619     DBUS_USER=$with_dbus_user
1620 fi
1621 AC_SUBST(DBUS_USER)
1622 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1623
1624 #### Prefix to install into
1625 DBUS_PREFIX=$EXPANDED_PREFIX
1626 AC_SUBST(DBUS_PREFIX)
1627 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1628
1629 #### Direcotry to install data files into
1630 DBUS_DATADIR=$EXPANDED_DATADIR
1631 AC_SUBST(DBUS_DATADIR)
1632 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1633
1634 #### Directory to install dbus-daemon
1635 if test -z "$with_dbus_daemondir" ; then
1636     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1637 else
1638     DBUS_DAEMONDIR=$with_dbus_daemondir
1639 fi
1640 AC_SUBST(DBUS_DAEMONDIR)
1641 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1642
1643 #### Directory to install the other binaries
1644 DBUS_BINDIR="$EXPANDED_BINDIR"
1645 AC_SUBST(DBUS_BINDIR)
1646 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1647
1648 #### Directory to install the libexec binaries
1649 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1650 AC_SUBST(DBUS_LIBEXECDIR)
1651 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1652
1653 #### Tell tests where to find certain stuff in builddir
1654
1655 DBUS_PWD=`pwd`
1656 # Useful in a cross-compilation environment, where the tests are run on the host system.
1657 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1658                            DBUS_PWD=$withval)
1659
1660 DBUS_TEST_EXEC="$DBUS_PWD/test"
1661 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1662
1663 AC_SUBST([DBUS_TEST_DATA])
1664 AC_SUBST([DBUS_TEST_EXEC])
1665
1666 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1667                    [Full path to the daemon in the builddir])
1668 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1669                    [Extension for executables, typically empty or .exe])
1670
1671 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1672                    [Full path to the daemon in the builddir])
1673 AC_SUBST(TEST_BUS_BINARY)
1674
1675 ## Export the non-setuid external helper
1676 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1677 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1678 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1679                    [Full path to the launch helper test program in the builddir])
1680
1681 #### Find socket directories
1682 if ! test -z "$TMPDIR" ; then
1683    DEFAULT_SOCKET_DIR=$TMPDIR
1684 elif ! test -z "$TEMP" ; then
1685    DEFAULT_SOCKET_DIR=$TEMP
1686 elif ! test -z "$TMP" ; then
1687    DEFAULT_SOCKET_DIR=$TMP
1688 else
1689    DEFAULT_SOCKET_DIR=/tmp
1690 fi
1691
1692 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1693
1694 if ! test -z "$with_test_socket_dir" ; then
1695    TEST_SOCKET_DIR="$with_test_socket_dir"
1696 else
1697    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1698 fi
1699 AC_SUBST(TEST_SOCKET_DIR)
1700 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1701
1702 if test "x$dbus_unix" = xyes; then
1703   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1704 else
1705   TEST_LISTEN="tcp:host=localhost"
1706 fi
1707 AC_SUBST([TEST_LISTEN])
1708 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1709   [Listening address for regression tests])
1710
1711 if ! test -z "$with_session_socket_dir" ; then
1712    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1713 else
1714    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1715 fi
1716 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1717 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1718
1719 # This must be a listening address. It doesn't necessarily need to be an
1720 # address you can connect to - it can be something vague like
1721 # "nonce-tcp:".
1722 #
1723 # The default varies by platform.
1724 AC_ARG_WITH([dbus_session_bus_listen_address],
1725             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1726                            [default address for a session bus to listen on (see configure.ac)]),
1727             [with_dbus_session_bus_listen_address=$withval],
1728             [with_dbus_session_bus_listen_address=])
1729
1730 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1731         # the user specified something, trust them
1732         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1733 elif test x$dbus_win = xyes; then
1734         # On Windows, you can (and should) listen on autolaunch addresses,
1735         # because autolaunching is different.
1736         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1737         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1738 elif test x$have_launchd = xyes; then
1739         # Mac OS X default is to use launchd
1740         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1741 else
1742         # The default on all other Unix platforms (notably Linux)
1743         # is to create a randomly named socket in /tmp or similar
1744         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1745 fi
1746 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1747
1748 # This must be an address you can connect to. It doesn't necessarily
1749 # need to be an address you can listen on - it can be "autolaunch:",
1750 # even on Unix.
1751 #
1752 # The default varies by platform.
1753 AC_ARG_WITH([dbus_session_bus_connect_address],
1754             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1755                            [fallback address for a session bus client to connect to (see configure.ac)]),
1756             [with_dbus_session_bus_connect_address=$withval],
1757             [with_dbus_session_bus_connect_address=])
1758
1759 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1760         # the user specified something, trust them
1761         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1762 elif test x$dbus_win = xyes; then
1763         # Windows autolaunching is a bit different; leaving it in its own
1764         # branch of the conditional because the default might conceivably
1765         # change (see #38201)
1766         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1767 else
1768         # The default on all other Unix platforms (notably Linux)
1769         # is to use auto-launching - this works a bit differently on Mac OS X
1770         # but comes out basically the same in the end
1771         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1772 fi
1773 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1774 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1775   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1776   [Fallback address for session bus clients])
1777
1778 # darwin needs this to initialize the environment
1779 AC_CHECK_HEADERS(crt_externs.h)
1780 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1781 AH_VERBATIM(_DARWIN_ENVIRON,
1782 [
1783 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1784 # include <sys/time.h>
1785 # include <crt_externs.h>
1786 # define environ (*_NSGetEnviron())
1787 #endif
1788 ])
1789
1790 AC_ARG_ENABLE([stats],
1791   [AS_HELP_STRING([--enable-stats],
1792     [enable bus daemon usage statistics])],
1793   [], [enable_stats=no])
1794 if test "x$enable_stats" = xyes; then
1795   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1796     [Define to enable bus daemon usage statistics])
1797 fi
1798
1799 AC_CONFIG_FILES([
1800 Doxyfile
1801 dbus/versioninfo.rc
1802 dbus/dbus-arch-deps.h
1803 bus/system.conf
1804 bus/session.conf
1805 bus/messagebus
1806 bus/messagebus-config
1807 bus/org.freedesktop.dbus-session.plist
1808 bus/rc.messagebus
1809 bus/dbus.service
1810 bus/dbus.socket
1811 Makefile
1812 dbus/Makefile
1813 bus/Makefile
1814 tools/Makefile
1815 test/Makefile
1816 test/name-test/Makefile
1817 doc/Makefile
1818 doc/dbus-cleanup-sockets.1.xml
1819 doc/dbus-daemon.1.xml
1820 doc/dbus-launch.1.xml
1821 doc/dbus-monitor.1.xml
1822 doc/dbus-send.1.xml
1823 doc/dbus-uuidgen.1.xml
1824 dbus-1.pc
1825 dbus-1-uninstalled.pc
1826 test/data/valid-config-files/debug-allow-all.conf
1827 test/data/valid-config-files/debug-allow-all-sha1.conf
1828 test/data/valid-config-files-system/debug-allow-all-pass.conf
1829 test/data/valid-config-files-system/debug-allow-all-fail.conf
1830 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1831 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1832 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1833 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1834 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1835 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1836 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1837 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1838 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1839 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1840 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1841 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1842 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1843 ])
1844 AC_OUTPUT
1845
1846 dnl ==========================================================================
1847 echo "
1848                     D-Bus $VERSION
1849                   ==============
1850
1851         prefix:                   ${EXPANDED_PREFIX}
1852         exec_prefix:              ${exec_prefix}
1853         libdir:                   ${EXPANDED_LIBDIR}
1854         libexecdir:               ${EXPANDED_LIBEXECDIR}
1855         bindir:                   ${EXPANDED_BINDIR}
1856         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1857         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1858         datadir:                  ${EXPANDED_DATADIR}
1859         source code location:     ${srcdir}
1860         compiler:                 ${CC}
1861         cflags:                   ${CFLAGS}
1862         cppflags:                 ${CPPFLAGS}
1863         cxxflags:                 ${CXXFLAGS}
1864         64-bit int:               ${DBUS_INT64_TYPE}
1865         32-bit int:               ${DBUS_INT32_TYPE}
1866         16-bit int:               ${DBUS_INT16_TYPE}
1867         Doxygen:                  ${DOXYGEN:-not found}
1868         xmlto:                    ${XMLTO:-not found}"
1869
1870 echo "
1871         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1872         gcc coverage profiling:   ${enable_compiler_coverage}
1873         Building embedded tests:  ${enable_embedded_tests}
1874         Building modular tests:   ${enable_modular_tests}
1875             - with GLib:          ${with_glib}
1876         Building verbose mode:    ${enable_verbose_mode}
1877         Building assertions:      ${enable_asserts}
1878         Building checks:          ${enable_checks}
1879         Building bus stats API:   ${enable_stats}
1880         Building SELinux support: ${have_selinux}
1881         Building inotify support: ${have_inotify}
1882         Building dnotify support: ${have_dnotify}
1883         Building kqueue support:  ${have_kqueue}
1884         Building systemd support: ${have_systemd}
1885         Building X11 code:        ${enable_x11}
1886         Building Doxygen docs:    ${enable_doxygen_docs}
1887         Building XML docs:        ${enable_xml_docs}
1888         Building cache support:   ${enable_userdb_cache}
1889         Building launchd support: ${have_launchd}
1890         Using XML parser:         ${with_xml}
1891         Init scripts style:       ${with_init_scripts}
1892         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1893         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1894         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1895         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1896         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1897         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1898         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1899         Console owner file:       ${have_console_owner_file}
1900         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1901         System bus user:          ${DBUS_USER}
1902         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1903         'make check' socket dir:  ${TEST_SOCKET_DIR}
1904 "
1905 if test x$have_launchd = xyes; then
1906         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1907 fi
1908 echo
1909
1910 if test x$enable_embedded_tests = xyes; then
1911         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1912 fi
1913 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1914         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1915 fi
1916 if test x$enable_compiler_coverage = xyes; then
1917         echo "NOTE: building with coverage profiling is definitely for developers only."
1918 fi
1919 if test x$enable_verbose_mode = xyes; then
1920         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1921 fi
1922 if test x$enable_asserts = xyes; then
1923         echo "NOTE: building with assertions increases library size and decreases performance."
1924 fi
1925 if test x$enable_checks = xno; then
1926         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1927 fi
1928 if test x$dbus_use_libxml = xtrue; then
1929         echo
1930         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1931 fi
1932
1933 if test "x$DBUS_HAVE_INT64" = x0; then
1934   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1935
1936   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1937   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1938   used if your compiler lacks support for 64-bit integers. Please report a bug
1939   with details of your platform and compiler.
1940
1941   This option is likely to be removed in future, unless the D-Bus developers
1942   receive reports that it is still needed.
1943   ])
1944 fi