CMakeLists.txt

   1 # cURL/libcurl CMake script
   2 # by Tetetest and Sukender (Benoit Neil)
   3
   4 # TODO:
   5 # The output .so file lacks the soname number which we currently have within the lib/Makefile.am file
   6 # Add full (4 or 5 libs) SSL support
   7 # Add INSTALL target (EXTRA_DIST variables in Makefile.am may be moved to Makefile.inc so that CMake/CPack is aware of what's to include).
   8 # Add CTests(?)
   9 # Check on all possible platforms
  10 # Test with as many configurations possible (With or without any option)
  11 # Create scripts that help keeping the CMake build system up to date (to reduce maintenance). According to Tetetest:
  12 #  - lists of headers that 'configure' checks for;
  13 #  - curl-specific tests (the ones that are in m4/curl-*.m4 files);
  14 #  - (most obvious thing:) curl version numbers.
  15 # Add documentation subproject
  16 #
  17 # To check:
  18 # (From Daniel Stenberg) The cmake build selected to run gcc with -fPIC on my box while the plain configure script did not.
  19 # (From Daniel Stenberg) The gcc command line use neither -g nor any -O options. As a developer, I also treasure our configure scripts's --enable-debug option that sets a long range of "picky" compiler options.
  20 cmake_minimum_required(VERSION 2.6.2 FATAL_ERROR)
  21 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake;${CMAKE_MODULE_PATH}")
  22 include(Utilities)
  23
  24 project( CURL C )
  25
  26
  27 file (READ ${CURL_SOURCE_DIR}/include/curl/curlver.h CURL_VERSION_H_CONTENTS)
  28 string (REGEX MATCH "LIBCURL_VERSION_MAJOR[ \t]+([0-9]+)"
  29   LIBCURL_VERSION_MJ ${CURL_VERSION_H_CONTENTS})
  30 string (REGEX MATCH "([0-9]+)"
  31   LIBCURL_VERSION_MJ ${LIBCURL_VERSION_MJ})
  32 string (REGEX MATCH
  33   "LIBCURL_VERSION_MINOR[ \t]+([0-9]+)"
  34   LIBCURL_VERSION_MI ${CURL_VERSION_H_CONTENTS})
  35 string (REGEX MATCH "([0-9]+)" LIBCURL_VERSION_MI ${LIBCURL_VERSION_MI})
  36 string (REGEX MATCH
  37   "LIBCURL_VERSION_PATCH[ \t]+([0-9]+)"
  38   LIBCURL_VERSION_PT ${CURL_VERSION_H_CONTENTS})
  39 string (REGEX MATCH "([0-9]+)" LIBCURL_VERSION_PT ${LIBCURL_VERSION_PT})
  40 set (CURL_MAJOR_VERSION ${LIBCURL_VERSION_MJ})
  41 set (CURL_MINOR_VERSION ${LIBCURL_VERSION_MI})
  42 set (CURL_PATCH_VERSION ${LIBCURL_VERSION_PT})
  43
  44 include_regular_expression("^.*$")    # Sukender: Is it necessary?
  45
  46 # Setup package meta-data
  47 # SET(PACKAGE "curl")
  48 set(CURL_VERSION ${CURL_MAJOR_VERSION}.${CURL_MINOR_VERSION}.${CURL_PATCH_VERSION})
  49 message(STATUS "curl version=[${CURL_VERSION}]")
  50 # SET(PACKAGE_TARNAME "curl")
  51 # SET(PACKAGE_NAME "curl")
  52 # SET(PACKAGE_VERSION "-")
  53 # SET(PACKAGE_STRING "curl-")
  54 # SET(PACKAGE_BUGREPORT "a suitable curl mailing list => http://curl.haxx.se/mail/")
  55 set(OPERATING_SYSTEM "${CMAKE_SYSTEM_NAME}")
  56 set(OS "\"${CMAKE_SYSTEM_NAME}\"")
  57
  58 include_directories(${PROJECT_BINARY_DIR}/include/curl)
  59 include_directories( ${CURL_SOURCE_DIR}/include )
  60
  61 if(WIN32)
  62   set(NATIVE_WINDOWS ON)
  63 endif()
  64
  65 option(BUILD_CURL_EXE "Set to ON to build cURL executable." ON)
  66 option(BUILD_CURL_TESTS "Set to ON to build cURL tests." ON)
  67 option(CURL_STATICLIB "Set to ON to build libcurl with static linking." OFF)
  68 option(CURL_USE_ARES "Set to ON to enable c-ares support" OFF)
  69 # initialize CURL_LIBS
  70 set(CURL_LIBS "")
  71
  72 if(CURL_USE_ARES)
  73   set(USE_ARES ${CURL_USE_ARES})
  74   find_package(CARES REQUIRED)
  75   list(APPEND CURL_LIBS ${CARES_LIBRARY} )
  76   set(CURL_LIBS ${CURL_LIBS} ${CARES_LIBRARY})
  77 endif()
  78
  79 option(BUILD_DASHBOARD_REPORTS "Set to ON to activate reporting of cURL builds here http://www.cdash.org/CDashPublic/index.php?project=CURL" OFF)
  80 if(BUILD_DASHBOARD_REPORTS)
  81   #INCLUDE(Dart)
  82   include(CTest)
  83 endif(BUILD_DASHBOARD_REPORTS)
  84
  85 if(MSVC)
  86   option(BUILD_RELEASE_DEBUG_DIRS "Set OFF to build each configuration to a separate directory" OFF)
  87   mark_as_advanced(BUILD_RELEASE_DEBUG_DIRS)
  88 endif()
  89
  90 option(CURL_HIDDEN_SYMBOLS "Set to ON to hide libcurl internal symbols (=hide all symbols that aren't officially external)." ON)
  91 mark_as_advanced(CURL_HIDDEN_SYMBOLS)
  92
  93 # IF(WIN32)
  94 # OPTION(CURL_WINDOWS_SSPI "Use windows libraries to allow NTLM authentication without openssl" ON)
  95 # MARK_AS_ADVANCED(CURL_WINDOWS_SSPI)
  96 # ENDIF()
  97
  98 option(HTTP_ONLY "disables all protocols except HTTP (This overrides all CURL_DISABLE_* options)" OFF)
  99 mark_as_advanced(HTTP_ONLY)
 100 option(CURL_DISABLE_FTP "disables FTP" OFF)
 101 mark_as_advanced(CURL_DISABLE_FTP)
 102 option(CURL_DISABLE_LDAP "disables LDAP" OFF)
 103 mark_as_advanced(CURL_DISABLE_LDAP)
 104 option(CURL_DISABLE_TELNET "disables Telnet" OFF)
 105 mark_as_advanced(CURL_DISABLE_TELNET)
 106 option(CURL_DISABLE_DICT "disables DICT" OFF)
 107 mark_as_advanced(CURL_DISABLE_DICT)
 108 option(CURL_DISABLE_FILE "disables FILE" OFF)
 109 mark_as_advanced(CURL_DISABLE_FILE)
 110 option(CURL_DISABLE_TFTP "disables TFTP" OFF)
 111 mark_as_advanced(CURL_DISABLE_TFTP)
 112 option(CURL_DISABLE_HTTP "disables HTTP" OFF)
 113 mark_as_advanced(CURL_DISABLE_HTTP)
 114
 115 option(CURL_DISABLE_LDAPS "to disable LDAPS" OFF)
 116 mark_as_advanced(CURL_DISABLE_LDAPS)
 117 if(WIN32)
 118   set(CURL_DEFAULT_DISABLE_LDAP OFF)
 119   # some windows compilers do not have wldap32
 120   if( NOT HAVE_WLDAP32)
 121     set(CURL_DISABLE_LDAP ON CACHE BOOL "" FORCE)
 122     message(STATUS "wldap32 not found CURL_DISABLE_LDAP set ON")
 123     option(CURL_LDAP_WIN "Use W$ LDAP implementation" OFF)
 124   else()
 125     option(CURL_LDAP_WIN "Use W$ LDAP implementation" ON)
 126   endif()
 127   mark_as_advanced(CURL_LDAP_WIN)
 128   set(CURL_LDAP_HYBRID OFF)
 129 else()
 130   option(CURL_LDAP_HYBRID "W$ LDAP with non-W$ compiler" OFF)
 131   mark_as_advanced(CURL_LDAP_HYBRID)
 132   set(CURL_LDAP_WIN OFF)
 133 endif()
 134
 135 if(HTTP_ONLY)
 136   set(CURL_DISABLE_FTP ON)
 137   set(CURL_DISABLE_LDAP ON)
 138   set(CURL_DISABLE_TELNET ON)
 139   set(CURL_DISABLE_DICT ON)
 140   set(CURL_DISABLE_FILE ON)
 141   set(CURL_DISABLE_TFTP ON)
 142 endif()
 143
 144 option(CURL_DISABLE_COOKIES "to disable cookies support" OFF)
 145 mark_as_advanced(CURL_DISABLE_COOKIES)
 146
 147 option(CURL_DISABLE_CRYPTO_AUTH "to disable cryptographic authentication" OFF)
 148 mark_as_advanced(CURL_DISABLE_CRYPTO_AUTH)
 149 option(CURL_DISABLE_VERBOSE_STRINGS "to disable verbose strings" OFF)
 150 mark_as_advanced(CURL_DISABLE_VERBOSE_STRINGS)
 151 option(DISABLED_THREADSAFE "Set to explicitly specify we don't want to use thread-safe functions" OFF)
 152 mark_as_advanced(DISABLED_THREADSAFE)
 153 option(ENABLE_IPV6 "Define if you want to enable IPv6 support" OFF)
 154 mark_as_advanced(ENABLE_IPV6)
 155
 156 if(WIN32)
 157   list_spaces_append_once(CMAKE_C_STANDARD_LIBRARIES wsock32.lib ws2_32.lib)  # bufferoverflowu.lib
 158   if(CURL_DISABLE_LDAP)
 159     # Remove wldap32.lib from space-separated list
 160     string(REPLACE " " ";" _LIST ${CMAKE_C_STANDARD_LIBRARIES})
 161     list(REMOVE_ITEM _LIST "wldap32.lib")
 162     to_list_spaces(_LIST CMAKE_C_STANDARD_LIBRARIES)
 163   else()
 164     # Append wldap32.lib
 165     list_spaces_append_once(CMAKE_C_STANDARD_LIBRARIES wldap32.lib)
 166   endif()
 167   set(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}"   CACHE STRING "" FORCE)
 168 endif()
 169
 170
 171 # We need ansi c-flags, especially on HP
 172 set(CMAKE_C_FLAGS "${CMAKE_ANSI_CFLAGS} ${CMAKE_C_FLAGS}")
 173 set(CMAKE_REQUIRED_FLAGS ${CMAKE_ANSI_CFLAGS})
 174
 175 # Disable warnings on Borland to avoid changing 3rd party code.
 176 if(BORLAND)
 177   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -w-")
 178 endif(BORLAND)
 179
 180 # If we are on AIX, do the _ALL_SOURCE magic
 181 if(${CMAKE_SYSTEM_NAME} MATCHES AIX)
 182   set(_ALL_SOURCE 1)
 183 endif(${CMAKE_SYSTEM_NAME} MATCHES AIX)
 184
 185 # Include all the necessary files for macros
 186 include (CheckFunctionExists)
 187 include (CheckIncludeFile)
 188 include (CheckIncludeFiles)
 189 include (CheckLibraryExists)
 190 include (CheckSymbolExists)
 191 # if crosscompiling is on, the CHECK_TYPE_SIZE macro coming with cmake uses
 192 # TRY_COMPILE instead of TRY_RUN which makes crosscompiling easier, Alex
 193 if(CMAKE_CROSSCOMPILING)
 194   include ("${CMAKE_MODULE_PATH}/CheckTypeSize.cmake")
 195 else(CMAKE_CROSSCOMPILING)
 196   include (CheckTypeSize)
 197 endif(CMAKE_CROSSCOMPILING)
 198
 199 # On windows preload settings
 200 if(WIN32)
 201   include(${CMAKE_CURRENT_SOURCE_DIR}/CMake/Platforms/WindowsCache.cmake)
 202 endif(WIN32)
 203
 204 # This macro checks if the symbol exists in the library and if it
 205 # does, it appends library to the list.
 206 macro(CHECK_LIBRARY_EXISTS_CONCAT LIBRARY SYMBOL VARIABLE)
 207   check_library_exists("${LIBRARY};${CURL_LIBS}" ${SYMBOL} ""
 208     ${VARIABLE})
 209   if(${VARIABLE})
 210     set(CURL_LIBS ${CURL_LIBS} ${LIBRARY})
 211   endif(${VARIABLE})
 212 endmacro(CHECK_LIBRARY_EXISTS_CONCAT)
 213
 214 # Check for all needed libraries
 215 check_library_exists_concat("dl"     dlopen       HAVE_LIBDL)
 216 check_library_exists_concat("socket" connect      HAVE_LIBSOCKET)
 217 check_library_exists("c" gethostbyname "" NOT_NEED_LIBNSL)
 218
 219 # Yellowtab Zeta needs different libraries than BeOS 5.
 220 if(BEOS)
 221   set(NOT_NEED_LIBNSL 1)
 222   check_library_exists_concat("bind" gethostbyname HAVE_LIBBIND)
 223   check_library_exists_concat("bnetapi" closesocket HAVE_LIBBNETAPI)
 224 endif(BEOS)
 225
 226 if(NOT NOT_NEED_LIBNSL)
 227   check_library_exists_concat("nsl"    gethostbyname  HAVE_LIBNSL)
 228 endif(NOT NOT_NEED_LIBNSL)
 229
 230 check_library_exists_concat("ws2_32" getch        HAVE_LIBWS2_32)
 231 check_library_exists_concat("winmm"  getch        HAVE_LIBWINMM)
 232 check_library_exists("wldap32" cldap_open "" HAVE_WLDAP32)
 233
 234 # IF(NOT CURL_SPECIAL_LIBZ)
 235 #  CHECK_LIBRARY_EXISTS_CONCAT("z"      inflateEnd   HAVE_LIBZ)
 236 # ENDIF(NOT CURL_SPECIAL_LIBZ)
 237
 238 option(CMAKE_USE_OPENSSL "Use OpenSSL code. Experimental" ON)
 239 mark_as_advanced(CMAKE_USE_OPENSSL)
 240 if(CMAKE_USE_OPENSSL)
 241   if(WIN32)
 242     find_package(OpenSSL)
 243     if(OPENSSL_FOUND)
 244       set(USE_SSLEAY TRUE)
 245       set(USE_OPENSSL TRUE)
 246       list(APPEND CURL_LIBS ${OPENSSL_LIBRARIES} )
 247     else()
 248       set(CMAKE_USE_OPENSSL FALSE)
 249       message(STATUS "OpenSSL NOT Found, disabling CMAKE_USE_OPENSSL")
 250     endif()
 251   else(WIN32)
 252     check_library_exists_concat("crypto" CRYPTO_lock  HAVE_LIBCRYPTO)
 253     check_library_exists_concat("ssl"    SSL_connect  HAVE_LIBSSL)
 254   endif(WIN32)
 255 endif(CMAKE_USE_OPENSSL)
 256
 257 # Check for idn
 258 check_library_exists_concat("idn" idna_to_ascii_lz HAVE_LIBIDN)
 259
 260 # Check for LDAP
 261 check_library_exists_concat("ldap" ldap_init HAVE_LIBLDAP)
 262 # if(NOT HAVE_LIBLDAP)
 263 # SET(CURL_DISABLE_LDAP ON)
 264 # endif(NOT HAVE_LIBLDAP)
 265
 266 # Check for symbol dlopen (same as HAVE_LIBDL)
 267 check_library_exists("${CURL_LIBS}" dlopen "" HAVE_DLOPEN)
 268
 269 # For other tests to use the same libraries
 270 set(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBS})
 271
 272 option(CURL_ZLIB "Set to ON to enable building cURL with zlib support." ON)
 273 set(HAVE_LIBZ OFF)
 274 set(HAVE_ZLIB_H OFF)
 275 set(HAVE_ZLIB OFF)
 276 if(CURL_ZLIB)  # AND CURL_CONFIG_HAS_BEEN_RUN_BEFORE
 277   find_package(ZLIB QUIET)
 278   if(ZLIB_FOUND)
 279     set(HAVE_ZLIB_H ON)
 280     set(HAVE_ZLIB ON)
 281     set(HAVE_LIBZ ON)
 282   endif()
 283 endif()
 284
 285 # If we have features.h, then do the _BSD_SOURCE magic
 286 check_include_file("features.h"       HAVE_FEATURES_H)
 287
 288 # Check if header file exists and add it to the list.
 289 macro(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 290   check_include_files("${CURL_INCLUDES};${FILE}" ${VARIABLE})
 291   if(${VARIABLE})
 292     set(CURL_INCLUDES ${CURL_INCLUDES} ${FILE})
 293     set(CURL_TEST_DEFINES "${CURL_TEST_DEFINES} -D${VARIABLE}")
 294   endif(${VARIABLE})
 295 endmacro(CHECK_INCLUDE_FILE_CONCAT)
 296
 297
 298 # Check for header files
 299 if(NOT UNIX)
 300   check_include_file_concat("ws2tcpip.h"     HAVE_WS2TCPIP_H)
 301   check_include_file_concat("winsock2.h"     HAVE_WINSOCK2_H)
 302 endif(NOT UNIX)
 303 check_include_file_concat("stdio.h"          HAVE_STDIO_H)
 304 if(NOT UNIX)
 305   check_include_file_concat("windows.h"      HAVE_WINDOWS_H)
 306   check_include_file_concat("winsock.h"      HAVE_WINSOCK_H)
 307 endif(NOT UNIX)
 308
 309 check_include_file_concat("inttypes.h"       HAVE_INTTYPES_H)
 310 check_include_file_concat("sys/filio.h"      HAVE_SYS_FILIO_H)
 311 check_include_file_concat("sys/ioctl.h"      HAVE_SYS_IOCTL_H)
 312 check_include_file_concat("sys/param.h"      HAVE_SYS_PARAM_H)
 313 check_include_file_concat("sys/poll.h"       HAVE_SYS_POLL_H)
 314 check_include_file_concat("sys/resource.h"   HAVE_SYS_RESOURCE_H)
 315 check_include_file_concat("sys/select.h"     HAVE_SYS_SELECT_H)
 316 check_include_file_concat("sys/socket.h"     HAVE_SYS_SOCKET_H)
 317 check_include_file_concat("sys/sockio.h"     HAVE_SYS_SOCKIO_H)
 318 check_include_file_concat("sys/stat.h"       HAVE_SYS_STAT_H)
 319 check_include_file_concat("sys/time.h"       HAVE_SYS_TIME_H)
 320 check_include_file_concat("sys/types.h"      HAVE_SYS_TYPES_H)
 321 check_include_file_concat("sys/uio.h"        HAVE_SYS_UIO_H)
 322 check_include_file_concat("sys/un.h"         HAVE_SYS_UN_H)
 323 check_include_file_concat("sys/utime.h"      HAVE_SYS_UTIME_H)
 324 check_include_file_concat("alloca.h"         HAVE_ALLOCA_H)
 325 check_include_file_concat("arpa/inet.h"      HAVE_ARPA_INET_H)
 326 check_include_file_concat("arpa/tftp.h"      HAVE_ARPA_TFTP_H)
 327 check_include_file_concat("assert.h"         HAVE_ASSERT_H)
 328 check_include_file_concat("crypto.h"         HAVE_CRYPTO_H)
 329 check_include_file_concat("des.h"            HAVE_DES_H)
 330 check_include_file_concat("err.h"            HAVE_ERR_H)
 331 check_include_file_concat("errno.h"          HAVE_ERRNO_H)
 332 check_include_file_concat("fcntl.h"          HAVE_FCNTL_H)
 333 check_include_file_concat("gssapi/gssapi.h"  HAVE_GSSAPI_GSSAPI_H)
 334 check_include_file_concat("gssapi/gssapi_generic.h" HAVE_GSSAPI_GSSAPI_GENERIC_H)
 335 check_include_file_concat("gssapi/gssapi_krb5.h" HAVE_GSSAPI_GSSAPI_KRB5_H)
 336 check_include_file_concat("idn-free.h"       HAVE_IDN_FREE_H)
 337 check_include_file_concat("ifaddrs.h"        HAVE_IFADDRS_H)
 338 check_include_file_concat("io.h"             HAVE_IO_H)
 339 check_include_file_concat("krb.h"            HAVE_KRB_H)
 340 check_include_file_concat("libgen.h"         HAVE_LIBGEN_H)
 341 check_include_file_concat("libssh2.h"        HAVE_LIBSSH2_H)
 342 check_include_file_concat("limits.h"         HAVE_LIMITS_H)
 343 check_include_file_concat("locale.h"         HAVE_LOCALE_H)
 344 check_include_file_concat("net/if.h"         HAVE_NET_IF_H)
 345 check_include_file_concat("netdb.h"          HAVE_NETDB_H)
 346 check_include_file_concat("netinet/in.h"     HAVE_NETINET_IN_H)
 347 check_include_file_concat("netinet/tcp.h"    HAVE_NETINET_TCP_H)
 348 check_include_file_concat("openssl/crypto.h" HAVE_OPENSSL_CRYPTO_H)
 349 check_include_file_concat("openssl/engine.h" HAVE_OPENSSL_ENGINE_H)
 350 check_include_file_concat("openssl/err.h"    HAVE_OPENSSL_ERR_H)
 351 check_include_file_concat("openssl/pem.h"    HAVE_OPENSSL_PEM_H)
 352 check_include_file_concat("openssl/pkcs12.h" HAVE_OPENSSL_PKCS12_H)
 353 check_include_file_concat("openssl/rsa.h"    HAVE_OPENSSL_RSA_H)
 354 check_include_file_concat("openssl/ssl.h"    HAVE_OPENSSL_SSL_H)
 355 check_include_file_concat("openssl/x509.h"   HAVE_OPENSSL_X509_H)
 356 check_include_file_concat("pem.h"            HAVE_PEM_H)
 357 check_include_file_concat("poll.h"           HAVE_POLL_H)
 358 check_include_file_concat("pwd.h"            HAVE_PWD_H)
 359 check_include_file_concat("rsa.h"            HAVE_RSA_H)
 360 check_include_file_concat("setjmp.h"         HAVE_SETJMP_H)
 361 check_include_file_concat("sgtty.h"          HAVE_SGTTY_H)
 362 check_include_file_concat("signal.h"         HAVE_SIGNAL_H)
 363 check_include_file_concat("ssl.h"            HAVE_SSL_H)
 364 check_include_file_concat("stdbool.h"        HAVE_STDBOOL_H)
 365 check_include_file_concat("stdint.h"         HAVE_STDINT_H)
 366 check_include_file_concat("stdio.h"          HAVE_STDIO_H)
 367 check_include_file_concat("stdlib.h"         HAVE_STDLIB_H)
 368 check_include_file_concat("string.h"         HAVE_STRING_H)
 369 check_include_file_concat("strings.h"        HAVE_STRINGS_H)
 370 check_include_file_concat("stropts.h"        HAVE_STROPTS_H)
 371 check_include_file_concat("termio.h"         HAVE_TERMIO_H)
 372 check_include_file_concat("termios.h"        HAVE_TERMIOS_H)
 373 check_include_file_concat("time.h"           HAVE_TIME_H)
 374 check_include_file_concat("tld.h"            HAVE_TLD_H)
 375 check_include_file_concat("unistd.h"         HAVE_UNISTD_H)
 376 check_include_file_concat("utime.h"          HAVE_UTIME_H)
 377 check_include_file_concat("x509.h"           HAVE_X509_H)
 378
 379 check_include_file_concat("process.h"        HAVE_PROCESS_H)
 380 check_include_file_concat("stddef.h"         HAVE_STDDEF_H)
 381 check_include_file_concat("dlfcn.h"          HAVE_DLFCN_H)
 382 check_include_file_concat("malloc.h"         HAVE_MALLOC_H)
 383 check_include_file_concat("memory.h"         HAVE_MEMORY_H)
 384 check_include_file_concat("ldap.h"           HAVE_LDAP_H)
 385 check_include_file_concat("netinet/if_ether.h" HAVE_NETINET_IF_ETHER_H)
 386 check_include_file_concat("stdint.h"        HAVE_STDINT_H)
 387 check_include_file_concat("sockio.h"        HAVE_SOCKIO_H)
 388 check_include_file_concat("sys/utsname.h"   HAVE_SYS_UTSNAME_H)
 389 check_include_file_concat("idna.h"          HAVE_IDNA_H)
 390
 391 if(CMAKE_USE_OPENSSL)
 392   check_include_file_concat("openssl/rand.h"   HAVE_OPENSSL_RAND_H)
 393 endif(CMAKE_USE_OPENSSL)
 394
 395
 396 check_type_size(size_t  SIZEOF_SIZE_T)
 397 check_type_size(ssize_t  SIZEOF_SSIZE_T)
 398 check_type_size("long long"  SIZEOF_LONG_LONG)
 399 check_type_size("long"  SIZEOF_LONG)
 400 check_type_size("short"  SIZEOF_SHORT)
 401 check_type_size("int"  SIZEOF_INT)
 402 check_type_size("__int64"  SIZEOF___INT64)
 403 check_type_size("long double"  SIZEOF_LONG_DOUBLE)
 404 check_type_size("time_t"  SIZEOF_TIME_T)
 405 if(NOT HAVE_SIZEOF_SSIZE_T)
 406   if(SIZEOF_LONG EQUAL SIZEOF_SIZE_T)
 407     set(ssize_t long)
 408   endif(SIZEOF_LONG EQUAL SIZEOF_SIZE_T)
 409   if(NOT ssize_t AND SIZEOF___INT64 EQUAL SIZEOF_SIZE_T)
 410     set(ssize_t __int64)
 411   endif(NOT ssize_t AND SIZEOF___INT64 EQUAL SIZEOF_SIZE_T)
 412 endif(NOT HAVE_SIZEOF_SSIZE_T)
 413
 414 # Different sizeofs, etc.
 415
 416 #    define CURL_SIZEOF_LONG        4
 417 #    define CURL_TYPEOF_CURL_OFF_T  long long
 418 #    define CURL_FORMAT_CURL_OFF_T  "lld"
 419 #    define CURL_FORMAT_CURL_OFF_TU "llu"
 420 #    define CURL_FORMAT_OFF_T       "%lld"
 421 #    define CURL_SIZEOF_CURL_OFF_T  8
 422 #    define CURL_SUFFIX_CURL_OFF_T  LL
 423 #    define CURL_SUFFIX_CURL_OFF_TU ULL
 424
 425 set(CURL_SIZEOF_LONG ${SIZEOF_LONG})
 426
 427 if(SIZEOF_LONG EQUAL 8)
 428   set(CURL_TYPEOF_CURL_OFF_T long)
 429   set(CURL_SIZEOF_CURL_OFF_T 8)
 430   set(CURL_FORMAT_CURL_OFF_T "ld")
 431   set(CURL_FORMAT_CURL_OFF_TU "lu")
 432   set(CURL_FORMAT_OFF_T "%ld")
 433   set(CURL_SUFFIX_CURL_OFF_T L)
 434   set(CURL_SUFFIX_CURL_OFF_TU LU)
 435 endif(SIZEOF_LONG EQUAL 8)
 436
 437 if(SIZEOF_LONG_LONG EQUAL 8)
 438   set(CURL_TYPEOF_CURL_OFF_T "long long")
 439   set(CURL_SIZEOF_CURL_OFF_T 8)
 440   set(CURL_FORMAT_CURL_OFF_T "lld")
 441   set(CURL_FORMAT_CURL_OFF_TU "llu")
 442   set(CURL_FORMAT_OFF_T "%lld")
 443   set(CURL_SUFFIX_CURL_OFF_T LL)
 444   set(CURL_SUFFIX_CURL_OFF_TU LLU)
 445 endif(SIZEOF_LONG_LONG EQUAL 8)
 446
 447 if(NOT CURL_TYPEOF_CURL_OFF_T)
 448   set(CURL_TYPEOF_CURL_OFF_T ${ssize_t})
 449   set(CURL_SIZEOF_CURL_OFF_T ${SIZEOF_SSIZE_T})
 450   # TODO: need adjustment here.
 451   set(CURL_FORMAT_CURL_OFF_T "ld")
 452   set(CURL_FORMAT_CURL_OFF_TU "lu")
 453   set(CURL_FORMAT_OFF_T "%ld")
 454   set(CURL_SUFFIX_CURL_OFF_T L)
 455   set(CURL_SUFFIX_CURL_OFF_TU LU)
 456 endif(NOT CURL_TYPEOF_CURL_OFF_T)
 457
 458 if(HAVE_SIZEOF_LONG_LONG)
 459   set(HAVE_LONGLONG 1)
 460   set(HAVE_LL 1)
 461 endif(HAVE_SIZEOF_LONG_LONG)
 462
 463 find_file(RANDOM_FILE urandom /dev)
 464 mark_as_advanced(RANDOM_FILE)
 465
 466 # Check for some functions that are used
 467 check_symbol_exists(basename      "${CURL_INCLUDES}" HAVE_BASENAME)
 468 check_symbol_exists(socket        "${CURL_INCLUDES}" HAVE_SOCKET)
 469 check_symbol_exists(poll          "${CURL_INCLUDES}" HAVE_POLL)
 470 check_symbol_exists(select        "${CURL_INCLUDES}" HAVE_SELECT)
 471 check_symbol_exists(strdup        "${CURL_INCLUDES}" HAVE_STRDUP)
 472 check_symbol_exists(strstr        "${CURL_INCLUDES}" HAVE_STRSTR)
 473 check_symbol_exists(strtok_r      "${CURL_INCLUDES}" HAVE_STRTOK_R)
 474 check_symbol_exists(strftime      "${CURL_INCLUDES}" HAVE_STRFTIME)
 475 check_symbol_exists(uname         "${CURL_INCLUDES}" HAVE_UNAME)
 476 check_symbol_exists(strcasecmp    "${CURL_INCLUDES}" HAVE_STRCASECMP)
 477 check_symbol_exists(stricmp       "${CURL_INCLUDES}" HAVE_STRICMP)
 478 check_symbol_exists(strcmpi       "${CURL_INCLUDES}" HAVE_STRCMPI)
 479 check_symbol_exists(strncmpi      "${CURL_INCLUDES}" HAVE_STRNCMPI)
 480 check_symbol_exists(alarm         "${CURL_INCLUDES}" HAVE_ALARM)
 481 if(NOT HAVE_STRNCMPI)
 482   set(HAVE_STRCMPI)
 483 endif(NOT HAVE_STRNCMPI)
 484 check_symbol_exists(gethostbyaddr "${CURL_INCLUDES}" HAVE_GETHOSTBYADDR)
 485 check_symbol_exists(gethostbyaddr_r "${CURL_INCLUDES}" HAVE_GETHOSTBYADDR_R)
 486 check_symbol_exists(gettimeofday  "${CURL_INCLUDES}" HAVE_GETTIMEOFDAY)
 487 check_symbol_exists(inet_addr     "${CURL_INCLUDES}" HAVE_INET_ADDR)
 488 check_symbol_exists(inet_ntoa     "${CURL_INCLUDES}" HAVE_INET_NTOA)
 489 check_symbol_exists(inet_ntoa_r   "${CURL_INCLUDES}" HAVE_INET_NTOA_R)
 490 check_symbol_exists(tcsetattr     "${CURL_INCLUDES}" HAVE_TCSETATTR)
 491 check_symbol_exists(tcgetattr     "${CURL_INCLUDES}" HAVE_TCGETATTR)
 492 check_symbol_exists(perror        "${CURL_INCLUDES}" HAVE_PERROR)
 493 check_symbol_exists(closesocket   "${CURL_INCLUDES}" HAVE_CLOSESOCKET)
 494 check_symbol_exists(setvbuf       "${CURL_INCLUDES}" HAVE_SETVBUF)
 495 check_symbol_exists(sigsetjmp     "${CURL_INCLUDES}" HAVE_SIGSETJMP)
 496 check_symbol_exists(getpass_r     "${CURL_INCLUDES}" HAVE_GETPASS_R)
 497 check_symbol_exists(strlcat       "${CURL_INCLUDES}" HAVE_STRLCAT)
 498 check_symbol_exists(getpwuid      "${CURL_INCLUDES}" HAVE_GETPWUID)
 499 check_symbol_exists(geteuid       "${CURL_INCLUDES}" HAVE_GETEUID)
 500 check_symbol_exists(utime         "${CURL_INCLUDES}" HAVE_UTIME)
 501 if(CMAKE_USE_OPENSSL)
 502   check_symbol_exists(RAND_status   "${CURL_INCLUDES}" HAVE_RAND_STATUS)
 503   check_symbol_exists(RAND_screen   "${CURL_INCLUDES}" HAVE_RAND_SCREEN)
 504   check_symbol_exists(RAND_egd      "${CURL_INCLUDES}" HAVE_RAND_EGD)
 505   check_symbol_exists(CRYPTO_cleanup_all_ex_data "${CURL_INCLUDES}"
 506     HAVE_CRYPTO_CLEANUP_ALL_EX_DATA)
 507   if(HAVE_LIBCRYPTO AND HAVE_LIBSSL)
 508     set(USE_OPENSSL 1)
 509     set(USE_SSLEAY 1)
 510   endif(HAVE_LIBCRYPTO AND HAVE_LIBSSL)
 511 endif(CMAKE_USE_OPENSSL)
 512 check_symbol_exists(gmtime_r      "${CURL_INCLUDES}" HAVE_GMTIME_R)
 513 check_symbol_exists(localtime_r   "${CURL_INCLUDES}" HAVE_LOCALTIME_R)
 514
 515 check_symbol_exists(gethostbyname   "${CURL_INCLUDES}" HAVE_GETHOSTBYNAME)
 516 check_symbol_exists(gethostbyname_r "${CURL_INCLUDES}" HAVE_GETHOSTBYNAME_R)
 517
 518 check_symbol_exists(signal        "${CURL_INCLUDES}" HAVE_SIGNAL_FUNC)
 519 check_symbol_exists(SIGALRM       "${CURL_INCLUDES}" HAVE_SIGNAL_MACRO)
 520 if(HAVE_SIGNAL_FUNC AND HAVE_SIGNAL_MACRO)
 521   set(HAVE_SIGNAL 1)
 522 endif(HAVE_SIGNAL_FUNC AND HAVE_SIGNAL_MACRO)
 523 check_symbol_exists(uname          "${CURL_INCLUDES}" HAVE_UNAME)
 524 check_symbol_exists(strtoll        "${CURL_INCLUDES}" HAVE_STRTOLL)
 525 check_symbol_exists(_strtoi64      "${CURL_INCLUDES}" HAVE__STRTOI64)
 526 check_symbol_exists(strerror_r     "${CURL_INCLUDES}" HAVE_STRERROR_R)
 527 check_symbol_exists(siginterrupt   "${CURL_INCLUDES}" HAVE_SIGINTERRUPT)
 528 check_symbol_exists(perror         "${CURL_INCLUDES}" HAVE_PERROR)
 529 check_symbol_exists(fork           "${CURL_INCLUDES}" HAVE_FORK)
 530 check_symbol_exists(freeaddrinfo   "${CURL_INCLUDES}" HAVE_FREEADDRINFO)
 531 check_symbol_exists(freeifaddrs    "${CURL_INCLUDES}" HAVE_FREEIFADDRS)
 532 check_symbol_exists(pipe           "${CURL_INCLUDES}" HAVE_PIPE)
 533 check_symbol_exists(ftruncate      "${CURL_INCLUDES}" HAVE_FTRUNCATE)
 534 check_symbol_exists(getprotobyname "${CURL_INCLUDES}" HAVE_GETPROTOBYNAME)
 535 check_symbol_exists(getrlimit      "${CURL_INCLUDES}" HAVE_GETRLIMIT)
 536 check_symbol_exists(idn_free       "${CURL_INCLUDES}" HAVE_IDN_FREE)
 537 check_symbol_exists(idna_strerror  "${CURL_INCLUDES}" HAVE_IDNA_STRERROR)
 538 check_symbol_exists(tld_strerror   "${CURL_INCLUDES}" HAVE_TLD_STRERROR)
 539 check_symbol_exists(setlocale      "${CURL_INCLUDES}" HAVE_SETLOCALE)
 540 check_symbol_exists(setrlimit      "${CURL_INCLUDES}" HAVE_SETRLIMIT)
 541 check_symbol_exists(fcntl          "${CURL_INCLUDES}" HAVE_FCNTL)
 542 check_symbol_exists(ioctl          "${CURL_INCLUDES}" HAVE_IOCTL)
 543 check_symbol_exists(setsockopt     "${CURL_INCLUDES}" HAVE_SETSOCKOPT)
 544
 545 # symbol exists in win32, but function does not.
 546 check_function_exists(inet_pton HAVE_INET_PTON)
 547
 548 # sigaction and sigsetjmp are special. Use special mechanism for
 549 # detecting those, but only if previous attempt failed.
 550 if(HAVE_SIGNAL_H)
 551   check_symbol_exists(sigaction "signal.h" HAVE_SIGACTION)
 552 endif(HAVE_SIGNAL_H)
 553
 554 if(NOT HAVE_SIGSETJMP)
 555   if(HAVE_SETJMP_H)
 556     check_symbol_exists(sigsetjmp "setjmp.h" HAVE_MACRO_SIGSETJMP)
 557     if(HAVE_MACRO_SIGSETJMP)
 558       set(HAVE_SIGSETJMP 1)
 559     endif(HAVE_MACRO_SIGSETJMP)
 560   endif(HAVE_SETJMP_H)
 561 endif(NOT HAVE_SIGSETJMP)
 562
 563 # If there is no stricmp(), do not allow LDAP to parse URLs
 564 if(NOT HAVE_STRICMP)
 565   set(HAVE_LDAP_URL_PARSE 1)
 566 endif(NOT HAVE_STRICMP)
 567
 568 # For other curl specific tests, use this macro.
 569 macro(CURL_INTERNAL_TEST CURL_TEST)
 570   if("${CURL_TEST}" MATCHES "^${CURL_TEST}$")
 571     set(MACRO_CHECK_FUNCTION_DEFINITIONS
 572       "-D${CURL_TEST} ${CURL_TEST_DEFINES} ${CMAKE_REQUIRED_FLAGS}")
 573     if(CMAKE_REQUIRED_LIBRARIES)
 574       set(CURL_TEST_ADD_LIBRARIES
 575         "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
 576     endif(CMAKE_REQUIRED_LIBRARIES)
 577
 578     message(STATUS "Performing Curl Test ${CURL_TEST}")
 579     try_compile(${CURL_TEST}
 580       ${CMAKE_BINARY_DIR}
 581       ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CurlTests.c
 582       CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
 583       "${CURL_TEST_ADD_LIBRARIES}"
 584       OUTPUT_VARIABLE OUTPUT)
 585     if(${CURL_TEST})
 586       set(${CURL_TEST} 1 CACHE INTERNAL "Curl test ${FUNCTION}")
 587       message(STATUS "Performing Curl Test ${CURL_TEST} - Success")
 588       file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 589         "Performing Curl Test ${CURL_TEST} passed with the following output:\n"
 590         "${OUTPUT}\n")
 591     else(${CURL_TEST})
 592       message(STATUS "Performing Curl Test ${CURL_TEST} - Failed")
 593       set(${CURL_TEST} "" CACHE INTERNAL "Curl test ${FUNCTION}")
 594       file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
 595         "Performing Curl Test ${CURL_TEST} failed with the following output:\n"
 596         "${OUTPUT}\n")
 597     endif(${CURL_TEST})
 598   endif("${CURL_TEST}" MATCHES "^${CURL_TEST}$")
 599 endmacro(CURL_INTERNAL_TEST)
 600
 601 macro(CURL_INTERNAL_TEST_RUN CURL_TEST)
 602   if("${CURL_TEST}_COMPILE" MATCHES "^${CURL_TEST}_COMPILE$")
 603     set(MACRO_CHECK_FUNCTION_DEFINITIONS
 604       "-D${CURL_TEST} ${CMAKE_REQUIRED_FLAGS}")
 605     if(CMAKE_REQUIRED_LIBRARIES)
 606       set(CURL_TEST_ADD_LIBRARIES
 607         "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
 608     endif(CMAKE_REQUIRED_LIBRARIES)
 609
 610     message(STATUS "Performing Curl Test ${CURL_TEST}")
 611     try_run(${CURL_TEST} ${CURL_TEST}_COMPILE
 612       ${CMAKE_BINARY_DIR}
 613       ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CurlTests.c
 614       CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
 615       "${CURL_TEST_ADD_LIBRARIES}"
 616       OUTPUT_VARIABLE OUTPUT)
 617     if(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 618       set(${CURL_TEST} 1 CACHE INTERNAL "Curl test ${FUNCTION}")
 619       message(STATUS "Performing Curl Test ${CURL_TEST} - Success")
 620     else(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 621       message(STATUS "Performing Curl Test ${CURL_TEST} - Failed")
 622       set(${CURL_TEST} "" CACHE INTERNAL "Curl test ${FUNCTION}")
 623       file(APPEND "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 624         "Performing Curl Test ${CURL_TEST} failed with the following output:\n"
 625         "${OUTPUT}")
 626       if(${CURL_TEST}_COMPILE)
 627         file(APPEND
 628           "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 629           "There was a problem running this test\n")
 630       endif(${CURL_TEST}_COMPILE)
 631       file(APPEND "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 632         "\n\n")
 633     endif(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 634   endif("${CURL_TEST}_COMPILE" MATCHES "^${CURL_TEST}_COMPILE$")
 635 endmacro(CURL_INTERNAL_TEST_RUN)
 636
 637 # Do curl specific tests
 638 foreach(CURL_TEST
 639     HAVE_FCNTL_O_NONBLOCK
 640     HAVE_IOCTLSOCKET
 641     HAVE_IOCTLSOCKET_CAMEL
 642     HAVE_IOCTLSOCKET_CAMEL_FIONBIO
 643     HAVE_IOCTLSOCKET_FIONBIO
 644     HAVE_IOCTL_FIONBIO
 645     HAVE_IOCTL_SIOCGIFADDR
 646     HAVE_SETSOCKOPT_SO_NONBLOCK
 647     HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID
 648     TIME_WITH_SYS_TIME
 649     HAVE_O_NONBLOCK
 650     HAVE_GETHOSTBYADDR_R_5
 651     HAVE_GETHOSTBYADDR_R_7
 652     HAVE_GETHOSTBYADDR_R_8
 653     HAVE_GETHOSTBYADDR_R_5_REENTRANT
 654     HAVE_GETHOSTBYADDR_R_7_REENTRANT
 655     HAVE_GETHOSTBYADDR_R_8_REENTRANT
 656     HAVE_GETHOSTBYNAME_R_3
 657     HAVE_GETHOSTBYNAME_R_5
 658     HAVE_GETHOSTBYNAME_R_6
 659     HAVE_GETHOSTBYNAME_R_3_REENTRANT
 660     HAVE_GETHOSTBYNAME_R_5_REENTRANT
 661     HAVE_GETHOSTBYNAME_R_6_REENTRANT
 662     HAVE_SOCKLEN_T
 663     HAVE_IN_ADDR_T
 664     HAVE_BOOL_T
 665     STDC_HEADERS
 666     RETSIGTYPE_TEST
 667     HAVE_INET_NTOA_R_DECL
 668     HAVE_INET_NTOA_R_DECL_REENTRANT
 669     HAVE_GETADDRINFO
 670     HAVE_FILE_OFFSET_BITS
 671     )
 672   curl_internal_test(${CURL_TEST})
 673 endforeach(CURL_TEST)
 674 if(HAVE_FILE_OFFSET_BITS)
 675   set(_FILE_OFFSET_BITS 64)
 676 endif(HAVE_FILE_OFFSET_BITS)
 677 foreach(CURL_TEST
 678     HAVE_GLIBC_STRERROR_R
 679     HAVE_POSIX_STRERROR_R
 680     )
 681   curl_internal_test_run(${CURL_TEST})
 682 endforeach(CURL_TEST)
 683
 684 # Check for reentrant
 685 foreach(CURL_TEST
 686     HAVE_GETHOSTBYADDR_R_5
 687     HAVE_GETHOSTBYADDR_R_7
 688     HAVE_GETHOSTBYADDR_R_8
 689     HAVE_GETHOSTBYNAME_R_3
 690     HAVE_GETHOSTBYNAME_R_5
 691     HAVE_GETHOSTBYNAME_R_6
 692     HAVE_INET_NTOA_R_DECL_REENTRANT)
 693   if(NOT ${CURL_TEST})
 694     if(${CURL_TEST}_REENTRANT)
 695       set(NEED_REENTRANT 1)
 696     endif(${CURL_TEST}_REENTRANT)
 697   endif(NOT ${CURL_TEST})
 698 endforeach(CURL_TEST)
 699
 700 if(NEED_REENTRANT)
 701   foreach(CURL_TEST
 702       HAVE_GETHOSTBYADDR_R_5
 703       HAVE_GETHOSTBYADDR_R_7
 704       HAVE_GETHOSTBYADDR_R_8
 705       HAVE_GETHOSTBYNAME_R_3
 706       HAVE_GETHOSTBYNAME_R_5
 707       HAVE_GETHOSTBYNAME_R_6)
 708     set(${CURL_TEST} 0)
 709     if(${CURL_TEST}_REENTRANT)
 710       set(${CURL_TEST} 1)
 711     endif(${CURL_TEST}_REENTRANT)
 712   endforeach(CURL_TEST)
 713 endif(NEED_REENTRANT)
 714
 715 if(HAVE_INET_NTOA_R_DECL_REENTRANT)
 716   set(HAVE_INET_NTOA_R_DECL 1)
 717   set(NEED_REENTRANT 1)
 718 endif(HAVE_INET_NTOA_R_DECL_REENTRANT)
 719
 720 # Some other minor tests
 721
 722 if(NOT HAVE_IN_ADDR_T)
 723   set(in_addr_t "unsigned long")
 724 endif(NOT HAVE_IN_ADDR_T)
 725
 726 # Fix libz / zlib.h
 727
 728 if(NOT CURL_SPECIAL_LIBZ)
 729   if(NOT HAVE_LIBZ)
 730     set(HAVE_ZLIB_H 0)
 731   endif(NOT HAVE_LIBZ)
 732
 733   if(NOT HAVE_ZLIB_H)
 734     set(HAVE_LIBZ 0)
 735   endif(NOT HAVE_ZLIB_H)
 736 endif(NOT CURL_SPECIAL_LIBZ)
 737
 738 if(_FILE_OFFSET_BITS)
 739   set(_FILE_OFFSET_BITS 64)
 740 endif(_FILE_OFFSET_BITS)
 741 set(CMAKE_REQUIRED_FLAGS "-D_FILE_OFFSET_BITS=64")
 742 set(CMAKE_EXTRA_INCLUDE_FILES "${CMAKE_CURRENT_SOURCE_DIR}/curl/curl.h")
 743 check_type_size("curl_off_t" SIZEOF_CURL_OFF_T)
 744 set(CMAKE_EXTRA_INCLUDE_FILES)
 745 set(CMAKE_REQUIRED_FLAGS)
 746
 747
 748 # Check for nonblocking
 749 set(HAVE_DISABLED_NONBLOCKING 1)
 750 if(HAVE_FIONBIO OR
 751     HAVE_IOCTLSOCKET OR
 752     HAVE_IOCTLSOCKET_CASE OR
 753     HAVE_O_NONBLOCK)
 754   set(HAVE_DISABLED_NONBLOCKING)
 755 endif(HAVE_FIONBIO OR
 756   HAVE_IOCTLSOCKET OR
 757   HAVE_IOCTLSOCKET_CASE OR
 758   HAVE_O_NONBLOCK)
 759
 760 if(RETSIGTYPE_TEST)
 761   set(RETSIGTYPE void)
 762 else(RETSIGTYPE_TEST)
 763   set(RETSIGTYPE int)
 764 endif(RETSIGTYPE_TEST)
 765
 766 if(CMAKE_COMPILER_IS_GNUCC AND APPLE)
 767   include(CheckCCompilerFlag)
 768   check_c_compiler_flag(-Wno-long-double HAVE_C_FLAG_Wno_long_double)
 769   if(HAVE_C_FLAG_Wno_long_double)
 770     # The Mac version of GCC warns about use of long double.  Disable it.
 771     get_source_file_property(MPRINTF_COMPILE_FLAGS mprintf.c COMPILE_FLAGS)
 772     if(MPRINTF_COMPILE_FLAGS)
 773       set(MPRINTF_COMPILE_FLAGS "${MPRINTF_COMPILE_FLAGS} -Wno-long-double")
 774     else(MPRINTF_COMPILE_FLAGS)
 775       set(MPRINTF_COMPILE_FLAGS "-Wno-long-double")
 776     endif(MPRINTF_COMPILE_FLAGS)
 777     set_source_files_properties(mprintf.c PROPERTIES
 778       COMPILE_FLAGS ${MPRINTF_COMPILE_FLAGS})
 779   endif(HAVE_C_FLAG_Wno_long_double)
 780 endif(CMAKE_COMPILER_IS_GNUCC AND APPLE)
 781
 782 if(HAVE_SOCKLEN_T)
 783   set(CURL_TYPEOF_CURL_SOCKLEN_T "socklen_t")
 784   check_type_size("socklen_t" CURL_SIZEOF_CURL_SOCKLEN_T)
 785 else()
 786   set(CURL_TYPEOF_CURL_SOCKLEN_T int)
 787   set(CURL_SIZEOF_CURL_SOCKLEN_T ${SIZEOF_INT})
 788 endif()
 789
 790 include(CMake/OtherTests.cmake)
 791
 792 add_definitions(-DHAVE_CONFIG_H)
 793
 794 # For windows, do not allow the compiler to use default target (Vista).
 795 if(WIN32)
 796   add_definitions(-D_WIN32_WINNT=0x0501)
 797 endif(WIN32)
 798
 799 if(MSVC)
 800   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 801 endif(MSVC)
 802
 803 # Sets up the dependencies (zlib, OpenSSL, etc.) of a cURL subproject according to options.
 804 # TODO This is far to be complete!
 805 function(SETUP_CURL_DEPENDENCIES TARGET_NAME)
 806   if(CURL_ZLIB AND ZLIB_FOUND)
 807     include_directories(${ZLIB_INCLUDE_DIR})
 808   endif()
 809   if(CURL_ZLIB AND ZLIB_FOUND)
 810     target_link_libraries(${TARGET_NAME} ${ZLIB_LIBRARIES})
 811     #ADD_DEFINITIONS( -DHAVE_ZLIB_H -DHAVE_ZLIB -DHAVE_LIBZ )
 812   endif()
 813
 814   if(CMAKE_USE_OPENSSL AND OPENSSL_FOUND)
 815     include_directories(${OPENSSL_INCLUDE_DIR})
 816   endif()
 817   if(CMAKE_USE_OPENSSL AND CURL_CONFIG_HAS_BEEN_RUN_BEFORE)
 818     target_link_libraries(${TARGET_NAME} ${OPENSSL_LIBRARIES})
 819     #ADD_DEFINITIONS( -DUSE_SSLEAY )
 820   endif()
 821 endfunction()
 822
 823 # Ugly (but functional) way to include "Makefile.inc" by transforming it (= regenerate it).
 824 function(TRANSFORM_MAKEFILE_INC INPUT_FILE OUTPUT_FILE)
 825   file(READ ${INPUT_FILE} MAKEFILE_INC_TEXT)
 826   string(REPLACE "$(top_srcdir)"   "\${CURL_SOURCE_DIR}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 827   string(REPLACE "$(top_builddir)" "\${CURL_BINARY_DIR}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 828
 829   string(REGEX REPLACE "\\\\\n" "§!§" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 830   string(REGEX REPLACE "([a-zA-Z_][a-zA-Z0-9_]*)[\t ]*=[\t ]*([^\n]*\n)" "SET(\\1 \\2)\n" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 831   string(REPLACE "§!§" "\n" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 832
 833   string(REGEX REPLACE "\\$\\(([a-zA-Z_][a-zA-Z0-9_]*)\\)" "\${\\1}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Replace $() with ${}
 834   string(REGEX REPLACE "@([a-zA-Z_][a-zA-Z0-9_]*)@" "\${\\1}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Replace @@ with ${}, even if that may not be read by CMake scripts.
 835   file(WRITE ${OUTPUT_FILE} ${MAKEFILE_INC_TEXT})
 836
 837 endfunction()
 838
 839 add_subdirectory(lib)
 840 if(BUILD_CURL_EXE)
 841   add_subdirectory(src)
 842 endif()
 843 if(BUILD_CURL_TESTS)
 844   add_subdirectory(tests)
 845 endif()
 846
 847 # This needs to be run very last so other parts of the scripts can take advantage of this.
 848 if(NOT CURL_CONFIG_HAS_BEEN_RUN_BEFORE)
 849   set(CURL_CONFIG_HAS_BEEN_RUN_BEFORE 1 CACHE INTERNAL "Flag to track whether this is the first time running CMake or if CMake has been configured before")
 850 endif()