configure.in

   1 AC_PREREQ([2.67])
   2 AC_INIT([cryptsetup],[1.2.0])
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=2:0:1
   7
   8 AC_CONFIG_SRCDIR(src/cryptsetup.c)
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 AC_CONFIG_HEADERS([config.h:config.h.in])
  12 AM_INIT_AUTOMAKE(dist-bzip2)
  13
  14 if test "x$prefix" = "xNONE"; then
  15         sysconfdir=/etc
  16 fi
  17 AC_PREFIX_DEFAULT(/usr)
  18
  19 AC_CANONICAL_HOST
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_PROG_CC
  22 AM_PROG_CC_C_O
  23 AC_PROG_CPP
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26 AC_ENABLE_STATIC(no)
  27 LT_INIT
  28
  29 AC_HEADER_DIRENT
  30 AC_HEADER_STDC
  31 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  32         ctype.h unistd.h locale.h)
  33
  34 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR('You need the uuid library')])
  35 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR('You need the device-mapper library')])
  36
  37 saved_LIBS=$LIBS
  38 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR('You need the uuid library')])
  39 AC_SUBST(UUID_LIBS, $LIBS)
  40 LIBS=$saved_LIBS
  41
  42 AC_CHECK_FUNCS([posix_memalign])
  43
  44 AC_C_CONST
  45 AC_C_BIGENDIAN
  46 AC_TYPE_OFF_T
  47 AC_SYS_LARGEFILE
  48
  49 AC_PROG_GCC_TRADITIONAL
  50
  51 dnl ==========================================================================
  52
  53 AM_GNU_GETTEXT([external],[need-ngettext])
  54 AM_GNU_GETTEXT_VERSION([0.15])
  55
  56 dnl ==========================================================================
  57
  58 saved_LIBS=$LIBS
  59 AC_CHECK_LIB(popt, poptConfigFileToString,,
  60         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  61 AC_SUBST(POPT_LIBS, $LIBS)
  62 LIBS=$saved_LIBS
  63
  64 dnl ==========================================================================
  65 dnl Crypto backend functions
  66
  67 AC_DEFUN([CONFIGURE_GCRYPT], [
  68         AM_PATH_LIBGCRYPT(1.1.42,,[AC_MSG_ERROR('You need the gcrypt library')])
  69
  70         if test x$enable_static_cryptsetup = xyes; then
  71                 saved_LIBS=$LIBS
  72                 LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
  73                 AC_CHECK_LIB(gcrypt, gcry_check_version,,
  74                         AC_MSG_ERROR([Cannot find static gcrypt library.]),
  75                         [-lgpg-error])
  76                 LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
  77                 LIBS=$saved_LIBS
  78         fi
  79
  80         CRYPTO_CFLAGS=$LIBGCRYPT_CFLAGS
  81         CRYPTO_LIBS=$LIBGCRYPT_LIBS
  82         CRYPTO_STATIC_LIBS=$LIBGCRYPT_STATIC_LIBS
  83 ])
  84
  85 AC_DEFUN([CONFIGURE_OPENSSL], [
  86         PKG_CHECK_MODULES([OPENSSL], [openssl >= 0.9.8],,
  87                 AC_MSG_ERROR('You need openssl library'))
  88         CRYPTO_CFLAGS=$OPENSSL_CFLAGS
  89         CRYPTO_LIBS=$OPENSSL_LIBS
  90
  91         if test x$enable_static_cryptsetup = xyes; then
  92                 saved_PKG_CONFIG=$PKG_CONFIG
  93                 PKG_CONFIG="$PKG_CONFIG --static"
  94                 PKG_CHECK_MODULES([OPENSSL], [openssl])
  95                 CRYPTO_STATIC_LIBS=$OPENSSL_LIBS
  96                 PKG_CONFIG=$saved_PKG_CONFIG
  97         fi
  98 ])
  99
 100 AC_DEFUN([CONFIGURE_NSS], [
 101         if test x$enable_static_cryptsetup = xyes; then
 102                 AC_MSG_ERROR([Static build of cryptsetup is not supported with NSS.]),
 103         fi
 104
 105         AC_MSG_WARN([NSS backend does NOT provide backward compatibility (missing ripemd160 hash).])
 106
 107         PKG_CHECK_MODULES([NSS], [nss],,
 108                 AC_MSG_ERROR('You need nss library'))
 109         CRYPTO_CFLAGS=$NSS_CFLAGS
 110         CRYPTO_LIBS=$NSS_LIBS
 111 ])
 112
 113 AC_DEFUN([CONFIGURE_KERNEL], [
 114         AC_CHECK_HEADERS(linux/if_alg.h,,
 115                 [AC_MSG_ERROR('You need Linux kernel with userspace crypto interface.')])
 116 #       AC_CHECK_DECLS([AF_ALG],,
 117 #               [AC_MSG_ERROR('You need Linux kernel with userspace crypto interface.')],
 118 #               [#include <sys/socket.h>])
 119
 120 ])
 121
 122 dnl ==========================================================================
 123 saved_LIBS=$LIBS
 124
 125 AC_ARG_ENABLE([static-cryptsetup],
 126         AS_HELP_STRING([--enable-static-cryptsetup],
 127         [enable build of static cryptsetup binary]))
 128 if test x$enable_static_cryptsetup = xyes; then
 129         if test x$enable_static = xno; then
 130                 AC_MSG_WARN([Requested static cryptsetup build, enabling static library.])
 131                 enable_static=yes
 132         fi
 133 fi
 134 AM_CONDITIONAL(STATIC_CRYPTSETUP, test x$enable_static_cryptsetup = xyes)
 135
 136 AC_ARG_ENABLE(selinux,
 137         AS_HELP_STRING([--disable-selinux],
 138         [disable selinux support [default=auto]]),[], [])
 139
 140 AC_ARG_ENABLE([udev],
 141         AS_HELP_STRING([--disable-udev],
 142         [disable udev support]),[], enable_udev=yes)
 143
 144 dnl Try to use pkg-config for devmapper, but fallback to old detection
 145 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
 146         AC_CHECK_LIB(devmapper, dm_task_set_name,,
 147                 [AC_MSG_ERROR([You need the device-mapper library.])])
 148         AC_CHECK_LIB(devmapper, dm_task_set_message,,
 149                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
 150         DEVMAPPER_LIBS=$LIBS
 151 ])
 152 LIBS=$saved_LIBS
 153
 154 LIBS="$LIBS $DEVMAPPER_LIBS"
 155 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
 156 if test "x$enable_udev" = xyes; then
 157         if test "x$have_cookie" = xno; then
 158                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 159         else
 160                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 161         fi
 162 fi
 163 LIBS=$saved_LIBS
 164
 165 dnl Crypto backend configuration.
 166 AC_ARG_WITH([crypto_backend],
 167         AS_HELP_STRING([--with-crypto_backend=BACKEND], [crypto backend (gcrypt/openssl/nss/kernel) [gcrypt]]),
 168         [], with_crypto_backend=gcrypt
 169 )
 170 case $with_crypto_backend in
 171         gcrypt)  CONFIGURE_GCRYPT([]) ;;
 172         openssl) CONFIGURE_OPENSSL([]) ;;
 173         nss)     CONFIGURE_NSS([]) ;;
 174         kernel)  CONFIGURE_KERNEL([]) ;;
 175         *) AC_MSG_ERROR([Unknown crypto backend.]) ;;
 176 esac
 177 AM_CONDITIONAL(CRYPTO_BACKEND_GCRYPT,  test $with_crypto_backend = gcrypt)
 178 AM_CONDITIONAL(CRYPTO_BACKEND_OPENSSL, test $with_crypto_backend = openssl)
 179 AM_CONDITIONAL(CRYPTO_BACKEND_NSS,     test $with_crypto_backend = nss)
 180 AM_CONDITIONAL(CRYPTO_BACKEND_KERNEL,  test $with_crypto_backend = kernel)
 181
 182 dnl Magic for cryptsetup.static build.
 183 if test x$enable_static_cryptsetup = xyes; then
 184         saved_PKG_CONFIG=$PKG_CONFIG
 185         PKG_CONFIG="$PKG_CONFIG --static"
 186
 187         LIBS="$saved_LIBS -static"
 188         AC_CHECK_LIB(popt, poptGetContext,,
 189                 AC_MSG_ERROR([Cannot find static popt library.]))
 190
 191         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 192         LIBS="$saved_LIBS -static"
 193         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 194                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 195                 if test "x$enable_selinux" != xno; then
 196                         AC_CHECK_LIB(sepol, sepol_bool_set)
 197                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 198                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 199                 fi
 200         ])
 201         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 202         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 203                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 204
 205         LIBS=$saved_LIBS
 206         PKG_CONFIG=$saved_PKG_CONFIG
 207 fi
 208
 209 AC_SUBST([DEVMAPPER_LIBS])
 210 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 211
 212 AC_SUBST([CRYPTO_CFLAGS])
 213 AC_SUBST([CRYPTO_LIBS])
 214 AC_SUBST([CRYPTO_STATIC_LIBS])
 215
 216 AC_SUBST([LIBCRYPTSETUP_VERSION])
 217 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 218
 219 dnl ==========================================================================
 220 AC_ARG_ENABLE([dev-random], AS_HELP_STRING([--enable-dev-random],
 221 [use blocking /dev/random by default for key generator (otherwise use /dev/urandom)]),
 222 [default_rng=/dev/random], [default_rng=/dev/urandom])
 223 AC_DEFINE_UNQUOTED(DEFAULT_RNG, ["$default_rng"], [default RNG type for key generator])
 224
 225 dnl ==========================================================================
 226 AC_DEFUN([CS_DEFINE],
 227         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 228 ])
 229
 230 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 231         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 232         [CS_DEFINE([$1], ["$withval"], [$2])],
 233         [CS_DEFINE([$1], ["$3"], [$2])]
 234 )])
 235
 236 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 237         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 238         [CS_DEFINE([$1], [$withval], [$2])],
 239         [CS_DEFINE([$1], [$3], [$2])]
 240 )])
 241
 242 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 243 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 244 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 245 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 246
 247 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 248 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 249 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 250 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 251
 252
 253 dnl ==========================================================================
 254
 255 AC_CONFIG_FILES([ Makefile
 256 lib/Makefile
 257 lib/libcryptsetup.pc
 258 lib/crypto_backend/Makefile
 259 lib/luks1/Makefile
 260 lib/loopaes/Makefile
 261 src/Makefile
 262 po/Makefile.in
 263 man/Makefile
 264 tests/Makefile
 265 ])
 266 AC_OUTPUT