configure.ac

   1 AC_PREREQ([2.67])
   2 AC_INIT([cryptsetup],[1.6.0-rc1])
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=9:0:5
   7 dnl library file name for FIPS selfcheck
   8 LIBCRYPTSETUP_VERSION_FIPS="libcryptsetup.so.4"
   9
  10 AC_CONFIG_SRCDIR(src/cryptsetup.c)
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CONFIG_HEADERS([config.h:config.h.in])
  14 AM_INIT_AUTOMAKE(dist-bzip2)
  15
  16 if test "x$prefix" = "xNONE"; then
  17         sysconfdir=/etc
  18 fi
  19 AC_PREFIX_DEFAULT(/usr)
  20
  21 AC_CANONICAL_HOST
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_PROG_CC
  24 AM_PROG_CC_C_O
  25 AC_PROG_CPP
  26 AC_PROG_INSTALL
  27 AC_PROG_MAKE_SET
  28 AC_ENABLE_STATIC(no)
  29 LT_INIT
  30
  31 AC_HEADER_DIRENT
  32 AC_HEADER_STDC
  33 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  34         ctype.h unistd.h locale.h)
  35
  36 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR([You need the uuid library.])])
  37 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR([You need the device-mapper library.])])
  38
  39 saved_LIBS=$LIBS
  40 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR([You need the uuid library.])])
  41 AC_SUBST(UUID_LIBS, $LIBS)
  42 LIBS=$saved_LIBS
  43
  44 AC_CHECK_FUNCS([posix_memalign])
  45
  46 AC_C_CONST
  47 AC_C_BIGENDIAN
  48 AC_TYPE_OFF_T
  49 AC_SYS_LARGEFILE
  50
  51 AC_PROG_GCC_TRADITIONAL
  52
  53 dnl ==========================================================================
  54
  55 AM_GNU_GETTEXT([external],[need-ngettext])
  56 AM_GNU_GETTEXT_VERSION([0.15])
  57
  58 dnl ==========================================================================
  59
  60 saved_LIBS=$LIBS
  61 AC_CHECK_LIB(popt, poptConfigFileToString,,
  62         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  63 AC_SUBST(POPT_LIBS, $LIBS)
  64 LIBS=$saved_LIBS
  65
  66 dnl ==========================================================================
  67 dnl FIPS extensions
  68 AC_ARG_ENABLE([fips], AS_HELP_STRING([--enable-fips],[enable FIPS mode restrictions]),
  69 [with_fips=$enableval],
  70 [with_fips=no])
  71
  72 if test "x$with_fips" = "xyes"; then
  73         AC_DEFINE(ENABLE_FIPS, 1, [Enable FIPS mode restrictions])
  74         AC_DEFINE_UNQUOTED(LIBCRYPTSETUP_VERSION_FIPS, ["$LIBCRYPTSETUP_VERSION_FIPS"],
  75                 [library file name for FIPS selfcheck])
  76
  77         if test "x$enable_static" = "xyes" -o "x$enable_static_cryptsetup" = "xyes" ; then
  78                 AC_MSG_ERROR([Static build is not compatible with FIPS.])
  79         fi
  80
  81         saved_LIBS=$LIBS
  82         AC_CHECK_LIB(fipscheck, FIPSCHECK_verify, ,[AC_MSG_ERROR([You need the fipscheck library.])])
  83         AC_SUBST(FIPSCHECK_LIBS, $LIBS)
  84         LIBS=$saved_LIBS
  85
  86 fi
  87
  88 AC_DEFUN([NO_FIPS], [
  89         if test "x$with_fips" = "xyes"; then
  90                 AC_MSG_ERROR([This option is not compatible with FIPS.])
  91         fi
  92 ])
  93
  94 dnl ==========================================================================
  95 dnl pwquality library (cryptsetup CLI only)
  96 AC_ARG_ENABLE([pwquality], AS_HELP_STRING([--enable-pwquality],[enable password quality checking]),
  97 [with_pwquality=$enableval],
  98 [with_pwquality=no])
  99
 100 if test "x$with_pwquality" = "xyes"; then
 101         AC_DEFINE(ENABLE_PWQUALITY, 1, [Enable password quality checking])
 102         PKG_CHECK_MODULES([PWQUALITY], [pwquality >= 1.0.0],,
 103                 AC_MSG_ERROR([You need pwquality library.]))
 104
 105         dnl FIXME: this is really hack for now
 106         PWQUALITY_STATIC_LIBS="$PWQUALITY_LIBS -lcrack -lz"
 107 fi
 108
 109 dnl ==========================================================================
 110 dnl Crypto backend functions
 111
 112 AC_DEFUN([CONFIGURE_GCRYPT], [
 113         if test "x$with_fips" = "xyes"; then
 114                 GCRYPT_REQ_VERSION=1.4.5
 115         else
 116                 GCRYPT_REQ_VERSION=1.1.42
 117         fi
 118         dnl Check if we can use gcrypt PBKDF2 (1.6.0 supports empty password)
 119         AM_PATH_LIBGCRYPT([1.6.0], [use_internal_pbkdf2=0], [use_internal_pbkdf2=1])
 120         AM_PATH_LIBGCRYPT($GCRYPT_REQ_VERSION,,[AC_MSG_ERROR([You need the gcrypt library.])])
 121
 122         if test x$enable_static_cryptsetup = xyes; then
 123                 saved_LIBS=$LIBS
 124                 LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
 125                 AC_CHECK_LIB(gcrypt, gcry_check_version,,
 126                         AC_MSG_ERROR([Cannot find static gcrypt library.]),
 127                         [-lgpg-error])
 128                 LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
 129                 LIBS=$saved_LIBS
 130         fi
 131
 132         CRYPTO_CFLAGS=$LIBGCRYPT_CFLAGS
 133         CRYPTO_LIBS=$LIBGCRYPT_LIBS
 134         CRYPTO_STATIC_LIBS=$LIBGCRYPT_STATIC_LIBS
 135
 136         AC_DEFINE_UNQUOTED(GCRYPT_REQ_VERSION, ["$GCRYPT_REQ_VERSION"], [Requested gcrypt version])
 137 ])
 138
 139 AC_DEFUN([CONFIGURE_OPENSSL], [
 140         PKG_CHECK_MODULES([OPENSSL], [openssl >= 0.9.8],,
 141                 AC_MSG_ERROR([You need openssl library.]))
 142         CRYPTO_CFLAGS=$OPENSSL_CFLAGS
 143         CRYPTO_LIBS=$OPENSSL_LIBS
 144         use_internal_pbkdf2=0
 145
 146         if test x$enable_static_cryptsetup = xyes; then
 147                 saved_PKG_CONFIG=$PKG_CONFIG
 148                 PKG_CONFIG="$PKG_CONFIG --static"
 149                 PKG_CHECK_MODULES([OPENSSL], [openssl])
 150                 CRYPTO_STATIC_LIBS=$OPENSSL_LIBS
 151                 PKG_CONFIG=$saved_PKG_CONFIG
 152         fi
 153         NO_FIPS([])
 154 ])
 155
 156 AC_DEFUN([CONFIGURE_NSS], [
 157         if test x$enable_static_cryptsetup = xyes; then
 158                 AC_MSG_ERROR([Static build of cryptsetup is not supported with NSS.])
 159         fi
 160
 161         AC_MSG_WARN([NSS backend does NOT provide backward compatibility (missing ripemd160 hash).])
 162
 163         PKG_CHECK_MODULES([NSS], [nss],,
 164                 AC_MSG_ERROR([You need nss library.]))
 165
 166         saved_CFLAGS=$CFLAGS
 167         CFLAGS="$CFLAGS $NSS_CFLAGS"
 168         AC_CHECK_DECLS([NSS_GetVersion], [], [], [#include <nss.h>])
 169         CFLAGS=$saved_CFLAGS
 170
 171         CRYPTO_CFLAGS=$NSS_CFLAGS
 172         CRYPTO_LIBS=$NSS_LIBS
 173         use_internal_pbkdf2=1
 174         NO_FIPS([])
 175 ])
 176
 177 AC_DEFUN([CONFIGURE_KERNEL], [
 178         AC_CHECK_HEADERS(linux/if_alg.h,,
 179                 [AC_MSG_ERROR([You need Linux kernel headers with userspace crypto interface.])])
 180 #       AC_CHECK_DECLS([AF_ALG],,
 181 #               [AC_MSG_ERROR([You need Linux kernel with userspace crypto interface.])],
 182 #               [#include <sys/socket.h>])
 183         use_internal_pbkdf2=1
 184         NO_FIPS([])
 185 ])
 186
 187 AC_DEFUN([CONFIGURE_NETTLE], [
 188         AC_CHECK_HEADERS(nettle/sha.h,,
 189                 [AC_MSG_ERROR([You need Nettle cryptographic library.])])
 190
 191         saved_LIBS=$LIBS
 192         AC_CHECK_LIB(nettle, nettle_ripemd160_init,,
 193                 [AC_MSG_ERROR([You need Nettle library version 2.4 or more recent.])])
 194         CRYPTO_LIBS=$LIBS
 195         LIBS=$saved_LIBS
 196
 197         CRYPTO_STATIC_LIBS=$CRYPTO_LIBS
 198         use_internal_pbkdf2=1
 199         NO_FIPS([])
 200 ])
 201
 202 dnl ==========================================================================
 203 saved_LIBS=$LIBS
 204
 205 AC_ARG_ENABLE([static-cryptsetup],
 206         AS_HELP_STRING([--enable-static-cryptsetup],
 207         [enable build of static cryptsetup binary]))
 208 if test x$enable_static_cryptsetup = xyes; then
 209         if test x$enable_static = xno; then
 210                 AC_MSG_WARN([Requested static cryptsetup build, enabling static library.])
 211                 enable_static=yes
 212         fi
 213 fi
 214 AM_CONDITIONAL(STATIC_TOOLS, test x$enable_static_cryptsetup = xyes)
 215
 216 AC_ARG_ENABLE(veritysetup,
 217         AS_HELP_STRING([--disable-veritysetup],
 218         [disable veritysetup support]),[], [enable_veritysetup=yes])
 219 AM_CONDITIONAL(VERITYSETUP, test x$enable_veritysetup = xyes)
 220
 221 AC_ARG_ENABLE([cryptsetup-reencrypt],
 222         AS_HELP_STRING([--enable-cryptsetup-reencrypt],
 223         [enable cryptsetup-reencrypt tool]))
 224 AM_CONDITIONAL(REENCRYPT, test x$enable_cryptsetup_reencrypt = xyes)
 225
 226 AC_ARG_ENABLE(selinux,
 227         AS_HELP_STRING([--disable-selinux],
 228         [disable selinux support [default=auto]]),[], [])
 229
 230 AC_ARG_ENABLE([udev],
 231         AS_HELP_STRING([--disable-udev],
 232         [disable udev support]),[], enable_udev=yes)
 233
 234 dnl Try to use pkg-config for devmapper, but fallback to old detection
 235 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
 236         AC_CHECK_LIB(devmapper, dm_task_set_name,,
 237                 [AC_MSG_ERROR([You need the device-mapper library.])])
 238         AC_CHECK_LIB(devmapper, dm_task_set_message,,
 239                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
 240         DEVMAPPER_LIBS=$LIBS
 241 ])
 242 LIBS=$saved_LIBS
 243
 244 LIBS="$LIBS $DEVMAPPER_LIBS"
 245 AC_CHECK_DECLS([dm_task_secure_data], [], [], [#include <libdevmapper.h>])
 246 AC_CHECK_DECLS([dm_task_retry_remove], [], [], [#include <libdevmapper.h>])
 247 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
 248 if test "x$enable_udev" = xyes; then
 249         if test "x$have_cookie" = xno; then
 250                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 251         else
 252                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 253         fi
 254 fi
 255 LIBS=$saved_LIBS
 256
 257 dnl Crypto backend configuration.
 258 AC_ARG_WITH([crypto_backend],
 259         AS_HELP_STRING([--with-crypto_backend=BACKEND], [crypto backend (gcrypt/openssl/nss/kernel/nettle) [gcrypt]]),
 260         [], with_crypto_backend=gcrypt
 261 )
 262
 263 dnl Kernel crypto API backend needed for benchmark and tcrypt
 264 AC_ARG_ENABLE([kernel_crypto], AS_HELP_STRING([--disable-kernel_crypto],
 265         [disable kernel userspace crypto (no benchmark and tcrypt)]),
 266         [with_kernel_crypto=$enableval],
 267         [with_kernel_crypto=yes])
 268
 269 if test "x$with_kernel_crypto" = "xyes"; then
 270         AC_CHECK_HEADERS(linux/if_alg.h,,
 271                 [AC_MSG_ERROR([You need Linux kernel headers with userspace crypto interface. (Or use --disable-kernel_crypto.)])])
 272         AC_DEFINE(ENABLE_AF_ALG, 1, [Enable using of kernel userspace crypto])
 273 fi
 274
 275 case $with_crypto_backend in
 276         gcrypt)  CONFIGURE_GCRYPT([]) ;;
 277         openssl) CONFIGURE_OPENSSL([]) ;;
 278         nss)     CONFIGURE_NSS([]) ;;
 279         kernel)  CONFIGURE_KERNEL([]) ;;
 280         nettle)  CONFIGURE_NETTLE([]) ;;
 281         *) AC_MSG_ERROR([Unknown crypto backend.]) ;;
 282 esac
 283 AM_CONDITIONAL(CRYPTO_BACKEND_GCRYPT,  test $with_crypto_backend = gcrypt)
 284 AM_CONDITIONAL(CRYPTO_BACKEND_OPENSSL, test $with_crypto_backend = openssl)
 285 AM_CONDITIONAL(CRYPTO_BACKEND_NSS,     test $with_crypto_backend = nss)
 286 AM_CONDITIONAL(CRYPTO_BACKEND_KERNEL,  test $with_crypto_backend = kernel)
 287 AM_CONDITIONAL(CRYPTO_BACKEND_NETTLE,  test $with_crypto_backend = nettle)
 288
 289 AM_CONDITIONAL(CRYPTO_INTERNAL_PBKDF2, test $use_internal_pbkdf2 = 1)
 290 AC_DEFINE_UNQUOTED(USE_INTERNAL_PBKDF2, [$use_internal_pbkdf2], [Use internal PBKDF2])
 291
 292 dnl Magic for cryptsetup.static build.
 293 if test x$enable_static_cryptsetup = xyes; then
 294         saved_PKG_CONFIG=$PKG_CONFIG
 295         PKG_CONFIG="$PKG_CONFIG --static"
 296
 297         LIBS="$saved_LIBS -static"
 298         AC_CHECK_LIB(popt, poptGetContext,,
 299                 AC_MSG_ERROR([Cannot find static popt library.]))
 300
 301         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 302         LIBS="$saved_LIBS -static"
 303         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 304                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 305                 if test "x$enable_selinux" != xno; then
 306                         AC_CHECK_LIB(sepol, sepol_bool_set)
 307                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 308                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 309                 fi
 310         ])
 311         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 312         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 313                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 314
 315         dnl Try to detect uuid static library.
 316         LIBS="$saved_LIBS -static"
 317         AC_CHECK_LIB(uuid, uuid_generate,,
 318                 AC_MSG_ERROR([Cannot find static uuid library.]))
 319
 320         LIBS=$saved_LIBS
 321         PKG_CONFIG=$saved_PKG_CONFIG
 322 fi
 323
 324 AC_SUBST([DEVMAPPER_LIBS])
 325 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 326
 327 AC_SUBST([PWQUALITY_LIBS])
 328 AC_SUBST([PWQUALITY_STATIC_LIBS])
 329
 330 AC_SUBST([CRYPTO_CFLAGS])
 331 AC_SUBST([CRYPTO_LIBS])
 332 AC_SUBST([CRYPTO_STATIC_LIBS])
 333
 334 AC_SUBST([LIBCRYPTSETUP_VERSION])
 335 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 336 AC_SUBST([LIBCRYPTSETUP_VERSION_FIPS])
 337
 338 dnl ==========================================================================
 339 AC_ARG_ENABLE([dev-random], AS_HELP_STRING([--enable-dev-random],
 340 [use blocking /dev/random by default for key generator (otherwise use /dev/urandom)]),
 341 [default_rng=/dev/random], [default_rng=/dev/urandom])
 342 AC_DEFINE_UNQUOTED(DEFAULT_RNG, ["$default_rng"], [default RNG type for key generator])
 343
 344 dnl ==========================================================================
 345 AC_DEFUN([CS_DEFINE],
 346         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 347 ])
 348
 349 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 350         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 351         [CS_DEFINE([$1], ["$withval"], [$2])],
 352         [CS_DEFINE([$1], ["$3"], [$2])]
 353 )])
 354
 355 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 356         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 357         [CS_DEFINE([$1], [$withval], [$2])],
 358         [CS_DEFINE([$1], [$3], [$2])]
 359 )])
 360
 361 dnl ==========================================================================
 362 dnl Python bindings
 363 AC_ARG_ENABLE([python], AS_HELP_STRING([--enable-python],[enable Python bindings]),
 364 [with_python=$enableval],
 365 [with_python=no])
 366
 367 if test "x$with_python" = "xyes"; then
 368         AM_PATH_PYTHON([2.4])
 369
 370         if ! test -x "$PYTHON-config" ; then
 371             AC_MSG_ERROR([Cannot find python development packages to build bindings])
 372         fi
 373
 374         PYTHON_INCLUDES=$($PYTHON-config --includes)
 375         AC_SUBST(PYTHON_INCLUDES)
 376 fi
 377 AM_CONDITIONAL([PYTHON_CRYPTSETUP], [test "x$with_python" = "xyes"])
 378
 379 dnl ==========================================================================
 380 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 381 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 382 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 383 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 384
 385 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 386 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 387 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 388 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 389 CS_NUM_WITH([luks1-iter-time],[PBKDF2 iteration time for LUKS1 (in ms)], [1000])
 390
 391 CS_STR_WITH([loopaes-cipher], [cipher for loop-AES mode], [aes])
 392 CS_NUM_WITH([loopaes-keybits],[key length in bits for loop-AES mode], [256])
 393
 394 CS_NUM_WITH([keyfile-size-maxkb],[maximum keyfile size (in KiB)], [8192])
 395 CS_NUM_WITH([passphrase-size-max],[maximum keyfile size (in characters)], [512])
 396
 397 CS_STR_WITH([verity-hash],       [hash function for verity mode], [sha256])
 398 CS_NUM_WITH([verity-data-block], [data block size for verity mode], [4096])
 399 CS_NUM_WITH([verity-hash-block], [hash block size for verity mode], [4096])
 400 CS_NUM_WITH([verity-salt-size],  [salt size for verity mode], [32])
 401
 402 dnl ==========================================================================
 403
 404 AC_CONFIG_FILES([ Makefile
 405 lib/Makefile
 406 lib/libcryptsetup.pc
 407 lib/crypto_backend/Makefile
 408 lib/luks1/Makefile
 409 lib/loopaes/Makefile
 410 lib/verity/Makefile
 411 lib/tcrypt/Makefile
 412 src/Makefile
 413 po/Makefile.in
 414 man/Makefile
 415 tests/Makefile
 416 python/Makefile
 417 ])
 418 AC_OUTPUT