configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [7])
   6 m4_define([dbus_micro_version], [5])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=11
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=8
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 154 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 155 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 156 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 157 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 158 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 159
 160 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 161 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 162 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 163 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 164 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 165 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 166 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 167 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 168 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 169 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 170
 171 AC_ARG_ENABLE([embedded-tests],
 172   AS_HELP_STRING([--enable-embedded-tests],
 173     [enable unit test code in the library and binaries]),
 174   [], [enable_embedded_tests=$enable_developer])
 175 AC_ARG_ENABLE([modular-tests],
 176   AS_HELP_STRING([--enable-modular-tests],
 177     [enable modular regression tests (requires GLib)]),
 178   [], [enable_modular_tests=auto])
 179 # --enable-tests overrides both --enable-embedded-tests and
 180 # --enable-modular-tests
 181 AC_ARG_ENABLE([tests],
 182   AS_HELP_STRING([--enable-tests],
 183     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 184   [
 185   if test "x$enableval" = xyes; then
 186     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 187     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 188   fi
 189   enable_embedded_tests=$enableval
 190   enable_modular_tests=$enableval
 191   ],
 192   [])
 193
 194 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 195 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 196 # name for this.
 197 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 198 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 199   [test "x$enable_embedded_tests" = xyes])
 200 if test "x$enable_embedded_tests" = xyes; then
 201     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 202       [Define to build test code into the library and binaries])
 203     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 204       [Define to build test code into the library and binaries])
 205 fi
 206
 207 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 208 # These use GTest, from GLib, because life's too short. They're enabled by
 209 # default (unless you don't have GLib), because they don't bloat the library
 210 # or binaries.
 211
 212 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_26], [Ignore post-2.26 deprecations])
 213 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_32], [Prevent post-2.32 APIs])
 214
 215 with_glib=yes
 216
 217 if test "x$enable_modular_tests" != xno; then
 218   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 219     [],
 220     [if test "x$enable_modular_tests" = xyes; then
 221       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 222       AC_MSG_ERROR([$GLIB_ERRORS])
 223     else # assumed to be "auto"
 224       with_glib=no
 225     fi])
 226   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 227   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 228     [],
 229     [if test "x$enable_modular_tests" = xyes; then
 230       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 231       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 232     else # assumed to be "auto"
 233       with_glib=no
 234     fi])
 235 fi
 236 if test "x$enable_modular_tests" != xno; then
 237   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 238     [Define to build independent test binaries])
 239 fi
 240 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 241   [test "x$enable_modular_tests" != xno])
 242
 243 if test "x$with_glib" != xno; then
 244   AC_DEFINE([DBUS_WITH_GLIB], [1],
 245     [Define if GLib, GObject, GIO are available])
 246 fi
 247 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 248
 249 AC_ARG_ENABLE([installed-tests],
 250   AS_HELP_STRING([--enable-installed-tests],
 251     [enable unit test code in the library and binaries]),
 252   [], [enable_installed_tests=no])
 253 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 254   [test "x$enable_installed_tests" = xyes])
 255
 256 if test "x$enable_tests" = xyes; then
 257   # full test coverage is required, Python is a hard dependency
 258   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 259   AM_PATH_PYTHON([2.6])
 260   AC_MSG_CHECKING([for Python modules for full test coverage])
 261   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 262     AC_MSG_RESULT([yes])
 263   else
 264     AC_MSG_RESULT([no])
 265     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 266   fi
 267 else
 268   # --enable-tests not given: do not abort if Python is missing
 269   AM_PATH_PYTHON([2.6], [], [:])
 270 fi
 271
 272 if test x$enable_verbose_mode = xyes; then
 273     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 274 fi
 275
 276 if test x$enable_asserts = xno; then
 277     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 278     DISABLE_UNUSED_WARNINGS="unused-label"
 279     R_DYNAMIC_LDFLAG=""
 280 else
 281     # -rdynamic is needed for glibc's backtrace_symbols to work.
 282     # No clue how much overhead this adds, but it's useful
 283     # to do this on any assertion failure,
 284     # so for now it's enabled anytime asserts are (currently not
 285     # in production builds).
 286
 287     # To get -rdynamic you pass -export-dynamic to libtool.
 288     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 289     R_DYNAMIC_LDFLAG=-export-dynamic
 290 fi
 291 AC_SUBST(R_DYNAMIC_LDFLAG)
 292
 293 if test x$enable_checks = xno; then
 294     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 295     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 296     DISABLE_UNUSED_WARNINGS="unused-label"
 297 fi
 298
 299 AH_BOTTOM([
 300 /* explicitly define these macros to get less confusing conditions */
 301 #ifndef DBUS_DISABLE_ASSERT
 302 #  define DBUS_ENABLE_ASSERT 1
 303 #endif
 304 #ifndef DBUS_DISABLE_CHECKS
 305 #  define DBUS_ENABLE_CHECKS 1
 306 #endif])
 307
 308 if test x$enable_userdb_cache = xyes; then
 309     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 310 fi
 311
 312 if test x$enable_compiler_coverage = xyes; then
 313      ## so that config.h changes when you toggle gcov support
 314      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 315 fi
 316
 317 # glibc21.m4 serial 3
 318 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 319 dnl This file is free software; the Free Software Foundation
 320 dnl gives unlimited permission to copy and/or distribute it,
 321 dnl with or without modifications, as long as this notice is preserved.
 322
 323 # Test for the GNU C Library, version 2.1 or newer.
 324 # From Bruno Haible.
 325
 326 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 327   ac_cv_gnu_library_2_1,
 328   [AC_EGREP_CPP([Lucky GNU user],
 329     [
 330 #include <features.h>
 331 #ifdef __GNU_LIBRARY__
 332  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 333   Lucky GNU user
 334  #endif
 335 #endif
 336     ],
 337     ac_cv_gnu_library_2_1=yes,
 338     ac_cv_gnu_library_2_1=no)
 339   ]
 340 )
 341
 342 #### Integer sizes
 343
 344 AC_CHECK_SIZEOF(char)
 345 AC_CHECK_SIZEOF(short)
 346 AC_CHECK_SIZEOF(long)
 347 AC_CHECK_SIZEOF(int)
 348 AC_CHECK_SIZEOF(void *)
 349 AC_CHECK_SIZEOF(long long)
 350 AC_CHECK_SIZEOF(__int64)
 351
 352 AC_ARG_WITH([64-bit],
 353   [AS_HELP_STRING([--without-64-bit],
 354     [If you have to use this option, please report it as a bug])],
 355   [],
 356   [with_64_bit=yes])
 357
 358 ### See what our 64 bit type is called
 359 AC_MSG_CHECKING([64-bit integer type])
 360
 361 case 8 in
 362 $ac_cv_sizeof_int)
 363   dbusint64=int
 364   dbusint64_constant='(val)'
 365   dbusuint64_constant='(val)'
 366   dbusint64_printf_modifier='""'
 367   ;;
 368 $ac_cv_sizeof_long)
 369   dbusint64=long
 370   dbusint64_constant='(val##L)'
 371   dbusuint64_constant='(val##UL)'
 372   dbusint64_printf_modifier='"l"'
 373   ;;
 374 $ac_cv_sizeof_long_long)
 375   dbusint64='long long'
 376   dbusint64_constant='(val##LL)'
 377   dbusuint64_constant='(val##ULL)'
 378   # Ideally we discover what the format is, but this is
 379   # only used in verbose mode, so eh...
 380   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 381     dbusint64_printf_modifier='"ll"'
 382   fi
 383   ;;
 384 $ac_cv_sizeof___int64)
 385   dbusint64=__int64
 386   dbusint64_constant='(val##i64)'
 387   dbusuint64_constant='(val##ui64)'
 388   # See above case
 389   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 390     dbusint64_printf_modifier='"ll"'
 391   fi
 392   ;;
 393 esac
 394
 395 AS_IF(
 396   [test "x$with_64_bit" = xno],
 397   [
 398         DBUS_INT64_TYPE="no_int64_type_detected"
 399         DBUS_HAVE_INT64=0
 400         DBUS_INT64_CONSTANT=
 401         DBUS_UINT64_CONSTANT=
 402         AC_MSG_RESULT([disabled via --without-64-bit])
 403   ],
 404   dnl else if
 405   [test -z "$dbusint64"],
 406   [AC_MSG_RESULT([not found])
 407   AC_MSG_ERROR([Could not find a 64-bit integer type.
 408
 409 Please report a bug here with details of your platform and compiler:
 410
 411     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 412
 413 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 414 the option "--without-64-bit".
 415
 416 This option is likely to be removed in future, unless you report that your
 417 platform needs it.])
 418   ],
 419   dnl else
 420   [
 421         DBUS_INT64_TYPE="$dbusint64"
 422         DBUS_HAVE_INT64=1
 423         DBUS_INT64_CONSTANT="$dbusint64_constant"
 424         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 425         if test x"$dbusint64_printf_modifier" != x; then
 426                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 427         fi
 428         AC_MSG_RESULT($DBUS_INT64_TYPE)
 429   ])
 430
 431 AC_SUBST(DBUS_INT64_TYPE)
 432 AC_SUBST(DBUS_INT64_CONSTANT)
 433 AC_SUBST(DBUS_UINT64_CONSTANT)
 434 AC_SUBST(DBUS_HAVE_INT64)
 435
 436 ### see what 32-bit int is called
 437 AC_MSG_CHECKING([32-bit integer type])
 438
 439 case 4 in
 440 $ac_cv_sizeof_short)
 441   dbusint32=short
 442   ;;
 443 $ac_cv_sizeof_int)
 444   dbusint32=int
 445   ;;
 446 $ac_cv_sizeof_long)
 447   dbusint32=long
 448   ;;
 449 esac
 450
 451 if test -z "$dbusint32" ; then
 452         DBUS_INT32_TYPE="no_int32_type_detected"
 453         AC_MSG_ERROR([No 32-bit integer type found])
 454 else
 455         DBUS_INT32_TYPE="$dbusint32"
 456         AC_MSG_RESULT($DBUS_INT32_TYPE)
 457 fi
 458
 459 AC_SUBST(DBUS_INT32_TYPE)
 460
 461 ### see what 16-bit int is called
 462 AC_MSG_CHECKING([16-bit integer type])
 463
 464 case 2 in
 465 $ac_cv_sizeof_short)
 466   dbusint16=short
 467   ;;
 468 $ac_cv_sizeof_int)
 469   dbusint16=int
 470   ;;
 471 esac
 472
 473 if test -z "$dbusint16" ; then
 474         DBUS_INT16_TYPE="no_int16_type_detected"
 475         AC_MSG_ERROR([No 16-bit integer type found])
 476 else
 477         DBUS_INT16_TYPE="$dbusint16"
 478         AC_MSG_RESULT($DBUS_INT16_TYPE)
 479 fi
 480
 481 AC_SUBST(DBUS_INT16_TYPE)
 482
 483 ## byte order
 484 case $host_os in
 485         darwin*)
 486                 # check at compile-time, so that it is possible to build universal
 487                 # (with multiple architectures at once on the compile line)
 488                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 489                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 490                         #if defined(__BIG_ENDIAN__)
 491                         #define WORDS_BIGENDIAN 1
 492                         #endif
 493                 ])
 494                 ;;
 495         *)
 496                 AC_C_BIGENDIAN
 497                 ;;
 498 esac
 499
 500 dnl **********************************
 501 dnl *** va_copy checks (from GLib) ***
 502 dnl **********************************
 503 dnl we currently check for all three va_copy possibilities, so we get
 504 dnl all results in config.log for bug reports.
 505 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 506         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 507 #include <stdlib.h>
 508         static void f (int i, ...) {
 509         va_list args1, args2;
 510         va_start (args1, i);
 511         va_copy (args2, args1);
 512         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 513           exit (1);
 514         va_end (args1); va_end (args2);
 515         }
 516         int main() {
 517           f (0, 42);
 518           return 0;
 519         }])],
 520         [dbus_cv_va_copy=yes],
 521         [dbus_cv_va_copy=no])
 522 ])
 523 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 524         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 525 #include <stdlib.h>
 526         static void f (int i, ...) {
 527         va_list args1, args2;
 528         va_start (args1, i);
 529         __va_copy (args2, args1);
 530         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 531           exit (1);
 532         va_end (args1); va_end (args2);
 533         }
 534         int main() {
 535           f (0, 42);
 536           return 0;
 537         }])],
 538         [dbus_cv___va_copy=yes],
 539         [dbus_cv___va_copy=no])
 540 ])
 541
 542 if test "x$dbus_cv_va_copy" = "xyes"; then
 543   dbus_va_copy_func=va_copy
 544 else if test "x$dbus_cv___va_copy" = "xyes"; then
 545   dbus_va_copy_func=__va_copy
 546 fi
 547 fi
 548
 549 if test -n "$dbus_va_copy_func"; then
 550   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 551 fi
 552
 553 AC_LANG_PUSH(C)
 554 AC_CACHE_CHECK([whether va_lists can be copied by value],
 555         dbus_cv_va_val_copy,
 556         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 557 [[
 558         #include <stdarg.h>
 559         #include <stdlib.h>
 560 ]],
 561 [[
 562         static void f (int i, ...) {
 563         va_list args1, args2;
 564         va_start (args1, i);
 565         args2 = args1;
 566         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 567           exit (1);
 568         va_end (args1); va_end (args2);
 569         }
 570         int main() {
 571           f (0, 42);
 572           return 0;
 573         }
 574 ]])],
 575         [dbus_cv_va_val_copy=yes],
 576         [dbus_cv_va_val_copy=no],
 577         [dbus_cv_va_val_copy=yes])
 578 ])
 579 AC_LANG_POP(C)
 580
 581 if test "x$dbus_cv_va_val_copy" = "xno"; then
 582   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 583 fi
 584
 585
 586 #### Atomic integers
 587
 588 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 589   dbus_cv_sync_sub_and_fetch,
 590   [AC_LINK_IFELSE([
 591      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 592      [dbus_cv_sync_sub_and_fetch=yes],
 593      [dbus_cv_sync_sub_and_fetch=no])
 594   ])
 595
 596 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 597    have_sync=1
 598 else
 599    have_sync=0
 600 fi
 601
 602 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 603
 604 #### Various functions
 605 AC_SEARCH_LIBS(socket,[socket network])
 606 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 607
 608 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
 609
 610 AC_CHECK_HEADERS([syslog.h])
 611 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 612   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 613 fi
 614
 615 #### Check for broken poll; taken from Glib's configure
 616
 617 AC_MSG_CHECKING([for broken poll])
 618 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 619     #include <stdlib.h>
 620     #include <fcntl.h>
 621     #include <poll.h>
 622     #ifdef HAVE_SYS_POLL_H
 623     #include <sys/poll.h>
 624     #endif
 625     int main(void) {
 626       struct pollfd fds[1];
 627       int fd;
 628       fd = open("/dev/null", 1);
 629       fds[0].fd = fd;
 630       fds[0].events = POLLIN;
 631       fds[0].revents = 0;
 632       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 633             exit(1);  /* Does not work for devices -- fail */
 634       }
 635       exit(0);
 636     }]])],
 637   [broken_poll=no],
 638   [broken_poll=yes
 639    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 640   [broken_poll="no (cross compiling)"])
 641 AC_MSG_RESULT($broken_poll)
 642
 643 AC_MSG_CHECKING(for dirfd)
 644 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 645 #include <sys/types.h>
 646 #include <dirent.h>
 647 ]], [[
 648 DIR *dirp;
 649 dirp = opendir(".");
 650 dirfd(dirp);
 651 closedir(dirp);
 652 ]])],
 653 [dbus_have_dirfd=yes],
 654 [dbus_have_dirfd=no])
 655 AC_MSG_RESULT($dbus_have_dirfd)
 656 if test "$dbus_have_dirfd" = yes; then
 657         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 658 else
 659         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 660         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 661 #include <sys/types.h>
 662 #include <dirent.h>
 663         ]], [[
 664 DIR *dirp;
 665 int fd;
 666 dirp = opendir(".");
 667 fd = dirp->dd_fd;
 668 closedir(dirp);
 669         ]])],
 670         [dbus_have_ddfd=yes],
 671         [dbus_have_ddfd=no])
 672         AC_MSG_RESULT($dbus_have_ddfd)
 673         if test "$dbus_have_ddfd" = yes; then
 674                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 675         fi
 676 fi
 677
 678 AC_CHECK_HEADERS(sys/resource.h)
 679
 680 AC_CHECK_HEADERS(dirent.h)
 681
 682 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 683
 684 AC_CHECK_HEADERS(errno.h)
 685
 686 AC_CHECK_HEADERS(signal.h)
 687
 688 AC_CHECK_HEADERS(locale.h)
 689
 690 AC_CHECK_HEADERS(byteswap.h)
 691
 692 AC_CHECK_HEADERS(unistd.h)
 693
 694 AC_CHECK_HEADERS(ws2tcpip.h)
 695
 696 AC_CHECK_HEADERS(wspiapi.h)
 697
 698 AC_CHECK_HEADERS(alloca.h)
 699
 700 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 701 #
 702 case $host_os in
 703     solaris*)
 704        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 705 esac
 706
 707 # checking for a posix version of getpwnam_r
 708 # if we are cross compiling and can not run the test
 709 # assume getpwnam_r is the posix version
 710 # it is up to the person cross compiling to change
 711 # this behavior if desired
 712 AC_LANG_PUSH(C)
 713 AC_CACHE_CHECK([for posix getpwnam_r],
 714                 ac_cv_func_posix_getpwnam_r,
 715                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 716 [[
 717 #include <errno.h>
 718 #include <pwd.h>
 719 ]],
 720 [[
 721     char buffer[10000];
 722     struct passwd pwd, *pwptr = &pwd;
 723     int error;
 724     errno = 0;
 725     error = getpwnam_r ("", &pwd, buffer,
 726                         sizeof (buffer), &pwptr);
 727    return (error < 0 && errno == ENOSYS)
 728            || error == ENOSYS;
 729 ]])],
 730         [ac_cv_func_posix_getpwnam_r=yes],
 731         [ac_cv_func_posix_getpwnam_r=no],
 732         [ac_cv_func_posix_getpwnam_r=yes]
 733 )])
 734 AC_LANG_POP(C)
 735
 736 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 737         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 738                 [Have POSIX function getpwnam_r])
 739 else
 740         AC_CACHE_CHECK([for nonposix getpwnam_r],
 741                 ac_cv_func_nonposix_getpwnam_r,
 742                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 743                         struct passwd pwd;
 744                         getpwnam_r ("", &pwd, buffer,
 745                                         sizeof (buffer));]])],
 746                         [ac_cv_func_nonposix_getpwnam_r=yes],
 747                         [ac_cv_func_nonposix_getpwnam_r=no])])
 748                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 749                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 750                         [Have non-POSIX function getpwnam_r])
 751         fi
 752 fi
 753
 754 dnl check for socklen_t
 755 AC_MSG_CHECKING(whether socklen_t is defined)
 756 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 757 #include <sys/types.h>
 758 #include <sys/socket.h>
 759 #include <netdb.h>
 760 ]], [[
 761 socklen_t foo;
 762 foo = 1;
 763 ]])],
 764 [dbus_have_socklen_t=yes],
 765 [dbus_have_socklen_t=no])
 766 AC_MSG_RESULT($dbus_have_socklen_t)
 767
 768 if test "x$dbus_have_socklen_t" = "xyes"; then
 769     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 770 fi
 771
 772 dnl check for writev header and writev function so we're
 773 dnl good to go if HAVE_WRITEV gets defined.
 774 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 775
 776 dnl needed on darwin for NAME_MAX
 777 AC_CHECK_HEADERS(sys/syslimits.h)
 778
 779 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 780 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 781 #include <sys/socket.h> ]])
 782
 783 dnl check for flavours of varargs macros (test from GLib)
 784 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 785 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 786 int a(int p1, int p2, int p3);
 787 #define call_a(...) a(1,__VA_ARGS__)
 788 call_a(2,3);
 789 ]])],
 790 [dbus_have_iso_c_varargs=yes],
 791 [dbus_have_iso_c_varargs=no])
 792 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 793
 794 AC_MSG_CHECKING(for GNUC varargs macros)
 795 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 796 int a(int p1, int p2, int p3);
 797 #define call_a(params...) a(1,params)
 798 call_a(2,3);
 799 ]])],
 800 [dbus_have_gnuc_varargs=yes],
 801 [dbus_have_gnuc_varargs=no])
 802 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 803
 804 dnl Output varargs tests
 805 if test x$dbus_have_iso_c_varargs = xyes; then
 806     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 807 fi
 808 if test x$dbus_have_gnuc_varargs = xyes; then
 809     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 810 fi
 811
 812 dnl Check for various credentials.
 813 AC_MSG_CHECKING(for struct cmsgcred)
 814 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 815 #include <sys/types.h>
 816 #include <sys/socket.h>
 817 ]], [[
 818 struct cmsgcred cred;
 819
 820 cred.cmcred_pid = 0;
 821 ]])],
 822 [dbus_have_struct_cmsgcred=yes],
 823 [dbus_have_struct_cmsgcred=no])
 824 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 825
 826 if test x$dbus_have_struct_cmsgcred = xyes; then
 827     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 828 fi
 829
 830 AC_CHECK_FUNCS(getpeerucred getpeereid)
 831
 832 AC_CHECK_FUNCS(pipe2 accept4)
 833
 834 #### Abstract sockets
 835
 836 if test x$enable_abstract_sockets = xauto; then
 837 AC_LANG_PUSH(C)
 838 warn_on_xcompile=no
 839 AC_CACHE_CHECK([abstract socket namespace],
 840                 ac_cv_have_abstract_sockets,
 841                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 842 [[
 843 #include <sys/types.h>
 844 #include <stdlib.h>
 845 #include <string.h>
 846 #include <stdio.h>
 847 #include <sys/socket.h>
 848 #include <sys/un.h>
 849 #include <errno.h>
 850 ]],
 851 [[
 852   size_t slen;
 853   int listen_fd;
 854   struct sockaddr_un addr;
 855
 856   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 857
 858   if (listen_fd < 0)
 859     {
 860       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 861       exit (1);
 862     }
 863
 864   memset (&addr, '\0', sizeof (addr));
 865   addr.sun_family = AF_UNIX;
 866   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 867   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 868    * beginning.
 869    */
 870   slen = SUN_LEN(&addr);
 871   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 872
 873   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 874     {
 875        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 876                 strerror (errno));
 877        exit (1);
 878     }
 879   else
 880     exit (0);
 881 ]])],
 882               [ac_cv_have_abstract_sockets=yes],
 883               [ac_cv_have_abstract_sockets=no],
 884               [
 885                 ac_cv_have_abstract_sockets=no
 886                 warn_on_xcompile=yes
 887               ]
 888 )])
 889 if test x$warn_on_xcompile = xyes ; then
 890   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 891 fi
 892 AC_LANG_POP(C)
 893 fi
 894
 895 if test x$enable_abstract_sockets = xyes; then
 896     if test x$ac_cv_have_abstract_sockets = xno; then
 897         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 898     fi
 899 fi
 900
 901 if test x$enable_abstract_sockets = xno; then
 902    ac_cv_have_abstract_sockets=no;
 903 fi
 904
 905 if test x$ac_cv_have_abstract_sockets = xyes ; then
 906    DBUS_PATH_OR_ABSTRACT=abstract
 907    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 908 else
 909    DBUS_PATH_OR_ABSTRACT=path
 910 fi
 911
 912 # this is used in addresses to prefer abstract, e.g.
 913 # unix:path=/foo or unix:abstract=/foo
 914 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 915
 916 PKG_PROG_PKG_CONFIG
 917
 918 #### Sort out XML library
 919
 920 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 921              [ AC_CHECK_HEADERS(expat.h, [],
 922                                 [AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])]) ],
 923              [ AC_MSG_ERROR([Explicitly requested expat but expat not found]) ])
 924
 925 XML_LIBS=-lexpat
 926 XML_CFLAGS=
 927 AC_SUBST([XML_CFLAGS])
 928 AC_SUBST([XML_LIBS])
 929
 930 # Thread lib detection
 931 AC_ARG_VAR([THREAD_LIBS])
 932 save_libs="$LIBS"
 933 LIBS="$LIBS $THREAD_LIBS"
 934
 935 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 936
 937 # Don't do these automatic checks if the user set THREAD_LIBS on the
 938 # configure command-line. If they did, we assume they're right.
 939 #
 940 # We also don't do these checks on Windows, because you don't need magical
 941 # linker flags to have threading support there.
 942 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 943   [
 944     # Mandatory pthread functions. In principle, some of these could be made
 945     # optional if there are platforms that don't have them.
 946     #
 947     # Currently, we only look in -lpthread.
 948     # In principle we might need to look in -lpthreads, -lthreads, ...
 949     # as well - please file a bug if your platform needs this.
 950     AC_SEARCH_LIBS([pthread_cond_timedwait],
 951         [pthread],
 952         [THREAD_LIBS="$LIBS"],
 953         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 954         [])
 955     AC_SEARCH_LIBS([pthread_mutexattr_init],
 956         [pthread],
 957         [THREAD_LIBS="$LIBS"],
 958         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 959         [])
 960     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 961         [pthread],
 962         [THREAD_LIBS="$LIBS"],
 963         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 964         [])
 965
 966     # Optional, for monotonic clocks. Because it's optional, this check
 967     # is non-fatal if we don't find it.
 968     AC_SEARCH_LIBS([pthread_condattr_setclock],
 969         [pthread],
 970         [THREAD_LIBS="$LIBS"])
 971
 972     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 973       [
 974         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 975         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 976         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 977 [[#include <time.h>
 978 #include <pthread.h>
 979 ]], [[
 980 struct timespec monotonic_timer;
 981 pthread_condattr_t attr;
 982 pthread_condattr_init (&attr);
 983 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 984 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 985 ]])],
 986             [have_clock_monotonic=true],
 987             [have_clock_monotonic=false])
 988         AS_IF([test x$have_clock_monotonic = xtrue],
 989           [
 990             AC_MSG_RESULT([found])
 991             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 992           ],
 993           [AC_MSG_RESULT([not found])])
 994       ]) dnl have pthread_condattr_setclock
 995   ]) dnl on Unix
 996
 997 LIBS="$save_libs"
 998
 999 AC_SUBST([THREAD_LIBS])
