projects/checksrc.bat

   1 @echo off
   2 rem ***************************************************************************
   3 rem *                                  _   _ ____  _
   4 rem *  Project                     ___| | | |  _ \| |
   5 rem *                             / __| | | | |_) | |
   6 rem *                            | (__| |_| |  _ <| |___
   7 rem *                             \___|\___/|_| \_\_____|
   8 rem *
   9 rem * Copyright (C) 2014 - 2015, Steve Holme, <steve_holme@hotmail.com>.
  10 rem *
  11 rem * This software is licensed as described in the file COPYING, which
  12 rem * you should have received as part of this distribution. The terms
  13 rem * are also available at http://curl.haxx.se/docs/copyright.html.
  14 rem *
  15 rem * You may opt to use, copy, modify, merge, publish, distribute and/or sell
  16 rem * copies of the Software, and permit persons to whom the Software is
  17 rem * furnished to do so, under the terms of the COPYING file.
  18 rem *
  19 rem * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
  20 rem * KIND, either express or implied.
  21 rem *
  22 rem ***************************************************************************
  23
  24 :begin
  25   rem Check we are running on a Windows NT derived OS
  26   if not "%OS%" == "Windows_NT" goto nodos
  27   setlocal
  28
  29   rem Display the help
  30   if /i "%~1" == "-?" goto syntax
  31   if /i "%~1" == "-h" goto syntax
  32   if /i "%~1" == "-help" goto syntax
  33
  34 :prerequisites
  35   rem Check we have Perl installed
  36   echo %PATH% | findstr /I /C:"\Perl" 1>nul
  37   if errorlevel 1 (
  38     if not exist "%SystemDrive%\Perl" (
  39       if not exist "%SystemDrive%\Perl64" goto noperl
  40     )
  41   )
  42
  43 :configure
  44   if "%1" == "" set SRC_DIR=..
  45   if not "%1" == "" set SRC_DIR=%~1%
  46   if not exist "%SRC_DIR%" goto nosrc
  47
  48 :start
  49   for /f "delims=" %%i in ('dir %SRC_DIR%\src\*.c.* /b') do @perl %SRC_DIR%\lib\checksrc.pl -D%SRC_DIR%\src "%%i"
  50   for /f "delims=" %%i in ('dir %SRC_DIR%\src\*.h.* /b') do @perl %SRC_DIR%\lib\checksrc.pl -D%SRC_DIR%\src "%%i"
  51   for /f "delims=" %%i in ('dir %SRC_DIR%\lib\*.c.* /b') do @perl %SRC_DIR%\lib\checksrc.pl -D%SRC_DIR%\lib "%%i"
  52   for /f "delims=" %%i in ('dir %SRC_DIR%\lib\*.h.* /b') do @perl %SRC_DIR%\lib\checksrc.pl -D%SRC_DIR%\lib -Wcurl_config.h.cmake "%%i"
  53   goto success
  54
  55 :syntax
  56   rem Display the help
  57   echo.
  58   echo Usage: checksrc [directory]
  59   echo.
  60   echo directory - Specifies the curl source directory
  61   goto success
  62
  63 :nodos
  64   echo.
  65   echo Error: Only a Windows NT based Operating System is supported
  66   goto error
  67
  68 :noperl
  69   echo.
  70   echo Error: Perl is not installed
  71   goto error
  72
  73 :nosrc
  74   echo.
  75   echo Error: "%SRC_DIR%" does not exist
  76   goto error
  77
  78 :error
  79   if "%OS%" == "Windows_NT" endlocal
  80   exit /B 1
  81
  82 :success
  83   endlocal
  84   exit /B 0