CMakeLists.txt

   1 # cURL/libcurl CMake script
   2 # by [PUT YOUR REAL NAME TETEST!] and Sukender (Benoit Neil)
   3
   4 # TODO:
   5 # The output .so file lacks the soname number which we currently have within the lib/Makefile.am file
   6 # Add full (4 or 5 libs) SSL support
   7 # Add INSTALL target (EXTRA_DIST variables in Makefile.am may be moved to Makefile.inc so that CMake/CPack is aware of what's to include).
   8 # Add CTests(?)
   9 # Check on all possible platforms
  10 # Test with as many configurations possible (With or without any option)
  11 # Create scripts that help keeping the CMake build system up to date (to reduce maintenance). According to Tetetest:
  12 #  - lists of headers that 'configure' checks for;
  13 #  - curl-specific tests (the ones that are in m4/curl-*.m4 files);
  14 #  - (most obvious thing:) curl version numbers.
  15 # Add documentation subproject
  16 #
  17 # To check:
  18 # (From Daniel Stenberg) The cmake build selected to run gcc with -fPIC on my box while the plain configure script did not.
  19 # (From Daniel Stenberg) The gcc command line use neither -g nor any -O options. As a developer, I also treasure our configure scripts's --enable-debug option that sets a long range of "picky" compiler options.
  20
  21 CMAKE_MINIMUM_REQUIRED(VERSION 2.6.2 FATAL_ERROR)
  22 SET(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake;${CMAKE_MODULE_PATH}")
  23
  24 FUNCTION(TO_LIST_SPACES _LIST_NAME OUTPUT_VAR)
  25   SET(NEW_LIST_SPACE)
  26   FOREACH(ITEM ${${_LIST_NAME}})
  27     SET(NEW_LIST_SPACE "${NEW_LIST_SPACE} ${ITEM}")
  28   ENDFOREACH()
  29   STRING(STRIP ${NEW_LIST_SPACE} NEW_LIST_SPACE)
  30   SET(${OUTPUT_VAR} "${NEW_LIST_SPACE}" PARENT_SCOPE)
  31 ENDFUNCTION()
  32
  33 # Appends a lis of item to a string which is a space-separated list, if they don't already exist.
  34 FUNCTION(LIST_SPACES_APPEND_ONCE LIST_NAME)
  35   STRING(REPLACE " " ";" _LIST ${${LIST_NAME}})
  36   LIST(APPEND _LIST ${ARGN})
  37   LIST(REMOVE_DUPLICATES _LIST)
  38   TO_LIST_SPACES(_LIST NEW_LIST_SPACE)
  39   SET(${LIST_NAME} "${NEW_LIST_SPACE}" PARENT_SCOPE)
  40 ENDFUNCTION()
  41
  42
  43 project( CURL C )
  44 SET(CURL_MAJOR_VERSION 7)
  45 SET(CURL_MINOR_VERSION 19)
  46 SET(CURL_PATCH_VERSION 4)
  47
  48 INCLUDE_REGULAR_EXPRESSION("^.*$")    # Sukender: Is it necessary?
  49
  50 # Setup package meta-data
  51 # SET(PACKAGE "curl")
  52 SET(CURL_VERSION ${CURL_MAJOR_VERSION}.${CURL_MINOR_VERSION}.${CURL_PATCH_VERSION})
  53 # SET(PACKAGE_TARNAME "curl")
  54 # SET(PACKAGE_NAME "curl")
  55 # SET(PACKAGE_VERSION "-")
  56 # SET(PACKAGE_STRING "curl-")
  57 # SET(PACKAGE_BUGREPORT "a suitable curl mailing list => http://curl.haxx.se/mail/")
  58 SET(OPERATING_SYSTEM "${CMAKE_SYSTEM_NAME}")
  59 SET(OS "\"${CMAKE_SYSTEM_NAME}\"")
  60
  61 # Make the base headers visible to everything
  62 # IF(NOT ${PROJECT_BINARY_DIR} EQUAL ${PROJECT_SOURCE_DIR})
  63    # INCLUDE_DIRECTORIES(${PROJECT_BINARY_DIR}/include)
  64 # ENDIF()
  65 INCLUDE_DIRECTORIES( ${CURL_SOURCE_DIR}/include )
  66
  67 IF(WIN32)
  68   SET(NATIVE_WINDOWS ON)
  69 ENDIF()
  70
  71 OPTION(BUILD_CURL_EXE "Set to ON to build cURL executable." ON)
  72 OPTION(BUILD_CURL_TESTS "Set to ON to build cURL tests." ON)
  73 OPTION(CURL_STATICLIB "Set to ON to build libcurl with static linking." OFF)
  74
  75 OPTION(BUILD_DASHBOARD_REPORTS "Set to ON to activate reporting of cURL builds here http://www.cdash.org/CDashPublic/index.php?project=CURL" OFF)
  76 IF(BUILD_DASHBOARD_REPORTS)
  77   #INCLUDE(Dart)
  78   INCLUDE(CTest)
  79 ENDIF(BUILD_DASHBOARD_REPORTS)
  80
  81 IF(MSVC)
  82   OPTION(BUILD_RELEASE_DEBUG_DIRS "Set OFF to build each configuration to a separate directory" OFF)
  83   MARK_AS_ADVANCED(BUILD_RELEASE_DEBUG_DIRS)
  84 ENDIF()
  85
  86 OPTION(CURL_HIDDEN_SYMBOLS "Set to ON to hide libcurl internal symbols (=hide all symbols that aren't officially external)." ON)
  87 MARK_AS_ADVANCED(CURL_HIDDEN_SYMBOLS)
  88
  89 # IF(WIN32)
  90   # OPTION(CURL_WINDOWS_SSPI "Use windows libraries to allow NTLM authentication without openssl" ON)
  91   # MARK_AS_ADVANCED(CURL_WINDOWS_SSPI)
  92 # ENDIF()
  93
  94 OPTION(HTTP_ONLY "disables all protocols except HTTP (This overrides all CURL_DISABLE_* options)" OFF)
  95 MARK_AS_ADVANCED(HTTP_ONLY)
  96 OPTION(CURL_DISABLE_FTP "disables FTP" OFF)
  97 MARK_AS_ADVANCED(CURL_DISABLE_FTP)
  98 OPTION(CURL_DISABLE_LDAP "disables LDAP" OFF)
  99 MARK_AS_ADVANCED(CURL_DISABLE_LDAP)
 100 OPTION(CURL_DISABLE_TELNET "disables Telnet" OFF)
 101 MARK_AS_ADVANCED(CURL_DISABLE_TELNET)
 102 OPTION(CURL_DISABLE_DICT "disables DICT" OFF)
 103 MARK_AS_ADVANCED(CURL_DISABLE_DICT)
 104 OPTION(CURL_DISABLE_FILE "disables FILE" OFF)
 105 MARK_AS_ADVANCED(CURL_DISABLE_FILE)
 106 OPTION(CURL_DISABLE_TFTP "disables TFTP" OFF)
 107 MARK_AS_ADVANCED(CURL_DISABLE_TFTP)
 108 OPTION(CURL_DISABLE_HTTP "disables HTTP" OFF)
 109 MARK_AS_ADVANCED(CURL_DISABLE_HTTP)
 110
 111 OPTION(CURL_DISABLE_LDAPS "to disable LDAPS" OFF)
 112 MARK_AS_ADVANCED(CURL_DISABLE_LDAPS)
 113 IF(WIN32)
 114   SET(CURL_LDAP_HYBRID OFF)
 115   OPTION(CURL_LDAP_WIN "Use W$ LDAP implementation" ON)
 116   MARK_AS_ADVANCED(CURL_LDAP_WIN)
 117 ELSE()
 118   OPTION(CURL_LDAP_HYBRID "W$ LDAP with non-W$ compiler" OFF)
 119   MARK_AS_ADVANCED(CURL_LDAP_HYBRID)
 120   SET(CURL_LDAP_WIN OFF)
 121 ENDIF()
 122
 123 IF(HTTP_ONLY)
 124   SET(CURL_DISABLE_FTP ON)
 125   SET(CURL_DISABLE_LDAP ON)
 126   SET(CURL_DISABLE_TELNET ON)
 127   SET(CURL_DISABLE_DICT ON)
 128   SET(CURL_DISABLE_FILE ON)
 129   SET(CURL_DISABLE_TFTP ON)
 130 ENDIF()
 131
 132 OPTION(CURL_DISABLE_COOKIES "to disable cookies support" OFF)
 133 MARK_AS_ADVANCED(CURL_DISABLE_COOKIES)
 134
 135 OPTION(CURL_DISABLE_CRYPTO_AUTH "to disable cryptographic authentication" OFF)
 136 MARK_AS_ADVANCED(CURL_DISABLE_CRYPTO_AUTH)
 137 OPTION(CURL_DISABLE_VERBOSE_STRINGS "to disable verbose strings" OFF)
 138 MARK_AS_ADVANCED(CURL_DISABLE_VERBOSE_STRINGS)
 139 OPTION(DISABLED_THREADSAFE "Set to explicitly specify we don't want to use thread-safe functions" OFF)
 140 MARK_AS_ADVANCED(DISABLED_THREADSAFE)
 141 OPTION(ENABLE_IPV6 "Define if you want to enable IPv6 support" OFF)
 142 MARK_AS_ADVANCED(ENABLE_IPV6)
 143
 144
 145 IF(WIN32)
 146   LIST_SPACES_APPEND_ONCE(CMAKE_C_STANDARD_LIBRARIES wsock32.lib ws2_32.lib)  # bufferoverflowu.lib
 147   IF(CURL_DISABLE_LDAP)
 148     # Remove wldap32.lib from space-separated list
 149     STRING(REPLACE " " ";" _LIST ${CMAKE_C_STANDARD_LIBRARIES})
 150     LIST(REMOVE_ITEM _LIST "wldap32.lib")
 151     TO_LIST_SPACES(_LIST CMAKE_C_STANDARD_LIBRARIES)
 152   ELSE()
 153     # Append wldap32.lib
 154     LIST_SPACES_APPEND_ONCE(CMAKE_C_STANDARD_LIBRARIES wldap32.lib)
 155   ENDIF()
 156   SET(CMAKE_C_STANDARD_LIBRARIES "${CMAKE_C_STANDARD_LIBRARIES}"   CACHE STRING "" FORCE)
 157 ENDIF()
 158
 159
 160 # We need ansi c-flags, especially on HP
 161 SET(CMAKE_C_FLAGS "${CMAKE_ANSI_CFLAGS} ${CMAKE_C_FLAGS}")
 162 SET(CMAKE_REQUIRED_FLAGS ${CMAKE_ANSI_CFLAGS})
 163
 164 # Disable warnings on Borland to avoid changing 3rd party code.
 165 IF(BORLAND)
 166   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -w-")
 167 ENDIF(BORLAND)
 168
 169 # If we are on AIX, do the _ALL_SOURCE magic
 170 IF(${CMAKE_SYSTEM_NAME} MATCHES AIX)
 171   SET(_ALL_SOURCE 1)
 172 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES AIX)
 173
 174 # Include all the necessary files for macros
 175 INCLUDE (CheckFunctionExists)
 176 INCLUDE (CheckIncludeFile)
 177 INCLUDE (CheckIncludeFiles)
 178 INCLUDE (CheckLibraryExists)
 179 INCLUDE (CheckSymbolExists)
 180 # if crosscompiling is on, the CHECK_TYPE_SIZE macro coming with cmake uses
 181 # TRY_COMPILE instead of TRY_RUN which makes crosscompiling easier, Alex
 182 IF(CMAKE_CROSSCOMPILING)
 183   INCLUDE ("${CMAKE_MODULE_PATH}/CheckTypeSize.cmake")
 184 ELSE(CMAKE_CROSSCOMPILING)
 185   INCLUDE (CheckTypeSize)
 186 ENDIF(CMAKE_CROSSCOMPILING)
 187
 188 # On windows preload settings
 189 IF(WIN32)
 190   INCLUDE(${CMAKE_CURRENT_SOURCE_DIR}/CMake/Platforms/WindowsCache.cmake)
 191 ENDIF(WIN32)
 192
 193 # This macro checks if the symbol exists in the library and if it
 194 # does, it appends library to the list.
 195 SET(CURL_LIBS "")
 196 MACRO(CHECK_LIBRARY_EXISTS_CONCAT LIBRARY SYMBOL VARIABLE)
 197   CHECK_LIBRARY_EXISTS("${LIBRARY};${CURL_LIBS}" ${SYMBOL} ""
 198     ${VARIABLE})
 199   IF(${VARIABLE})
 200     SET(CURL_LIBS ${CURL_LIBS} ${LIBRARY})
 201   ENDIF(${VARIABLE})
 202 ENDMACRO(CHECK_LIBRARY_EXISTS_CONCAT)
 203
 204 # Check for all needed libraries
 205 CHECK_LIBRARY_EXISTS_CONCAT("dl"     dlopen       HAVE_LIBDL)
 206 #CHECK_LIBRARY_EXISTS_CONCAT("ucb"    gethostname  HAVE_LIBUCB)
 207 CHECK_LIBRARY_EXISTS_CONCAT("socket" connect      HAVE_LIBSOCKET)
 208 CHECK_LIBRARY_EXISTS("c" gethostbyname "" NOT_NEED_LIBNSL)
 209
 210 # Yellowtab Zeta needs different libraries than BeOS 5.
 211 IF(BEOS)
 212   SET(NOT_NEED_LIBNSL 1)
 213   CHECK_LIBRARY_EXISTS_CONCAT("bind" gethostbyname HAVE_LIBBIND)
 214   CHECK_LIBRARY_EXISTS_CONCAT("bnetapi" closesocket HAVE_LIBBNETAPI)
 215 ENDIF(BEOS)
 216
 217 IF(NOT NOT_NEED_LIBNSL)
 218   CHECK_LIBRARY_EXISTS_CONCAT("nsl"    gethostbyname  HAVE_LIBNSL)
 219 ENDIF(NOT NOT_NEED_LIBNSL)
 220
 221 CHECK_LIBRARY_EXISTS_CONCAT("ws2_32" getch        HAVE_LIBWS2_32)
 222 CHECK_LIBRARY_EXISTS_CONCAT("winmm"  getch        HAVE_LIBWINMM)
 223 # IF(NOT CURL_SPECIAL_LIBZ)
 224 #  CHECK_LIBRARY_EXISTS_CONCAT("z"      inflateEnd   HAVE_LIBZ)
 225 # ENDIF(NOT CURL_SPECIAL_LIBZ)
 226
 227 OPTION(CMAKE_USE_OPENSSL "Use OpenSSL code. Experimental" ON)
 228 MARK_AS_ADVANCED(CMAKE_USE_OPENSSL)
 229 IF(CMAKE_USE_OPENSSL)
 230   IF(WIN32)
 231   FIND_PACKAGE(OpenSSL)
 232   IF(OPENSSL_FOUND)
 233     SET(USE_SSLEAY TRUE)
 234     SET(USE_OPENSSL TRUE)
 235     LIST(APPEND CURL_LIBS ${OPENSSL_LIBRARIES} )
 236   ENDIF()
 237     #FIND_LIBRARY(LIBEAY NAMES libeay32)
 238     #LIST(APPEND CURL_LIBS ${LIBEAY} )
 239   ELSE(WIN32)
 240     CHECK_LIBRARY_EXISTS_CONCAT("crypto" CRYPTO_lock  HAVE_LIBCRYPTO)
 241     CHECK_LIBRARY_EXISTS_CONCAT("ssl"    SSL_connect  HAVE_LIBSSL)
 242   ENDIF(WIN32)
 243 ENDIF(CMAKE_USE_OPENSSL)
 244
 245 # Check for idn
 246 CHECK_LIBRARY_EXISTS_CONCAT("idn" idna_to_ascii_lz HAVE_LIBIDN)
 247
 248 # Check for LDAP
 249 CHECK_LIBRARY_EXISTS_CONCAT("ldap" ldap_init HAVE_LIBLDAP)
 250 # if(NOT HAVE_LIBLDAP)
 251     # SET(CURL_DISABLE_LDAP ON)
 252 # endif(NOT HAVE_LIBLDAP)
 253
 254 # Check for symbol dlopen (same as HAVE_LIBDL)
 255 CHECK_LIBRARY_EXISTS("${CURL_LIBS}" dlopen "" HAVE_DLOPEN)
 256
 257 # For other tests to use the same libraries
 258 SET(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBS})
 259
 260 OPTION(CURL_ZLIB "Set to ON to enable building cURL with zlib support." ON)
 261 SET(HAVE_LIBZ OFF)
 262 SET(HAVE_ZLIB_H OFF)
 263 SET(HAVE_ZLIB OFF)
 264 IF(CURL_ZLIB)  # AND CURL_CONFIG_HAS_BEEN_RUN_BEFORE
 265   FIND_PACKAGE(ZLIB)
 266   IF(ZLIB_FOUND)
 267     SET(HAVE_ZLIB_H ON)
 268     SET(HAVE_ZLIB ON)
 269     SET(HAVE_LIBZ ON)
 270   ENDIF()
 271 ENDIF()
 272
 273 # If we have features.h, then do the _BSD_SOURCE magic
 274 CHECK_INCLUDE_FILE("features.h"       HAVE_FEATURES_H)
 275
 276 # Check if header file exists and add it to the list.
 277 MACRO(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 278   CHECK_INCLUDE_FILES("${CURL_INCLUDES};${FILE}" ${VARIABLE})
 279   IF(${VARIABLE})
 280     SET(CURL_INCLUDES ${CURL_INCLUDES} ${FILE})
 281     SET(CURL_TEST_DEFINES "${CURL_TEST_DEFINES} -D${VARIABLE}")
 282   ENDIF(${VARIABLE})
 283 ENDMACRO(CHECK_INCLUDE_FILE_CONCAT)
 284
 285
 286 # Check for header files
 287 IF(NOT UNIX)
 288   CHECK_INCLUDE_FILE_CONCAT("ws2tcpip.h"     HAVE_WS2TCPIP_H)
 289   CHECK_INCLUDE_FILE_CONCAT("winsock2.h"     HAVE_WINSOCK2_H)
 290 ENDIF(NOT UNIX)
 291 CHECK_INCLUDE_FILE_CONCAT("stdio.h"          HAVE_STDIO_H)
 292 IF(NOT UNIX)
 293   CHECK_INCLUDE_FILE_CONCAT("windows.h"      HAVE_WINDOWS_H)
 294   CHECK_INCLUDE_FILE_CONCAT("winsock.h"      HAVE_WINSOCK_H)
 295 ENDIF(NOT UNIX)
 296
 297 CHECK_INCLUDE_FILE_CONCAT("inttypes.h"       HAVE_INTTYPES_H)
 298 CHECK_INCLUDE_FILE_CONCAT("sys/filio.h"      HAVE_SYS_FILIO_H)
 299 CHECK_INCLUDE_FILE_CONCAT("sys/ioctl.h"      HAVE_SYS_IOCTL_H)
 300 CHECK_INCLUDE_FILE_CONCAT("sys/param.h"      HAVE_SYS_PARAM_H)
 301 CHECK_INCLUDE_FILE_CONCAT("sys/poll.h"       HAVE_SYS_POLL_H)
 302 CHECK_INCLUDE_FILE_CONCAT("sys/resource.h"   HAVE_SYS_RESOURCE_H)
 303 CHECK_INCLUDE_FILE_CONCAT("sys/select.h"     HAVE_SYS_SELECT_H)
 304 CHECK_INCLUDE_FILE_CONCAT("sys/socket.h"     HAVE_SYS_SOCKET_H)
 305 CHECK_INCLUDE_FILE_CONCAT("sys/sockio.h"     HAVE_SYS_SOCKIO_H)
 306 CHECK_INCLUDE_FILE_CONCAT("sys/stat.h"       HAVE_SYS_STAT_H)
 307 CHECK_INCLUDE_FILE_CONCAT("sys/time.h"       HAVE_SYS_TIME_H)
 308 CHECK_INCLUDE_FILE_CONCAT("sys/types.h"      HAVE_SYS_TYPES_H)
 309 CHECK_INCLUDE_FILE_CONCAT("sys/uio.h"        HAVE_SYS_UIO_H)
 310 CHECK_INCLUDE_FILE_CONCAT("sys/un.h"         HAVE_SYS_UN_H)
 311 CHECK_INCLUDE_FILE_CONCAT("sys/utime.h"      HAVE_SYS_UTIME_H)
 312 CHECK_INCLUDE_FILE_CONCAT("alloca.h"         HAVE_ALLOCA_H)
 313 CHECK_INCLUDE_FILE_CONCAT("arpa/inet.h"      HAVE_ARPA_INET_H)
 314 CHECK_INCLUDE_FILE_CONCAT("arpa/tftp.h"      HAVE_ARPA_TFTP_H)
 315 CHECK_INCLUDE_FILE_CONCAT("assert.h"         HAVE_ASSERT_H)
 316 CHECK_INCLUDE_FILE_CONCAT("crypto.h"         HAVE_CRYPTO_H)
 317 CHECK_INCLUDE_FILE_CONCAT("des.h"            HAVE_DES_H)
 318 CHECK_INCLUDE_FILE_CONCAT("err.h"            HAVE_ERR_H)
 319 CHECK_INCLUDE_FILE_CONCAT("errno.h"          HAVE_ERRNO_H)
 320 CHECK_INCLUDE_FILE_CONCAT("fcntl.h"          HAVE_FCNTL_H)
 321 CHECK_INCLUDE_FILE_CONCAT("gssapi/gssapi.h"  HAVE_GSSAPI_GSSAPI_H)
 322 CHECK_INCLUDE_FILE_CONCAT("gssapi/gssapi_generic.h" HAVE_GSSAPI_GSSAPI_GENERIC_H)
 323 CHECK_INCLUDE_FILE_CONCAT("gssapi/gssapi_krb5.h" HAVE_GSSAPI_GSSAPI_KRB5_H)
 324 CHECK_INCLUDE_FILE_CONCAT("idn-free.h"       HAVE_IDN_FREE_H)
 325 CHECK_INCLUDE_FILE_CONCAT("ifaddrs.h"        HAVE_IFADDRS_H)
 326 CHECK_INCLUDE_FILE_CONCAT("io.h"             HAVE_IO_H)
 327 CHECK_INCLUDE_FILE_CONCAT("krb.h"            HAVE_KRB_H)
 328 CHECK_INCLUDE_FILE_CONCAT("libgen.h"         HAVE_LIBGEN_H)
 329 CHECK_INCLUDE_FILE_CONCAT("libssh2.h"        HAVE_LIBSSH2_H)
 330 CHECK_INCLUDE_FILE_CONCAT("limits.h"         HAVE_LIMITS_H)
 331 CHECK_INCLUDE_FILE_CONCAT("locale.h"         HAVE_LOCALE_H)
 332 CHECK_INCLUDE_FILE_CONCAT("net/if.h"         HAVE_NET_IF_H)
 333 CHECK_INCLUDE_FILE_CONCAT("netdb.h"          HAVE_NETDB_H)
 334 CHECK_INCLUDE_FILE_CONCAT("netinet/in.h"     HAVE_NETINET_IN_H)
 335 CHECK_INCLUDE_FILE_CONCAT("netinet/tcp.h"    HAVE_NETINET_TCP_H)
 336 CHECK_INCLUDE_FILE_CONCAT("openssl/crypto.h" HAVE_OPENSSL_CRYPTO_H)
 337 CHECK_INCLUDE_FILE_CONCAT("openssl/engine.h" HAVE_OPENSSL_ENGINE_H)
 338 CHECK_INCLUDE_FILE_CONCAT("openssl/err.h"    HAVE_OPENSSL_ERR_H)
 339 CHECK_INCLUDE_FILE_CONCAT("openssl/pem.h"    HAVE_OPENSSL_PEM_H)
 340 CHECK_INCLUDE_FILE_CONCAT("openssl/pkcs12.h" HAVE_OPENSSL_PKCS12_H)
 341 CHECK_INCLUDE_FILE_CONCAT("openssl/rsa.h"    HAVE_OPENSSL_RSA_H)
 342 CHECK_INCLUDE_FILE_CONCAT("openssl/ssl.h"    HAVE_OPENSSL_SSL_H)
 343 CHECK_INCLUDE_FILE_CONCAT("openssl/x509.h"   HAVE_OPENSSL_X509_H)
 344 CHECK_INCLUDE_FILE_CONCAT("pem.h"            HAVE_PEM_H)
 345 CHECK_INCLUDE_FILE_CONCAT("poll.h"           HAVE_POLL_H)
 346 CHECK_INCLUDE_FILE_CONCAT("pwd.h"            HAVE_PWD_H)
 347 CHECK_INCLUDE_FILE_CONCAT("rsa.h"            HAVE_RSA_H)
 348 CHECK_INCLUDE_FILE_CONCAT("setjmp.h"         HAVE_SETJMP_H)
 349 CHECK_INCLUDE_FILE_CONCAT("sgtty.h"          HAVE_SGTTY_H)
 350 CHECK_INCLUDE_FILE_CONCAT("signal.h"         HAVE_SIGNAL_H)
 351 CHECK_INCLUDE_FILE_CONCAT("ssl.h"            HAVE_SSL_H)
 352 CHECK_INCLUDE_FILE_CONCAT("stdbool.h"        HAVE_STDBOOL_H)
 353 CHECK_INCLUDE_FILE_CONCAT("stdint.h"         HAVE_STDINT_H)
 354 CHECK_INCLUDE_FILE_CONCAT("stdio.h"          HAVE_STDIO_H)
 355 CHECK_INCLUDE_FILE_CONCAT("stdlib.h"         HAVE_STDLIB_H)
 356 CHECK_INCLUDE_FILE_CONCAT("string.h"         HAVE_STRING_H)
 357 CHECK_INCLUDE_FILE_CONCAT("strings.h"        HAVE_STRINGS_H)
 358 CHECK_INCLUDE_FILE_CONCAT("stropts.h"        HAVE_STROPTS_H)
 359 CHECK_INCLUDE_FILE_CONCAT("termio.h"         HAVE_TERMIO_H)
 360 CHECK_INCLUDE_FILE_CONCAT("termios.h"        HAVE_TERMIOS_H)
 361 CHECK_INCLUDE_FILE_CONCAT("time.h"           HAVE_TIME_H)
 362 CHECK_INCLUDE_FILE_CONCAT("tld.h"            HAVE_TLD_H)
 363 CHECK_INCLUDE_FILE_CONCAT("unistd.h"         HAVE_UNISTD_H)
 364 CHECK_INCLUDE_FILE_CONCAT("utime.h"          HAVE_UTIME_H)
 365 CHECK_INCLUDE_FILE_CONCAT("x509.h"           HAVE_X509_H)
 366
 367 CHECK_INCLUDE_FILE_CONCAT("process.h"        HAVE_PROCESS_H)
 368 CHECK_INCLUDE_FILE_CONCAT("stddef.h"         HAVE_STDDEF_H)
 369 CHECK_INCLUDE_FILE_CONCAT("dlfcn.h"          HAVE_DLFCN_H)
 370 CHECK_INCLUDE_FILE_CONCAT("malloc.h"         HAVE_MALLOC_H)
 371 CHECK_INCLUDE_FILE_CONCAT("memory.h"         HAVE_MEMORY_H)
 372 CHECK_INCLUDE_FILE_CONCAT("ldap.h"           HAVE_LDAP_H)
 373 CHECK_INCLUDE_FILE_CONCAT("netinet/if_ether.h" HAVE_NETINET_IF_ETHER_H)
 374 CHECK_INCLUDE_FILE_CONCAT("stdint.h"        HAVE_STDINT_H)
 375 CHECK_INCLUDE_FILE_CONCAT("sockio.h"        HAVE_SOCKIO_H)
 376 CHECK_INCLUDE_FILE_CONCAT("sys/utsname.h"   HAVE_SYS_UTSNAME_H)
 377 CHECK_INCLUDE_FILE_CONCAT("idna.h"          HAVE_IDNA_H)
 378
 379 IF(CMAKE_USE_OPENSSL)
 380   CHECK_INCLUDE_FILE_CONCAT("openssl/rand.h"   HAVE_OPENSSL_RAND_H)
 381 ENDIF(CMAKE_USE_OPENSSL)
 382
 383
 384 CHECK_TYPE_SIZE(size_t  SIZEOF_SIZE_T)
 385 CHECK_TYPE_SIZE(ssize_t  SIZEOF_SSIZE_T)
 386 CHECK_TYPE_SIZE("long long"  SIZEOF_LONG_LONG)
 387 CHECK_TYPE_SIZE("long"  SIZEOF_LONG)
 388 CHECK_TYPE_SIZE("int"  SIZEOF_INT)
 389 CHECK_TYPE_SIZE("__int64"  SIZEOF___INT64)
 390 CHECK_TYPE_SIZE("long double"  SIZEOF_LONG_DOUBLE)
 391 CHECK_TYPE_SIZE("time_t"  SIZEOF_TIME_T)
 392 IF(NOT HAVE_SIZEOF_SSIZE_T)
 393   IF(SIZEOF_LONG EQUAL SIZEOF_SIZE_T)
 394     SET(ssize_t long)
 395   ENDIF(SIZEOF_LONG EQUAL SIZEOF_SIZE_T)
 396   IF(NOT ssize_t AND SIZEOF___INT64 EQUAL SIZEOF_SIZE_T)
 397     SET(ssize_t __int64)
 398   ENDIF(NOT ssize_t AND SIZEOF___INT64 EQUAL SIZEOF_SIZE_T)
 399 ENDIF(NOT HAVE_SIZEOF_SSIZE_T)
 400
 401 # Different sizeofs, etc.
 402
 403 #    define CURL_SIZEOF_LONG        4
 404 #    define CURL_TYPEOF_CURL_OFF_T  long long
 405 #    define CURL_FORMAT_CURL_OFF_T  "lld"
 406 #    define CURL_FORMAT_CURL_OFF_TU "llu"
 407 #    define CURL_FORMAT_OFF_T       "%lld"
 408 #    define CURL_SIZEOF_CURL_OFF_T  8
 409 #    define CURL_SUFFIX_CURL_OFF_T  LL
 410 #    define CURL_SUFFIX_CURL_OFF_TU ULL
 411
 412 set(CURL_SIZEOF_LONG ${SIZEOF_LONG})
 413
 414 if(SIZEOF_LONG EQUAL 8)
 415   set(CURL_TYPEOF_CURL_OFF_T long)
 416   set(CURL_SIZEOF_CURL_OFF_T 8)
 417   set(CURL_FORMAT_CURL_OFF_T "ld")
 418   set(CURL_FORMAT_CURL_OFF_TU "lu")
 419   set(CURL_FORMAT_OFF_T "%ld")
 420   set(CURL_SUFFIX_CURL_OFF_T L)
 421   set(CURL_SUFFIX_CURL_OFF_TU LU)
 422 endif(SIZEOF_LONG EQUAL 8)
 423
 424 if(SIZEOF_LONG_LONG EQUAL 8)
 425   set(CURL_TYPEOF_CURL_OFF_T "long long")
 426   set(CURL_SIZEOF_CURL_OFF_T 8)
 427   set(CURL_FORMAT_CURL_OFF_T "lld")
 428   set(CURL_FORMAT_CURL_OFF_TU "llu")
 429   set(CURL_FORMAT_OFF_T "%lld")
 430   set(CURL_SUFFIX_CURL_OFF_T LL)
 431   set(CURL_SUFFIX_CURL_OFF_TU LLU)
 432 endif(SIZEOF_LONG_LONG EQUAL 8)
 433
 434 if(NOT CURL_TYPEOF_CURL_OFF_T)
 435   set(CURL_TYPEOF_CURL_OFF_T ${ssize_t})
 436   set(CURL_SIZEOF_CURL_OFF_T ${SIZEOF_SSIZE_T})
 437   # TODO: need adjustment here.
 438   set(CURL_FORMAT_CURL_OFF_T "ld")
 439   set(CURL_FORMAT_CURL_OFF_TU "lu")
 440   set(CURL_FORMAT_OFF_T "%ld")
 441   set(CURL_SUFFIX_CURL_OFF_T L)
 442   set(CURL_SUFFIX_CURL_OFF_TU LU)
 443 endif(NOT CURL_TYPEOF_CURL_OFF_T)
 444
 445 IF(HAVE_SIZEOF_LONG_LONG)
 446   SET(HAVE_LONGLONG 1)
 447   SET(HAVE_LL 1)
 448 ENDIF(HAVE_SIZEOF_LONG_LONG)
 449
 450 FIND_FILE(RANDOM_FILE urandom /dev)
 451 MARK_AS_ADVANCED(RANDOM_FILE)
 452
 453 # Check for some functions that are used
 454 CHECK_SYMBOL_EXISTS(basename      "${CURL_INCLUDES}" HAVE_BASENAME)
 455 CHECK_SYMBOL_EXISTS(socket        "${CURL_INCLUDES}" HAVE_SOCKET)
 456 CHECK_SYMBOL_EXISTS(poll          "${CURL_INCLUDES}" HAVE_POLL)
 457 CHECK_SYMBOL_EXISTS(select        "${CURL_INCLUDES}" HAVE_SELECT)
 458 CHECK_SYMBOL_EXISTS(strdup        "${CURL_INCLUDES}" HAVE_STRDUP)
 459 CHECK_SYMBOL_EXISTS(strstr        "${CURL_INCLUDES}" HAVE_STRSTR)
 460 CHECK_SYMBOL_EXISTS(strtok_r      "${CURL_INCLUDES}" HAVE_STRTOK_R)
 461 CHECK_SYMBOL_EXISTS(strftime      "${CURL_INCLUDES}" HAVE_STRFTIME)
 462 CHECK_SYMBOL_EXISTS(uname         "${CURL_INCLUDES}" HAVE_UNAME)
 463 CHECK_SYMBOL_EXISTS(strcasecmp    "${CURL_INCLUDES}" HAVE_STRCASECMP)
 464 CHECK_SYMBOL_EXISTS(stricmp       "${CURL_INCLUDES}" HAVE_STRICMP)
 465 CHECK_SYMBOL_EXISTS(strcmpi       "${CURL_INCLUDES}" HAVE_STRCMPI)
 466 CHECK_SYMBOL_EXISTS(strncmpi      "${CURL_INCLUDES}" HAVE_STRNCMPI)
 467 CHECK_SYMBOL_EXISTS(alarm         "${CURL_INCLUDES}" HAVE_ALARM)
 468 IF(NOT HAVE_STRNCMPI)
 469   SET(HAVE_STRCMPI)
 470 ENDIF(NOT HAVE_STRNCMPI)
 471 CHECK_SYMBOL_EXISTS(gethostbyaddr "${CURL_INCLUDES}" HAVE_GETHOSTBYADDR)
 472 CHECK_SYMBOL_EXISTS(gethostbyaddr_r "${CURL_INCLUDES}" HAVE_GETHOSTBYADDR_R)
 473 CHECK_SYMBOL_EXISTS(gettimeofday  "${CURL_INCLUDES}" HAVE_GETTIMEOFDAY)
 474 CHECK_SYMBOL_EXISTS(inet_addr     "${CURL_INCLUDES}" HAVE_INET_ADDR)
 475 CHECK_SYMBOL_EXISTS(inet_ntoa     "${CURL_INCLUDES}" HAVE_INET_NTOA)
 476 CHECK_SYMBOL_EXISTS(inet_ntoa_r   "${CURL_INCLUDES}" HAVE_INET_NTOA_R)
 477 CHECK_SYMBOL_EXISTS(tcsetattr     "${CURL_INCLUDES}" HAVE_TCSETATTR)
 478 CHECK_SYMBOL_EXISTS(tcgetattr     "${CURL_INCLUDES}" HAVE_TCGETATTR)
 479 CHECK_SYMBOL_EXISTS(perror        "${CURL_INCLUDES}" HAVE_PERROR)
 480 CHECK_SYMBOL_EXISTS(closesocket   "${CURL_INCLUDES}" HAVE_CLOSESOCKET)
 481 CHECK_SYMBOL_EXISTS(setvbuf       "${CURL_INCLUDES}" HAVE_SETVBUF)
 482 CHECK_SYMBOL_EXISTS(sigsetjmp     "${CURL_INCLUDES}" HAVE_SIGSETJMP)
 483 CHECK_SYMBOL_EXISTS(getpass_r     "${CURL_INCLUDES}" HAVE_GETPASS_R)
 484 CHECK_SYMBOL_EXISTS(strlcat       "${CURL_INCLUDES}" HAVE_STRLCAT)
 485 CHECK_SYMBOL_EXISTS(getpwuid      "${CURL_INCLUDES}" HAVE_GETPWUID)
 486 CHECK_SYMBOL_EXISTS(geteuid       "${CURL_INCLUDES}" HAVE_GETEUID)
 487 CHECK_SYMBOL_EXISTS(utime         "${CURL_INCLUDES}" HAVE_UTIME)
 488 IF(CMAKE_USE_OPENSSL)
 489   CHECK_SYMBOL_EXISTS(RAND_status   "${CURL_INCLUDES}" HAVE_RAND_STATUS)
 490   CHECK_SYMBOL_EXISTS(RAND_screen   "${CURL_INCLUDES}" HAVE_RAND_SCREEN)
 491   CHECK_SYMBOL_EXISTS(RAND_egd      "${CURL_INCLUDES}" HAVE_RAND_EGD)
 492   CHECK_SYMBOL_EXISTS(CRYPTO_cleanup_all_ex_data "${CURL_INCLUDES}"
 493     HAVE_CRYPTO_CLEANUP_ALL_EX_DATA)
 494   IF(HAVE_LIBCRYPTO AND HAVE_LIBSSL)
 495   SET(USE_OPENSSL 1)
 496   SET(USE_SSLEAY 1)
 497   ENDIF(HAVE_LIBCRYPTO AND HAVE_LIBSSL)
 498 ENDIF(CMAKE_USE_OPENSSL)
 499 CHECK_SYMBOL_EXISTS(gmtime_r      "${CURL_INCLUDES}" HAVE_GMTIME_R)
 500 CHECK_SYMBOL_EXISTS(localtime_r   "${CURL_INCLUDES}" HAVE_LOCALTIME_R)
 501
 502 CHECK_SYMBOL_EXISTS(gethostbyname   "${CURL_INCLUDES}" HAVE_GETHOSTBYNAME)
 503 CHECK_SYMBOL_EXISTS(gethostbyname_r "${CURL_INCLUDES}" HAVE_GETHOSTBYNAME_R)
 504
 505 CHECK_SYMBOL_EXISTS(signal        "${CURL_INCLUDES}" HAVE_SIGNAL_FUNC)
 506 CHECK_SYMBOL_EXISTS(SIGALRM       "${CURL_INCLUDES}" HAVE_SIGNAL_MACRO)
 507 IF(HAVE_SIGNAL_FUNC AND HAVE_SIGNAL_MACRO)
 508   SET(HAVE_SIGNAL 1)
 509 ENDIF(HAVE_SIGNAL_FUNC AND HAVE_SIGNAL_MACRO)
 510 CHECK_SYMBOL_EXISTS(uname          "${CURL_INCLUDES}" HAVE_UNAME)
 511 CHECK_SYMBOL_EXISTS(strtoll        "${CURL_INCLUDES}" HAVE_STRTOLL)
 512 CHECK_SYMBOL_EXISTS(_strtoi64      "${CURL_INCLUDES}" HAVE__STRTOI64)
 513 CHECK_SYMBOL_EXISTS(strerror_r     "${CURL_INCLUDES}" HAVE_STRERROR_R)
 514 CHECK_SYMBOL_EXISTS(siginterrupt   "${CURL_INCLUDES}" HAVE_SIGINTERRUPT)
 515 CHECK_SYMBOL_EXISTS(perror         "${CURL_INCLUDES}" HAVE_PERROR)
 516 CHECK_SYMBOL_EXISTS(fork           "${CURL_INCLUDES}" HAVE_FORK)
 517 CHECK_SYMBOL_EXISTS(freeaddrinfo   "${CURL_INCLUDES}" HAVE_FREEADDRINFO)
 518 CHECK_SYMBOL_EXISTS(freeifaddrs    "${CURL_INCLUDES}" HAVE_FREEIFADDRS)
 519 CHECK_SYMBOL_EXISTS(pipe           "${CURL_INCLUDES}" HAVE_PIPE)
 520 CHECK_SYMBOL_EXISTS(ftruncate      "${CURL_INCLUDES}" HAVE_FTRUNCATE)
 521 CHECK_SYMBOL_EXISTS(getprotobyname "${CURL_INCLUDES}" HAVE_GETPROTOBYNAME)
 522 CHECK_SYMBOL_EXISTS(getrlimit      "${CURL_INCLUDES}" HAVE_GETRLIMIT)
 523 CHECK_SYMBOL_EXISTS(idn_free       "${CURL_INCLUDES}" HAVE_IDN_FREE)
 524 CHECK_SYMBOL_EXISTS(idna_strerror  "${CURL_INCLUDES}" HAVE_IDNA_STRERROR)
 525 CHECK_SYMBOL_EXISTS(tld_strerror   "${CURL_INCLUDES}" HAVE_TLD_STRERROR)
 526 CHECK_SYMBOL_EXISTS(setlocale      "${CURL_INCLUDES}" HAVE_SETLOCALE)
 527 CHECK_SYMBOL_EXISTS(setrlimit      "${CURL_INCLUDES}" HAVE_SETRLIMIT)
 528 CHECK_SYMBOL_EXISTS(fcntl          "${CURL_INCLUDES}" HAVE_FCNTL)
 529 CHECK_SYMBOL_EXISTS(ioctl          "${CURL_INCLUDES}" HAVE_IOCTL)
 530 CHECK_SYMBOL_EXISTS(setsockopt     "${CURL_INCLUDES}" HAVE_SETSOCKOPT)
 531
 532 # symbol exists in win32, but function does not.
 533 CHECK_FUNCTION_EXISTS(inet_pton HAVE_INET_PTON)
 534
 535 # sigaction and sigsetjmp are special. Use special mechanism for
 536 # detecting those, but only if previous attempt failed.
 537 IF(HAVE_SIGNAL_H)
 538   CHECK_SYMBOL_EXISTS(sigaction "signal.h" HAVE_SIGACTION)
 539 ENDIF(HAVE_SIGNAL_H)
 540
 541 IF(NOT HAVE_SIGSETJMP)
 542   IF(HAVE_SETJMP_H)
 543     CHECK_SYMBOL_EXISTS(sigsetjmp "setjmp.h" HAVE_MACRO_SIGSETJMP)
 544     IF(HAVE_MACRO_SIGSETJMP)
 545       SET(HAVE_SIGSETJMP 1)
 546     ENDIF(HAVE_MACRO_SIGSETJMP)
 547   ENDIF(HAVE_SETJMP_H)
 548 ENDIF(NOT HAVE_SIGSETJMP)
 549
 550 # If there is no stricmp(), do not allow LDAP to parse URLs
 551 if(NOT HAVE_STRICMP)
 552     SET(HAVE_LDAP_URL_PARSE 1)
 553 endif(NOT HAVE_STRICMP)
 554
 555 # For other curl specific tests, use this macro.
 556 MACRO(CURL_INTERNAL_TEST CURL_TEST)
 557   IF("${CURL_TEST}" MATCHES "^${CURL_TEST}$")
 558     SET(MACRO_CHECK_FUNCTION_DEFINITIONS
 559       "-D${CURL_TEST} ${CURL_TEST_DEFINES} ${CMAKE_REQUIRED_FLAGS}")
 560     IF(CMAKE_REQUIRED_LIBRARIES)
 561       SET(CURL_TEST_ADD_LIBRARIES
 562         "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
 563     ENDIF(CMAKE_REQUIRED_LIBRARIES)
 564
 565     MESSAGE(STATUS "Performing Curl Test ${CURL_TEST}")
 566     TRY_COMPILE(${CURL_TEST}
 567       ${CMAKE_BINARY_DIR}
 568       ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CurlTests.c
 569       CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
 570       "${CURL_TEST_ADD_LIBRARIES}"
 571       OUTPUT_VARIABLE OUTPUT)
 572     IF(${CURL_TEST})
 573       SET(${CURL_TEST} 1 CACHE INTERNAL "Curl test ${FUNCTION}")
 574       MESSAGE(STATUS "Performing Curl Test ${CURL_TEST} - Success")
 575       FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 576         "Performing Curl Test ${CURL_TEST} passed with the following output:\n"
 577         "${OUTPUT}\n")
 578     ELSE(${CURL_TEST})
 579       MESSAGE(STATUS "Performing Curl Test ${CURL_TEST} - Failed")
 580       SET(${CURL_TEST} "" CACHE INTERNAL "Curl test ${FUNCTION}")
 581       FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
 582         "Performing Curl Test ${CURL_TEST} failed with the following output:\n"
 583         "${OUTPUT}\n")
 584     ENDIF(${CURL_TEST})
 585   ENDIF("${CURL_TEST}" MATCHES "^${CURL_TEST}$")
 586 ENDMACRO(CURL_INTERNAL_TEST)
 587
 588 MACRO(CURL_INTERNAL_TEST_RUN CURL_TEST)
 589   IF("${CURL_TEST}_COMPILE" MATCHES "^${CURL_TEST}_COMPILE$")
 590     SET(MACRO_CHECK_FUNCTION_DEFINITIONS
 591       "-D${CURL_TEST} ${CMAKE_REQUIRED_FLAGS}")
 592     IF(CMAKE_REQUIRED_LIBRARIES)
 593       SET(CURL_TEST_ADD_LIBRARIES
 594         "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
 595     ENDIF(CMAKE_REQUIRED_LIBRARIES)
 596
 597     MESSAGE(STATUS "Performing Curl Test ${CURL_TEST}")
 598     TRY_RUN(${CURL_TEST} ${CURL_TEST}_COMPILE
 599       ${CMAKE_BINARY_DIR}
 600       ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CurlTests.c
 601       CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
 602       "${CURL_TEST_ADD_LIBRARIES}"
 603       OUTPUT_VARIABLE OUTPUT)
 604     IF(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 605       SET(${CURL_TEST} 1 CACHE INTERNAL "Curl test ${FUNCTION}")
 606       MESSAGE(STATUS "Performing Curl Test ${CURL_TEST} - Success")
 607     ELSE(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 608       MESSAGE(STATUS "Performing Curl Test ${CURL_TEST} - Failed")
 609       SET(${CURL_TEST} "" CACHE INTERNAL "Curl test ${FUNCTION}")
 610       FILE(APPEND "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 611         "Performing Curl Test ${CURL_TEST} failed with the following output:\n"
 612         "${OUTPUT}")
 613       IF(${CURL_TEST}_COMPILE)
 614         FILE(APPEND
 615           "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 616           "There was a problem running this test\n")
 617       ENDIF(${CURL_TEST}_COMPILE)
 618       FILE(APPEND "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 619         "\n\n")
 620     ENDIF(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 621   ENDIF("${CURL_TEST}_COMPILE" MATCHES "^${CURL_TEST}_COMPILE$")
 622 ENDMACRO(CURL_INTERNAL_TEST_RUN)
 623
 624 # Do curl specific tests
 625 FOREACH(CURL_TEST
 626     HAVE_FCNTL_O_NONBLOCK
 627     HAVE_IOCTLSOCKET
 628     HAVE_IOCTLSOCKET_CAMEL
 629     HAVE_IOCTLSOCKET_CAMEL_FIONBIO
 630     HAVE_IOCTLSOCKET_FIONBIO
 631     HAVE_IOCTL_FIONBIO
 632     HAVE_IOCTL_SIOCGIFADDR
 633     HAVE_SETSOCKOPT_SO_NONBLOCK
 634     HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID
 635     TIME_WITH_SYS_TIME
 636     HAVE_O_NONBLOCK
 637     HAVE_GETHOSTBYADDR_R_5
 638     HAVE_GETHOSTBYADDR_R_7
 639     HAVE_GETHOSTBYADDR_R_8
 640     HAVE_GETHOSTBYADDR_R_5_REENTRANT
 641     HAVE_GETHOSTBYADDR_R_7_REENTRANT
 642     HAVE_GETHOSTBYADDR_R_8_REENTRANT
 643     HAVE_GETHOSTBYNAME_R_3
 644     HAVE_GETHOSTBYNAME_R_5
 645     HAVE_GETHOSTBYNAME_R_6
 646     HAVE_GETHOSTBYNAME_R_3_REENTRANT
 647     HAVE_GETHOSTBYNAME_R_5_REENTRANT
 648     HAVE_GETHOSTBYNAME_R_6_REENTRANT
 649     HAVE_SOCKLEN_T
 650     HAVE_IN_ADDR_T
 651     HAVE_BOOL_T
 652     STDC_HEADERS
 653     RETSIGTYPE_TEST
 654     HAVE_INET_NTOA_R_DECL
 655     HAVE_INET_NTOA_R_DECL_REENTRANT
 656     HAVE_GETADDRINFO
 657     HAVE_FILE_OFFSET_BITS
 658     )
 659   CURL_INTERNAL_TEST(${CURL_TEST})
 660 ENDFOREACH(CURL_TEST)
 661 IF(HAVE_FILE_OFFSET_BITS)
 662   SET(_FILE_OFFSET_BITS 64)
 663 ENDIF(HAVE_FILE_OFFSET_BITS)
 664
 665 FOREACH(CURL_TEST
 666     HAVE_GLIBC_STRERROR_R
 667     HAVE_POSIX_STRERROR_R
 668     )
 669   CURL_INTERNAL_TEST_RUN(${CURL_TEST})
 670 ENDFOREACH(CURL_TEST)
 671
 672 # Check for reentrant
 673 FOREACH(CURL_TEST
 674     HAVE_GETHOSTBYADDR_R_5
 675     HAVE_GETHOSTBYADDR_R_7
 676     HAVE_GETHOSTBYADDR_R_8
 677     HAVE_GETHOSTBYNAME_R_3
 678     HAVE_GETHOSTBYNAME_R_5
 679     HAVE_GETHOSTBYNAME_R_6
 680     HAVE_INET_NTOA_R_DECL_REENTRANT)
 681   IF(NOT ${CURL_TEST})
 682     IF(${CURL_TEST}_REENTRANT)
 683       SET(NEED_REENTRANT 1)
 684     ENDIF(${CURL_TEST}_REENTRANT)
 685   ENDIF(NOT ${CURL_TEST})
 686 ENDFOREACH(CURL_TEST)
 687
 688 IF(NEED_REENTRANT)
 689   FOREACH(CURL_TEST
 690       HAVE_GETHOSTBYADDR_R_5
 691       HAVE_GETHOSTBYADDR_R_7
 692       HAVE_GETHOSTBYADDR_R_8
 693       HAVE_GETHOSTBYNAME_R_3
 694       HAVE_GETHOSTBYNAME_R_5
 695       HAVE_GETHOSTBYNAME_R_6)
 696     SET(${CURL_TEST} 0)
 697     IF(${CURL_TEST}_REENTRANT)
 698       SET(${CURL_TEST} 1)
 699     ENDIF(${CURL_TEST}_REENTRANT)
 700   ENDFOREACH(CURL_TEST)
 701 ENDIF(NEED_REENTRANT)
 702
 703 IF(HAVE_INET_NTOA_R_DECL_REENTRANT)
 704   SET(HAVE_INET_NTOA_R_DECL 1)
 705   SET(NEED_REENTRANT 1)
 706 ENDIF(HAVE_INET_NTOA_R_DECL_REENTRANT)
 707
 708 # Some other minor tests
 709
 710 IF(NOT HAVE_SOCKLEN_T)
 711   SET(socklen_t "int")
 712 ENDIF(NOT HAVE_SOCKLEN_T)
 713
 714 IF(NOT HAVE_IN_ADDR_T)
 715   SET(in_addr_t "unsigned long")
 716 ENDIF(NOT HAVE_IN_ADDR_T)
 717
 718 # Fix libz / zlib.h
 719
 720 IF(NOT CURL_SPECIAL_LIBZ)
 721   IF(NOT HAVE_LIBZ)
 722     SET(HAVE_ZLIB_H 0)
 723   ENDIF(NOT HAVE_LIBZ)
 724
 725   IF(NOT HAVE_ZLIB_H)
 726     SET(HAVE_LIBZ 0)
 727   ENDIF(NOT HAVE_ZLIB_H)
 728 ENDIF(NOT CURL_SPECIAL_LIBZ)
 729
 730 IF(_FILE_OFFSET_BITS)
 731   SET(_FILE_OFFSET_BITS 64)
 732 ENDIF(_FILE_OFFSET_BITS)
 733 SET(CMAKE_REQUIRED_FLAGS "-D_FILE_OFFSET_BITS=64")
 734 SET(CMAKE_EXTRA_INCLUDE_FILES "${CMAKE_CURRENT_SOURCE_DIR}/curl/curl.h")
 735 CHECK_TYPE_SIZE("curl_off_t" SIZEOF_CURL_OFF_T)
 736 SET(CMAKE_EXTRA_INCLUDE_FILES)
 737 SET(CMAKE_REQUIRED_FLAGS)
 738
 739
 740 # Check for nonblocking
 741 SET(HAVE_DISABLED_NONBLOCKING 1)
 742 IF(HAVE_FIONBIO OR
 743     HAVE_IOCTLSOCKET OR
 744     HAVE_IOCTLSOCKET_CASE OR
 745     HAVE_O_NONBLOCK)
 746   SET(HAVE_DISABLED_NONBLOCKING)
 747 ENDIF(HAVE_FIONBIO OR
 748   HAVE_IOCTLSOCKET OR
 749   HAVE_IOCTLSOCKET_CASE OR
 750   HAVE_O_NONBLOCK)
 751
 752 IF(RETSIGTYPE_TEST)
 753   SET(RETSIGTYPE void)
 754 ELSE(RETSIGTYPE_TEST)
 755   SET(RETSIGTYPE int)
 756 ENDIF(RETSIGTYPE_TEST)
 757
 758 IF(CMAKE_COMPILER_IS_GNUCC AND APPLE)
 759   INCLUDE(CheckCCompilerFlag)
 760   CHECK_C_COMPILER_FLAG(-Wno-long-double HAVE_C_FLAG_Wno_long_double)
 761   IF(HAVE_C_FLAG_Wno_long_double)
 762     # The Mac version of GCC warns about use of long double.  Disable it.
 763     GET_SOURCE_FILE_PROPERTY(MPRINTF_COMPILE_FLAGS mprintf.c COMPILE_FLAGS)
 764     IF(MPRINTF_COMPILE_FLAGS)
 765       SET(MPRINTF_COMPILE_FLAGS "${MPRINTF_COMPILE_FLAGS} -Wno-long-double")
 766     ELSE(MPRINTF_COMPILE_FLAGS)
 767       SET(MPRINTF_COMPILE_FLAGS "-Wno-long-double")
 768     ENDIF(MPRINTF_COMPILE_FLAGS)
 769     SET_SOURCE_FILES_PROPERTIES(mprintf.c PROPERTIES
 770       COMPILE_FLAGS ${MPRINTF_COMPILE_FLAGS})
 771   ENDIF(HAVE_C_FLAG_Wno_long_double)
 772 ENDIF(CMAKE_COMPILER_IS_GNUCC AND APPLE)
 773
 774 INCLUDE(CMake/OtherTests.cmake)
 775
 776 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 777
 778 # For windows, do not allow the compiler to use default target (Vista).
 779 IF(WIN32)
 780   ADD_DEFINITIONS(-D_WIN32_WINNT=0x0501)
 781 ENDIF(WIN32)
 782
 783 IF(MSVC)
 784   ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 785 ENDIF(MSVC)
 786
 787 # Sets up the dependencies (zlib, OpenSSL, etc.) of a cURL subproject according to options.
 788 # TODO This is far to be complete!
 789 FUNCTION(SETUP_CURL_DEPENDENCIES TARGET_NAME)
 790   IF(CURL_ZLIB AND ZLIB_FOUND)
 791     INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 792   ENDIF()
 793   IF(CURL_ZLIB AND ZLIB_FOUND)
 794     TARGET_LINK_LIBRARIES(${TARGET_NAME} ${ZLIB_LIBRARIES})
 795     #ADD_DEFINITIONS( -DHAVE_ZLIB_H -DHAVE_ZLIB -DHAVE_LIBZ )
 796   ENDIF()
 797
 798   IF(CMAKE_USE_OPENSSL AND OPENSSL_FOUND)
 799     INCLUDE_DIRECTORIES(${OPENSSL_INCLUDE_DIR})
 800   ENDIF()
 801   IF(CURL_SSL AND CURL_CONFIG_HAS_BEEN_RUN_BEFORE)
 802     TARGET_LINK_LIBRARIES(${TARGET_NAME} ${OPENSSL_LIBRARIES})
 803     #ADD_DEFINITIONS( -DUSE_SSLEAY )
 804   ENDIF()
 805 ENDFUNCTION()
 806
 807 # Ugly (but functional) way to include "Makefile.inc" by transforming it (= regenerate it).
 808 FUNCTION(TRANSFORM_MAKEFILE_INC INPUT_FILE OUTPUT_FILE)
 809   FILE(READ ${INPUT_FILE} MAKEFILE_INC_TEXT)
 810   STRING(REPLACE "$(top_srcdir)"   "\${CURL_SOURCE_DIR}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 811   STRING(REPLACE "$(top_builddir)" "\${CURL_BINARY_DIR}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 812
 813   STRING(REGEX REPLACE "\\\\\n" "§!§" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 814   STRING(REGEX REPLACE "([a-zA-Z_][a-zA-Z0-9_]*)[\t ]*=[\t ]*([^\n]*\n)" "SET(\\1 \\2)\n" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 815   STRING(REPLACE "§!§" "\n" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 816
 817   STRING(REGEX REPLACE "\\$\\(([a-zA-Z_][a-zA-Z0-9_]*)\\)" "\${\\1}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Replace $() with ${}
 818   STRING(REGEX REPLACE "@([a-zA-Z_][a-zA-Z0-9_]*)@" "\${\\1}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Replace @@ with ${}, even if that may not be read by CMake scripts.
 819   FILE(WRITE ${OUTPUT_FILE} ${MAKEFILE_INC_TEXT})
 820
 821   ### BUGGY METHOD 1
 822   # FILE(STRINGS Makefile.inc MAKEFILE_INC_TEXT)
 823   # STRING(REPLACE "# ./lib/Makefile.inc" "" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 824   # STRING(REPLACE "  " " " MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Replace tabs with spaces
 825
 826   # #STRING(REGEX MATCH "CSOURCES *=" AAA ${MAKEFILE_INC_TEXT})
 827   # #MESSAGE(STATUS ${AAA})
 828
 829   # STRING(REPLACE "CSOURCES =" "" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 830   # STRING(REPLACE "HHEADERS =" "" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 831
 832   # STRING(REGEX REPLACE "[^ ]+\\.c" "" ${HEADERS_VAR} ${MAKEFILE_INC_TEXT})    # Remove source files and store into headers var
 833   # STRING(REGEX REPLACE "  +" " " ${HEADERS_VAR} ${${HEADERS_VAR}})
 834   # STRING(REGEX REPLACE " " ";" ${HEADERS_VAR} ${${HEADERS_VAR}})
 835
 836   # STRING(REGEX REPLACE "[^ ]+\\.h" "" ${SOURCES_VAR} ${MAKEFILE_INC_TEXT})    # Remove headers and store into source files var
 837   # STRING(REGEX REPLACE "  +" " " ${SOURCES_VAR} ${${SOURCES_VAR}})
 838   # STRING(REGEX REPLACE " " ";" ${SOURCES_VAR} ${${SOURCES_VAR}})
 839
 840   # SET(${HEADERS_VAR} ${${HEADERS_VAR}} PARENT_SCOPE)
 841   # SET(${SOURCES_VAR} ${${SOURCES_VAR}} PARENT_SCOPE)
 842
 843   ### BUGGY METHOD 2
 844   # FILE(READ Makefile.inc MAKEFILE_INC_TEXT)
 845   # #STRING(REPLACE "\t" " " MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Replace tabs with spaces
 846   # #STRING(REGEX REPLACE "\n+" "\n" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Remove empty lines (allow a simplification in the script)
 847   # STRING(REGEX REPLACE "([A-Z]+)[\t ]*=[\t ]*" "SET(\\1 " MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 848   # #STRING(REGEX REPLACE "^(.*)[\t ]*[^\\]$" ")" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 849   # STRING(REGEX REPLACE "([^\\])\n" "\\1)\n" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 850   # # STRING(REGEX REPLACE "CSOURCES *=" "SET(libCurl_SRCS " MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 851   # # STRING(REGEX REPLACE "HHEADERS *=" "SET(libCurl_HEADERS " MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 852   # FILE(WRITE Makefile.inc.cmake ${MAKEFILE_INC_TEXT})
 853 ENDFUNCTION()
 854
 855 ADD_SUBDIRECTORY(lib)
 856 IF(BUILD_CURL_EXE)
 857   ADD_SUBDIRECTORY(src)
 858 ENDIF()
 859 IF(BUILD_CURL_TESTS)
 860   ADD_SUBDIRECTORY(tests)
 861 ENDIF()
 862
 863 # This needs to be run very last so other parts of the scripts can take advantage of this.
 864 IF(NOT CURL_CONFIG_HAS_BEEN_RUN_BEFORE)
 865     SET(CURL_CONFIG_HAS_BEEN_RUN_BEFORE 1 CACHE INTERNAL "Flag to track whether this is the first time running CMake or if CMake has been configured before")
 866 ENDIF()