configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [6])
   6 m4_define([dbus_micro_version], [5])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=10
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=7
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 154 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 155 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 156 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 157 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 158 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 159 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 160
 161 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 162 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 163 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 164 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 165 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 166 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 167 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 168 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 169 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 170 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 171 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 172 AC_ARG_WITH(dbus_session_bus_default_address, AS_HELP_STRING([--with-dbus-session-bus-default-address=[nonce-tcp:/autolaunch:/tcp:host:port]],[Transport Type to be used (default: nonce-tcp:)]),with_dbus_session_bus_default_address=$withval,with_dbus_session_bus_default_address=nonce-tcp:)
 173
 174 AC_ARG_ENABLE([embedded-tests],
 175   AS_HELP_STRING([--enable-embedded-tests],
 176     [enable unit test code in the library and binaries]),
 177   [], [enable_embedded_tests=$enable_developer])
 178 AC_ARG_ENABLE([modular-tests],
 179   AS_HELP_STRING([--enable-modular-tests],
 180     [enable modular regression tests (requires GLib)]),
 181   [], [enable_modular_tests=auto])
 182 # --enable-tests overrides both --enable-embedded-tests and
 183 # --enable-modular-tests
 184 AC_ARG_ENABLE([tests],
 185   AS_HELP_STRING([--enable-tests],
 186     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 187   [
 188   if test "x$enableval" = xyes; then
 189     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 190     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 191   fi
 192   enable_embedded_tests=$enableval
 193   enable_modular_tests=$enableval
 194   ],
 195   [])
 196
 197 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 198 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 199 # name for this.
 200 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 201 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 202   [test "x$enable_embedded_tests" = xyes])
 203 if test "x$enable_embedded_tests" = xyes; then
 204     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 205       [Define to build test code into the library and binaries])
 206     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 207       [Define to build test code into the library and binaries])
 208 fi
 209
 210 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 211 # These use GTest, from GLib, because life's too short. They're enabled by
 212 # default (unless you don't have GLib), because they don't bloat the library
 213 # or binaries.
 214
 215 with_glib=yes
 216
 217 if test "x$enable_modular_tests" != xno; then
 218   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 219     [],
 220     [if test "x$enable_modular_tests" = xyes; then
 221       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 222       AC_MSG_ERROR([$GLIB_ERRORS])
 223     else # assumed to be "auto"
 224       with_glib=no
 225     fi])
 226   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 227   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 228     [],
 229     [if test "x$enable_modular_tests" = xyes; then
 230       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 231       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 232     else # assumed to be "auto"
 233       with_glib=no
 234     fi])
 235 fi
 236 if test "x$enable_modular_tests" != xno; then
 237   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 238     [Define to build independent test binaries])
 239 fi
 240 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 241   [test "x$enable_modular_tests" != xno])
 242
 243 if test "x$with_glib" != xno; then
 244   AC_DEFINE([DBUS_WITH_GLIB], [1],
 245     [Define if GLib, GObject, GIO are available])
 246 fi
 247 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 248
 249 AC_ARG_ENABLE([installed-tests],
 250   AS_HELP_STRING([--enable-installed-tests],
 251     [enable unit test code in the library and binaries]),
 252   [], [enable_installed_tests=no])
 253 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 254   [test "x$enable_installed_tests" = xyes])
 255
 256 if test "x$enable_tests" = xyes; then
 257   # full test coverage is required, Python is a hard dependency
 258   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 259   AM_PATH_PYTHON([2.6])
 260   AC_MSG_CHECKING([for Python modules for full test coverage])
 261   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 262     AC_MSG_RESULT([yes])
 263   else
 264     AC_MSG_RESULT([no])
 265     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 266   fi
 267 else
 268   # --enable-tests not given: do not abort if Python is missing
 269   AM_PATH_PYTHON([2.6], [], [:])
 270 fi
 271
 272 if test x$enable_verbose_mode = xyes; then
 273     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 274 fi
 275
 276 if test x$enable_asserts = xno; then
 277     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 278     DISABLE_UNUSED_WARNINGS="unused-label"
 279     R_DYNAMIC_LDFLAG=""
 280 else
 281     # -rdynamic is needed for glibc's backtrace_symbols to work.
 282     # No clue how much overhead this adds, but it's useful
 283     # to do this on any assertion failure,
 284     # so for now it's enabled anytime asserts are (currently not
 285     # in production builds).
 286
 287     # To get -rdynamic you pass -export-dynamic to libtool.
 288     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 289     R_DYNAMIC_LDFLAG=-export-dynamic
 290 fi
 291 AC_SUBST(R_DYNAMIC_LDFLAG)
 292
 293 if test x$enable_checks = xno; then
 294     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 295     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 296     DISABLE_UNUSED_WARNINGS="unused-label"
 297 fi
 298
 299 if test x$enable_userdb_cache = xyes; then
 300     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 301 fi
 302
 303 if test x$enable_compiler_coverage = xyes; then
 304      ## so that config.h changes when you toggle gcov support
 305      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 306 fi
 307
 308 # glibc21.m4 serial 3
 309 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 310 dnl This file is free software; the Free Software Foundation
 311 dnl gives unlimited permission to copy and/or distribute it,
 312 dnl with or without modifications, as long as this notice is preserved.
 313
 314 # Test for the GNU C Library, version 2.1 or newer.
 315 # From Bruno Haible.
 316
 317 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 318   ac_cv_gnu_library_2_1,
 319   [AC_EGREP_CPP([Lucky GNU user],
 320     [
 321 #include <features.h>
 322 #ifdef __GNU_LIBRARY__
 323  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 324   Lucky GNU user
 325  #endif
 326 #endif
 327     ],
 328     ac_cv_gnu_library_2_1=yes,
 329     ac_cv_gnu_library_2_1=no)
 330   ]
 331 )
 332
 333 #### Integer sizes
 334
 335 AC_CHECK_SIZEOF(char)
 336 AC_CHECK_SIZEOF(short)
 337 AC_CHECK_SIZEOF(long)
 338 AC_CHECK_SIZEOF(int)
 339 AC_CHECK_SIZEOF(void *)
 340 AC_CHECK_SIZEOF(long long)
 341 AC_CHECK_SIZEOF(__int64)
 342
 343 AC_ARG_WITH([64-bit],
 344   [AS_HELP_STRING([--without-64-bit],
 345     [If you have to use this option, please report it as a bug])],
 346   [],
 347   [with_64_bit=yes])
 348
 349 ### See what our 64 bit type is called
 350 AC_MSG_CHECKING([64-bit integer type])
 351
 352 case 8 in
 353 $ac_cv_sizeof_int)
 354   dbusint64=int
 355   dbusint64_constant='(val)'
 356   dbusuint64_constant='(val)'
 357   dbusint64_printf_modifier='""'
 358   ;;
 359 $ac_cv_sizeof_long)
 360   dbusint64=long
 361   dbusint64_constant='(val##L)'
 362   dbusuint64_constant='(val##UL)'
 363   dbusint64_printf_modifier='"l"'
 364   ;;
 365 $ac_cv_sizeof_long_long)
 366   dbusint64='long long'
 367   dbusint64_constant='(val##LL)'
 368   dbusuint64_constant='(val##ULL)'
 369   # Ideally we discover what the format is, but this is
 370   # only used in verbose mode, so eh...
 371   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 372     dbusint64_printf_modifier='"ll"'
 373   fi
 374   ;;
 375 $ac_cv_sizeof___int64)
 376   dbusint64=__int64
 377   dbusint64_constant='(val##i64)'
 378   dbusuint64_constant='(val##ui64)'
 379   # See above case
 380   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 381     dbusint64_printf_modifier='"ll"'
 382   fi
 383   ;;
 384 esac
 385
 386 AS_IF(
 387   [test "x$with_64_bit" = xno],
 388   [
 389         DBUS_INT64_TYPE="no_int64_type_detected"
 390         DBUS_HAVE_INT64=0
 391         DBUS_INT64_CONSTANT=
 392         DBUS_UINT64_CONSTANT=
 393         AC_MSG_RESULT([disabled via --without-64-bit])
 394   ],
 395   dnl else if
 396   [test -z "$dbusint64"],
 397   [AC_MSG_RESULT([not found])
 398   AC_MSG_ERROR([Could not find a 64-bit integer type.
 399
 400 Please report a bug here with details of your platform and compiler:
 401
 402     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 403
 404 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 405 the option "--without-64-bit".
 406
 407 This option is likely to be removed in future, unless you report that your
 408 platform needs it.])
 409   ],
 410   dnl else
 411   [
 412         DBUS_INT64_TYPE="$dbusint64"
 413         DBUS_HAVE_INT64=1
 414         DBUS_INT64_CONSTANT="$dbusint64_constant"
 415         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 416         if test x"$dbusint64_printf_modifier" != x; then
 417                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 418         fi
 419         AC_MSG_RESULT($DBUS_INT64_TYPE)
 420   ])
 421
 422 AC_SUBST(DBUS_INT64_TYPE)
 423 AC_SUBST(DBUS_INT64_CONSTANT)
 424 AC_SUBST(DBUS_UINT64_CONSTANT)
 425 AC_SUBST(DBUS_HAVE_INT64)
 426
 427 ### see what 32-bit int is called
 428 AC_MSG_CHECKING([32-bit integer type])
 429
 430 case 4 in
 431 $ac_cv_sizeof_short)
 432   dbusint32=short
 433   ;;
 434 $ac_cv_sizeof_int)
 435   dbusint32=int
 436   ;;
 437 $ac_cv_sizeof_long)
 438   dbusint32=long
 439   ;;
 440 esac
 441
 442 if test -z "$dbusint32" ; then
 443         DBUS_INT32_TYPE="no_int32_type_detected"
 444         AC_MSG_ERROR([No 32-bit integer type found])
 445 else
 446         DBUS_INT32_TYPE="$dbusint32"
 447         AC_MSG_RESULT($DBUS_INT32_TYPE)
 448 fi
 449
 450 AC_SUBST(DBUS_INT32_TYPE)
 451
 452 ### see what 16-bit int is called
 453 AC_MSG_CHECKING([16-bit integer type])
 454
 455 case 2 in
 456 $ac_cv_sizeof_short)
 457   dbusint16=short
 458   ;;
 459 $ac_cv_sizeof_int)
 460   dbusint16=int
 461   ;;
 462 esac
 463
 464 if test -z "$dbusint16" ; then
 465         DBUS_INT16_TYPE="no_int16_type_detected"
 466         AC_MSG_ERROR([No 16-bit integer type found])
 467 else
 468         DBUS_INT16_TYPE="$dbusint16"
 469         AC_MSG_RESULT($DBUS_INT16_TYPE)
 470 fi
 471
 472 AC_SUBST(DBUS_INT16_TYPE)
 473
 474 ## byte order
 475 case $host_os in
 476         darwin*)
 477                 # check at compile-time, so that it is possible to build universal
 478                 # (with multiple architectures at once on the compile line)
 479                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 480                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 481                         #if defined(__BIG_ENDIAN__)
 482                         #define WORDS_BIGENDIAN 1
 483                         #endif
 484                 ])
 485                 ;;
 486         *)
 487                 AC_C_BIGENDIAN
 488                 ;;
 489 esac
 490
 491 dnl **********************************
 492 dnl *** va_copy checks (from GLib) ***
 493 dnl **********************************
 494 dnl we currently check for all three va_copy possibilities, so we get
 495 dnl all results in config.log for bug reports.
 496 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 497         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 498 #include <stdlib.h>
 499         static void f (int i, ...) {
 500         va_list args1, args2;
 501         va_start (args1, i);
 502         va_copy (args2, args1);
 503         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 504           exit (1);
 505         va_end (args1); va_end (args2);
 506         }
 507         int main() {
 508           f (0, 42);
 509           return 0;
 510         }])],
 511         [dbus_cv_va_copy=yes],
 512         [dbus_cv_va_copy=no])
 513 ])
 514 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 515         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 516 #include <stdlib.h>
 517         static void f (int i, ...) {
 518         va_list args1, args2;
 519         va_start (args1, i);
 520         __va_copy (args2, args1);
 521         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 522           exit (1);
 523         va_end (args1); va_end (args2);
 524         }
 525         int main() {
 526           f (0, 42);
 527           return 0;
 528         }])],
 529         [dbus_cv___va_copy=yes],
 530         [dbus_cv___va_copy=no])
 531 ])
 532
 533 if test "x$dbus_cv_va_copy" = "xyes"; then
 534   dbus_va_copy_func=va_copy
 535 else if test "x$dbus_cv___va_copy" = "xyes"; then
 536   dbus_va_copy_func=__va_copy
 537 fi
 538 fi
 539
 540 if test -n "$dbus_va_copy_func"; then
 541   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 542 fi
 543
 544 AC_LANG_PUSH(C)
 545 AC_CACHE_CHECK([whether va_lists can be copied by value],
 546         dbus_cv_va_val_copy,
 547         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 548 [[
 549         #include <stdarg.h>
 550         #include <stdlib.h>
 551 ]],
 552 [[
 553         static void f (int i, ...) {
 554         va_list args1, args2;
 555         va_start (args1, i);
 556         args2 = args1;
 557         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 558           exit (1);
 559         va_end (args1); va_end (args2);
 560         }
 561         int main() {
 562           f (0, 42);
 563           return 0;
 564         }
 565 ]])],
 566         [dbus_cv_va_val_copy=yes],
 567         [dbus_cv_va_val_copy=no],
 568         [dbus_cv_va_val_copy=yes])
 569 ])
 570 AC_LANG_POP(C)
 571
 572 if test "x$dbus_cv_va_val_copy" = "xno"; then
 573   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 574 fi
 575
 576
 577 #### Atomic integers
 578
 579 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 580   dbus_cv_sync_sub_and_fetch,
 581   [AC_LINK_IFELSE([
 582      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 583      [dbus_cv_sync_sub_and_fetch=yes],
 584      [dbus_cv_sync_sub_and_fetch=no])
 585   ])
 586
 587 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 588    have_sync=1
 589 else
 590    have_sync=0
 591 fi
 592
 593 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 594
 595 #### Various functions
 596 AC_SEARCH_LIBS(socket,[socket network])
 597 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 598
 599 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid secure_getenv __secure_getenv )
 600
 601 AC_CHECK_HEADERS([syslog.h])
 602 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 603   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 604 fi
 605
 606 #### Check for broken poll; taken from Glib's configure
 607
 608 AC_MSG_CHECKING([for broken poll])
 609 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 610     #include <stdlib.h>
 611     #include <fcntl.h>
 612     #include <poll.h>
 613     #ifdef HAVE_SYS_POLL_H
 614     #include <sys/poll.h>
 615     #endif
 616     int main(void) {
 617       struct pollfd fds[1];
 618       int fd;
 619       fd = open("/dev/null", 1);
 620       fds[0].fd = fd;
 621       fds[0].events = POLLIN;
 622       fds[0].revents = 0;
 623       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 624             exit(1);  /* Does not work for devices -- fail */
 625       }
 626       exit(0);
 627     }]])],
 628   [broken_poll=no],
 629   [broken_poll=yes
 630    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 631   [broken_poll="no (cross compiling)"])
 632 AC_MSG_RESULT($broken_poll)
 633
 634 AC_MSG_CHECKING(for dirfd)
 635 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 636 #include <sys/types.h>
 637 #include <dirent.h>
 638 ]], [[
 639 DIR *dirp;
 640 dirp = opendir(".");
 641 dirfd(dirp);
 642 closedir(dirp);
 643 ]])],
 644 [dbus_have_dirfd=yes],
 645 [dbus_have_dirfd=no])
 646 AC_MSG_RESULT($dbus_have_dirfd)
 647 if test "$dbus_have_dirfd" = yes; then
 648         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 649 else
 650         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 651         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 652 #include <sys/types.h>
 653 #include <dirent.h>
 654         ]], [[
 655 DIR *dirp;
 656 int fd;
 657 dirp = opendir(".");
 658 fd = dirp->dd_fd;
 659 closedir(dirp);
 660         ]])],
 661         [dbus_have_ddfd=yes],
 662         [dbus_have_ddfd=no])
 663         AC_MSG_RESULT($dbus_have_ddfd)
 664         if test "$dbus_have_ddfd" = yes; then
 665                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 666         fi
 667 fi
 668
 669 AC_CHECK_HEADERS(sys/resource.h)
 670
 671 AC_CHECK_HEADERS(dirent.h)
 672
 673 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 674
 675 AC_CHECK_HEADERS(errno.h)
 676
 677 AC_CHECK_HEADERS(signal.h)
 678
 679 AC_CHECK_HEADERS(locale.h)
 680
 681 AC_CHECK_HEADERS(byteswap.h)
 682
 683 AC_CHECK_HEADERS(unistd.h)
 684
 685 AC_CHECK_HEADERS(ws2tcpip.h)
 686
 687 AC_CHECK_HEADERS(wspiapi.h)
 688
 689 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 690 #
 691 case $host_os in
 692     solaris*)
 693        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 694 esac
 695
 696 # checking for a posix version of getpwnam_r
 697 # if we are cross compiling and can not run the test
 698 # assume getpwnam_r is the posix version
 699 # it is up to the person cross compiling to change
 700 # this behavior if desired
 701 AC_LANG_PUSH(C)
 702 AC_CACHE_CHECK([for posix getpwnam_r],
 703                 ac_cv_func_posix_getpwnam_r,
 704                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 705 [[
 706 #include <errno.h>
 707 #include <pwd.h>
 708 ]],
 709 [[
 710     char buffer[10000];
 711     struct passwd pwd, *pwptr = &pwd;
 712     int error;
 713     errno = 0;
 714     error = getpwnam_r ("", &pwd, buffer,
 715                         sizeof (buffer), &pwptr);
 716    return (error < 0 && errno == ENOSYS)
 717            || error == ENOSYS;
 718 ]])],
 719         [ac_cv_func_posix_getpwnam_r=yes],
 720         [ac_cv_func_posix_getpwnam_r=no],
 721         [ac_cv_func_posix_getpwnam_r=yes]
 722 )])
 723 AC_LANG_POP(C)
 724
 725 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 726         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 727                 [Have POSIX function getpwnam_r])
 728 else
 729         AC_CACHE_CHECK([for nonposix getpwnam_r],
 730                 ac_cv_func_nonposix_getpwnam_r,
 731                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 732                         struct passwd pwd;
 733                         getpwnam_r ("", &pwd, buffer,
 734                                         sizeof (buffer));]])],
 735                         [ac_cv_func_nonposix_getpwnam_r=yes],
 736                         [ac_cv_func_nonposix_getpwnam_r=no])])
 737                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 738                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 739                         [Have non-POSIX function getpwnam_r])
 740         fi
 741 fi
 742
 743 dnl check for socklen_t
 744 AC_MSG_CHECKING(whether socklen_t is defined)
 745 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 746 #include <sys/types.h>
 747 #include <sys/socket.h>
 748 #include <netdb.h>
 749 ]], [[
 750 socklen_t foo;
 751 foo = 1;
 752 ]])],
 753 [dbus_have_socklen_t=yes],
 754 [dbus_have_socklen_t=no])
 755 AC_MSG_RESULT($dbus_have_socklen_t)
 756
 757 if test "x$dbus_have_socklen_t" = "xyes"; then
 758     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 759 fi
 760
 761 dnl check for writev header and writev function so we're
 762 dnl good to go if HAVE_WRITEV gets defined.
 763 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 764
 765 dnl needed on darwin for NAME_MAX
 766 AC_CHECK_HEADERS(sys/syslimits.h)
 767
 768 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 769 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 770 #include <sys/socket.h> ]])
 771
 772 dnl check for flavours of varargs macros (test from GLib)
 773 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 774 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 775 int a(int p1, int p2, int p3);
 776 #define call_a(...) a(1,__VA_ARGS__)
 777 call_a(2,3);
 778 ]])],
 779 [dbus_have_iso_c_varargs=yes],
 780 [dbus_have_iso_c_varargs=no])
 781 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 782
 783 AC_MSG_CHECKING(for GNUC varargs macros)
 784 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 785 int a(int p1, int p2, int p3);
 786 #define call_a(params...) a(1,params)
 787 call_a(2,3);
 788 ]])],
 789 [dbus_have_gnuc_varargs=yes],
 790 [dbus_have_gnuc_varargs=no])
 791 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 792
 793 dnl Output varargs tests
 794 if test x$dbus_have_iso_c_varargs = xyes; then
 795     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 796 fi
 797 if test x$dbus_have_gnuc_varargs = xyes; then
 798     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 799 fi
 800
 801 dnl Check for various credentials.
 802 AC_MSG_CHECKING(for struct cmsgcred)
 803 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 804 #include <sys/types.h>
 805 #include <sys/socket.h>
 806 ]], [[
 807 struct cmsgcred cred;
 808
 809 cred.cmcred_pid = 0;
 810 ]])],
 811 [dbus_have_struct_cmsgcred=yes],
 812 [dbus_have_struct_cmsgcred=no])
 813 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 814
 815 if test x$dbus_have_struct_cmsgcred = xyes; then
 816     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 817 fi
 818
 819 AC_CHECK_FUNCS(getpeerucred getpeereid)
 820
 821 AC_CHECK_FUNCS(pipe2 accept4)
 822
 823 #### Abstract sockets
 824
 825 if test x$enable_abstract_sockets = xauto; then
 826 AC_LANG_PUSH(C)
 827 warn_on_xcompile=no
 828 AC_CACHE_CHECK([abstract socket namespace],
 829                 ac_cv_have_abstract_sockets,
 830                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 831 [[
 832 #include <sys/types.h>
 833 #include <stdlib.h>
 834 #include <string.h>
 835 #include <stdio.h>
 836 #include <sys/socket.h>
 837 #include <sys/un.h>
 838 #include <errno.h>
 839 ]],
 840 [[
 841   size_t slen;
 842   int listen_fd;
 843   struct sockaddr_un addr;
 844
 845   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 846
 847   if (listen_fd < 0)
 848     {
 849       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 850       exit (1);
 851     }
 852
 853   memset (&addr, '\0', sizeof (addr));
 854   addr.sun_family = AF_UNIX;
 855   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 856   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 857    * beginning.
 858    */
 859   slen = SUN_LEN(&addr);
 860   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 861
 862   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 863     {
 864        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 865                 strerror (errno));
 866        exit (1);
 867     }
 868   else
 869     exit (0);
 870 ]])],
 871               [ac_cv_have_abstract_sockets=yes],
 872               [ac_cv_have_abstract_sockets=no],
 873               [
 874                 ac_cv_have_abstract_sockets=no
 875                 warn_on_xcompile=yes
 876               ]
 877 )])
 878 if test x$warn_on_xcompile = xyes ; then
 879   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 880 fi
 881 AC_LANG_POP(C)
 882 fi
 883
 884 if test x$enable_abstract_sockets = xyes; then
 885     if test x$ac_cv_have_abstract_sockets = xno; then
 886         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 887     fi
 888 fi
 889
 890 if test x$enable_abstract_sockets = xno; then
 891    ac_cv_have_abstract_sockets=no;
 892 fi
 893
 894 if test x$ac_cv_have_abstract_sockets = xyes ; then
 895    DBUS_PATH_OR_ABSTRACT=abstract
 896    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 897 else
 898    DBUS_PATH_OR_ABSTRACT=path
 899 fi
 900
 901 # this is used in addresses to prefer abstract, e.g.
 902 # unix:path=/foo or unix:abstract=/foo
 903 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 904
 905 PKG_PROG_PKG_CONFIG
 906
 907 #### Sort out XML library
 908
 909 # see what we have
 910 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 911              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 912              have_expat=false)
 913
 914 # see what we want to use
 915 dbus_use_libxml=false
 916 dbus_use_expat=false
 917 if test x$with_xml = xexpat; then
 918         if ! $have_expat ; then
 919            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 920         fi
 921         dbus_use_expat=true
 922 elif test x$with_xml = xlibxml; then
 923         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 924         if ! $have_libxml ; then
 925            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 926         fi
 927         dbus_use_libxml=true
 928 else
 929         ### expat is the default because libxml can't currently survive
 930         ### our brutal OOM-handling unit test setup.
 931         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 932         if test x$have_expat = xfalse; then
 933                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 934         fi
 935         ### By default, only use Expat since it's tested and known to work.  If you're a
 936         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 937         ### if your OS is built around libxml, that's another case.
 938         dbus_use_expat=true
 939 fi
 940
 941 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 942 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 943
 944 if $dbus_use_expat; then
 945    XML_LIBS=-lexpat
 946    XML_CFLAGS=
 947 fi
 948 if $dbus_use_libxml; then
 949    XML_LIBS=$LIBXML_LIBS
 950    XML_CFLAGS=$LIBXML_CFLAGS
 951 fi
 952 AC_SUBST([XML_CFLAGS])
 953 AC_SUBST([XML_LIBS])
 954
 955 # Thread lib detection
 956 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 957                                                     [THREAD_LIBS="-lpthread"])])
 958 save_libs="$LIBS"
 959 LIBS="$LIBS $THREAD_LIBS"
 960 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 961 if test x$have_pthread_condattr_setclock = xtrue; then
 962     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 963     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 964     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 965 #include <pthread.h>
 966 ]], [[
 967 struct timespec monotonic_timer;
 968 pthread_condattr_t attr;
 969 pthread_condattr_init (&attr);
 970 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 971 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 972 ]])],
 973 [have_clock_monotonic=true],
 974 [have_clock_monotonic=false])
 975 if test x$have_clock_monotonic = xtrue; then
 976     AC_MSG_RESULT([found])
 977     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 978 else
 979     AC_MSG_RESULT([not found])
 980 fi
 981 fi
 982 LIBS="$save_libs"
 983
 984 AC_SUBST([THREAD_LIBS])
 985
 986 # SELinux detection
 987 if test x$enable_selinux = xno ; then
 988     have_selinux=no;
 989 else
 990     # See if we have SELinux library
 991     AC_CHECK_LIB(selinux, is_selinux_enabled,
 992                  have_selinux=yes, have_selinux=no)
 993
 994     # see if we have the SELinux header with the new D-Bus stuff in it
 995     if test x$have_selinux = xyes ; then
 996         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 997         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 998                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 999                             #else
