CMakeLists.txt

   1 # cURL/libcurl CMake script
   2 # by Tetetest and Sukender (Benoit Neil)
   3
   4 # TODO:
   5 # The output .so file lacks the soname number which we currently have within the lib/Makefile.am file
   6 # Add full (4 or 5 libs) SSL support
   7 # Add INSTALL target (EXTRA_DIST variables in Makefile.am may be moved to Makefile.inc so that CMake/CPack is aware of what's to include).
   8 # Add CTests(?)
   9 # Check on all possible platforms
  10 # Test with as many configurations possible (With or without any option)
  11 # Create scripts that help keeping the CMake build system up to date (to reduce maintenance). According to Tetetest:
  12 #  - lists of headers that 'configure' checks for;
  13 #  - curl-specific tests (the ones that are in m4/curl-*.m4 files);
  14 #  - (most obvious thing:) curl version numbers.
  15 # Add documentation subproject
  16 #
  17 # To check:
  18 # (From Daniel Stenberg) The cmake build selected to run gcc with -fPIC on my box while the plain configure script did not.
  19 # (From Daniel Stenberg) The gcc command line use neither -g nor any -O options. As a developer, I also treasure our configure scripts's --enable-debug option that sets a long range of "picky" compiler options.
  20 cmake_minimum_required(VERSION 2.6.2 FATAL_ERROR)
  21 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake;${CMAKE_MODULE_PATH}")
  22 include(Utilities)
  23
  24 project( CURL C )
  25
  26 file (READ ${CURL_SOURCE_DIR}/include/curl/curlver.h CURL_VERSION_H_CONTENTS)
  27 string (REGEX MATCH "LIBCURL_VERSION_MAJOR[ \t]+([0-9]+)"
  28   LIBCURL_VERSION_MJ ${CURL_VERSION_H_CONTENTS})
  29 string (REGEX MATCH "([0-9]+)"
  30   LIBCURL_VERSION_MJ ${LIBCURL_VERSION_MJ})
  31 string (REGEX MATCH
  32   "LIBCURL_VERSION_MINOR[ \t]+([0-9]+)"
  33   LIBCURL_VERSION_MI ${CURL_VERSION_H_CONTENTS})
  34 string (REGEX MATCH "([0-9]+)" LIBCURL_VERSION_MI ${LIBCURL_VERSION_MI})
  35 string (REGEX MATCH
  36   "LIBCURL_VERSION_PATCH[ \t]+([0-9]+)"
  37   LIBCURL_VERSION_PT ${CURL_VERSION_H_CONTENTS})
  38 string (REGEX MATCH "([0-9]+)" LIBCURL_VERSION_PT ${LIBCURL_VERSION_PT})
  39 set (CURL_MAJOR_VERSION ${LIBCURL_VERSION_MJ})
  40 set (CURL_MINOR_VERSION ${LIBCURL_VERSION_MI})
  41 set (CURL_PATCH_VERSION ${LIBCURL_VERSION_PT})
  42
  43 include_regular_expression("^.*$")    # Sukender: Is it necessary?
  44
  45 # Setup package meta-data
  46 # SET(PACKAGE "curl")
  47 set(CURL_VERSION ${CURL_MAJOR_VERSION}.${CURL_MINOR_VERSION}.${CURL_PATCH_VERSION})
  48 message(STATUS "curl version=[${CURL_VERSION}]")
  49 # SET(PACKAGE_TARNAME "curl")
  50 # SET(PACKAGE_NAME "curl")
  51 # SET(PACKAGE_VERSION "-")
  52 # SET(PACKAGE_STRING "curl-")
  53 # SET(PACKAGE_BUGREPORT "a suitable curl mailing list => http://curl.haxx.se/mail/")
  54 set(OPERATING_SYSTEM "${CMAKE_SYSTEM_NAME}")
  55 set(OS "\"${CMAKE_SYSTEM_NAME}\"")
  56
  57 include_directories(${PROJECT_BINARY_DIR}/include/curl)
  58 include_directories( ${CURL_SOURCE_DIR}/include )
  59
  60 option(BUILD_CURL_EXE "Set to ON to build cURL executable." ON)
  61 option(BUILD_CURL_TESTS "Set to ON to build cURL tests." ON)
  62 option(CURL_STATICLIB "Set to ON to build libcurl with static linking." OFF)
  63 option(CURL_USE_ARES "Set to ON to enable c-ares support" OFF)
  64 # initialize CURL_LIBS
  65 set(CURL_LIBS "")
  66
  67 if(CURL_USE_ARES)
  68   set(USE_ARES ${CURL_USE_ARES})
  69   find_package(CARES REQUIRED)
  70   list(APPEND CURL_LIBS ${CARES_LIBRARY} )
  71   set(CURL_LIBS ${CURL_LIBS} ${CARES_LIBRARY})
  72 endif()
  73
  74 option(BUILD_DASHBOARD_REPORTS "Set to ON to activate reporting of cURL builds here http://www.cdash.org/CDashPublic/index.php?project=CURL" OFF)
  75 if(BUILD_DASHBOARD_REPORTS)
  76   #INCLUDE(Dart)
  77   include(CTest)
  78 endif(BUILD_DASHBOARD_REPORTS)
  79
  80 if(MSVC)
  81   option(BUILD_RELEASE_DEBUG_DIRS "Set OFF to build each configuration to a separate directory" OFF)
  82   mark_as_advanced(BUILD_RELEASE_DEBUG_DIRS)
  83 endif()
  84
  85 option(CURL_HIDDEN_SYMBOLS "Set to ON to hide libcurl internal symbols (=hide all symbols that aren't officially external)." ON)
  86 mark_as_advanced(CURL_HIDDEN_SYMBOLS)
  87
  88 # IF(WIN32)
  89 # OPTION(CURL_WINDOWS_SSPI "Use windows libraries to allow NTLM authentication without openssl" ON)
  90 # MARK_AS_ADVANCED(CURL_WINDOWS_SSPI)
  91 # ENDIF()
  92
  93 option(HTTP_ONLY "disables all protocols except HTTP (This overrides all CURL_DISABLE_* options)" OFF)
  94 mark_as_advanced(HTTP_ONLY)
  95 option(CURL_DISABLE_FTP "disables FTP" OFF)
  96 mark_as_advanced(CURL_DISABLE_FTP)
  97 option(CURL_DISABLE_LDAP "disables LDAP" OFF)
  98 mark_as_advanced(CURL_DISABLE_LDAP)
  99 option(CURL_DISABLE_TELNET "disables Telnet" OFF)
 100 mark_as_advanced(CURL_DISABLE_TELNET)
 101 option(CURL_DISABLE_DICT "disables DICT" OFF)
 102 mark_as_advanced(CURL_DISABLE_DICT)
 103 option(CURL_DISABLE_FILE "disables FILE" OFF)
 104 mark_as_advanced(CURL_DISABLE_FILE)
 105 option(CURL_DISABLE_TFTP "disables TFTP" OFF)
 106 mark_as_advanced(CURL_DISABLE_TFTP)
 107 option(CURL_DISABLE_HTTP "disables HTTP" OFF)
 108 mark_as_advanced(CURL_DISABLE_HTTP)
 109
 110 option(CURL_DISABLE_LDAPS "to disable LDAPS" OFF)
 111 mark_as_advanced(CURL_DISABLE_LDAPS)
 112
 113 if(HTTP_ONLY)
 114   set(CURL_DISABLE_FTP ON)
 115   set(CURL_DISABLE_LDAP ON)
 116   set(CURL_DISABLE_LDAPS ON)
 117   set(CURL_DISABLE_TELNET ON)
 118   set(CURL_DISABLE_DICT ON)
 119   set(CURL_DISABLE_FILE ON)
 120   set(CURL_DISABLE_TFTP ON)
 121 endif()
 122
 123 option(CURL_DISABLE_COOKIES "to disable cookies support" OFF)
 124 mark_as_advanced(CURL_DISABLE_COOKIES)
 125
 126 option(CURL_DISABLE_CRYPTO_AUTH "to disable cryptographic authentication" OFF)
 127 mark_as_advanced(CURL_DISABLE_CRYPTO_AUTH)
 128 option(CURL_DISABLE_VERBOSE_STRINGS "to disable verbose strings" OFF)
 129 mark_as_advanced(CURL_DISABLE_VERBOSE_STRINGS)
 130 option(DISABLED_THREADSAFE "Set to explicitly specify we don't want to use thread-safe functions" OFF)
 131 mark_as_advanced(DISABLED_THREADSAFE)
 132 option(ENABLE_IPV6 "Define if you want to enable IPv6 support" OFF)
 133 mark_as_advanced(ENABLE_IPV6)
 134
 135
 136 # We need ansi c-flags, especially on HP
 137 set(CMAKE_C_FLAGS "${CMAKE_ANSI_CFLAGS} ${CMAKE_C_FLAGS}")
 138 set(CMAKE_REQUIRED_FLAGS ${CMAKE_ANSI_CFLAGS})
 139
 140 # Disable warnings on Borland to avoid changing 3rd party code.
 141 if(BORLAND)
 142   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -w-")
 143 endif(BORLAND)
 144
 145 # If we are on AIX, do the _ALL_SOURCE magic
 146 if(${CMAKE_SYSTEM_NAME} MATCHES AIX)
 147   set(_ALL_SOURCE 1)
 148 endif(${CMAKE_SYSTEM_NAME} MATCHES AIX)
 149
 150 # Include all the necessary files for macros
 151 include (CheckFunctionExists)
 152 include (CheckIncludeFile)
 153 include (CheckIncludeFiles)
 154 include (CheckLibraryExists)
 155 include (CheckSymbolExists)
 156 include (CheckTypeSize)
 157
 158 # On windows preload settings
 159 if(WIN32)
 160   include(${CMAKE_CURRENT_SOURCE_DIR}/CMake/Platforms/WindowsCache.cmake)
 161 endif(WIN32)
 162
 163 # This macro checks if the symbol exists in the library and if it
 164 # does, it prepends library to the list.
 165 macro(CHECK_LIBRARY_EXISTS_CONCAT LIBRARY SYMBOL VARIABLE)
 166   check_library_exists("${LIBRARY};${CURL_LIBS}" ${SYMBOL} "${CMAKE_LIBRARY_PATH}"
 167     ${VARIABLE})
 168   if(${VARIABLE})
 169     set(CURL_LIBS ${LIBRARY} ${CURL_LIBS})
 170   endif(${VARIABLE})
 171 endmacro(CHECK_LIBRARY_EXISTS_CONCAT)
 172
 173 # Check for all needed libraries
 174 check_library_exists_concat("dl"     dlopen       HAVE_LIBDL)
 175 check_library_exists_concat("socket" connect      HAVE_LIBSOCKET)
 176 check_library_exists("c" gethostbyname "" NOT_NEED_LIBNSL)
 177
 178 # Yellowtab Zeta needs different libraries than BeOS 5.
 179 if(BEOS)
 180   set(NOT_NEED_LIBNSL 1)
 181   check_library_exists_concat("bind" gethostbyname HAVE_LIBBIND)
 182   check_library_exists_concat("bnetapi" closesocket HAVE_LIBBNETAPI)
 183 endif(BEOS)
 184
 185 if(NOT NOT_NEED_LIBNSL)
 186   check_library_exists_concat("nsl"    gethostbyname  HAVE_LIBNSL)
 187 endif(NOT NOT_NEED_LIBNSL)
 188
 189 check_library_exists_concat("ws2_32" getch        HAVE_LIBWS2_32)
 190 check_library_exists_concat("winmm"  getch        HAVE_LIBWINMM)
 191 check_library_exists("wldap32" cldap_open "" HAVE_WLDAP32)
 192
 193 if(WIN32)
 194   set(CURL_DEFAULT_DISABLE_LDAP OFF)
 195   # some windows compilers do not have wldap32
 196   if(NOT HAVE_WLDAP32)
 197     set(CURL_DISABLE_LDAP ON CACHE BOOL "" FORCE)
 198     message(STATUS "wldap32 not found CURL_DISABLE_LDAP set ON")
 199     option(CURL_LDAP_WIN "Use Windows LDAP implementation" OFF)
 200   else()
 201     option(CURL_LDAP_WIN "Use Windows LDAP implementation" ON)
 202   endif()
 203   mark_as_advanced(CURL_LDAP_WIN)
 204 endif()
 205
 206
 207 # IF(NOT CURL_SPECIAL_LIBZ)
 208 #  CHECK_LIBRARY_EXISTS_CONCAT("z"      inflateEnd   HAVE_LIBZ)
 209 # ENDIF(NOT CURL_SPECIAL_LIBZ)
 210
 211 # Check for idn
 212 check_library_exists_concat("idn" idna_to_ascii_lz HAVE_LIBIDN)
 213
 214 # Check for LDAP
 215 check_library_exists_concat("ldap" ldap_init HAVE_LIBLDAP)
 216 # if(NOT HAVE_LIBLDAP)
 217 # SET(CURL_DISABLE_LDAP ON)
 218 # endif(NOT HAVE_LIBLDAP)
 219
 220 # Check for symbol dlopen (same as HAVE_LIBDL)
 221 check_library_exists("${CURL_LIBS}" dlopen "" HAVE_DLOPEN)
 222
 223 # For other tests to use the same libraries
 224 set(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBS})
 225
 226 option(CURL_ZLIB "Set to ON to enable building cURL with zlib support." ON)
 227 set(HAVE_LIBZ OFF)
 228 set(HAVE_ZLIB_H OFF)
 229 set(HAVE_ZLIB OFF)
 230 if(CURL_ZLIB)  # AND CURL_CONFIG_HAS_BEEN_RUN_BEFORE
 231   find_package(ZLIB QUIET)
 232   if(ZLIB_FOUND)
 233     set(HAVE_ZLIB_H ON)
 234     set(HAVE_ZLIB ON)
 235     set(HAVE_LIBZ ON)
 236     list(APPEND CURL_LIBS ${ZLIB_LIBRARIES})
 237   endif()
 238 endif()
 239
 240 option(CMAKE_USE_OPENSSL "Use OpenSSL code. Experimental" ON)
 241 mark_as_advanced(CMAKE_USE_OPENSSL)
 242 if(CMAKE_USE_OPENSSL)
 243
 244   set(USE_SSLEAY OFF)
 245   set(USE_OPENSSL OFF)
 246   set(HAVE_LIBCRYPTO OFF)
 247   set(HAVE_LIBSSL OFF)
 248
 249   find_package(OpenSSL)
 250   if(OPENSSL_FOUND)
 251     list(APPEND CURL_LIBS ${OPENSSL_LIBRARIES})
 252     list(APPEND CMAKE_REQUIRED_INCLUDES ${OPENSSL_INCLUDE_DIR})
 253     set(USE_SSLEAY ON)
 254     set(USE_OPENSSL ON)
 255     set(HAVE_LIBCRYPTO ON)
 256     set(HAVE_LIBSSL ON)
 257   endif(OPENSSL_FOUND)
 258 endif(CMAKE_USE_OPENSSL)
 259
 260 # If we have features.h, then do the _BSD_SOURCE magic
 261 check_include_file("features.h"       HAVE_FEATURES_H)
 262
 263 # Check if header file exists and add it to the list.
 264 macro(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 265   check_include_files("${CURL_INCLUDES};${FILE}" ${VARIABLE})
 266   if(${VARIABLE})
 267     set(CURL_INCLUDES ${CURL_INCLUDES} ${FILE})
 268     set(CURL_TEST_DEFINES "${CURL_TEST_DEFINES} -D${VARIABLE}")
 269   endif(${VARIABLE})
 270 endmacro(CHECK_INCLUDE_FILE_CONCAT)
 271
 272
 273 # Check for header files
 274 if(NOT UNIX)
 275   check_include_file_concat("ws2tcpip.h"     HAVE_WS2TCPIP_H)
 276   check_include_file_concat("winsock2.h"     HAVE_WINSOCK2_H)
 277 endif(NOT UNIX)
 278 check_include_file_concat("stdio.h"          HAVE_STDIO_H)
 279 if(NOT UNIX)
 280   check_include_file_concat("windows.h"      HAVE_WINDOWS_H)
 281   check_include_file_concat("winsock.h"      HAVE_WINSOCK_H)
 282 endif(NOT UNIX)
 283
 284 check_include_file_concat("inttypes.h"       HAVE_INTTYPES_H)
 285 check_include_file_concat("sys/filio.h"      HAVE_SYS_FILIO_H)
 286 check_include_file_concat("sys/ioctl.h"      HAVE_SYS_IOCTL_H)
 287 check_include_file_concat("sys/param.h"      HAVE_SYS_PARAM_H)
 288 check_include_file_concat("sys/poll.h"       HAVE_SYS_POLL_H)
 289 check_include_file_concat("sys/resource.h"   HAVE_SYS_RESOURCE_H)
 290 check_include_file_concat("sys/select.h"     HAVE_SYS_SELECT_H)
 291 check_include_file_concat("sys/socket.h"     HAVE_SYS_SOCKET_H)
 292 check_include_file_concat("sys/sockio.h"     HAVE_SYS_SOCKIO_H)
 293 check_include_file_concat("sys/stat.h"       HAVE_SYS_STAT_H)
 294 check_include_file_concat("sys/time.h"       HAVE_SYS_TIME_H)
 295 check_include_file_concat("sys/types.h"      HAVE_SYS_TYPES_H)
 296 check_include_file_concat("sys/uio.h"        HAVE_SYS_UIO_H)
 297 check_include_file_concat("sys/un.h"         HAVE_SYS_UN_H)
 298 check_include_file_concat("sys/utime.h"      HAVE_SYS_UTIME_H)
 299 check_include_file_concat("alloca.h"         HAVE_ALLOCA_H)
 300 check_include_file_concat("arpa/inet.h"      HAVE_ARPA_INET_H)
 301 check_include_file_concat("arpa/tftp.h"      HAVE_ARPA_TFTP_H)
 302 check_include_file_concat("assert.h"         HAVE_ASSERT_H)
 303 check_include_file_concat("crypto.h"         HAVE_CRYPTO_H)
 304 check_include_file_concat("des.h"            HAVE_DES_H)
 305 check_include_file_concat("err.h"            HAVE_ERR_H)
 306 check_include_file_concat("errno.h"          HAVE_ERRNO_H)
 307 check_include_file_concat("fcntl.h"          HAVE_FCNTL_H)
 308 check_include_file_concat("gssapi/gssapi.h"  HAVE_GSSAPI_GSSAPI_H)
 309 check_include_file_concat("gssapi/gssapi_generic.h" HAVE_GSSAPI_GSSAPI_GENERIC_H)
 310 check_include_file_concat("gssapi/gssapi_krb5.h" HAVE_GSSAPI_GSSAPI_KRB5_H)
 311 check_include_file_concat("idn-free.h"       HAVE_IDN_FREE_H)
 312 check_include_file_concat("ifaddrs.h"        HAVE_IFADDRS_H)
 313 check_include_file_concat("io.h"             HAVE_IO_H)
 314 check_include_file_concat("krb.h"            HAVE_KRB_H)
 315 check_include_file_concat("libgen.h"         HAVE_LIBGEN_H)
 316 check_include_file_concat("libssh2.h"        HAVE_LIBSSH2_H)
 317 check_include_file_concat("limits.h"         HAVE_LIMITS_H)
 318 check_include_file_concat("locale.h"         HAVE_LOCALE_H)
 319 check_include_file_concat("net/if.h"         HAVE_NET_IF_H)
 320 check_include_file_concat("netdb.h"          HAVE_NETDB_H)
 321 check_include_file_concat("netinet/in.h"     HAVE_NETINET_IN_H)
 322 check_include_file_concat("netinet/tcp.h"    HAVE_NETINET_TCP_H)
 323 if(CMAKE_USE_OPENSSL AND OPENSSL_FOUND)
 324   check_include_file_concat("openssl/crypto.h" HAVE_OPENSSL_CRYPTO_H)
 325   check_include_file_concat("openssl/engine.h" HAVE_OPENSSL_ENGINE_H)
 326   check_include_file_concat("openssl/err.h"    HAVE_OPENSSL_ERR_H)
 327   check_include_file_concat("openssl/pem.h"    HAVE_OPENSSL_PEM_H)
 328   check_include_file_concat("openssl/pkcs12.h" HAVE_OPENSSL_PKCS12_H)
 329   check_include_file_concat("openssl/rsa.h"    HAVE_OPENSSL_RSA_H)
 330   check_include_file_concat("openssl/ssl.h"    HAVE_OPENSSL_SSL_H)
 331   check_include_file_concat("openssl/x509.h"   HAVE_OPENSSL_X509_H)
 332   check_include_file_concat("openssl/rand.h"   HAVE_OPENSSL_RAND_H)
 333 endif(CMAKE_USE_OPENSSL AND OPENSSL_FOUND)
 334 check_include_file_concat("pem.h"            HAVE_PEM_H)
 335 check_include_file_concat("poll.h"           HAVE_POLL_H)
 336 check_include_file_concat("pwd.h"            HAVE_PWD_H)
 337 check_include_file_concat("rsa.h"            HAVE_RSA_H)
 338 check_include_file_concat("setjmp.h"         HAVE_SETJMP_H)
 339 check_include_file_concat("sgtty.h"          HAVE_SGTTY_H)
 340 check_include_file_concat("signal.h"         HAVE_SIGNAL_H)
 341 check_include_file_concat("ssl.h"            HAVE_SSL_H)
 342 check_include_file_concat("stdbool.h"        HAVE_STDBOOL_H)
 343 check_include_file_concat("stdint.h"         HAVE_STDINT_H)
 344 check_include_file_concat("stdio.h"          HAVE_STDIO_H)
 345 check_include_file_concat("stdlib.h"         HAVE_STDLIB_H)
 346 check_include_file_concat("string.h"         HAVE_STRING_H)
 347 check_include_file_concat("strings.h"        HAVE_STRINGS_H)
 348 check_include_file_concat("stropts.h"        HAVE_STROPTS_H)
 349 check_include_file_concat("termio.h"         HAVE_TERMIO_H)
 350 check_include_file_concat("termios.h"        HAVE_TERMIOS_H)
 351 check_include_file_concat("time.h"           HAVE_TIME_H)
 352 check_include_file_concat("tld.h"            HAVE_TLD_H)
 353 check_include_file_concat("unistd.h"         HAVE_UNISTD_H)
 354 check_include_file_concat("utime.h"          HAVE_UTIME_H)
 355 check_include_file_concat("x509.h"           HAVE_X509_H)
 356
 357 check_include_file_concat("process.h"        HAVE_PROCESS_H)
 358 check_include_file_concat("stddef.h"         HAVE_STDDEF_H)
 359 check_include_file_concat("dlfcn.h"          HAVE_DLFCN_H)
 360 check_include_file_concat("malloc.h"         HAVE_MALLOC_H)
 361 check_include_file_concat("memory.h"         HAVE_MEMORY_H)
 362 check_include_file_concat("ldap.h"           HAVE_LDAP_H)
 363 check_include_file_concat("netinet/if_ether.h" HAVE_NETINET_IF_ETHER_H)
 364 check_include_file_concat("stdint.h"        HAVE_STDINT_H)
 365 check_include_file_concat("sockio.h"        HAVE_SOCKIO_H)
 366 check_include_file_concat("sys/utsname.h"   HAVE_SYS_UTSNAME_H)
 367 check_include_file_concat("idna.h"          HAVE_IDNA_H)
 368
 369 if(NOT HAVE_LDAP_H)
 370   message(STATUS "LDAP_H not found CURL_DISABLE_LDAP set ON")
 371   set(CURL_DISABLE_LDAP ON CACHE BOOL "" FORCE)
 372 endif()
 373
 374 # No ldap, no ldaps.
 375 if(CURL_DISABLE_LDAP)
 376   if(NOT CURL_DISABLE_LDAPS)
 377     message(STATUS "LDAP needs to be enabled to support LDAPS")
 378     set(CURL_DISABLE_LDAPS ON CACHE BOOL "" FORCE)
 379   endif()
 380 endif()
 381
 382 check_type_size(size_t  SIZEOF_SIZE_T)
 383 check_type_size(ssize_t  SIZEOF_SSIZE_T)
 384 check_type_size("long long"  SIZEOF_LONG_LONG)
 385 check_type_size("long"  SIZEOF_LONG)
 386 check_type_size("short"  SIZEOF_SHORT)
 387 check_type_size("int"  SIZEOF_INT)
 388 check_type_size("__int64"  SIZEOF___INT64)
 389 check_type_size("long double"  SIZEOF_LONG_DOUBLE)
 390 check_type_size("time_t"  SIZEOF_TIME_T)
 391 if(NOT HAVE_SIZEOF_SSIZE_T)
 392   if(SIZEOF_LONG EQUAL SIZEOF_SIZE_T)
 393     set(ssize_t long)
 394   endif(SIZEOF_LONG EQUAL SIZEOF_SIZE_T)
 395   if(NOT ssize_t AND SIZEOF___INT64 EQUAL SIZEOF_SIZE_T)
 396     set(ssize_t __int64)
 397   endif(NOT ssize_t AND SIZEOF___INT64 EQUAL SIZEOF_SIZE_T)
 398 endif(NOT HAVE_SIZEOF_SSIZE_T)
 399
 400 # Different sizeofs, etc.
 401
 402 #    define CURL_SIZEOF_LONG        4
 403 #    define CURL_TYPEOF_CURL_OFF_T  long long
 404 #    define CURL_FORMAT_CURL_OFF_T  "lld"
 405 #    define CURL_FORMAT_CURL_OFF_TU "llu"
 406 #    define CURL_FORMAT_OFF_T       "%lld"
 407 #    define CURL_SIZEOF_CURL_OFF_T  8
 408 #    define CURL_SUFFIX_CURL_OFF_T  LL
 409 #    define CURL_SUFFIX_CURL_OFF_TU ULL
 410
 411 set(CURL_SIZEOF_LONG ${SIZEOF_LONG})
 412
 413 if(SIZEOF_LONG EQUAL 8)
 414   set(CURL_TYPEOF_CURL_OFF_T long)
 415   set(CURL_SIZEOF_CURL_OFF_T 8)
 416   set(CURL_FORMAT_CURL_OFF_T "ld")
 417   set(CURL_FORMAT_CURL_OFF_TU "lu")
 418   set(CURL_FORMAT_OFF_T "%ld")
 419   set(CURL_SUFFIX_CURL_OFF_T L)
 420   set(CURL_SUFFIX_CURL_OFF_TU UL)
 421 endif(SIZEOF_LONG EQUAL 8)
 422
 423 if(SIZEOF_LONG_LONG EQUAL 8)
 424   set(CURL_TYPEOF_CURL_OFF_T "long long")
 425   set(CURL_SIZEOF_CURL_OFF_T 8)
 426   set(CURL_FORMAT_CURL_OFF_T "lld")
 427   set(CURL_FORMAT_CURL_OFF_TU "llu")
 428   set(CURL_FORMAT_OFF_T "%lld")
 429   set(CURL_SUFFIX_CURL_OFF_T LL)
 430   set(CURL_SUFFIX_CURL_OFF_TU ULL)
 431 endif(SIZEOF_LONG_LONG EQUAL 8)
 432
 433 if(NOT CURL_TYPEOF_CURL_OFF_T)
 434   set(CURL_TYPEOF_CURL_OFF_T ${ssize_t})
 435   set(CURL_SIZEOF_CURL_OFF_T ${SIZEOF_SSIZE_T})
 436   # TODO: need adjustment here.
 437   set(CURL_FORMAT_CURL_OFF_T "ld")
 438   set(CURL_FORMAT_CURL_OFF_TU "lu")
 439   set(CURL_FORMAT_OFF_T "%ld")
 440   set(CURL_SUFFIX_CURL_OFF_T L)
 441   set(CURL_SUFFIX_CURL_OFF_TU LU)
 442 endif(NOT CURL_TYPEOF_CURL_OFF_T)
 443
 444 if(HAVE_SIZEOF_LONG_LONG)
 445   set(HAVE_LONGLONG 1)
 446   set(HAVE_LL 1)
 447 endif(HAVE_SIZEOF_LONG_LONG)
 448
 449 find_file(RANDOM_FILE urandom /dev)
 450 mark_as_advanced(RANDOM_FILE)
 451
 452 # Check for some functions that are used
 453 check_symbol_exists(basename      "${CURL_INCLUDES}" HAVE_BASENAME)
 454 check_symbol_exists(socket        "${CURL_INCLUDES}" HAVE_SOCKET)
 455 check_symbol_exists(poll          "${CURL_INCLUDES}" HAVE_POLL)
 456 check_symbol_exists(select        "${CURL_INCLUDES}" HAVE_SELECT)
 457 check_symbol_exists(strdup        "${CURL_INCLUDES}" HAVE_STRDUP)
 458 check_symbol_exists(strstr        "${CURL_INCLUDES}" HAVE_STRSTR)
 459 check_symbol_exists(strtok_r      "${CURL_INCLUDES}" HAVE_STRTOK_R)
 460 check_symbol_exists(strftime      "${CURL_INCLUDES}" HAVE_STRFTIME)
 461 check_symbol_exists(uname         "${CURL_INCLUDES}" HAVE_UNAME)
 462 check_symbol_exists(strcasecmp    "${CURL_INCLUDES}" HAVE_STRCASECMP)
 463 check_symbol_exists(stricmp       "${CURL_INCLUDES}" HAVE_STRICMP)
 464 check_symbol_exists(strcmpi       "${CURL_INCLUDES}" HAVE_STRCMPI)
 465 check_symbol_exists(strncmpi      "${CURL_INCLUDES}" HAVE_STRNCMPI)
 466 check_symbol_exists(alarm         "${CURL_INCLUDES}" HAVE_ALARM)
 467 if(NOT HAVE_STRNCMPI)
 468   set(HAVE_STRCMPI)
 469 endif(NOT HAVE_STRNCMPI)
 470 check_symbol_exists(gethostbyaddr "${CURL_INCLUDES}" HAVE_GETHOSTBYADDR)
 471 check_symbol_exists(gethostbyaddr_r "${CURL_INCLUDES}" HAVE_GETHOSTBYADDR_R)
 472 check_symbol_exists(gettimeofday  "${CURL_INCLUDES}" HAVE_GETTIMEOFDAY)
 473 check_symbol_exists(inet_addr     "${CURL_INCLUDES}" HAVE_INET_ADDR)
 474 check_symbol_exists(inet_ntoa     "${CURL_INCLUDES}" HAVE_INET_NTOA)
 475 check_symbol_exists(inet_ntoa_r   "${CURL_INCLUDES}" HAVE_INET_NTOA_R)
 476 check_symbol_exists(tcsetattr     "${CURL_INCLUDES}" HAVE_TCSETATTR)
 477 check_symbol_exists(tcgetattr     "${CURL_INCLUDES}" HAVE_TCGETATTR)
 478 check_symbol_exists(perror        "${CURL_INCLUDES}" HAVE_PERROR)
 479 check_symbol_exists(closesocket   "${CURL_INCLUDES}" HAVE_CLOSESOCKET)
 480 check_symbol_exists(setvbuf       "${CURL_INCLUDES}" HAVE_SETVBUF)
 481 check_symbol_exists(sigsetjmp     "${CURL_INCLUDES}" HAVE_SIGSETJMP)
 482 check_symbol_exists(getpass_r     "${CURL_INCLUDES}" HAVE_GETPASS_R)
 483 check_symbol_exists(strlcat       "${CURL_INCLUDES}" HAVE_STRLCAT)
 484 check_symbol_exists(getpwuid      "${CURL_INCLUDES}" HAVE_GETPWUID)
 485 check_symbol_exists(geteuid       "${CURL_INCLUDES}" HAVE_GETEUID)
 486 check_symbol_exists(utime         "${CURL_INCLUDES}" HAVE_UTIME)
 487 if(CMAKE_USE_OPENSSL)
 488   check_symbol_exists(RAND_status   "${CURL_INCLUDES}" HAVE_RAND_STATUS)
 489   check_symbol_exists(RAND_screen   "${CURL_INCLUDES}" HAVE_RAND_SCREEN)
 490   check_symbol_exists(RAND_egd      "${CURL_INCLUDES}" HAVE_RAND_EGD)
 491   check_symbol_exists(CRYPTO_cleanup_all_ex_data "${CURL_INCLUDES}"
 492     HAVE_CRYPTO_CLEANUP_ALL_EX_DATA)
 493   if(HAVE_LIBCRYPTO AND HAVE_LIBSSL)
 494     set(USE_OPENSSL 1)
 495     set(USE_SSLEAY 1)
 496   endif(HAVE_LIBCRYPTO AND HAVE_LIBSSL)
 497 endif(CMAKE_USE_OPENSSL)
 498 check_symbol_exists(gmtime_r      "${CURL_INCLUDES}" HAVE_GMTIME_R)
 499 check_symbol_exists(localtime_r   "${CURL_INCLUDES}" HAVE_LOCALTIME_R)
 500
 501 check_symbol_exists(gethostbyname   "${CURL_INCLUDES}" HAVE_GETHOSTBYNAME)
 502 check_symbol_exists(gethostbyname_r "${CURL_INCLUDES}" HAVE_GETHOSTBYNAME_R)
 503
 504 check_symbol_exists(signal        "${CURL_INCLUDES}" HAVE_SIGNAL_FUNC)
 505 check_symbol_exists(SIGALRM       "${CURL_INCLUDES}" HAVE_SIGNAL_MACRO)
 506 if(HAVE_SIGNAL_FUNC AND HAVE_SIGNAL_MACRO)
 507   set(HAVE_SIGNAL 1)
 508 endif(HAVE_SIGNAL_FUNC AND HAVE_SIGNAL_MACRO)
 509 check_symbol_exists(uname          "${CURL_INCLUDES}" HAVE_UNAME)
 510 check_symbol_exists(strtoll        "${CURL_INCLUDES}" HAVE_STRTOLL)
 511 check_symbol_exists(_strtoi64      "${CURL_INCLUDES}" HAVE__STRTOI64)
 512 check_symbol_exists(strerror_r     "${CURL_INCLUDES}" HAVE_STRERROR_R)
 513 check_symbol_exists(siginterrupt   "${CURL_INCLUDES}" HAVE_SIGINTERRUPT)
 514 check_symbol_exists(perror         "${CURL_INCLUDES}" HAVE_PERROR)
 515 check_symbol_exists(fork           "${CURL_INCLUDES}" HAVE_FORK)
 516 check_symbol_exists(freeaddrinfo   "${CURL_INCLUDES}" HAVE_FREEADDRINFO)
 517 check_symbol_exists(freeifaddrs    "${CURL_INCLUDES}" HAVE_FREEIFADDRS)
 518 check_symbol_exists(pipe           "${CURL_INCLUDES}" HAVE_PIPE)
 519 check_symbol_exists(ftruncate      "${CURL_INCLUDES}" HAVE_FTRUNCATE)
 520 check_symbol_exists(getprotobyname "${CURL_INCLUDES}" HAVE_GETPROTOBYNAME)
 521 check_symbol_exists(getrlimit      "${CURL_INCLUDES}" HAVE_GETRLIMIT)
 522 check_symbol_exists(idn_free       "${CURL_INCLUDES}" HAVE_IDN_FREE)
 523 check_symbol_exists(idna_strerror  "${CURL_INCLUDES}" HAVE_IDNA_STRERROR)
 524 check_symbol_exists(tld_strerror   "${CURL_INCLUDES}" HAVE_TLD_STRERROR)
 525 check_symbol_exists(setlocale      "${CURL_INCLUDES}" HAVE_SETLOCALE)
 526 check_symbol_exists(setrlimit      "${CURL_INCLUDES}" HAVE_SETRLIMIT)
 527 check_symbol_exists(fcntl          "${CURL_INCLUDES}" HAVE_FCNTL)
 528 check_symbol_exists(ioctl          "${CURL_INCLUDES}" HAVE_IOCTL)
 529 check_symbol_exists(setsockopt     "${CURL_INCLUDES}" HAVE_SETSOCKOPT)
 530
 531 # symbol exists in win32, but function does not.
 532 check_function_exists(inet_pton HAVE_INET_PTON)
 533
 534 # sigaction and sigsetjmp are special. Use special mechanism for
 535 # detecting those, but only if previous attempt failed.
 536 if(HAVE_SIGNAL_H)
 537   check_symbol_exists(sigaction "signal.h" HAVE_SIGACTION)
 538 endif(HAVE_SIGNAL_H)
 539
 540 if(NOT HAVE_SIGSETJMP)
 541   if(HAVE_SETJMP_H)
 542     check_symbol_exists(sigsetjmp "setjmp.h" HAVE_MACRO_SIGSETJMP)
 543     if(HAVE_MACRO_SIGSETJMP)
 544       set(HAVE_SIGSETJMP 1)
 545     endif(HAVE_MACRO_SIGSETJMP)
 546   endif(HAVE_SETJMP_H)
 547 endif(NOT HAVE_SIGSETJMP)
 548
 549 # If there is no stricmp(), do not allow LDAP to parse URLs
 550 if(NOT HAVE_STRICMP)
 551   set(HAVE_LDAP_URL_PARSE 1)
 552 endif(NOT HAVE_STRICMP)
 553
 554 # For other curl specific tests, use this macro.
 555 macro(CURL_INTERNAL_TEST CURL_TEST)
 556   if("${CURL_TEST}" MATCHES "^${CURL_TEST}$")
 557     set(MACRO_CHECK_FUNCTION_DEFINITIONS
 558       "-D${CURL_TEST} ${CURL_TEST_DEFINES} ${CMAKE_REQUIRED_FLAGS}")
 559     if(CMAKE_REQUIRED_LIBRARIES)
 560       set(CURL_TEST_ADD_LIBRARIES
 561         "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
 562     endif(CMAKE_REQUIRED_LIBRARIES)
 563
 564     message(STATUS "Performing Curl Test ${CURL_TEST}")
 565     try_compile(${CURL_TEST}
 566       ${CMAKE_BINARY_DIR}
 567       ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CurlTests.c
 568       CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
 569       "${CURL_TEST_ADD_LIBRARIES}"
 570       OUTPUT_VARIABLE OUTPUT)
 571     if(${CURL_TEST})
 572       set(${CURL_TEST} 1 CACHE INTERNAL "Curl test ${FUNCTION}")
 573       message(STATUS "Performing Curl Test ${CURL_TEST} - Success")
 574       file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
 575         "Performing Curl Test ${CURL_TEST} passed with the following output:\n"
 576         "${OUTPUT}\n")
 577     else(${CURL_TEST})
 578       message(STATUS "Performing Curl Test ${CURL_TEST} - Failed")
 579       set(${CURL_TEST} "" CACHE INTERNAL "Curl test ${FUNCTION}")
 580       file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
 581         "Performing Curl Test ${CURL_TEST} failed with the following output:\n"
 582         "${OUTPUT}\n")
 583     endif(${CURL_TEST})
 584   endif("${CURL_TEST}" MATCHES "^${CURL_TEST}$")
 585 endmacro(CURL_INTERNAL_TEST)
 586
 587 macro(CURL_INTERNAL_TEST_RUN CURL_TEST)
 588   if("${CURL_TEST}_COMPILE" MATCHES "^${CURL_TEST}_COMPILE$")
 589     set(MACRO_CHECK_FUNCTION_DEFINITIONS
 590       "-D${CURL_TEST} ${CMAKE_REQUIRED_FLAGS}")
 591     if(CMAKE_REQUIRED_LIBRARIES)
 592       set(CURL_TEST_ADD_LIBRARIES
 593         "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
 594     endif(CMAKE_REQUIRED_LIBRARIES)
 595
 596     message(STATUS "Performing Curl Test ${CURL_TEST}")
 597     try_run(${CURL_TEST} ${CURL_TEST}_COMPILE
 598       ${CMAKE_BINARY_DIR}
 599       ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CurlTests.c
 600       CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
 601       "${CURL_TEST_ADD_LIBRARIES}"
 602       OUTPUT_VARIABLE OUTPUT)
 603     if(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 604       set(${CURL_TEST} 1 CACHE INTERNAL "Curl test ${FUNCTION}")
 605       message(STATUS "Performing Curl Test ${CURL_TEST} - Success")
 606     else(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 607       message(STATUS "Performing Curl Test ${CURL_TEST} - Failed")
 608       set(${CURL_TEST} "" CACHE INTERNAL "Curl test ${FUNCTION}")
 609       file(APPEND "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 610         "Performing Curl Test ${CURL_TEST} failed with the following output:\n"
 611         "${OUTPUT}")
 612       if(${CURL_TEST}_COMPILE)
 613         file(APPEND
 614           "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 615           "There was a problem running this test\n")
 616       endif(${CURL_TEST}_COMPILE)
 617       file(APPEND "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 618         "\n\n")
 619     endif(${CURL_TEST}_COMPILE AND NOT ${CURL_TEST})
 620   endif("${CURL_TEST}_COMPILE" MATCHES "^${CURL_TEST}_COMPILE$")
 621 endmacro(CURL_INTERNAL_TEST_RUN)
 622
 623 # Do curl specific tests
 624 foreach(CURL_TEST
 625     HAVE_FCNTL_O_NONBLOCK
 626     HAVE_IOCTLSOCKET
 627     HAVE_IOCTLSOCKET_CAMEL
 628     HAVE_IOCTLSOCKET_CAMEL_FIONBIO
 629     HAVE_IOCTLSOCKET_FIONBIO
 630     HAVE_IOCTL_FIONBIO
 631     HAVE_IOCTL_SIOCGIFADDR
 632     HAVE_SETSOCKOPT_SO_NONBLOCK
 633     HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID
 634     TIME_WITH_SYS_TIME
 635     HAVE_O_NONBLOCK
 636     HAVE_GETHOSTBYADDR_R_5
 637     HAVE_GETHOSTBYADDR_R_7
 638     HAVE_GETHOSTBYADDR_R_8
 639     HAVE_GETHOSTBYADDR_R_5_REENTRANT
 640     HAVE_GETHOSTBYADDR_R_7_REENTRANT
 641     HAVE_GETHOSTBYADDR_R_8_REENTRANT
 642     HAVE_GETHOSTBYNAME_R_3
 643     HAVE_GETHOSTBYNAME_R_5
 644     HAVE_GETHOSTBYNAME_R_6
 645     HAVE_GETHOSTBYNAME_R_3_REENTRANT
 646     HAVE_GETHOSTBYNAME_R_5_REENTRANT
 647     HAVE_GETHOSTBYNAME_R_6_REENTRANT
 648     HAVE_SOCKLEN_T
 649     HAVE_IN_ADDR_T
 650     HAVE_BOOL_T
 651     STDC_HEADERS
 652     RETSIGTYPE_TEST
 653     HAVE_INET_NTOA_R_DECL
 654     HAVE_INET_NTOA_R_DECL_REENTRANT
 655     HAVE_GETADDRINFO
 656     HAVE_FILE_OFFSET_BITS
 657     )
 658   curl_internal_test(${CURL_TEST})
 659 endforeach(CURL_TEST)
 660 if(HAVE_FILE_OFFSET_BITS)
 661   set(_FILE_OFFSET_BITS 64)
 662 endif(HAVE_FILE_OFFSET_BITS)
 663 foreach(CURL_TEST
 664     HAVE_GLIBC_STRERROR_R
 665     HAVE_POSIX_STRERROR_R
 666     )
 667   curl_internal_test_run(${CURL_TEST})
 668 endforeach(CURL_TEST)
 669
 670 # Check for reentrant
 671 foreach(CURL_TEST
 672     HAVE_GETHOSTBYADDR_R_5
 673     HAVE_GETHOSTBYADDR_R_7
 674     HAVE_GETHOSTBYADDR_R_8
 675     HAVE_GETHOSTBYNAME_R_3
 676     HAVE_GETHOSTBYNAME_R_5
 677     HAVE_GETHOSTBYNAME_R_6
 678     HAVE_INET_NTOA_R_DECL_REENTRANT)
 679   if(NOT ${CURL_TEST})
 680     if(${CURL_TEST}_REENTRANT)
 681       set(NEED_REENTRANT 1)
 682     endif(${CURL_TEST}_REENTRANT)
 683   endif(NOT ${CURL_TEST})
 684 endforeach(CURL_TEST)
 685
 686 if(NEED_REENTRANT)
 687   foreach(CURL_TEST
 688       HAVE_GETHOSTBYADDR_R_5
 689       HAVE_GETHOSTBYADDR_R_7
 690       HAVE_GETHOSTBYADDR_R_8
 691       HAVE_GETHOSTBYNAME_R_3
 692       HAVE_GETHOSTBYNAME_R_5
 693       HAVE_GETHOSTBYNAME_R_6)
 694     set(${CURL_TEST} 0)
 695     if(${CURL_TEST}_REENTRANT)
 696       set(${CURL_TEST} 1)
 697     endif(${CURL_TEST}_REENTRANT)
 698   endforeach(CURL_TEST)
 699 endif(NEED_REENTRANT)
 700
 701 if(HAVE_INET_NTOA_R_DECL_REENTRANT)
 702   set(HAVE_INET_NTOA_R_DECL 1)
 703   set(NEED_REENTRANT 1)
 704 endif(HAVE_INET_NTOA_R_DECL_REENTRANT)
 705
 706 # Some other minor tests
 707
 708 if(NOT HAVE_IN_ADDR_T)
 709   set(in_addr_t "unsigned long")
 710 endif(NOT HAVE_IN_ADDR_T)
 711
 712 # Fix libz / zlib.h
 713
 714 if(NOT CURL_SPECIAL_LIBZ)
 715   if(NOT HAVE_LIBZ)
 716     set(HAVE_ZLIB_H 0)
 717   endif(NOT HAVE_LIBZ)
 718
 719   if(NOT HAVE_ZLIB_H)
 720     set(HAVE_LIBZ 0)
 721   endif(NOT HAVE_ZLIB_H)
 722 endif(NOT CURL_SPECIAL_LIBZ)
 723
 724 if(_FILE_OFFSET_BITS)
 725   set(_FILE_OFFSET_BITS 64)
 726 endif(_FILE_OFFSET_BITS)
 727 set(CMAKE_REQUIRED_FLAGS "-D_FILE_OFFSET_BITS=64")
 728 set(CMAKE_EXTRA_INCLUDE_FILES "${CMAKE_CURRENT_SOURCE_DIR}/curl/curl.h")
 729 check_type_size("curl_off_t" SIZEOF_CURL_OFF_T)
 730 set(CMAKE_EXTRA_INCLUDE_FILES)
 731 set(CMAKE_REQUIRED_FLAGS)
 732
 733
 734 # Check for nonblocking
 735 set(HAVE_DISABLED_NONBLOCKING 1)
 736 if(HAVE_FIONBIO OR
 737     HAVE_IOCTLSOCKET OR
 738     HAVE_IOCTLSOCKET_CASE OR
 739     HAVE_O_NONBLOCK)
 740   set(HAVE_DISABLED_NONBLOCKING)
 741 endif(HAVE_FIONBIO OR
 742   HAVE_IOCTLSOCKET OR
 743   HAVE_IOCTLSOCKET_CASE OR
 744   HAVE_O_NONBLOCK)
 745
 746 if(RETSIGTYPE_TEST)
 747   set(RETSIGTYPE void)
 748 else(RETSIGTYPE_TEST)
 749   set(RETSIGTYPE int)
 750 endif(RETSIGTYPE_TEST)
 751
 752 if(CMAKE_COMPILER_IS_GNUCC AND APPLE)
 753   include(CheckCCompilerFlag)
 754   check_c_compiler_flag(-Wno-long-double HAVE_C_FLAG_Wno_long_double)
 755   if(HAVE_C_FLAG_Wno_long_double)
 756     # The Mac version of GCC warns about use of long double.  Disable it.
 757     get_source_file_property(MPRINTF_COMPILE_FLAGS mprintf.c COMPILE_FLAGS)
 758     if(MPRINTF_COMPILE_FLAGS)
 759       set(MPRINTF_COMPILE_FLAGS "${MPRINTF_COMPILE_FLAGS} -Wno-long-double")
 760     else(MPRINTF_COMPILE_FLAGS)
 761       set(MPRINTF_COMPILE_FLAGS "-Wno-long-double")
 762     endif(MPRINTF_COMPILE_FLAGS)
 763     set_source_files_properties(mprintf.c PROPERTIES
 764       COMPILE_FLAGS ${MPRINTF_COMPILE_FLAGS})
 765   endif(HAVE_C_FLAG_Wno_long_double)
 766 endif(CMAKE_COMPILER_IS_GNUCC AND APPLE)
 767
 768 if(HAVE_SOCKLEN_T)
 769   set(CURL_TYPEOF_CURL_SOCKLEN_T "socklen_t")
 770   if(WIN32)
 771     set(CMAKE_EXTRA_INCLUDE_FILES "winsock2.h;ws2tcpip.h")
 772   elseif(HAVE_SYS_SOCKET_H)
 773     set(CMAKE_EXTRA_INCLUDE_FILES "sys/socket.h")
 774   endif()
 775   check_type_size("socklen_t" CURL_SIZEOF_CURL_SOCKLEN_T)
 776   set(CMAKE_EXTRA_INCLUDE_FILES)
 777   if(NOT HAVE_CURL_SIZEOF_CURL_SOCKLEN_T)
 778     message(FATAL_ERROR
 779      "Check for sizeof socklen_t failed, see CMakeFiles/CMakerror.log")
 780   endif()
 781 else()
 782   set(CURL_TYPEOF_CURL_SOCKLEN_T int)
 783   set(CURL_SIZEOF_CURL_SOCKLEN_T ${SIZEOF_INT})
 784 endif()
 785
 786 include(CMake/OtherTests.cmake)
 787
 788 add_definitions(-DHAVE_CONFIG_H)
 789
 790 # For windows, do not allow the compiler to use default target (Vista).
 791 if(WIN32)
 792   add_definitions(-D_WIN32_WINNT=0x0501)
 793 endif(WIN32)
 794
 795 if(MSVC)
 796   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 797 endif(MSVC)
 798
 799 # Sets up the dependencies (zlib, OpenSSL, etc.) of a cURL subproject according to options.
 800 # TODO This is far to be complete!
 801 function(SETUP_CURL_DEPENDENCIES TARGET_NAME)
 802   if(CURL_ZLIB AND ZLIB_FOUND)
 803     include_directories(${ZLIB_INCLUDE_DIR})
 804     #ADD_DEFINITIONS( -DHAVE_ZLIB_H -DHAVE_ZLIB -DHAVE_LIBZ )
 805   endif()
 806
 807   if(CMAKE_USE_OPENSSL AND OPENSSL_FOUND)
 808     include_directories(${OPENSSL_INCLUDE_DIR})
 809   endif()
 810   if(CMAKE_USE_OPENSSL AND CURL_CONFIG_HAS_BEEN_RUN_BEFORE)
 811     #ADD_DEFINITIONS( -DUSE_SSLEAY )
 812   endif()
 813
 814   target_link_libraries(${TARGET_NAME} ${CURL_LIBS})
 815 endfunction()
 816
 817 # Ugly (but functional) way to include "Makefile.inc" by transforming it (= regenerate it).
 818 function(TRANSFORM_MAKEFILE_INC INPUT_FILE OUTPUT_FILE)
 819   file(READ ${INPUT_FILE} MAKEFILE_INC_TEXT)
 820   string(REPLACE "$(top_srcdir)"   "\${CURL_SOURCE_DIR}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 821   string(REPLACE "$(top_builddir)" "\${CURL_BINARY_DIR}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 822
 823   string(REGEX REPLACE "\\\\\n" "§!§" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 824   string(REGEX REPLACE "([a-zA-Z_][a-zA-Z0-9_]*)[\t ]*=[\t ]*([^\n]*)" "SET(\\1 \\2)" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 825   string(REPLACE "§!§" "\n" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})
 826
 827   string(REGEX REPLACE "\\$\\(([a-zA-Z_][a-zA-Z0-9_]*)\\)" "\${\\1}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Replace $() with ${}
 828   string(REGEX REPLACE "@([a-zA-Z_][a-zA-Z0-9_]*)@" "\${\\1}" MAKEFILE_INC_TEXT ${MAKEFILE_INC_TEXT})    # Replace @@ with ${}, even if that may not be read by CMake scripts.
 829   file(WRITE ${OUTPUT_FILE} ${MAKEFILE_INC_TEXT})
 830
 831 endfunction()
 832
 833 add_subdirectory(lib)
 834 if(BUILD_CURL_EXE)
 835   add_subdirectory(src)
 836 endif()
 837 if(BUILD_CURL_TESTS)
 838   add_subdirectory(tests)
 839 endif()
 840
 841 # This needs to be run very last so other parts of the scripts can take advantage of this.
 842 if(NOT CURL_CONFIG_HAS_BEEN_RUN_BEFORE)
 843   set(CURL_CONFIG_HAS_BEEN_RUN_BEFORE 1 CACHE INTERNAL "Flag to track whether this is the first time running CMake or if CMake has been configured before")
 844 endif()
 845
 846 # Installation.
 847 # First, install generated curlbuild.h
 848 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/include/curl/curlbuild.h"
 849     DESTINATION include/curl )
 850 # Next, install other headers excluding curlbuild.h
 851 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/curl"
 852     DESTINATION include
 853     FILES_MATCHING PATTERN "*.h"
 854     PATTERN "curlbuild.h" EXCLUDE)
 855
 856
 857 # Workaround for MSVS10 to avoid the Dialog Hell
 858 # FIXME: This could be removed with future version of CMake.
 859 if(MSVC_VERSION EQUAL 1600)
 860   set(CURL_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/CURL.sln")
 861   if(EXISTS "${CURL_SLN_FILENAME}")
 862     file(APPEND "${CURL_SLN_FILENAME}" "\n# This should be regenerated!\n")
 863   endif()
 864 endif()