1000
1001 # SELinux detection
1002 if test x$enable_selinux = xno ; then
1003     have_selinux=no;
1004 else
1005     # See if we have SELinux library
1006     AC_CHECK_LIB(selinux, is_selinux_enabled,
1007                  have_selinux=yes, have_selinux=no)
1008
1009     # see if we have the SELinux header with the new D-Bus stuff in it
1010     if test x$have_selinux = xyes ; then
1011         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1012         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1013                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1014                             #else
1015                             #error DBUS__ACQUIRE_SVC not defined
1016                             #endif]])],
1017                           [have_selinux=yes],
1018                           [have_selinux=no])
1019         AC_MSG_RESULT($have_selinux)
1020     fi
1021
1022     if test x$enable_selinux = xauto ; then
1023         if test x$have_selinux = xno ; then
1024                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1025         fi
1026     else
1027         if test x$have_selinux = xno ; then
1028                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1029         fi
1030     fi
1031 fi
1032
1033 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1034
1035 if test x$have_selinux = xyes ; then
1036     # the selinux code creates threads
1037     # which requires libpthread even on linux
1038     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1039                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1040
1041     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1042     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1043 else
1044     SELINUX_LIBS=
1045 fi
1046
1047 # inotify checks
1048 if test x$enable_inotify = xno ; then
1049     have_inotify=no;
1050 else
1051     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1052 fi
1053
1054 dnl check if inotify backend is enabled
1055 if test x$have_inotify = xyes; then
1056    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1057    AC_CHECK_FUNCS(inotify_init1)
1058 fi
1059
1060 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1061
1062 # For simplicity, we require the userland API for epoll_create1 at
1063 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1064 # not to have it at runtime.
1065 AC_ARG_ENABLE([epoll],
1066               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1067               [enable_epoll=$enableval], [enable_epoll=auto])
1068 if test x$enable_epoll = xno; then
1069     have_linux_epoll=no
1070 else
1071     AC_MSG_CHECKING([for Linux epoll(4)])
1072     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1073         [
1074         #ifndef __linux__
1075         #error This is not Linux
1076         #endif
1077         #include <sys/epoll.h>
1078         ],
1079         [epoll_create1 (EPOLL_CLOEXEC);])],
1080         [have_linux_epoll=yes],
1081         [have_linux_epoll=no])
1082     AC_MSG_RESULT([$have_linux_epoll])
1083 fi
1084 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1085     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1086 fi
1087 if test x$have_linux_epoll = xyes; then
1088   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1089 fi
1090 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1091
1092 # kqueue checks
1093 if test x$enable_kqueue = xno ; then
1094     have_kqueue=no
1095 else
1096     have_kqueue=yes
1097     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1098     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1099
1100     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1101         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1102     fi
1103 fi
1104
1105 dnl check if kqueue backend is enabled
1106 if test x$have_kqueue = xyes; then
1107    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1108 fi
1109
1110 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1111
1112 # launchd checks
1113 if test x$enable_launchd = xno ; then
1114     have_launchd=no
1115 else
1116     have_launchd=yes
1117     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1118     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1119     if test "x$LAUNCHCTL" = "x"; then
1120         have_launchd=no
1121     fi
1122
1123     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1124         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1125     fi
1126 fi
1127
1128 dnl check if launchd is enabled
1129 if test x$have_launchd = xyes; then
1130     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1131 fi
1132
1133 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1134
1135 #### Directory to place launchd agent file
1136 if test "x$with_launchd_agent_dir" = "x"; then
1137    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1138 else
1139    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1140 fi
1141
1142 AC_SUBST(LAUNCHD_AGENT_DIR)
1143
1144 dnl console owner file
1145 if test x$enable_console_owner_file = xno ; then
1146     have_console_owner_file=no;
1147 else
1148     case $host_os in
1149     solaris*)
1150         have_console_owner_file=yes;
1151         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1152         ;;
1153     *)
1154         have_console_owner_file=no;;
1155     esac
1156 fi
1157
1158 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1159
1160 dnl systemd detection
1161 if test x$enable_systemd = xno ; then
1162     have_systemd=no;
1163 else
1164     PKG_CHECK_MODULES(SYSTEMD,
1165         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1166         have_systemd=yes,
1167         have_systemd=no)
1168 fi
1169
1170 if test x$have_systemd = xyes; then
1171     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1172 fi
1173
1174 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1175     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1176 fi
1177
1178 # libaudit detection
1179 if test x$enable_libaudit = xno ; then
1180     have_libaudit=no;
1181 else
1182     # See if we have audit daemon & capabilities library
1183     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1184                  have_libaudit=yes, have_libaudit=no)
1185     if test x$have_libaudit = xyes ; then
1186         AC_CHECK_LIB(cap-ng, capng_clear,
1187                  have_libaudit=yes, have_libaudit=no)
1188     fi
1189 fi
1190
1191 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1192
1193 if test x$have_libaudit = xyes ; then
1194     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1195     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1196 fi
1197
1198 AC_SUBST([SELINUX_LIBS])
1199
1200 # Check for ADT API (Solaris Basic Security Mode auditing)
1201 AC_MSG_CHECKING(for ADT API)
1202 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1203 #include <bsm/adt.h>
1204 adt_user_context = ADT_USER;
1205 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1206
1207 if test ${check_adt_audit} = yes
1208 then
1209    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1210    ADT_LIBS="-lbsm"
1211    LIBS="-lbsm $LIBS"
1212    AC_MSG_RESULT(yes)
1213 else
1214    AC_MSG_RESULT(no)
1215 fi
1216 AC_SUBST([ADT_LIBS])
1217
1218 # Check for SCM_RIGHTS
1219 AC_MSG_CHECKING([for SCM_RIGHTS])
1220 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1221 #include <sys/types.h>
1222 #include <sys/socket.h>
1223 #include <sys/un.h>
1224 static int x = SCM_RIGHTS;
1225 ]], [[]])],
1226 [ AC_MSG_RESULT([supported])
1227   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1228 [ AC_MSG_RESULT([not supported]) ])
1229
1230 NETWORK_libs=
1231 if test x$dbus_win = xyes ; then
1232   if test x$dbus_wince = xyes ; then
1233     NETWORK_libs="-lws2"
1234   else
1235     NETWORK_libs="-lws2_32 -liphlpapi"
1236   fi
1237 fi
1238
1239 AC_SUBST([NETWORK_libs])
1240
1241 AC_ARG_WITH([valgrind],
1242   [AS_HELP_STRING([--with-valgrind],
1243      [Add instrumentation to help valgrind to understand our allocator])],
1244   [],
1245   [with_valgrind=no])
1246
1247 if test x$with_valgrind != xno; then
1248   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1249   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1250 fi
1251
1252 # Determine maximum number of Unix fds which may be passed
1253 AS_CASE([$host_os],
1254   [*qnx*],
1255     [DEFAULT_MESSAGE_UNIX_FDS=256],
1256   [*],
1257     [DEFAULT_MESSAGE_UNIX_FDS=1024])
1258 AC_DEFINE_UNQUOTED([DBUS_DEFAULT_MESSAGE_UNIX_FDS],
1259   [$DEFAULT_MESSAGE_UNIX_FDS],
1260   [Default for dbus_connection_get_max_message_unix_fds()])
1261 AC_SUBST([DEFAULT_MESSAGE_UNIX_FDS])
1262
1263 #### Set up final flags
1264 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1265 AC_SUBST([LIBDBUS_LIBS])
1266
1267 ### X11 detection
1268 DBUS_X_LIBS=
1269 DBUS_X_CFLAGS=
1270
1271 AC_ARG_ENABLE([x11-autolaunch],
1272   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1273   [], [enable_x11_autolaunch=auto])
1274
1275 if test "x$dbus_win" = xyes; then
1276     if test "x$enable_x11_autolaunch" = xyes; then
1277         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1278     fi
1279
1280     enable_x11_autolaunch=no
1281     have_x11=no
1282 else
1283     AC_PATH_XTRA
1284
1285     if test "x$no_x" = xyes; then
1286         have_x11=no
1287     else
1288         have_x11=yes
1289         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1290         DBUS_X_CFLAGS="$X_CFLAGS"
1291     fi
1292 fi
1293
1294 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1295     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1296 else
1297     # move from "auto" to "yes" or "no" if necessary
1298     if test "x$enable_x11_autolaunch" != xno; then
1299         enable_x11_autolaunch="$have_x11"
1300     fi
1301 fi
1302
1303 if test "x$have_x11" = xyes ; then
1304    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1305 fi
1306
1307 if test "x$enable_x11_autolaunch" = xyes ; then
1308    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1309 fi
1310
1311 AC_SUBST([DBUS_X_CFLAGS])
1312 AC_SUBST([DBUS_X_LIBS])
1313
1314 #### gcc warning flags
1315
1316 cc_supports_flag() {
1317   AC_MSG_CHECKING(whether $CC supports "$*")
1318   save_CFLAGS="$CFLAGS"
1319   CFLAGS="$*"
1320   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1321   CFLAGS="$save_CFLAGS"
1322   AC_MSG_RESULT([$rc])
1323   test "x$rc" = xyes
1324 }
1325
1326 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1327   dnl Use -Werror by default if:
1328   dnl - we're not on Windows (too many warnings), and
1329   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1330   dnl Override with --enable-Werror or --disable-Werror
1331   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1332
1333   dnl Enable these warnings if possible:
1334   [all \
1335    extra \
1336    char-subscripts \
1337    missing-declarations \
1338    missing-prototypes \
1339    nested-externs \
1340    pointer-arith \
1341    cast-align \
1342    no-address \
1343    float-equal \
1344    declaration-after-statement \
1345   ],
1346
1347   dnl Disable these warnings if possible, make them non-fatal if possible,
1348   dnl and don't enable -Werror unless we succeeded.
1349   dnl
1350   dnl Intentional:
1351   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1352   dnl   checking or not asserting
1353   dnl - missing field initializers being 0 is a C feature, not a bug
1354   dnl - unused-parameter is to make writing callbacks less annoying
1355   dnl
1356   dnl To be fixed one day:
1357   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1358   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1359   dnl   is better than nothing
1360   [$DISABLE_UNUSED_WARNINGS \
1361    missing-field-initializers \
1362    unused-parameter \
1363    sign-compare \
1364    pointer-sign \
1365    type-limits \
1366   ])
1367
1368 if test "x$GCC" = "xyes"; then
1369   # We're treating -fno-common like a warning: it makes the linker more
1370   # strict, because on some systems the linker is *always* this strict
1371   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1372
1373   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1374   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1375
1376   if test "x$enable_ansi" = "xyes"; then
1377     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1378       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1379   fi
1380 fi
1381
1382 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1383 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1384 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1385 dnl is the next best thing
1386 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1387
1388 case $host_os in
1389     solaris*)
1390         # Solaris' C library apparently needs these runes to be threadsafe...
1391         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1392         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1393         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1394         # ... and this opt-in to get file descriptor passing support
1395         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1396         ;;
1397 esac
1398
1399 ### Doxygen Documentation
1400
1401 AC_PATH_PROG(DOXYGEN, doxygen, no)
1402
1403 AC_MSG_CHECKING([whether to build Doxygen documentation])
1404
1405 if test x$DOXYGEN = xno ; then
1406     have_doxygen=no
1407 else
1408     have_doxygen=yes
1409 fi
1410
1411 if test x$enable_doxygen_docs = xauto ; then
1412     if test x$have_doxygen = xno ; then
1413         enable_doxygen_docs=no
1414     else
1415         enable_doxygen_docs=yes
1416     fi
1417 fi
1418
1419 if test x$enable_doxygen_docs = xyes; then
1420     if test x$have_doxygen = xno; then
1421         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1422     fi
1423 fi
1424
1425 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1426 AC_MSG_RESULT($enable_doxygen_docs)
1427
1428 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1429 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1430
1431 ### XML Documentation
1432
1433 AC_PATH_PROG(XMLTO, xmlto, no)
1434
1435 AC_MSG_CHECKING([whether to build XML documentation])
1436
1437 if test x$XMLTO = xno ; then
1438     have_xmlto=no
1439 else
1440     have_xmlto=yes
1441 fi
1442
1443 if test x$enable_xml_docs = xauto ; then
1444     if test x$have_xmlto = xno ; then
1445         enable_xml_docs=no
1446     else
1447         enable_xml_docs=yes
1448     fi
1449 fi
1450
1451 if test x$enable_xml_docs = xyes; then
1452     if test x$have_xmlto = xno; then
1453         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1454     fi
1455 fi
1456
1457 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1458 AC_MSG_RESULT($enable_xml_docs)
1459
1460 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1461     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes])
1462
1463 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1464
1465 #### find the actual value for $prefix that we'll end up with
1466 ##   (I know this is broken and should be done in the Makefile, but
1467 ##    that's a major pain and almost nobody actually seems to care)
1468 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1469 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1470 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1471 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1472 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1473 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1474 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1475
1476 #### Check our operating system
1477 operating_system=unknown
1478 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1479    operating_system=redhat
1480 fi
1481
1482 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1483    operating_system=slackware
1484 fi
1485
1486 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1487    operating_system=cygwin
1488 fi
1489
1490 #### Sort out init scripts
1491
1492 if test x$with_init_scripts = x; then
1493     case x$operating_system in
1494         xredhat)        with_init_scripts=redhat ;;
1495         xslackware)     with_init_scripts=slackware ;;
1496         xcygwin)        with_init_scripts=cygwin ;;
1497         *)                      with_init_scripts=none ;;
1498     esac
1499 fi
1500
1501 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1502 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1503 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1504
1505 ##### systemd unit files
1506 AC_ARG_WITH([systemdsystemunitdir],
1507 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1508     [],
1509     [
1510     PKG_CHECK_EXISTS([systemd],
1511       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1512       [with_systemdsystemunitdir=no])
1513     ])
1514 if test "x$with_systemdsystemunitdir" != xno; then
1515    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1516 fi
1517 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1518
1519 ##### Set up location for system bus socket
1520 if ! test -z "$with_system_socket"; then
1521    DBUS_SYSTEM_SOCKET=$with_system_socket
1522 else
1523    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1524 fi
1525
1526 AC_SUBST(DBUS_SYSTEM_SOCKET)
1527 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1528
1529 ## System bus only listens on local domain sockets, and never
1530 ## on an abstract socket (so only root can create the socket).
1531 ##
1532 ## This won't work on Windows. It's not meant to - the system bus is
1533 ## meaningless on Windows anyway.
1534 ##
1535 ## This has to be suitable for hard-coding in client libraries as well as
1536 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1537 ## and also to connect to. If this ever changes, it'll need to be split into
1538 ## two variables, one for the listening address and one for the connecting
1539 ## address.
1540 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1541 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1542 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1543
1544 #### Set up the pid file
1545 if ! test -z "$with_system_pid_file"; then
1546    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1547 elif test x$with_init_scripts = xredhat ; then
1548    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1549 else
1550    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1551 fi
1552
1553 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1554
1555 #### Directory to check for console ownership
1556 if ! test -z "$with_console_auth_dir"; then
1557    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1558 else
1559    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1560 fi
1561
1562 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1563 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1564
1565 #### File to check for console ownership
1566 if test x$have_console_owner_file = xyes; then
1567    if ! test -z "$with_console_owner_file"; then
1568       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1569    else
1570       DBUS_CONSOLE_OWNER_FILE=/dev/console
1571    fi
1572 else
1573   DBUS_CONSOLE_OWNER_FILE=
1574 fi
1575
1576 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1577 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1578
1579 #### User to start the system bus as
1580 if test -z "$with_dbus_user" ; then
1581     DBUS_USER=messagebus
1582 else
1583     DBUS_USER=$with_dbus_user
1584 fi
1585 AC_SUBST(DBUS_USER)
1586 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1587
1588 #### Prefix to install into
1589 DBUS_PREFIX=$EXPANDED_PREFIX
1590 AC_SUBST(DBUS_PREFIX)
1591 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1592
1593 #### Direcotry to install data files into
1594 DBUS_DATADIR=$EXPANDED_DATADIR
1595 AC_SUBST(DBUS_DATADIR)
1596 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1597
1598 #### Directory to install dbus-daemon
1599 if test -z "$with_dbus_daemondir" ; then
1600     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1601 else
1602     DBUS_DAEMONDIR=$with_dbus_daemondir
1603 fi
1604 AC_SUBST(DBUS_DAEMONDIR)
1605 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1606
1607 #### Directory to install the other binaries
1608 DBUS_BINDIR="$EXPANDED_BINDIR"
1609 AC_SUBST(DBUS_BINDIR)
1610 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1611
1612 #### Directory to install the libexec binaries
1613 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1614 AC_SUBST(DBUS_LIBEXECDIR)
1615 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1616
1617 #### Tell tests where to find certain stuff in builddir
1618
1619 DBUS_PWD=`pwd`
1620 # Useful in a cross-compilation environment, where the tests are run on the host system.
1621 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1622                            DBUS_PWD=$withval)
1623
1624 DBUS_TEST_EXEC="$DBUS_PWD/test"
1625 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1626
1627 AC_SUBST([DBUS_TEST_DATA])
1628 AC_SUBST([DBUS_TEST_EXEC])
1629
1630 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1631                    [Full path to the daemon in the builddir])
1632 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1633                    [Extension for executables, typically empty or .exe])
1634
1635 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1636                    [Full path to the daemon in the builddir])
1637 AC_SUBST(TEST_BUS_BINARY)
1638
1639 ## Export the non-setuid external helper
1640 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1641 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1642 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1643                    [Full path to the launch helper test program in the builddir])
1644
1645 #### Find socket directories
1646 if ! test -z "$TMPDIR" ; then
1647    DEFAULT_SOCKET_DIR=$TMPDIR
1648 elif ! test -z "$TEMP" ; then
1649    DEFAULT_SOCKET_DIR=$TEMP
1650 elif ! test -z "$TMP" ; then
1651    DEFAULT_SOCKET_DIR=$TMP
1652 else
1653    DEFAULT_SOCKET_DIR=/tmp
1654 fi
1655
1656 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1657
1658 if ! test -z "$with_test_socket_dir" ; then
1659    TEST_SOCKET_DIR="$with_test_socket_dir"
1660 else
1661    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1662 fi
1663 AC_SUBST(TEST_SOCKET_DIR)
1664 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1665
1666 if test "x$dbus_unix" = xyes; then
1667   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1668 else
1669   TEST_LISTEN="tcp:host=localhost"
1670 fi
1671 AC_SUBST([TEST_LISTEN])
1672 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1673   [Listening address for regression tests])
1674
1675 if ! test -z "$with_session_socket_dir" ; then
1676    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1677 else
1678    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1679 fi
1680 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1681 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1682
1683 # This must be a listening address. It doesn't necessarily need to be an
1684 # address you can connect to - it can be something vague like
1685 # "nonce-tcp:".
1686 #
1687 # The default varies by platform.
1688 AC_ARG_WITH([dbus_session_bus_listen_address],
1689             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1690                            [default address for a session bus to listen on (see configure.ac)]),
1691             [with_dbus_session_bus_listen_address=$withval],
1692             [with_dbus_session_bus_listen_address=])
1693
1694 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1695         # the user specified something, trust them
1696         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1697 elif test x$dbus_win = xyes; then
1698         # On Windows, you can (and should) listen on autolaunch addresses,
1699         # because autolaunching is different.
1700         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1701         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1702 elif test x$have_launchd = xyes; then
1703         # Mac OS X default is to use launchd
1704         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1705 else
1706         # The default on all other Unix platforms (notably Linux)
1707         # is to create a randomly named socket in /tmp or similar
1708         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1709 fi
1710 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1711
1712 # This must be an address you can connect to. It doesn't necessarily
1713 # need to be an address you can listen on - it can be "autolaunch:",
1714 # even on Unix.
1715 #
1716 # The default varies by platform.
1717 AC_ARG_WITH([dbus_session_bus_connect_address],
1718             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1719                            [fallback address for a session bus client to connect to (see configure.ac)]),
1720             [with_dbus_session_bus_connect_address=$withval],
1721             [with_dbus_session_bus_connect_address=])
1722
1723 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1724         # the user specified something, trust them
1725         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1726 elif test x$dbus_win = xyes; then
1727         # Windows autolaunching is a bit different; leaving it in its own
1728         # branch of the conditional because the default might conceivably
1729         # change (see #38201)
1730         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1731 else
1732         # The default on all other Unix platforms (notably Linux)
1733         # is to use auto-launching - this works a bit differently on Mac OS X
1734         # but comes out basically the same in the end
1735         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1736 fi
1737 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1738 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1739   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1740   [Fallback address for session bus clients])
1741
1742 # darwin needs this to initialize the environment
1743 AC_CHECK_HEADERS(crt_externs.h)
1744 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1745 AH_VERBATIM(_DARWIN_ENVIRON,
1746 [
1747 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1748 # include <sys/time.h>
1749 # include <crt_externs.h>
1750 # define environ (*_NSGetEnviron())
1751 #endif
1752 ])
1753
1754 AC_ARG_ENABLE([stats],
1755   [AS_HELP_STRING([--enable-stats],
1756     [enable bus daemon usage statistics])],
1757   [], [enable_stats=no])
1758 if test "x$enable_stats" = xyes; then
1759   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1760     [Define to enable bus daemon usage statistics])
1761 fi
1762
1763 AC_CONFIG_FILES([
1764 Doxyfile
1765 dbus/versioninfo.rc
1766 dbus/dbus-arch-deps.h
1767 bus/system.conf
1768 bus/session.conf
1769 bus/messagebus
1770 bus/messagebus-config
1771 bus/org.freedesktop.dbus-session.plist
1772 bus/rc.messagebus
1773 bus/dbus.service
1774 bus/dbus.socket
1775 Makefile
1776 dbus/Makefile
1777 bus/Makefile
1778 tools/Makefile
1779 test/Makefile
1780 test/name-test/Makefile
1781 doc/Makefile
1782 doc/dbus-cleanup-sockets.1.xml
1783 doc/dbus-daemon.1.xml
1784 doc/dbus-launch.1.xml
1785 doc/dbus-monitor.1.xml
1786 doc/dbus-run-session.1.xml
1787 doc/dbus-send.1.xml
1788 doc/dbus-uuidgen.1.xml
1789 dbus-1.pc
1790 dbus-1-uninstalled.pc
1791 test/data/valid-config-files/debug-allow-all.conf
1792 test/data/valid-config-files/debug-allow-all-sha1.conf
1793 test/data/valid-config-files-system/debug-allow-all-pass.conf
1794 test/data/valid-config-files-system/debug-allow-all-fail.conf
1795 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1796 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1797 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1798 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1799 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1800 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1801 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1802 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1803 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1804 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1805 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1806 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1807 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1808 ])
1809 AC_OUTPUT
1810
1811 dnl ==========================================================================
1812 echo "
1813                     D-Bus $VERSION
1814                   ==============
1815
1816         prefix:                   ${EXPANDED_PREFIX}
1817         exec_prefix:              ${exec_prefix}
1818         libdir:                   ${EXPANDED_LIBDIR}
1819         libexecdir:               ${EXPANDED_LIBEXECDIR}
1820         bindir:                   ${EXPANDED_BINDIR}
1821         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1822         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1823         datadir:                  ${EXPANDED_DATADIR}
1824         source code location:     ${srcdir}
1825         compiler:                 ${CC}
1826         cflags:                   ${CFLAGS}
1827         cppflags:                 ${CPPFLAGS}
1828         cxxflags:                 ${CXXFLAGS}
1829         64-bit int:               ${DBUS_INT64_TYPE}
1830         32-bit int:               ${DBUS_INT32_TYPE}
1831         16-bit int:               ${DBUS_INT16_TYPE}
1832         Doxygen:                  ${DOXYGEN:-not found}
1833         xmlto:                    ${XMLTO:-not found}"
1834
1835 echo "
1836         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1837         gcc coverage profiling:   ${enable_compiler_coverage}
1838         Building embedded tests:  ${enable_embedded_tests}
1839         Building modular tests:   ${enable_modular_tests}
1840             - with GLib:          ${with_glib}
1841         Building verbose mode:    ${enable_verbose_mode}
1842         Building assertions:      ${enable_asserts}
1843         Building checks:          ${enable_checks}
1844         Building bus stats API:   ${enable_stats}
1845         Building SELinux support: ${have_selinux}
1846         Building inotify support: ${have_inotify}
1847         Building kqueue support:  ${have_kqueue}
1848         Building systemd support: ${have_systemd}
1849         Building X11 code:        ${have_x11}
1850         Building Doxygen docs:    ${enable_doxygen_docs}
1851         Building XML docs:        ${enable_xml_docs}
1852         Building cache support:   ${enable_userdb_cache}
1853         Building launchd support: ${have_launchd}
1854         Init scripts style:       ${with_init_scripts}
1855         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1856         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1857         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1858         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1859         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1860         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1861         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1862         Console owner file:       ${have_console_owner_file}
1863         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1864         System bus user:          ${DBUS_USER}
1865         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1866         'make check' socket dir:  ${TEST_SOCKET_DIR}
1867 "
1868 if test x$have_launchd = xyes; then
1869         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1870 fi
1871 echo
1872
1873 if test x$enable_embedded_tests = xyes; then
1874         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1875 fi
1876 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1877         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1878 fi
1879 if test x$enable_compiler_coverage = xyes; then
1880         echo "NOTE: building with coverage profiling is definitely for developers only."
1881 fi
1882 if test x$enable_verbose_mode = xyes; then
1883         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1884 fi
1885 if test x$enable_asserts = xyes; then
1886         echo "NOTE: building with assertions increases library size and decreases performance."
1887 fi
1888 if test x$enable_checks = xno; then
1889         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1890 fi
1891
1892 if test "x$DBUS_HAVE_INT64" = x0; then
1893   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1894
1895   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1896   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1897   used if your compiler lacks support for 64-bit integers. Please report a bug
1898   with details of your platform and compiler.
1899
1900   This option is likely to be removed in future, unless the D-Bus developers
1901   receive reports that it is still needed.
1902   ])
1903 fi