lib/mk-ca-bundle.vbs

   1 '***************************************************************************\r
   2 '*                                  _   _ ____  _\r
   3 '*  Project                     ___| | | |  _ \| |\r
   4 '*                             / __| | | | |_) | |\r
   5 '*                            | (__| |_| |  _ <| |___\r
   6 '*                             \___|\___/|_| \_\_____|\r
   7 '*\r
   8 '* Copyright (C) 1998 - 2013, Daniel Stenberg, <daniel@haxx.se>, et al.\r
   9 '*\r
  10 '* This software is licensed as described in the file COPYING, which\r
  11 '* you should have received as part of this distribution. The terms\r
  12 '* are also available at http://curl.haxx.se/docs/copyright.html.\r
  13 '*\r
  14 '* You may opt to use, copy, modify, merge, publish, distribute and/or sell\r
  15 '* copies of the Software, and permit persons to whom the Software is\r
  16 '* furnished to do so, under the terms of the COPYING file.\r
  17 '*\r
  18 '* This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY\r
  19 '* KIND, either express or implied.\r
  20 '*\r
  21 '***************************************************************************\r
  22 '* Script to fetch certdata.txt from Mozilla.org site and create a\r
  23 '* ca-bundle.crt for use with OpenSSL / libcurl / libcurl bindings\r
  24 '* Requires WinHttp.WinHttpRequest.5.1 and ADODB.Stream which are part of\r
  25 '* W2000 SP3 or later, WXP SP1 or later, W2003 Server SP1 or later.\r
  26 '* Hacked by Guenter Knauf\r
  27 '***************************************************************************\r
  28 Option Explicit\r
  29 Const myVersion = "0.3.8"\r
  30 \r
  31 Const myUrl = "http://mxr.mozilla.org/mozilla/source/security/nss/lib/ckfw/builtins/certdata.txt?raw=1"\r
  32 \r
  33 Const myOpenssl = "openssl.exe"\r
  34 \r
  35 Const myCdSavF = FALSE       ' Flag: save downloaded data to file certdata.txt\r
  36 Const myCaBakF = TRUE        ' Flag: backup existing ca-bundle certificate\r
  37 Const myAskLiF = TRUE        ' Flag: display certdata.txt license agreement\r
  38 Const myAskTiF = TRUE        ' Flag: ask to include certificate text info\r
  39 Const myWrapLe = 76          ' Default length of base64 output lines\r
  40 \r
  41 '******************* Nothing to configure below! *******************\r
  42 Dim objShell, objNetwork, objFSO, objHttp\r
  43 Dim myBase, mySelf, myFh, myTmpFh, myCdData, myCdFile, myCaFile, myTmpName, myBakNum, myOptTxt, i\r
  44 Set objNetwork = WScript.CreateObject("WScript.Network")\r
  45 Set objShell = WScript.CreateObject("WScript.Shell")\r
  46 Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")\r
  47 Set objHttp = WScript.CreateObject("WinHttp.WinHttpRequest.5.1")\r
  48 If objHttp Is Nothing Then Set objHttp = WScript.CreateObject("WinHttp.WinHttpRequest")\r
  49 myBase = Left(WScript.ScriptFullName, InstrRev(WScript.ScriptFullName, "\"))\r
  50 mySelf = Left(WScript.ScriptName, InstrRev(WScript.ScriptName, ".") - 1) & " " & myVersion\r
  51 myCdFile = Mid(myUrl, InstrRev(myUrl, "/") + 1, InstrRev(myUrl, "?") - InstrRev(myUrl, "/") - 1)\r
  52 myCaFile = "ca-bundle.crt"\r
  53 myTmpName = InputBox("Enter output filename:", mySelf, myCaFile)\r
  54 If Not (myTmpName = "") Then\r
  55   myCaFile = myTmpName\r
  56 End If\r
  57 ' Lets ignore SSL invalid cert errors\r
  58 objHttp.Option(4) = 256 + 512 + 4096 + 8192\r
  59 objHttp.SetTimeouts 0, 5000, 10000, 10000\r
  60 objHttp.Open "GET", myUrl, FALSE\r
  61 objHttp.setRequestHeader "User-Agent", WScript.ScriptName & "/" & myVersion\r
  62 objHttp.Send ""\r
  63 If Not (objHttp.statusText = "OK") Then\r
  64   MsgBox("Failed to download '" & myCdFile & "': " & objHttp.statusText), vbCritical, mySelf\r
  65   WScript.Quit 1\r
  66 End If\r
  67 ' Convert data from ResponseBody instead of using ResponseText because of UTF-8\r
  68 myCdData = ConvertBinaryData(objHttp.ResponseBody)\r
  69 Set objHttp = Nothing\r
  70 ' Write received data to file if enabled\r
  71 If (myCdSavF = TRUE) Then\r
  72   Set myFh = objFSO.OpenTextFile(myCdFile, 2, TRUE)\r
  73   myFh.Write myCdData\r
  74   myFh.Close\r
  75 End If\r
  76 ' Backup exitsing ca-bundle certificate file\r
  77 If (myCaBakF = TRUE) Then\r
  78   If objFSO.FileExists(myCaFile) Then\r
  79     Dim myBakFile, b\r
  80     b = 1\r
  81     myBakFile = myCaFile & ".~" & b & "~"\r
  82     While objFSO.FileExists(myBakFile)\r
  83       b = b + 1\r
  84       myBakFile = myCaFile & ".~" & b & "~"\r
  85     Wend\r
  86     Set myTmpFh = objFSO.GetFile(myCaFile)\r
  87     myTmpFh.Move myBakFile\r
  88   End If\r
  89 End If\r
  90 If (myAskTiF = TRUE) Then\r
  91   If (6 = objShell.PopUp("Do you want to include text information about each certificate?" & vbLf & _\r
  92           "(requires OpenSSL commandline in current directory or in search path)",, _\r
  93           mySelf, vbQuestion + vbYesNo + vbDefaultButton2)) Then\r
  94     myOptTxt = TRUE\r
  95   Else\r
  96     myOptTxt = FALSE\r
  97   End If\r
  98 End If\r
  99 ' Process the received data\r
 100 Dim myLines, myPattern, myInsideCert, myInsideLicense, myLicenseText, myNumCerts, myNumSkipped\r
 101 Dim myLabel, myOctets, myData, myPem, myRev, myUntrusted, j\r
 102 myNumSkipped = 0\r
 103 myNumCerts = 0\r
 104 myData = ""\r
 105 myLines = Split(myCdData, vbLf, -1)\r
 106 Set myFh = objFSO.OpenTextFile(myCaFile, 2, TRUE)\r
 107 myFh.Write "##" & vbLf\r
 108 myFh.Write "## " & myCaFile & " -- Bundle of CA Root Certificates" & vbLf\r
 109 myFh.Write "##" & vbLf\r
 110 myFh.Write "## Converted at: " & Now & vbLf\r
 111 myFh.Write "##" & vbLf\r
 112 myFh.Write "## This is a bundle of X.509 certificates of public Certificate Authorities" & vbLf\r
 113 myFh.Write "## (CA). These were automatically extracted from Mozilla's root certificates" & vbLf\r
 114 myFh.Write "## file (certdata.txt).  This file can be found in the mozilla source tree:" & vbLf\r
 115 myFh.Write "## '/mozilla/source/security/nss/lib/ckfw/builtins/certdata.txt'" & vbLf\r
 116 myFh.Write "##" & vbLf\r
 117 myFh.Write "## It contains the certificates in PEM format and therefore" & vbLf\r
 118 myFh.Write "## can be directly used with curl / libcurl / php_curl, or with" & vbLf\r
 119 myFh.Write "## an Apache+mod_ssl webserver for SSL client authentication." & vbLf\r
 120 myFh.Write "## Just configure this file as the SSLCACertificateFile." & vbLf\r
 121 myFh.Write "##" & vbLf\r
 122 myFh.Write vbLf\r
 123 For i = 0 To UBound(myLines)\r
 124   If InstrRev(myLines(i), "CKA_LABEL ") Then\r
 125     myPattern = "^CKA_LABEL\s+[A-Z0-9]+\s+""(.+?)"""\r
 126     myLabel = RegExprFirst(myPattern, myLines(i))\r
 127   End If\r
 128   If (myInsideCert = TRUE) Then\r
 129     If InstrRev(myLines(i), "END") Then\r
 130       myInsideCert = FALSE\r
 131       While (i < UBound(myLines)) And Not (myLines(i) = "#")\r
 132         i = i + 1\r
 133         If InstrRev(myLines(i), "CKA_TRUST_SERVER_AUTH CK_TRUST CKT_NSS_TRUSTED_DELEGATOR") Then\r
 134           myUntrusted = FALSE\r
 135         End If\r
 136       Wend\r
 137       If (myUntrusted = TRUE) Then\r
 138         myNumSkipped = myNumSkipped + 1\r
 139       Else\r
 140         myFh.Write myLabel & vbLf\r
 141         myFh.Write String(Len(myLabel), "=") & vbLf\r
 142         myPem = "-----BEGIN CERTIFICATE-----" & vbLf & _\r
 143                 Base64Encode(myData) & vbLf & _\r
 144                 "-----END CERTIFICATE-----" & vbLf\r
 145         If (myOptTxt = FALSE) Then\r
 146           myFh.Write myPem & vbLf\r
 147         Else\r
 148           Dim myCmd, myRval, myTmpIn, myTmpOut\r
 149           myTmpIn = objFSO.GetSpecialFolder(2).Path & "\" & objFSO.GetTempName\r
 150           myTmpOut = objFSO.GetSpecialFolder(2).Path & "\" & objFSO.GetTempName\r
 151           Set myTmpFh = objFSO.OpenTextFile(myTmpIn, 2, TRUE)\r
 152           myTmpFh.Write myPem\r
 153           myTmpFh.Close\r
 154           myCmd = myOpenssl & " x509 -md5 -fingerprint -text -inform PEM" & _\r
 155                   " -in " & myTmpIn & " -out " & myTmpOut\r
 156           myRval = objShell.Run (myCmd, 0, TRUE)\r
 157           objFSO.DeleteFile myTmpIn, TRUE\r
 158           If Not (myRval = 0) Then\r
 159             MsgBox("Failed to process PEM cert with OpenSSL commandline!"), vbCritical, mySelf\r
 160             objFSO.DeleteFile myTmpOut, TRUE\r
 161             WScript.Quit 3\r
 162           End If\r
 163           Set myTmpFh = objFSO.OpenTextFile(myTmpOut, 1)\r
 164           myFh.Write myTmpFh.ReadAll & vbLf\r
 165           myTmpFh.Close\r
 166           objFSO.DeleteFile myTmpOut, TRUE\r
 167         End If\r
 168         myNumCerts = myNumCerts + 1\r
 169       End If\r
 170     Else\r
 171       myOctets = Split(myLines(i), "\")\r
 172       For j = 1 To UBound(myOctets)\r
 173         myData = myData & Chr(CByte("&o" & myOctets(j)))\r
 174       Next\r
 175     End If\r
 176   End If\r
 177   If InstrRev(myLines(i), "CVS_ID ") Then\r
 178     myPattern = "^CVS_ID\s+""(.+?)"""\r
 179     myRev = RegExprFirst(myPattern, myLines(i))\r
 180     myFh.Write "# " & myRev & vbLf & vbLf\r
 181   End If\r
 182   If InstrRev(myLines(i), "CKA_VALUE MULTILINE_OCTAL") Then\r
 183     myInsideCert = TRUE\r
 184     myUntrusted = TRUE\r
 185     myData = ""\r
 186   End If\r
 187   If InstrRev(myLines(i), "***** BEGIN LICENSE BLOCK *****") Then\r
 188     myInsideLicense = TRUE\r
 189   End If\r
 190   If (myInsideLicense = TRUE) Then\r
 191     myFh.Write myLines(i) & vbLf\r
 192     myLicenseText = myLicenseText & Mid(myLines(i), 2) & vbLf\r
 193   End If\r
 194   If InstrRev(myLines(i), "***** END LICENSE BLOCK *****") Then\r
 195     myInsideLicense = FALSE\r
 196     If (myAskLiF = TRUE) Then\r
 197       If Not (6 = objShell.PopUp(myLicenseText & vbLf & _\r
 198               "Do you agree to the license shown above (required to proceed) ?",, _\r
 199               mySelf, vbQuestion + vbYesNo + vbDefaultButton1)) Then\r
 200         myFh.Close\r
 201         objFSO.DeleteFile myCaFile, TRUE\r
 202         WScript.Quit 2\r
 203       End If\r
 204     End If\r
 205   End If\r
 206 Next\r
 207 myFh.Close\r
 208 objShell.PopUp "Done (" & myNumCerts & " CA certs processed, " & myNumSkipped & _\r
 209                " untrusted skipped).", 20, mySelf, vbInformation\r
 210 WScript.Quit 0\r
 211 \r
 212 Function ConvertBinaryData(arrBytes)\r
 213   Dim objStream\r
 214   Set objStream = CreateObject("ADODB.Stream")\r
 215   objStream.Open\r
 216   objStream.Type = 1\r
 217   objStream.Write arrBytes\r
 218   objStream.Position = 0\r
 219   objStream.Type = 2\r
 220   objStream.Charset = "ascii"\r
 221   ConvertBinaryData = objStream.ReadText\r
 222   Set objStream = Nothing\r
 223 End Function\r
 224 \r
 225 Function RegExprFirst(SearchPattern, TheString)\r
 226   Dim objRegExp, Matches                        ' create variables.\r
 227   Set objRegExp = New RegExp                    ' create a regular expression.\r
 228   objRegExp.Pattern = SearchPattern             ' sets the search pattern.\r
 229   objRegExp.IgnoreCase = TRUE                   ' set to ignores case.\r
 230   objRegExp.Global = TRUE                       ' set to gloabal search.\r
 231   Set Matches = objRegExp.Execute(TheString)    ' do the search.\r
 232   If (Matches.Count) Then\r
 233     RegExprFirst = Matches(0).SubMatches(0)     ' return first match.\r
 234   Else\r
 235     RegExprFirst = ""\r
 236   End If\r
 237   Set objRegExp = Nothing\r
 238 End Function\r
 239 \r
 240 Function Base64Encode(inData)\r
 241   Const Base64 = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"\r
 242   Dim cOut, sOut, lWrap, I\r
 243   lWrap = Int(myWrapLe * 3 / 4)\r
 244 \r
 245   'For each group of 3 bytes\r
 246   For I = 1 To Len(inData) Step 3\r
 247     Dim nGroup, pOut, sGroup\r
 248 \r
 249     'Create one long from this 3 bytes.\r
 250     nGroup = &H10000 * Asc(Mid(inData, I, 1)) + _\r
 251              &H100 * MyASC(Mid(inData, I + 1, 1)) + _\r
 252              MyASC(Mid(inData, I + 2, 1))\r
 253 \r
 254     'Oct splits the long To 8 groups with 3 bits\r
 255     nGroup = Oct(nGroup)\r
 256 \r
 257     'Add leading zeros\r
 258     nGroup = String(8 - Len(nGroup), "0") & nGroup\r
 259 \r
 260     'Convert To base64\r
 261     pOut = Mid(Base64, CLng("&o" & Mid(nGroup, 1, 2)) + 1, 1) & _\r
 262            Mid(Base64, CLng("&o" & Mid(nGroup, 3, 2)) + 1, 1) & _\r
 263            Mid(Base64, CLng("&o" & Mid(nGroup, 5, 2)) + 1, 1) & _\r
 264            Mid(Base64, CLng("&o" & Mid(nGroup, 7, 2)) + 1, 1)\r
 265 \r
 266     'Add the part To OutPut string\r
 267     sOut = sOut + pOut\r
 268 \r
 269     'Add a new line For Each myWrapLe chars In dest\r
 270     If (I < Len(inData) - 2) Then\r
 271       If (I + 2) Mod lWrap = 0 Then sOut = sOut & vbLf\r
 272     End If\r
 273   Next\r
 274   Select Case Len(inData) Mod 3\r
 275     Case 1: '8 bit final\r
 276       sOut = Left(sOut, Len(sOut) - 2) & "=="\r
 277     Case 2: '16 bit final\r
 278       sOut = Left(sOut, Len(sOut) - 1) & "="\r
 279   End Select\r
 280   Base64Encode = sOut\r
 281 End Function\r
 282 \r
 283 Function MyASC(OneChar)\r
 284   If OneChar = "" Then MyASC = 0 Else MyASC = Asc(OneChar)\r
 285 End Function\r
 286 \r
 287 \r