configure.in

   1 AC_PREREQ(2.57)
   2 AC_INIT(cryptsetup,1.1.3)
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=1:0:0
   7
   8 AC_CONFIG_SRCDIR(src/cryptsetup.c)
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 AM_CONFIG_HEADER([config.h:config.h.in])
  12 AM_INIT_AUTOMAKE(dist-bzip2)
  13
  14 if test "x$prefix" = "xNONE"; then
  15         sysconfdir=/etc
  16 fi
  17 AC_PREFIX_DEFAULT(/usr)
  18
  19 AC_CANONICAL_HOST
  20 AC_GNU_SOURCE
  21 AC_PROG_CC
  22 AM_PROG_CC_C_O
  23 AC_PROG_CPP
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26 AC_ENABLE_STATIC(no)
  27 AM_PROG_LIBTOOL
  28
  29 AC_HEADER_DIRENT
  30 AC_HEADER_STDC
  31 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  32         ctype.h unistd.h locale.h)
  33
  34 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR('You need the uuid library')])
  35 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR('You need the device-mapper library')])
  36
  37 saved_LIBS=$LIBS
  38 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR('You need the uuid library')])
  39 AC_SUBST(UUID_LIBS, $LIBS)
  40 LIBS=$saved_LIBS
  41
  42
  43 AM_PATH_LIBGCRYPT(1.1.42,,[AC_MSG_ERROR('You need the gcrypt library')])
  44
  45 AC_CHECK_FUNCS([posix_memalign])
  46
  47 AC_C_CONST
  48 AC_C_BIGENDIAN
  49 AC_TYPE_OFF_T
  50 AC_STRUCT_ST_RDEV
  51 AC_SYS_LARGEFILE
  52
  53 AC_PROG_GCC_TRADITIONAL
  54
  55 dnl ==========================================================================
  56
  57 AM_GNU_GETTEXT([external],[need-ngettext])
  58 AM_GNU_GETTEXT_VERSION([0.15])
  59
  60 dnl ==========================================================================
  61
  62 saved_LIBS=$LIBS
  63 AC_CHECK_LIB(popt, poptConfigFileToString,,
  64         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  65 AC_SUBST(POPT_LIBS, $LIBS)
  66 LIBS=$saved_LIBS
  67
  68 dnl ==========================================================================
  69
  70 AC_ARG_ENABLE(shared-library,
  71 [  --disable-shared-library
  72                           disable building of shared cryptsetup library],,
  73 enable_shared_library=yes)
  74 AM_CONDITIONAL(STATIC_LIBRARY, test x$enable_shared_library = xno)
  75
  76 AC_ARG_ENABLE(selinux,
  77 [  --disable-selinux       disable selinux support [[default=auto]]],[], [])
  78
  79 AC_ARG_ENABLE([udev],AS_HELP_STRING([--disable-udev],[disable udev support]),[], enable_udev=yes)
  80
  81 dnl Try to use pkg-config for devmapper, but fallback to old detection
  82 saved_LIBS=$LIBS
  83 if AC_RUN_LOG([pkg-config --exists --print-errors devmapper]); then
  84         PKG_PROG_PKG_CONFIG
  85         if test x$enable_static = xyes; then
  86                 PKG_CONFIG="$PKG_CONFIG --static"
  87         fi
  88         PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03])
  89         LIBS="$LIBS $DEVMAPPER_LIBS"
  90 else
  91         AC_CHECK_LIB(devmapper, dm_task_set_name,,
  92                 [AC_MSG_ERROR('You need the device-mapper library')])
  93         AC_CHECK_LIB(devmapper, dm_task_set_message,,
  94                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
  95         DEVMAPPER_LIBS=$LIBS
  96 fi
  97
  98 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
  99 if test "x$enable_udev" = xyes; then
 100         if test "x$have_cookie" = xno; then
 101                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 102         else
 103                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 104         fi
 105 fi
 106
 107 LIBS=$saved_LIBS
 108 if test "x$enable_selinux" != xno; then
 109         AC_CHECK_LIB(sepol, sepol_bool_set)
 110         AC_CHECK_LIB(selinux, is_selinux_enabled)
 111         if test x$enable_static = xyes; then
 112                 SELINUX_STATIC_LIBS=$LIBS
 113                 # Check if we need -pthread with --enable-static and selinux
 114                 saved_LIBS2=$LIBS
 115                 LIBS="$LIBS -static"
 116                 AC_SEARCH_LIBS([pthread_mutex_lock], [pthread],
 117                         [test "$ac_cv_search_pthread_mutex_lock" = "none required" || LIB_PTHREAD=-lpthread])
 118                 LIBS=$saved_LIBS2
 119         fi
 120 fi
 121
 122 LIBS=$saved_LIBS
 123
 124 DEVMAPPER_LIBS="$DEVMAPPER_LIBS $LIB_PTHREAD"
 125 AC_SUBST([DEVMAPPER_LIBS])
 126 AC_SUBST([SELINUX_STATIC_LIBS])
 127 AC_SUBST([LIBCRYPTSETUP_VERSION])
 128 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 129
 130 dnl ==========================================================================
 131 AC_DEFUN([CS_DEFINE],
 132         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 133 ])
 134
 135 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 136         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 137         [CS_DEFINE([$1], ["$withval"], [$2])],
 138         [CS_DEFINE([$1], ["$3"], [$2])]
 139 )])
 140
 141 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 142         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 143         [CS_DEFINE([$1], [$withval], [$2])],
 144         [CS_DEFINE([$1], [$3], [$2])]
 145 )])
 146
 147 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 148 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 149 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 150 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 151
 152 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 153 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 154 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 155 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 156
 157 dnl ==========================================================================
 158
 159 AM_CONDITIONAL(STATIC_CRYPTSETUP, test x$enable_static = xyes)
 160 AM_CONDITIONAL(DYNAMIC_CRYPTSETUP, test x$enable_static = xno)
 161
 162 dnl ==========================================================================
 163
 164 AC_OUTPUT([ Makefile
 165 lib/Makefile
 166 lib/libcryptsetup.pc
 167 src/Makefile
 168 po/Makefile.in
 169 luks/Makefile
 170 man/Makefile
 171 tests/Makefile
 172 ])