lib/mk-ca-bundle.pl

   1 #!/usr/bin/perl -w
   2 # ***************************************************************************
   3 # *                                  _   _ ____  _
   4 # *  Project                     ___| | | |  _ \| |
   5 # *                             / __| | | | |_) | |
   6 # *                            | (__| |_| |  _ <| |___
   7 # *                             \___|\___/|_| \_\_____|
   8 # *
   9 # * Copyright (C) 1998 - 2014, Daniel Stenberg, <daniel@haxx.se>, et al.
  10 # *
  11 # * This software is licensed as described in the file COPYING, which
  12 # * you should have received as part of this distribution. The terms
  13 # * are also available at http://curl.haxx.se/docs/copyright.html.
  14 # *
  15 # * You may opt to use, copy, modify, merge, publish, distribute and/or sell
  16 # * copies of the Software, and permit persons to whom the Software is
  17 # * furnished to do so, under the terms of the COPYING file.
  18 # *
  19 # * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
  20 # * KIND, either express or implied.
  21 # *
  22 # ***************************************************************************
  23 # This Perl script creates a fresh ca-bundle.crt file for use with libcurl.
  24 # It downloads certdata.txt from Mozilla's source tree (see URL below),
  25 # then parses certdata.txt and extracts CA Root Certificates into PEM format.
  26 # These are then processed with the OpenSSL commandline tool to produce the
  27 # final ca-bundle.crt file.
  28 # The script is based on the parse-certs script written by Roland Krikava.
  29 # This Perl script works on almost any platform since its only external
  30 # dependency is the OpenSSL commandline tool for optional text listing.
  31 # Hacked by Guenter Knauf.
  32 #
  33 use Getopt::Std;
  34 use MIME::Base64;
  35 use LWP::UserAgent;
  36 use strict;
  37 use vars qw($opt_b $opt_d $opt_f $opt_h $opt_i $opt_l $opt_n $opt_p $opt_q $opt_s $opt_t $opt_u $opt_v $opt_w);
  38 use List::Util;
  39 use Text::Wrap;
  40 my $MOD_SHA = "Digest::SHA";
  41 eval "require $MOD_SHA";
  42 if ($@) {
  43   $MOD_SHA = "Digest::SHA::PurePerl";
  44   eval "require $MOD_SHA";
  45 }
  46
  47 my %urls = (
  48   'nss' =>
  49     'http://hg.mozilla.org/projects/nss/raw-file/tip/lib/ckfw/builtins/certdata.txt',
  50   'central' =>
  51     'http://hg.mozilla.org/mozilla-central/raw-file/default/security/nss/lib/ckfw/builtins/certdata.txt',
  52   'aurora' =>
  53     'http://hg.mozilla.org/releases/mozilla-aurora/raw-file/default/security/nss/lib/ckfw/builtins/certdata.txt',
  54   'beta' =>
  55     'http://hg.mozilla.org/releases/mozilla-beta/raw-file/default/security/nss/lib/ckfw/builtins/certdata.txt',
  56   'release' =>
  57     'http://hg.mozilla.org/releases/mozilla-release/raw-file/default/security/nss/lib/ckfw/builtins/certdata.txt',
  58 );
  59
  60 $opt_d = 'release';
  61
  62 # If the OpenSSL commandline is not in search path you can configure it here!
  63 my $openssl = 'openssl';
  64
  65 my $version = '1.25';
  66
  67 $opt_w = 76; # default base64 encoded lines length
  68
  69 # default cert types to include in the output (default is to include CAs which may issue SSL server certs)
  70 my $default_mozilla_trust_purposes = "SERVER_AUTH";
  71 my $default_mozilla_trust_levels = "TRUSTED_DELEGATOR";
  72 $opt_p = $default_mozilla_trust_purposes . ":" . $default_mozilla_trust_levels;
  73
  74 my @valid_mozilla_trust_purposes = (
  75   "DIGITAL_SIGNATURE",
  76   "NON_REPUDIATION",
  77   "KEY_ENCIPHERMENT",
  78   "DATA_ENCIPHERMENT",
  79   "KEY_AGREEMENT",
  80   "KEY_CERT_SIGN",
  81   "CRL_SIGN",
  82   "SERVER_AUTH",
  83   "CLIENT_AUTH",
  84   "CODE_SIGNING",
  85   "EMAIL_PROTECTION",
  86   "IPSEC_END_SYSTEM",
  87   "IPSEC_TUNNEL",
  88   "IPSEC_USER",
  89   "TIME_STAMPING",
  90   "STEP_UP_APPROVED"
  91 );
  92
  93 my @valid_mozilla_trust_levels = (
  94   "TRUSTED_DELEGATOR",    # CAs
  95   "NOT_TRUSTED",          # Don't trust these certs.
  96   "MUST_VERIFY_TRUST",    # This explicitly tells us that it ISN'T a CA but is otherwise ok. In other words, this should tell the app to ignore any other sources that claim this is a CA.
  97   "TRUSTED"               # This cert is trusted, but only for itself and not for delegates (i.e. it is not a CA).
  98 );
  99
 100 my $default_signature_algorithms = $opt_s = "MD5";
 101
 102 my @valid_signature_algorithms = (
 103   "MD5",
 104   "SHA1",
 105   "SHA256",
 106   "SHA384",
 107   "SHA512"
 108 );
 109
 110 $0 =~ s@.*(/|\\)@@;
 111 $Getopt::Std::STANDARD_HELP_VERSION = 1;
 112 getopts('bd:fhilnp:qs:tuvw:');
 113
 114 if(!defined($opt_d)) {
 115     # to make plain "-d" use not cause warnings, and actually still work
 116     $opt_d = 'release';
 117 }
 118
 119 # Use predefined URL or else custom URL specified on command line.
 120 my $url = ( defined( $urls{$opt_d} ) ) ? $urls{$opt_d} : $opt_d;
 121
 122 my $curl = `curl -V`;
 123
 124 if ($opt_i) {
 125   print ("=" x 78 . "\n");
 126   print "Script Version                   : $version\n";
 127   print "Perl Version                     : $]\n";
 128   print "Operating System Name            : $^O\n";
 129   print "Getopt::Std.pm Version           : ${Getopt::Std::VERSION}\n";
 130   print "MIME::Base64.pm Version          : ${MIME::Base64::VERSION}\n";
 131   print "LWP::UserAgent.pm Version        : ${LWP::UserAgent::VERSION}\n";
 132   print "LWP.pm Version                   : ${LWP::VERSION}\n";
 133   print "Digest::SHA.pm Version           : ${Digest::SHA::VERSION}\n" if ($Digest::SHA::VERSION);
 134   print "Digest::SHA::PurePerl.pm Version : ${Digest::SHA::PurePerl::VERSION}\n" if ($Digest::SHA::PurePerl::VERSION);
 135   print ("=" x 78 . "\n");
 136 }
 137
 138 sub warning_message() {
 139   if ( $opt_d =~ m/^risk$/i ) { # Long Form Warning and Exit
 140     print "Warning: Use of this script may pose some risk:\n";
 141     print "\n";
 142     print "  1) Using http is subject to man in the middle attack of certdata content\n";
 143     print "  2) Default to 'release', but more recent updates may be found in other trees\n";
 144     print "  3) certdata.txt file format may change, lag time to update this script\n";
 145     print "  4) Generally unwise to blindly trust CAs without manual review & verification\n";
 146     print "  5) Mozilla apps use additional security checks aren't represented in certdata\n";
 147     print "  6) Use of this script will make a security engineer grind his teeth and\n";
 148     print "     swear at you.  ;)\n";
 149     exit;
 150   } else { # Short Form Warning
 151     print "Warning: Use of this script may pose some risk, -d risk for more details.\n";
 152   }
 153 }
 154
 155 sub HELP_MESSAGE() {
 156   print "Usage:\t${0} [-b] [-d<certdata>] [-f] [-i] [-l] [-n] [-p<purposes:levels>] [-q] [-s<algorithms>] [-t] [-u] [-v] [-w<l>] [<outputfile>]\n";
 157   print "\t-b\tbackup an existing version of ca-bundle.crt\n";
 158   print "\t-d\tspecify Mozilla tree to pull certdata.txt or custom URL\n";
 159   print "\t\t  Valid names are:\n";
 160   print "\t\t    ", join( ", ", map { ( $_ =~ m/$opt_d/ ) ? "$_ (default)" : "$_" } sort keys %urls ), "\n";
 161   print "\t-f\tforce rebuild even if certdata.txt is current\n";
 162   print "\t-i\tprint version info about used modules\n";
 163   print "\t-l\tprint license info about certdata.txt\n";
 164   print "\t-n\tno download of certdata.txt (to use existing)\n";
 165   print wrap("\t","\t\t", "-p\tlist of Mozilla trust purposes and levels for certificates to include in output. Takes the form of a comma separated list of purposes, a colon, and a comma separated list of levels. (default: $default_mozilla_trust_purposes:$default_mozilla_trust_levels)"), "\n";
 166   print "\t\t  Valid purposes are:\n";
 167   print wrap("\t\t    ","\t\t    ", join( ", ", "ALL", @valid_mozilla_trust_purposes ) ), "\n";
 168   print "\t\t  Valid levels are:\n";
 169   print wrap("\t\t    ","\t\t    ", join( ", ", "ALL", @valid_mozilla_trust_levels ) ), "\n";
 170   print "\t-q\tbe really quiet (no progress output at all)\n";
 171   print wrap("\t","\t\t", "-s\tcomma separated list of certificate signatures/hashes to output in plain text mode. (default: $default_signature_algorithms)\n");
 172   print "\t\t  Valid signature algorithms are:\n";
 173   print wrap("\t\t    ","\t\t    ", join( ", ", "ALL", @valid_signature_algorithms ) ), "\n";
 174   print "\t-t\tinclude plain text listing of certificates\n";
 175   print "\t-u\tunlink (remove) certdata.txt after processing\n";
 176   print "\t-v\tbe verbose and print out processed CAs\n";
 177   print "\t-w <l>\twrap base64 output lines after <l> chars (default: ${opt_w})\n";
 178   exit;
 179 }
 180
 181 sub VERSION_MESSAGE() {
 182   print "${0} version ${version} running Perl ${]} on ${^O}\n";
 183 }
 184
 185 warning_message() unless ($opt_q || $url =~ m/^(ht|f)tps:/i );
 186 HELP_MESSAGE() if ($opt_h);
 187
 188 sub is_in_list($@) {
 189   my $target = shift;
 190
 191   return defined(List::Util::first { $target eq $_ } @_);
 192 }
 193
 194 # Parses $param_string as a case insensitive comma separated list with optional whitespace
 195 # validates that only allowed parameters are supplied
 196 sub parse_csv_param($$@) {
 197   my $description = shift;
 198   my $param_string = shift;
 199   my @valid_values = @_;
 200
 201   my @values = map {
 202     s/^\s+//;  # strip leading spaces
 203     s/\s+$//;  # strip trailing spaces
 204     uc $_      # return the modified string as upper case
 205   } split( ',', $param_string );
 206
 207   # Find all values which are not in the list of valid values or "ALL"
 208   my @invalid = grep { !is_in_list($_,"ALL",@valid_values) } @values;
 209
 210   if ( scalar(@invalid) > 0 ) {
 211     # Tell the user which parameters were invalid and print the standard help message which will exit
 212     print "Error: Invalid ", $description, scalar(@invalid) == 1 ? ": " : "s: ", join( ", ", map { "\"$_\"" } @invalid ), "\n";
 213     HELP_MESSAGE();
 214   }
 215
 216   @values = @valid_values if ( is_in_list("ALL",@values) );
 217
 218   return @values;
 219 }
 220
 221 sub sha1 {
 222   my $result;
 223   if ($Digest::SHA::VERSION || $Digest::SHA::PurePerl::VERSION) {
 224     open(FILE, $_[0]) or die "Can't open '$_[0]': $!";
 225     binmode(FILE);
 226     $result = $MOD_SHA->new(1)->addfile(*FILE)->hexdigest;
 227     close(FILE);
 228   } else {
 229     # Use OpenSSL command if Perl Digest::SHA modules not available
 230     $result = (split(/ |\r|\n/,`$openssl dgst -sha1 $_[0]`))[1];
 231   }
 232   return $result;
 233 }
 234
 235
 236 sub oldsha1 {
 237   my $sha1 = "";
 238   open(C, "<$_[0]") || return 0;
 239   while(<C>) {
 240     chomp;
 241     if($_ =~ /^\#\# SHA1: (.*)/) {
 242       $sha1 = $1;
 243       last;
 244     }
 245   }
 246   close(C);
 247   return $sha1;
 248 }
 249
 250 if ( $opt_p !~ m/:/ ) {
 251   print "Error: Mozilla trust identifier list must include both purposes and levels\n";
 252   HELP_MESSAGE();
 253 }
 254
 255 (my $included_mozilla_trust_purposes_string, my $included_mozilla_trust_levels_string) = split( ':', $opt_p );
 256 my @included_mozilla_trust_purposes = parse_csv_param( "trust purpose", $included_mozilla_trust_purposes_string, @valid_mozilla_trust_purposes );
 257 my @included_mozilla_trust_levels = parse_csv_param( "trust level", $included_mozilla_trust_levels_string, @valid_mozilla_trust_levels );
 258
 259 my @included_signature_algorithms = parse_csv_param( "signature algorithm", $opt_s, @valid_signature_algorithms );
 260
 261 sub should_output_cert(%) {
 262   my %trust_purposes_by_level = @_;
 263
 264   foreach my $level (@included_mozilla_trust_levels) {
 265     # for each level we want to output, see if any of our desired purposes are included
 266     return 1 if ( defined( List::Util::first { is_in_list( $_, @included_mozilla_trust_purposes ) } @{$trust_purposes_by_level{$level}} ) );
 267   }
 268
 269   return 0;
 270 }
 271
 272 my $crt = $ARGV[0] || 'ca-bundle.crt';
 273 (my $txt = $url) =~ s@(.*/|\?.*)@@g;
 274
 275 my $stdout = $crt eq '-';
 276 my $resp;
 277 my $fetched;
 278
 279 my $oldsha1 = oldsha1($crt);
 280
 281 print STDERR "SHA1 of old file: $oldsha1\n" if (!$opt_q);
 282
 283 print STDERR "Downloading '$txt' ...\n" if (!$opt_q);
 284
 285 if($curl && !$opt_n) {
 286   my $https = $url;
 287   $https =~ s/^http:/https:/;
 288   print STDERR "Get certdata over HTTPS with curl!\n" if (!$opt_q);
 289   my $quiet = $opt_q ? "-s" : "";
 290   my @out = `curl -w %{response_code} $quiet -O $https`;
 291   if(@out && $out[0] == 200) {
 292     $fetched = 1;
 293   } else {
 294     print STDERR "Failed downloading HTTPS with curl, trying HTTP with LWP\n" if (!$opt_q);
 295   }
 296 }
 297
 298 unless ($fetched || ($opt_n and -e $txt)) {
 299   my $ua  = new LWP::UserAgent(agent => "$0/$version");
 300   $ua->env_proxy();
 301   $resp = $ua->mirror($url, $txt);
 302   if ($resp && $resp->code eq '304') {
 303     print STDERR "Not modified\n" unless $opt_q;
 304     exit 0 if -e $crt && !$opt_f;
 305   } else {
 306       $fetched = 1;
 307   }
 308   if( !$resp || $resp->code !~ /^(?:200|304)$/ ) {
 309       print STDERR "Unable to download latest data: "
 310         . ($resp? $resp->code . ' - ' . $resp->message : "LWP failed") . "\n"
 311         unless $opt_q;
 312       exit 1 if -e $crt || ! -r $txt;
 313   }
 314 }
 315
 316 my $filedate = $resp ? $resp->last_modified : (stat($txt))[9];
 317 my $datesrc = "as of";
 318 if(!$filedate) {
 319     # mxr.mozilla.org gave us a time, hg.mozilla.org does not!
 320     $filedate = time();
 321     $datesrc="downloaded on";
 322 }
 323
 324 # get the hash from the download file
 325 my $newsha1= sha1($txt);
 326
 327 if(!$opt_f && $oldsha1 eq $newsha1) {
 328     print STDERR "Downloaded file identical to previous run\'s source file. Exiting\n";
 329     exit;
 330 }
 331
 332 print STDERR "SHA1 of new file: $newsha1\n";
 333
 334 my $currentdate = scalar gmtime($filedate);
 335
 336 my $format = $opt_t ? "plain text and " : "";
 337 if( $stdout ) {
 338     open(CRT, '> -') or die "Couldn't open STDOUT: $!\n";
 339 } else {
 340     open(CRT,">$crt.~") or die "Couldn't open $crt.~: $!\n";
 341 }
 342 print CRT <<EOT;
 343 ##
 344 ## Bundle of CA Root Certificates
 345 ##
 346 ## Certificate data from Mozilla ${datesrc}: ${currentdate}
 347 ##
 348 ## This is a bundle of X.509 certificates of public Certificate Authorities
 349 ## (CA). These were automatically extracted from Mozilla's root certificates
 350 ## file (certdata.txt).  This file can be found in the mozilla source tree:
 351 ## ${url}
 352 ##
 353 ## It contains the certificates in ${format}PEM format and therefore
 354 ## can be directly used with curl / libcurl / php_curl, or with
 355 ## an Apache+mod_ssl webserver for SSL client authentication.
 356 ## Just configure this file as the SSLCACertificateFile.
 357 ##
 358 ## Conversion done with mk-ca-bundle.pl version $version.
 359 ## SHA1: $newsha1
 360 ##
 361
 362 EOT
 363
 364 print STDERR "Processing  '$txt' ...\n" if (!$opt_q);
 365 my $caname;
 366 my $certnum = 0;
 367 my $skipnum = 0;
 368 my $start_of_cert = 0;
 369
 370 open(TXT,"$txt") or die "Couldn't open $txt: $!\n";
 371 while (<TXT>) {
 372   if (/\*\*\*\*\* BEGIN LICENSE BLOCK \*\*\*\*\*/) {
 373     print CRT;
 374     print if ($opt_l);
 375     while (<TXT>) {
 376       print CRT;
 377       print if ($opt_l);
 378       last if (/\*\*\*\*\* END LICENSE BLOCK \*\*\*\*\*/);
 379     }
 380   }
 381   next if /^#|^\s*$/;
 382   chomp;
 383   if (/^CVS_ID\s+\"(.*)\"/) {
 384     print CRT "# $1\n";
 385   }
 386
 387   # this is a match for the start of a certificate
 388   if (/^CKA_CLASS CK_OBJECT_CLASS CKO_CERTIFICATE/) {
 389     $start_of_cert = 1
 390   }
 391   if ($start_of_cert && /^CKA_LABEL UTF8 \"(.*)\"/) {
 392     $caname = $1;
 393   }
 394   my %trust_purposes_by_level;
 395   if ($start_of_cert && /^CKA_VALUE MULTILINE_OCTAL/) {
 396     my $data;
 397     while (<TXT>) {
 398       last if (/^END/);
 399       chomp;
 400       my @octets = split(/\\/);
 401       shift @octets;
 402       for (@octets) {
 403         $data .= chr(oct);
 404       }
 405     }
 406     # scan forwards until the trust part
 407     while (<TXT>) {
 408       last if (/^CKA_CLASS CK_OBJECT_CLASS CKO_NSS_TRUST/);
 409       chomp;
 410     }
 411     # now scan the trust part to determine how we should trust this cert
 412     while (<TXT>) {
 413       last if (/^#/);
 414       if (/^CKA_TRUST_([A-Z_]+)\s+CK_TRUST\s+CKT_NSS_([A-Z_]+)\s*$/) {
 415         if ( !is_in_list($1,@valid_mozilla_trust_purposes) ) {
 416           print STDERR "Warning: Unrecognized trust purpose for cert: $caname. Trust purpose: $1. Trust Level: $2\n" if (!$opt_q);
 417         } elsif ( !is_in_list($2,@valid_mozilla_trust_levels) ) {
 418           print STDERR "Warning: Unrecognized trust level for cert: $caname. Trust purpose: $1. Trust Level: $2\n" if (!$opt_q);
 419         } else {
 420           push @{$trust_purposes_by_level{$2}}, $1;
 421         }
 422       }
 423     }
 424
 425     if ( !should_output_cert(%trust_purposes_by_level) ) {
 426       $skipnum ++;
 427     } else {
 428       my $encoded = MIME::Base64::encode_base64($data, '');
 429       $encoded =~ s/(.{1,${opt_w}})/$1\n/g;
 430       my $pem = "-----BEGIN CERTIFICATE-----\n"
 431               . $encoded
 432               . "-----END CERTIFICATE-----\n";
 433       print CRT "\n$caname\n";
 434
 435       my $maxStringLength = length($caname);
 436       if ($opt_t) {
 437         foreach my $key (keys %trust_purposes_by_level) {
 438            my $string = $key . ": " . join(", ", @{$trust_purposes_by_level{$key}});
 439            $maxStringLength = List::Util::max( length($string), $maxStringLength );
 440            print CRT $string . "\n";
 441         }
 442       }
 443       print CRT ("=" x $maxStringLength . "\n");
 444       if (!$opt_t) {
 445         print CRT $pem;
 446       } else {
 447         my $pipe = "";
 448         foreach my $hash (@included_signature_algorithms) {
 449           $pipe = "|$openssl x509 -" . $hash . " -fingerprint -noout -inform PEM";
 450           if (!$stdout) {
 451             $pipe .= " >> $crt.~";
 452             close(CRT) or die "Couldn't close $crt.~: $!";
 453           }
 454           open(TMP, $pipe) or die "Couldn't open openssl pipe: $!";
 455           print TMP $pem;
 456           close(TMP) or die "Couldn't close openssl pipe: $!";
 457           if (!$stdout) {
 458             open(CRT, ">>$crt.~") or die "Couldn't open $crt.~: $!";
 459           }
 460         }
 461         $pipe = "|$openssl x509 -text -inform PEM";
 462         if (!$stdout) {
 463           $pipe .= " >> $crt.~";
 464           close(CRT) or die "Couldn't close $crt.~: $!";
 465         }
 466         open(TMP, $pipe) or die "Couldn't open openssl pipe: $!";
 467         print TMP $pem;
 468         close(TMP) or die "Couldn't close openssl pipe: $!";
 469         if (!$stdout) {
 470           open(CRT, ">>$crt.~") or die "Couldn't open $crt.~: $!";
 471         }
 472       }
 473       print STDERR "Parsing: $caname\n" if ($opt_v);
 474       $certnum ++;
 475       $start_of_cert = 0;
 476     }
 477   }
 478 }
 479 close(TXT) or die "Couldn't close $txt: $!\n";
 480 close(CRT) or die "Couldn't close $crt.~: $!\n";
 481 unless( $stdout ) {
 482     if ($opt_b && -e $crt) {
 483         my $bk = 1;
 484         while (-e "$crt.~${bk}~") {
 485             $bk++;
 486         }
 487         rename $crt, "$crt.~${bk}~" or die "Failed to create backup $crt.~$bk}~: $!\n";
 488     } elsif( -e $crt ) {
 489         unlink( $crt ) or die "Failed to remove $crt: $!\n";
 490     }
 491     rename "$crt.~", $crt or die "Failed to rename $crt.~ to $crt: $!\n";
 492 }
 493 unlink $txt if ($opt_u);
 494 print STDERR "Done ($certnum CA certs processed, $skipnum skipped).\n" if (!$opt_q);