1000                             #error DBUS__ACQUIRE_SVC not defined
1001                             #endif]])],
1002                           [have_selinux=yes],
1003                           [have_selinux=no])
1004         AC_MSG_RESULT($have_selinux)
1005     fi
1006
1007     if test x$enable_selinux = xauto ; then
1008         if test x$have_selinux = xno ; then
1009                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1010         fi
1011     else
1012         if test x$have_selinux = xno ; then
1013                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1014         fi
1015     fi
1016 fi
1017
1018 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1019
1020 if test x$have_selinux = xyes ; then
1021     # the selinux code creates threads
1022     # which requires libpthread even on linux
1023     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1024                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1025
1026     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1027     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1028 else
1029     SELINUX_LIBS=
1030 fi
1031
1032 # inotify checks
1033 if test x$enable_inotify = xno ; then
1034     have_inotify=no;
1035 else
1036     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1037 fi
1038
1039 dnl check if inotify backend is enabled
1040 if test x$have_inotify = xyes; then
1041    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1042    AC_CHECK_FUNCS(inotify_init1)
1043 fi
1044
1045 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1046
1047 # dnotify checks
1048 if test x$enable_dnotify = xno ; then
1049     have_dnotify=no;
1050 else
1051     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1052         have_dnotify=yes;
1053     else
1054         have_dnotify=no;
1055     fi
1056 fi
1057
1058 dnl check if dnotify backend is enabled
1059 if test x$have_dnotify = xyes; then
1060    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1061 fi
1062
1063 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1064
1065 # For simplicity, we require the userland API for epoll_create1 at
1066 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1067 # not to have it at runtime.
1068 AC_ARG_ENABLE([epoll],
1069               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1070               [enable_epoll=$enableval], [enable_epoll=auto])
1071 if test x$enable_epoll = xno; then
1072     have_linux_epoll=no
1073 else
1074     AC_MSG_CHECKING([for Linux epoll(4)])
1075     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1076         [
1077         #ifndef __linux__
1078         #error This is not Linux
1079         #endif
1080         #include <sys/epoll.h>
1081         ],
1082         [epoll_create1 (EPOLL_CLOEXEC);])],
1083         [have_linux_epoll=yes],
1084         [have_linux_epoll=no])
1085     AC_MSG_RESULT([$have_linux_epoll])
1086 fi
1087 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1088     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1089 fi
1090 if test x$have_linux_epoll = xyes; then
1091   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1092 fi
1093 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1094
1095 # kqueue checks
1096 if test x$enable_kqueue = xno ; then
1097     have_kqueue=no
1098 else
1099     have_kqueue=yes
1100     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1101     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1102
1103     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1104         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1105     fi
1106 fi
1107
1108 dnl check if kqueue backend is enabled
1109 if test x$have_kqueue = xyes; then
1110    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1111 fi
1112
1113 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1114
1115 # launchd checks
1116 if test x$enable_launchd = xno ; then
1117     have_launchd=no
1118 else
1119     have_launchd=yes
1120     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1121     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1122     if test "x$LAUNCHCTL" = "x"; then
1123         have_launchd=no
1124     fi
1125
1126     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1127         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1128     fi
1129 fi
1130
1131 dnl check if launchd is enabled
1132 if test x$have_launchd = xyes; then
1133     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1134 fi
1135
1136 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1137
1138 #### Directory to place launchd agent file
1139 if test "x$with_launchd_agent_dir" = "x"; then
1140    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1141 else
1142    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1143 fi
1144
1145 AC_SUBST(LAUNCHD_AGENT_DIR)
1146
1147 dnl console owner file
1148 if test x$enable_console_owner_file = xno ; then
1149     have_console_owner_file=no;
1150 else
1151     case $host_os in
1152     solaris*)
1153         have_console_owner_file=yes;
1154         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1155         ;;
1156     *)
1157         have_console_owner_file=no;;
1158     esac
1159 fi
1160
1161 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1162
1163 dnl systemd detection
1164 if test x$enable_systemd = xno ; then
1165     have_systemd=no;
1166 else
1167     PKG_CHECK_MODULES(SYSTEMD,
1168         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1169         have_systemd=yes,
1170         have_systemd=no)
1171 fi
1172
1173 if test x$have_systemd = xyes; then
1174     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1175 fi
1176
1177 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1178     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1179 fi
1180
1181 # libaudit detection
1182 if test x$enable_libaudit = xno ; then
1183     have_libaudit=no;
1184 else
1185     # See if we have audit daemon & capabilities library
1186     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1187                  have_libaudit=yes, have_libaudit=no)
1188     if test x$have_libaudit = xyes ; then
1189         AC_CHECK_LIB(cap-ng, capng_clear,
1190                  have_libaudit=yes, have_libaudit=no)
1191     fi
1192 fi
1193
1194 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1195
1196 if test x$have_libaudit = xyes ; then
1197     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1198     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1199 fi
1200
1201 AC_SUBST([SELINUX_LIBS])
1202
1203 # Check for ADT API (Solaris Basic Security Mode auditing)
1204 AC_MSG_CHECKING(for ADT API)
1205 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1206 #include <bsm/adt.h>
1207 adt_user_context = ADT_USER;
1208 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1209
1210 if test ${check_adt_audit} = yes
1211 then
1212    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1213    ADT_LIBS="-lbsm"
1214    LIBS="-lbsm $LIBS"
1215    AC_MSG_RESULT(yes)
1216 else
1217    AC_MSG_RESULT(no)
1218 fi
1219 AC_SUBST([ADT_LIBS])
1220
1221 # Check for SCM_RIGHTS
1222 AC_MSG_CHECKING([for SCM_RIGHTS])
1223 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1224 #include <sys/types.h>
1225 #include <sys/socket.h>
1226 #include <sys/un.h>
1227 static int x = SCM_RIGHTS;
1228 ]], [[]])],
1229 [ AC_MSG_RESULT([supported])
1230   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1231 [ AC_MSG_RESULT([not supported]) ])
1232
1233 NETWORK_libs=
1234 if test x$dbus_win = xyes ; then
1235   if test x$dbus_wince = xyes ; then
1236     NETWORK_libs="-lws2"
1237   else
1238     NETWORK_libs="-lws2_32"
1239   fi
1240 fi
1241
1242 AC_SUBST([NETWORK_libs])
1243
1244 AC_ARG_WITH([valgrind],
1245   [AS_HELP_STRING([--with-valgrind],
1246      [Add instrumentation to help valgrind to understand our allocator])],
1247   [],
1248   [with_valgrind=no])
1249
1250 if test x$with_valgrind != xno; then
1251   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1252   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1253 fi
1254
1255 #### Set up final flags
1256 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1257 AC_SUBST([LIBDBUS_LIBS])
1258
1259 ### X11 detection
1260 DBUS_X_LIBS=
1261 DBUS_X_CFLAGS=
1262
1263 AC_ARG_ENABLE([x11-autolaunch],
1264   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1265   [], [enable_x11_autolaunch=auto])
1266
1267 if test "x$dbus_win" = xyes; then
1268     if test "x$enable_x11_autolaunch" = xyes; then
1269         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1270     fi
1271
1272     enable_x11_autolaunch=no
1273     have_x11=no
1274 else
1275     AC_PATH_XTRA
1276
1277     if test "x$no_x" = xyes; then
1278         have_x11=no
1279     else
1280         have_x11=yes
1281         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1282         DBUS_X_CFLAGS="$X_CFLAGS"
1283     fi
1284 fi
1285
1286 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1287     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1288 else
1289     # move from "auto" to "yes" or "no" if necessary
1290     if test "x$enable_x11_autolaunch" != xno; then
1291         enable_x11_autolaunch="$have_x11"
1292     fi
1293 fi
1294
1295 if test "x$have_x11" = xyes ; then
1296    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1297 fi
1298
1299 if test "x$enable_x11_autolaunch" = xyes ; then
1300    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1301 fi
1302
1303 AC_SUBST([DBUS_X_CFLAGS])
1304 AC_SUBST([DBUS_X_LIBS])
1305
1306 #### gcc warning flags
1307
1308 cc_supports_flag() {
1309   AC_MSG_CHECKING(whether $CC supports "$*")
1310   save_CFLAGS="$CFLAGS"
1311   CFLAGS="$*"
1312   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1313   CFLAGS="$save_CFLAGS"
1314   AC_MSG_RESULT([$rc])
1315   test "x$rc" = xyes
1316 }
1317
1318 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1319   dnl Use -Werror by default if:
1320   dnl - we're not on Windows (too many warnings), and
1321   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1322   dnl Override with --enable-Werror or --disable-Werror
1323   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1324
1325   dnl Enable these warnings if possible:
1326   [all \
1327    extra \
1328    char-subscripts \
1329    missing-declarations \
1330    missing-prototypes \
1331    nested-externs \
1332    pointer-arith \
1333    cast-align \
1334    no-address \
1335    float-equal \
1336    declaration-after-statement \
1337   ],
1338
1339   dnl Disable these warnings if possible, make them non-fatal if possible,
1340   dnl and don't enable -Werror unless we succeeded.
1341   dnl
1342   dnl Intentional:
1343   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1344   dnl   checking or not asserting
1345   dnl - missing field initializers being 0 is a C feature, not a bug
1346   dnl - unused-parameter is to make writing callbacks less annoying
1347   dnl
1348   dnl To be fixed one day:
1349   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1350   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1351   dnl   is better than nothing
1352   [$DISABLE_UNUSED_WARNINGS \
1353    missing-field-initializers \
1354    unused-parameter \
1355    sign-compare \
1356    pointer-sign \
1357    type-limits \
1358   ])
1359
1360 if test "x$GCC" = "xyes"; then
1361   # We're treating -fno-common like a warning: it makes the linker more
1362   # strict, because on some systems the linker is *always* this strict
1363   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1364
1365   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1366   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1367
1368   if test "x$enable_ansi" = "xyes"; then
1369     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1370       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1371   fi
1372 fi
1373
1374 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1375 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1376 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1377 dnl is the next best thing
1378 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1379
1380 case $host_os in
1381     solaris*)
1382         # Solaris' C library apparently needs these runes to be threadsafe...
1383         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1384         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1385         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1386         # ... and this opt-in to get file descriptor passing support
1387         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1388         ;;
1389 esac
1390
1391 ### Doxygen Documentation
1392
1393 AC_PATH_PROG(DOXYGEN, doxygen, no)
1394
1395 AC_MSG_CHECKING([whether to build Doxygen documentation])
1396
1397 if test x$DOXYGEN = xno ; then
1398     have_doxygen=no
1399 else
1400     have_doxygen=yes
1401 fi
1402
1403 if test x$enable_doxygen_docs = xauto ; then
1404     if test x$have_doxygen = xno ; then
1405         enable_doxygen_docs=no
1406     else
1407         enable_doxygen_docs=yes
1408     fi
1409 fi
1410
1411 if test x$enable_doxygen_docs = xyes; then
1412     if test x$have_doxygen = xno; then
1413         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1414     fi
1415 fi
1416
1417 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1418 AC_MSG_RESULT($enable_doxygen_docs)
1419
1420 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1421 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1422
1423 ### XML Documentation
1424
1425 AC_PATH_PROG(XMLTO, xmlto, no)
1426
1427 AC_MSG_CHECKING([whether to build XML documentation])
1428
1429 if test x$XMLTO = xno ; then
1430     have_xmlto=no
1431 else
1432     have_xmlto=yes
1433 fi
1434
1435 if test x$enable_xml_docs = xauto ; then
1436     if test x$have_xmlto = xno ; then
1437         enable_xml_docs=no
1438     else
1439         enable_xml_docs=yes
1440     fi
1441 fi
1442
1443 if test x$enable_xml_docs = xyes; then
1444     if test x$have_xmlto = xno; then
1445         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1446     fi
1447 fi
1448
1449 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1450 AC_MSG_RESULT($enable_xml_docs)
1451
1452 AC_PATH_PROG([MAN2HTML], [man2html])
1453 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1454 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1455
1456 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1457     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1458          x$MAN2HTML != x)
1459
1460 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1461
1462 #### find the actual value for $prefix that we'll end up with
1463 ##   (I know this is broken and should be done in the Makefile, but
1464 ##    that's a major pain and almost nobody actually seems to care)
1465 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1466 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1467 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1468 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1469 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1470 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1471 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1472
1473 #### Check our operating system
1474 operating_system=unknown
1475 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1476    operating_system=redhat
1477 fi
1478
1479 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1480    operating_system=slackware
1481 fi
1482
1483 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1484    operating_system=cygwin
1485 fi
1486
1487 #### Sort out init scripts
1488
1489 if test x$with_init_scripts = x; then
1490     case x$operating_system in
1491         xredhat)        with_init_scripts=redhat ;;
1492         xslackware)     with_init_scripts=slackware ;;
1493         xcygwin)        with_init_scripts=cygwin ;;
1494         *)                      with_init_scripts=none ;;
1495     esac
1496 fi
1497
1498 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1499 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1500 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1501
1502 ##### systemd unit files
1503 AC_ARG_WITH([systemdsystemunitdir],
1504 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1505     [],
1506     [
1507     PKG_CHECK_EXISTS([systemd],
1508       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1509       [with_systemdsystemunitdir=no])
1510     ])
1511 if test "x$with_systemdsystemunitdir" != xno; then
1512    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1513 fi
1514 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1515
1516 ##### Set up location for system bus socket
1517 if ! test -z "$with_system_socket"; then
1518    DBUS_SYSTEM_SOCKET=$with_system_socket
1519 else
1520    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1521 fi
1522
1523 AC_SUBST(DBUS_SYSTEM_SOCKET)
1524 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1525
1526 ## system bus only listens on local domain sockets, and never
1527 ## on an abstract socket (so only root can create the socket)
1528 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1529 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1530 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1531
1532 #### Set up the pid file
1533 if ! test -z "$with_system_pid_file"; then
1534    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1535 elif test x$with_init_scripts = xredhat ; then
1536    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1537 else
1538    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1539 fi
1540
1541 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1542
1543 #### Directory to check for console ownership
1544 if ! test -z "$with_console_auth_dir"; then
1545    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1546 else
1547    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1548 fi
1549
1550 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1551 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1552
1553 #### File to check for console ownership
1554 if test x$have_console_owner_file = xyes; then
1555    if ! test -z "$with_console_owner_file"; then
1556       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1557    else
1558       DBUS_CONSOLE_OWNER_FILE=/dev/console
1559    fi
1560 else
1561   DBUS_CONSOLE_OWNER_FILE=
1562 fi
1563
1564 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1565 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1566
1567 #### User to start the system bus as
1568 if test -z "$with_dbus_user" ; then
1569     DBUS_USER=messagebus
1570 else
1571     DBUS_USER=$with_dbus_user
1572 fi
1573 AC_SUBST(DBUS_USER)
1574 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1575
1576 #### Prefix to install into
1577 DBUS_PREFIX=$EXPANDED_PREFIX
1578 AC_SUBST(DBUS_PREFIX)
1579 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1580
1581 #### Direcotry to install data files into
1582 DBUS_DATADIR=$EXPANDED_DATADIR
1583 AC_SUBST(DBUS_DATADIR)
1584 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1585
1586 #### Directory to install dbus-daemon
1587 if test -z "$with_dbus_daemondir" ; then
1588     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1589 else
1590     DBUS_DAEMONDIR=$with_dbus_daemondir
1591 fi
1592 AC_SUBST(DBUS_DAEMONDIR)
1593 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1594
1595 #### Directory to install the other binaries
1596 DBUS_BINDIR="$EXPANDED_BINDIR"
1597 AC_SUBST(DBUS_BINDIR)
1598 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1599
1600 #### Directory to install the libexec binaries
1601 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1602 AC_SUBST(DBUS_LIBEXECDIR)
1603 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1604
1605 #### Tell tests where to find certain stuff in builddir
1606
1607 DBUS_PWD=`pwd`
1608 # Useful in a cross-compilation environment, where the tests are run on the host system.
1609 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1610                            DBUS_PWD=$withval)
1611
1612 DBUS_TEST_EXEC="$DBUS_PWD/test"
1613 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1614
1615 AC_SUBST([DBUS_TEST_DATA])
1616 AC_SUBST([DBUS_TEST_EXEC])
1617
1618 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1619                    [Full path to the daemon in the builddir])
1620 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1621                    [Extension for executables, typically empty or .exe])
1622
1623 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1624                    [Full path to the daemon in the builddir])
1625 AC_SUBST(TEST_BUS_BINARY)
1626
1627 ## Export the non-setuid external helper
1628 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1629 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1630 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1631                    [Full path to the launch helper test program in the builddir])
1632
1633 #### Find socket directories
1634 if ! test -z "$TMPDIR" ; then
1635    DEFAULT_SOCKET_DIR=$TMPDIR
1636 elif ! test -z "$TEMP" ; then
1637    DEFAULT_SOCKET_DIR=$TEMP
1638 elif ! test -z "$TMP" ; then
1639    DEFAULT_SOCKET_DIR=$TMP
1640 else
1641    DEFAULT_SOCKET_DIR=/tmp
1642 fi
1643
1644 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1645
1646 if ! test -z "$with_test_socket_dir" ; then
1647    TEST_SOCKET_DIR="$with_test_socket_dir"
1648 else
1649    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1650 fi
1651 AC_SUBST(TEST_SOCKET_DIR)
1652 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1653
1654 if test "x$dbus_unix" = xyes; then
1655   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1656 else
1657   TEST_LISTEN="tcp:host=localhost"
1658 fi
1659 AC_SUBST([TEST_LISTEN])
1660 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1661   [Listening address for regression tests])
1662
1663 if ! test -z "$with_session_socket_dir" ; then
1664    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1665 else
1666    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1667 fi
1668 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1669 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1670
1671 if test x$dbus_win = xyes; then
1672         DBUS_SESSION_BUS_DEFAULT_ADDRESS="$with_dbus_session_bus_default_address"
1673 elif test x$have_launchd = xyes; then
1674         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1675 else
1676         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1677 fi
1678 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1679
1680 # darwin needs this to initialize the environment
1681 AC_CHECK_HEADERS(crt_externs.h)
1682 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1683 AH_VERBATIM(_DARWIN_ENVIRON,
1684 [
1685 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1686 # include <sys/time.h>
1687 # include <crt_externs.h>
1688 # define environ (*_NSGetEnviron())
1689 #endif
1690 ])
1691
1692 AC_ARG_ENABLE([stats],
1693   [AS_HELP_STRING([--enable-stats],
1694     [enable bus daemon usage statistics])],
1695   [], [enable_stats=no])
1696 if test "x$enable_stats" = xyes; then
1697   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1698     [Define to enable bus daemon usage statistics])
1699 fi
1700
1701 AC_CONFIG_FILES([
1702 Doxyfile
1703 dbus/versioninfo.rc
1704 dbus/dbus-arch-deps.h
1705 bus/system.conf
1706 bus/session.conf
1707 bus/messagebus
1708 bus/messagebus-config
1709 bus/org.freedesktop.dbus-session.plist
1710 bus/rc.messagebus
1711 bus/dbus.service
1712 bus/dbus.socket
1713 Makefile
1714 dbus/Makefile
1715 bus/Makefile
1716 tools/Makefile
1717 test/Makefile
1718 test/name-test/Makefile
1719 doc/Makefile
1720 doc/dbus-daemon.1
1721 dbus-1.pc
1722 dbus-1-uninstalled.pc
1723 test/data/valid-config-files/debug-allow-all.conf
1724 test/data/valid-config-files/debug-allow-all-sha1.conf
1725 test/data/valid-config-files-system/debug-allow-all-pass.conf
1726 test/data/valid-config-files-system/debug-allow-all-fail.conf
1727 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1728 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1729 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1730 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1731 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1732 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1733 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1734 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1735 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1736 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1737 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1738 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1739 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1740 ])
1741 AC_OUTPUT
1742
1743 dnl ==========================================================================
1744 echo "
1745                     D-Bus $VERSION
1746                   ==============
1747
1748         prefix:                   ${EXPANDED_PREFIX}
1749         exec_prefix:              ${exec_prefix}
1750         libdir:                   ${EXPANDED_LIBDIR}
1751         libexecdir:               ${EXPANDED_LIBEXECDIR}
1752         bindir:                   ${EXPANDED_BINDIR}
1753         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1754         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1755         datadir:                  ${EXPANDED_DATADIR}
1756         source code location:     ${srcdir}
1757         compiler:                 ${CC}
1758         cflags:                   ${CFLAGS}
1759         cppflags:                 ${CPPFLAGS}
1760         cxxflags:                 ${CXXFLAGS}
1761         64-bit int:               ${DBUS_INT64_TYPE}
1762         32-bit int:               ${DBUS_INT32_TYPE}
1763         16-bit int:               ${DBUS_INT16_TYPE}
1764         Doxygen:                  ${DOXYGEN:-not found}
1765         xmlto:                    ${XMLTO:-not found}
1766         man2html:                 ${MAN2HTML:-not found}"
1767
1768 echo "
1769         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1770         gcc coverage profiling:   ${enable_compiler_coverage}
1771         Building embedded tests:  ${enable_embedded_tests}
1772         Building modular tests:   ${enable_modular_tests}
1773             - with GLib:          ${with_glib}
1774         Building verbose mode:    ${enable_verbose_mode}
1775         Building assertions:      ${enable_asserts}
1776         Building checks:          ${enable_checks}
1777         Building bus stats API:   ${enable_stats}
1778         Building SELinux support: ${have_selinux}
1779         Building inotify support: ${have_inotify}
1780         Building dnotify support: ${have_dnotify}
1781         Building kqueue support:  ${have_kqueue}
1782         Building systemd support: ${have_systemd}
1783         Building X11 code:        ${enable_x11}
1784         Building Doxygen docs:    ${enable_doxygen_docs}
1785         Building XML docs:        ${enable_xml_docs}
1786         Building cache support:   ${enable_userdb_cache}
1787         Building launchd support: ${have_launchd}
1788         Using XML parser:         ${with_xml}
1789         Init scripts style:       ${with_init_scripts}
1790         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1791         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1792         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1793         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1794         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1795         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1796         Console owner file:       ${have_console_owner_file}
1797         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1798         System bus user:          ${DBUS_USER}
1799         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1800         'make check' socket dir:  ${TEST_SOCKET_DIR}
1801 "
1802 if test x$have_launchd = xyes; then
1803         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1804 fi
1805 echo
1806
1807 if test x$enable_embedded_tests = xyes; then
1808         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1809 fi
1810 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1811         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1812 fi
1813 if test x$enable_compiler_coverage = xyes; then
1814         echo "NOTE: building with coverage profiling is definitely for developers only."
1815 fi
1816 if test x$enable_verbose_mode = xyes; then
1817         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1818 fi
1819 if test x$enable_asserts = xyes; then
1820         echo "NOTE: building with assertions increases library size and decreases performance."
1821 fi
1822 if test x$enable_checks = xno; then
1823         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1824 fi
1825 if test x$dbus_use_libxml = xtrue; then
1826         echo
1827         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1828 fi
1829
1830 if test "x$DBUS_HAVE_INT64" = x0; then
1831   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1832
1833   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1834   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1835   used if your compiler lacks support for 64-bit integers. Please report a bug
1836   with details of your platform and compiler.
1837
1838   This option is likely to be removed in future, unless the D-Bus developers
1839   receive reports that it is still needed.
1840   ])
1841 fi