configure.ac

   1 #***************************************************************************
   2 #                                  _   _ ____  _
   3 #  Project                     ___| | | |  _ \| |
   4 #                             / __| | | | |_) | |
   5 #                            | (__| |_| |  _ <| |___
   6 #                             \___|\___/|_| \_\_____|
   7 #
   8 # Copyright (C) 1998 - 2014, Daniel Stenberg, <daniel@haxx.se>, et al.
   9 #
  10 # This software is licensed as described in the file COPYING, which
  11 # you should have received as part of this distribution. The terms
  12 # are also available at http://curl.haxx.se/docs/copyright.html.
  13 #
  14 # You may opt to use, copy, modify, merge, publish, distribute and/or sell
  15 # copies of the Software, and permit persons to whom the Software is
  16 # furnished to do so, under the terms of the COPYING file.
  17 #
  18 # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
  19 # KIND, either express or implied.
  20 #
  21 #***************************************************************************
  22 dnl Process this file with autoconf to produce a configure script.
  23
  24 AC_PREREQ(2.57)
  25
  26 dnl We don't know the version number "statically" so we use a dash here
  27 AC_INIT([curl], [-], [a suitable curl mailing list: http://curl.haxx.se/mail/])
  28
  29 XC_OVR_ZZ50
  30 XC_OVR_ZZ60
  31 CURL_OVERRIDE_AUTOCONF
  32
  33 dnl configure script copyright
  34 AC_COPYRIGHT([Copyright (c) 1998 - 2014 Daniel Stenberg, <daniel@haxx.se>
  35 This configure script may be copied, distributed and modified under the
  36 terms of the curl license; see COPYING for more details])
  37
  38 AC_CONFIG_SRCDIR([lib/urldata.h])
  39 AC_CONFIG_HEADERS(lib/curl_config.h include/curl/curlbuild.h)
  40 AC_CONFIG_MACRO_DIR([m4])
  41 AM_MAINTAINER_MODE
  42
  43 CURL_CHECK_OPTION_DEBUG
  44 CURL_CHECK_OPTION_OPTIMIZE
  45 CURL_CHECK_OPTION_WARNINGS
  46 CURL_CHECK_OPTION_WERROR
  47 CURL_CHECK_OPTION_CURLDEBUG
  48 CURL_CHECK_OPTION_SYMBOL_HIDING
  49 CURL_CHECK_OPTION_ARES
  50
  51 XC_CHECK_PATH_SEPARATOR
  52
  53 #
  54 # save the configure arguments
  55 #
  56 CONFIGURE_OPTIONS="\"$ac_configure_args\""
  57 AC_SUBST(CONFIGURE_OPTIONS)
  58
  59 CURL_CFLAG_EXTRAS=""
  60 if test X"$want_werror" = Xyes; then
  61   CURL_CFLAG_EXTRAS="-Werror"
  62 fi
  63 AC_SUBST(CURL_CFLAG_EXTRAS)
  64
  65 dnl SED is mandatory for configure process and libtool.
  66 dnl Set it now, allowing it to be changed later.
  67 if test -z "$SED"; then
  68   dnl allow it to be overridden
  69   AC_PATH_PROG([SED], [sed], [not_found],
  70     [$PATH:/usr/bin:/usr/local/bin])
  71   if test -z "$SED" || test "$SED" = "not_found"; then
  72     AC_MSG_ERROR([sed not found in PATH. Cannot continue without sed.])
  73   fi
  74 fi
  75 AC_SUBST([SED])
  76
  77 dnl GREP is mandatory for configure process and libtool.
  78 dnl Set it now, allowing it to be changed later.
  79 if test -z "$GREP"; then
  80   dnl allow it to be overridden
  81   AC_PATH_PROG([GREP], [grep], [not_found],
  82     [$PATH:/usr/bin:/usr/local/bin])
  83   if test -z "$GREP" || test "$GREP" = "not_found"; then
  84     AC_MSG_ERROR([grep not found in PATH. Cannot continue without grep.])
  85   fi
  86 fi
  87 AC_SUBST([GREP])
  88
  89 dnl EGREP is mandatory for configure process and libtool.
  90 dnl Set it now, allowing it to be changed later.
  91 if test -z "$EGREP"; then
  92   dnl allow it to be overridden
  93   if echo a | ($GREP -E '(a|b)') >/dev/null 2>&1; then
  94     AC_MSG_CHECKING([for egrep])
  95     EGREP="$GREP -E"
  96     AC_MSG_RESULT([$EGREP])
  97   else
  98     AC_PATH_PROG([EGREP], [egrep], [not_found],
  99       [$PATH:/usr/bin:/usr/local/bin])
 100   fi
 101 fi
 102 if test -z "$EGREP" || test "$EGREP" = "not_found"; then
 103   AC_MSG_ERROR([egrep not found in PATH. Cannot continue without egrep.])
 104 fi
 105 AC_SUBST([EGREP])
 106
 107 dnl AR is mandatory for configure process and libtool.
 108 dnl This is target dependent, so check it as a tool.
 109 if test -z "$AR"; then
 110   dnl allow it to be overridden
 111   AC_PATH_TOOL([AR], [ar], [not_found],
 112     [$PATH:/usr/bin:/usr/local/bin])
 113   if test -z "$AR" || test "$AR" = "not_found"; then
 114     AC_MSG_ERROR([ar not found in PATH. Cannot continue without ar.])
 115   fi
 116 fi
 117 AC_SUBST([AR])
 118
 119 AC_SUBST(libext)
 120
 121 dnl Remove non-configure distributed curlbuild.h
 122 if test -f ${srcdir}/include/curl/curlbuild.h; then
 123   rm -f ${srcdir}/include/curl/curlbuild.h
 124 fi
 125
 126 dnl figure out the libcurl version
 127 CURLVERSION=`$SED -ne 's/^#define LIBCURL_VERSION "\(.*\)"/\1/p' ${srcdir}/include/curl/curlver.h`
 128 XC_CHECK_PROG_CC
 129 XC_AUTOMAKE
 130 AC_MSG_CHECKING([curl version])
 131 AC_MSG_RESULT($CURLVERSION)
 132
 133 AC_SUBST(CURLVERSION)
 134
 135 dnl
 136 dnl we extract the numerical version for curl-config only
 137 VERSIONNUM=`$SED -ne 's/^#define LIBCURL_VERSION_NUM 0x\(.*\)/\1/p' ${srcdir}/include/curl/curlver.h`
 138 AC_SUBST(VERSIONNUM)
 139
 140 dnl Solaris pkgadd support definitions
 141 PKGADD_PKG="HAXXcurl"
 142 PKGADD_NAME="cURL - a client that groks URLs"
 143 PKGADD_VENDOR="curl.haxx.se"
 144 AC_SUBST(PKGADD_PKG)
 145 AC_SUBST(PKGADD_NAME)
 146 AC_SUBST(PKGADD_VENDOR)
 147
 148 dnl
 149 dnl initialize all the info variables
 150     curl_ssl_msg="no      (--with-{ssl,gnutls,nss,polarssl,cyassl,axtls,winssl,darwinssl} )"
 151     curl_ssh_msg="no      (--with-libssh2)"
 152    curl_zlib_msg="no      (--with-zlib)"
 153     curl_gss_msg="no      (--with-gssapi)"
 154  curl_spnego_msg="no      (--with-spnego)"
 155 curl_tls_srp_msg="no      (--enable-tls-srp)"
 156     curl_res_msg="default (--enable-ares / --enable-threaded-resolver)"
 157    curl_ipv6_msg="no      (--enable-ipv6)"
 158     curl_idn_msg="no      (--with-{libidn,winidn})"
 159  curl_manual_msg="no      (--enable-manual)"
 160 curl_libcurl_msg="enabled (--disable-libcurl-option)"
 161 curl_verbose_msg="enabled (--disable-verbose)"
 162    curl_sspi_msg="no      (--enable-sspi)"
 163    curl_ldap_msg="no      (--enable-ldap / --with-ldap-lib / --with-lber-lib)"
 164   curl_ldaps_msg="no      (--enable-ldaps)"
 165    curl_rtsp_msg="no      (--enable-rtsp)"
 166    curl_rtmp_msg="no      (--with-librtmp)"
 167   curl_mtlnk_msg="no      (--with-libmetalink)"
 168
 169     init_ssl_msg=${curl_ssl_msg}
 170
 171 dnl
 172 dnl Save some initial values the user might have provided
 173 dnl
 174 INITIAL_LDFLAGS=$LDFLAGS
 175 INITIAL_LIBS=$LIBS
 176
 177 dnl
 178 dnl Detect the canonical host and target build environment
 179 dnl
 180
 181 AC_CANONICAL_HOST
 182 dnl Get system canonical name
 183 AC_DEFINE_UNQUOTED(OS, "${host}", [cpu-machine-OS])
 184
 185 dnl Checks for programs.
 186
 187 dnl Our curl_off_t internal and external configure settings
 188 CURL_CONFIGURE_CURL_OFF_T
 189
 190 dnl This defines _ALL_SOURCE for AIX
 191 CURL_CHECK_AIX_ALL_SOURCE
 192
 193 dnl Our configure and build reentrant settings
 194 CURL_CONFIGURE_THREAD_SAFE
 195 CURL_CONFIGURE_REENTRANT
 196
 197 dnl check for how to do large files
 198 AC_SYS_LARGEFILE
 199
 200 XC_LIBTOOL
 201
 202 #
 203 # Automake conditionals based on libtool related checks
 204 #
 205
 206 AM_CONDITIONAL([CURL_LT_SHLIB_USE_VERSION_INFO],
 207   [test "x$xc_lt_shlib_use_version_info" = 'xyes'])
 208 AM_CONDITIONAL([CURL_LT_SHLIB_USE_NO_UNDEFINED],
 209   [test "x$xc_lt_shlib_use_no_undefined" = 'xyes'])
 210 AM_CONDITIONAL([CURL_LT_SHLIB_USE_MIMPURE_TEXT],
 211   [test "x$xc_lt_shlib_use_mimpure_text" = 'xyes'])
 212
 213 #
 214 # Due to libtool and automake machinery limitations of not allowing
 215 # specifying separate CPPFLAGS or CFLAGS when compiling objects for
 216 # inclusion of these in shared or static libraries, we are forced to
 217 # build using separate configure runs for shared and static libraries
 218 # on systems where different CPPFLAGS or CFLAGS are mandatory in order
 219 # to compile objects for each kind of library. Notice that relying on
 220 # the '-DPIC' CFLAG that libtool provides is not valid given that the
 221 # user might for example choose to build static libraries with PIC.
 222 #
 223
 224 #
 225 # Make our Makefile.am files use the staticlib CPPFLAG only when strictly
 226 # targeting a static library and not building its shared counterpart.
 227 #
 228
 229 AM_CONDITIONAL([USE_CPPFLAG_CURL_STATICLIB],
 230   [test "x$xc_lt_build_static_only" = 'xyes'])
 231
 232 #
 233 # Make staticlib CPPFLAG variable and its definition visible in output
 234 # files unconditionally, providing an empty definition unless strictly
 235 # targeting a static library and not building its shared counterpart.
 236 #
 237
 238 CPPFLAG_CURL_STATICLIB=
 239 if test "x$xc_lt_build_static_only" = 'xyes'; then
 240   CPPFLAG_CURL_STATICLIB='-DCURL_STATICLIB'
 241 fi
 242 AC_SUBST([CPPFLAG_CURL_STATICLIB])
 243
 244
 245 # Determine whether all dependent libraries must be specified when linking
 246 if test "X$enable_shared" = "Xyes" -a "X$link_all_deplibs" = "Xno"
 247 then
 248     REQUIRE_LIB_DEPS=no
 249 else
 250     REQUIRE_LIB_DEPS=yes
 251 fi
 252 AC_SUBST(REQUIRE_LIB_DEPS)
 253 AM_CONDITIONAL(USE_EXPLICIT_LIB_DEPS, test x$REQUIRE_LIB_DEPS = xyes)
 254
 255 dnl check if there's a way to force code inline
 256 AC_C_INLINE
 257
 258 dnl **********************************************************************
 259 dnl platform/compiler/architecture specific checks/flags
 260 dnl **********************************************************************
 261
 262 CURL_CHECK_COMPILER
 263 CURL_SET_COMPILER_BASIC_OPTS
 264 CURL_SET_COMPILER_DEBUG_OPTS
 265 CURL_SET_COMPILER_OPTIMIZE_OPTS
 266 CURL_SET_COMPILER_WARNING_OPTS
 267
 268 if test "$compiler_id" = "INTEL_UNIX_C"; then
 269   #
 270   if test "$compiler_num" -ge "1000"; then
 271     dnl icc 10.X or later
 272     CFLAGS="$CFLAGS -shared-intel"
 273   elif test "$compiler_num" -ge "900"; then
 274     dnl icc 9.X specific
 275     CFLAGS="$CFLAGS -i-dynamic"
 276   fi
 277   #
 278 fi
 279
 280 CURL_CHECK_COMPILER_HALT_ON_ERROR
 281 CURL_CHECK_COMPILER_ARRAY_SIZE_NEGATIVE
 282 CURL_CHECK_COMPILER_PROTOTYPE_MISMATCH
 283 CURL_CHECK_COMPILER_SYMBOL_HIDING
 284
 285 CURL_CHECK_CURLDEBUG
 286 AM_CONDITIONAL(CURLDEBUG, test x$want_curldebug = xyes)
 287
 288 supports_unittests=yes
 289 # cross-compilation of unit tests static library/programs fails when
 290 # libcurl shared library is built. This might be due to a libtool or
 291 # automake issue. In this case we disable unit tests.
 292 if test "x$cross_compiling" != "xno" &&
 293    test "x$enable_shared" != "xno"; then
 294   supports_unittests=no
 295 fi
 296
 297 # IRIX 6.5.24 gcc 3.3 autobuilds fail unittests library compilation due to
 298 # a problem related with OpenSSL headers and library versions not matching.
 299 # Disable unit tests while time to further investigate this is found.
 300 case $host in
 301   mips-sgi-irix6.5)
 302     if test "$compiler_id" = "GNU_C"; then
 303       supports_unittests=no
 304     fi
 305     ;;
 306 esac
 307
 308 # All AIX autobuilds fails unit tests linking against unittests library
 309 # due to unittests library being built with no symbols or members. Libtool ?
 310 # Disable unit tests while time to further investigate this is found.
 311 case $host_os in
 312   aix*)
 313     supports_unittests=no
 314     ;;
 315 esac
 316
 317 dnl Build unit tests when option --enable-debug is given.
 318 if test "x$want_debug" = "xyes" &&
 319    test "x$supports_unittests" = "xyes"; then
 320   want_unittests=yes
 321 else
 322   want_unittests=no
 323 fi
 324 AM_CONDITIONAL(BUILD_UNITTESTS, test x$want_unittests = xyes)
 325
 326 dnl **********************************************************************
 327 dnl Compilation based checks should not be done before this point.
 328 dnl **********************************************************************
 329
 330 dnl **********************************************************************
 331 dnl Make sure that our checks for headers windows.h winsock.h winsock2.h
 332 dnl and ws2tcpip.h take precedence over any other further checks which
 333 dnl could be done later using AC_CHECK_HEADER or AC_CHECK_HEADERS for
 334 dnl this specific header files. And do them before its results are used.
 335 dnl **********************************************************************
 336
 337 CURL_CHECK_HEADER_WINDOWS
 338 CURL_CHECK_NATIVE_WINDOWS
 339 case X-"$ac_cv_native_windows" in
 340   X-yes)
 341     CURL_CHECK_HEADER_WINSOCK
 342     CURL_CHECK_HEADER_WINSOCK2
 343     CURL_CHECK_HEADER_WS2TCPIP
 344     CURL_CHECK_HEADER_WINLDAP
 345     CURL_CHECK_HEADER_WINBER
 346     ;;
 347   *)
 348     ac_cv_header_winsock_h="no"
 349     ac_cv_header_winsock2_h="no"
 350     ac_cv_header_ws2tcpip_h="no"
 351     ac_cv_header_winldap_h="no"
 352     ac_cv_header_winber_h="no"
 353     ;;
 354 esac
 355 CURL_CHECK_WIN32_LARGEFILE
 356
 357 dnl ************************************************************
 358 dnl switch off particular protocols
 359 dnl
 360 AC_MSG_CHECKING([whether to support http])
 361 AC_ARG_ENABLE(http,
 362 AC_HELP_STRING([--enable-http],[Enable HTTP support])
 363 AC_HELP_STRING([--disable-http],[Disable HTTP support]),
 364 [ case "$enableval" in
 365   no)
 366        AC_MSG_RESULT(no)
 367        AC_DEFINE(CURL_DISABLE_HTTP, 1, [to disable HTTP])
 368        AC_MSG_WARN([disable HTTP disables FTP over proxy and RTSP])
 369        AC_SUBST(CURL_DISABLE_HTTP, [1])
 370        AC_DEFINE(CURL_DISABLE_RTSP, 1, [to disable RTSP])
 371        AC_SUBST(CURL_DISABLE_RTSP, [1])
 372        ;;
 373   *)   AC_MSG_RESULT(yes)
 374        ;;
 375   esac ],
 376        AC_MSG_RESULT(yes)
 377 )
 378 AC_MSG_CHECKING([whether to support ftp])
 379 AC_ARG_ENABLE(ftp,
 380 AC_HELP_STRING([--enable-ftp],[Enable FTP support])
 381 AC_HELP_STRING([--disable-ftp],[Disable FTP support]),
 382 [ case "$enableval" in
 383   no)
 384        AC_MSG_RESULT(no)
 385        AC_DEFINE(CURL_DISABLE_FTP, 1, [to disable FTP])
 386        AC_SUBST(CURL_DISABLE_FTP, [1])
 387        ;;
 388   *)   AC_MSG_RESULT(yes)
 389        ;;
 390   esac ],
 391        AC_MSG_RESULT(yes)
 392 )
 393 AC_MSG_CHECKING([whether to support file])
 394 AC_ARG_ENABLE(file,
 395 AC_HELP_STRING([--enable-file],[Enable FILE support])
 396 AC_HELP_STRING([--disable-file],[Disable FILE support]),
 397 [ case "$enableval" in
 398   no)
 399        AC_MSG_RESULT(no)
 400        AC_DEFINE(CURL_DISABLE_FILE, 1, [to disable FILE])
 401        AC_SUBST(CURL_DISABLE_FILE, [1])
 402        ;;
 403   *)   AC_MSG_RESULT(yes)
 404        ;;
 405   esac ],
 406        AC_MSG_RESULT(yes)
 407 )
 408 AC_MSG_CHECKING([whether to support ldap])
 409 AC_ARG_ENABLE(ldap,
 410 AC_HELP_STRING([--enable-ldap],[Enable LDAP support])
 411 AC_HELP_STRING([--disable-ldap],[Disable LDAP support]),
 412 [ case "$enableval" in
 413   no)
 414        AC_MSG_RESULT(no)
 415        AC_DEFINE(CURL_DISABLE_LDAP, 1, [to disable LDAP])
 416        AC_SUBST(CURL_DISABLE_LDAP, [1])
 417        ;;
 418   *)
 419        AC_MSG_RESULT(yes)
 420        ;;
 421   esac ],[
 422        AC_MSG_RESULT(yes) ]
 423 )
 424 AC_MSG_CHECKING([whether to support ldaps])
 425 AC_ARG_ENABLE(ldaps,
 426 AC_HELP_STRING([--enable-ldaps],[Enable LDAPS support])
 427 AC_HELP_STRING([--disable-ldaps],[Disable LDAPS support]),
 428 [ case "$enableval" in
 429   no)
 430        AC_MSG_RESULT(no)
 431        AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
 432        AC_SUBST(CURL_DISABLE_LDAPS, [1])
 433        ;;
 434   *)   if test "x$CURL_DISABLE_LDAP" = "x1" ; then
 435          AC_MSG_RESULT(LDAP needs to be enabled to support LDAPS)
 436          AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
 437          AC_SUBST(CURL_DISABLE_LDAPS, [1])
 438        else
 439          AC_MSG_RESULT(yes)
 440          AC_DEFINE(HAVE_LDAP_SSL, 1, [Use LDAPS implementation])
 441          AC_SUBST(HAVE_LDAP_SSL, [1])
 442        fi
 443        ;;
 444   esac ],[
 445        if test "x$CURL_DISABLE_LDAP" = "x1" ; then
 446          AC_MSG_RESULT(no)
 447          AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
 448          AC_SUBST(CURL_DISABLE_LDAPS, [1])
 449        else
 450          AC_MSG_RESULT(yes)
 451          AC_DEFINE(HAVE_LDAP_SSL, 1, [Use LDAPS implementation])
 452          AC_SUBST(HAVE_LDAP_SSL, [1])
 453        fi ]
 454 )
 455
 456 AC_MSG_CHECKING([whether to support rtsp])
 457 AC_ARG_ENABLE(rtsp,
 458 AC_HELP_STRING([--enable-rtsp],[Enable RTSP support])
 459 AC_HELP_STRING([--disable-rtsp],[Disable RTSP support]),
 460 [ case "$enableval" in
 461   no)
 462        AC_MSG_RESULT(no)
 463        AC_DEFINE(CURL_DISABLE_RTSP, 1, [to disable RTSP])
 464        AC_SUBST(CURL_DISABLE_RTSP, [1])
 465        ;;
 466   *)   if test x$CURL_DISABLE_HTTP = x1 ; then
 467           AC_MSG_ERROR(HTTP support needs to be enabled in order to enable RTSP support!)
 468        else
 469           AC_MSG_RESULT(yes)
 470           curl_rtsp_msg="enabled"
 471        fi
 472        ;;
 473   esac ],
 474        if test "x$CURL_DISABLE_HTTP" != "x1"; then
 475           AC_MSG_RESULT(yes)
 476           curl_rtsp_msg="enabled"
 477        else
 478           AC_MSG_RESULT(no)
 479        fi
 480 )
 481
 482 AC_MSG_CHECKING([whether to support proxies])
 483 AC_ARG_ENABLE(proxy,
 484 AC_HELP_STRING([--enable-proxy],[Enable proxy support])
 485 AC_HELP_STRING([--disable-proxy],[Disable proxy support]),
 486 [ case "$enableval" in
 487   no)
 488        AC_MSG_RESULT(no)
 489        AC_DEFINE(CURL_DISABLE_PROXY, 1, [to disable proxies])
 490        AC_SUBST(CURL_DISABLE_PROXY, [1])
 491        ;;
 492   *)   AC_MSG_RESULT(yes)
 493        ;;
 494   esac ],
 495        AC_MSG_RESULT(yes)
 496 )
 497
 498 AC_MSG_CHECKING([whether to support dict])
 499 AC_ARG_ENABLE(dict,
 500 AC_HELP_STRING([--enable-dict],[Enable DICT support])
 501 AC_HELP_STRING([--disable-dict],[Disable DICT support]),
 502 [ case "$enableval" in
 503   no)
 504        AC_MSG_RESULT(no)
 505        AC_DEFINE(CURL_DISABLE_DICT, 1, [to disable DICT])
 506        AC_SUBST(CURL_DISABLE_DICT, [1])
 507        ;;
 508   *)   AC_MSG_RESULT(yes)
 509        ;;
 510   esac ],
 511        AC_MSG_RESULT(yes)
 512 )
 513 AC_MSG_CHECKING([whether to support telnet])
 514 AC_ARG_ENABLE(telnet,
 515 AC_HELP_STRING([--enable-telnet],[Enable TELNET support])
 516 AC_HELP_STRING([--disable-telnet],[Disable TELNET support]),
 517 [ case "$enableval" in
 518   no)
 519        AC_MSG_RESULT(no)
 520        AC_DEFINE(CURL_DISABLE_TELNET, 1, [to disable TELNET])
 521        AC_SUBST(CURL_DISABLE_TELNET, [1])
 522        ;;
 523   *)   AC_MSG_RESULT(yes)
 524        ;;
 525   esac ],
 526        AC_MSG_RESULT(yes)
 527 )
 528 AC_MSG_CHECKING([whether to support tftp])
 529 AC_ARG_ENABLE(tftp,
 530 AC_HELP_STRING([--enable-tftp],[Enable TFTP support])
 531 AC_HELP_STRING([--disable-tftp],[Disable TFTP support]),
 532 [ case "$enableval" in
 533   no)
 534        AC_MSG_RESULT(no)
 535        AC_DEFINE(CURL_DISABLE_TFTP, 1, [to disable TFTP])
 536        AC_SUBST(CURL_DISABLE_TFTP, [1])
 537        ;;
 538   *)   AC_MSG_RESULT(yes)
 539        ;;
 540   esac ],
 541        AC_MSG_RESULT(yes)
 542 )
 543
 544 AC_MSG_CHECKING([whether to support pop3])
 545 AC_ARG_ENABLE(pop3,
 546 AC_HELP_STRING([--enable-pop3],[Enable POP3 support])
 547 AC_HELP_STRING([--disable-pop3],[Disable POP3 support]),
 548 [ case "$enableval" in
 549   no)
 550        AC_MSG_RESULT(no)
 551        AC_DEFINE(CURL_DISABLE_POP3, 1, [to disable POP3])
 552        AC_SUBST(CURL_DISABLE_POP3, [1])
 553        ;;
 554   *)   AC_MSG_RESULT(yes)
 555        ;;
 556   esac ],
 557        AC_MSG_RESULT(yes)
 558 )
 559
 560
 561 AC_MSG_CHECKING([whether to support imap])
 562 AC_ARG_ENABLE(imap,
 563 AC_HELP_STRING([--enable-imap],[Enable IMAP support])
 564 AC_HELP_STRING([--disable-imap],[Disable IMAP support]),
 565 [ case "$enableval" in
 566   no)
 567        AC_MSG_RESULT(no)
 568        AC_DEFINE(CURL_DISABLE_IMAP, 1, [to disable IMAP])
 569        AC_SUBST(CURL_DISABLE_IMAP, [1])
 570        ;;
 571   *)   AC_MSG_RESULT(yes)
 572        ;;
 573   esac ],
 574        AC_MSG_RESULT(yes)
 575 )
 576
 577
 578 AC_MSG_CHECKING([whether to support smtp])
 579 AC_ARG_ENABLE(smtp,
 580 AC_HELP_STRING([--enable-smtp],[Enable SMTP support])
 581 AC_HELP_STRING([--disable-smtp],[Disable SMTP support]),
 582 [ case "$enableval" in
 583   no)
 584        AC_MSG_RESULT(no)
 585        AC_DEFINE(CURL_DISABLE_SMTP, 1, [to disable SMTP])
 586        AC_SUBST(CURL_DISABLE_SMTP, [1])
 587        ;;
 588   *)   AC_MSG_RESULT(yes)
 589        ;;
 590   esac ],
 591        AC_MSG_RESULT(yes)
 592 )
 593
 594 AC_MSG_CHECKING([whether to support gopher])
 595 AC_ARG_ENABLE(gopher,
 596 AC_HELP_STRING([--enable-gopher],[Enable Gopher support])
 597 AC_HELP_STRING([--disable-gopher],[Disable Gopher support]),
 598 [ case "$enableval" in
 599   no)
 600        AC_MSG_RESULT(no)
 601        AC_DEFINE(CURL_DISABLE_GOPHER, 1, [to disable Gopher])
 602        AC_SUBST(CURL_DISABLE_GOPHER, [1])
 603        ;;
 604   *)   AC_MSG_RESULT(yes)
 605        ;;
 606   esac ],
 607        AC_MSG_RESULT(yes)
 608 )
 609
 610
 611 dnl **********************************************************************
 612 dnl Check for built-in manual
 613 dnl **********************************************************************
 614
 615 AC_MSG_CHECKING([whether to provide built-in manual])
 616 AC_ARG_ENABLE(manual,
 617 AC_HELP_STRING([--enable-manual],[Enable built-in manual])
 618 AC_HELP_STRING([--disable-manual],[Disable built-in manual]),
 619 [ case "$enableval" in
 620   no)
 621        AC_MSG_RESULT(no)
 622        ;;
 623   *)   AC_MSG_RESULT(yes)
 624        USE_MANUAL="1"
 625        ;;
 626   esac ],
 627        AC_MSG_RESULT(yes)
 628        USE_MANUAL="1"
 629 )
 630 dnl The actual use of the USE_MANUAL variable is done much later in this
 631 dnl script to allow other actions to disable it as well.
 632
 633 dnl ************************************************************
 634 dnl disable C code generation support
 635 dnl
 636 AC_MSG_CHECKING([whether to enable generation of C code])
 637 AC_ARG_ENABLE(libcurl_option,
 638 AC_HELP_STRING([--enable-libcurl-option],[Enable --libcurl C code generation support])
 639 AC_HELP_STRING([--disable-libcurl-option],[Disable --libcurl C code generation support]),
 640 [ case "$enableval" in
 641   no)
 642        AC_MSG_RESULT(no)
 643        AC_DEFINE(CURL_DISABLE_LIBCURL_OPTION, 1, [to disable --libcurl C code generation option])
 644        curl_libcurl_msg="no"
 645        ;;
 646   *)   AC_MSG_RESULT(yes)
 647        ;;
 648   esac ],
 649        AC_MSG_RESULT(yes)
 650 )
 651
 652 dnl **********************************************************************
 653 dnl Checks for libraries.
 654 dnl **********************************************************************
 655
 656 AC_MSG_CHECKING([whether to use libgcc])
 657 AC_ARG_ENABLE(libgcc,
 658 AC_HELP_STRING([--enable-libgcc],[use libgcc when linking]),
 659 [ case "$enableval" in
 660   yes)
 661        LIBS="-lgcc $LIBS"
 662        AC_MSG_RESULT(yes)
 663        ;;
 664   *)   AC_MSG_RESULT(no)
 665        ;;
 666   esac ],
 667        AC_MSG_RESULT(no)
 668 )
 669
 670 CURL_CHECK_LIB_XNET
 671
 672 dnl gethostbyname without lib or in the nsl lib?
 673 AC_CHECK_FUNC(gethostbyname,
 674               [HAVE_GETHOSTBYNAME="1"
 675               ],
 676               [ AC_CHECK_LIB(nsl, gethostbyname,
 677                              [HAVE_GETHOSTBYNAME="1"
 678                              LIBS="-lnsl $LIBS"
 679                              ])
 680               ])
 681
 682 if test "$HAVE_GETHOSTBYNAME" != "1"
 683 then
 684   dnl gethostbyname in the socket lib?
 685   AC_CHECK_LIB(socket, gethostbyname,
 686                [HAVE_GETHOSTBYNAME="1"
 687                LIBS="-lsocket $LIBS"
 688                ])
 689 fi
 690
 691 if test "$HAVE_GETHOSTBYNAME" != "1"
 692 then
 693   dnl gethostbyname in the watt lib?
 694   AC_CHECK_LIB(watt, gethostbyname,
 695                [HAVE_GETHOSTBYNAME="1"
 696                CPPFLAGS="-I/dev/env/WATT_ROOT/inc"
 697                LDFLAGS="-L/dev/env/WATT_ROOT/lib"
 698                LIBS="-lwatt $LIBS"
 699                ])
 700 fi
 701
 702 dnl At least one system has been identified to require BOTH nsl and socket
 703 dnl libs at the same time to link properly.
 704 if test "$HAVE_GETHOSTBYNAME" != "1"
 705 then
 706   AC_MSG_CHECKING([for gethostbyname with both nsl and socket libs])
 707   my_ac_save_LIBS=$LIBS
 708   LIBS="-lnsl -lsocket $LIBS"
 709   AC_LINK_IFELSE([
 710     AC_LANG_PROGRAM([[
 711     ]],[[
 712       gethostbyname();
 713     ]])
 714   ],[
 715     AC_MSG_RESULT([yes])
 716     HAVE_GETHOSTBYNAME="1"
 717   ],[
 718     AC_MSG_RESULT([no])
 719     LIBS=$my_ac_save_LIBS
 720   ])
 721 fi
 722
 723 if test "$HAVE_GETHOSTBYNAME" != "1"
 724 then
 725   dnl This is for winsock systems
 726   if test "$ac_cv_header_windows_h" = "yes"; then
 727     if test "$ac_cv_header_winsock_h" = "yes"; then
 728       case $host in
 729         *-*-mingw32ce*)
 730           winsock_LIB="-lwinsock"
 731           ;;
 732         *)
 733           winsock_LIB="-lwsock32"
 734           ;;
 735       esac
 736     fi
 737     if test "$ac_cv_header_winsock2_h" = "yes"; then
 738       winsock_LIB="-lws2_32"
 739     fi
 740     if test ! -z "$winsock_LIB"; then
 741       my_ac_save_LIBS=$LIBS
 742       LIBS="$winsock_LIB $LIBS"
 743       AC_MSG_CHECKING([for gethostbyname in $winsock_LIB])
 744       AC_LINK_IFELSE([
 745         AC_LANG_PROGRAM([[
 746 #ifdef HAVE_WINDOWS_H
 747 #ifndef WIN32_LEAN_AND_MEAN
 748 #define WIN32_LEAN_AND_MEAN
 749 #endif
 750 #include <windows.h>
 751 #ifdef HAVE_WINSOCK2_H
 752 #include <winsock2.h>
 753 #else
 754 #ifdef HAVE_WINSOCK_H
 755 #include <winsock.h>
 756 #endif
 757 #endif
 758 #endif
 759         ]],[[
 760           gethostbyname("www.dummysite.com");
 761         ]])
 762       ],[
 763         AC_MSG_RESULT([yes])
 764         HAVE_GETHOSTBYNAME="1"
 765       ],[
 766         AC_MSG_RESULT([no])
 767         winsock_LIB=""
 768         LIBS=$my_ac_save_LIBS
 769       ])
 770     fi
 771   fi
 772 fi
 773
 774 if test "$HAVE_GETHOSTBYNAME" != "1"
 775 then
 776   dnl This is for Minix 3.1
 777   AC_MSG_CHECKING([for gethostbyname for Minix 3])
 778   AC_LINK_IFELSE([
 779     AC_LANG_PROGRAM([[
 780 /* Older Minix versions may need <net/gen/netdb.h> here instead */
 781 #include <netdb.h>
 782     ]],[[
 783       gethostbyname("www.dummysite.com");
 784     ]])
 785   ],[
 786     AC_MSG_RESULT([yes])
 787     HAVE_GETHOSTBYNAME="1"
 788   ],[
 789     AC_MSG_RESULT([no])
 790   ])
 791 fi
 792
 793 if test "$HAVE_GETHOSTBYNAME" != "1"
 794 then
 795   dnl This is for eCos with a stubbed DNS implementation
 796   AC_MSG_CHECKING([for gethostbyname for eCos])
 797   AC_LINK_IFELSE([
 798     AC_LANG_PROGRAM([[
 799 #include <stdio.h>
 800 #include <netdb.h>
 801     ]],[[
 802       gethostbyname("www.dummysite.com");
 803     ]])
 804   ],[
 805     AC_MSG_RESULT([yes])
 806     HAVE_GETHOSTBYNAME="1"
 807   ],[
 808     AC_MSG_RESULT([no])
 809   ])
 810 fi
 811
 812 if test "$HAVE_GETHOSTBYNAME" != "1"
 813 then
 814   dnl gethostbyname in the network lib - for Haiku OS
 815   AC_CHECK_LIB(network, gethostbyname,
 816                [HAVE_GETHOSTBYNAME="1"
 817                LIBS="-lnetwork $LIBS"
 818                ])
 819 fi
 820
 821 if test "$HAVE_GETHOSTBYNAME" != "1"
 822 then
 823   dnl gethostbyname in the net lib - for BeOS
 824   AC_CHECK_LIB(net, gethostbyname,
 825                [HAVE_GETHOSTBYNAME="1"
 826                LIBS="-lnet $LIBS"
 827                ])
 828 fi
 829
 830
 831 if test "$HAVE_GETHOSTBYNAME" != "1"; then
 832   AC_MSG_ERROR([couldn't find libraries for gethostbyname()])
 833 fi
 834
 835 dnl resolve lib?
 836 AC_CHECK_FUNC(strcasecmp, , [ AC_CHECK_LIB(resolve, strcasecmp) ])
 837
 838 if test "$ac_cv_lib_resolve_strcasecmp" = "$ac_cv_func_strcasecmp"; then
 839   AC_CHECK_LIB(resolve, strcasecmp,
 840               [LIBS="-lresolve $LIBS"],
 841                ,
 842                -lnsl)
 843 fi
 844 ac_cv_func_strcasecmp="no"
 845
 846 CURL_CHECK_LIBS_CONNECT
 847
 848 CURL_NETWORK_LIBS=$LIBS
 849
 850 dnl **********************************************************************
 851 dnl In case that function clock_gettime with monotonic timer is available,
 852 dnl check for additional required libraries.
 853 dnl **********************************************************************
 854 CURL_CHECK_LIBS_CLOCK_GETTIME_MONOTONIC
 855
 856 dnl **********************************************************************
 857 dnl The preceding library checks are all potentially useful for test
 858 dnl servers and libtest cases which require networking and clock_gettime
 859 dnl support.  Save the list of required libraries at this point for use
 860 dnl while linking those test servers and programs.
 861 dnl **********************************************************************
 862 CURL_NETWORK_AND_TIME_LIBS=$LIBS
 863
 864 dnl **********************************************************************
 865 dnl Check for the presence of ZLIB libraries and headers
 866 dnl **********************************************************************
 867
 868 dnl Check for & handle argument to --with-zlib.
 869
 870 clean_CPPFLAGS=$CPPFLAGS
 871 clean_LDFLAGS=$LDFLAGS
 872 clean_LIBS=$LIBS
 873 ZLIB_LIBS=""
 874 AC_ARG_WITH(zlib,
 875 AC_HELP_STRING([--with-zlib=PATH],[search for zlib in PATH])
 876 AC_HELP_STRING([--without-zlib],[disable use of zlib]),
 877                [OPT_ZLIB="$withval"])
 878
 879 if test "$OPT_ZLIB" = "no" ; then
 880     AC_MSG_WARN([zlib disabled])
 881 else
 882   if test "$OPT_ZLIB" = "yes" ; then
 883     OPT_ZLIB=""
 884   fi
 885
 886   if test -z "$OPT_ZLIB" ; then
 887     dnl check for the lib first without setting any new path, since many
 888     dnl people have it in the default path
 889
 890     AC_CHECK_LIB(z, inflateEnd,
 891                    dnl libz found, set the variable
 892                    [HAVE_LIBZ="1"
 893                     LIBS="-lz $LIBS"],
 894                    dnl if no lib found, try /usr/local
 895                    [OPT_ZLIB="/usr/local"])
 896
 897   fi
 898
 899   dnl Add a nonempty path to the compiler flags
 900   if test -n "$OPT_ZLIB"; then
 901      CPPFLAGS="$CPPFLAGS -I$OPT_ZLIB/include"
 902      LDFLAGS="$LDFLAGS -L$OPT_ZLIB/lib$libsuff"
 903   fi
 904
 905   AC_CHECK_HEADER(zlib.h,
 906     [
 907     dnl zlib.h was found
 908     HAVE_ZLIB_H="1"
 909     dnl if the lib wasn't found already, try again with the new paths
 910     if test "$HAVE_LIBZ" != "1"; then
 911       AC_CHECK_LIB(z, gzread,
 912                    [
 913                    dnl the lib was found!
 914                    HAVE_LIBZ="1"
 915                    LIBS="-lz $LIBS"
 916                    ],
 917                    [ CPPFLAGS=$clean_CPPFLAGS
 918                    LDFLAGS=$clean_LDFLAGS])
 919     fi
 920     ],
 921     [
 922       dnl zlib.h was not found, restore the flags
 923       CPPFLAGS=$clean_CPPFLAGS
 924       LDFLAGS=$clean_LDFLAGS]
 925     )
 926
 927   if test "$HAVE_LIBZ" = "1" && test "$HAVE_ZLIB_H" != "1"
 928   then
 929     AC_MSG_WARN([configure found only the libz lib, not the header file!])
 930     HAVE_LIBZ=""
 931     CPPFLAGS=$clean_CPPFLAGS
 932     LDFLAGS=$clean_LDFLAGS
 933     LIBS=$clean_LIBS
 934   elif test "$HAVE_LIBZ" != "1" && test "$HAVE_ZLIB_H" = "1"
 935   then
 936     AC_MSG_WARN([configure found only the libz header file, not the lib!])
 937     CPPFLAGS=$clean_CPPFLAGS
 938     LDFLAGS=$clean_LDFLAGS
 939     LIBS=$clean_LIBS
 940   elif test "$HAVE_LIBZ" = "1" && test "$HAVE_ZLIB_H" = "1"
 941   then
 942     dnl both header and lib were found!
 943     AC_SUBST(HAVE_LIBZ)
 944     AC_DEFINE(HAVE_ZLIB_H, 1, [if you have the zlib.h header file])
 945     AC_DEFINE(HAVE_LIBZ, 1, [if zlib is available])
 946
 947     ZLIB_LIBS="-lz"
 948     LIBS="-lz $clean_LIBS"
 949
 950     dnl replace 'HAVE_LIBZ' in the automake makefile.ams
 951     AMFIXLIB="1"
 952     AC_MSG_NOTICE([found both libz and libz.h header])
 953     curl_zlib_msg="enabled"
 954   fi
 955 fi
 956
 957 dnl set variable for use in automakefile(s)
 958 AM_CONDITIONAL(HAVE_LIBZ, test x"$AMFIXLIB" = x1)
 959 AC_SUBST(ZLIB_LIBS)
 960
 961 dnl **********************************************************************
 962 dnl Check for LDAP
 963 dnl **********************************************************************
 964
 965 LDAPLIBNAME=""
 966 AC_ARG_WITH(ldap-lib,
 967 AC_HELP_STRING([--with-ldap-lib=libname],[Specify name of ldap lib file]),
 968  [LDAPLIBNAME="$withval"])
 969
 970 LBERLIBNAME=""
 971 AC_ARG_WITH(lber-lib,
 972 AC_HELP_STRING([--with-lber-lib=libname],[Specify name of lber lib file]),
 973  [LBERLIBNAME="$withval"])
 974
 975 if test x$CURL_DISABLE_LDAP != x1 ; then
 976
 977   CURL_CHECK_HEADER_LBER
 978   CURL_CHECK_HEADER_LDAP
 979   CURL_CHECK_HEADER_LDAPSSL
 980   CURL_CHECK_HEADER_LDAP_SSL
 981
 982   if test -z "$LDAPLIBNAME" ; then
 983     if test "$ac_cv_native_windows" = "yes"; then
 984       dnl Windows uses a single and unique LDAP library name
 985       LDAPLIBNAME="wldap32"
 986       LBERLIBNAME="no"
 987     fi
 988   fi
 989
 990   if test "$LDAPLIBNAME" ; then
 991     AC_CHECK_LIB("$LDAPLIBNAME", ldap_init,, [
 992       AC_MSG_WARN(["$LDAPLIBNAME" is not an LDAP library: LDAP disabled])
 993       AC_DEFINE(CURL_DISABLE_LDAP, 1, [to disable LDAP])
 994       AC_SUBST(CURL_DISABLE_LDAP, [1])
 995       AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
 996       AC_SUBST(CURL_DISABLE_LDAPS, [1])])
 997   else
 998     dnl Try to find the right ldap libraries for this system
 999     CURL_CHECK_LIBS_LDAP
1000     case X-"$curl_cv_ldap_LIBS" in
1001       X-unknown)
1002         AC_MSG_WARN([Cannot find libraries for LDAP support: LDAP disabled])
1003         AC_DEFINE(CURL_DISABLE_LDAP, 1, [to disable LDAP])
1004         AC_SUBST(CURL_DISABLE_LDAP, [1])
1005         AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
1006         AC_SUBST(CURL_DISABLE_LDAPS, [1])
1007         ;;
1008     esac
1009   fi
1010 fi
1011
1012 if test x$CURL_DISABLE_LDAP != x1 ; then
1013
1014   if test "$LBERLIBNAME" ; then
1015     dnl If name is "no" then don't define this library at all
1016     dnl (it's only needed if libldap.so's dependencies are broken).
1017     if test "$LBERLIBNAME" != "no" ; then
1018       AC_CHECK_LIB("$LBERLIBNAME", ber_free,, [
1019         AC_MSG_WARN(["$LBERLIBNAME" is not an LBER library: LDAP disabled])
1020         AC_DEFINE(CURL_DISABLE_LDAP, 1, [to disable LDAP])
1021         AC_SUBST(CURL_DISABLE_LDAP, [1])
1022         AC_DEFINE(CURL_DISABLE_LDAPS, 1, [to disable LDAPS])
1023         AC_SUBST(CURL_DISABLE_LDAPS, [1])])
1024     fi
1025   fi
1026 fi
1027
1028 if test x$CURL_DISABLE_LDAP != x1 ; then
1029   AC_CHECK_FUNCS([ldap_url_parse ldap_init_fd])
1030
1031   if test "$LDAPLIBNAME" = "wldap32"; then
1032     curl_ldap_msg="enabled (winldap)"
1033     AC_DEFINE(CURL_LDAP_WIN, 1, [Use Windows LDAP implementation])
1034   else
1035     curl_ldap_msg="enabled (OpenLDAP)"
1036     if test "x$ac_cv_func_ldap_init_fd" = "xyes"; then
1037       AC_DEFINE(USE_OPENLDAP, 1, [Use OpenLDAP-specific code])
1038       AC_SUBST(USE_OPENLDAP, [1])
1039     fi
1040   fi
1041 fi
1042
1043 if test x$CURL_DISABLE_LDAPS != x1 ; then
1044     curl_ldaps_msg="enabled"
1045 fi
1046
1047 dnl **********************************************************************
1048 dnl Checks for IPv6
1049 dnl **********************************************************************
1050
1051 AC_MSG_CHECKING([whether to enable ipv6])
1052 AC_ARG_ENABLE(ipv6,
1053 AC_HELP_STRING([--enable-ipv6],[Enable ipv6 (with ipv4) support])
1054 AC_HELP_STRING([--disable-ipv6],[Disable ipv6 support]),
1055 [ case "$enableval" in
1056   no)
1057        AC_MSG_RESULT(no)
1058        ipv6=no
1059        ;;
1060   *)   AC_MSG_RESULT(yes)
1061        ipv6=yes
1062        ;;
1063   esac ],
1064
1065   AC_TRY_RUN([ /* is AF_INET6 available? */
1066 #include <sys/types.h>
1067 #include <sys/socket.h>
1068 #include <stdlib.h> /* for exit() */
1069 main()
1070 {
1071  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
1072    exit(1);
1073  else
1074    exit(0);
1075 }
1076 ],
1077   AC_MSG_RESULT(yes)
1078   ipv6=yes,
1079   AC_MSG_RESULT(no)
1080   ipv6=no,
1081   AC_MSG_RESULT(no)
1082   ipv6=no
1083 ))
1084
1085 if test "$ipv6" = "yes"; then
1086   curl_ipv6_msg="enabled"
1087 fi
1088
1089 # Check if struct sockaddr_in6 have sin6_scope_id member
1090 if test "$ipv6" = yes; then
1091   AC_MSG_CHECKING([if struct sockaddr_in6 has sin6_scope_id member])
1092   AC_TRY_COMPILE([
1093 #include <sys/types.h>
1094 #include <netinet/in.h>] ,
1095   struct sockaddr_in6 s; s.sin6_scope_id = 0; , have_sin6_scope_id=yes)
1096   if test "$have_sin6_scope_id" = yes; then
1097     AC_MSG_RESULT([yes])
1098     AC_DEFINE(HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID, 1, [Define to 1 if struct sockaddr_in6 has the sin6_scope_id member])
1099   else
1100     AC_MSG_RESULT([no])
1101   fi
1102 fi
1103
1104 dnl **********************************************************************
1105 dnl Check if the operating system allows programs to write to their own argv[]
1106 dnl **********************************************************************
1107
1108 AC_MSG_CHECKING([if argv can be written to])
1109 AC_RUN_IFELSE([
1110   AC_LANG_SOURCE([[
1111 int main(int argc, char ** argv) {
1112     argv[0][0] = ' ';
1113     return (argv[0][0] == ' ')?0:1;
1114 }
1115   ]])
1116 ],[
1117   curl_cv_writable_argv=yes
1118 ],[
1119   curl_cv_writable_argv=no
1120 ],[
1121   curl_cv_writable_argv=cross
1122 ])
1123 case $curl_cv_writable_argv in
1124 yes)
1125         AC_DEFINE(HAVE_WRITABLE_ARGV, 1, [Define this symbol if your OS supports changing the contents of argv])
1126         AC_MSG_RESULT(yes)
1127         ;;
1128 no)
1129         AC_MSG_RESULT(no)
1130         ;;
1131 *)
1132         AC_MSG_RESULT(no)
1133         AC_MSG_WARN([the previous check could not be made default was used])
1134         ;;
1135 esac
1136
1137 dnl **********************************************************************
1138 dnl Check for FBopenssl(SPNEGO) libraries
1139 dnl **********************************************************************
1140
1141 AC_ARG_WITH(spnego,
1142   AC_HELP_STRING([--with-spnego=DIR],
1143                  [Specify location of SPNEGO library fbopenssl]), [
1144   SPNEGO_ROOT="$withval"
1145   if test x"$SPNEGO_ROOT" != xno; then
1146     want_spnego="yes"
1147   fi
1148 ])
1149
1150 AC_MSG_CHECKING([if SPNEGO support is requested])
1151 if test x"$want_spnego" = xyes; then
1152
1153   if test X"$SPNEGO_ROOT" = Xyes; then
1154      AC_MSG_ERROR([FBOpenSSL libs and/or directories were not found where specified!])
1155      AC_MSG_RESULT(no)
1156   else
1157      if test -z "$SPNEGO_LIB_DIR"; then
1158         LDFLAGS="$LDFLAGS -L$SPNEGO_ROOT -lfbopenssl"
1159      else
1160         LDFLAGS="$LDFLAGS $SPNEGO_LIB_DIR"
1161      fi
1162
1163      AC_MSG_RESULT(yes)
1164      AC_DEFINE(HAVE_SPNEGO, 1,
1165                [Define this if you have the SPNEGO library fbopenssl])
1166      curl_spnego_msg="enabled"
1167   fi
1168 else
1169   AC_MSG_RESULT(no)
1170 fi
1171
1172 dnl **********************************************************************
1173 dnl Check for GSS-API libraries
1174 dnl **********************************************************************
1175
1176 dnl check for gss stuff in the /usr as default
1177
1178 GSSAPI_ROOT="/usr"
1179 AC_ARG_WITH(gssapi-includes,
1180   AC_HELP_STRING([--with-gssapi-includes=DIR],
1181                  [Specify location of GSSAPI header]),
1182   [ GSSAPI_INCS="-I$withval"
1183     want_gss="yes" ]
1184 )
1185
1186 AC_ARG_WITH(gssapi-libs,
1187   AC_HELP_STRING([--with-gssapi-libs=DIR],
1188                  [Specify location of GSSAPI libs]),
1189   [ GSSAPI_LIB_DIR="-L$withval"
1190     want_gss="yes" ]
1191 )
1192
1193 AC_ARG_WITH(gssapi,
1194   AC_HELP_STRING([--with-gssapi=DIR],
1195                  [Where to look for GSSAPI]), [
1196   GSSAPI_ROOT="$withval"
1197   if test x"$GSSAPI_ROOT" != xno; then
1198     want_gss="yes"
1199     if test x"$GSSAPI_ROOT" = xyes; then
1200       dnl if yes, then use default root
1201       GSSAPI_ROOT="/usr"
1202     fi
1203   fi
1204 ])
1205
1206 save_CPPFLAGS="$CPPFLAGS"
1207 AC_MSG_CHECKING([if GSSAPI support is requested])
1208 if test x"$want_gss" = xyes; then
1209   AC_MSG_RESULT(yes)
1210
1211   if test -z "$GSSAPI_INCS"; then
1212      if test -f "$GSSAPI_ROOT/bin/krb5-config"; then
1213         GSSAPI_INCS=`$GSSAPI_ROOT/bin/krb5-config --cflags gssapi`
1214      elif test "$GSSAPI_ROOT" != "yes"; then
1215         GSSAPI_INCS="-I$GSSAPI_ROOT/include"
1216      fi
1217   fi
1218
1219   CPPFLAGS="$CPPFLAGS $GSSAPI_INCS"
1220
1221   AC_CHECK_HEADER(gss.h,
1222     [
1223       dnl found in the given dirs
1224       AC_DEFINE(HAVE_GSSGNU, 1, [if you have the GNU gssapi libraries])
1225       gnu_gss=yes
1226     ],
1227     [
1228       dnl not found, check Heimdal or MIT
1229       AC_CHECK_HEADERS([gssapi/gssapi.h], [], [not_mit=1])
1230       AC_CHECK_HEADERS(
1231         [gssapi/gssapi_generic.h gssapi/gssapi_krb5.h],
1232         [],
1233         [not_mit=1],
1234         [
1235 AC_INCLUDES_DEFAULT
1236 #ifdef HAVE_GSSAPI_GSSAPI_H
1237 #include <gssapi/gssapi.h>
1238 #endif
1239         ])
1240       if test "x$not_mit" = "x1"; then
1241         dnl MIT not found, check for Heimdal
1242         AC_CHECK_HEADER(gssapi.h,
1243             [
1244               dnl found
1245               AC_DEFINE(HAVE_GSSHEIMDAL, 1, [if you have the Heimdal gssapi libraries])
1246             ],
1247             [
1248               dnl no header found, disabling GSS
1249               want_gss=no
1250               AC_MSG_WARN(disabling GSSAPI since no header files was found)
1251             ]
1252           )
1253       else
1254         dnl MIT found
1255         AC_DEFINE(HAVE_GSSMIT, 1, [if you have the MIT gssapi libraries])
1256         dnl check if we have a really old MIT kerberos (<= 1.2)
1257         AC_MSG_CHECKING([if gssapi headers declare GSS_C_NT_HOSTBASED_SERVICE])
1258         AC_COMPILE_IFELSE([
1259           AC_LANG_PROGRAM([[
1260 #include <gssapi/gssapi.h>
1261 #include <gssapi/gssapi_generic.h>
1262 #include <gssapi/gssapi_krb5.h>
1263           ]],[[
1264             gss_import_name(
1265                             (OM_uint32 *)0,
1266                             (gss_buffer_t)0,
1267                             GSS_C_NT_HOSTBASED_SERVICE,
1268                             (gss_name_t *)0);
1269           ]])
1270         ],[
1271           AC_MSG_RESULT([yes])
1272         ],[
1273           AC_MSG_RESULT([no])
1274           AC_DEFINE(HAVE_OLD_GSSMIT, 1,
1275             [if you have an old MIT gssapi library, lacking GSS_C_NT_HOSTBASED_SERVICE])
1276         ])
1277       fi
1278     ]
1279   )
1280 else
1281   AC_MSG_RESULT(no)
1282 fi
1283 if test x"$want_gss" = xyes; then
1284   AC_DEFINE(HAVE_GSSAPI, 1, [if you have the gssapi libraries])
1285
1286   curl_gss_msg="enabled (MIT/Heimdal)"
1287
1288   if test -n "$gnu_gss"; then
1289     curl_gss_msg="enabled (GNU GSS)"
1290     LDFLAGS="$LDFLAGS $GSSAPI_LIB_DIR"
1291     LIBS="-lgss $LIBS"
1292   elif test -z "$GSSAPI_LIB_DIR"; then
1293      case $host in
1294      *-*-darwin*)
1295         LIBS="-lgssapi_krb5 -lresolv $LIBS"
1296         ;;
1297      *-hp-hpux*)
1298         if test "$GSSAPI_ROOT" != "yes"; then
1299            LDFLAGS="$LDFLAGS -L$GSSAPI_ROOT/lib$libsuff"
1300         fi
1301         LIBS="-lgss $LIBS"
1302         ;;
1303      *)
1304         if test -f "$GSSAPI_ROOT/bin/krb5-config"; then
1305            dnl krb5-config doesn't have --libs-only-L or similar, put everything
1306            dnl into LIBS
1307            gss_libs=`$GSSAPI_ROOT/bin/krb5-config --libs gssapi`
1308            LIBS="$gss_libs $LIBS"
1309         elif test "$GSSAPI_ROOT" != "yes"; then
1310            LDFLAGS="$LDFLAGS -L$GSSAPI_ROOT/lib$libsuff"
1311            LIBS="-lgssapi $LIBS"
1312         else
1313            LIBS="-lgssapi $LIBS"
1314         fi
1315         ;;
1316      esac
1317   else
1318      LDFLAGS="$LDFLAGS $GSSAPI_LIB_DIR"
1319      case $host in
1320      *-hp-hpux*)
1321         LIBS="-lgss $LIBS"
1322         ;;
1323      *)
1324         LIBS="-lgssapi $LIBS"
1325         ;;
1326      esac
1327   fi
1328 else
1329   CPPFLAGS="$save_CPPFLAGS"
1330 fi
1331
1332 dnl -------------------------------------------------
1333 dnl check winssl option before other SSL libraries
1334 dnl -------------------------------------------------
1335
1336 OPT_WINSSL=no
1337 AC_ARG_WITH(winssl,dnl
1338 AC_HELP_STRING([--with-winssl],[enable Windows native SSL/TLS])
1339 AC_HELP_STRING([--without-winssl], [disable Windows native SSL/TLS]),
1340   OPT_WINSSL=$withval)
1341
1342 AC_MSG_CHECKING([whether to enable Windows native SSL/TLS (Windows native builds only)])
1343 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1344   if test "x$OPT_WINSSL" != "xno"  &&
1345      test "x$ac_cv_native_windows" = "xyes"; then
1346     AC_MSG_RESULT(yes)
1347     AC_DEFINE(USE_SCHANNEL, 1, [to enable Windows native SSL/TLS support])
1348     AC_SUBST(USE_SCHANNEL, [1])
1349     curl_ssl_msg="enabled (Windows-native)"
1350     WINSSL_ENABLED=1
1351     # --with-winssl implies --enable-sspi
1352     AC_DEFINE(USE_WINDOWS_SSPI, 1, [to enable SSPI support])
1353     AC_SUBST(USE_WINDOWS_SSPI, [1])
1354     curl_sspi_msg="enabled"
1355   else
1356     AC_MSG_RESULT(no)
1357   fi
1358 else
1359   AC_MSG_RESULT(no)
1360 fi
1361
1362 OPT_DARWINSSL=no
1363 AC_ARG_WITH(darwinssl,dnl
1364 AC_HELP_STRING([--with-darwinssl],[enable iOS/Mac OS X native SSL/TLS])
1365 AC_HELP_STRING([--without-darwinssl], [disable iOS/Mac OS X native SSL/TLS]),
1366   OPT_DARWINSSL=$withval)
1367
1368 AC_MSG_CHECKING([whether to enable iOS/Mac OS X native SSL/TLS])
1369 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1370   if test "x$OPT_DARWINSSL" != "xno" &&
1371      test -d "/System/Library/Frameworks/Security.framework"; then
1372     AC_MSG_RESULT(yes)
1373     AC_DEFINE(USE_DARWINSSL, 1, [to enable iOS/Mac OS X native SSL/TLS support])
1374     AC_SUBST(USE_DARWINSSL, [1])
1375     curl_ssl_msg="enabled (iOS/Mac OS X-native)"
1376     DARWINSSL_ENABLED=1
1377     LDFLAGS="$LDFLAGS -framework CoreFoundation -framework Security"
1378   else
1379     AC_MSG_RESULT(no)
1380   fi
1381 else
1382   AC_MSG_RESULT(no)
1383 fi
1384
1385 dnl **********************************************************************
1386 dnl Check for the presence of SSL libraries and headers
1387 dnl **********************************************************************
1388
1389 dnl Default to compiler & linker defaults for SSL files & libraries.
1390 OPT_SSL=off
1391 dnl Default to no CA bundle
1392 ca="no"
1393 AC_ARG_WITH(ssl,dnl
1394 AC_HELP_STRING([--with-ssl=PATH],[Where to look for OpenSSL, PATH points to the SSL installation (default: /usr/local/ssl); when possible, set the PKG_CONFIG_PATH environment variable instead of using this option])
1395 AC_HELP_STRING([--without-ssl], [disable OpenSSL]),
1396   OPT_SSL=$withval)
1397
1398 if test "$curl_ssl_msg" = "$init_ssl_msg" && test X"$OPT_SSL" != Xno; then
1399   dnl backup the pre-ssl variables
1400   CLEANLDFLAGS="$LDFLAGS"
1401   CLEANCPPFLAGS="$CPPFLAGS"
1402   CLEANLIBS="$LIBS"
1403
1404   case "$OPT_SSL" in
1405   yes)
1406     dnl --with-ssl (without path) used
1407     if test x$cross_compiling != xyes; then
1408       dnl only do pkg-config magic when not cross-compiling
1409       PKGTEST="yes"
1410     fi
1411     PREFIX_OPENSSL=/usr/local/ssl
1412     LIB_OPENSSL="$PREFIX_OPENSSL/lib$libsuff"
1413     ;;
1414   off)
1415     dnl no --with-ssl option given, just check default places
1416     if test x$cross_compiling != xyes; then
1417       dnl only do pkg-config magic when not cross-compiling
1418       PKGTEST="yes"
1419     fi
1420     PREFIX_OPENSSL=
1421     ;;
1422   *)
1423     dnl check the given --with-ssl spot
1424     PKGTEST="no"
1425     PREFIX_OPENSSL=$OPT_SSL
1426
1427     dnl Try pkg-config even when cross-compiling.  Since we
1428     dnl specify PKG_CONFIG_LIBDIR we're only looking where
1429     dnl the user told us to look
1430     OPENSSL_PCDIR="$OPT_SSL/lib/pkgconfig"
1431     AC_MSG_NOTICE([PKG_CONFIG_LIBDIR will be set to "$OPENSSL_PCDIR"])
1432     if test -f "$OPENSSL_PCDIR/openssl.pc"; then
1433       PKGTEST="yes"
1434     fi
1435
1436     dnl in case pkg-config comes up empty, use what we got
1437     dnl via --with-ssl
1438     LIB_OPENSSL="$PREFIX_OPENSSL/lib$libsuff"
1439     if test "$PREFIX_OPENSSL" != "/usr" ; then
1440       SSL_LDFLAGS="-L$LIB_OPENSSL"
1441       SSL_CPPFLAGS="-I$PREFIX_OPENSSL/include"
1442     fi
1443     SSL_CPPFLAGS="$SSL_CPPFLAGS -I$PREFIX_OPENSSL/include/openssl"
1444     ;;
1445   esac
1446
1447   if test "$PKGTEST" = "yes"; then
1448
1449     CURL_CHECK_PKGCONFIG(openssl, [$OPENSSL_PCDIR])
1450
1451     if test "$PKGCONFIG" != "no" ; then
1452       SSL_LIBS=`CURL_EXPORT_PCDIR([$OPENSSL_PCDIR]) dnl
1453         $PKGCONFIG --libs-only-l openssl 2>/dev/null`
1454
1455       SSL_LDFLAGS=`CURL_EXPORT_PCDIR([$OPENSSL_PCDIR]) dnl
1456         $PKGCONFIG --libs-only-L openssl 2>/dev/null`
1457
1458       SSL_CPPFLAGS=`CURL_EXPORT_PCDIR([$OPENSSL_PCDIR]) dnl
1459         $PKGCONFIG --cflags-only-I openssl 2>/dev/null`
1460
1461       AC_MSG_NOTICE([pkg-config: SSL_LIBS: "$SSL_LIBS"])
1462       AC_MSG_NOTICE([pkg-config: SSL_LDFLAGS: "$SSL_LDFLAGS"])
1463       AC_MSG_NOTICE([pkg-config: SSL_CPPFLAGS: "$SSL_CPPFLAGS"])
1464
1465       LIB_OPENSSL=`echo $SSL_LDFLAGS | sed -e 's/-L//g'`
1466
1467       dnl use the values pkg-config reported.  This is here
1468       dnl instead of below with CPPFLAGS and LDFLAGS because we only
1469       dnl learn about this via pkg-config.  If we only have
1470       dnl the argument to --with-ssl we don't know what
1471       dnl additional libs may be necessary.  Hope that we
1472       dnl don't need any.
1473       LIBS="$SSL_LIBS $LIBS"
1474     fi
1475   fi
1476
1477   dnl finally, set flags to use SSL
1478   CPPFLAGS="$CPPFLAGS $SSL_CPPFLAGS"
1479   LDFLAGS="$LDFLAGS $SSL_LDFLAGS"
1480
1481   dnl This is for Msys/Mingw
1482   case $host in
1483     *-*-msys* | *-*-mingw*)
1484       AC_MSG_CHECKING([for gdi32])
1485       my_ac_save_LIBS=$LIBS
1486       LIBS="-lgdi32 $LIBS"
1487       AC_TRY_LINK([#include <windef.h>
1488                    #include <wingdi.h>],
1489                    [GdiFlush();],
1490                    [ dnl worked!
1491                    AC_MSG_RESULT([yes])],
1492                    [ dnl failed, restore LIBS
1493                    LIBS=$my_ac_save_LIBS
1494                    AC_MSG_RESULT(no)]
1495                   )
1496       ;;
1497   esac
1498
1499   AC_CHECK_LIB(crypto, CRYPTO_lock,[
1500      HAVECRYPTO="yes"
1501      LIBS="-lcrypto $LIBS"
1502      ],[
1503      LDFLAGS="$CLEANLDFLAGS -L$LIB_OPENSSL"
1504      CPPFLAGS="$CLEANCPPFLAGS -I$PREFIX_OPENSSL/include/openssl -I$PREFIX_OPENSSL/include"
1505      AC_CHECK_LIB(crypto, CRYPTO_add_lock,[
1506        HAVECRYPTO="yes"
1507        LIBS="-lcrypto $LIBS"], [
1508        LDFLAGS="$CLEANLDFLAGS"
1509        CPPFLAGS="$CLEANCPPFLAGS"
1510        LIBS="$CLEANLIBS"
1511        ])
1512     ])
1513
1514
1515   if test X"$HAVECRYPTO" = X"yes"; then
1516     dnl This is only reasonable to do if crypto actually is there: check for
1517     dnl SSL libs NOTE: it is important to do this AFTER the crypto lib
1518
1519     AC_CHECK_LIB(ssl, SSL_connect)
1520
1521     if test "$ac_cv_lib_ssl_SSL_connect" != yes; then
1522         dnl we didn't find the SSL lib, try the RSAglue/rsaref stuff
1523         AC_MSG_CHECKING(for ssl with RSAglue/rsaref libs in use);
1524         OLIBS=$LIBS
1525         LIBS="-lRSAglue -lrsaref $LIBS"
1526         AC_CHECK_LIB(ssl, SSL_connect)
1527         if test "$ac_cv_lib_ssl_SSL_connect" != yes; then
1528             dnl still no SSL_connect
1529             AC_MSG_RESULT(no)
1530             LIBS=$OLIBS
1531         else
1532             AC_MSG_RESULT(yes)
1533         fi
1534
1535     else
1536
1537       dnl Have the libraries--check for SSLeay/OpenSSL headers
1538       AC_CHECK_HEADERS(openssl/x509.h openssl/rsa.h openssl/crypto.h \
1539                        openssl/pem.h openssl/ssl.h openssl/err.h,
1540         curl_ssl_msg="enabled (OpenSSL)"
1541         OPENSSL_ENABLED=1
1542         AC_DEFINE(USE_OPENSSL, 1, [if OpenSSL is in use]))
1543
1544       if test $ac_cv_header_openssl_x509_h = no; then
1545         dnl we don't use the "action" part of the AC_CHECK_HEADERS macro
1546         dnl since 'err.h' might in fact find a krb4 header with the same
1547         dnl name
1548         AC_CHECK_HEADERS(x509.h rsa.h crypto.h pem.h ssl.h err.h)
1549
1550         if test $ac_cv_header_x509_h = yes &&
1551            test $ac_cv_header_crypto_h = yes &&
1552            test $ac_cv_header_ssl_h = yes; then
1553           dnl three matches
1554           curl_ssl_msg="enabled (OpenSSL)"
1555           OPENSSL_ENABLED=1
1556         fi
1557       fi
1558     fi
1559
1560     if test X"$OPENSSL_ENABLED" = X"1"; then
1561        AC_DEFINE(USE_SSLEAY, 1, [if SSL is enabled])
1562
1563        dnl is there a pkcs12.h header present?
1564        AC_CHECK_HEADERS(openssl/pkcs12.h)
1565     else
1566        LIBS="$CLEANLIBS"
1567     fi
1568     dnl USE_SSLEAY is the historical name for what configure calls
1569     dnl OPENSSL_ENABLED; the names should really be unified
1570     USE_SSLEAY="$OPENSSL_ENABLED"
1571     AC_SUBST(USE_SSLEAY)
1572
1573     if test X"$OPT_SSL" != Xoff &&
1574        test "$OPENSSL_ENABLED" != "1"; then
1575       AC_MSG_ERROR([OpenSSL libs and/or directories were not found where specified!])
1576     fi
1577   fi
1578
1579   if test X"$OPENSSL_ENABLED" = X"1"; then
1580     dnl If the ENGINE library seems to be around, check for the OpenSSL engine
1581     dnl stuff, it is kind of "separated" from the main SSL check
1582     AC_CHECK_FUNC(ENGINE_init,
1583               [
1584                 AC_CHECK_HEADERS(openssl/engine.h)
1585                 AC_CHECK_FUNCS( ENGINE_load_builtin_engines )
1586               ])
1587
1588     dnl these can only exist if openssl exists
1589     dnl yassl doesn't have SSL_get_shutdown
1590
1591     AC_CHECK_FUNCS( RAND_status \
1592                     RAND_screen \
1593                     RAND_egd \
1594                     ENGINE_cleanup \
1595                     CRYPTO_cleanup_all_ex_data \
1596                     SSL_get_shutdown \
1597                     SSLv2_client_method )
1598
1599     dnl Make an attempt to detect if this is actually yassl's headers and
1600     dnl OpenSSL emulation layer. We still leave everything else believing
1601     dnl and acting like OpenSSL.
1602
1603     AC_MSG_CHECKING([for yaSSL using OpenSSL compatibility mode])
1604     AC_COMPILE_IFELSE([
1605       AC_LANG_PROGRAM([[
1606 #include <openssl/ssl.h>
1607       ]],[[
1608 #if defined(YASSL_VERSION) && defined(OPENSSL_VERSION_NUMBER)
1609         int dummy = SSL_ERROR_NONE;
1610 #else
1611         Not the yaSSL OpenSSL compatibility header.
1612 #endif
1613       ]])
1614     ],[
1615       AC_MSG_RESULT([yes])
1616       AC_DEFINE_UNQUOTED(USE_YASSLEMUL, 1,
1617         [Define to 1 if using yaSSL in OpenSSL compatibility mode.])
1618       curl_ssl_msg="enabled (OpenSSL emulation by yaSSL)"
1619     ],[
1620       AC_MSG_RESULT([no])
1621     ])
1622   fi
1623
1624   if test "$OPENSSL_ENABLED" = "1"; then
1625     if test -n "$LIB_OPENSSL"; then
1626        dnl when the ssl shared libs were found in a path that the run-time
1627        dnl linker doesn't search through, we need to add it to LD_LIBRARY_PATH
1628        dnl to prevent further configure tests to fail due to this
1629        if test "x$cross_compiling" != "xyes"; then
1630          LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$LIB_OPENSSL"
1631          export LD_LIBRARY_PATH
1632          AC_MSG_NOTICE([Added $LIB_OPENSSL to LD_LIBRARY_PATH])
1633        fi
1634     fi
1635     CURL_CHECK_OPENSSL_API
1636   fi
1637
1638 fi
1639
1640 dnl **********************************************************************
1641 dnl Check for the random seed preferences
1642 dnl **********************************************************************
1643
1644 if test X"$OPENSSL_ENABLED" = X"1"; then
1645   AC_ARG_WITH(egd-socket,
1646   AC_HELP_STRING([--with-egd-socket=FILE],
1647                  [Entropy Gathering Daemon socket pathname]),
1648       [ EGD_SOCKET="$withval" ]
1649   )
1650   if test -n "$EGD_SOCKET" ; then
1651           AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET",
1652           [your Entropy Gathering Daemon socket pathname] )
1653   fi
1654
1655   dnl Check for user-specified random device
1656   AC_ARG_WITH(random,
1657   AC_HELP_STRING([--with-random=FILE],
1658                  [read randomness from FILE (default=/dev/urandom)]),
1659       [ RANDOM_FILE="$withval" ],
1660       [
1661           if test x$cross_compiling != xyes; then
1662             dnl Check for random device
1663             AC_CHECK_FILE("/dev/urandom", [ RANDOM_FILE="/dev/urandom"] )
1664           else
1665             AC_MSG_WARN([skipped the /dev/urandom detection when cross-compiling])
1666           fi
1667       ]
1668   )
1669   if test -n "$RANDOM_FILE" && test X"$RANDOM_FILE" != Xno ; then
1670           AC_SUBST(RANDOM_FILE)
1671           AC_DEFINE_UNQUOTED(RANDOM_FILE, "$RANDOM_FILE",
1672           [a suitable file to read random data from])
1673   fi
1674 fi
1675
1676 dnl ---
1677 dnl We require OpenSSL with SRP support.
1678 dnl ---
1679 if test "$OPENSSL_ENABLED" = "1"; then
1680   AC_CHECK_LIB(crypto, SRP_Calc_client_key,
1681    [
1682      AC_DEFINE(HAVE_SSLEAY_SRP, 1, [if you have the function SRP_Calc_client_key])
1683      AC_SUBST(HAVE_SSLEAY_SRP, [1])
1684    ])
1685 fi
1686
1687 dnl ----------------------------------------------------
1688 dnl check for GnuTLS
1689 dnl ----------------------------------------------------
1690
1691 dnl Default to compiler & linker defaults for GnuTLS files & libraries.
1692 OPT_GNUTLS=no
1693
1694 AC_ARG_WITH(gnutls,dnl
1695 AC_HELP_STRING([--with-gnutls=PATH],[where to look for GnuTLS, PATH points to the installation root])
1696 AC_HELP_STRING([--without-gnutls], [disable GnuTLS detection]),
1697   OPT_GNUTLS=$withval)
1698
1699 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1700
1701   if test X"$OPT_GNUTLS" != Xno; then
1702
1703     addld=""
1704     addlib=""
1705     gtlslib=""
1706     version=""
1707     addcflags=""
1708
1709     if test "x$OPT_GNUTLS" = "xyes"; then
1710       dnl this is with no partiular path given
1711       CURL_CHECK_PKGCONFIG(gnutls)
1712
1713       if test "$PKGCONFIG" != "no" ; then
1714         addlib=`$PKGCONFIG --libs-only-l gnutls`
1715         addld=`$PKGCONFIG --libs-only-L gnutls`
1716         addcflags=`$PKGCONFIG --cflags-only-I gnutls`
1717         version=`$PKGCONFIG --modversion gnutls`
1718         gtlslib=`echo $addld | $SED -e 's/-L//'`
1719       else
1720         dnl without pkg-config, we try libgnutls-config as that was how it
1721         dnl used to be done
1722         check=`libgnutls-config --version 2>/dev/null`
1723         if test -n "$check"; then
1724           addlib=`libgnutls-config --libs`
1725           addcflags=`libgnutls-config --cflags`
1726           version=`libgnutls-config --version`
1727           gtlslib=`libgnutls-config --prefix`/lib$libsuff
1728         fi
1729       fi
1730     else
1731       dnl this is with a given path, first check if there's a libgnutls-config
1732       dnl there and if not, make an educated guess
1733       cfg=$OPT_GNUTLS/bin/libgnutls-config
1734       check=`$cfg --version 2>/dev/null`
1735       if test -n "$check"; then
1736         addlib=`$cfg --libs`
1737         addcflags=`$cfg --cflags`
1738         version=`$cfg --version`
1739         gtlslib=`$cfg --prefix`/lib$libsuff
1740       else
1741         dnl without pkg-config and libgnutls-config, we guess a lot!
1742         addlib=-lgnutls
1743         addld=-L$OPT_GNUTLS/lib$libsuff
1744         addcflags=-I$OPT_GNUTLS/include
1745         version="" # we just don't know
1746         gtlslib=$OPT_GNUTLS/lib$libsuff
1747       fi
1748     fi
1749
1750     if test -z "$version"; then
1751       dnl lots of efforts, still no go
1752       version="unknown"
1753     fi
1754
1755     if test -n "$addlib"; then
1756
1757       CLEANLIBS="$LIBS"
1758       CLEANCPPFLAGS="$CPPFLAGS"
1759       CLEANLDFLAGS="$LDFLAGS"
1760
1761       LIBS="$addlib $LIBS"
1762       LDFLAGS="$LDFLAGS $addld"
1763       if test "$addcflags" != "-I/usr/include"; then
1764          CPPFLAGS="$CPPFLAGS $addcflags"
1765       fi
1766
1767       AC_CHECK_LIB(gnutls, gnutls_check_version,
1768        [
1769        AC_DEFINE(USE_GNUTLS, 1, [if GnuTLS is enabled])
1770        AC_SUBST(USE_GNUTLS, [1])
1771        GNUTLS_ENABLED=1
1772        USE_GNUTLS="yes"
1773        curl_ssl_msg="enabled (GnuTLS)"
1774        ],
1775        [
1776          LIBS="$CLEANLIBS"
1777          CPPFLAGS="$CLEANCPPFLAGS"
1778        ])
1779
1780       if test "x$USE_GNUTLS" = "xyes"; then
1781         AC_MSG_NOTICE([detected GnuTLS version $version])
1782
1783         if test -n "$gtlslib"; then
1784           dnl when shared libs were found in a path that the run-time
1785           dnl linker doesn't search through, we need to add it to
1786           dnl LD_LIBRARY_PATH to prevent further configure tests to fail
1787           dnl due to this
1788           if test "x$cross_compiling" != "xyes"; then
1789             LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$gtlslib"
1790             export LD_LIBRARY_PATH
1791             AC_MSG_NOTICE([Added $gtlslib to LD_LIBRARY_PATH])
1792           fi
1793         fi
1794       fi
1795
1796     fi
1797
1798   fi dnl GNUTLS not disabled
1799
1800 fi
1801
1802 dnl ---
1803 dnl Check which crypto backend GnuTLS uses
1804 dnl ---
1805
1806 if test "$GNUTLS_ENABLED" = "1"; then
1807   USE_GNUTLS_NETTLE=
1808   # First check if we can detect either crypto library via transitive linking
1809   AC_CHECK_LIB(gnutls, nettle_MD5Init, [ USE_GNUTLS_NETTLE=1 ])
1810   if test "$USE_GNUTLS_NETTLE" = ""; then
1811     AC_CHECK_LIB(gnutls, gcry_control, [ USE_GNUTLS_NETTLE=0 ])
1812   fi
1813   # If not, try linking directly to both of them to see if they are available
1814   if test "$USE_GNUTLS_NETTLE" = ""; then
1815     AC_CHECK_LIB(nettle, nettle_MD5Init, [ USE_GNUTLS_NETTLE=1 ])
1816   fi
1817   if test "$USE_GNUTLS_NETTLE" = ""; then
1818     AC_CHECK_LIB(gcrypt, gcry_control, [ USE_GNUTLS_NETTLE=0 ])
1819   fi
1820   if test "$USE_GNUTLS_NETTLE" = ""; then
1821     AC_MSG_ERROR([GnuTLS found, but neither gcrypt nor nettle found])
1822   fi
1823   if test "$USE_GNUTLS_NETTLE" = "1"; then
1824     AC_DEFINE(USE_GNUTLS_NETTLE, 1, [if GnuTLS uses nettle as crypto backend])
1825     AC_SUBST(USE_GNUTLS_NETTLE, [1])
1826     LIBS="-lnettle $LIBS"
1827   else
1828     LIBS="-lgcrypt $LIBS"
1829   fi
1830 fi
1831
1832 dnl ---
1833 dnl We require GnuTLS with SRP support.
1834 dnl ---
1835 if test "$GNUTLS_ENABLED" = "1"; then
1836   AC_CHECK_LIB(gnutls, gnutls_srp_verifier,
1837    [
1838      AC_DEFINE(HAVE_GNUTLS_SRP, 1, [if you have the function gnutls_srp_verifier])
1839      AC_SUBST(HAVE_GNUTLS_SRP, [1])
1840    ])
1841 fi
1842
1843 dnl ----------------------------------------------------
1844 dnl check for PolarSSL
1845 dnl ----------------------------------------------------
1846
1847 dnl Default to compiler & linker defaults for PolarSSL files & libraries.
1848 OPT_POLARSSL=no
1849
1850 _cppflags=$CPPFLAGS
1851 _ldflags=$LDFLAGS
1852 AC_ARG_WITH(polarssl,dnl
1853 AC_HELP_STRING([--with-polarssl=PATH],[where to look for PolarSSL, PATH points to the installation root])
1854 AC_HELP_STRING([--without-polarssl], [disable PolarSSL detection]),
1855   OPT_POLARSSL=$withval)
1856
1857 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1858
1859   if test X"$OPT_POLARSSL" != Xno; then
1860
1861     if test "$OPT_POLARSSL" = "yes"; then
1862       OPT_POLARSSL=""
1863     fi
1864
1865     if test -z "$OPT_POLARSSL" ; then
1866       dnl check for lib first without setting any new path
1867
1868       AC_CHECK_LIB(polarssl, havege_init,
1869       dnl libpolarssl found, set the variable
1870        [
1871          AC_DEFINE(USE_POLARSSL, 1, [if PolarSSL is enabled])
1872          AC_SUBST(USE_POLARSSL, [1])
1873          POLARSSL_ENABLED=1
1874          USE_POLARSSL="yes"
1875          curl_ssl_msg="enabled (PolarSSL)"
1876         ])
1877     fi
1878
1879     addld=""
1880     addlib=""
1881     addcflags=""
1882     polarssllib=""
1883
1884     if test "x$USE_POLARSSL" != "xyes"; then
1885       dnl add the path and test again
1886       addld=-L$OPT_POLARSSL/lib$libsuff
1887       addcflags=-I$OPT_POLARSSL/include
1888       polarssllib=$OPT_POLARSSL/lib$libsuff
1889
1890       LDFLAGS="$LDFLAGS $addld"
1891       if test "$addcflags" != "-I/usr/include"; then
1892          CPPFLAGS="$CPPFLAGS $addcflags"
1893       fi
1894
1895       AC_CHECK_LIB(polarssl, ssl_init,
1896        [
1897        AC_DEFINE(USE_POLARSSL, 1, [if PolarSSL is enabled])
1898        AC_SUBST(USE_POLARSSL, [1])
1899        POLARSSL_ENABLED=1
1900        USE_POLARSSL="yes"
1901        curl_ssl_msg="enabled (PolarSSL)"
1902        ],
1903        [
1904          CPPFLAGS=$_cppflags
1905          LDFLAGS=$_ldflags
1906        ])
1907     fi
1908
1909     if test "x$USE_POLARSSL" = "xyes"; then
1910       AC_MSG_NOTICE([detected PolarSSL])
1911
1912       LIBS="-lpolarssl $LIBS"
1913
1914       if test -n "$polarssllib"; then
1915         dnl when shared libs were found in a path that the run-time
1916         dnl linker doesn't search through, we need to add it to
1917         dnl LD_LIBRARY_PATH to prevent further configure tests to fail
1918         dnl due to this
1919         if test "x$cross_compiling" != "xyes"; then
1920           LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$polarssllib"
1921           export LD_LIBRARY_PATH
1922           AC_MSG_NOTICE([Added $polarssllib to LD_LIBRARY_PATH])
1923         fi
1924       fi
1925     fi
1926
1927   fi dnl PolarSSL not disabled
1928
1929 fi
1930
1931 dnl ----------------------------------------------------
1932 dnl check for CyaSSL
1933 dnl ----------------------------------------------------
1934
1935 dnl Default to compiler & linker defaults for CyaSSL files & libraries.
1936 OPT_CYASSL=no
1937
1938 _cppflags=$CPPFLAGS
1939 _ldflags=$LDFLAGS
1940 AC_ARG_WITH(cyassl,dnl
1941 AC_HELP_STRING([--with-cyassl=PATH],[where to look for CyaSSL, PATH points to the installation root (default: system lib default)])
1942 AC_HELP_STRING([--without-cyassl], [disable CyaSSL detection]),
1943   OPT_CYASSL=$withval)
1944
1945 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
1946
1947   if test X"$OPT_CYASSL" != Xno; then
1948
1949     if test "$OPT_CYASSL" = "yes"; then
1950       OPT_CYASSL=""
1951     fi
1952
1953     if test -z "$OPT_CYASSL" ; then
1954       dnl check for lib in system default first
1955
1956       AC_CHECK_LIB(cyassl, CyaSSL_Init,
1957       dnl libcyassl found, set the variable
1958        [
1959          AC_DEFINE(USE_CYASSL, 1, [if CyaSSL is enabled])
1960          AC_SUBST(USE_CYASSL, [1])
1961          CYASSL_ENABLED=1
1962          USE_CYASSL="yes"
1963          curl_ssl_msg="enabled (CyaSSL)"
1964         ])
1965     fi
1966
1967     addld=""
1968     addlib=""
1969     addcflags=""
1970     cyassllib=""
1971
1972     if test "x$USE_CYASSL" != "xyes"; then
1973       dnl add the path and test again
1974       addld=-L$OPT_CYASSL/lib$libsuff
1975       addcflags=-I$OPT_CYASSL/include
1976       cyassllib=$OPT_CYASSL/lib$libsuff
1977
1978       LDFLAGS="$LDFLAGS $addld"
1979       if test "$addcflags" != "-I/usr/include"; then
1980          CPPFLAGS="$CPPFLAGS $addcflags"
1981       fi
1982
1983       AC_CHECK_LIB(cyassl, CyaSSL_Init,
1984        [
1985        AC_DEFINE(USE_CYASSL, 1, [if CyaSSL is enabled])
1986        AC_SUBST(USE_CYASSL, [1])
1987        CYASSL_ENABLED=1
1988        USE_CYASSL="yes"
1989        curl_ssl_msg="enabled (CyaSSL)"
1990        ],
1991        [
1992          CPPFLAGS=$_cppflags
1993          LDFLAGS=$_ldflags
1994        ])
1995     fi
1996
1997     if test "x$USE_CYASSL" = "xyes"; then
1998       AC_MSG_NOTICE([detected CyaSSL])
1999
2000       dnl cyassl/ctaocrypt/types.h needs SIZEOF_LONG_LONG defined!
2001       AC_CHECK_SIZEOF(long long)
2002
2003       LIBS="-lcyassl -lm $LIBS"
2004
2005       if test -n "$cyassllib"; then
2006         dnl when shared libs were found in a path that the run-time
2007         dnl linker doesn't search through, we need to add it to
2008         dnl LD_LIBRARY_PATH to prevent further configure tests to fail
2009         dnl due to this
2010         if test "x$cross_compiling" != "xyes"; then
2011           LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$cyassllib"
2012           export LD_LIBRARY_PATH
2013           AC_MSG_NOTICE([Added $cyassllib to LD_LIBRARY_PATH])
2014         fi
2015       fi
2016
2017     fi
2018
2019   fi dnl CyaSSL not disabled
2020
2021 fi
2022
2023 dnl ----------------------------------------------------
2024 dnl NSS. Only check if GnuTLS and OpenSSL are not enabled
2025 dnl ----------------------------------------------------
2026
2027 dnl Default to compiler & linker defaults for NSS files & libraries.
2028 OPT_NSS=no
2029
2030 AC_ARG_WITH(nss,dnl
2031 AC_HELP_STRING([--with-nss=PATH],[where to look for NSS, PATH points to the installation root])
2032 AC_HELP_STRING([--without-nss], [disable NSS detection]),
2033   OPT_NSS=$withval)
2034
2035 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
2036
2037   if test X"$OPT_NSS" != Xno; then
2038
2039     addld=""
2040     addlib=""
2041     addcflags=""
2042     nssprefix=""
2043     version=""
2044
2045     if test "x$OPT_NSS" = "xyes"; then
2046
2047       CURL_CHECK_PKGCONFIG(nss)
2048
2049       if test "$PKGCONFIG" != "no" ; then
2050         addlib=`$PKGCONFIG --libs nss`
2051         addcflags=`$PKGCONFIG --cflags nss`
2052         version=`$PKGCONFIG --modversion nss`
2053         nssprefix=`$PKGCONFIG --variable=prefix nss`
2054       else
2055         dnl Without pkg-config, we check for nss-config
2056
2057         check=`nss-config --version 2>/dev/null`
2058         if test -n "$check"; then
2059           addlib=`nss-config --libs`
2060           addcflags=`nss-config --cflags`
2061           version=`nss-config --version`
2062           nssprefix=`nss-config --prefix`
2063         else
2064           addlib="-lnss3"
2065           addcflags=""
2066           version="unknown"
2067         fi
2068       fi
2069     else
2070         # Without pkg-config, we'll kludge in some defaults
2071         addlib="-L$OPT_NSS/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
2072         addcflags="-I$OPT_NSS/include"
2073         version="unknown"
2074         nssprefix=$OPT_NSS
2075     fi
2076
2077     if test -n "$addlib"; then
2078
2079       CLEANLIBS="$LIBS"
2080       CLEANCPPFLAGS="$CPPFLAGS"
2081
2082       LIBS="$addlib $LIBS"
2083       if test "$addcflags" != "-I/usr/include"; then
2084          CPPFLAGS="$CPPFLAGS $addcflags"
2085       fi
2086
2087       dnl The function SSL_VersionRangeSet() is needed to enable TLS > 1.0
2088       AC_CHECK_LIB(nss3, SSL_VersionRangeSet,
2089        [
2090        AC_DEFINE(USE_NSS, 1, [if NSS is enabled])
2091        AC_SUBST(USE_NSS, [1])
2092        USE_NSS="yes"
2093        NSS_ENABLED=1
2094        curl_ssl_msg="enabled (NSS)"
2095        ],
2096        [
2097          LIBS="$CLEANLIBS"
2098          CPPFLAGS="$CLEANCPPFLAGS"
2099        ])
2100
2101       if test "x$USE_NSS" = "xyes"; then
2102         AC_MSG_NOTICE([detected NSS version $version])
2103
2104         dnl when shared libs were found in a path that the run-time
2105         dnl linker doesn't search through, we need to add it to
2106         dnl LD_LIBRARY_PATH to prevent further configure tests to fail
2107         dnl due to this
2108         if test "x$cross_compiling" != "xyes"; then
2109           LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$nssprefix/lib$libsuff"
2110           export LD_LIBRARY_PATH
2111           AC_MSG_NOTICE([Added $nssprefix/lib$libsuff to LD_LIBRARY_PATH])
2112         fi
2113       fi
2114
2115     fi
2116
2117   fi dnl NSS not disabled
2118
2119 fi dnl curl_ssl_msg = init_ssl_msg
2120
2121 OPT_AXTLS=off
2122
2123 AC_ARG_WITH(axtls,dnl
2124 AC_HELP_STRING([--with-axtls=PATH],[Where to look for axTLS, PATH points to the axTLS installation prefix (default: /usr/local).  Ignored if another SSL engine is selected.])
2125 AC_HELP_STRING([--without-axtls], [disable axTLS]),
2126   OPT_AXTLS=$withval)
2127
2128 if test "$curl_ssl_msg" = "$init_ssl_msg"; then
2129   if test X"$OPT_AXTLS" != Xno; then
2130     dnl backup the pre-axtls variables
2131     CLEANLDFLAGS="$LDFLAGS"
2132     CLEANCPPFLAGS="$CPPFLAGS"
2133     CLEANLIBS="$LIBS"
2134
2135     case "$OPT_AXTLS" in
2136     yes)
2137       dnl --with-axtls (without path) used
2138       PREFIX_AXTLS=/usr/local
2139       LIB_AXTLS="$PREFIX_AXTLS/lib"
2140       LDFLAGS="$LDFLAGS -L$LIB_AXTLS"
2141       CPPFLAGS="$CPPFLAGS -I$PREFIX_AXTLS/include"
2142       ;;
2143     off)
2144       dnl no --with-axtls option given, just check default places
2145       PREFIX_AXTLS=
2146       ;;
2147     *)
2148       dnl check the given --with-axtls spot
2149       PREFIX_AXTLS=$OPT_AXTLS
2150       LIB_AXTLS="$PREFIX_AXTLS/lib"
2151       LDFLAGS="$LDFLAGS -L$LIB_AXTLS"
2152       CPPFLAGS="$CPPFLAGS -I$PREFIX_AXTLS/include"
2153       ;;
2154     esac
2155
2156     AC_CHECK_LIB(axtls, ssl_version,[
2157       LIBS="-laxtls $LIBS"
2158       AC_DEFINE(USE_AXTLS, 1, [if axTLS is enabled])
2159       AC_SUBST(USE_AXTLS, [1])
2160       AXTLS_ENABLED=1
2161       USE_AXTLS="yes"
2162       curl_ssl_msg="enabled (axTLS)"
2163
2164
2165       LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$LIB_AXTLS"
2166       export LD_LIBRARY_PATH
2167       AC_MSG_NOTICE([Added $LIB_AXTLS to LD_LIBRARY_PATH])
2168       ],[
2169       LDFLAGS="$CLEANLDFLAGS"
2170       CPPFLAGS="$CLEANCPPFLAGS"
2171       LIBS="$CLEANLIBS"
2172     ])
2173   fi
2174 fi
2175
2176 if test "x$OPENSSL_ENABLED$GNUTLS_ENABLED$NSS_ENABLED$POLARSSL_ENABLED$AXTLS_ENABLED$CYASSL_ENABLED$WINSSL_ENABLED$DARWINSSL_ENABLED" = "x"; then
2177   AC_MSG_WARN([SSL disabled, you will not be able to use HTTPS, FTPS, NTLM and more.])
2178   AC_MSG_WARN([Use --with-ssl, --with-gnutls, --with-polarssl, --with-cyassl, --with-nss, --with-axtls, --with-winssl, or --with-darwinssl to address this.])
2179 else
2180   # SSL is enabled, genericly
2181   AC_SUBST(SSL_ENABLED)
2182   SSL_ENABLED="1"
2183 fi
2184
2185 dnl **********************************************************************
2186 dnl Check for the CA bundle
2187 dnl **********************************************************************
2188
2189 CURL_CHECK_CA_BUNDLE
2190
2191 dnl **********************************************************************
2192 dnl Check for libmetalink
2193 dnl **********************************************************************
2194
2195 OPT_LIBMETALINK=no
2196
2197 AC_ARG_WITH(libmetalink,dnl
2198 AC_HELP_STRING([--with-libmetalink=PATH],[where to look for libmetalink, PATH points to the installation root])
2199 AC_HELP_STRING([--without-libmetalink], [disable libmetalink detection]),
2200   OPT_LIBMETALINK=$withval)
2201
2202 if test X"$OPT_LIBMETALINK" != Xno; then
2203
2204   addld=""
2205   addlib=""
2206   addcflags=""
2207   version=""
2208   libmetalinklib=""
2209
2210   PKGTEST="no"
2211   if test "x$OPT_LIBMETALINK" = "xyes"; then
2212     dnl this is with no partiular path given
2213     PKGTEST="yes"
2214     CURL_CHECK_PKGCONFIG(libmetalink)
2215   else
2216     dnl When particular path is given, set PKG_CONFIG_LIBDIR using the path.
2217     LIBMETALINK_PCDIR="$OPT_LIBMETALINK/lib/pkgconfig"
2218     AC_MSG_NOTICE([PKG_CONFIG_LIBDIR will be set to "$LIBMETALINK_PCDIR"])
2219     if test -f "$LIBMETALINK_PCDIR/libmetalink.pc"; then
2220       PKGTEST="yes"
2221     fi
2222     if test "$PKGTEST" = "yes"; then
2223       CURL_CHECK_PKGCONFIG(libmetalink, [$LIBMETALINK_PCDIR])
2224     fi
2225   fi
2226   if test "$PKGTEST" = "yes" && test "$PKGCONFIG" != "no"; then
2227     addlib=`CURL_EXPORT_PCDIR([$LIBMETALINK_PCDIR]) dnl
2228       $PKGCONFIG --libs-only-l libmetalink`
2229     addld=`CURL_EXPORT_PCDIR([$LIBMETALINK_PCDIR]) dnl
2230       $PKGCONFIG --libs-only-L libmetalink`
2231     addcflags=`CURL_EXPORT_PCDIR([$LIBMETALINK_PCDIR]) dnl
2232       $PKGCONFIG --cflags-only-I libmetalink`
2233     version=`CURL_EXPORT_PCDIR([$LIBMETALINK_PCDIR]) dnl
2234       $PKGCONFIG --modversion libmetalink`
2235     libmetalinklib=`echo $addld | $SED -e 's/-L//'`
2236   fi
2237   if test -n "$addlib"; then
2238
2239     clean_CPPFLAGS="$CPPFLAGS"
2240     clean_LDFLAGS="$LDFLAGS"
2241     clean_LIBS="$LIBS"
2242     CPPFLAGS="$addcflags $clean_CPPFLAGS"
2243     LDFLAGS="$addld $clean_LDFLAGS"
2244     LIBS="$addlib $clean_LIBS"
2245     AC_MSG_CHECKING([if libmetalink is recent enough])
2246     AC_LINK_IFELSE([
2247       AC_LANG_PROGRAM([[
2248 #       include <metalink/metalink.h>
2249       ]],[[
2250         if(0 != metalink_strerror(0)) /* added in 0.1.0 */
2251           return 1;
2252       ]])
2253     ],[
2254       AC_MSG_RESULT([yes ($version)])
2255       want_metalink="yes"
2256     ],[
2257       AC_MSG_RESULT([no ($version)])
2258       AC_MSG_NOTICE([libmetalink library defective or too old])
2259       want_metalink="no"
2260     ])
2261     CPPFLAGS="$clean_CPPFLAGS"
2262     LDFLAGS="$clean_LDFLAGS"
2263     LIBS="$clean_LIBS"
2264     if test "$want_metalink" = "yes"; then
2265       dnl finally libmetalink will be used
2266       AC_DEFINE(USE_METALINK, 1, [Define to enable metalink support])
2267       LIBMETALINK_LIBS=$addlib
2268       LIBMETALINK_LDFLAGS=$addld
2269       LIBMETALINK_CPPFLAGS=$addcflags
2270       AC_SUBST([LIBMETALINK_LIBS])
2271       AC_SUBST([LIBMETALINK_LDFLAGS])
2272       AC_SUBST([LIBMETALINK_CPPFLAGS])
2273       curl_mtlnk_msg="enabled"
2274     fi
2275
2276   fi
2277 fi
2278
2279 dnl **********************************************************************
2280 dnl Check for the presence of LIBSSH2 libraries and headers
2281 dnl **********************************************************************
2282
2283 dnl Default to compiler & linker defaults for LIBSSH2 files & libraries.
2284 OPT_LIBSSH2=off
2285 AC_ARG_WITH(libssh2,dnl
2286 AC_HELP_STRING([--with-libssh2=PATH],[Where to look for libssh2, PATH points to the LIBSSH2 installation; when possible, set the PKG_CONFIG_PATH environment variable instead of using this option])
2287 AC_HELP_STRING([--without-libssh2], [disable LIBSSH2]),
2288   OPT_LIBSSH2=$withval)
2289
2290 if test X"$OPT_LIBSSH2" != Xno; then
2291   dnl backup the pre-libssh2 variables
2292   CLEANLDFLAGS="$LDFLAGS"
2293   CLEANCPPFLAGS="$CPPFLAGS"
2294   CLEANLIBS="$LIBS"
2295
2296   case "$OPT_LIBSSH2" in
2297   yes)
2298     dnl --with-libssh2 (without path) used
2299     CURL_CHECK_PKGCONFIG(libssh2)
2300
2301     if test "$PKGCONFIG" != "no" ; then
2302       LIB_SSH2=`$PKGCONFIG --libs-only-l libssh2`
2303       LD_SSH2=`$PKGCONFIG --libs-only-L libssh2`
2304       CPP_SSH2=`$PKGCONFIG --cflags-only-I libssh2`
2305       version=`$PKGCONFIG --modversion libssh2`
2306       DIR_SSH2=`echo $LD_SSH2 | $SED -e 's/-L//'`
2307     fi
2308
2309     ;;
2310   off)
2311     dnl no --with-libssh2 option given, just check default places
2312     ;;
2313   *)
2314     dnl use the given --with-libssh2 spot
2315     PREFIX_SSH2=$OPT_LIBSSH2
2316     ;;
2317   esac
2318
2319   dnl if given with a prefix, we set -L and -I based on that
2320   if test -n "$PREFIX_SSH2"; then
2321     LIB_SSH2="-lssh2"
2322     LD_SSH2=-L${PREFIX_SSH2}/lib$libsuff
2323     CPP_SSH2=-I${PREFIX_SSH2}/include
2324     DIR_SSH2=${PREFIX_SSH2}/lib$libsuff
2325   fi
2326
2327   LDFLAGS="$LDFLAGS $LD_SSH2"
2328   CPPFLAGS="$CPPFLAGS $CPP_SSH2"
2329   LIBS="$LIB_SSH2 $LIBS"
2330
2331   AC_CHECK_LIB(ssh2, libssh2_channel_open_ex)
2332
2333   AC_CHECK_HEADERS(libssh2.h,
2334     curl_ssh_msg="enabled (libSSH2)"
2335     LIBSSH2_ENABLED=1
2336     AC_DEFINE(USE_LIBSSH2, 1, [if libSSH2 is in use])
2337     AC_SUBST(USE_LIBSSH2, [1])
2338   )
2339
2340   if test X"$OPT_LIBSSH2" != Xoff &&
2341      test "$LIBSSH2_ENABLED" != "1"; then
2342     AC_MSG_ERROR([libSSH2 libs and/or directories were not found where specified!])
2343   fi
2344
2345   if test "$LIBSSH2_ENABLED" = "1"; then
2346     if test -n "$DIR_SSH2"; then
2347        dnl when the libssh2 shared libs were found in a path that the run-time
2348        dnl linker doesn't search through, we need to add it to LD_LIBRARY_PATH
2349        dnl to prevent further configure tests to fail due to this
2350
2351        dnl libssh2_version is a post 1.0 addition
2352        dnl libssh2_init and libssh2_exit were added in 1.2.5
2353        dnl libssh2_scp_send64 was added in 1.2.6
2354        dnl libssh2_session_handshake was added in 1.2.8
2355        AC_CHECK_FUNCS( libssh2_version libssh2_init libssh2_exit \
2356                        libssh2_scp_send64 libssh2_session_handshake)
2357        if test "x$cross_compiling" != "xyes"; then
2358          LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$DIR_SSH2"
2359          export LD_LIBRARY_PATH
2360          AC_MSG_NOTICE([Added $DIR_SSH2 to LD_LIBRARY_PATH])
2361        fi
2362     fi
2363   else
2364     dnl no libssh2, revert back to clean variables
2365     LDFLAGS=$CLEANLDFLAGS
2366     CPPFLAGS=$CLEANCPPFLAGS
2367     LIBS=$CLEANLIBS
2368   fi
2369 fi
2370
2371 dnl **********************************************************************
2372 dnl Check for the presence of LIBRTMP libraries and headers
2373 dnl **********************************************************************
2374
2375 dnl Default to compiler & linker defaults for LIBRTMP files & libraries.
2376 OPT_LIBRTMP=off
2377 AC_ARG_WITH(librtmp,dnl
2378 AC_HELP_STRING([--with-librtmp=PATH],[Where to look for librtmp, PATH points to the LIBRTMP installation; when possible, set the PKG_CONFIG_PATH environment variable instead of using this option])
2379 AC_HELP_STRING([--without-librtmp], [disable LIBRTMP]),
2380   OPT_LIBRTMP=$withval)
2381
2382 if test X"$OPT_LIBRTMP" != Xno; then
2383   dnl backup the pre-librtmp variables
2384   CLEANLDFLAGS="$LDFLAGS"
2385   CLEANCPPFLAGS="$CPPFLAGS"
2386   CLEANLIBS="$LIBS"
2387
2388   case "$OPT_LIBRTMP" in
2389   yes)
2390     dnl --with-librtmp (without path) used
2391     CURL_CHECK_PKGCONFIG(librtmp)
2392
2393     if test "$PKGCONFIG" != "no" ; then
2394       LIB_RTMP=`$PKGCONFIG --libs-only-l librtmp`
2395       LD_RTMP=`$PKGCONFIG --libs-only-L librtmp`
2396       CPP_RTMP=`$PKGCONFIG --cflags-only-I librtmp`
2397       version=`$PKGCONFIG --modversion librtmp`
2398       DIR_RTMP=`echo $LD_RTMP | $SED -e 's/-L//'`
2399     else
2400       dnl To avoid link errors, we do not allow --librtmp without
2401       dnl a pkgconfig file
2402       AC_MSG_ERROR([--librtmp was specified but could not find librtmp pkgconfig file.])
2403     fi
2404
2405     ;;
2406   off)
2407     dnl no --with-librtmp option given, just check default places
2408     LIB_RTMP="-lrtmp"
2409     ;;
2410   *)
2411     dnl use the given --with-librtmp spot
2412     PREFIX_RTMP=$OPT_LIBRTMP
2413     ;;
2414   esac
2415
2416   dnl if given with a prefix, we set -L and -I based on that
2417   if test -n "$PREFIX_RTMP"; then
2418     LD_RTMP=-L${PREFIX_RTMP}/lib$libsuff
2419     CPP_RTMP=-I${PREFIX_RTMP}/include
2420     DIR_RTMP=${PREFIX_RTMP}/lib$libsuff
2421   fi
2422
2423   LDFLAGS="$LDFLAGS $LD_RTMP"
2424   CPPFLAGS="$CPPFLAGS $CPP_RTMP"
2425   LIBS="$LIB_RTMP $LIBS"
2426
2427   AC_CHECK_LIB(rtmp, RTMP_Init,
2428     [
2429      AC_CHECK_HEADERS(librtmp/rtmp.h,
2430         curl_rtmp_msg="enabled (librtmp)"
2431         LIBRTMP_ENABLED=1
2432         AC_DEFINE(USE_LIBRTMP, 1, [if librtmp is in use])
2433         AC_SUBST(USE_LIBRTMP, [1])
2434      )
2435     ],
2436       dnl not found, revert back to clean variables
2437       LDFLAGS=$CLEANLDFLAGS
2438       CPPFLAGS=$CLEANCPPFLAGS
2439       LIBS=$CLEANLIBS
2440   )
2441
2442   if test X"$OPT_LIBRTMP" != Xoff &&
2443      test "$LIBRTMP_ENABLED" != "1"; then
2444     AC_MSG_ERROR([librtmp libs and/or directories were not found where specified!])
2445   fi
2446
2447 fi
2448
2449 dnl **********************************************************************
2450 dnl Check for linker switch for versioned symbols
2451 dnl **********************************************************************
2452
2453 versioned_symbols_flavour=
2454 AC_MSG_CHECKING([whether versioned symbols are wanted])
2455 AC_ARG_ENABLE(versioned-symbols,
2456 AC_HELP_STRING([--enable-versioned-symbols], [Enable versioned symbols in shared library])
2457 AC_HELP_STRING([--disable-versioned-symbols], [Disable versioned symbols in shared library]),
2458 [ case "$enableval" in
2459   yes) AC_MSG_RESULT(yes)
2460     AC_MSG_CHECKING([if libraries can be versioned])
2461     GLD=`$LD --help < /dev/null 2>/dev/null | grep version-script`
2462     if test -z "$GLD"; then
2463         AC_MSG_RESULT(no)
2464         AC_MSG_WARN([You need an ld version supporting the --version-script option])
2465     else
2466         AC_MSG_RESULT(yes)
2467         if test "x$OPENSSL_ENABLED" = "x1"; then
2468           versioned_symbols_flavour="OPENSSL_"
2469         elif test "x$GNUTLS_ENABLED" == "x1"; then
2470           versioned_symbols_flavour="GNUTLS_"
2471         elif test "x$NSS_ENABLED" == "x1"; then
2472           versioned_symbols_flavour="NSS_"
2473         elif test "x$POLARSSL_ENABLED" == "x1"; then
2474           versioned_symbols_flavour="POLARSSL_"
2475         elif test "x$CYASSL_ENABLED" == "x1"; then
2476           versioned_symbols_flavour="CYASSL_"
2477         elif test "x$AXTLS_ENABLED" == "x1"; then
2478           versioned_symbols_flavour="AXTLS_"
2479         elif test "x$WINSSL_ENABLED" == "x1"; then
2480           versioned_symbols_flavour="WINSSL_"
2481         elif test "x$DARWINSSL_ENABLED" == "x1"; then
2482           versioned_symbols_flavour="DARWINSSL_"
2483         else
2484           versioned_symbols_flavour=""
2485         fi
2486         versioned_symbols="yes"
2487     fi
2488     ;;
2489
2490   *)   AC_MSG_RESULT(no)
2491     ;;
2492   esac
2493 ], [
2494 AC_MSG_RESULT(no)
2495 ]
2496 )
2497
2498 AC_SUBST([CURL_LT_SHLIB_VERSIONED_FLAVOUR],
2499   ["$versioned_symbols_flavour"])
2500 AM_CONDITIONAL([CURL_LT_SHLIB_USE_VERSIONED_SYMBOLS],
2501   [test "x$versioned_symbols" = 'xyes'])
2502
2503 dnl -------------------------------------------------
2504 dnl check winidn option before other IDN libraries
2505 dnl -------------------------------------------------
2506
2507 AC_MSG_CHECKING([whether to enable Windows native IDN (Windows native builds only)])
2508 OPT_WINIDN="default"
2509 AC_ARG_WITH(winidn,
2510 AC_HELP_STRING([--with-winidn=PATH],[enable Windows native IDN])
2511 AC_HELP_STRING([--without-winidn], [disable Windows native IDN]),
2512   OPT_WINIDN=$withval)
2513 case "$OPT_WINIDN" in
2514   no|default)
2515     dnl --without-winidn option used or configure option not specified
2516     want_winidn="no"
2517     AC_MSG_RESULT([no])
2518     ;;
2519   yes)
2520     dnl --with-winidn option used without path
2521     want_winidn="yes"
2522     want_winidn_path="default"
2523     AC_MSG_RESULT([yes])
2524     ;;
2525   *)
2526     dnl --with-winidn option used with path
2527     want_winidn="yes"
2528     want_winidn_path="$withval"
2529     AC_MSG_RESULT([yes ($withval)])
2530     ;;
2531 esac
2532
2533 if test "$want_winidn" = "yes"; then
2534   dnl winidn library support has been requested
2535   clean_CPPFLAGS="$CPPFLAGS"
2536   clean_LDFLAGS="$LDFLAGS"
2537   clean_LIBS="$LIBS"
2538   WINIDN_LIBS="-lnormaliz"
2539   #
2540   if test "$want_winidn_path" != "default"; then
2541     dnl path has been specified
2542     dnl pkg-config not available or provides no info
2543     WINIDN_LDFLAGS="-L$want_winidn_path/lib$libsuff"
2544     WINIDN_CPPFLAGS="-I$want_winidn_path/include"
2545     WINIDN_DIR="$want_winidn_path/lib$libsuff"
2546   fi
2547   #
2548   CPPFLAGS="$WINIDN_CPPFLAGS $CPPFLAGS"
2549   LDFLAGS="$WINIDN_LDFLAGS $LDFLAGS"
2550   LIBS="$WINIDN_LIBS $LIBS"
2551   #
2552   AC_MSG_CHECKING([if IdnToUnicode can be linked])
2553   AC_LINK_IFELSE([
2554     AC_LANG_FUNC_LINK_TRY([IdnToUnicode])
2555   ],[
2556     AC_MSG_RESULT([yes])
2557     tst_links_winidn="yes"
2558   ],[
2559     AC_MSG_RESULT([no])
2560     tst_links_winidn="no"
2561   ])
2562   #
2563   if test "$tst_links_winidn" = "yes"; then
2564     AC_DEFINE(USE_WIN32_IDN, 1, [Define to 1 if you have the `normaliz' (WinIDN) library (-lnormaliz).])
2565     AC_DEFINE(WANT_IDN_PROTOTYPES, 1, [Define to 1 to provide own prototypes.])
2566     AC_SUBST([IDN_ENABLED], [1])
2567     curl_idn_msg="enabled (Windows-native)"
2568   else
2569     AC_MSG_WARN([Cannot find libraries for IDN support: IDN disabled])
2570     CPPFLAGS="$clean_CPPFLAGS"
2571     LDFLAGS="$clean_LDFLAGS"
2572     LIBS="$clean_LIBS"
2573   fi
2574 fi
2575
2576 dnl **********************************************************************
2577 dnl Check for the presence of IDN libraries and headers
2578 dnl **********************************************************************
2579
2580 AC_MSG_CHECKING([whether to build with libidn])
2581 OPT_IDN="default"
2582 AC_ARG_WITH(libidn,
2583 AC_HELP_STRING([--with-libidn=PATH],[Enable libidn usage])
2584 AC_HELP_STRING([--without-libidn],[Disable libidn usage]),
2585   [OPT_IDN=$withval])
2586 case "$OPT_IDN" in
2587   no)
2588     dnl --without-libidn option used
2589     want_idn="no"
2590     AC_MSG_RESULT([no])
2591     ;;
2592   default)
2593     dnl configure option not specified
2594     want_idn="yes"
2595     want_idn_path="default"
2596     AC_MSG_RESULT([(assumed) yes])
2597     ;;
2598   yes)
2599     dnl --with-libidn option used without path
2600     want_idn="yes"
2601     want_idn_path="default"
2602     AC_MSG_RESULT([yes])
2603     ;;
2604   *)
2605     dnl --with-libidn option used with path
2606     want_idn="yes"
2607     want_idn_path="$withval"
2608     AC_MSG_RESULT([yes ($withval)])
2609     ;;
2610 esac
2611
2612 if test "$want_idn" = "yes"; then
2613   dnl idn library support has been requested
2614   clean_CPPFLAGS="$CPPFLAGS"
2615   clean_LDFLAGS="$LDFLAGS"
2616   clean_LIBS="$LIBS"
2617   PKGCONFIG="no"
2618   #
2619   if test "$want_idn_path" != "default"; then
2620     dnl path has been specified
2621     IDN_PCDIR="$want_idn_path/lib$libsuff/pkgconfig"
2622     CURL_CHECK_PKGCONFIG(libidn, [$IDN_PCDIR])
2623     if test "$PKGCONFIG" != "no"; then
2624       IDN_LIBS=`CURL_EXPORT_PCDIR([$IDN_PCDIR]) dnl
2625         $PKGCONFIG --libs-only-l libidn 2>/dev/null`
2626       IDN_LDFLAGS=`CURL_EXPORT_PCDIR([$IDN_PCDIR]) dnl
2627         $PKGCONFIG --libs-only-L libidn 2>/dev/null`
2628       IDN_CPPFLAGS=`CURL_EXPORT_PCDIR([$IDN_PCDIR]) dnl
2629         $PKGCONFIG --cflags-only-I libidn 2>/dev/null`
2630       IDN_DIR=`echo $IDN_LDFLAGS | $SED -e 's/-L//'`
2631     else
2632       dnl pkg-config not available or provides no info
2633       IDN_LIBS="-lidn"
2634       IDN_LDFLAGS="-L$want_idn_path/lib$libsuff"
2635       IDN_CPPFLAGS="-I$want_idn_path/include"
2636       IDN_DIR="$want_idn_path/lib$libsuff"
2637     fi
2638   else
2639     dnl path not specified
2640     CURL_CHECK_PKGCONFIG(libidn)
2641     if test "$PKGCONFIG" != "no"; then
2642       IDN_LIBS=`$PKGCONFIG --libs-only-l libidn 2>/dev/null`
2643       IDN_LDFLAGS=`$PKGCONFIG --libs-only-L libidn 2>/dev/null`
2644       IDN_CPPFLAGS=`$PKGCONFIG --cflags-only-I libidn 2>/dev/null`
2645       IDN_DIR=`echo $IDN_LDFLAGS | $SED -e 's/-L//'`
2646     else
2647       dnl pkg-config not available or provides no info
2648       IDN_LIBS="-lidn"
2649     fi
2650   fi
2651   #
2652   if test "$PKGCONFIG" != "no"; then
2653     AC_MSG_NOTICE([pkg-config: IDN_LIBS: "$IDN_LIBS"])
2654     AC_MSG_NOTICE([pkg-config: IDN_LDFLAGS: "$IDN_LDFLAGS"])
2655     AC_MSG_NOTICE([pkg-config: IDN_CPPFLAGS: "$IDN_CPPFLAGS"])
2656     AC_MSG_NOTICE([pkg-config: IDN_DIR: "$IDN_DIR"])
2657   else
2658     AC_MSG_NOTICE([IDN_LIBS: "$IDN_LIBS"])
2659     AC_MSG_NOTICE([IDN_LDFLAGS: "$IDN_LDFLAGS"])
2660     AC_MSG_NOTICE([IDN_CPPFLAGS: "$IDN_CPPFLAGS"])
2661     AC_MSG_NOTICE([IDN_DIR: "$IDN_DIR"])
2662   fi
2663   #
2664   CPPFLAGS="$IDN_CPPFLAGS $CPPFLAGS"
2665   LDFLAGS="$IDN_LDFLAGS $LDFLAGS"
2666   LIBS="$IDN_LIBS $LIBS"
2667   #
2668   AC_MSG_CHECKING([if idna_to_ascii_4i can be linked])
2669   AC_LINK_IFELSE([
2670     AC_LANG_FUNC_LINK_TRY([idna_to_ascii_4i])
2671   ],[
2672     AC_MSG_RESULT([yes])
2673     tst_links_libidn="yes"
2674   ],[
2675     AC_MSG_RESULT([no])
2676     tst_links_libidn="no"
2677   ])
2678   if test "$tst_links_libidn" = "no"; then
2679     AC_MSG_CHECKING([if idna_to_ascii_lz can be linked])
2680     AC_LINK_IFELSE([
2681       AC_LANG_FUNC_LINK_TRY([idna_to_ascii_lz])
2682     ],[
2683       AC_MSG_RESULT([yes])
2684       tst_links_libidn="yes"
2685     ],[
2686       AC_MSG_RESULT([no])
2687       tst_links_libidn="no"
2688     ])
2689   fi
2690   #
2691   if test "$tst_links_libidn" = "yes"; then
2692     AC_DEFINE(HAVE_LIBIDN, 1, [Define to 1 if you have the `idn' library (-lidn).])
2693     dnl different versions of libidn have different setups of these:
2694     AC_CHECK_FUNCS( idn_free idna_strerror tld_strerror )
2695     AC_CHECK_HEADERS( idn-free.h tld.h )
2696     if test "x$ac_cv_header_tld_h" = "xyes"; then
2697       AC_SUBST([IDN_ENABLED], [1])
2698       curl_idn_msg="enabled"
2699       if test -n "$IDN_DIR"; then
2700         LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$IDN_DIR"
2701         export LD_LIBRARY_PATH
2702         AC_MSG_NOTICE([Added $IDN_DIR to LD_LIBRARY_PATH])
2703       fi
2704     else
2705       AC_MSG_WARN([Libraries for IDN support too old: IDN disabled])
2706       CPPFLAGS="$clean_CPPFLAGS"
2707       LDFLAGS="$clean_LDFLAGS"
2708       LIBS="$clean_LIBS"
2709     fi
2710   else
2711     AC_MSG_WARN([Cannot find libraries for IDN support: IDN disabled])
2712     CPPFLAGS="$clean_CPPFLAGS"
2713     LDFLAGS="$clean_LDFLAGS"
2714     LIBS="$clean_LIBS"
2715   fi
2716 fi
2717
2718
2719 dnl Let's hope this split URL remains working:
2720 dnl http://publibn.boulder.ibm.com/doc_link/en_US/a_doc_lib/aixprggd/ \
2721 dnl genprogc/thread_quick_ref.htm
2722
2723
2724 dnl **********************************************************************
2725 dnl Check for nghttp2
2726 dnl **********************************************************************
2727
2728 AC_MSG_CHECKING([whether to build with nghttp2])
2729 OPT_H2="no"
2730 AC_ARG_WITH(nghttp2,
2731 AC_HELP_STRING([--with-nghttp2=PATH],[Enable nghttp2 usage])
2732 AC_HELP_STRING([--without-nghttp2],[Disable nghttp2 usage]),
2733   [OPT_H2=$withval])
2734 case "$OPT_H2" in
2735   no)
2736     dnl --without-nghttp2 option used
2737     want_idn="no"
2738     AC_MSG_RESULT([no])
2739     ;;
2740   default)
2741     dnl configure option not specified
2742     want_h2="no"
2743     want_h2_path="default"
2744     AC_MSG_RESULT([no])
2745     ;;
2746   yes)
2747     dnl --with-nghttp2 option used without path
2748     want_h2="yes"
2749     want_h2_path=""
2750     AC_MSG_RESULT([yes])
2751     ;;
2752   *)
2753     dnl --with-nghttp2 option used with path
2754     want_h2="yes"
2755     want_h2_path="$withval"
2756     AC_MSG_RESULT([yes ($withval)])
2757     ;;
2758 esac
2759
2760 curl_h2_msg="disabled (--with-nghttp2)"
2761 if test X"$OPT_H2" != Xno; then
2762   dnl backup the pre-librtmp variables
2763   CLEANLDFLAGS="$LDFLAGS"
2764   CLEANCPPFLAGS="$CPPFLAGS"
2765   CLEANLIBS="$LIBS"
2766
2767   h2pcdir=${want_h2_path}/lib/pkgconfig
2768   CURL_CHECK_PKGCONFIG(libnghttp2, $h2pcdir)
2769
2770   if test "$PKGCONFIG" != "no" ; then
2771     LIB_H2=`CURL_EXPORT_PCDIR([$h2pcdir])
2772       $PKGCONFIG --libs-only-l libnghttp2`
2773     AC_MSG_NOTICE([-l is $LIB_H2])
2774
2775     CPP_H2=`CURL_EXPORT_PCDIR([$h2pcdir]) dnl
2776       $PKGCONFIG --cflags-only-I libnghttp2`
2777     AC_MSG_NOTICE([-I is $CPP_H2])
2778
2779     LD_H2=`CURL_EXPORT_PCDIR([$h2pcdir])
2780       $PKGCONFIG --libs-only-L libnghttp2`
2781     AC_MSG_NOTICE([-L is $LD_H2])
2782
2783   else
2784     dnl To avoid link errors, we do not allow --libnghttp2 without
2785     dnl a pkgconfig file
2786     AC_MSG_ERROR([--with-nghttp2 was specified but could not find libnghttp2 pkg-config file.])
2787   fi
2788
2789   LDFLAGS="$LDFLAGS $LD_H2"
2790   CPPFLAGS="$CPPFLAGS $CPP_H2"
2791   LIBS="$LIB_H2 $LIBS"
2792
2793   AC_CHECK_LIB(nghttp2, nghttp2_session_client_new,
2794     [
2795      AC_CHECK_HEADERS(nghttp2/nghttp2.h,
2796         curl_h2_msg="enabled (nghttp2)"
2797         NGHTTP2_ENABLED=1
2798         AC_DEFINE(USE_NGHTTP2, 1, [if nghttp2 is in use])
2799         AC_SUBST(USE_NGHTTP2, [1])
2800      )
2801     ],
2802       dnl not found, revert back to clean variables
2803       LDFLAGS=$CLEANLDFLAGS
2804       CPPFLAGS=$CLEANCPPFLAGS
2805       LIBS=$CLEANLIBS
2806   )
2807
2808 fi
2809
2810 dnl **********************************************************************
2811 dnl Back to "normal" configuring
2812 dnl **********************************************************************
2813
2814 dnl Checks for header files.
2815 AC_HEADER_STDC
2816
2817 CURL_CHECK_HEADER_MALLOC
2818 CURL_CHECK_HEADER_MEMORY
2819
2820 dnl Now check for the very most basic headers. Then we can use these
2821 dnl ones as default-headers when checking for the rest!
2822 AC_CHECK_HEADERS(
2823         sys/types.h \
2824         sys/time.h \
2825         sys/select.h \
2826         sys/socket.h \
2827         sys/ioctl.h \
2828         sys/uio.h \
2829         assert.h \
2830         unistd.h \
2831         stdlib.h \
2832         limits.h \
2833         arpa/inet.h \
2834         net/if.h \
2835         netinet/in.h \
2836         sys/un.h \
2837         netinet/tcp.h \
2838         netdb.h \
2839         sys/sockio.h \
2840         sys/stat.h \
2841         sys/param.h \
2842         termios.h \
2843         termio.h \
2844         sgtty.h \
2845         fcntl.h \
2846         alloca.h \
2847         time.h \
2848         io.h \
2849         pwd.h \
2850         utime.h \
2851         sys/utime.h \
2852         sys/poll.h \
2853         poll.h \
2854         socket.h \
2855         sys/resource.h \
2856         libgen.h \
2857         locale.h \
2858         errno.h \
2859         stdbool.h \
2860         arpa/tftp.h \
2861         sys/filio.h \
2862         sys/wait.h \
2863         setjmp.h,
2864 dnl to do if not found
2865 [],
2866 dnl to do if found
2867 [],
2868 dnl default includes
2869 [
2870 #ifdef HAVE_SYS_TYPES_H
2871 #include <sys/types.h>
2872 #endif
2873 #ifdef HAVE_SYS_TIME_H
2874 #include <sys/time.h>
2875 #endif
2876 #ifdef HAVE_SYS_SELECT_H
2877 #include <sys/select.h>
2878 #endif
2879 #ifdef HAVE_SYS_SOCKET_H
2880 #include <sys/socket.h>
2881 #endif
2882 #ifdef HAVE_NETINET_IN_H
2883 #include <netinet/in.h>
2884 #endif
2885 #ifdef HAVE_SYS_UN_H
2886 #include <sys/un.h>
2887 #endif
2888 ]
2889 )
2890
2891 dnl Checks for typedefs, structures, and compiler characteristics.
2892 AC_C_CONST
2893 CURL_CHECK_VARIADIC_MACROS
2894 AC_TYPE_SIZE_T
2895 AC_HEADER_TIME
2896 CURL_CHECK_STRUCT_TIMEVAL
2897 CURL_VERIFY_RUNTIMELIBS
2898
2899 AC_CHECK_SIZEOF(size_t)
2900 AC_CHECK_SIZEOF(long)
2901 AC_CHECK_SIZEOF(int)
2902 AC_CHECK_SIZEOF(short)
2903 CURL_CONFIGURE_LONG
2904 AC_CHECK_SIZEOF(time_t)
2905 AC_CHECK_SIZEOF(off_t)
2906
2907 soname_bump=no
2908 if test x"$ac_cv_native_windows" != "xyes" &&
2909    test $ac_cv_sizeof_off_t -ne $curl_sizeof_curl_off_t; then
2910   AC_MSG_WARN([This libcurl built is probably not ABI compatible with previous])
2911   AC_MSG_WARN([builds! You MUST read lib/README.curl_off_t to figure it out.])
2912   soname_bump=yes
2913 fi
2914
2915
2916 AC_CHECK_TYPE(long long,
2917    [AC_DEFINE(HAVE_LONGLONG, 1,
2918       [Define to 1 if the compiler supports the 'long long' data type.])]
2919    longlong="yes"
2920 )
2921
2922 if test "xyes" = "x$longlong"; then
2923   AC_MSG_CHECKING([if numberLL works])
2924   AC_COMPILE_IFELSE([
2925     AC_LANG_PROGRAM([[
2926     ]],[[
2927       long long val = 1000LL;
2928     ]])
2929   ],[
2930     AC_MSG_RESULT([yes])
2931     AC_DEFINE(HAVE_LL, 1, [if your compiler supports LL])
2932   ],[
2933     AC_MSG_RESULT([no])
2934   ])
2935 fi
2936
2937
2938 # check for ssize_t
2939 AC_CHECK_TYPE(ssize_t, ,
2940    AC_DEFINE(ssize_t, int, [the signed version of size_t]))
2941
2942 # check for bool type
2943 AC_CHECK_TYPE([bool],[
2944   AC_DEFINE(HAVE_BOOL_T, 1,
2945     [Define to 1 if bool is an available type.])
2946 ], ,[
2947 #ifdef HAVE_SYS_TYPES_H
2948 #include <sys/types.h>
2949 #endif
2950 #ifdef HAVE_STDBOOL_H
2951 #include <stdbool.h>
2952 #endif
2953 ])
2954
2955 CURL_CONFIGURE_CURL_SOCKLEN_T
2956
2957 CURL_CONFIGURE_PULL_SYS_POLL
2958
2959 TYPE_IN_ADDR_T
2960
2961 TYPE_SOCKADDR_STORAGE
2962
2963 TYPE_SIG_ATOMIC_T
2964
2965 AC_TYPE_SIGNAL
2966
2967 CURL_CHECK_FUNC_SELECT
2968
2969 CURL_CHECK_FUNC_RECV
2970 CURL_CHECK_FUNC_SEND
2971 CURL_CHECK_MSG_NOSIGNAL
2972
2973 CURL_CHECK_FUNC_ALARM
2974 CURL_CHECK_FUNC_BASENAME
2975 CURL_CHECK_FUNC_CLOSESOCKET
2976 CURL_CHECK_FUNC_CLOSESOCKET_CAMEL
2977 CURL_CHECK_FUNC_CONNECT
2978 CURL_CHECK_FUNC_FCNTL
2979 CURL_CHECK_FUNC_FDOPEN
2980 CURL_CHECK_FUNC_FREEADDRINFO
2981 CURL_CHECK_FUNC_FREEIFADDRS
2982 CURL_CHECK_FUNC_FSETXATTR
2983 CURL_CHECK_FUNC_FTRUNCATE
2984 CURL_CHECK_FUNC_GETADDRINFO
2985 CURL_CHECK_FUNC_GAI_STRERROR
2986 CURL_CHECK_FUNC_GETHOSTBYADDR
2987 CURL_CHECK_FUNC_GETHOSTBYADDR_R
2988 CURL_CHECK_FUNC_GETHOSTBYNAME
2989 CURL_CHECK_FUNC_GETHOSTBYNAME_R
2990 CURL_CHECK_FUNC_GETHOSTNAME
2991 CURL_CHECK_FUNC_GETIFADDRS
2992 CURL_CHECK_FUNC_GETSERVBYPORT_R
2993 CURL_CHECK_FUNC_GMTIME_R
2994 CURL_CHECK_FUNC_INET_NTOA_R
2995 CURL_CHECK_FUNC_INET_NTOP
2996 CURL_CHECK_FUNC_INET_PTON
2997 CURL_CHECK_FUNC_IOCTL
2998 CURL_CHECK_FUNC_IOCTLSOCKET
2999 CURL_CHECK_FUNC_IOCTLSOCKET_CAMEL
3000 CURL_CHECK_FUNC_LOCALTIME_R
3001 CURL_CHECK_FUNC_MEMRCHR
3002 CURL_CHECK_FUNC_POLL
3003 CURL_CHECK_FUNC_SETSOCKOPT
3004 CURL_CHECK_FUNC_SIGACTION
3005 CURL_CHECK_FUNC_SIGINTERRUPT
3006 CURL_CHECK_FUNC_SIGNAL
3007 CURL_CHECK_FUNC_SIGSETJMP
3008 CURL_CHECK_FUNC_SOCKET
3009 CURL_CHECK_FUNC_SOCKETPAIR
3010 CURL_CHECK_FUNC_STRCASECMP
3011 CURL_CHECK_FUNC_STRCMPI
3012 CURL_CHECK_FUNC_STRDUP
3013 CURL_CHECK_FUNC_STRERROR_R
3014 CURL_CHECK_FUNC_STRICMP
3015 CURL_CHECK_FUNC_STRNCASECMP
3016 CURL_CHECK_FUNC_STRNCMPI
3017 CURL_CHECK_FUNC_STRNICMP
3018 CURL_CHECK_FUNC_STRSTR
3019 CURL_CHECK_FUNC_STRTOK_R
3020 CURL_CHECK_FUNC_STRTOLL
3021 CURL_CHECK_FUNC_WRITEV
3022
3023 case $host in
3024   *msdosdjgpp)
3025      ac_cv_func_pipe=no
3026      skipcheck_pipe=yes
3027      AC_MSG_NOTICE([skip check for pipe on msdosdjgpp])
3028     ;;
3029 esac
3030
3031 AC_CHECK_FUNCS([fork \
3032   geteuid \
3033   getpass_r \
3034   getppid \
3035   getprotobyname \
3036   getpwuid \
3037   getrlimit \
3038   gettimeofday \
3039   inet_addr \
3040   perror \
3041   pipe \
3042   setlocale \
3043   setmode \
3044   setrlimit \
3045   uname \
3046   utime
3047 ],[
3048 ],[
3049   func="$ac_func"
3050   eval skipcheck=\$skipcheck_$func
3051   if test "x$skipcheck" != "xyes"; then
3052     AC_MSG_CHECKING([deeper for $func])
3053     AC_LINK_IFELSE([
3054       AC_LANG_PROGRAM([[
3055       ]],[[
3056         $func ();
3057       ]])
3058     ],[
3059       AC_MSG_RESULT([yes])
3060       eval "ac_cv_func_$func=yes"
3061       AC_DEFINE_UNQUOTED(XC_SH_TR_CPP([HAVE_$func]), [1],
3062         [Define to 1 if you have the $func function.])
3063     ],[
3064       AC_MSG_RESULT([but still no])
3065     ])
3066   fi
3067 ])
3068
3069 dnl Check if the getnameinfo function is available
3070 dnl and get the types of five of its arguments.
3071 CURL_CHECK_FUNC_GETNAMEINFO
3072
3073 if test "$ipv6" = "yes"; then
3074   if test "$ac_cv_func_getaddrinfo" = "yes"; then
3075     AC_DEFINE(ENABLE_IPV6, 1, [Define if you want to enable IPv6 support])
3076     IPV6_ENABLED=1
3077     AC_SUBST(IPV6_ENABLED)
3078   fi
3079   CURL_CHECK_NI_WITHSCOPEID
3080 fi
3081
3082 CURL_CHECK_NONBLOCKING_SOCKET
3083
3084 dnl ************************************************************
3085 dnl nroff tool stuff
3086 dnl
3087
3088 AC_PATH_PROG( PERL, perl, ,
3089   $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
3090 AC_SUBST(PERL)
3091
3092 AC_PATH_PROGS( NROFF, gnroff nroff, ,
3093   $PATH:/usr/bin/:/usr/local/bin )
3094 AC_SUBST(NROFF)
3095
3096 if test -n "$NROFF"; then
3097   dnl only check for nroff options if an nroff command was found
3098
3099   AC_MSG_CHECKING([how to use *nroff to get plain text from man pages])
3100   MANOPT="-man"
3101   mancheck=`echo foo | $NROFF $MANOPT 2>/dev/null`
3102   if test -z "$mancheck"; then
3103     MANOPT="-mandoc"
3104    mancheck=`echo foo | $NROFF $MANOPT 2>/dev/null`
3105     if test -z "$mancheck"; then
3106       MANOPT=""
3107       AC_MSG_RESULT([failed])
3108       AC_MSG_WARN([found no *nroff option to get plaintext from man pages])
3109     else
3110       AC_MSG_RESULT([$MANOPT])
3111     fi
3112   else
3113     AC_MSG_RESULT([$MANOPT])
3114   fi
3115   AC_SUBST(MANOPT)
3116 fi
3117
3118 if test -z "$MANOPT"
3119 then
3120   dnl if no nroff tool was found, or no option that could convert man pages
3121   dnl was found, then disable the built-in manual stuff
3122   AC_MSG_WARN([disabling built-in manual])
3123   USE_MANUAL="no";
3124 fi
3125
3126 dnl *************************************************************************
3127 dnl If the manual variable still is set, then we go with providing a built-in
3128 dnl manual
3129
3130 if test "$USE_MANUAL" = "1"; then
3131   AC_DEFINE(USE_MANUAL, 1, [If you want to build curl with the built-in manual])
3132   curl_manual_msg="enabled"
3133 fi
3134
3135 dnl set variable for use in automakefile(s)
3136 AM_CONDITIONAL(USE_MANUAL, test x"$USE_MANUAL" = x1)
3137
3138 CURL_CHECK_LIB_ARES
3139 AM_CONDITIONAL(USE_EMBEDDED_ARES, test x$embedded_ares = xyes)
3140
3141 if test "x$ac_cv_native_windows" != "xyes" &&
3142    test "x$enable_shared" = "xyes"; then
3143   build_libhostname=yes
3144 else
3145   build_libhostname=no
3146 fi
3147 AM_CONDITIONAL(BUILD_LIBHOSTNAME, test x$build_libhostname = xyes)
3148
3149 CURL_CHECK_OPTION_THREADED_RESOLVER
3150
3151 if test "x$want_thres" = xyes && test "x$want_ares" = xyes; then
3152   AC_MSG_ERROR(
3153 [Options --enable-threaded-resolver and --enable-ares are mutually exclusive])
3154 fi
3155
3156 if test "$want_thres" = "yes"; then
3157   AC_CHECK_HEADER(pthread.h,
3158     [ AC_DEFINE(HAVE_PTHREAD_H, 1, [if you have <pthread.h>])
3159       save_CFLAGS="$CFLAGS"
3160
3161       dnl first check for function without lib
3162       AC_CHECK_FUNC(pthread_create, [USE_THREADS_POSIX=1] )
3163
3164       dnl if it wasn't found without lib, search for it in pthread lib
3165       if test "$USE_THREADS_POSIX" != "1"
3166       then
3167         CFLAGS="$CFLAGS -pthread"
3168         AC_CHECK_LIB(pthread, pthread_create,
3169                      [USE_THREADS_POSIX=1],
3170                      [ CFLAGS="$save_CFLAGS"])
3171       fi
3172
3173       if test "x$USE_THREADS_POSIX" = "x1"
3174       then
3175         AC_DEFINE(USE_THREADS_POSIX, 1, [if you want POSIX threaded DNS lookup])
3176         curl_res_msg="POSIX threaded"
3177       fi
3178
3179
3180   ])
3181 fi
3182
3183 dnl ************************************************************
3184 dnl disable verbose text strings
3185 dnl
3186 AC_MSG_CHECKING([whether to enable verbose strings])
3187 AC_ARG_ENABLE(verbose,
3188 AC_HELP_STRING([--enable-verbose],[Enable verbose strings])
3189 AC_HELP_STRING([--disable-verbose],[Disable verbose strings]),
3190 [ case "$enableval" in
3191   no)
3192        AC_MSG_RESULT(no)
3193        AC_DEFINE(CURL_DISABLE_VERBOSE_STRINGS, 1, [to disable verbose strings])
3194        curl_verbose_msg="no"
3195        ;;
3196   *)   AC_MSG_RESULT(yes)
3197        ;;
3198   esac ],
3199        AC_MSG_RESULT(yes)
3200 )
3201
3202 dnl ************************************************************
3203 dnl enable SSPI support
3204 dnl
3205 AC_MSG_CHECKING([whether to enable SSPI support (Windows native builds only)])
3206 AC_ARG_ENABLE(sspi,
3207 AC_HELP_STRING([--enable-sspi],[Enable SSPI])
3208 AC_HELP_STRING([--disable-sspi],[Disable SSPI]),
3209 [ case "$enableval" in
3210   yes)
3211        if test "$ac_cv_native_windows" = "yes"; then
3212          AC_MSG_RESULT(yes)
3213          AC_DEFINE(USE_WINDOWS_SSPI, 1, [to enable SSPI support])
3214          AC_SUBST(USE_WINDOWS_SSPI, [1])
3215          curl_sspi_msg="enabled"
3216        else
3217          AC_MSG_RESULT(no)
3218          AC_MSG_WARN([--enable-sspi Ignored. Only supported on native Windows builds.])
3219        fi
3220        ;;
3221   *)
3222        if test "x$WINSSL_ENABLED" = "x1"; then
3223          # --with-winssl implies --enable-sspi
3224          AC_MSG_RESULT(yes)
3225        else
3226          AC_MSG_RESULT(no)
3227        fi
3228        ;;
3229   esac ],
3230        if test "x$WINSSL_ENABLED" = "x1"; then
3231          # --with-winssl implies --enable-sspi
3232          AC_MSG_RESULT(yes)
3233        else
3234          AC_MSG_RESULT(no)
3235        fi
3236 )
3237
3238 dnl ************************************************************
3239 dnl disable cryptographic authentication
3240 dnl
3241 AC_MSG_CHECKING([whether to enable cryptographic authentication methods])
3242 AC_ARG_ENABLE(crypto-auth,
3243 AC_HELP_STRING([--enable-crypto-auth],[Enable cryptographic authentication])
3244 AC_HELP_STRING([--disable-crypto-auth],[Disable cryptographic authentication]),
3245 [ case "$enableval" in
3246   no)
3247        AC_MSG_RESULT(no)
3248        AC_DEFINE(CURL_DISABLE_CRYPTO_AUTH, 1, [to disable cryptographic authentication])
3249        ;;
3250   *)   AC_MSG_RESULT(yes)
3251        ;;
3252   esac ],
3253        AC_MSG_RESULT(yes)
3254 )
3255
3256 CURL_CHECK_OPTION_NTLM_WB
3257
3258 CURL_CHECK_NTLM_WB
3259
3260 dnl ************************************************************
3261 dnl disable TLS-SRP authentication
3262 dnl
3263 AC_MSG_CHECKING([whether to enable TLS-SRP authentication])
3264 AC_ARG_ENABLE(tls-srp,
3265 AC_HELP_STRING([--enable-tls-srp],[Enable TLS-SRP authentication])
3266 AC_HELP_STRING([--disable-tls-srp],[Disable TLS-SRP authentication]),
3267 [ case "$enableval" in
3268   no)
3269        AC_MSG_RESULT(no)
3270        AC_DEFINE(CURL_DISABLE_TLS_SRP, 1, [to disable TLS-SRP authentication])
3271        want_tls_srp=no
3272        ;;
3273   *)   AC_MSG_RESULT(yes)
3274        want_tls_srp=yes
3275        ;;
3276   esac ],
3277        AC_MSG_RESULT(yes)
3278        want_tls_srp=yes
3279 )
3280
3281 if test "$want_tls_srp" = "yes" && ( test "x$HAVE_GNUTLS_SRP" = "x1" || test "x$HAVE_SSLEAY_SRP" = "x1") ; then
3282    AC_DEFINE(USE_TLS_SRP, 1, [Use TLS-SRP authentication])
3283    USE_TLS_SRP=1
3284    curl_tls_srp_msg="enabled"
3285 fi
3286
3287 dnl ************************************************************
3288 dnl disable cookies support
3289 dnl
3290 AC_MSG_CHECKING([whether to enable support for cookies])
3291 AC_ARG_ENABLE(cookies,
3292 AC_HELP_STRING([--enable-cookies],[Enable cookies support])
3293 AC_HELP_STRING([--disable-cookies],[Disable cookies support]),
3294 [ case "$enableval" in
3295   no)
3296        AC_MSG_RESULT(no)
3297        AC_DEFINE(CURL_DISABLE_COOKIES, 1, [to disable cookies support])
3298        ;;
3299   *)   AC_MSG_RESULT(yes)
3300        ;;
3301   esac ],
3302        AC_MSG_RESULT(yes)
3303 )
3304
3305 dnl ************************************************************
3306 dnl hiding of library internal symbols
3307 dnl
3308 CURL_CONFIGURE_SYMBOL_HIDING
3309
3310 dnl ************************************************************
3311 dnl enforce SONAME bump
3312 dnl
3313
3314 AC_MSG_CHECKING([whether to enforce SONAME bump])
3315 AC_ARG_ENABLE(soname-bump,
3316 AC_HELP_STRING([--enable-soname-bump],[Enable enforced SONAME bump])
3317 AC_HELP_STRING([--disable-soname-bump],[Disable enforced SONAME bump]),
3318 [ case "$enableval" in
3319   yes)   AC_MSG_RESULT(yes)
3320          soname_bump=yes
3321          ;;
3322   *)
3323          AC_MSG_RESULT(no)
3324          ;;
3325   esac ],
3326         AC_MSG_RESULT($soname_bump)
3327 )
3328 AM_CONDITIONAL(SONAME_BUMP, test x$soname_bump = xyes)
3329
3330 dnl
3331 dnl All the library dependencies put into $LIB apply to libcurl only.
3332 dnl
3333 LIBCURL_LIBS=$LIBS
3334
3335 AC_SUBST(LIBCURL_LIBS)
3336 AC_SUBST(CURL_NETWORK_LIBS)
3337 AC_SUBST(CURL_NETWORK_AND_TIME_LIBS)
3338
3339 dnl BLANK_AT_MAKETIME may be used in our Makefile.am files to blank
3340 dnl LIBS variable used in generated makefile at makefile processing
3341 dnl time. Doing this functionally prevents LIBS from being used for
3342 dnl all link targets in given makefile.
3343 BLANK_AT_MAKETIME=
3344 AC_SUBST(BLANK_AT_MAKETIME)
3345
3346 AM_CONDITIONAL(CROSSCOMPILING, test x$cross_compiling = xyes)
3347
3348 dnl yes or no
3349 ENABLE_SHARED="$enable_shared"
3350 AC_SUBST(ENABLE_SHARED)
3351
3352 dnl to let curl-config output the static libraries correctly
3353 ENABLE_STATIC="$enable_static"
3354 AC_SUBST(ENABLE_STATIC)
3355
3356
3357 dnl
3358 dnl For keeping supported features and protocols also in pkg-config file
3359 dnl since it is more cross-compile friendly than curl-config
3360 dnl
3361
3362 if test "x$USE_SSLEAY" = "x1"; then
3363   SUPPORT_FEATURES="$SUPPORT_FEATURES SSL"
3364 elif test -n "$SSL_ENABLED"; then
3365   SUPPORT_FEATURES="$SUPPORT_FEATURES SSL"
3366 fi
3367 if test "x$IPV6_ENABLED" = "x1"; then
3368   SUPPORT_FEATURES="$SUPPORT_FEATURES IPv6"
3369 fi
3370 if test "x$HAVE_LIBZ" = "x1"; then
3371   SUPPORT_FEATURES="$SUPPORT_FEATURES libz"
3372 fi
3373 if test "x$USE_ARES" = "x1" -o "x$USE_THREADS_POSIX" = "x1"; then
3374   SUPPORT_FEATURES="$SUPPORT_FEATURES AsynchDNS"
3375 fi
3376 if test "x$IDN_ENABLED" = "x1"; then
3377   SUPPORT_FEATURES="$SUPPORT_FEATURES IDN"
3378 fi
3379 if test "x$USE_WINDOWS_SSPI" = "x1"; then
3380   SUPPORT_FEATURES="$SUPPORT_FEATURES SSPI"
3381 fi
3382 if test "x$CURL_DISABLE_HTTP" != "x1"; then
3383   if test "x$USE_SSLEAY" = "x1" -o "x$USE_WINDOWS_SSPI" = "x1" \
3384       -o "x$GNUTLS_ENABLED" = "x1" -o "x$NSS_ENABLED" = "x1" \
3385       -o "x$DARWINSSL_ENABLED" = "x1"; then
3386     SUPPORT_FEATURES="$SUPPORT_FEATURES NTLM"
3387     if test "x$NTLM_WB_ENABLED" = "x1"; then
3388       SUPPORT_FEATURES="$SUPPORT_FEATURES NTLM_WB"
3389     fi
3390   fi
3391 fi
3392 if test "x$USE_TLS_SRP" = "x1"; then
3393   SUPPORT_FEATURES="$SUPPORT_FEATURES TLS-SRP"
3394 fi
3395
3396 if test "x$USE_NGHTTP2" = "x1"; then
3397   SUPPORT_FEATURES="$SUPPORT_FEATURES HTTP2"
3398 fi
3399
3400 AC_SUBST(SUPPORT_FEATURES)
3401
3402 dnl For supported protocols in pkg-config file
3403 if test "x$CURL_DISABLE_HTTP" != "x1"; then
3404   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS HTTP"
3405   if test "x$SSL_ENABLED" = "x1"; then
3406     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS HTTPS"
3407   fi
3408 fi
3409 if test "x$CURL_DISABLE_FTP" != "x1"; then
3410   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS FTP"
3411   if test "x$SSL_ENABLED" = "x1"; then
3412     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS FTPS"
3413   fi
3414 fi
3415 if test "x$CURL_DISABLE_FILE" != "x1"; then
3416   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS FILE"
3417 fi
3418 if test "x$CURL_DISABLE_TELNET" != "x1"; then
3419   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS TELNET"
3420 fi
3421 if test "x$CURL_DISABLE_LDAP" != "x1"; then
3422   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS LDAP"
3423   if test "x$CURL_DISABLE_LDAPS" != "x1"; then
3424     if (test "x$USE_OPENLDAP" = "x1" && test "x$SSL_ENABLED" = "x1") ||
3425       (test "x$USE_OPENLDAP" != "x1"  && test "x$HAVE_LDAP_SSL" = "x1"); then
3426       SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS LDAPS"
3427     fi
3428   fi
3429 fi
3430 if test "x$CURL_DISABLE_DICT" != "x1"; then
3431   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS DICT"
3432 fi
3433 if test "x$CURL_DISABLE_TFTP" != "x1"; then
3434   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS TFTP"
3435 fi
3436 if test "x$CURL_DISABLE_GOPHER" != "x1"; then
3437   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS GOPHER"
3438 fi
3439 if test "x$CURL_DISABLE_POP3" != "x1"; then
3440   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS POP3"
3441   if test "x$SSL_ENABLED" = "x1"; then
3442     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS POP3S"
3443   fi
3444 fi
3445 if test "x$CURL_DISABLE_IMAP" != "x1"; then
3446   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS IMAP"
3447   if test "x$SSL_ENABLED" = "x1"; then
3448     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS IMAPS"
3449   fi
3450 fi
3451 if test "x$CURL_DISABLE_SMTP" != "x1"; then
3452   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS SMTP"
3453   if test "x$SSL_ENABLED" = "x1"; then
3454     SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS SMTPS"
3455   fi
3456 fi
3457 if test "x$USE_LIBSSH2" = "x1"; then
3458   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS SCP"
3459   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS SFTP"
3460 fi
3461 if test "x$CURL_DISABLE_RTSP" != "x1"; then
3462   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS RTSP"
3463 fi
3464 if test "x$USE_LIBRTMP" = "x1"; then
3465   SUPPORT_PROTOCOLS="$SUPPORT_PROTOCOLS RTMP"
3466 fi
3467
3468 dnl replace spaces with newlines
3469 dnl sort the lines
3470 dnl replace the newlines back to spaces
3471 SUPPORT_PROTOCOLS=`echo $SUPPORT_PROTOCOLS | tr ' ' '\012' | sort | tr '\012' ' '`
3472
3473 AC_SUBST(SUPPORT_PROTOCOLS)
3474
3475 dnl squeeze whitespace out of some variables
3476
3477 squeeze CFLAGS
3478 squeeze CPPFLAGS
3479 squeeze DEFS
3480 squeeze LDFLAGS
3481 squeeze LIBS
3482
3483 squeeze LIBCURL_LIBS
3484 squeeze CURL_NETWORK_LIBS
3485 squeeze CURL_NETWORK_AND_TIME_LIBS
3486
3487 squeeze SUPPORT_FEATURES
3488 squeeze SUPPORT_PROTOCOLS
3489
3490 XC_CHECK_BUILD_FLAGS
3491
3492 if test "x$want_curldebug_assumed" = "xyes" &&
3493   test "x$want_curldebug" = "xyes" && test "x$USE_ARES" = "x1"; then
3494   ac_configure_args="$ac_configure_args --enable-curldebug"
3495 fi
3496
3497 AC_CONFIG_FILES([Makefile \
3498            docs/Makefile \
3499            docs/examples/Makefile \
3500            docs/libcurl/Makefile \
3501            include/Makefile \
3502            include/curl/Makefile \
3503            src/Makefile \
3504            lib/Makefile \
3505            lib/libcurl.vers \
3506            tests/Makefile \
3507            tests/certs/Makefile \
3508            tests/certs/scripts/Makefile \
3509            tests/data/Makefile \
3510            tests/server/Makefile \
3511            tests/libtest/Makefile \
3512            tests/unit/Makefile \
3513            packages/Makefile \
3514            packages/Win32/Makefile \
3515            packages/Win32/cygwin/Makefile \
3516            packages/Linux/Makefile \
3517            packages/Linux/RPM/Makefile \
3518            packages/Linux/RPM/curl.spec \
3519            packages/Linux/RPM/curl-ssl.spec \
3520            packages/Solaris/Makefile \
3521            packages/EPM/curl.list \
3522            packages/EPM/Makefile \
3523            packages/vms/Makefile \
3524            packages/AIX/Makefile \
3525            packages/AIX/RPM/Makefile \
3526            packages/AIX/RPM/curl.spec \
3527            curl-config \
3528            libcurl.pc
3529 ])
3530 AC_OUTPUT
3531
3532 CURL_GENERATE_CONFIGUREHELP_PM
3533
3534 XC_AMEND_DISTCLEAN([lib src tests/unit tests/server tests/libtest docs/examples])
3535
3536 AC_MSG_NOTICE([Configured to build curl/libcurl:
3537
3538   curl version:     ${CURLVERSION}
3539   Host setup:       ${host}
3540   Install prefix:   ${prefix}
3541   Compiler:         ${CC}
3542   SSL support:      ${curl_ssl_msg}
3543   SSH support:      ${curl_ssh_msg}
3544   zlib support:     ${curl_zlib_msg}
3545   GSSAPI support:   ${curl_gss_msg}
3546   SPNEGO support:   ${curl_spnego_msg}
3547   TLS-SRP support:  ${curl_tls_srp_msg}
3548   resolver:         ${curl_res_msg}
3549   ipv6 support:     ${curl_ipv6_msg}
3550   IDN support:      ${curl_idn_msg}
3551   Build libcurl:    Shared=${enable_shared}, Static=${enable_static}
3552   Built-in manual:  ${curl_manual_msg}
3553   --libcurl option: ${curl_libcurl_msg}
3554   Verbose errors:   ${curl_verbose_msg}
3555   SSPI support:     ${curl_sspi_msg}
3556   ca cert bundle:   ${ca}
3557   ca cert path:     ${capath}
3558   LDAP support:     ${curl_ldap_msg}
3559   LDAPS support:    ${curl_ldaps_msg}
3560   RTSP support:     ${curl_rtsp_msg}
3561   RTMP support:     ${curl_rtmp_msg}
3562   metalink support: ${curl_mtlnk_msg}
3563   HTTP2 support:    ${curl_h2_msg}
3564   Protocols:        ${SUPPORT_PROTOCOLS}
3565 ])
3566
3567 if test "x$soname_bump" = "xyes"; then
3568
3569 cat <<EOM
3570   SONAME bump:     yes - WARNING: this library will be built with the SONAME
3571                    number bumped due to (a detected) ABI breakage.
3572                    See lib/README.curl_off_t for details on this.
3573 EOM
3574
3575 fi
3576