configure.in

   1 AC_PREREQ([2.67])
   2 AC_INIT([cryptsetup],[1.5.0-git])
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=7:0:3
   7
   8 AC_CONFIG_SRCDIR(src/cryptsetup.c)
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 AC_CONFIG_HEADERS([config.h:config.h.in])
  12 AM_INIT_AUTOMAKE(dist-bzip2)
  13
  14 if test "x$prefix" = "xNONE"; then
  15         sysconfdir=/etc
  16 fi
  17 AC_PREFIX_DEFAULT(/usr)
  18
  19 AC_CANONICAL_HOST
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_PROG_CC
  22 AM_PROG_CC_C_O
  23 AC_PROG_CPP
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26 AC_ENABLE_STATIC(no)
  27 LT_INIT
  28
  29 AC_HEADER_DIRENT
  30 AC_HEADER_STDC
  31 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  32         ctype.h unistd.h locale.h)
  33
  34 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR([You need the uuid library.])])
  35 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR([You need the device-mapper library.])])
  36
  37 saved_LIBS=$LIBS
  38 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR([You need the uuid library.])])
  39 AC_SUBST(UUID_LIBS, $LIBS)
  40 LIBS=$saved_LIBS
  41
  42 AC_CHECK_FUNCS([posix_memalign])
  43
  44 AC_C_CONST
  45 AC_C_BIGENDIAN
  46 AC_TYPE_OFF_T
  47 AC_SYS_LARGEFILE
  48
  49 AC_PROG_GCC_TRADITIONAL
  50
  51 dnl ==========================================================================
  52
  53 AM_GNU_GETTEXT([external],[need-ngettext])
  54 AM_GNU_GETTEXT_VERSION([0.15])
  55
  56 dnl ==========================================================================
  57
  58 saved_LIBS=$LIBS
  59 AC_CHECK_LIB(popt, poptConfigFileToString,,
  60         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  61 AC_SUBST(POPT_LIBS, $LIBS)
  62 LIBS=$saved_LIBS
  63
  64 dnl ==========================================================================
  65 dnl FIPS extensions
  66 AC_ARG_ENABLE([fips], AS_HELP_STRING([--enable-fips],[enable FIPS mode restrictions]),
  67 [with_fips=$enableval],
  68 [with_fips=no])
  69
  70 if test "x$with_fips" = "xyes"; then
  71         AC_DEFINE(ENABLE_FIPS, 1, [Enable FIPS mode restrictions])
  72
  73         if test "x$enable_static" = "xyes" -o "x$enable_static_cryptsetup" = "xyes" ; then
  74                 AC_MSG_ERROR([Static build is not compatible with FIPS.])
  75         fi
  76
  77         saved_LIBS=$LIBS
  78         AC_CHECK_LIB(fipscheck, FIPSCHECK_verify, ,[AC_MSG_ERROR([You need the fipscheck library.])])
  79         AC_SUBST(FIPSCHECK_LIBS, $LIBS)
  80         LIBS=$saved_LIBS
  81
  82 fi
  83
  84 AC_DEFUN([NO_FIPS], [
  85         if test "x$with_fips" = "xyes"; then
  86                 AC_MSG_ERROR([This option is not compatible with FIPS.])
  87         fi
  88 ])
  89
  90 dnl ==========================================================================
  91 dnl Crypto backend functions
  92
  93 AC_DEFUN([CONFIGURE_GCRYPT], [
  94         if test "x$with_fips" = "xyes"; then
  95                 GCRYPT_REQ_VERSION=1.4.5
  96         else
  97                 GCRYPT_REQ_VERSION=1.1.42
  98         fi
  99         AM_PATH_LIBGCRYPT($GCRYPT_REQ_VERSION,,[AC_MSG_ERROR([You need the gcrypt library.])])
 100
 101         if test x$enable_static_cryptsetup = xyes; then
 102                 saved_LIBS=$LIBS
 103                 LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
 104                 AC_CHECK_LIB(gcrypt, gcry_check_version,,
 105                         AC_MSG_ERROR([Cannot find static gcrypt library.]),
 106                         [-lgpg-error])
 107                 LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
 108                 LIBS=$saved_LIBS
 109         fi
 110
 111         CRYPTO_CFLAGS=$LIBGCRYPT_CFLAGS
 112         CRYPTO_LIBS=$LIBGCRYPT_LIBS
 113         CRYPTO_STATIC_LIBS=$LIBGCRYPT_STATIC_LIBS
 114
 115         AC_DEFINE_UNQUOTED(GCRYPT_REQ_VERSION, ["$GCRYPT_REQ_VERSION"], [Requested gcrypt version])
 116 ])
 117
 118 AC_DEFUN([CONFIGURE_OPENSSL], [
 119         PKG_CHECK_MODULES([OPENSSL], [openssl >= 0.9.8],,
 120                 AC_MSG_ERROR([You need openssl library.]))
 121         CRYPTO_CFLAGS=$OPENSSL_CFLAGS
 122         CRYPTO_LIBS=$OPENSSL_LIBS
 123
 124         if test x$enable_static_cryptsetup = xyes; then
 125                 saved_PKG_CONFIG=$PKG_CONFIG
 126                 PKG_CONFIG="$PKG_CONFIG --static"
 127                 PKG_CHECK_MODULES([OPENSSL], [openssl])
 128                 CRYPTO_STATIC_LIBS=$OPENSSL_LIBS
 129                 PKG_CONFIG=$saved_PKG_CONFIG
 130         fi
 131         NO_FIPS([])
 132 ])
 133
 134 AC_DEFUN([CONFIGURE_NSS], [
 135         if test x$enable_static_cryptsetup = xyes; then
 136                 AC_MSG_ERROR([Static build of cryptsetup is not supported with NSS.])
 137         fi
 138
 139         AC_MSG_WARN([NSS backend does NOT provide backward compatibility (missing ripemd160 hash).])
 140
 141         PKG_CHECK_MODULES([NSS], [nss],,
 142                 AC_MSG_ERROR([You need nss library.]))
 143
 144         saved_CFLAGS=$CFLAGS
 145         CFLAGS="$CFLAGS $NSS_CFLAGS"
 146         AC_CHECK_DECLS([NSS_GetVersion], [], [], [#include <nss.h>])
 147         CFLAGS=$saved_CFLAGS
 148
 149         CRYPTO_CFLAGS=$NSS_CFLAGS
 150         CRYPTO_LIBS=$NSS_LIBS
 151         NO_FIPS([])
 152 ])
 153
 154 AC_DEFUN([CONFIGURE_KERNEL], [
 155         AC_CHECK_HEADERS(linux/if_alg.h,,
 156                 [AC_MSG_ERROR([You need Linux kernel with userspace crypto interface.])])
 157 #       AC_CHECK_DECLS([AF_ALG],,
 158 #               [AC_MSG_ERROR([You need Linux kernel with userspace crypto interface.])],
 159 #               [#include <sys/socket.h>])
 160         NO_FIPS([])
 161 ])
 162
 163 AC_DEFUN([CONFIGURE_NETTLE], [
 164         AC_CHECK_HEADERS(nettle/sha.h,,
 165                 [AC_MSG_ERROR([You need Nettle cryptographic library.])])
 166
 167         saved_LIBS=$LIBS
 168         AC_CHECK_LIB(nettle, nettle_ripemd160_init,,
 169                 [AC_MSG_ERROR([You need Nettle library version 2.4 or more recent.])])
 170         CRYPTO_LIBS=$LIBS
 171         LIBS=$saved_LIBS
 172
 173         CRYPTO_STATIC_LIBS=$CRYPTO_LIBS
 174         NO_FIPS([])
 175 ])
 176
 177 dnl ==========================================================================
 178 saved_LIBS=$LIBS
 179
 180 AC_ARG_ENABLE([static-cryptsetup],
 181         AS_HELP_STRING([--enable-static-cryptsetup],
 182         [enable build of static cryptsetup binary]))
 183 if test x$enable_static_cryptsetup = xyes; then
 184         if test x$enable_static = xno; then
 185                 AC_MSG_WARN([Requested static cryptsetup build, enabling static library.])
 186                 enable_static=yes
 187         fi
 188 fi
 189 AM_CONDITIONAL(STATIC_TOOLS, test x$enable_static_cryptsetup = xyes)
 190
 191 AC_ARG_ENABLE(veritysetup,
 192         AS_HELP_STRING([--disable-veritysetup],
 193         [disable veritysetup support]),[], [enable_veritysetup=yes])
 194 AM_CONDITIONAL(VERITYSETUP, test x$enable_veritysetup = xyes)
 195
 196 AC_ARG_ENABLE(selinux,
 197         AS_HELP_STRING([--disable-selinux],
 198         [disable selinux support [default=auto]]),[], [])
 199
 200 AC_ARG_ENABLE([udev],
 201         AS_HELP_STRING([--disable-udev],
 202         [disable udev support]),[], enable_udev=yes)
 203
 204 dnl Try to use pkg-config for devmapper, but fallback to old detection
 205 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
 206         AC_CHECK_LIB(devmapper, dm_task_set_name,,
 207                 [AC_MSG_ERROR([You need the device-mapper library.])])
 208         AC_CHECK_LIB(devmapper, dm_task_set_message,,
 209                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
 210         DEVMAPPER_LIBS=$LIBS
 211 ])
 212 LIBS=$saved_LIBS
 213
 214 LIBS="$LIBS $DEVMAPPER_LIBS"
 215 AC_CHECK_DECLS([dm_task_secure_data], [], [], [#include <libdevmapper.h>])
 216 AC_CHECK_DECLS([dm_task_retry_remove], [], [], [#include <libdevmapper.h>])
 217 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
 218 if test "x$enable_udev" = xyes; then
 219         if test "x$have_cookie" = xno; then
 220                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 221         else
 222                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 223         fi
 224 fi
 225 LIBS=$saved_LIBS
 226
 227 dnl Crypto backend configuration.
 228 AC_ARG_WITH([crypto_backend],
 229         AS_HELP_STRING([--with-crypto_backend=BACKEND], [crypto backend (gcrypt/openssl/nss/kernel/nettle) [gcrypt]]),
 230         [], with_crypto_backend=gcrypt
 231 )
 232 case $with_crypto_backend in
 233         gcrypt)  CONFIGURE_GCRYPT([]) ;;
 234         openssl) CONFIGURE_OPENSSL([]) ;;
 235         nss)     CONFIGURE_NSS([]) ;;
 236         kernel)  CONFIGURE_KERNEL([]) ;;
 237         nettle)  CONFIGURE_NETTLE([]) ;;
 238         *) AC_MSG_ERROR([Unknown crypto backend.]) ;;
 239 esac
 240 AM_CONDITIONAL(CRYPTO_BACKEND_GCRYPT,  test $with_crypto_backend = gcrypt)
 241 AM_CONDITIONAL(CRYPTO_BACKEND_OPENSSL, test $with_crypto_backend = openssl)
 242 AM_CONDITIONAL(CRYPTO_BACKEND_NSS,     test $with_crypto_backend = nss)
 243 AM_CONDITIONAL(CRYPTO_BACKEND_KERNEL,  test $with_crypto_backend = kernel)
 244 AM_CONDITIONAL(CRYPTO_BACKEND_NETTLE,  test $with_crypto_backend = nettle)
 245
 246 dnl Magic for cryptsetup.static build.
 247 if test x$enable_static_cryptsetup = xyes; then
 248         saved_PKG_CONFIG=$PKG_CONFIG
 249         PKG_CONFIG="$PKG_CONFIG --static"
 250
 251         LIBS="$saved_LIBS -static"
 252         AC_CHECK_LIB(popt, poptGetContext,,
 253                 AC_MSG_ERROR([Cannot find static popt library.]))
 254
 255         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 256         LIBS="$saved_LIBS -static"
 257         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 258                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 259                 if test "x$enable_selinux" != xno; then
 260                         AC_CHECK_LIB(sepol, sepol_bool_set)
 261                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 262                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 263                 fi
 264         ])
 265         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 266         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 267                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 268
 269         dnl Try to detect uuid static library.
 270         LIBS="$saved_LIBS -static"
 271         AC_CHECK_LIB(uuid, uuid_generate,,
 272                 AC_MSG_ERROR([Cannot find static uuid library.]))
 273
 274         LIBS=$saved_LIBS
 275         PKG_CONFIG=$saved_PKG_CONFIG
 276 fi
 277
 278 AC_SUBST([DEVMAPPER_LIBS])
 279 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 280
 281 AC_SUBST([CRYPTO_CFLAGS])
 282 AC_SUBST([CRYPTO_LIBS])
 283 AC_SUBST([CRYPTO_STATIC_LIBS])
 284
 285 AC_SUBST([LIBCRYPTSETUP_VERSION])
 286 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 287
 288 dnl ==========================================================================
 289 AC_ARG_ENABLE([dev-random], AS_HELP_STRING([--enable-dev-random],
 290 [use blocking /dev/random by default for key generator (otherwise use /dev/urandom)]),
 291 [default_rng=/dev/random], [default_rng=/dev/urandom])
 292 AC_DEFINE_UNQUOTED(DEFAULT_RNG, ["$default_rng"], [default RNG type for key generator])
 293
 294 dnl ==========================================================================
 295 AC_DEFUN([CS_DEFINE],
 296         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 297 ])
 298
 299 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 300         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 301         [CS_DEFINE([$1], ["$withval"], [$2])],
 302         [CS_DEFINE([$1], ["$3"], [$2])]
 303 )])
 304
 305 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 306         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 307         [CS_DEFINE([$1], [$withval], [$2])],
 308         [CS_DEFINE([$1], [$3], [$2])]
 309 )])
 310
 311 dnl ==========================================================================
 312 dnl Python bindings
 313 AC_ARG_ENABLE([python], AS_HELP_STRING([--enable-python],[enable Python bindings]),
 314 [with_python=$enableval],
 315 [with_python=no])
 316
 317 if test "x$with_python" = "xyes"; then
 318         AM_PATH_PYTHON([2.4])
 319
 320         if ! test -x "$PYTHON-config" ; then
 321             AC_MSG_ERROR([Cannot find python development packages to build bindings])
 322         fi
 323
 324         PYTHON_INCLUDES=$($PYTHON-config --includes)
 325         AC_SUBST(PYTHON_INCLUDES)
 326 fi
 327 AM_CONDITIONAL([PYTHON_CRYPTSETUP], [test "x$with_python" = "xyes"])
 328
 329 dnl ==========================================================================
 330 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 331 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 332 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 333 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 334
 335 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 336 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 337 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 338 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 339
 340 CS_STR_WITH([loopaes-cipher], [cipher for loop-AES mode], [aes])
 341 CS_NUM_WITH([loopaes-keybits],[key length in bits for loop-AES mode], [256])
 342
 343 CS_NUM_WITH([keyfile-size-maxkb],[maximum keyfile size (in kilobytes)], [8192])
 344 CS_NUM_WITH([passphrase-size-max],[maximum keyfile size (in kilobytes)], [512])
 345
 346 CS_STR_WITH([verity-hash],       [hash function for verity mode], [sha256])
 347 CS_NUM_WITH([verity-data-block], [data block size for verity mode], [4096])
 348 CS_NUM_WITH([verity-hash-block], [hash block size for verity mode], [4096])
 349 CS_NUM_WITH([verity-salt-size],  [salt size for verity mode], [32])
 350
 351 dnl ==========================================================================
 352
 353 AC_CONFIG_FILES([ Makefile
 354 lib/Makefile
 355 lib/libcryptsetup.pc
 356 lib/crypto_backend/Makefile
 357 lib/luks1/Makefile
 358 lib/loopaes/Makefile
 359 lib/verity/Makefile
 360 src/Makefile
 361 po/Makefile.in
 362 man/Makefile
 363 tests/Makefile
 364 python/Makefile
 365 ])
 366 AC_OUTPUT