configure.ac

   1 #***************************************************************************
   2 #                                  _   _ ____  _
   3 #  Project                     ___| | | |  _ \| |
   4 #                             / __| | | | |_) | |
   5 #                            | (__| |_| |  _ <| |___
   6 #                             \___|\___/|_| \_\_____|
   7 #
   8 # Copyright (C) 1998 - 2014, Daniel Stenberg, <daniel@haxx.se>, et al.
   9 #
  10 # This software is licensed as described in the file COPYING, which
  11 # you should have received as part of this distribution. The terms
  12 # are also available at http://curl.haxx.se/docs/copyright.html.
  13 #
  14 # You may opt to use, copy, modify, merge, publish, distribute and/or sell
  15 # copies of the Software, and permit persons to whom the Software is
  16 # furnished to do so, under the terms of the COPYING file.
  17 #
  18 # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
  19 # KIND, either express or implied.
  20 #
  21 #***************************************************************************
  22 dnl Process this file with autoconf to produce a configure script.
  23
  24 AC_PREREQ(2.57)
  25
  26 dnl We don't know the version number "statically" so we use a dash here
  27 AC_INIT([curl], [-], [a suitable curl mailing list: http://curl.haxx.se/mail/])
  28
  29 XC_OVR_ZZ50
  30 XC_OVR_ZZ60
  31 CURL_OVERRIDE_AUTOCONF
  32
  33 dnl configure script copyright
  34 AC_COPYRIGHT([Copyright (c) 1998 - 2014 Daniel Stenberg, <daniel@haxx.se>
  35 This configure script may be copied, distributed and modified under the
  36 terms of the curl license; see COPYING for more details])
  37
  38 AC_CONFIG_SRCDIR([lib/urldata.h])
  39 AC_CONFIG_HEADERS(lib/curl_config.h include/curl/curlbuild.h)
  40 AC_CONFIG_MACRO_DIR([m4])
  41 AM_MAINTAINER_MODE
  42
  43 CURL_CHECK_OPTION_DEBUG
  44 CURL_CHECK_OPTION_OPTIMIZE
  45 CURL_CHECK_OPTION_WARNINGS
  46 CURL_CHECK_OPTION_WERROR
  47 CURL_CHECK_OPTION_CURLDEBUG
  48 CURL_CHECK_OPTION_SYMBOL_HIDING
  49 CURL_CHECK_OPTION_ARES
  50
  51 XC_CHECK_PATH_SEPARATOR
  52
  53 #
  54 # save the configure arguments
  55 #
  56 CONFIGURE_OPTIONS="\"$ac_configure_args\""
  57 AC_SUBST(CONFIGURE_OPTIONS)
  58
  59 CURL_CFLAG_EXTRAS=""
  60 if test X"$want_werror" = Xyes; then
  61   CURL_CFLAG_EXTRAS="-Werror"
  62 fi
  63 AC_SUBST(CURL_CFLAG_EXTRAS)
  64
  65 dnl SED is mandatory for configure process and libtool.
  66 dnl Set it now, allowing it to be changed later.
  67 if test -z "$SED"; then
  68   dnl allow it to be overridden
  69   AC_PATH_PROG([SED], [sed], [not_found],
  70     [$PATH:/usr/bin:/usr/local/bin])
  71   if test -z "$SED" || test "$SED" = "not_found"; then
  72     AC_MSG_ERROR([sed not found in PATH. Cannot continue without sed.])
  73   fi
  74 fi
  75 AC_SUBST([SED])
  76
  77 dnl GREP is mandatory for configure process and libtool.
  78 dnl Set it now, allowing it to be changed later.
  79 if test -z "$GREP"; then
  80   dnl allow it to be overridden
  81   AC_PATH_PROG([GREP], [grep], [not_found],
  82     [$PATH:/usr/bin:/usr/local/bin])
  83   if test -z "$GREP" || test "$GREP" = "not_found"; then
  84     AC_MSG_ERROR([grep not found in PATH. Cannot continue without grep.])
  85   fi
  86 fi
  87 AC_SUBST([GREP])
  88
  89 dnl EGREP is mandatory for configure process and libtool.
  90 dnl Set it now, allowing it to be changed later.
  91 if test -z "$EGREP"; then
  92   dnl allow it to be overridden
  93   if echo a | ($GREP -E '(a|b)') >/dev/null 2>&1; then
  94     AC_MSG_CHECKING([for egrep])
  95     EGREP="$GREP -E"
  96     AC_MSG_RESULT([$EGREP])
  97   else
  98     AC_PATH_PROG([EGREP], [egrep], [not_found],
  99       [$PATH:/usr/bin:/usr/local/bin])
 100   fi
 101 fi
 102 if test -z "$EGREP" || test "$EGREP" = "not_found"; then
 103   AC_MSG_ERROR([egrep not found in PATH. Cannot continue without egrep.])
 104 fi
 105 AC_SUBST([EGREP])
 106
 107 dnl AR is mandatory for configure process and libtool.
 108 dnl This is target dependent, so check it as a tool.
 109 if test -z "$AR"; then
 110   dnl allow it to be overridden
 111   AC_PATH_TOOL([AR], [ar], [not_found],
 112     [$PATH:/usr/bin:/usr/local/bin])
 113   if test -z "$AR" || test "$AR" = "not_found"; then
 114     AC_MSG_ERROR([ar not found in PATH. Cannot continue without ar.])
 115   fi
 116 fi
 117 AC_SUBST([AR])
 118
 119 AC_SUBST(libext)
 120
 121 dnl Remove non-configure distributed curlbuild.h
 122 if test -f ${srcdir}/include/curl/curlbuild.h; then
 123   rm -f ${srcdir}/include/curl/curlbuild.h
 124 fi
 125
 126 dnl figure out the libcurl version
 127 CURLVERSION=`$SED -ne 's/^#define LIBCURL_VERSION "\(.*\)"/\1/p' ${srcdir}/include/curl/curlver.h`
 128 XC_CHECK_PROG_CC
 129 XC_AUTOMAKE
 130 AC_MSG_CHECKING([curl version])
 131 AC_MSG_RESULT($CURLVERSION)
 132
 133 AC_SUBST(CURLVERSION)
 134
 135 dnl
 136 dnl we extract the numerical version for curl-config only
 137 VERSIONNUM=`$SED -ne 's/^#define LIBCURL_VERSION_NUM 0x\(.*\)/\1/p' ${srcdir}/include/curl/curlver.h`
 138 AC_SUBST(VERSIONNUM)
 139
 140 dnl Solaris pkgadd support definitions
 141 PKGADD_PKG="HAXXcurl"
 142 PKGADD_NAME="cURL - a client that groks URLs"
 143 PKGADD_VENDOR="curl.haxx.se"
 144 AC_SUBST(PKGADD_PKG)
 145 AC_SUBST(PKGADD_NAME)
 146 AC_SUBST(PKGADD_VENDOR)
 147
 148 dnl
 149 dnl initialize all the info variables
 150     curl_ssl_msg="no      (--with-{ssl,gnutls,nss,polarssl,cyassl,axtls,winssl,darwinssl} )"
 151     curl_ssh_msg="no      (--with-libssh2)"
 152    curl_zlib_msg="no      (--with-zlib)"
 153     curl_gss_msg="no      (--with-gssapi)"
 154  curl_spnego_msg="no      (--with-spnego)"
 155 curl_tls_srp_msg="no      (--enable-tls-srp)"
 156     curl_res_msg="default (--enable-ares / --enable-threaded-resolver)"
 157    curl_ipv6_msg="no      (--enable-ipv6)"
 158     curl_idn_msg="no      (--with-{libidn,winidn})"
 159  curl_manual_msg="no      (--enable-manual)"
 160 curl_libcurl_msg="enabled (--disable-libcurl-option)"
 161 curl_verbose_msg="enabled (--disable-verbose)"
 162    curl_sspi_msg="no      (--enable-sspi)"
 163    curl_ldap_msg="no      (--enable-ldap / --with-ldap-lib / --with-lber-lib)"
 164   curl_ldaps_msg="no      (--enable-ldaps)"
 165    curl_rtsp_msg="no      (--enable-rtsp)"
 166    curl_rtmp_msg="no      (--with-librtmp)"
 167   curl_mtlnk_msg="no      (--with-libmetalink)"
 168
 169     init_ssl_msg=${curl_ssl_msg}
 170
 171 dnl
 172 dnl Save some initial values the user might have provided
 173 dnl
 174 INITIAL_LDFLAGS=$LDFLAGS
 175 INITIAL_LIBS=$LIBS
 176
 177 dnl
 178 dnl Detect the canonical host and target build environment
 179 dnl
 180
 181 AC_CANONICAL_HOST
 182 dnl Get system canonical name
 183 AC_DEFINE_UNQUOTED(OS, "${host}", [cpu-machine-OS])
 184
 185 dnl Checks for programs.
 186
 187 dnl Our curl_off_t internal and external configure settings
 188 CURL_CONFIGURE_CURL_OFF_T
 189
 190 dnl This defines _ALL_SOURCE for AIX
 191 CURL_CHECK_AIX_ALL_SOURCE
 192
 193 dnl Our configure and build reentrant settings
 194 CURL_CONFIGURE_THREAD_SAFE
 195 CURL_CONFIGURE_REENTRANT
 196
 197 dnl check for how to do large files
 198 AC_SYS_LARGEFILE
 199
 200 XC_LIBTOOL
 201
 202 #
 203 # Automake conditionals based on libtool related checks
 204 #
 205
 206 AM_CONDITIONAL([CURL_LT_SHLIB_USE_VERSION_INFO],
 207   [test "x$xc_lt_shlib_use_version_info" = 'xyes'])
 208 AM_CONDITIONAL([CURL_LT_SHLIB_USE_NO_UNDEFINED],
 209   [test "x$xc_lt_shlib_use_no_undefined" = 'xyes'])
 210 AM_CONDITIONAL([CURL_LT_SHLIB_USE_MIMPURE_TEXT],
 211   [test "x$xc_lt_shlib_use_mimpure_text" = 'xyes'])
 212
 213 #
 214 # Due to libtool and automake machinery limitations of not allowing
 215 # specifying separate CPPFLAGS or CFLAGS when compiling objects for
 216 # inclusion of these in shared or static libraries, we are forced to
 217 # build using separate configure runs for shared and static libraries
 218 # on systems where different CPPFLAGS or CFLAGS are mandatory in order
 219 # to compile objects for each kind of library. Notice that relying on
 220 # the '-DPIC' CFLAG that libtool provides is not valid given that the
 221 # user might for example choose to build static libraries with PIC.
 222 #
 223
 224 #
 225 # Make our Makefile.am files use the staticlib CPPFLAG only when strictly
 226 # targeting a static library and not building its shared counterpart.
 227 #
 228
 229 AM_CONDITIONAL([USE_CPPFLAG_CURL_STATICLIB],
 230   [test "x$xc_lt_build_static_only" = 'xyes'])
 231
 232 #
 233 # Make staticlib CPPFLAG variable and its definition visible in output
 234 # files unconditionally, providing an empty definition unless strictly
 235 # targeting a static library and not building its shared counterpart.
 236 #
 237
 238 CPPFLAG_CURL_STATICLIB=
 239 if test "x$xc_lt_build_static_only" = 'xyes'; then
 240   CPPFLAG_CURL_STATICLIB='-DCURL_STATICLIB'
 241 fi
 242 AC_SUBST([CPPFLAG_CURL_STATICLIB])
 243
 244
 245 # Determine whether all dependent libraries must be specified when linking
 246 if test "X$enable_shared" = "Xyes" -a "X$link_all_deplibs" = "Xno"
 247 then
 248     REQUIRE_LIB_DEPS=no
 249 else
 250     REQUIRE_LIB_DEPS=yes
 251 fi
 252 AC_SUBST(REQUIRE_LIB_DEPS)
 253 AM_CONDITIONAL(USE_EXPLICIT_LIB_DEPS, test x$REQUIRE_LIB_DEPS = xyes)
 254
 255 dnl check if there's a way to force code inline
 256 AC_C_INLINE
 257
 258 dnl **********************************************************************
 259 dnl platform/compiler/architecture specific checks/flags
 260 dnl **********************************************************************
 261
 262 CURL_CHECK_COMPILER
 263 CURL_SET_COMPILER_BASIC_OPTS
 264 CURL_SET_COMPILER_DEBUG_OPTS
 265 CURL_SET_COMPILER_OPTIMIZE_OPTS
 266 CURL_SET_COMPILER_WARNING_OPTS
 267
 268 if test "$compiler_id" = "INTEL_UNIX_C"; then
 269   #
 270   if test "$compiler_num" -ge "1000"; then
 271     dnl icc 10.X or later
 272     CFLAGS="$CFLAGS -shared-intel"
 273   elif test "$compiler_num" -ge "900"; then
 274     dnl icc 9.X specific
 275     CFLAGS="$CFLAGS -i-dynamic"
 276   fi
 277   #
 278 fi
 279
 280 CURL_CHECK_COMPILER_HALT_ON_ERROR
 281 CURL_CHECK_COMPILER_ARRAY_SIZE_NEGATIVE
 282 CURL_CHECK_COMPILER_PROTOTYPE_MISMATCH
 283 CURL_CHECK_COMPILER_SYMBOL_HIDING
 284
 285 CURL_CHECK_CURLDEBUG
 286 AM_CONDITIONAL(CURLDEBUG, test x$want_curldebug = xyes)
 287
 288 supports_unittests=yes
 289 # cross-compilation of unit tests static library/programs fails when
 290 # libcurl shared library is built. This might be due to a libtool or
 291 # automake issue. In this case we disable unit tests.
 292 if test "x$cross_compiling" != "xno" &&
 293    test "x$enable_shared" != "xno"; then
 294   supports_unittests=no
 295 fi
 296
 297 # IRIX 6.5.24 gcc 3.3 autobuilds fail unittests library compilation due to
 298 # a problem related with OpenSSL headers and library versions not matching.
 299 # Disable unit tests while time to further investigate this is found.
 300 case $host in
 301   mips-sgi-irix6.5)
 302     if test "$compiler_id" = "GNU_C"; then
 303       supports_unittests=no
 304     fi
 305     ;;
 306 esac
 307
 308 # All AIX autobuilds fails unit tests linking against unittests library
 309 # due to unittests library being built with no symbols or members. Libtool ?
 310 # Disable unit tests while time to further investigate this is found.
 311 case $host_os in
 312   aix*)
 313     supports_unittests=no
 314     ;;
 315 esac
 316
 317 dnl Build unit tests when option --enable-debug is given.
 318 if test "x$want_debug" = "xyes" &&
 319    test "x$supports_unittests" = "xyes"; then
 320   want_unittests=yes
 321 else
 322   want_unittests=no
 323 fi
 324 AM_CONDITIONAL(BUILD_UNITTESTS, test x$want_unittests = xyes)
 325
 326 dnl **********************************************************************
 327 dnl Compilation based checks should not be done before this point.
 328 dnl **********************************************************************
 329
 330 dnl **********************************************************************
 331 dnl Make sure that our checks for headers windows.h winsock.h winsock2.h
 332 dnl and ws2tcpip.h take precedence over any other further checks which
 333 dnl could be done later using AC_CHECK_HEADER or AC_CHECK_HEADERS for
 334 dnl this specific header files. And do them before its results are used.
 335 dnl **********************************************************************
 336
 337 CURL_CHECK_HEADER_WINDOWS
 338 CURL_CHECK_NATIVE_WINDOWS
 339 case X-"$ac_cv_native_windows" in
 340   X-yes)
 341     CURL_CHECK_HEADER_WINSOCK
 342     CURL_CHECK_HEADER_WINSOCK2
 343     CURL_CHECK_HEADER_WS2TCPIP
 344     CURL_CHECK_HEADER_WINLDAP
 345     CURL_CHECK_HEADER_WINBER
 346     ;;
 347   *)
 348     ac_cv_header_winsock_h="no"
 349     ac_cv_header_winsock2_h="no"
 350     ac_cv_header_ws2tcpip_h="no"
 351     ac_cv_header_winldap_h="no"
 352     ac_cv_header_winber_h="no"
 353     ;;
 354 esac
 355 CURL_CHECK_WIN32_LARGEFILE
 356
 357 dnl ************************************************************
 358 dnl switch off particular protocols
 359 dnl
 360 AC_MSG_CHECKING([whether to support http])
 361 AC_ARG_ENABLE(http,
 362 AC_HELP_STRING([--enable-http],[Enable HTTP support])
 363 AC_HELP_STRING([--disable-http],[Disable HTTP support]),
 364 [ case "$enableval" in
 365   no)
 366        AC_MSG_RESULT(no)
 367        AC_DEFINE(CURL_DISABLE_HTTP, 1, [to disable HTTP])
 368        AC_MSG_WARN([disable HTTP disables FTP over proxy and RTSP])
 369        AC_SUBST(CURL_DISABLE_HTTP, [1])
 370        AC_DEFINE(CURL_DISABLE_RTSP, 1, [to disable RTSP])
 371        AC_SUBST(CURL_DISABLE_RTSP, [1])
 372        ;;
 373   *)   AC_MSG_RESULT(yes)
 374        ;;
 375   esac ],
 376        AC_MSG_RESULT(yes)
 377 )
 378 AC_MSG_CHECKING([whether to support ftp])
 379 AC_ARG_ENABLE(ftp,
 380 AC_HELP_STRING([--enable-ftp],[Enable FTP support])
 381 AC_HELP_STRING([--disable-ftp],[Disable FTP support]),
 382 [ case "$enableval" in
 383   no)
 384        AC_MSG_RESULT(no)
 385        AC_DEFINE(CURL_DISABLE_FTP, 1, [to disable FTP])
 386        AC_SUBST(CURL_DISABLE_FTP, [1])
 387        ;;
 388   *)   AC_MSG_RESULT(yes)
 389        ;;
 390   esac ],
 391        AC_MSG_RESULT(yes)
 392 )
 393 AC_MSG_CHECKING([whether to support file])
 394 AC_ARG_ENABLE(file,
 395 AC_HELP_STRING([--enable-file],[Enable FILE support])
 396 AC_HELP_STRING([--disable-file],[Disable FILE support]),
 397 [ case "$enableval" in
 398   no)
 399        AC_MSG_RESULT(no)
 400        AC_DEFINE(CURL_DISABLE_FILE, 1, [to disable FILE])
 401        AC_SUBST(CURL_DISABLE_FILE, [1])
 402        ;;
 403   *)   AC_MSG_RESULT(yes)
 404        ;;
 405   esac ],
 406        AC_MSG_RESULT(yes)
 407 )
 408 AC_MSG_CHECKING([whether to support ldap])
 409 AC_ARG_ENABLE(ldap,
 410 AC_HELP_STRING([--enable-ldap],[Enable LDAP support])
 411 AC_HELP_STRING([--disable-ldap],[Disable LDAP support]),
 412 [ case "$enableval" in
 413   no)
 414        AC_MSG_RESULT(no)
 415        AC_DEFINE(CURL_DISABLE_LDAP, 1, [to disable LDAP])
 416        AC_SUBST(CURL_DISABLE_LDAP, [1])
 417        ;;
 418   *)
 419        AC_MSG_RESULT(yes)
 420        ;;
 421   esac ],[
 422        AC_MSG_RESULT(yes) ]
 423 )
 424 AC_MSG_CHECKING([whether to support ldaps])
 425 AC_ARG_ENABLE(ldaps,
 426 AC_HELP_STRING([--enable-ldaps],[Enable LDAPS support])
 427 AC_HELP_STRING([--disable-ldaps],[Disable LDAPS support]),
 428 [ case "$enableval" in
 429   no)
 430        AC_MSG_RESULT(no)
 431        AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
 432        AC_SUBST(CURL_DISABLE_LDAPS, [1])
 433        ;;
 434   *)   if test "x$CURL_DISABLE_LDAP" = "x1" ; then
 435          AC_MSG_RESULT(LDAP needs to be enabled to support LDAPS)
 436          AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
 437          AC_SUBST(CURL_DISABLE_LDAPS, [1])
 438        else
 439          AC_MSG_RESULT(yes)
 440          AC_DEFINE(HAVE_LDAP_SSL, 1, [Use LDAPS implementation])
 441          AC_SUBST(HAVE_LDAP_SSL, [1])
 442        fi
 443        ;;
 444   esac ],[
 445        if test "x$CURL_DISABLE_LDAP" = "x1" ; then
 446          AC_MSG_RESULT(no)
 447          AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
 448          AC_SUBST(CURL_DISABLE_LDAPS, [1])
 449        else
 450          AC_MSG_RESULT(yes)
 451          AC_DEFINE(HAVE_LDAP_SSL, 1, [Use LDAPS implementation])
 452          AC_SUBST(HAVE_LDAP_SSL, [1])
 453        fi ]
 454 )
 455
 456 AC_MSG_CHECKING([whether to support rtsp])
 457 AC_ARG_ENABLE(rtsp,
 458 AC_HELP_STRING([--enable-rtsp],[Enable RTSP support])
 459 AC_HELP_STRING([--disable-rtsp],[Disable RTSP support]),
 460 [ case "$enableval" in
 461   no)
 462        AC_MSG_RESULT(no)
 463        AC_DEFINE(CURL_DISABLE_RTSP, 1, [to disable RTSP])
 464        AC_SUBST(CURL_DISABLE_RTSP, [1])
 465        ;;
 466   *)   if test x$CURL_DISABLE_HTTP = x1 ; then
 467           AC_MSG_ERROR(HTTP support needs to be enabled in order to enable RTSP support!)
 468        else
 469           AC_MSG_RESULT(yes)
 470           curl_rtsp_msg="enabled"
 471        fi
 472        ;;
 473   esac ],
 474        if test "x$CURL_DISABLE_HTTP" != "x1"; then
 475           AC_MSG_RESULT(yes)
 476           curl_rtsp_msg="enabled"
 477        else
 478           AC_MSG_RESULT(no)
 479        fi
 480 )
 481
 482 AC_MSG_CHECKING([whether to support proxies])
 483 AC_ARG_ENABLE(proxy,
 484 AC_HELP_STRING([--enable-proxy],[Enable proxy support])
 485 AC_HELP_STRING([--disable-proxy],[Disable proxy support]),
 486 [ case "$enableval" in
 487   no)
 488        AC_MSG_RESULT(no)
 489        AC_DEFINE(CURL_DISABLE_PROXY, 1, [to disable proxies])
 490        AC_SUBST(CURL_DISABLE_PROXY, [1])
 491        ;;
 492   *)   AC_MSG_RESULT(yes)
 493        ;;
 494   esac ],
 495        AC_MSG_RESULT(yes)
 496 )
 497
 498 AC_MSG_CHECKING([whether to support dict])
 499 AC_ARG_ENABLE(dict,
 500 AC_HELP_STRING([--enable-dict],[Enable DICT support])
 501 AC_HELP_STRING([--disable-dict],[Disable DICT support]),
 502 [ case "$enableval" in
 503   no)
 504        AC_MSG_RESULT(no)
 505        AC_DEFINE(CURL_DISABLE_DICT, 1, [to disable DICT])
 506        AC_SUBST(CURL_DISABLE_DICT, [1])
 507        ;;
 508   *)   AC_MSG_RESULT(yes)
 509        ;;
 510   esac ],
 511        AC_MSG_RESULT(yes)
 512 )
 513 AC_MSG_CHECKING([whether to support telnet])
 514 AC_ARG_ENABLE(telnet,
 515 AC_HELP_STRING([--enable-telnet],[Enable TELNET support])
 516 AC_HELP_STRING([--disable-telnet],[Disable TELNET support]),
 517 [ case "$enableval" in
 518   no)
 519        AC_MSG_RESULT(no)
 520        AC_DEFINE(CURL_DISABLE_TELNET, 1, [to disable TELNET])
 521        AC_SUBST(CURL_DISABLE_TELNET, [1])
 522        ;;
 523   *)   AC_MSG_RESULT(yes)
 524        ;;
 525   esac ],
 526        AC_MSG_RESULT(yes)
 527 )
 528 AC_MSG_CHECKING([whether to support tftp])
 529 AC_ARG_ENABLE(tftp,
 530 AC_HELP_STRING([--enable-tftp],[Enable TFTP support])
 531 AC_HELP_STRING([--disable-tftp],[Disable TFTP support]),
 532 [ case "$enableval" in
 533   no)
 534        AC_MSG_RESULT(no)
 535        AC_DEFINE(CURL_DISABLE_TFTP, 1, [to disable TFTP])
 536        AC_SUBST(CURL_DISABLE_TFTP, [1])
 537        ;;
 538   *)   AC_MSG_RESULT(yes)
 539        ;;
 540   esac ],
 541        AC_MSG_RESULT(yes)
 542 )
 543
 544 AC_MSG_CHECKING([whether to support pop3])
 545 AC_ARG_ENABLE(pop3,
 546 AC_HELP_STRING([--enable-pop3],[Enable POP3 support])
 547 AC_HELP_STRING([--disable-pop3],[Disable POP3 support]),
 548 [ case "$enableval" in
 549   no)
 550        AC_MSG_RESULT(no)
 551        AC_DEFINE(CURL_DISABLE_POP3, 1, [to disable POP3])
 552        AC_SUBST(CURL_DISABLE_POP3, [1])
 553        ;;
 554   *)   AC_MSG_RESULT(yes)
 555        ;;
 556   esac ],
 557        AC_MSG_RESULT(yes)
 558 )
 559
 560
 561 AC_MSG_CHECKING([whether to support imap])
 562 AC_ARG_ENABLE(imap,
 563 AC_HELP_STRING([--enable-imap],[Enable IMAP support])
 564 AC_HELP_STRING([--disable-imap],[Disable IMAP support]),
 565 [ case "$enableval" in
 566   no)
 567        AC_MSG_RESULT(no)
 568        AC_DEFINE(CURL_DISABLE_IMAP, 1, [to disable IMAP])
 569        AC_SUBST(CURL_DISABLE_IMAP, [1])
 570        ;;
 571   *)   AC_MSG_RESULT(yes)
 572        ;;
 573   esac ],
 574        AC_MSG_RESULT(yes)
 575 )
 576
 577
 578 AC_MSG_CHECKING([whether to support smtp])
 579 AC_ARG_ENABLE(smtp,
 580 AC_HELP_STRING([--enable-smtp],[Enable SMTP support])
 581 AC_HELP_STRING([--disable-smtp],[Disable SMTP support]),
 582 [ case "$enableval" in
 583   no)
 584        AC_MSG_RESULT(no)
 585        AC_DEFINE(CURL_DISABLE_SMTP, 1, [to disable SMTP])
 586        AC_SUBST(CURL_DISABLE_SMTP, [1])
 587        ;;
 588   *)   AC_MSG_RESULT(yes)
 589        ;;
 590   esac ],
 591        AC_MSG_RESULT(yes)
 592 )
 593
 594 AC_MSG_CHECKING([whether to support gopher])
 595 AC_ARG_ENABLE(gopher,
 596 AC_HELP_STRING([--enable-gopher],[Enable Gopher support])
 597 AC_HELP_STRING([--disable-gopher],[Disable Gopher support]),
 598 [ case "$enableval" in
 599   no)
 600        AC_MSG_RESULT(no)
 601        AC_DEFINE(CURL_DISABLE_GOPHER, 1, [to disable Gopher])
 602        AC_SUBST(CURL_DISABLE_GOPHER, [1])
 603        ;;
 604   *)   AC_MSG_RESULT(yes)
 605        ;;
 606   esac ],
 607        AC_MSG_RESULT(yes)
 608 )
 609
 610
 611 dnl **********************************************************************
 612 dnl Check for built-in manual
 613 dnl **********************************************************************
 614
 615 AC_MSG_CHECKING([whether to provide built-in manual])
 616 AC_ARG_ENABLE(manual,
 617 AC_HELP_STRING([--enable-manual],[Enable built-in manual])
 618 AC_HELP_STRING([--disable-manual],[Disable built-in manual]),
 619 [ case "$enableval" in
 620   no)
 621        AC_MSG_RESULT(no)
 622        ;;
 623   *)   AC_MSG_RESULT(yes)
 624        USE_MANUAL="1"
 625        ;;
 626   esac ],
 627        AC_MSG_RESULT(yes)
 628        USE_MANUAL="1"
 629 )
 630 dnl The actual use of the USE_MANUAL variable is done much later in this
 631 dnl script to allow other actions to disable it as well.
 632
 633 dnl ************************************************************
 634 dnl disable C code generation support
 635 dnl
 636 AC_MSG_CHECKING([whether to enable generation of C code])
 637 AC_ARG_ENABLE(libcurl_option,
 638 AC_HELP_STRING([--enable-libcurl-option],[Enable --libcurl C code generation support])
 639 AC_HELP_STRING([--disable-libcurl-option],[Disable --libcurl C code generation support]),
 640 [ case "$enableval" in
 641   no)
 642        AC_MSG_RESULT(no)
 643        AC_DEFINE(CURL_DISABLE_LIBCURL_OPTION, 1, [to disable --libcurl C code generation option])
 644        curl_libcurl_msg="no"
 645        ;;
 646   *)   AC_MSG_RESULT(yes)
 647        ;;
 648   esac ],
 649        AC_MSG_RESULT(yes)
 650 )
 651
 652 dnl **********************************************************************
 653 dnl Checks for libraries.
 654 dnl **********************************************************************
 655
 656 AC_MSG_CHECKING([whether to use libgcc])
 657 AC_ARG_ENABLE(libgcc,
 658 AC_HELP_STRING([--enable-libgcc],[use libgcc when linking]),
 659 [ case "$enableval" in
 660   yes)
 661        LIBS="-lgcc $LIBS"
 662        AC_MSG_RESULT(yes)
 663        ;;
 664   *)   AC_MSG_RESULT(no)
 665        ;;
 666   esac ],
 667        AC_MSG_RESULT(no)
 668 )
 669
 670 CURL_CHECK_LIB_XNET
 671
 672 dnl gethostbyname without lib or in the nsl lib?
 673 AC_CHECK_FUNC(gethostbyname,
 674               [HAVE_GETHOSTBYNAME="1"
 675               ],
 676               [ AC_CHECK_LIB(nsl, gethostbyname,
 677                              [HAVE_GETHOSTBYNAME="1"
 678                              LIBS="-lnsl $LIBS"
 679                              ])
 680               ])
 681
 682 if test "$HAVE_GETHOSTBYNAME" != "1"
 683 then
 684   dnl gethostbyname in the socket lib?
 685   AC_CHECK_LIB(socket, gethostbyname,
 686                [HAVE_GETHOSTBYNAME="1"
 687                LIBS="-lsocket $LIBS"
 688                ])
 689 fi
 690
 691 if test "$HAVE_GETHOSTBYNAME" != "1"
 692 then
 693   dnl gethostbyname in the watt lib?
 694   AC_CHECK_LIB(watt, gethostbyname,
 695                [HAVE_GETHOSTBYNAME="1"
 696                CPPFLAGS="-I/dev/env/WATT_ROOT/inc"
 697                LDFLAGS="-L/dev/env/WATT_ROOT/lib"
 698                LIBS="-lwatt $LIBS"
 699                ])
 700 fi
 701
 702 dnl At least one system has been identified to require BOTH nsl and socket
 703 dnl libs at the same time to link properly.
 704 if test "$HAVE_GETHOSTBYNAME" != "1"
 705 then
 706   AC_MSG_CHECKING([for gethostbyname with both nsl and socket libs])
 707   my_ac_save_LIBS=$LIBS
 708   LIBS="-lnsl -lsocket $LIBS"
 709   AC_LINK_IFELSE([
 710     AC_LANG_PROGRAM([[
 711     ]],[[
 712       gethostbyname();
 713     ]])
 714   ],[
 715     AC_MSG_RESULT([yes])
 716     HAVE_GETHOSTBYNAME="1"
 717   ],[
 718     AC_MSG_RESULT([no])
 719     LIBS=$my_ac_save_LIBS
 720   ])
 721 fi
 722
 723 if test "$HAVE_GETHOSTBYNAME" != "1"
 724 then
 725   dnl This is for winsock systems
 726   if test "$ac_cv_header_windows_h" = "yes"; then
 727     if test "$ac_cv_header_winsock_h" = "yes"; then
 728       case $host in
 729         *-*-mingw32ce*)
 730           winsock_LIB="-lwinsock"
 731           ;;
 732         *)
 733           winsock_LIB="-lwsock32"
 734           ;;
 735       esac
 736     fi
 737     if test "$ac_cv_header_winsock2_h" = "yes"; then
 738       winsock_LIB="-lws2_32"
 739     fi
 740     if test ! -z "$winsock_LIB"; then
 741       my_ac_save_LIBS=$LIBS
 742       LIBS="$winsock_LIB $LIBS"
 743       AC_MSG_CHECKING([for gethostbyname in $winsock_LIB])
 744       AC_LINK_IFELSE([
 745         AC_LANG_PROGRAM([[
 746 #ifdef HAVE_WINDOWS_H
 747 #ifndef WIN32_LEAN_AND_MEAN
 748 #define WIN32_LEAN_AND_MEAN
 749 #endif
 750 #include <windows.h>
 751 #ifdef HAVE_WINSOCK2_H
 752 #include <winsock2.h>
 753 #else
 754 #ifdef HAVE_WINSOCK_H
 755 #include <winsock.h>
 756 #endif
 757 #endif
 758 #endif
 759         ]],[[
 760           gethostbyname("www.dummysite.com");
 761         ]])
 762       ],[
 763         AC_MSG_RESULT([yes])
 764         HAVE_GETHOSTBYNAME="1"
 765       ],[
 766         AC_MSG_RESULT([no])
 767         winsock_LIB=""
 768         LIBS=$my_ac_save_LIBS
 769       ])
 770     fi
 771   fi
 772 fi
 773
 774 if test "$HAVE_GETHOSTBYNAME" != "1"
 775 then
 776   dnl This is for Minix 3.1
 777   AC_MSG_CHECKING([for gethostbyname for Minix 3])
 778   AC_LINK_IFELSE([
 779     AC_LANG_PROGRAM([[
 780 /* Older Minix versions may need <net/gen/netdb.h> here instead */
 781 #include <netdb.h>
 782     ]],[[
 783       gethostbyname("www.dummysite.com");
 784     ]])
 785   ],[
 786     AC_MSG_RESULT([yes])
 787     HAVE_GETHOSTBYNAME="1"
 788   ],[
 789     AC_MSG_RESULT([no])
 790   ])
 791 fi
 792
 793 if test "$HAVE_GETHOSTBYNAME" != "1"
 794 then
 795   dnl This is for eCos with a stubbed DNS implementation
 796   AC_MSG_CHECKING([for gethostbyname for eCos])
 797   AC_LINK_IFELSE([
 798     AC_LANG_PROGRAM([[
 799 #include <stdio.h>
 800 #include <netdb.h>
 801     ]],[[
 802       gethostbyname("www.dummysite.com");
 803     ]])
 804   ],[
 805     AC_MSG_RESULT([yes])
 806     HAVE_GETHOSTBYNAME="1"
 807   ],[
 808     AC_MSG_RESULT([no])
 809   ])
 810 fi
 811
 812 if test "$HAVE_GETHOSTBYNAME" != "1"
 813 then
 814   dnl gethostbyname in the network lib - for Haiku OS
 815   AC_CHECK_LIB(network, gethostbyname,
 816                [HAVE_GETHOSTBYNAME="1"
 817                LIBS="-lnetwork $LIBS"
 818                ])
 819 fi
 820
 821 if test "$HAVE_GETHOSTBYNAME" != "1"
 822 then
 823   dnl gethostbyname in the net lib - for BeOS
 824   AC_CHECK_LIB(net, gethostbyname,
 825                [HAVE_GETHOSTBYNAME="1"
 826                LIBS="-lnet $LIBS"
 827                ])
 828 fi
 829
 830
 831 if test "$HAVE_GETHOSTBYNAME" != "1"; then
 832   AC_MSG_ERROR([couldn't find libraries for gethostbyname()])
 833 fi
 834
 835 dnl resolve lib?
 836 AC_CHECK_FUNC(strcasecmp, , [ AC_CHECK_LIB(resolve, strcasecmp) ])
 837
 838 if test "$ac_cv_lib_resolve_strcasecmp" = "$ac_cv_func_strcasecmp"; then
 839   AC_CHECK_LIB(resolve, strcasecmp,
 840               [LIBS="-lresolve $LIBS"],
 841                ,
 842                -lnsl)
 843 fi
 844 ac_cv_func_strcasecmp="no"
 845
 846 CURL_CHECK_LIBS_CONNECT
 847
 848 CURL_NETWORK_LIBS=$LIBS
 849
 850 dnl **********************************************************************
 851 dnl In case that function clock_gettime with monotonic timer is available,
 852 dnl check for additional required libraries.
 853 dnl **********************************************************************
 854 CURL_CHECK_LIBS_CLOCK_GETTIME_MONOTONIC
 855
 856 dnl **********************************************************************
 857 dnl The preceding library checks are all potentially useful for test
 858 dnl servers and libtest cases which require networking and clock_gettime
 859 dnl support.  Save the list of required libraries at this point for use
 860 dnl while linking those test servers and programs.
 861 dnl **********************************************************************
 862 CURL_NETWORK_AND_TIME_LIBS=$LIBS
 863
 864 dnl **********************************************************************
 865 dnl Check for the presence of ZLIB libraries and headers
 866 dnl **********************************************************************
 867
 868 dnl Check for & handle argument to --with-zlib.
 869
 870 clean_CPPFLAGS=$CPPFLAGS
 871 clean_LDFLAGS=$LDFLAGS
 872 clean_LIBS=$LIBS
 873 ZLIB_LIBS=""
 874 AC_ARG_WITH(zlib,
 875 AC_HELP_STRING([--with-zlib=PATH],[search for zlib in PATH])
 876 AC_HELP_STRING([--without-zlib],[disable use of zlib]),
 877                [OPT_ZLIB="$withval"])
 878
 879 if test "$OPT_ZLIB" = "no" ; then
 880     AC_MSG_WARN([zlib disabled])
 881 else
 882   if test "$OPT_ZLIB" = "yes" ; then
 883     OPT_ZLIB=""
 884   fi
 885
 886   if test -z "$OPT_ZLIB" ; then
 887     dnl check for the lib first without setting any new path, since many
 888     dnl people have it in the default path
 889
 890     AC_CHECK_LIB(z, inflateEnd,
 891                    dnl libz found, set the variable
 892                    [HAVE_LIBZ="1"
 893                     LIBS="-lz $LIBS"],
 894                    dnl if no lib found, try /usr/local
 895                    [OPT_ZLIB="/usr/local"])
 896
 897   fi
 898
 899   dnl Add a nonempty path to the compiler flags
 900   if test -n "$OPT_ZLIB"; then
 901      CPPFLAGS="$CPPFLAGS -I$OPT_ZLIB/include"
 902      LDFLAGS="$LDFLAGS -L$OPT_ZLIB/lib$libsuff"
 903   fi
 904
 905   AC_CHECK_HEADER(zlib.h,
 906     [
 907     dnl zlib.h was found
 908     HAVE_ZLIB_H="1"
 909     dnl if the lib wasn't found already, try again with the new paths
 910     if test "$HAVE_LIBZ" != "1"; then
 911       AC_CHECK_LIB(z, gzread,
 912                    [
 913                    dnl the lib was found!
 914                    HAVE_LIBZ="1"
 915                    LIBS="-lz $LIBS"
 916                    ],
 917                    [ CPPFLAGS=$clean_CPPFLAGS
 918                    LDFLAGS=$clean_LDFLAGS])
 919     fi
 920     ],
 921     [
 922       dnl zlib.h was not found, restore the flags
 923       CPPFLAGS=$clean_CPPFLAGS
 924       LDFLAGS=$clean_LDFLAGS]
 925     )
 926
 927   if test "$HAVE_LIBZ" = "1" && test "$HAVE_ZLIB_H" != "1"
 928   then
 929     AC_MSG_WARN([configure found only the libz lib, not the header file!])
 930     HAVE_LIBZ=""
 931     CPPFLAGS=$clean_CPPFLAGS
 932     LDFLAGS=$clean_LDFLAGS
 933     LIBS=$clean_LIBS
 934   elif test "$HAVE_LIBZ" != "1" && test "$HAVE_ZLIB_H" = "1"
 935   then
 936     AC_MSG_WARN([configure found only the libz header file, not the lib!])
 937     CPPFLAGS=$clean_CPPFLAGS
 938     LDFLAGS=$clean_LDFLAGS
 939     LIBS=$clean_LIBS
 940   elif test "$HAVE_LIBZ" = "1" && test "$HAVE_ZLIB_H" = "1"
 941   then
 942     dnl both header and lib were found!
 943     AC_SUBST(HAVE_LIBZ)
 944     AC_DEFINE(HAVE_ZLIB_H, 1, [if you have the zlib.h header file])
 945     AC_DEFINE(HAVE_LIBZ, 1, [if zlib is available])
 946
 947     ZLIB_LIBS="-lz"
 948     LIBS="-lz $clean_LIBS"
 949
 950     dnl replace 'HAVE_LIBZ' in the automake makefile.ams
 951     AMFIXLIB="1"
 952     AC_MSG_NOTICE([found both libz and libz.h header])
 953     curl_zlib_msg="enabled"
 954   fi
 955 fi
 956
 957 dnl set variable for use in automakefile(s)
 958 AM_CONDITIONAL(HAVE_LIBZ, test x"$AMFIXLIB" = x1)
 959 AC_SUBST(ZLIB_LIBS)
 960
 961 dnl **********************************************************************
 962 dnl Check for LDAP
 963 dnl **********************************************************************
 964
 965 LDAPLIBNAME=""
 966 AC_ARG_WITH(ldap-lib,
 967 AC_HELP_STRING([--with-ldap-lib=libname],[Specify name of ldap lib file]),
 968  [LDAPLIBNAME="$withval"])
 969
 970 LBERLIBNAME=""
 971 AC_ARG_WITH(lber-lib,
 972 AC_HELP_STRING([--with-lber-lib=libname],[Specify name of lber lib file]),
 973  [LBERLIBNAME="$withval"])
 974
 975 if test x$CURL_DISABLE_LDAP != x1 ; then
 976
 977   CURL_CHECK_HEADER_LBER
 978   CURL_CHECK_HEADER_LDAP
 979   CURL_CHECK_HEADER_LDAPSSL
 980   CURL_CHECK_HEADER_LDAP_SSL
 981
 982   if test -z "$LDAPLIBNAME" ; then
 983     if test "$ac_cv_native_windows" = "yes"; then
 984       dnl Windows uses a single and unique LDAP library name
 985       LDAPLIBNAME="wldap32"
 986       LBERLIBNAME="no"
 987     fi
 988   fi
 989
 990   if test "$LDAPLIBNAME" ; then
 991     AC_CHECK_LIB("$LDAPLIBNAME", ldap_init,, [
 992       AC_MSG_WARN(["$LDAPLIBNAME" is not an LDAP library: LDAP disabled])
 993       AC_DEFINE(CURL_DISABLE_LDAP, 1, [to disable LDAP])
 994       AC_SUBST(CURL_DISABLE_LDAP, [1])
 995       AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
 996       AC_SUBST(CURL_DISABLE_LDAPS, [1])])
 997   else
 998     dnl Try to find the right ldap libraries for this system
 999     CURL_CHECK_LIBS_LDAP
1000     case X-"$curl_cv_ldap_LIBS" in
1001       X-unknown)
1002         AC_MSG_WARN([Cannot find libraries for LDAP support: LDAP disabled])
1003         AC_DEFINE(CURL_DISABLE_LDAP, 1, [to disable LDAP])
1004         AC_SUBST(CURL_DISABLE_LDAP, [1])
1005         AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
1006         AC_SUBST(CURL_DISABLE_LDAPS, [1])
1007         ;;
1008     esac
1009   fi
1010 fi
1011
1012 if test x$CURL_DISABLE_LDAP != x1 ; then
1013
1014   if test "$LBERLIBNAME" ; then
1015     dnl If name is "no" then don't define this library at all
1016     dnl (it's only needed if libldap.so's dependencies are broken).
1017     if test "$LBERLIBNAME" != "no" ; then
1018       AC_CHECK_LIB("$LBERLIBNAME", ber_free,, [
1019         AC_MSG_WARN(["$LBERLIBNAME" is not an LBER library: LDAP disabled])
1020         AC_DEFINE(CURL_DISABLE_LDAP, 1, [to disable LDAP])
1021         AC_SUBST(CURL_DISABLE_LDAP, [1])
1022         AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
1023         AC_SUBST(CURL_DISABLE_LDAPS, [1])])
1024     fi
1025   fi
1026 fi
1027
1028 if test x$CURL_DISABLE_LDAP != x1 ; then
1029   AC_CHECK_FUNCS([ldap_url_parse ldap_init_fd])
1030
1031   if test "$LDAPLIBNAME" = "wldap32"; then
1032     curl_ldap_msg="enabled (winldap)"
1033     AC_DEFINE(CURL_LDAP_WIN, 1, [Use Windows LDAP implementation])
1034   else
1035     curl_ldap_msg="enabled (OpenLDAP)"
1036     if test "x$ac_cv_func_ldap_init_fd" = "xyes"; then
1037       AC_DEFINE(USE_OPENLDAP, 1, [Use OpenLDAP-specific code])
1038       AC_SUBST(USE_OPENLDAP, [1])
1039     fi
1040   fi
1041 fi
1042
1043 if test x$CURL_DISABLE_LDAPS != x1 ; then
1044     curl_ldaps_msg="enabled"
1045 fi
1046
1047 dnl **********************************************************************
1048 dnl Checks for IPv6
1049 dnl **********************************************************************
1050
1051 AC_MSG_CHECKING([whether to enable ipv6])
1052 AC_ARG_ENABLE(ipv6,
1053 AC_HELP_STRING([--enable-ipv6],[Enable ipv6 (with ipv4) support])
1054 AC_HELP_STRING([--disable-ipv6],[Disable ipv6 support]),
1055 [ case "$enableval" in
1056   no)
1057        AC_MSG_RESULT(no)
1058        ipv6=no
1059        ;;
1060   *)   AC_MSG_RESULT(yes)
1061        ipv6=yes
1062        ;;
1063   esac ],
1064
1065   AC_TRY_RUN([ /* is AF_INET6 available? */
1066 #include <sys/types.h>
1067 #include <sys/socket.h>
1068 #include <stdlib.h> /* for exit() */
1069 main()
1070 {
1071  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
1072    exit(1);
1073  else
1074    exit(0);
1075 }
1076 ],
1077   AC_MSG_RESULT(yes)
1078   ipv6=yes,
1079   AC_MSG_RESULT(no)
1080   ipv6=no,
1081   AC_MSG_RESULT(no)
1082   ipv6=no
1083 ))
1084
1085 if test "$ipv6" = "yes"; then
1086   curl_ipv6_msg="enabled"
1087 fi
1088
1089 # Check if struct sockaddr_in6 have sin6_scope_id member
1090 if test "$ipv6" = yes; then
1091   AC_MSG_CHECKING([if struct sockaddr_in6 has sin6_scope_id member])
1092   AC_TRY_COMPILE([
1093 #include <sys/types.h>
1094 #include <netinet/in.h>] ,
1095   struct sockaddr_in6 s; s.sin6_scope_id = 0; , have_sin6_scope_id=yes)
1096   if test "$have_sin6_scope_id" = yes; then
1097     AC_MSG_RESULT([yes])
1098     AC_DEFINE(HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID, 1, [Define to 1 if struct sockaddr_in6 has the sin6_scope_id member])
1099   else
1100     AC_MSG_RESULT([no])
1101   fi
1102 fi
1103
1104 dnl **********************************************************************
1105 dnl Check if the operating system allows programs to write to their own argv[]
1106 dnl **********************************************************************
1107
1108 AC_MSG_CHECKING([if argv can be written to])
1109 AC_RUN_IFELSE([
1110   AC_LANG_SOURCE([[
1111 int main(int argc, char ** argv) {
1112     argv[0][0] = ' ';
1113     return (argv[0][0] == ' ')?0:1;
1114 }
1115   ]])
1116 ],[
1117   curl_cv_writable_argv=yes
1118 ],[
1119   curl_cv_writable_argv=no
1120 ],[
1121   curl_cv_writable_argv=cross
1122 ])
1123 case $curl_cv_writable_argv in
1124 yes)
1125         AC_DEFINE(HAVE_WRITABLE_ARGV, 1, [Define this symbol if your OS supports changing the contents of argv])
1126         AC_MSG_RESULT(yes)
1127         ;;
1128 no)
1129         AC_MSG_RESULT(no)
1130         ;;
1131 *)
1132         AC_MSG_RESULT(no)
1133         AC_MSG_WARN([the previous check could not be made default was used])
1134         ;;
1135 esac
1136
1137 dnl **********************************************************************
1138 dnl Check for FBopenssl(SPNEGO) libraries
1139 dnl **********************************************************************
1140
1141 AC_ARG_WITH(spnego,
1142   AC_HELP_STRING([--with-spnego=DIR],
1143                  [Specify location of SPNEGO library fbopenssl]), [
1144   SPNEGO_ROOT="$withval"
1145   if test x"$SPNEGO_ROOT" != xno; then
1146     want_spnego="yes"
1147   fi
1148 ])
1149
1150 AC_MSG_CHECKING([if SPNEGO support is requested])
1151 if test x"$want_spnego" = xyes; then
1152
1153   if test X"$SPNEGO_ROOT" = Xyes; then
1154      AC_MSG_ERROR([FBOpenSSL libs and/or directories were not found where specified!])
1155      AC_MSG_RESULT(no)
1156   else
1157      if test -z "$SPNEGO_LIB_DIR"; then
1158         LDFLAGS="$LDFLAGS -L$SPNEGO_ROOT -lfbopenssl"
1159      else
1160         LDFLAGS="$LDFLAGS $SPNEGO_LIB_DIR"
1161      fi
1162
1163      AC_MSG_RESULT(yes)
1164      AC_DEFINE(HAVE_SPNEGO, 1,
1165                [Define this if you have the SPNEGO library fbopenssl])
1166      curl_spnego_msg="enabled"
1167   fi
1168 else
1169   AC_MSG_RESULT(no)
1170 fi
1171
1172 dnl **********************************************************************
1173 dnl Check for GSS-API libraries
1174 dnl **********************************************************************
1175
1176 dnl check for gss stuff in the /usr as default
1177
1178 GSSAPI_ROOT="/usr"
1179 AC_ARG_WITH(gssapi-includes,
1180   AC_HELP_STRING([--with-gssapi-includes=DIR],
1181                  [Specify location of GSSAPI header]),
1182   [ GSSAPI_INCS="-I$withval"
1183     want_gss="yes" ]
1184 )
1185
1186 AC_ARG_WITH(gssapi-libs,
1187   AC_HELP_STRING([--with-gssapi-libs=DIR],
1188                  [Specify location of GSSAPI libs]),
1189   [ GSSAPI_LIB_DIR="-L$withval"
1190     want_gss="yes" ]
1191 )
1192
1193 AC_ARG_WITH(gssapi,
1194   AC_HELP_STRING([--with-gssapi=DIR],
1195                  [Where to look for GSSAPI]), [
1196   GSSAPI_ROOT="$withval"
1197   if test x"$GSSAPI_ROOT" != xno; then
1198     want_gss="yes"
1199     if test x"$GSSAPI_ROOT" = xyes; then
1200       dnl if yes, then use default root
1201       GSSAPI_ROOT="/usr"
1202     fi
1203   fi
1204 ])
1205
1206 save_CPPFLAGS="$CPPFLAGS"
1207 AC_MSG_CHECKING([if GSSAPI support is requested])
1208 if test x"$want_gss" = xyes; then
1209   AC_MSG_RESULT(yes)
1210
1211   if test -z "$GSSAPI_INCS"; then
1212      if test -f "$GSSAPI_ROOT/bin/krb5-config"; then
1213         GSSAPI_INCS=`$GSSAPI_ROOT/bin/krb5-config --cflags gssapi`
1214      elif test "$GSSAPI_ROOT" != "yes"; then
1215         GSSAPI_INCS="-I$GSSAPI_ROOT/include"
1216      fi
1217   fi
1218
1219   CPPFLAGS="$CPPFLAGS $GSSAPI_INCS"
1220
1221   AC_CHECK_HEADER(gss.h,
1222     [
1223       dnl found in the given dirs
1224       AC_DEFINE(HAVE_GSSGNU, 1, [if you have the GNU gssapi libraries])
1225       gnu_gss=yes
1226     ],
1227     [
1228       dnl not found, check Heimdal or MIT
1229       AC_CHECK_HEADERS([gssapi/gssapi.h], [], [not_mit=1])
1230       AC_CHECK_HEADERS(
1231         [gssapi/gssapi_generic.h gssapi/gssapi_krb5.h],
1232         [],
1233         [not_mit=1],
1234         [
1235 AC_INCLUDES_DEFAULT
1236 #ifdef HAVE_GSSAPI_GSSAPI_H
1237 #include <gssapi/gssapi.h>
1238 #endif
1239         ])
1240       if test "x$not_mit" = "x1"; then
1241         dnl MIT not found, check for Heimdal
1242         AC_CHECK_HEADER(gssapi.h,
1243             [
1244               dnl found
1245               AC_DEFINE(HAVE_GSSHEIMDAL, 1, [if you have the Heimdal gssapi libraries])
1246             ],
1247             [
1248               dnl no header found, disabling GSS
1249               want_gss=no
1250               AC_MSG_WARN(disabling GSSAPI since no header files was found)
1251             ]
1252           )
1253       else
1254         dnl MIT found
1255         AC_DEFINE(HAVE_GSSMIT, 1, [if you have the MIT gssapi libraries])
1256         dnl check if we have a really old MIT kerberos (<= 1.2)
1257         AC_MSG_CHECKING([if gssapi headers declare GSS_C_NT_HOSTBASED_SERVICE])
1258         AC_COMPILE_IFELSE([
1259           AC_LANG_PROGRAM([[
1260 #include <gssapi/gssapi.h>
1261 #include <gssapi/gssapi_generic.h>
1262 #include <gssapi/gssapi_krb5.h>
1263           ]],[[
1264             gss_import_name(
1265                             (OM_uint32 *)0,
1266                             (gss_buffer_t)0,
1267                             GSS_C_NT_HOSTBASED_SERVICE,
1268                             (gss_name_t *)0);
1269           ]])
1270         ],[
1271           AC_MSG_RESULT([yes])
1272         ],[
1273           AC_MSG_RESULT([no])
1274           AC_DEFINE(HAVE_OLD_GSSMIT, 1,
1275             [if you have an old MIT gssapi library, lacking GSS_C_NT_HOSTBASED_SERVICE])
1276         ])
1277       fi
1278     ]
1279   )
1280 else
1281   AC_MSG_RESULT(no)
1282 fi
1283 if test x"$want_gss" = xyes; then
1284   AC_DEFINE(HAVE_GSSAPI, 1, [if you have the gssapi libraries])
1285
1286   curl_gss_msg="enabled (MIT/Heimdal)"
1287
1288   if test -n "$gnu_gss"; then
1289     curl_gss_msg="enabled (GNU GSS)"
1290     LDFLAGS="$LDFLAGS $GSSAPI_LIB_DIR"
1291     LIBS="-lgss $LIBS"
1292   elif test -z "$GSSAPI_LIB_DIR"; then
1293      case $host in
1294      *-*-darwin*)
1295         LIBS="-lgssapi_krb5 -lresolv $LIBS"
1296         ;;
1297      *-hp-hpux*)
1298         if test "$GSSAPI_ROOT" != "yes"; then
1299            LDFLAGS="$LDFLAGS -L$GSSAPI_ROOT/lib$libsuff"
1300         fi
1301         LIBS="-lgss $LIBS"
1302         ;;
1303      *)
1304         if test -f "$GSSAPI_ROOT/bin/krb5-config"; then
1305            dnl krb5-config doesn't have --libs-only-L or similar, put everything
1306            dnl into LIBS
1307            gss_libs=`$GSSAPI_ROOT/bin/krb5-config --libs gssapi`
1308            LIBS="$gss_libs $LIBS"
1309         elif test "$GSSAPI_ROOT" != "yes"; then
1310            LDFLAGS="$LDFLAGS -L$GSSAPI_ROOT/lib$libsuff"
1311            LIBS="-lgssapi $LIBS"
1312         else
1313            LIBS="-lgssapi $LIBS"
1314         fi
1315         ;;
1316      esac
1317   else
1318      LDFLAGS="$LDFLAGS $GSSAPI_LIB_DIR"
1319      case $host in
1320      *-hp-hpux*)
1321         LIBS="-lgss $LIBS"
1322         ;;
1323      *)
1324         LIBS="-lgssapi $LIBS"
1325         ;;
1326      esac
1327   fi
1328 else
1329   CPPFLAGS="$save_CPPFLAGS"
1330 fi
1331
1332 dnl -------------------------------------------------
1333 dnl check winssl option before other SSL libraries
1334 dnl -------------------------------------------------
1335
1336 OPT_WINSSL=no
1337 AC_ARG_WITH(winssl,dnl
1338 AC_HELP_STRING([--with-winssl],[enable Windows native SSL/TLS])
1339 AC_HELP_STRING([--without-winssl], [disable Windows native SSL/TLS]),
1340   OPT_WINSSL=$withval)
1341
1342 AC_MSG_CHECKING([whether to enable Windows native SSL/TLS (Windows native builds only)])
1343 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1344   if test "x$OPT_WINSSL" != "xno"  &&
1345      test "x$ac_cv_native_windows" = "xyes"; then
1346     AC_MSG_RESULT(yes)
1347     AC_DEFINE(USE_SCHANNEL, 1, [to enable Windows native SSL/TLS support])
1348     AC_SUBST(USE_SCHANNEL, [1])
1349     curl_ssl_msg="enabled (Windows-native)"
1350     WINSSL_ENABLED=1
1351     # --with-winssl implies --enable-sspi
1352     AC_DEFINE(USE_WINDOWS_SSPI, 1, [to enable SSPI support])
1353     AC_SUBST(USE_WINDOWS_SSPI, [1])
1354     curl_sspi_msg="enabled"
1355   else
1356     AC_MSG_RESULT(no)
1357   fi
1358 else
1359   AC_MSG_RESULT(no)
1360 fi
1361
1362 OPT_DARWINSSL=no
1363 AC_ARG_WITH(darwinssl,dnl
1364 AC_HELP_STRING([--with-darwinssl],[enable iOS/Mac OS X native SSL/TLS])
1365 AC_HELP_STRING([--without-darwinssl], [disable iOS/Mac OS X native SSL/TLS]),
1366   OPT_DARWINSSL=$withval)
1367
1368 AC_MSG_CHECKING([whether to enable iOS/Mac OS X native SSL/TLS])
1369 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1370   if test "x$OPT_DARWINSSL" != "xno" &&
1371      test -d "/System/Library/Frameworks/Security.framework"; then
1372     AC_MSG_RESULT(yes)
1373     AC_DEFINE(USE_DARWINSSL, 1, [to enable iOS/Mac OS X native SSL/TLS support])
1374     AC_SUBST(USE_DARWINSSL, [1])
1375     curl_ssl_msg="enabled (iOS/Mac OS X-native)"
1376     DARWINSSL_ENABLED=1
1377     LDFLAGS="$LDFLAGS -framework CoreFoundation -framework Security"
1378   else
1379     AC_MSG_RESULT(no)
1380   fi
1381 else
1382   AC_MSG_RESULT(no)
1383 fi
1384
1385 dnl **********************************************************************
1386 dnl Check for the presence of SSL libraries and headers
1387 dnl **********************************************************************
1388
1389 dnl Default to compiler & linker defaults for SSL files & libraries.
1390 OPT_SSL=off
1391 dnl Default to no CA bundle
1392 ca="no"
1393 AC_ARG_WITH(ssl,dnl
1394 AC_HELP_STRING([--with-ssl=PATH],[Where to look for OpenSSL, PATH points to the SSL installation (default: /usr/local/ssl); when possible, set the PKG_CONFIG_PATH environment variable instead of using this option])
1395 AC_HELP_STRING([--without-ssl], [disable OpenSSL]),
1396   OPT_SSL=$withval)
1397
1398 if test "$curl_ssl_msg" = "$init_ssl_msg" && test X"$OPT_SSL" != Xno; then
1399   dnl backup the pre-ssl variables
1400   CLEANLDFLAGS="$LDFLAGS"
1401   CLEANCPPFLAGS="$CPPFLAGS"
1402   CLEANLIBS="$LIBS"
1403
1404   case "$OPT_SSL" in
1405   yes)
1406     dnl --with-ssl (without path) used
1407     if test x$cross_compiling != xyes; then
1408       dnl only do pkg-config magic when not cross-compiling
1409       PKGTEST="yes"
1410     fi
1411     PREFIX_OPENSSL=/usr/local/ssl
1412     LIB_OPENSSL="$PREFIX_OPENSSL/lib$libsuff"
1413     ;;
1414   off)
1415     dnl no --with-ssl option given, just check default places
1416     if test x$cross_compiling != xyes; then
1417       dnl only do pkg-config magic when not cross-compiling
1418       PKGTEST="yes"
1419     fi
1420     PREFIX_OPENSSL=
1421     ;;
1422   *)
1423     dnl check the given --with-ssl spot
1424     PKGTEST="no"
1425     PREFIX_OPENSSL=$OPT_SSL
1426
1427     dnl Try pkg-config even when cross-compiling.  Since we
1428     dnl specify PKG_CONFIG_LIBDIR we're only looking where
1429     dnl the user told us to look
1430     OPENSSL_PCDIR="$OPT_SSL/lib/pkgconfig"
1431     AC_MSG_NOTICE([PKG_CONFIG_LIBDIR will be set to "$OPENSSL_PCDIR"])
1432     if test -f "$OPENSSL_PCDIR/openssl.pc"; then
1433       PKGTEST="yes"
1434     fi
1435
1436     dnl in case pkg-config comes up empty, use what we got
1437     dnl via --with-ssl
1438     LIB_OPENSSL="$PREFIX_OPENSSL/lib$libsuff"
1439     if test "$PREFIX_OPENSSL" != "/usr" ; then
1440       SSL_LDFLAGS="-L$LIB_OPENSSL"
1441       SSL_CPPFLAGS="-I$PREFIX_OPENSSL/include"
1442     fi
1443     SSL_CPPFLAGS="$SSL_CPPFLAGS -I$PREFIX_OPENSSL/include/openssl"
1444     ;;
1445   esac
1446
1447   if test "$PKGTEST" = "yes"; then
1448
1449     CURL_CHECK_PKGCONFIG(openssl, [$OPENSSL_PCDIR])
1450
1451     if test "$PKGCONFIG" != "no" ; then
1452       SSL_LIBS=`CURL_EXPORT_PCDIR([$OPENSSL_PCDIR]) dnl
1453         $PKGCONFIG --libs-only-l openssl 2>/dev/null`
1454
1455       SSL_LDFLAGS=`CURL_EXPORT_PCDIR([$OPENSSL_PCDIR]) dnl
1456         $PKGCONFIG --libs-only-L openssl 2>/dev/null`
1457
1458       SSL_CPPFLAGS=`CURL_EXPORT_PCDIR([$OPENSSL_PCDIR]) dnl
1459         $PKGCONFIG --cflags-only-I openssl 2>/dev/null`
1460
1461       AC_MSG_NOTICE([pkg-config: SSL_LIBS: "$SSL_LIBS"])
1462       AC_MSG_NOTICE([pkg-config: SSL_LDFLAGS: "$SSL_LDFLAGS"])
1463       AC_MSG_NOTICE([pkg-config: SSL_CPPFLAGS: "$SSL_CPPFLAGS"])
1464
1465       LIB_OPENSSL=`echo $SSL_LDFLAGS | sed -e 's/-L//g'`
1466
1467       dnl use the values pkg-config reported.  This is here
1468       dnl instead of below with CPPFLAGS and LDFLAGS because we only
1469       dnl learn about this via pkg-config.  If we only have
1470       dnl the argument to --with-ssl we don't know what
1471       dnl additional libs may be necessary.  Hope that we
1472       dnl don't need any.
1473       LIBS="$SSL_LIBS $LIBS"
1474     fi
1475   fi
1476
1477   dnl finally, set flags to use SSL
1478   CPPFLAGS="$CPPFLAGS $SSL_CPPFLAGS"
1479   LDFLAGS="$LDFLAGS $SSL_LDFLAGS"
1480
1481   dnl This is for Msys/Mingw
1482   case $host in
1483     *-*-msys* | *-*-mingw*)
1484       AC_MSG_CHECKING([for gdi32])
1485       my_ac_save_LIBS=$LIBS
1486       LIBS="-lgdi32 $LIBS"
1487       AC_TRY_LINK([#include <windef.h>
1488                    #include <wingdi.h>],
1489                    [GdiFlush();],
1490                    [ dnl worked!
1491                    AC_MSG_RESULT([yes])],
1492                    [ dnl failed, restore LIBS
1493                    LIBS=$my_ac_save_LIBS
1494                    AC_MSG_RESULT(no)]
1495                   )
1496       ;;
1497   esac
1498
1499   AC_CHECK_LIB(crypto, CRYPTO_lock,[
1500      HAVECRYPTO="yes"
1501      LIBS="-lcrypto $LIBS"
1502      ],[
1503      LDFLAGS="$CLEANLDFLAGS -L$LIB_OPENSSL"
1504      CPPFLAGS="$CLEANCPPFLAGS -I$PREFIX_OPENSSL/include/openssl -I$PREFIX_OPENSSL/include"
1505      AC_CHECK_LIB(crypto, CRYPTO_add_lock,[
1506        HAVECRYPTO="yes"
1507        LIBS="-lcrypto $LIBS"], [
1508        LDFLAGS="$CLEANLDFLAGS"
1509        CPPFLAGS="$CLEANCPPFLAGS"
1510        LIBS="$CLEANLIBS"
1511        ])
1512     ])
1513
1514
1515   if test X"$HAVECRYPTO" = X"yes"; then
1516     dnl This is only reasonable to do if crypto actually is there: check for
1517     dnl SSL libs NOTE: it is important to do this AFTER the crypto lib
1518
1519     AC_CHECK_LIB(ssl, SSL_connect)
1520
1521     if test "$ac_cv_lib_ssl_SSL_connect" != yes; then
1522         dnl we didn't find the SSL lib, try the RSAglue/rsaref stuff
1523         AC_MSG_CHECKING(for ssl with RSAglue/rsaref libs in use);
1524         OLIBS=$LIBS
1525         LIBS="-lRSAglue -lrsaref $LIBS"
1526         AC_CHECK_LIB(ssl, SSL_connect)
1527         if test "$ac_cv_lib_ssl_SSL_connect" != yes; then
1528             dnl still no SSL_connect
1529             AC_MSG_RESULT(no)
1530             LIBS=$OLIBS
1531         else
1532             AC_MSG_RESULT(yes)
1533         fi
1534
1535     else
1536
1537       dnl Have the libraries--check for SSLeay/OpenSSL headers
1538       AC_CHECK_HEADERS(openssl/x509.h openssl/rsa.h openssl/crypto.h \
1539                        openssl/pem.h openssl/ssl.h openssl/err.h,
1540         curl_ssl_msg="enabled (OpenSSL)"
1541         OPENSSL_ENABLED=1
1542         AC_DEFINE(USE_OPENSSL, 1, [if OpenSSL is in use]))
1543
1544       if test $ac_cv_header_openssl_x509_h = no; then
1545         dnl we don't use the "action" part of the AC_CHECK_HEADERS macro
1546         dnl since 'err.h' might in fact find a krb4 header with the same
1547         dnl name
1548         AC_CHECK_HEADERS(x509.h rsa.h crypto.h pem.h ssl.h err.h)
1549
1550         if test $ac_cv_header_x509_h = yes &&
1551            test $ac_cv_header_crypto_h = yes &&
1552            test $ac_cv_header_ssl_h = yes; then
1553           dnl three matches
1554           curl_ssl_msg="enabled (OpenSSL)"
1555           OPENSSL_ENABLED=1
1556         fi
1557       fi
1558     fi
1559
1560     if test X"$OPENSSL_ENABLED" = X"1"; then
1561        AC_DEFINE(USE_SSLEAY, 1, [if SSL is enabled])
1562
1563        dnl is there a pkcs12.h header present?
1564        AC_CHECK_HEADERS(openssl/pkcs12.h)
1565     else
1566        LIBS="$CLEANLIBS"
1567     fi
1568     dnl USE_SSLEAY is the historical name for what configure calls
1569     dnl OPENSSL_ENABLED; the names should really be unified
1570     USE_SSLEAY="$OPENSSL_ENABLED"
1571     AC_SUBST(USE_SSLEAY)
1572
1573     if test X"$OPT_SSL" != Xoff &&
1574        test "$OPENSSL_ENABLED" != "1"; then
1575       AC_MSG_ERROR([OpenSSL libs and/or directories were not found where specified!])
1576     fi
1577   fi
1578
1579   if test X"$OPENSSL_ENABLED" = X"1"; then
1580     dnl If the ENGINE library seems to be around, check for the OpenSSL engine
1581     dnl stuff, it is kind of "separated" from the main SSL check
1582     AC_CHECK_FUNC(ENGINE_init,
1583               [
1584                 AC_CHECK_HEADERS(openssl/engine.h)
1585                 AC_CHECK_FUNCS( ENGINE_load_builtin_engines )
1586               ])
1587
1588     dnl these can only exist if openssl exists
1589     dnl yassl doesn't have SSL_get_shutdown
1590
1591     AC_CHECK_FUNCS( RAND_status \
1592                     RAND_screen \
1593                     RAND_egd \
1594                     ENGINE_cleanup \
1595                     CRYPTO_cleanup_all_ex_data \
1596                     SSL_get_shutdown \
1597                     SSLv2_client_method \
1598                     SSL_CTX_set_next_proto_select_cb )
1599
1600     dnl Make an attempt to detect if this is actually yassl's headers and
1601     dnl OpenSSL emulation layer. We still leave everything else believing
1602     dnl and acting like OpenSSL.
1603
1604     AC_MSG_CHECKING([for yaSSL using OpenSSL compatibility mode])
1605     AC_COMPILE_IFELSE([
1606       AC_LANG_PROGRAM([[
1607 #include <openssl/ssl.h>
1608       ]],[[
1609 #if defined(YASSL_VERSION) && defined(OPENSSL_VERSION_NUMBER)
1610         int dummy = SSL_ERROR_NONE;
1611 #else
1612         Not the yaSSL OpenSSL compatibility header.
1613 #endif
1614       ]])
1615     ],[
1616       AC_MSG_RESULT([yes])
1617       AC_DEFINE_UNQUOTED(USE_YASSLEMUL, 1,
1618         [Define to 1 if using yaSSL in OpenSSL compatibility mode.])
1619       curl_ssl_msg="enabled (OpenSSL emulation by yaSSL)"
1620     ],[
1621       AC_MSG_RESULT([no])
1622     ])
1623   fi
1624
1625   if test "$OPENSSL_ENABLED" = "1"; then
1626     if test -n "$LIB_OPENSSL"; then
1627        dnl when the ssl shared libs were found in a path that the run-time
1628        dnl linker doesn't search through, we need to add it to LD_LIBRARY_PATH
1629        dnl to prevent further configure tests to fail due to this
1630        if test "x$cross_compiling" != "xyes"; then
1631          LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$LIB_OPENSSL"
1632          export LD_LIBRARY_PATH
1633          AC_MSG_NOTICE([Added $LIB_OPENSSL to LD_LIBRARY_PATH])
1634        fi
1635     fi
1636     CURL_CHECK_OPENSSL_API
1637   fi
1638
1639 fi
1640
1641 dnl **********************************************************************
1642 dnl Check for the random seed preferences
1643 dnl **********************************************************************
1644
1645 if test X"$OPENSSL_ENABLED" = X"1"; then
1646   AC_ARG_WITH(egd-socket,
1647   AC_HELP_STRING([--with-egd-socket=FILE],
1648                  [Entropy Gathering Daemon socket pathname]),
1649       [ EGD_SOCKET="$withval" ]
1650   )
1651   if test -n "$EGD_SOCKET" ; then
1652           AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET",
1653           [your Entropy Gathering Daemon socket pathname] )
1654   fi
1655
1656   dnl Check for user-specified random device
1657   AC_ARG_WITH(random,
1658   AC_HELP_STRING([--with-random=FILE],
1659                  [read randomness from FILE (default=/dev/urandom)]),
1660       [ RANDOM_FILE="$withval" ],
1661       [
1662           if test x$cross_compiling != xyes; then
1663             dnl Check for random device
1664             AC_CHECK_FILE("/dev/urandom", [ RANDOM_FILE="/dev/urandom"] )
1665           else
1666             AC_MSG_WARN([skipped the /dev/urandom detection when cross-compiling])
1667           fi
1668       ]
1669   )
1670   if test -n "$RANDOM_FILE" && test X"$RANDOM_FILE" != Xno ; then
1671           AC_SUBST(RANDOM_FILE)
1672           AC_DEFINE_UNQUOTED(RANDOM_FILE, "$RANDOM_FILE",
1673           [a suitable file to read random data from])
1674   fi
1675 fi
1676
1677 dnl ---
1678 dnl We require OpenSSL with SRP support.
1679 dnl ---
1680 if test "$OPENSSL_ENABLED" = "1"; then
1681   AC_CHECK_LIB(crypto, SRP_Calc_client_key,
1682    [
1683      AC_DEFINE(HAVE_SSLEAY_SRP, 1, [if you have the function SRP_Calc_client_key])
1684      AC_SUBST(HAVE_SSLEAY_SRP, [1])
1685    ])
1686 fi
1687
1688 dnl ----------------------------------------------------
1689 dnl check for GnuTLS
1690 dnl ----------------------------------------------------
1691
1692 dnl Default to compiler & linker defaults for GnuTLS files & libraries.
1693 OPT_GNUTLS=no
1694
1695 AC_ARG_WITH(gnutls,dnl
1696 AC_HELP_STRING([--with-gnutls=PATH],[where to look for GnuTLS, PATH points to the installation root])
1697 AC_HELP_STRING([--without-gnutls], [disable GnuTLS detection]),
1698   OPT_GNUTLS=$withval)
1699
1700 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1701
1702   if test X"$OPT_GNUTLS" != Xno; then
1703
1704     addld=""
1705     addlib=""
1706     gtlslib=""
1707     version=""
1708     addcflags=""
1709
1710     if test "x$OPT_GNUTLS" = "xyes"; then
1711       dnl this is with no partiular path given
1712       CURL_CHECK_PKGCONFIG(gnutls)
1713
1714       if test "$PKGCONFIG" != "no" ; then
1715         addlib=`$PKGCONFIG --libs-only-l gnutls`
1716         addld=`$PKGCONFIG --libs-only-L gnutls`
1717         addcflags=`$PKGCONFIG --cflags-only-I gnutls`
1718         version=`$PKGCONFIG --modversion gnutls`
1719         gtlslib=`echo $addld | $SED -e 's/-L//'`
1720       else
1721         dnl without pkg-config, we try libgnutls-config as that was how it
1722         dnl used to be done
1723         check=`libgnutls-config --version 2>/dev/null`
1724         if test -n "$check"; then
1725           addlib=`libgnutls-config --libs`
1726           addcflags=`libgnutls-config --cflags`
1727           version=`libgnutls-config --version`
1728           gtlslib=`libgnutls-config --prefix`/lib$libsuff
1729         fi
1730       fi
1731     else
1732       dnl this is with a given path, first check if there's a libgnutls-config
1733       dnl there and if not, make an educated guess
1734       cfg=$OPT_GNUTLS/bin/libgnutls-config
1735       check=`$cfg --version 2>/dev/null`
1736       if test -n "$check"; then
1737         addlib=`$cfg --libs`
1738         addcflags=`$cfg --cflags`
1739         version=`$cfg --version`
1740         gtlslib=`$cfg --prefix`/lib$libsuff
1741       else
1742         dnl without pkg-config and libgnutls-config, we guess a lot!
1743         addlib=-lgnutls
1744         addld=-L$OPT_GNUTLS/lib$libsuff
1745         addcflags=-I$OPT_GNUTLS/include
1746         version="" # we just don't know
1747         gtlslib=$OPT_GNUTLS/lib$libsuff
1748       fi
1749     fi
1750
1751     if test -z "$version"; then
1752       dnl lots of efforts, still no go
1753       version="unknown"
1754     fi
1755
1756     if test -n "$addlib"; then
1757
1758       CLEANLIBS="$LIBS"
1759       CLEANCPPFLAGS="$CPPFLAGS"
1760       CLEANLDFLAGS="$LDFLAGS"
1761
1762       LIBS="$addlib $LIBS"
1763       LDFLAGS="$LDFLAGS $addld"
1764       if test "$addcflags" != "-I/usr/include"; then
1765          CPPFLAGS="$CPPFLAGS $addcflags"
1766       fi
1767
1768       AC_CHECK_LIB(gnutls, gnutls_check_version,
1769        [
1770        AC_DEFINE(USE_GNUTLS, 1, [if GnuTLS is enabled])
1771        AC_SUBST(USE_GNUTLS, [1])
1772        GNUTLS_ENABLED=1
1773        USE_GNUTLS="yes"
1774        curl_ssl_msg="enabled (GnuTLS)"
1775        ],
1776        [
1777          LIBS="$CLEANLIBS"
1778          CPPFLAGS="$CLEANCPPFLAGS"
1779        ])
1780
1781       if test "x$USE_GNUTLS" = "xyes"; then
1782         AC_MSG_NOTICE([detected GnuTLS version $version])
1783
1784         if test -n "$gtlslib"; then
1785           dnl when shared libs were found in a path that the run-time
1786           dnl linker doesn't search through, we need to add it to
1787           dnl LD_LIBRARY_PATH to prevent further configure tests to fail
1788           dnl due to this
1789           if test "x$cross_compiling" != "xyes"; then
1790             LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$gtlslib"
1791             export LD_LIBRARY_PATH
1792             AC_MSG_NOTICE([Added $gtlslib to LD_LIBRARY_PATH])
1793           fi
1794         fi
1795       fi
1796
1797     fi
1798
1799   fi dnl GNUTLS not disabled
1800
1801 fi
1802
1803 dnl ---
1804 dnl Check which crypto backend GnuTLS uses
1805 dnl ---
1806
1807 if test "$GNUTLS_ENABLED" = "1"; then
1808   USE_GNUTLS_NETTLE=
1809   # First check if we can detect either crypto library via transitive linking
1810   AC_CHECK_LIB(gnutls, nettle_MD5Init, [ USE_GNUTLS_NETTLE=1 ])
1811   if test "$USE_GNUTLS_NETTLE" = ""; then
1812     AC_CHECK_LIB(gnutls, gcry_control, [ USE_GNUTLS_NETTLE=0 ])
1813   fi
1814   # If not, try linking directly to both of them to see if they are available
1815   if test "$USE_GNUTLS_NETTLE" = ""; then
1816     AC_CHECK_LIB(nettle, nettle_MD5Init, [ USE_GNUTLS_NETTLE=1 ])
1817   fi
1818   if test "$USE_GNUTLS_NETTLE" = ""; then
1819     AC_CHECK_LIB(gcrypt, gcry_control, [ USE_GNUTLS_NETTLE=0 ])
1820   fi
1821   if test "$USE_GNUTLS_NETTLE" = ""; then
1822     AC_MSG_ERROR([GnuTLS found, but neither gcrypt nor nettle found])
1823   fi
1824   if test "$USE_GNUTLS_NETTLE" = "1"; then
1825     AC_DEFINE(USE_GNUTLS_NETTLE, 1, [if GnuTLS uses nettle as crypto backend])
1826     AC_SUBST(USE_GNUTLS_NETTLE, [1])
1827     LIBS="-lnettle $LIBS"
1828   else
1829     LIBS="-lgcrypt $LIBS"
1830   fi
1831 fi
1832
1833 dnl ---
1834 dnl We require GnuTLS with SRP support.
1835 dnl ---
1836 if test "$GNUTLS_ENABLED" = "1"; then
1837   AC_CHECK_LIB(gnutls, gnutls_srp_verifier,
1838    [
1839      AC_DEFINE(HAVE_GNUTLS_SRP, 1, [if you have the function gnutls_srp_verifier])
1840      AC_SUBST(HAVE_GNUTLS_SRP, [1])
1841    ])
1842 fi
1843
1844 dnl ----------------------------------------------------
1845 dnl check for PolarSSL
1846 dnl ----------------------------------------------------
1847
1848 dnl Default to compiler & linker defaults for PolarSSL files & libraries.
1849 OPT_POLARSSL=no
1850
1851 _cppflags=$CPPFLAGS
1852 _ldflags=$LDFLAGS
1853 AC_ARG_WITH(polarssl,dnl
1854 AC_HELP_STRING([--with-polarssl=PATH],[where to look for PolarSSL, PATH points to the installation root])
1855 AC_HELP_STRING([--without-polarssl], [disable PolarSSL detection]),
1856   OPT_POLARSSL=$withval)
1857
1858 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1859
1860   if test X"$OPT_POLARSSL" != Xno; then
1861
1862     if test "$OPT_POLARSSL" = "yes"; then
1863       OPT_POLARSSL=""
1864     fi
1865
1866     if test -z "$OPT_POLARSSL" ; then
1867       dnl check for lib first without setting any new path
1868
1869       AC_CHECK_LIB(polarssl, havege_init,
1870       dnl libpolarssl found, set the variable
1871        [
1872          AC_DEFINE(USE_POLARSSL, 1, [if PolarSSL is enabled])
1873          AC_SUBST(USE_POLARSSL, [1])
1874          POLARSSL_ENABLED=1
1875          USE_POLARSSL="yes"
1876          curl_ssl_msg="enabled (PolarSSL)"
1877         ])
1878     fi
1879
1880     addld=""
1881     addlib=""
1882     addcflags=""
1883     polarssllib=""
1884
1885     if test "x$USE_POLARSSL" != "xyes"; then
1886       dnl add the path and test again
1887       addld=-L$OPT_POLARSSL/lib$libsuff
1888       addcflags=-I$OPT_POLARSSL/include
1889       polarssllib=$OPT_POLARSSL/lib$libsuff
1890
1891       LDFLAGS="$LDFLAGS $addld"
1892       if test "$addcflags" != "-I/usr/include"; then
1893          CPPFLAGS="$CPPFLAGS $addcflags"
1894       fi
1895
1896       AC_CHECK_LIB(polarssl, ssl_init,
1897        [
1898        AC_DEFINE(USE_POLARSSL, 1, [if PolarSSL is enabled])
1899        AC_SUBST(USE_POLARSSL, [1])
1900        POLARSSL_ENABLED=1
1901        USE_POLARSSL="yes"
1902        curl_ssl_msg="enabled (PolarSSL)"
1903        ],
1904        [
1905          CPPFLAGS=$_cppflags
1906          LDFLAGS=$_ldflags
1907        ])
1908     fi
1909
1910     if test "x$USE_POLARSSL" = "xyes"; then
1911       AC_MSG_NOTICE([detected PolarSSL])
1912
1913       LIBS="-lpolarssl $LIBS"
1914
1915       if test -n "$polarssllib"; then
1916         dnl when shared libs were found in a path that the run-time
1917         dnl linker doesn't search through, we need to add it to
1918         dnl LD_LIBRARY_PATH to prevent further configure tests to fail
1919         dnl due to this
1920         if test "x$cross_compiling" != "xyes"; then
1921           LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$polarssllib"
1922           export LD_LIBRARY_PATH
1923           AC_MSG_NOTICE([Added $polarssllib to LD_LIBRARY_PATH])
1924         fi
1925       fi
1926     fi
1927
1928   fi dnl PolarSSL not disabled
1929
1930 fi
1931
1932 dnl ----------------------------------------------------
1933 dnl check for CyaSSL
1934 dnl ----------------------------------------------------
1935
1936 dnl Default to compiler & linker defaults for CyaSSL files & libraries.
1937 OPT_CYASSL=no
1938
1939 _cppflags=$CPPFLAGS
1940 _ldflags=$LDFLAGS
1941 AC_ARG_WITH(cyassl,dnl
1942 AC_HELP_STRING([--with-cyassl=PATH],[where to look for CyaSSL, PATH points to the installation root (default: system lib default)])
1943 AC_HELP_STRING([--without-cyassl], [disable CyaSSL detection]),
1944   OPT_CYASSL=$withval)
1945
1946 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1947
1948   if test X"$OPT_CYASSL" != Xno; then
1949
1950     if test "$OPT_CYASSL" = "yes"; then
1951       OPT_CYASSL=""
1952     fi
1953
1954     if test -z "$OPT_CYASSL" ; then
1955       dnl check for lib in system default first
1956
1957       AC_CHECK_LIB(cyassl, CyaSSL_Init,
1958       dnl libcyassl found, set the variable
1959        [
1960          AC_DEFINE(USE_CYASSL, 1, [if CyaSSL is enabled])
1961          AC_SUBST(USE_CYASSL, [1])
1962          CYASSL_ENABLED=1
1963          USE_CYASSL="yes"
1964          curl_ssl_msg="enabled (CyaSSL)"
1965         ])
1966     fi
1967
1968     addld=""
1969     addlib=""
1970     addcflags=""
1971     cyassllib=""
1972
1973     if test "x$USE_CYASSL" != "xyes"; then
1974       dnl add the path and test again
1975       addld=-L$OPT_CYASSL/lib$libsuff
1976       addcflags=-I$OPT_CYASSL/include
1977       cyassllib=$OPT_CYASSL/lib$libsuff
1978
1979       LDFLAGS="$LDFLAGS $addld"
1980       if test "$addcflags" != "-I/usr/include"; then
1981          CPPFLAGS="$CPPFLAGS $addcflags"
1982       fi
1983
1984       AC_CHECK_LIB(cyassl, CyaSSL_Init,
1985        [
1986        AC_DEFINE(USE_CYASSL, 1, [if CyaSSL is enabled])
1987        AC_SUBST(USE_CYASSL, [1])
1988        CYASSL_ENABLED=1
1989        USE_CYASSL="yes"
1990        curl_ssl_msg="enabled (CyaSSL)"
1991        ],
1992        [
1993          CPPFLAGS=$_cppflags
1994          LDFLAGS=$_ldflags
1995        ])
1996     fi
1997
1998     if test "x$USE_CYASSL" = "xyes"; then
1999       AC_MSG_NOTICE([detected CyaSSL])
2000
2001       dnl cyassl/ctaocrypt/types.h needs SIZEOF_LONG_LONG defined!
2002       AC_CHECK_SIZEOF(long long)
2003
2004       LIBS="-lcyassl -lm $LIBS"
2005
2006       if test -n "$cyassllib"; then
2007         dnl when shared libs were found in a path that the run-time
2008         dnl linker doesn't search through, we need to add it to
2009         dnl LD_LIBRARY_PATH to prevent further configure tests to fail
2010         dnl due to this
2011         if test "x$cross_compiling" != "xyes"; then
2012           LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$cyassllib"
2013           export LD_LIBRARY_PATH
2014           AC_MSG_NOTICE([Added $cyassllib to LD_LIBRARY_PATH])
2015         fi
2016       fi
2017
2018     fi
2019
2020   fi dnl CyaSSL not disabled
2021
2022 fi
2023
2024 dnl ----------------------------------------------------
2025 dnl NSS. Only check if GnuTLS and OpenSSL are not enabled
2026 dnl ----------------------------------------------------
2027
2028 dnl Default to compiler & linker defaults for NSS files & libraries.
2029 OPT_NSS=no
2030
2031 AC_ARG_WITH(nss,dnl
2032 AC_HELP_STRING([--with-nss=PATH],[where to look for NSS, PATH points to the installation root])
2033 AC_HELP_STRING([--without-nss], [disable NSS detection]),
2034   OPT_NSS=$withval)
2035
2036 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
2037
2038   if test X"$OPT_NSS" != Xno; then
2039
2040     addld=""
2041     addlib=""
2042     addcflags=""
2043     nssprefix=""
2044     version=""
2045
2046     if test "x$OPT_NSS" = "xyes"; then
2047
2048       CURL_CHECK_PKGCONFIG(nss)
2049
2050       if test "$PKGCONFIG" != "no" ; then
2051         addlib=`$PKGCONFIG --libs nss`
2052         addcflags=`$PKGCONFIG --cflags nss`
2053         version=`$PKGCONFIG --modversion nss`
2054         nssprefix=`$PKGCONFIG --variable=prefix nss`
2055       else
2056         dnl Without pkg-config, we check for nss-config
2057
2058         check=`nss-config --version 2>/dev/null`
2059         if test -n "$check"; then
2060           addlib=`nss-config --libs`
2061           addcflags=`nss-config --cflags`
2062           version=`nss-config --version`
2063           nssprefix=`nss-config --prefix`
2064         else
2065           addlib="-lnss3"
2066           addcflags=""
2067           version="unknown"
2068         fi
2069       fi
2070     else
2071         # Without pkg-config, we'll kludge in some defaults
2072         addlib="-L$OPT_NSS/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
2073         addcflags="-I$OPT_NSS/include"
2074         version="unknown"
2075         nssprefix=$OPT_NSS
2076     fi
2077
2078     if test -n "$addlib"; then
2079
2080       CLEANLIBS="$LIBS"
2081       CLEANCPPFLAGS="$CPPFLAGS"
2082
2083       LIBS="$addlib $LIBS"
2084       if test "$addcflags" != "-I/usr/include"; then
2085          CPPFLAGS="$CPPFLAGS $addcflags"
2086       fi
2087
2088       dnl The function SSL_VersionRangeSet() is needed to enable TLS > 1.0
2089       AC_CHECK_LIB(nss3, SSL_VersionRangeSet,
2090        [
2091        AC_DEFINE(USE_NSS, 1, [if NSS is enabled])
2092        AC_SUBST(USE_NSS, [1])
2093        USE_NSS="yes"
2094        NSS_ENABLED=1
2095        curl_ssl_msg="enabled (NSS)"
2096        ],
2097        [
2098          LIBS="$CLEANLIBS"
2099          CPPFLAGS="$CLEANCPPFLAGS"
2100        ])
2101
2102       if test "x$USE_NSS" = "xyes"; then
2103         AC_MSG_NOTICE([detected NSS version $version])
2104
2105         dnl when shared libs were found in a path that the run-time
2106         dnl linker doesn't search through, we need to add it to
2107         dnl LD_LIBRARY_PATH to prevent further configure tests to fail
2108         dnl due to this
2109         if test "x$cross_compiling" != "xyes"; then
2110           LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$nssprefix/lib$libsuff"
2111           export LD_LIBRARY_PATH
2112           AC_MSG_NOTICE([Added $nssprefix/lib$libsuff to LD_LIBRARY_PATH])
2113         fi
2114       fi
2115
2116     fi
2117
2118   fi dnl NSS not disabled
2119
2120 fi dnl curl_ssl_msg = init_ssl_msg
2121
2122 OPT_AXTLS=off
2123
2124 AC_ARG_WITH(axtls,dnl
2125 AC_HELP_STRING([--with-axtls=PATH],[Where to look for axTLS, PATH points to the axTLS installation prefix (default: /usr/local).  Ignored if another SSL engine is selected.])
2126 AC_HELP_STRING([--without-axtls], [disable axTLS]),
2127   OPT_AXTLS=$withval)
2128
2129 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
2130   if test X"$OPT_AXTLS" != Xno; then
2131     dnl backup the pre-axtls variables
2132     CLEANLDFLAGS="$LDFLAGS"
2133     CLEANCPPFLAGS="$CPPFLAGS"
2134     CLEANLIBS="$LIBS"
2135
2136     case "$OPT_AXTLS" in
2137     yes)
2138       dnl --with-axtls (without path) used
2139       PREFIX_AXTLS=/usr/local
2140       LIB_AXTLS="$PREFIX_AXTLS/lib"
2141       LDFLAGS="$LDFLAGS -L$LIB_AXTLS"
2142       CPPFLAGS="$CPPFLAGS -I$PREFIX_AXTLS/include"
2143       ;;
2144     off)
2145       dnl no --with-axtls option given, just check default places
2146       PREFIX_AXTLS=
2147       ;;
2148     *)
2149       dnl check the given --with-axtls spot
2150       PREFIX_AXTLS=$OPT_AXTLS
2151       LIB_AXTLS="$PREFIX_AXTLS/lib"
2152       LDFLAGS="$LDFLAGS -L$LIB_AXTLS"
2153       CPPFLAGS="$CPPFLAGS -I$PREFIX_AXTLS/include"
2154       ;;
2155     esac
2156
2157     AC_CHECK_LIB(axtls, ssl_version,[
2158       LIBS="-laxtls $LIBS"
2159       AC_DEFINE(USE_AXTLS, 1, [if axTLS is enabled])
2160       AC_SUBST(USE_AXTLS, [1])
2161       AXTLS_ENABLED=1
2162       USE_AXTLS="yes"
2163       curl_ssl_msg="enabled (axTLS)"
2164
2165
2166       LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$LIB_AXTLS"
2167       export LD_LIBRARY_PATH
2168       AC_MSG_NOTICE([Added $LIB_AXTLS to LD_LIBRARY_PATH])
2169       ],[
2170       LDFLAGS="$CLEANLDFLAGS"
2171       CPPFLAGS="$CLEANCPPFLAGS"
2172       LIBS="$CLEANLIBS"
2173     ])
2174   fi
2175 fi
2176
2177 if test "x$OPENSSL_ENABLED$GNUTLS_ENABLED$NSS_ENABLED$POLARSSL_ENABLED$AXTLS_ENABLED$CYASSL_ENABLED$WINSSL_ENABLED$DARWINSSL_ENABLED" = "x"; then
2178   AC_MSG_WARN([SSL disabled, you will not be able to use HTTPS, FTPS, NTLM and more.])
2179   AC_MSG_WARN([Use --with-ssl, --with-gnutls, --with-polarssl, --with-cyassl, --with-nss, --with-axtls, --with-winssl, or --with-darwinssl to address this.])
2180 else
2181   # SSL is enabled, genericly
2182   AC_SUBST(SSL_ENABLED)
2183   SSL_ENABLED="1"
2184 fi
2185
2186 dnl **********************************************************************
2187 dnl Check for the CA bundle
2188 dnl **********************************************************************
2189
2190 CURL_CHECK_CA_BUNDLE
2191
2192 dnl **********************************************************************
2193 dnl Check for libmetalink
2194 dnl **********************************************************************
2195
2196 OPT_LIBMETALINK=no
2197
2198 AC_ARG_WITH(libmetalink,dnl
2199 AC_HELP_STRING([--with-libmetalink=PATH],[where to look for libmetalink, PATH points to the installation root])
2200 AC_HELP_STRING([--without-libmetalink], [disable libmetalink detection]),
2201   OPT_LIBMETALINK=$withval)
2202
2203 if test X"$OPT_LIBMETALINK" != Xno; then
2204
2205   addld=""
2206   addlib=""
2207   addcflags=""
2208   version=""
2209   libmetalinklib=""
2210
2211   PKGTEST="no"
2212   if test "x$OPT_LIBMETALINK" = "xyes"; then
2213     dnl this is with no partiular path given
2214     PKGTEST="yes"
2215     CURL_CHECK_PKGCONFIG(libmetalink)
2216   else
2217     dnl When particular path is given, set PKG_CONFIG_LIBDIR using the path.
2218     LIBMETALINK_PCDIR="$OPT_LIBMETALINK/lib/pkgconfig"
2219     AC_MSG_NOTICE([PKG_CONFIG_LIBDIR will be set to "$LIBMETALINK_PCDIR"])
2220     if test -f "$LIBMETALINK_PCDIR/libmetalink.pc"; then
2221       PKGTEST="yes"
2222     fi
2223     if test "$PKGTEST" = "yes"; then
2224       CURL_CHECK_PKGCONFIG(libmetalink, [$LIBMETALINK_PCDIR])
2225     fi
2226   fi
2227   if test "$PKGTEST" = "yes" && test "$PKGCONFIG" != "no"; then
2228     addlib=`CURL_EXPORT_PCDIR([$LIBMETALINK_PCDIR]) dnl
2229       $PKGCONFIG --libs-only-l libmetalink`
2230     addld=`CURL_EXPORT_PCDIR([$LIBMETALINK_PCDIR]) dnl
2231       $PKGCONFIG --libs-only-L libmetalink`
2232     addcflags=`CURL_EXPORT_PCDIR([$LIBMETALINK_PCDIR]) dnl
2233       $PKGCONFIG --cflags-only-I libmetalink`
2234     version=`CURL_EXPORT_PCDIR([$LIBMETALINK_PCDIR]) dnl
2235       $PKGCONFIG --modversion libmetalink`
2236     libmetalinklib=`echo $addld | $SED -e 's/-L//'`
2237   fi
2238   if test -n "$addlib"; then
2239
2240     clean_CPPFLAGS="$CPPFLAGS"
2241     clean_LDFLAGS="$LDFLAGS"
2242     clean_LIBS="$LIBS"
2243     CPPFLAGS="$addcflags $clean_CPPFLAGS"
2244     LDFLAGS="$addld $clean_LDFLAGS"
2245     LIBS="$addlib $clean_LIBS"
2246     AC_MSG_CHECKING([if libmetalink is recent enough])
2247     AC_LINK_IFELSE([
2248       AC_LANG_PROGRAM([[
2249 #       include <metalink/metalink.h>
2250       ]],[[
2251         if(0 != metalink_strerror(0)) /* added in 0.1.0 */
2252           return 1;
2253       ]])
2254     ],[
2255       AC_MSG_RESULT([yes ($version)])
2256       want_metalink="yes"
2257     ],[
2258       AC_MSG_RESULT([no ($version)])
2259       AC_MSG_NOTICE([libmetalink library defective or too old])
2260       want_metalink="no"
2261     ])
2262     CPPFLAGS="$clean_CPPFLAGS"
2263     LDFLAGS="$clean_LDFLAGS"
2264     LIBS="$clean_LIBS"
2265     if test "$want_metalink" = "yes"; then
2266       dnl finally libmetalink will be used
2267       AC_DEFINE(USE_METALINK, 1, [Define to enable metalink support])
2268       LIBMETALINK_LIBS=$addlib
2269       LIBMETALINK_LDFLAGS=$addld
2270       LIBMETALINK_CPPFLAGS=$addcflags
2271       AC_SUBST([LIBMETALINK_LIBS])
2272       AC_SUBST([LIBMETALINK_LDFLAGS])
2273       AC_SUBST([LIBMETALINK_CPPFLAGS])
2274       curl_mtlnk_msg="enabled"
2275     fi
2276
2277   fi
2278 fi
2279
2280 dnl **********************************************************************
2281 dnl Check for the presence of LIBSSH2 libraries and headers
2282 dnl **********************************************************************
2283
2284 dnl Default to compiler & linker defaults for LIBSSH2 files & libraries.
2285 OPT_LIBSSH2=off
2286 AC_ARG_WITH(libssh2,dnl
2287 AC_HELP_STRING([--with-libssh2=PATH],[Where to look for libssh2, PATH points to the LIBSSH2 installation; when possible, set the PKG_CONFIG_PATH environment variable instead of using this option])
2288 AC_HELP_STRING([--without-libssh2], [disable LIBSSH2]),
2289   OPT_LIBSSH2=$withval)
2290
2291 if test X"$OPT_LIBSSH2" != Xno; then
2292   dnl backup the pre-libssh2 variables
2293   CLEANLDFLAGS="$LDFLAGS"
2294   CLEANCPPFLAGS="$CPPFLAGS"
2295   CLEANLIBS="$LIBS"
2296
2297   case "$OPT_LIBSSH2" in
2298   yes)
2299     dnl --with-libssh2 (without path) used
2300     CURL_CHECK_PKGCONFIG(libssh2)
2301
2302     if test "$PKGCONFIG" != "no" ; then
2303       LIB_SSH2=`$PKGCONFIG --libs-only-l libssh2`
2304       LD_SSH2=`$PKGCONFIG --libs-only-L libssh2`
2305       CPP_SSH2=`$PKGCONFIG --cflags-only-I libssh2`
2306       version=`$PKGCONFIG --modversion libssh2`
2307       DIR_SSH2=`echo $LD_SSH2 | $SED -e 's/-L//'`
2308     fi
2309
2310     ;;
2311   off)
2312     dnl no --with-libssh2 option given, just check default places
2313     ;;
2314   *)
2315     dnl use the given --with-libssh2 spot
2316     PREFIX_SSH2=$OPT_LIBSSH2
2317     ;;
2318   esac
2319
2320   dnl if given with a prefix, we set -L and -I based on that
2321   if test -n "$PREFIX_SSH2"; then
2322     LIB_SSH2="-lssh2"
2323     LD_SSH2=-L${PREFIX_SSH2}/lib$libsuff
2324     CPP_SSH2=-I${PREFIX_SSH2}/include
2325     DIR_SSH2=${PREFIX_SSH2}/lib$libsuff
2326   fi
2327
2328   LDFLAGS="$LDFLAGS $LD_SSH2"
2329   CPPFLAGS="$CPPFLAGS $CPP_SSH2"
2330   LIBS="$LIB_SSH2 $LIBS"
2331
2332   AC_CHECK_LIB(ssh2, libssh2_channel_open_ex)
2333
2334   AC_CHECK_HEADERS(libssh2.h,
2335     curl_ssh_msg="enabled (libSSH2)"
2336     LIBSSH2_ENABLED=1
2337     AC_DEFINE(USE_LIBSSH2, 1, [if libSSH2 is in use])
2338     AC_SUBST(USE_LIBSSH2, [1])
2339   )
2340
2341   if test X"$OPT_LIBSSH2" != Xoff &&
2342      test "$LIBSSH2_ENABLED" != "1"; then
2343     AC_MSG_ERROR([libSSH2 libs and/or directories were not found where specified!])
2344   fi
2345
2346   if test "$LIBSSH2_ENABLED" = "1"; then
2347     if test -n "$DIR_SSH2"; then
2348        dnl when the libssh2 shared libs were found in a path that the run-time
2349        dnl linker doesn't search through, we need to add it to LD_LIBRARY_PATH
2350        dnl to prevent further configure tests to fail due to this
2351
2352        dnl libssh2_version is a post 1.0 addition
2353        dnl libssh2_init and libssh2_exit were added in 1.2.5
2354        dnl libssh2_scp_send64 was added in 1.2.6
2355        dnl libssh2_session_handshake was added in 1.2.8
2356        AC_CHECK_FUNCS( libssh2_version libssh2_init libssh2_exit \
2357                        libssh2_scp_send64 libssh2_session_handshake)
2358        if test "x$cross_compiling" != "xyes"; then
2359          LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$DIR_SSH2"
2360          export LD_LIBRARY_PATH
2361          AC_MSG_NOTICE([Added $DIR_SSH2 to LD_LIBRARY_PATH])
2362        fi
2363     fi
2364   else
2365     dnl no libssh2, revert back to clean variables
2366     LDFLAGS=$CLEANLDFLAGS
2367     CPPFLAGS=$CLEANCPPFLAGS
2368     LIBS=$CLEANLIBS
2369   fi
2370 fi
2371
2372 dnl **********************************************************************
2373 dnl Check for the presence of LIBRTMP libraries and headers
2374 dnl **********************************************************************
2375
2376 dnl Default to compiler & linker defaults for LIBRTMP files & libraries.
2377 OPT_LIBRTMP=off
2378 AC_ARG_WITH(librtmp,dnl
2379 AC_HELP_STRING([--with-librtmp=PATH],[Where to look for librtmp, PATH points to the LIBRTMP installation; when possible, set the PKG_CONFIG_PATH environment variable instead of using this option])
2380 AC_HELP_STRING([--without-librtmp], [disable LIBRTMP]),
2381   OPT_LIBRTMP=$withval)
2382
2383 if test X"$OPT_LIBRTMP" != Xno; then
2384   dnl backup the pre-librtmp variables
2385   CLEANLDFLAGS="$LDFLAGS"
2386   CLEANCPPFLAGS="$CPPFLAGS"
2387   CLEANLIBS="$LIBS"
2388
2389   case "$OPT_LIBRTMP" in
2390   yes)
2391     dnl --with-librtmp (without path) used
2392     CURL_CHECK_PKGCONFIG(librtmp)
2393
2394     if test "$PKGCONFIG" != "no" ; then
2395       LIB_RTMP=`$PKGCONFIG --libs-only-l librtmp`
2396       LD_RTMP=`$PKGCONFIG --libs-only-L librtmp`
2397       CPP_RTMP=`$PKGCONFIG --cflags-only-I librtmp`
2398       version=`$PKGCONFIG --modversion librtmp`
2399       DIR_RTMP=`echo $LD_RTMP | $SED -e 's/-L//'`
2400     else
2401       dnl To avoid link errors, we do not allow --librtmp without
2402       dnl a pkgconfig file
2403       AC_MSG_ERROR([--librtmp was specified but could not find librtmp pkgconfig file.])
2404     fi
2405
2406     ;;
2407   off)
2408     dnl no --with-librtmp option given, just check default places
2409     LIB_RTMP="-lrtmp"
2410     ;;
2411   *)
2412     dnl use the given --with-librtmp spot
2413     PREFIX_RTMP=$OPT_LIBRTMP
2414     ;;
2415   esac
2416
2417   dnl if given with a prefix, we set -L and -I based on that
2418   if test -n "$PREFIX_RTMP"; then
2419     LD_RTMP=-L${PREFIX_RTMP}/lib$libsuff
2420     CPP_RTMP=-I${PREFIX_RTMP}/include
2421     DIR_RTMP=${PREFIX_RTMP}/lib$libsuff
2422   fi
2423
2424   LDFLAGS="$LDFLAGS $LD_RTMP"
2425   CPPFLAGS="$CPPFLAGS $CPP_RTMP"
2426   LIBS="$LIB_RTMP $LIBS"
2427
2428   AC_CHECK_LIB(rtmp, RTMP_Init,
2429     [
2430      AC_CHECK_HEADERS(librtmp/rtmp.h,
2431         curl_rtmp_msg="enabled (librtmp)"
2432         LIBRTMP_ENABLED=1
2433         AC_DEFINE(USE_LIBRTMP, 1, [if librtmp is in use])
2434         AC_SUBST(USE_LIBRTMP, [1])
2435      )
2436     ],
2437       dnl not found, revert back to clean variables
2438       LDFLAGS=$CLEANLDFLAGS
2439       CPPFLAGS=$CLEANCPPFLAGS
2440       LIBS=$CLEANLIBS
2441   )
2442
2443   if test X"$OPT_LIBRTMP" != Xoff &&
2444      test "$LIBRTMP_ENABLED" != "1"; then
2445     AC_MSG_ERROR([librtmp libs and/or directories were not found where specified!])
2446   fi
2447
2448 fi
2449
2450 dnl **********************************************************************
2451 dnl Check for linker switch for versioned symbols
2452 dnl **********************************************************************
2453
2454 versioned_symbols_flavour=
2455 AC_MSG_CHECKING([whether versioned symbols are wanted])
2456 AC_ARG_ENABLE(versioned-symbols,
2457 AC_HELP_STRING([--enable-versioned-symbols], [Enable versioned symbols in shared library])
2458 AC_HELP_STRING([--disable-versioned-symbols], [Disable versioned symbols in shared library]),
2459 [ case "$enableval" in
2460   yes) AC_MSG_RESULT(yes)
2461     AC_MSG_CHECKING([if libraries can be versioned])
2462     GLD=`$LD --help < /dev/null 2>/dev/null | grep version-script`
2463     if test -z "$GLD"; then
2464         AC_MSG_RESULT(no)
2465         AC_MSG_WARN([You need an ld version supporting the --version-script option])
2466     else
2467         AC_MSG_RESULT(yes)
2468         if test "x$OPENSSL_ENABLED" = "x1"; then
2469           versioned_symbols_flavour="OPENSSL_"
2470         elif test "x$GNUTLS_ENABLED" == "x1"; then
2471           versioned_symbols_flavour="GNUTLS_"
2472         elif test "x$NSS_ENABLED" == "x1"; then
2473           versioned_symbols_flavour="NSS_"
2474         elif test "x$POLARSSL_ENABLED" == "x1"; then
2475           versioned_symbols_flavour="POLARSSL_"
2476         elif test "x$CYASSL_ENABLED" == "x1"; then
2477           versioned_symbols_flavour="CYASSL_"
2478         elif test "x$AXTLS_ENABLED" == "x1"; then
2479           versioned_symbols_flavour="AXTLS_"
2480         elif test "x$WINSSL_ENABLED" == "x1"; then
2481           versioned_symbols_flavour="WINSSL_"
2482         elif test "x$DARWINSSL_ENABLED" == "x1"; then
2483           versioned_symbols_flavour="DARWINSSL_"
2484         else
2485           versioned_symbols_flavour=""
2486         fi
2487         versioned_symbols="yes"
2488     fi
2489     ;;
2490
2491   *)   AC_MSG_RESULT(no)
2492     ;;
2493   esac
2494 ], [
2495 AC_MSG_RESULT(no)
2496 ]
2497 )
2498
2499 AC_SUBST([CURL_LT_SHLIB_VERSIONED_FLAVOUR],
2500   ["$versioned_symbols_flavour"])
2501 AM_CONDITIONAL([CURL_LT_SHLIB_USE_VERSIONED_SYMBOLS],
2502   [test "x$versioned_symbols" = 'xyes'])
2503
2504 dnl -------------------------------------------------
2505 dnl check winidn option before other IDN libraries
2506 dnl -------------------------------------------------
2507
2508 AC_MSG_CHECKING([whether to enable Windows native IDN (Windows native builds only)])
2509 OPT_WINIDN="default"
2510 AC_ARG_WITH(winidn,
2511 AC_HELP_STRING([--with-winidn=PATH],[enable Windows native IDN])
2512 AC_HELP_STRING([--without-winidn], [disable Windows native IDN]),
2513   OPT_WINIDN=$withval)
2514 case "$OPT_WINIDN" in
2515   no|default)
2516     dnl --without-winidn option used or configure option not specified
2517     want_winidn="no"
2518     AC_MSG_RESULT([no])
2519     ;;
2520   yes)
2521     dnl --with-winidn option used without path
2522     want_winidn="yes"
2523     want_winidn_path="default"
2524     AC_MSG_RESULT([yes])
2525     ;;
2526   *)
2527     dnl --with-winidn option used with path
2528     want_winidn="yes"
2529     want_winidn_path="$withval"
2530     AC_MSG_RESULT([yes ($withval)])
2531     ;;
2532 esac
2533
2534 if test "$want_winidn" = "yes"; then
2535   dnl winidn library support has been requested
2536   clean_CPPFLAGS="$CPPFLAGS"
2537   clean_LDFLAGS="$LDFLAGS"
2538   clean_LIBS="$LIBS"
2539   WINIDN_LIBS="-lnormaliz"
2540   #
2541   if test "$want_winidn_path" != "default"; then
2542     dnl path has been specified
2543     dnl pkg-config not available or provides no info
2544     WINIDN_LDFLAGS="-L$want_winidn_path/lib$libsuff"
2545     WINIDN_CPPFLAGS="-I$want_winidn_path/include"
2546     WINIDN_DIR="$want_winidn_path/lib$libsuff"
2547   fi
2548   #
2549   CPPFLAGS="$WINIDN_CPPFLAGS $CPPFLAGS"
2550   LDFLAGS="$WINIDN_LDFLAGS $LDFLAGS"
2551   LIBS="$WINIDN_LIBS $LIBS"
2552   #
2553   AC_MSG_CHECKING([if IdnToUnicode can be linked])
2554   AC_LINK_IFELSE([
2555     AC_LANG_FUNC_LINK_TRY([IdnToUnicode])
2556   ],[
2557     AC_MSG_RESULT([yes])
2558     tst_links_winidn="yes"
2559   ],[
2560     AC_MSG_RESULT([no])
2561     tst_links_winidn="no"
2562   ])
2563   #
2564   if test "$tst_links_winidn" = "yes"; then
2565     AC_DEFINE(USE_WIN32_IDN, 1, [Define to 1 if you have the `normaliz' (WinIDN) library (-lnormaliz).])
2566     AC_DEFINE(WANT_IDN_PROTOTYPES, 1, [Define to 1 to provide own prototypes.])
2567     AC_SUBST([IDN_ENABLED], [1])
2568     curl_idn_msg="enabled (Windows-native)"
2569   else
2570     AC_MSG_WARN([Cannot find libraries for IDN support: IDN disabled])
2571     CPPFLAGS="$clean_CPPFLAGS"
2572     LDFLAGS="$clean_LDFLAGS"
2573     LIBS="$clean_LIBS"
2574   fi
2575 fi
2576
2577 dnl **********************************************************************
2578 dnl Check for the presence of IDN libraries and headers
2579 dnl **********************************************************************
2580
2581 AC_MSG_CHECKING([whether to build with libidn])
2582 OPT_IDN="default"
2583 AC_ARG_WITH(libidn,
2584 AC_HELP_STRING([--with-libidn=PATH],[Enable libidn usage])
2585 AC_HELP_STRING([--without-libidn],[Disable libidn usage]),
2586   [OPT_IDN=$withval])
2587 case "$OPT_IDN" in
2588   no)
2589     dnl --without-libidn option used
2590     want_idn="no"
2591     AC_MSG_RESULT([no])
2592     ;;
2593   default)
2594     dnl configure option not specified
2595     want_idn="yes"
2596     want_idn_path="default"
2597     AC_MSG_RESULT([(assumed) yes])
2598     ;;
2599   yes)
2600     dnl --with-libidn option used without path
2601     want_idn="yes"
2602     want_idn_path="default"
2603     AC_MSG_RESULT([yes])
2604     ;;
2605   *)
2606     dnl --with-libidn option used with path
2607     want_idn="yes"
2608     want_idn_path="$withval"
2609     AC_MSG_RESULT([yes ($withval)])
2610     ;;
2611 esac
2612
2613 if test "$want_idn" = "yes"; then
2614   dnl idn library support has been requested
2615   clean_CPPFLAGS="$CPPFLAGS"
2616   clean_LDFLAGS="$LDFLAGS"
2617   clean_LIBS="$LIBS"
2618   PKGCONFIG="no"
2619   #
2620   if test "$want_idn_path" != "default"; then
2621     dnl path has been specified
2622     IDN_PCDIR="$want_idn_path/lib$libsuff/pkgconfig"
2623     CURL_CHECK_PKGCONFIG(libidn, [$IDN_PCDIR])
2624     if test "$PKGCONFIG" != "no"; then
2625       IDN_LIBS=`CURL_EXPORT_PCDIR([$IDN_PCDIR]) dnl
2626         $PKGCONFIG --libs-only-l libidn 2>/dev/null`
2627       IDN_LDFLAGS=`CURL_EXPORT_PCDIR([$IDN_PCDIR]) dnl
2628         $PKGCONFIG --libs-only-L libidn 2>/dev/null`
2629       IDN_CPPFLAGS=`CURL_EXPORT_PCDIR([$IDN_PCDIR]) dnl
2630         $PKGCONFIG --cflags-only-I libidn 2>/dev/null`
2631       IDN_DIR=`echo $IDN_LDFLAGS | $SED -e 's/-L//'`
2632     else
2633       dnl pkg-config not available or provides no info
2634       IDN_LIBS="-lidn"
2635       IDN_LDFLAGS="-L$want_idn_path/lib$libsuff"
2636       IDN_CPPFLAGS="-I$want_idn_path/include"
2637       IDN_DIR="$want_idn_path/lib$libsuff"
2638     fi
2639   else
2640     dnl path not specified
2641     CURL_CHECK_PKGCONFIG(libidn)
2642     if test "$PKGCONFIG" != "no"; then
2643       IDN_LIBS=`$PKGCONFIG --libs-only-l libidn 2>/dev/null`
2644       IDN_LDFLAGS=`$PKGCONFIG --libs-only-L libidn 2>/dev/null`
2645       IDN_CPPFLAGS=`$PKGCONFIG --cflags-only-I libidn 2>/dev/null`
2646       IDN_DIR=`echo $IDN_LDFLAGS | $SED -e 's/-L//'`
2647     else
2648       dnl pkg-config not available or provides no info
2649       IDN_LIBS="-lidn"
2650     fi
2651   fi
2652   #
2653   if test "$PKGCONFIG" != "no"; then
2654     AC_MSG_NOTICE([pkg-config: IDN_LIBS: "$IDN_LIBS"])
2655     AC_MSG_NOTICE([pkg-config: IDN_LDFLAGS: "$IDN_LDFLAGS"])
2656     AC_MSG_NOTICE([pkg-config: IDN_CPPFLAGS: "$IDN_CPPFLAGS"])
2657     AC_MSG_NOTICE([pkg-config: IDN_DIR: "$IDN_DIR"])
2658   else
2659     AC_MSG_NOTICE([IDN_LIBS: "$IDN_LIBS"])
2660     AC_MSG_NOTICE([IDN_LDFLAGS: "$IDN_LDFLAGS"])
2661     AC_MSG_NOTICE([IDN_CPPFLAGS: "$IDN_CPPFLAGS"])
2662     AC_MSG_NOTICE([IDN_DIR: "$IDN_DIR"])
2663   fi
2664   #
2665   CPPFLAGS="$IDN_CPPFLAGS $CPPFLAGS"
2666   LDFLAGS="$IDN_LDFLAGS $LDFLAGS"
2667   LIBS="$IDN_LIBS $LIBS"
2668   #
2669   AC_MSG_CHECKING([if idna_to_ascii_4i can be linked])
2670   AC_LINK_IFELSE([
2671     AC_LANG_FUNC_LINK_TRY([idna_to_ascii_4i])
2672   ],[
2673     AC_MSG_RESULT([yes])
2674     tst_links_libidn="yes"
2675   ],[
2676     AC_MSG_RESULT([no])
2677     tst_links_libidn="no"
2678   ])
2679   if test "$tst_links_libidn" = "no"; then
2680     AC_MSG_CHECKING([if idna_to_ascii_lz can be linked])
2681     AC_LINK_IFELSE([
2682       AC_LANG_FUNC_LINK_TRY([idna_to_ascii_lz])
2683     ],[
2684       AC_MSG_RESULT([yes])
2685       tst_links_libidn="yes"
2686     ],[
2687       AC_MSG_RESULT([no])
2688       tst_links_libidn="no"
2689     ])
2690   fi
2691   #
2692   if test "$tst_links_libidn" = "yes"; then
2693     AC_DEFINE(HAVE_LIBIDN, 1, [Define to 1 if you have the `idn' library (-lidn).])
2694     dnl different versions of libidn have different setups of these:
2695     AC_CHECK_FUNCS( idn_free idna_strerror tld_strerror )
2696     AC_CHECK_HEADERS( idn-free.h tld.h )
2697     if test "x$ac_cv_header_tld_h" = "xyes"; then
2698       AC_SUBST([IDN_ENABLED], [1])
2699       curl_idn_msg="enabled"
2700       if test -n "$IDN_DIR"; then
2701         LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$IDN_DIR"
2702         export LD_LIBRARY_PATH
2703         AC_MSG_NOTICE([Added $IDN_DIR to LD_LIBRARY_PATH])
2704       fi
2705     else
2706       AC_MSG_WARN([Libraries for IDN support too old: IDN disabled])
2707       CPPFLAGS="$clean_CPPFLAGS"
2708       LDFLAGS="$clean_LDFLAGS"
2709       LIBS="$clean_LIBS"
2710     fi
2711   else
2712     AC_MSG_WARN([Cannot find libraries for IDN support: IDN disabled])
2713     CPPFLAGS="$clean_CPPFLAGS"
2714     LDFLAGS="$clean_LDFLAGS"
2715     LIBS="$clean_LIBS"
2716   fi
2717 fi
2718
2719
2720 dnl Let's hope this split URL remains working:
2721 dnl http://publibn.boulder.ibm.com/doc_link/en_US/a_doc_lib/aixprggd/ \
2722 dnl genprogc/thread_quick_ref.htm
2723
2724
2725 dnl **********************************************************************
2726 dnl Check for nghttp2
2727 dnl **********************************************************************
2728
2729 AC_MSG_CHECKING([whether to build with nghttp2])
2730 OPT_H2="no"
2731 AC_ARG_WITH(nghttp2,
2732 AC_HELP_STRING([--with-nghttp2=PATH],[Enable nghttp2 usage])
2733 AC_HELP_STRING([--without-nghttp2],[Disable nghttp2 usage]),
2734   [OPT_H2=$withval])
2735 case "$OPT_H2" in
2736   no)
2737     dnl --without-nghttp2 option used
2738     want_idn="no"
2739     AC_MSG_RESULT([no])
2740     ;;
2741   default)
2742     dnl configure option not specified
2743     want_h2="no"
2744     want_h2_path="default"
2745     AC_MSG_RESULT([no])
2746     ;;
2747   yes)
2748     dnl --with-nghttp2 option used without path
2749     want_h2="yes"
2750     want_h2_path=""
2751     AC_MSG_RESULT([yes])
2752     ;;
2753   *)
2754     dnl --with-nghttp2 option used with path
2755     want_h2="yes"
2756     want_h2_path="$withval"
2757     AC_MSG_RESULT([yes ($withval)])
2758     ;;
2759 esac
2760
2761 curl_h2_msg="disabled (--with-nghttp2)"
2762 if test X"$OPT_H2" != Xno; then
2763   dnl backup the pre-librtmp variables
2764   CLEANLDFLAGS="$LDFLAGS"
2765   CLEANCPPFLAGS="$CPPFLAGS"
2766   CLEANLIBS="$LIBS"
2767
2768   h2pcdir=${want_h2_path}/lib/pkgconfig
2769   CURL_CHECK_PKGCONFIG(libnghttp2, $h2pcdir)
2770
2771   if test "$PKGCONFIG" != "no" ; then
2772     LIB_H2=`CURL_EXPORT_PCDIR([$h2pcdir])
2773       $PKGCONFIG --libs-only-l libnghttp2`
2774     AC_MSG_NOTICE([-l is $LIB_H2])
2775
2776     CPP_H2=`CURL_EXPORT_PCDIR([$h2pcdir]) dnl
2777       $PKGCONFIG --cflags-only-I libnghttp2`
2778     AC_MSG_NOTICE([-I is $CPP_H2])
2779
2780     LD_H2=`CURL_EXPORT_PCDIR([$h2pcdir])
2781       $PKGCONFIG --libs-only-L libnghttp2`
2782     AC_MSG_NOTICE([-L is $LD_H2])
2783
2784   else
2785     dnl To avoid link errors, we do not allow --libnghttp2 without
2786     dnl a pkgconfig file
2787     AC_MSG_ERROR([--with-nghttp2 was specified but could not find libnghttp2 pkg-config file.])
2788   fi
2789
2790   LDFLAGS="$LDFLAGS $LD_H2"
2791   CPPFLAGS="$CPPFLAGS $CPP_H2"
2792   LIBS="$LIB_H2 $LIBS"
2793
2794   AC_CHECK_LIB(nghttp2, nghttp2_session_client_new,
2795     [
2796      AC_CHECK_HEADERS(nghttp2/nghttp2.h,
2797         curl_h2_msg="enabled (nghttp2)"
2798         NGHTTP2_ENABLED=1
2799         AC_DEFINE(USE_NGHTTP2, 1, [if nghttp2 is in use])
2800         AC_SUBST(USE_NGHTTP2, [1])
2801      )
2802     ],
2803       dnl not found, revert back to clean variables
2804       LDFLAGS=$CLEANLDFLAGS
2805       CPPFLAGS=$CLEANCPPFLAGS
2806       LIBS=$CLEANLIBS
2807   )
2808
2809 fi
2810
2811 dnl **********************************************************************
2812 dnl Back to "normal" configuring
2813 dnl **********************************************************************
2814
2815 dnl Checks for header files.
2816 AC_HEADER_STDC
2817
2818 CURL_CHECK_HEADER_MALLOC
2819 CURL_CHECK_HEADER_MEMORY
2820
2821 dnl Now check for the very most basic headers. Then we can use these
2822 dnl ones as default-headers when checking for the rest!
2823 AC_CHECK_HEADERS(
2824         sys/types.h \
2825         sys/time.h \
2826         sys/select.h \
2827         sys/socket.h \
2828         sys/ioctl.h \
2829         sys/uio.h \
2830         assert.h \
2831         unistd.h \
2832         stdlib.h \
2833         limits.h \
2834         arpa/inet.h \
2835         net/if.h \
2836         netinet/in.h \
2837         sys/un.h \
2838         netinet/tcp.h \
2839         netdb.h \
2840         sys/sockio.h \
2841         sys/stat.h \
2842         sys/param.h \
2843         termios.h \
2844         termio.h \
2845         sgtty.h \
2846         fcntl.h \
2847         alloca.h \
2848         time.h \
2849         io.h \
2850         pwd.h \
2851         utime.h \
2852         sys/utime.h \
2853         sys/poll.h \
2854         poll.h \
2855         socket.h \
2856         sys/resource.h \
2857         libgen.h \
2858         locale.h \
2859         errno.h \
2860         stdbool.h \
2861         arpa/tftp.h \
2862         sys/filio.h \
2863         sys/wait.h \
2864         setjmp.h,
2865 dnl to do if not found
2866 [],
2867 dnl to do if found
2868 [],
2869 dnl default includes
2870 [
2871 #ifdef HAVE_SYS_TYPES_H
2872 #include <sys/types.h>
2873 #endif
2874 #ifdef HAVE_SYS_TIME_H
2875 #include <sys/time.h>
2876 #endif
2877 #ifdef HAVE_SYS_SELECT_H
2878 #include <sys/select.h>
2879 #endif
2880 #ifdef HAVE_SYS_SOCKET_H
2881 #include <sys/socket.h>
2882 #endif
2883 #ifdef HAVE_NETINET_IN_H
2884 #include <netinet/in.h>
2885 #endif
2886 #ifdef HAVE_SYS_UN_H
2887 #include <sys/un.h>
2888 #endif
2889 ]
2890 )
2891
2892 dnl Checks for typedefs, structures, and compiler characteristics.
2893 AC_C_CONST
2894 CURL_CHECK_VARIADIC_MACROS
2895 AC_TYPE_SIZE_T
2896 AC_HEADER_TIME
2897 CURL_CHECK_STRUCT_TIMEVAL
2898 CURL_VERIFY_RUNTIMELIBS
2899
2900 AC_CHECK_SIZEOF(size_t)
2901 AC_CHECK_SIZEOF(long)
2902 AC_CHECK_SIZEOF(int)
2903 AC_CHECK_SIZEOF(short)
2904 CURL_CONFIGURE_LONG
2905 AC_CHECK_SIZEOF(time_t)
2906 AC_CHECK_SIZEOF(off_t)
2907
2908 soname_bump=no
2909 if test x"$ac_cv_native_windows" != "xyes" &&
2910    test $ac_cv_sizeof_off_t -ne $curl_sizeof_curl_off_t; then
2911   AC_MSG_WARN([This libcurl built is probably not ABI compatible with previous])
2912   AC_MSG_WARN([builds! You MUST read lib/README.curl_off_t to figure it out.])
2913   soname_bump=yes
2914 fi
2915
2916
2917 AC_CHECK_TYPE(long long,
2918    [AC_DEFINE(HAVE_LONGLONG, 1,
2919       [Define to 1 if the compiler supports the 'long long' data type.])]
2920    longlong="yes"
2921 )
2922
2923 if test "xyes" = "x$longlong"; then
2924   AC_MSG_CHECKING([if numberLL works])
2925   AC_COMPILE_IFELSE([
2926     AC_LANG_PROGRAM([[
2927     ]],[[
2928       long long val = 1000LL;
2929     ]])
2930   ],[
2931     AC_MSG_RESULT([yes])
2932     AC_DEFINE(HAVE_LL, 1, [if your compiler supports LL])
2933   ],[
2934     AC_MSG_RESULT([no])
2935   ])
2936 fi
2937
2938
2939 # check for ssize_t
2940 AC_CHECK_TYPE(ssize_t, ,
2941    AC_DEFINE(ssize_t, int, [the signed version of size_t]))
2942
2943 # check for bool type
2944 AC_CHECK_TYPE([bool],[
2945   AC_DEFINE(HAVE_BOOL_T, 1,
2946     [Define to 1 if bool is an available type.])
2947 ], ,[
2948 #ifdef HAVE_SYS_TYPES_H
2949 #include <sys/types.h>
2950 #endif
2951 #ifdef HAVE_STDBOOL_H
2952 #include <stdbool.h>
2953 #endif
2954 ])
2955
2956 CURL_CONFIGURE_CURL_SOCKLEN_T
2957
2958 CURL_CONFIGURE_PULL_SYS_POLL
2959
2960 TYPE_IN_ADDR_T
2961
2962 TYPE_SOCKADDR_STORAGE
2963
2964 TYPE_SIG_ATOMIC_T
2965
2966 AC_TYPE_SIGNAL
2967
2968 CURL_CHECK_FUNC_SELECT
2969
2970 CURL_CHECK_FUNC_RECV
2971 CURL_CHECK_FUNC_SEND
2972 CURL_CHECK_MSG_NOSIGNAL
2973
2974 CURL_CHECK_FUNC_ALARM
2975 CURL_CHECK_FUNC_BASENAME
2976 CURL_CHECK_FUNC_CLOSESOCKET
2977 CURL_CHECK_FUNC_CLOSESOCKET_CAMEL
2978 CURL_CHECK_FUNC_CONNECT
2979 CURL_CHECK_FUNC_FCNTL
2980 CURL_CHECK_FUNC_FDOPEN
2981 CURL_CHECK_FUNC_FREEADDRINFO
2982 CURL_CHECK_FUNC_FREEIFADDRS
2983 CURL_CHECK_FUNC_FSETXATTR
2984 CURL_CHECK_FUNC_FTRUNCATE
2985 CURL_CHECK_FUNC_GETADDRINFO
2986 CURL_CHECK_FUNC_GAI_STRERROR
2987 CURL_CHECK_FUNC_GETHOSTBYADDR
2988 CURL_CHECK_FUNC_GETHOSTBYADDR_R
2989 CURL_CHECK_FUNC_GETHOSTBYNAME
2990 CURL_CHECK_FUNC_GETHOSTBYNAME_R
2991 CURL_CHECK_FUNC_GETHOSTNAME
2992 CURL_CHECK_FUNC_GETIFADDRS
2993 CURL_CHECK_FUNC_GETSERVBYPORT_R
2994 CURL_CHECK_FUNC_GMTIME_R
2995 CURL_CHECK_FUNC_INET_NTOA_R
2996 CURL_CHECK_FUNC_INET_NTOP
2997 CURL_CHECK_FUNC_INET_PTON
2998 CURL_CHECK_FUNC_IOCTL
2999 CURL_CHECK_FUNC_IOCTLSOCKET
3000 CURL_CHECK_FUNC_IOCTLSOCKET_CAMEL
3001 CURL_CHECK_FUNC_LOCALTIME_R
3002 CURL_CHECK_FUNC_MEMRCHR
3003 CURL_CHECK_FUNC_POLL
3004 CURL_CHECK_FUNC_SETSOCKOPT
3005 CURL_CHECK_FUNC_SIGACTION
3006 CURL_CHECK_FUNC_SIGINTERRUPT
3007 CURL_CHECK_FUNC_SIGNAL
3008 CURL_CHECK_FUNC_SIGSETJMP
3009 CURL_CHECK_FUNC_SOCKET
3010 CURL_CHECK_FUNC_SOCKETPAIR
3011 CURL_CHECK_FUNC_STRCASECMP
3012 CURL_CHECK_FUNC_STRCMPI
3013 CURL_CHECK_FUNC_STRDUP
3014 CURL_CHECK_FUNC_STRERROR_R
3015 CURL_CHECK_FUNC_STRICMP
3016 CURL_CHECK_FUNC_STRNCASECMP
3017 CURL_CHECK_FUNC_STRNCMPI
3018 CURL_CHECK_FUNC_STRNICMP
3019 CURL_CHECK_FUNC_STRSTR
3020 CURL_CHECK_FUNC_STRTOK_R
3021 CURL_CHECK_FUNC_STRTOLL
3022 CURL_CHECK_FUNC_WRITEV
3023
3024 case $host in
3025   *msdosdjgpp)
3026      ac_cv_func_pipe=no
3027      skipcheck_pipe=yes
3028      AC_MSG_NOTICE([skip check for pipe on msdosdjgpp])
3029     ;;
3030 esac
3031
3032 AC_CHECK_FUNCS([fork \
3033   geteuid \
3034   getpass_r \
3035   getppid \
3036   getprotobyname \
3037   getpwuid \
3038   getrlimit \
3039   gettimeofday \
3040   inet_addr \
3041   perror \
3042   pipe \
3043   setlocale \
3044   setmode \
3045   setrlimit \
3046   uname \
3047   utime
3048 ],[
3049 ],[
3050   func="$ac_func"
3051   eval skipcheck=\$skipcheck_$func
3052   if test "x$skipcheck" != "xyes"; then
3053     AC_MSG_CHECKING([deeper for $func])
3054     AC_LINK_IFELSE([
3055       AC_LANG_PROGRAM([[
3056       ]],[[
3057         $func ();
3058       ]])
3059     ],[
3060       AC_MSG_RESULT([yes])
3061       eval "ac_cv_func_$func=yes"
3062       AC_DEFINE_UNQUOTED(XC_SH_TR_CPP([HAVE_$func]), [1],
3063         [Define to 1 if you have the $func function.])
3064     ],[
3065       AC_MSG_RESULT([but still no])
3066     ])
3067   fi
3068 ])
3069
3070 dnl Check if the getnameinfo function is available
3071 dnl and get the types of five of its arguments.
3072 CURL_CHECK_FUNC_GETNAMEINFO
3073
3074 if test "$ipv6" = "yes"; then
3075   if test "$ac_cv_func_getaddrinfo" = "yes"; then
3076     AC_DEFINE(ENABLE_IPV6, 1, [Define if you want to enable IPv6 support])
3077     IPV6_ENABLED=1
3078     AC_SUBST(IPV6_ENABLED)
3079   fi
3080   CURL_CHECK_NI_WITHSCOPEID
3081 fi
3082
3083 CURL_CHECK_NONBLOCKING_SOCKET
3084
3085 dnl ************************************************************
3086 dnl nroff tool stuff
3087 dnl
3088
3089 AC_PATH_PROG( PERL, perl, ,
3090   $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
3091 AC_SUBST(PERL)
3092
3093 AC_PATH_PROGS( NROFF, gnroff nroff, ,
3094   $PATH:/usr/bin/:/usr/local/bin )
3095 AC_SUBST(NROFF)
3096
3097 if test -n "$NROFF"; then
3098   dnl only check for nroff options if an nroff command was found
3099
3100   AC_MSG_CHECKING([how to use *nroff to get plain text from man pages])
3101   MANOPT="-man"
3102   mancheck=`echo foo | $NROFF $MANOPT 2>/dev/null`
3103   if test -z "$mancheck"; then
3104     MANOPT="-mandoc"
3105    mancheck=`echo foo | $NROFF $MANOPT 2>/dev/null`
3106     if test -z "$mancheck"; then
3107       MANOPT=""
3108       AC_MSG_RESULT([failed])
3109       AC_MSG_WARN([found no *nroff option to get plaintext from man pages])
3110     else
3111       AC_MSG_RESULT([$MANOPT])
3112     fi
3113   else
3114     AC_MSG_RESULT([$MANOPT])
3115   fi
3116   AC_SUBST(MANOPT)
3117 fi
3118
3119 if test -z "$MANOPT"
3120 then
3121   dnl if no nroff tool was found, or no option that could convert man pages
3122   dnl was found, then disable the built-in manual stuff
3123   AC_MSG_WARN([disabling built-in manual])
3124   USE_MANUAL="no";
3125 fi
3126
3127 dnl *************************************************************************
3128 dnl If the manual variable still is set, then we go with providing a built-in
3129 dnl manual
3130
3131 if test "$USE_MANUAL" = "1"; then
3132   AC_DEFINE(USE_MANUAL, 1, [If you want to build curl with the built-in manual])
3133   curl_manual_msg="enabled"
3134 fi
3135
3136 dnl set variable for use in automakefile(s)
3137 AM_CONDITIONAL(USE_MANUAL, test x"$USE_MANUAL" = x1)
3138
3139 CURL_CHECK_LIB_ARES
3140 AM_CONDITIONAL(USE_EMBEDDED_ARES, test x$embedded_ares = xyes)
3141
3142 if test "x$ac_cv_native_windows" != "xyes" &&
3143    test "x$enable_shared" = "xyes"; then
3144   build_libhostname=yes
3145 else
3146   build_libhostname=no
3147 fi
3148 AM_CONDITIONAL(BUILD_LIBHOSTNAME, test x$build_libhostname = xyes)
3149
3150 CURL_CHECK_OPTION_THREADED_RESOLVER
3151
3152 if test "x$want_thres" = xyes && test "x$want_ares" = xyes; then
3153   AC_MSG_ERROR(
3154 [Options --enable-threaded-resolver and --enable-ares are mutually exclusive])
3155 fi
3156
3157 if test "$want_thres" = "yes"; then
3158   AC_CHECK_HEADER(pthread.h,
3159     [ AC_DEFINE(HAVE_PTHREAD_H, 1, [if you have <pthread.h>])
3160       save_CFLAGS="$CFLAGS"
3161
3162       dnl first check for function without lib
3163       AC_CHECK_FUNC(pthread_create, [USE_THREADS_POSIX=1] )
3164
3165       dnl if it wasn't found without lib, search for it in pthread lib
3166       if test "$USE_THREADS_POSIX" != "1"
3167       then
3168         CFLAGS="$CFLAGS -pthread"
3169         AC_CHECK_LIB(pthread, pthread_create,
3170                      [USE_THREADS_POSIX=1],
3171                      [ CFLAGS="$save_CFLAGS"])
3172       fi
3173
3174       if test "x$USE_THREADS_POSIX" = "x1"
3175       then
3176         AC_DEFINE(USE_THREADS_POSIX, 1, [if you want POSIX threaded DNS lookup])
3177         curl_res_msg="POSIX threaded"
3178       fi
3179
3180
3181   ])
3182 fi
3183
3184 dnl ************************************************************
3185 dnl disable verbose text strings
3186 dnl
3187 AC_MSG_CHECKING([whether to enable verbose strings])
3188 AC_ARG_ENABLE(verbose,
3189 AC_HELP_STRING([--enable-verbose],[Enable verbose strings])
3190 AC_HELP_STRING([--disable-verbose],[Disable verbose strings]),
3191 [ case "$enableval" in
3192   no)
3193        AC_MSG_RESULT(no)
3194        AC_DEFINE(CURL_DISABLE_VERBOSE_STRINGS, 1, [to disable verbose strings])
3195        curl_verbose_msg="no"
3196        ;;
3197   *)   AC_MSG_RESULT(yes)
3198        ;;
3199   esac ],
3200        AC_MSG_RESULT(yes)
3201 )
3202
3203 dnl ************************************************************
3204 dnl enable SSPI support
3205 dnl
3206 AC_MSG_CHECKING([whether to enable SSPI support (Windows native builds only)])
3207 AC_ARG_ENABLE(sspi,
3208 AC_HELP_STRING([--enable-sspi],[Enable SSPI])
3209 AC_HELP_STRING([--disable-sspi],[Disable SSPI]),
3210 [ case "$enableval" in
3211   yes)
3212        if test "$ac_cv_native_windows" = "yes"; then
3213          AC_MSG_RESULT(yes)
3214          AC_DEFINE(USE_WINDOWS_SSPI, 1, [to enable SSPI support])
3215          AC_SUBST(USE_WINDOWS_SSPI, [1])
3216          curl_sspi_msg="enabled"
3217        else
3218          AC_MSG_RESULT(no)
3219          AC_MSG_WARN([--enable-sspi Ignored. Only supported on native Windows builds.])
3220        fi
3221        ;;
3222   *)
3223        if test "x$WINSSL_ENABLED" = "x1"; then
3224          # --with-winssl implies --enable-sspi
3225          AC_MSG_RESULT(yes)
3226        else
3227          AC_MSG_RESULT(no)
3228        fi
3229        ;;
3230   esac ],
3231        if test "x$WINSSL_ENABLED" = "x1"; then
3232          # --with-winssl implies --enable-sspi
3233          AC_MSG_RESULT(yes)
3234        else
3235          AC_MSG_RESULT(no)
3236        fi
3237 )
3238
3239 dnl ************************************************************
3240 dnl disable cryptographic authentication
3241 dnl
3242 AC_MSG_CHECKING([whether to enable cryptographic authentication methods])
3243 AC_ARG_ENABLE(crypto-auth,
3244 AC_HELP_STRING([--enable-crypto-auth],[Enable cryptographic authentication])
3245 AC_HELP_STRING([--disable-crypto-auth],[Disable cryptographic authentication]),
3246 [ case "$enableval" in
3247   no)
3248        AC_MSG_RESULT(no)
3249        AC_DEFINE(CURL_DISABLE_CRYPTO_AUTH, 1, [to disable cryptographic authentication])
3250        ;;
3251   *)   AC_MSG_RESULT(yes)
3252        ;;
3253   esac ],
3254        AC_MSG_RESULT(yes)
3255 )
3256
3257 CURL_CHECK_OPTION_NTLM_WB
3258
3259 CURL_CHECK_NTLM_WB
3260
3261 dnl ************************************************************
3262 dnl disable TLS-SRP authentication
3263 dnl
3264 AC_MSG_CHECKING([whether to enable TLS-SRP authentication])
3265 AC_ARG_ENABLE(tls-srp,
3266 AC_HELP_STRING([--enable-tls-srp],[Enable TLS-SRP authentication])
3267 AC_HELP_STRING([--disable-tls-srp],[Disable TLS-SRP authentication]),
3268 [ case "$enableval" in
3269   no)
3270        AC_MSG_RESULT(no)
3271        AC_DEFINE(CURL_DISABLE_TLS_SRP, 1, [to disable TLS-SRP authentication])
3272        want_tls_srp=no
3273        ;;
3274   *)   AC_MSG_RESULT(yes)
3275        want_tls_srp=yes
3276        ;;
3277   esac ],
3278        AC_MSG_RESULT(yes)
3279        want_tls_srp=yes
3280 )
3281
3282 if test "$want_tls_srp" = "yes" && ( test "x$HAVE_GNUTLS_SRP" = "x1" || test "x$HAVE_SSLEAY_SRP" = "x1") ; then
3283    AC_DEFINE(USE_TLS_SRP, 1, [Use TLS-SRP authentication])
3284    USE_TLS_SRP=1
3285    curl_tls_srp_msg="enabled"
3286 fi
3287
3288 dnl ************************************************************
3289 dnl disable cookies support
3290 dnl
3291 AC_MSG_CHECKING([whether to enable support for cookies])
3292 AC_ARG_ENABLE(cookies,
3293 AC_HELP_STRING([--enable-cookies],[Enable cookies support])
3294 AC_HELP_STRING([--disable-cookies],[Disable cookies support]),
3295 [ case "$enableval" in
3296   no)
3297        AC_MSG_RESULT(no)
3298        AC_DEFINE(CURL_DISABLE_COOKIES, 1, [to disable cookies support])
3299        ;;
3300   *)   AC_MSG_RESULT(yes)
3301        ;;
3302   esac ],
3303        AC_MSG_RESULT(yes)
3304 )
3305
3306 dnl ************************************************************
3307 dnl hiding of library internal symbols
3308 dnl
3309 CURL_CONFIGURE_SYMBOL_HIDING
3310
3311 dnl ************************************************************
3312 dnl enforce SONAME bump
3313 dnl
3314
3315 AC_MSG_CHECKING([whether to enforce SONAME bump])
3316 AC_ARG_ENABLE(soname-bump,
3317 AC_HELP_STRING([--enable-soname-bump],[Enable enforced SONAME bump])
3318 AC_HELP_STRING([--disable-soname-bump],[Disable enforced SONAME bump]),
3319 [ case "$enableval" in
3320   yes)   AC_MSG_RESULT(yes)
3321          soname_bump=yes
3322          ;;
3323   *)
3324          AC_MSG_RESULT(no)
3325          ;;
3326   esac ],
3327         AC_MSG_RESULT($soname_bump)
3328 )
3329 AM_CONDITIONAL(SONAME_BUMP, test x$soname_bump = xyes)
3330
3331 dnl
3332 dnl All the library dependencies put into $LIB apply to libcurl only.
3333 dnl
3334 LIBCURL_LIBS=$LIBS
3335
3336 AC_SUBST(LIBCURL_LIBS)
3337 AC_SUBST(CURL_NETWORK_LIBS)
3338 AC_SUBST(CURL_NETWORK_AND_TIME_LIBS)
3339
3340 dnl BLANK_AT_MAKETIME may be used in our Makefile.am files to blank
3341 dnl LIBS variable used in generated makefile at makefile processing
3342 dnl time. Doing this functionally prevents LIBS from being used for
3343 dnl all link targets in given makefile.
3344 BLANK_AT_MAKETIME=
3345 AC_SUBST(BLANK_AT_MAKETIME)
3346
3347 AM_CONDITIONAL(CROSSCOMPILING, test x$cross_compiling = xyes)
3348
3349 dnl yes or no
3350 ENABLE_SHARED="$enable_shared"
3351 AC_SUBST(ENABLE_SHARED)
3352
3353 dnl to let curl-config output the static libraries correctly
3354 ENABLE_STATIC="$enable_static"
3355 AC_SUBST(ENABLE_STATIC)
3356
3357
3358 dnl
3359 dnl For keeping supported features and protocols also in pkg-config file
3360 dnl since it is more cross-compile friendly than curl-config
3361 dnl
3362
3363 if test "x$USE_SSLEAY" = "x1"; then
3364   SUPPORT_FEATURES="$SUPPORT_FEATURES SSL"
3365 elif test -n "$SSL_ENABLED"; then
3366   SUPPORT_FEATURES="$SUPPORT_FEATURES SSL"
3367 fi
3368 if test "x$IPV6_ENABLED" = "x1"; then
3369   SUPPORT_FEATURES="$SUPPORT_FEATURES IPv6"
3370 fi
3371 if test "x$HAVE_LIBZ" = "x1"; then
3372   SUPPORT_FEATURES="$SUPPORT_FEATURES libz"
3373 fi
3374 if test "x$USE_ARES" = "x1" -o "x$USE_THREADS_POSIX" = "x1"; then
3375   SUPPORT_FEATURES="$SUPPORT_FEATURES AsynchDNS"
3376 fi
3377 if test "x$IDN_ENABLED" = "x1"; then
3378   SUPPORT_FEATURES="$SUPPORT_FEATURES IDN"
3379 fi
3380 if test "x$USE_WINDOWS_SSPI" = "x1"; then
3381   SUPPORT_FEATURES="$SUPPORT_FEATURES SSPI"
3382 fi
3383 if test "x$CURL_DISABLE_HTTP" != "x1"; then
3384   if test "x$USE_SSLEAY" = "x1" -o "x$USE_WINDOWS_SSPI" = "x1" \
3385       -o "x$GNUTLS_ENABLED" = "x1" -o "x$NSS_ENABLED" = "x1" \
3386       -o "x$DARWINSSL_ENABLED" = "x1"; then
3387     SUPPORT_FEATURES="$SUPPORT_FEATURES NTLM"
3388     if test "x$NTLM_WB_ENABLED" = "x1"; then
3389       SUPPORT_FEATURES="$SUPPORT_FEATURES NTLM_WB"
3390     fi
3391   fi
3392 fi
3393 if test "x$USE_TLS_SRP" = "x1"; then
3394   SUPPORT_FEATURES="$SUPPORT_FEATURES TLS-SRP"
3395 fi
3396
3397 if test "x$USE_NGHTTP2" = "x1"; then
3398   SUPPORT_FEATURES="$SUPPORT_FEATURES HTTP2"
3399 fi
3400
3401 AC_SUBST(SUPPORT_FEATURES)
3402
3403 dnl For supported protocols in pkg-config file
3404 if test "x$CURL_DISABLE_HTTP" != "x1"; then
3405   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS HTTP"
3406   if test "x$SSL_ENABLED" = "x1"; then
3407     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS HTTPS"
3408   fi
3409 fi
3410 if test "x$CURL_DISABLE_FTP" != "x1"; then
3411   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS FTP"
3412   if test "x$SSL_ENABLED" = "x1"; then
3413     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS FTPS"
3414   fi
3415 fi
3416 if test "x$CURL_DISABLE_FILE" != "x1"; then
3417   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS FILE"
3418 fi
3419 if test "x$CURL_DISABLE_TELNET" != "x1"; then
3420   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS TELNET"
3421 fi
3422 if test "x$CURL_DISABLE_LDAP" != "x1"; then
3423   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS LDAP"
3424   if test "x$CURL_DISABLE_LDAPS" != "x1"; then
3425     if (test "x$USE_OPENLDAP" = "x1" && test "x$SSL_ENABLED" = "x1") ||
3426       (test "x$USE_OPENLDAP" != "x1"  && test "x$HAVE_LDAP_SSL" = "x1"); then
3427       SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS LDAPS"
3428     fi
3429   fi
3430 fi
3431 if test "x$CURL_DISABLE_DICT" != "x1"; then
3432   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS DICT"
3433 fi
3434 if test "x$CURL_DISABLE_TFTP" != "x1"; then
3435   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS TFTP"
3436 fi
3437 if test "x$CURL_DISABLE_GOPHER" != "x1"; then
3438   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS GOPHER"
3439 fi
3440 if test "x$CURL_DISABLE_POP3" != "x1"; then
3441   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS POP3"
3442   if test "x$SSL_ENABLED" = "x1"; then
3443     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS POP3S"
3444   fi
3445 fi
3446 if test "x$CURL_DISABLE_IMAP" != "x1"; then
3447   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS IMAP"
3448   if test "x$SSL_ENABLED" = "x1"; then
3449     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS IMAPS"
3450   fi
3451 fi
3452 if test "x$CURL_DISABLE_SMTP" != "x1"; then
3453   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS SMTP"
3454   if test "x$SSL_ENABLED" = "x1"; then
3455     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS SMTPS"
3456   fi
3457 fi
3458 if test "x$USE_LIBSSH2" = "x1"; then
3459   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS SCP"
3460   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS SFTP"
3461 fi
3462 if test "x$CURL_DISABLE_RTSP" != "x1"; then
3463   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS RTSP"
3464 fi
3465 if test "x$USE_LIBRTMP" = "x1"; then
3466   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS RTMP"
3467 fi
3468
3469 dnl replace spaces with newlines
3470 dnl sort the lines
3471 dnl replace the newlines back to spaces
3472 SUPPORT_PROTOCOLS=`echo $SUPPORT_PROTOCOLS | tr ' ' '\012' | sort | tr '\012' ' '`
3473
3474 AC_SUBST(SUPPORT_PROTOCOLS)
3475
3476 dnl squeeze whitespace out of some variables
3477
3478 squeeze CFLAGS
3479 squeeze CPPFLAGS
3480 squeeze DEFS
3481 squeeze LDFLAGS
3482 squeeze LIBS
3483
3484 squeeze LIBCURL_LIBS
3485 squeeze CURL_NETWORK_LIBS
3486 squeeze CURL_NETWORK_AND_TIME_LIBS
3487
3488 squeeze SUPPORT_FEATURES
3489 squeeze SUPPORT_PROTOCOLS
3490
3491 XC_CHECK_BUILD_FLAGS
3492
3493 if test "x$want_curldebug_assumed" = "xyes" &&
3494   test "x$want_curldebug" = "xyes" && test "x$USE_ARES" = "x1"; then
3495   ac_configure_args="$ac_configure_args --enable-curldebug"
3496 fi
3497
3498 AC_CONFIG_FILES([Makefile \
3499            docs/Makefile \
3500            docs/examples/Makefile \
3501            docs/libcurl/Makefile \
3502            include/Makefile \
3503            include/curl/Makefile \
3504            src/Makefile \
3505            lib/Makefile \
3506            lib/libcurl.vers \
3507            tests/Makefile \
3508            tests/certs/Makefile \
3509            tests/certs/scripts/Makefile \
3510            tests/data/Makefile \
3511            tests/server/Makefile \
3512            tests/libtest/Makefile \
3513            tests/unit/Makefile \
3514            packages/Makefile \
3515            packages/Win32/Makefile \
3516            packages/Win32/cygwin/Makefile \
3517            packages/Linux/Makefile \
3518            packages/Linux/RPM/Makefile \
3519            packages/Linux/RPM/curl.spec \
3520            packages/Linux/RPM/curl-ssl.spec \
3521            packages/Solaris/Makefile \
3522            packages/EPM/curl.list \
3523            packages/EPM/Makefile \
3524            packages/vms/Makefile \
3525            packages/AIX/Makefile \
3526            packages/AIX/RPM/Makefile \
3527            packages/AIX/RPM/curl.spec \
3528            curl-config \
3529            libcurl.pc
3530 ])
3531 AC_OUTPUT
3532
3533 CURL_GENERATE_CONFIGUREHELP_PM
3534
3535 XC_AMEND_DISTCLEAN([lib src tests/unit tests/server tests/libtest docs/examples])
3536
3537 AC_MSG_NOTICE([Configured to build curl/libcurl:
3538
3539   curl version:     ${CURLVERSION}
3540   Host setup:       ${host}
3541   Install prefix:   ${prefix}
3542   Compiler:         ${CC}
3543   SSL support:      ${curl_ssl_msg}
3544   SSH support:      ${curl_ssh_msg}
3545   zlib support:     ${curl_zlib_msg}
3546   GSSAPI support:   ${curl_gss_msg}
3547   SPNEGO support:   ${curl_spnego_msg}
3548   TLS-SRP support:  ${curl_tls_srp_msg}
3549   resolver:         ${curl_res_msg}
3550   ipv6 support:     ${curl_ipv6_msg}
3551   IDN support:      ${curl_idn_msg}
3552   Build libcurl:    Shared=${enable_shared}, Static=${enable_static}
3553   Built-in manual:  ${curl_manual_msg}
3554   --libcurl option: ${curl_libcurl_msg}
3555   Verbose errors:   ${curl_verbose_msg}
3556   SSPI support:     ${curl_sspi_msg}
3557   ca cert bundle:   ${ca}
3558   ca cert path:     ${capath}
3559   LDAP support:     ${curl_ldap_msg}
3560   LDAPS support:    ${curl_ldaps_msg}
3561   RTSP support:     ${curl_rtsp_msg}
3562   RTMP support:     ${curl_rtmp_msg}
3563   metalink support: ${curl_mtlnk_msg}
3564   HTTP2 support:    ${curl_h2_msg}
3565   Protocols:        ${SUPPORT_PROTOCOLS}
3566 ])
3567
3568 if test "x$soname_bump" = "xyes"; then
3569
3570 cat <<EOM
3571   SONAME bump:     yes - WARNING: this library will be built with the SONAME
3572                    number bumped due to (a detected) ABI breakage.
3573                    See lib/README.curl_off_t for details on this.
3574 EOM
3575
3576 fi
3577