configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT(connman, 0.80)
   3
   4 AM_INIT_AUTOMAKE([foreign subdir-objects color-tests])
   5 AM_CONFIG_HEADER(config.h)
   6
   7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   8
   9 AM_MAINTAINER_MODE
  10
  11 AC_PREFIX_DEFAULT(/usr/local)
  12
  13 PKG_PROG_PKG_CONFIG
  14
  15 COMPILER_FLAGS
  16
  17 AC_SUBST(abs_top_srcdir)
  18 AC_SUBST(abs_top_builddir)
  19
  20 AC_LANG_C
  21
  22 AC_PROG_CC
  23 AM_PROG_CC_C_O
  24 AC_PROG_CC_PIE
  25 AC_PROG_INSTALL
  26 AM_PROG_MKDIR_P
  27
  28 m4_define([_LT_AC_TAGCONFIG], [])
  29 m4_ifdef([AC_LIBTOOL_TAGS], [AC_LIBTOOL_TAGS([])])
  30
  31 AC_DISABLE_STATIC
  32 AC_PROG_LIBTOOL
  33
  34 AC_ARG_ENABLE(optimization, AC_HELP_STRING([--disable-optimization],
  35                         [disable code optimization through compiler]), [
  36         if (test "${enableval}" = "no"); then
  37                 CFLAGS="$CFLAGS -O0"
  38         fi
  39 ])
  40
  41 GTK_DOC_CHECK
  42
  43 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug],
  44                         [enable compiling with debugging information]), [
  45         if (test "${enableval}" = "yes" &&
  46                                 test "${ac_cv_prog_cc_g}" = "yes"); then
  47                 CFLAGS="$CFLAGS -g"
  48         fi
  49 ])
  50
  51 AC_ARG_ENABLE(pie, AC_HELP_STRING([--enable-pie],
  52                         [enable position independent executables flag]), [
  53         if (test "${enableval}" = "yes" &&
  54                                 test "${ac_cv_prog_cc_pie}" = "yes"); then
  55                 CFLAGS="$CFLAGS -fPIE"
  56                 LDFLAGS="$LDFLAGS -pie"
  57         fi
  58 ])
  59
  60 AC_ARG_ENABLE(threads,
  61         AC_HELP_STRING([--enable-threads], [enable threading support]),
  62                         [enable_threads=${enableval}], [enable_threads="no"])
  63
  64 AC_ARG_ENABLE(ethernet,
  65         AC_HELP_STRING([--enable-ethernet], [enable Ethernet support]),
  66                         [enable_ethernet=${enableval}], [enable_ethernet="no"])
  67 AM_CONDITIONAL(ETHERNET, test "${enable_ethernet}" != "no")
  68 AM_CONDITIONAL(ETHERNET_BUILTIN, test "${enable_ethernet}" = "builtin")
  69
  70 AC_ARG_ENABLE(wifi,
  71         AC_HELP_STRING([--enable-wifi], [enable WiFi support]),
  72                         [enable_wifi=${enableval}], [enable_wifi="no"])
  73 if (test "${enable_wifi}" != "no"); then
  74         AC_PATH_PROG(WPASUPPLICANT, [wpa_supplicant], [],
  75                                                 $PATH:/sbin:/usr/sbin)
  76 fi
  77 AM_CONDITIONAL(WIFI, test "${enable_wifi}" != "no")
  78 AM_CONDITIONAL(WIFI_BUILTIN, test "${enable_wifi}" = "builtin")
  79
  80 AC_ARG_ENABLE(bluetooth,
  81         AC_HELP_STRING([--enable-bluetooth], [enable Bluetooth support]),
  82                         [enable_bluetooth=${enableval}], [enable_bluetooth="no"])
  83 AM_CONDITIONAL(BLUETOOTH, test "${enable_bluetooth}" != "no")
  84 AM_CONDITIONAL(BLUETOOTH_BUILTIN, test "${enable_bluetooth}" = "builtin")
  85
  86 AC_ARG_ENABLE(hh2serial-gps,
  87         AC_HELP_STRING([--enable-hh2serial-gps], [enable hh2serial GPS support]),
  88                         [enable_hh2serial_gps=${enableval}], [enable_hh2serial_gps="no"])
  89 AM_CONDITIONAL(HH2SERIAL_GPS, test "${enable_hh2serial_gps}" != "no")
  90 AM_CONDITIONAL(HH2SERIAL_GPS_BUILTIN, test "${enable_hh2serial_gps}" = "builtin")
  91
  92 AC_ARG_ENABLE(ofono,
  93         AC_HELP_STRING([--enable-ofono], [enable oFono support]),
  94                         [enable_ofono=${enableval}], [enable_ofono="no"])
  95 AM_CONDITIONAL(OFONO, test "${enable_ofono}" != "no")
  96 AM_CONDITIONAL(OFONO_BUILTIN, test "${enable_ofono}" = "builtin")
  97
  98 AC_ARG_WITH(openconnect, AC_HELP_STRING([--with-openconnect=PROGRAM],
  99         [specify location of openconnect binary]), [path_openconnect=${withval}])
 100
 101 AC_ARG_ENABLE(openconnect,
 102         AC_HELP_STRING([--enable-openconnect], [enable openconnect support]),
 103                         [enable_openconnect=${enableval}], [enable_openconnect="no"])
 104 if (test "${enable_openconnect}" != "no"); then
 105         if (test -z "${path_openconnect}"); then
 106                 AC_PATH_PROG(OPENCONNECT, [openconnect], [], $PATH:/sbin:/usr/sbin)
 107                 if (test -z "${OPENCONNECT}"); then
 108                         AC_MSG_ERROR(openconnect binary not found)
 109                 fi
 110         else
 111                 OPENCONNECT="${path_openconnect}"
 112                 AC_SUBST(OPENCONNECT)
 113         fi
 114 fi
 115 AM_CONDITIONAL(OPENCONNECT, test "${enable_openconnect}" != "no")
 116 AM_CONDITIONAL(OPENCONNECT_BUILTIN, test "${enable_openconnect}" = "builtin")
 117
 118 AC_ARG_WITH(openvpn, AC_HELP_STRING([--with-openvpn=PROGRAM],
 119         [specify location of openvpn binary]), [path_openvpn=${withval}])
 120
 121 AC_ARG_ENABLE(openvpn,
 122         AC_HELP_STRING([--enable-openvpn], [enable openvpn support]),
 123                         [enable_openvpn=${enableval}], [enable_openvpn="no"])
 124 if (test "${enable_openvpn}" != "no"); then
 125         if (test -z "${path_openvpn}"); then
 126                 AC_PATH_PROG(OPENVPN, [openvpn], [], $PATH:/sbin:/usr/sbin)
 127                 if (test -z "${OPENVPN}"); then
 128                         AC_MSG_ERROR(openvpn binary not found)
 129                 fi
 130         else
 131                 OPENVPN="${path_openvpn}"
 132                 AC_SUBST(OPENVPN)
 133         fi
 134 fi
 135 AM_CONDITIONAL(OPENVPN, test "${enable_openvpn}" != "no")
 136 AM_CONDITIONAL(OPENVPN_BUILTIN, test "${enable_openvpn}" = "builtin")
 137
 138 AC_ARG_WITH(vpnc, AC_HELP_STRING([--with-vpnc=PROGRAM],
 139         [specify location of vpnc binary]), [path_vpnc=${withval}])
 140
 141 AC_ARG_ENABLE(vpnc,
 142         AC_HELP_STRING([--enable-vpnc], [enable vpnc support]),
 143                 [enable_vpnc=${enableval}], [enable_vpnc="no"])
 144 if (test "${enable_vpnc}" != "no"); then
 145         if (test -z "${path_vpnc}"); then
 146                 AC_PATH_PROG(VPNC, [vpnc], [], $PATH:/sbin:/usr/sbin)
 147                 if (test -z "${VPNC}"); then
 148                         AC_MSG_ERROR(vpnc binary not found)
 149                 fi
 150         else
 151                 VPNC="${path_vpnc}"
 152                 AC_SUBST(VPNC)
 153         fi
 154 fi
 155 AM_CONDITIONAL(VPNC, test "${enable_vpnc}" != "no")
 156 AM_CONDITIONAL(VPNC_BUILTIN, test "${enable_vpnc}" = "builtin")
 157
 158 AC_ARG_ENABLE(l2tp,
 159         AC_HELP_STRING([--enable-l2tp], [enable l2tp support]),
 160                         [enable_l2tp=${enableval}], [enable_l2tp="no"])
 161 if (test "${enable_l2tp}" != "no"); then
 162         if (test -z "${path_pppd}"); then
 163                 AC_PATH_PROG(PPPD, [pppd], [/usr/sbin/pppd], $PATH:/sbin:/usr/sbin)
 164         else
 165                 PPPD="${path_pppd}"
 166                 AC_SUBST(PPPD)
 167         fi
 168         AC_CHECK_HEADERS(pppd/pppd.h, dummy=yes,
 169                         AC_MSG_ERROR(ppp header files are required))
 170         if (test -z "${path_l2tp}"); then
 171                 AC_PATH_PROG(L2TP, [xl2tpd], [/usr/sbin/xl2tpd], $PATH:/sbin:/usr/sbin)
 172         else
 173                 L2TP="${path_l2tp}"
 174                 AC_SUBST(L2TP)
 175         fi
 176 fi
 177 AM_CONDITIONAL(L2TP, test "${enable_l2tp}" != "no")
 178 AM_CONDITIONAL(L2TP_BUILTIN, test "${enable_l2tp}" = "builtin")
 179
 180 AC_ARG_ENABLE(pptp,
 181         AC_HELP_STRING([--enable-pptp], [enable pptp support]),
 182                         [enable_pptp=${enableval}], [enable_pptp="no"])
 183 if (test "${enable_pptp}" != "no"); then
 184         if (test -z "${path_pppd}"); then
 185                 AC_PATH_PROG(PPPD, [pppd], [/usr/sbin/pppd], $PATH:/sbin:/usr/sbin)
 186         else
 187                 PPPD="${path_pppd}"
 188                 AC_SUBST(PPPD)
 189         fi
 190         AC_CHECK_HEADERS(pppd/pppd.h, dummy=yes,
 191                         AC_MSG_ERROR(ppp header files are required))
 192         if (test -z "${path_pptp}"); then
 193                 AC_PATH_PROG(PPTP, [pptp], [/usr/sbin/pptp], $PATH:/sbin:/usr/sbin)
 194         else
 195                 PPTP="${path_pptp}"
 196                 AC_SUBST(PPTP)
 197         fi
 198 fi
 199 AM_CONDITIONAL(PPTP, test "${enable_pptp}" != "no")
 200 AM_CONDITIONAL(PPTP_BUILTIN, test "${enable_pptp}" = "builtin")
 201
 202 AC_ARG_ENABLE(loopback,
 203         AC_HELP_STRING([--enable-loopback], [enable loopback support]),
 204                         [enable_loopback=${enableval}], [enable_loopback="no"])
 205 if (test "${enable_loopback}" != "no"); then
 206         AC_CHECK_HEADERS(sys/inotify.h, dummy=yes,
 207                         AC_MSG_ERROR(inotify header files are required))
 208
 209         AC_CHECK_LIB(c, inotify_init, dummy=yes,
 210                         AC_MSG_ERROR(inotify library support is required))
 211 fi
 212 AM_CONDITIONAL(LOOPBACK, test "${enable_loopback}" != "no")
 213 AM_CONDITIONAL(LOOPBACK_BUILTIN, test "${enable_loopback}" = "builtin")
 214
 215 AC_ARG_ENABLE(pacrunner,
 216         AC_HELP_STRING([--enable-pacrunner], [enable PAC runner support]),
 217                         [enable_pacrunner=${enableval}], [enable_pacrunner="no"])
 218
 219 AM_CONDITIONAL(PACRUNNER, test "${enable_pacrunner}" != "no")
 220 AM_CONDITIONAL(PACRUNNER_BUILTIN, test "${enable_pacrunner}" = "builtin")
 221
 222 AC_CHECK_HEADERS(resolv.h, dummy=yes,
 223         AC_MSG_ERROR(resolver header files are required))
 224 AC_CHECK_LIB(resolv, ns_initparse, dummy=yes, [
 225         AC_CHECK_LIB(resolv, __ns_initparse, dummy=yes,
 226                 AC_MSG_ERROR(resolver library support is required))
 227 ])
 228
 229 AC_CHECK_FUNC(signalfd, dummy=yes,
 230                         AC_MSG_ERROR(signalfd support is required))
 231
 232 AC_CHECK_LIB(dl, dlopen, dummy=yes,
 233                         AC_MSG_ERROR(dynamic linking loader is required))
 234
 235 AC_ARG_WITH(iwmxsdk, AC_HELP_STRING([--with-iwmxsdk=PATH],
 236                                                 [path to Intel WiMAX SDK]),
 237                                 [pkgconfig_iwmxsdk=${withval}/lib/pkgconfig])
 238
 239 AC_ARG_ENABLE(iwmx, AC_HELP_STRING([--enable-iwmx],
 240                 [enable Intel WiMAX support]), [enable_iwmx=${enableval}])
 241 if (test "${enable_iwmx}" = "yes"); then
 242         enable_threads="yes"
 243         export PKG_CONFIG_PATH="${pkgconfig_iwmxsdk}"
 244         PKG_CHECK_MODULES(IWMXSDK, libiWmxSdk-0, dummy=yes,
 245                                 AC_MSG_ERROR(Intel WiMAX SDK is required))
 246         PKG_CONFIG_PATH=""
 247         AC_SUBST(IWMXSDK_CFLAGS)
 248         AC_SUBST(IWMXSDK_LIBS)
 249
 250         # Fix API compat breakage from 1.4 to 1.5...
 251         CPPFLAGS_save=$CPPFLAGS
 252         CPPFLAGS="$IWMXSDK_CFLAGS $CPPFLAGS"
 253         AH_TEMPLATE([HAVE_IWMXSDK_STATUS_IDLE],
 254                     [WIMAX_API_DEVICE_STATUS_Connection_Idle is present])
 255         AC_CHECK_DECL(WIMAX_API_DEVICE_STATUS_Connection_Idle,
 256                       [AC_DEFINE([HAVE_IWMXSDK_STATUS_IDLE], [1], [])],
 257                       [],
 258                       [[#include <WiMaxType.h>]])
 259
 260         AH_TEMPLATE([HAVE_WIMAX_API_DEVICE_ID],
 261                     [WIMAX_API_DEVICE_ID is present])
 262         AC_CHECK_TYPE(WIMAX_API_DEVICE_ID,
 263                       [AC_DEFINE([HAVE_WIMAX_API_DEVICE_ID], [1], [])],
 264                       [],
 265                       [[#include <WiMaxType.h>]])
 266
 267         AH_TEMPLATE([HAVE_WIMAX_API_HW_DEVICE_ID],
 268                     [WIMAX_API_HW_DEVICE_ID is present])
 269         AC_CHECK_TYPE(WIMAX_API_HW_DEVICE_ID,
 270                       [AC_DEFINE([HAVE_WIMAX_API_HW_DEVICE_ID], [1], [])],
 271                       [],
 272                       [[#include <WiMaxType.h>]])
 273
 274         AH_TEMPLATE([HAVE_WIMAX_API_NSP_INFO_EX],
 275                     [WIMAX_API_NSP_INFO_EX is present])
 276         AC_CHECK_TYPE(WIMAX_API_NSP_INFO_EX,
 277                       [AC_DEFINE([HAVE_WIMAX_API_NSP_INFO_EX], [1], [])],
 278                       [],
 279                       [[#include <WiMaxType.h>]
 280                        [#include <WiMaxTypesEx.h>]])
 281
 282         AH_TEMPLATE([HAVE_WIMAX_API_CONNECTED_NSP_INFO],
 283                     [WIMAX_API_CONNECTED_NSP_INFO is present])
 284         AC_CHECK_TYPE(WIMAX_API_CONNECTED_NSP_INFO,
 285                       [AC_DEFINE([HAVE_WIMAX_API_CONNECTED_NSP_INFO], [1], [])],
 286                       [],
 287                       [[#include <WiMaxType.h>]])
 288
 289         CPPFLAGS=$CPPFLAGS_save
 290 fi
 291 AM_CONDITIONAL(IWMX, test "${enable_iwmx}" = "yes")
 292
 293 AC_ARG_ENABLE(iospm, AC_HELP_STRING([--enable-iospm],
 294                 [enable Intel OSPM support]), [enable_iospm=${enableval}])
 295 AM_CONDITIONAL(IOSPM, test "${enable_iospm}" = "yes")
 296
 297 AC_ARG_ENABLE(nmcompat,
 298         AC_HELP_STRING([--enable-nmcompat], [enable nmcompat support]),
 299                         [enable_nmcompat=${enableval}], [enable_nmcompat="no"])
 300 AM_CONDITIONAL(NMCOMPAT, test "${enable_nmcompat}" != "no")
 301 AM_CONDITIONAL(NMCOMPAT_BUILTIN, test "${enable_nmcompat}" = "builtin")
 302
 303 AC_ARG_ENABLE(tist,
 304         AC_HELP_STRING([--enable-tist], [enable TI Shared Transport support]),
 305                         [enable_tist=${enableval}], [enable_tist="no"])
 306 AM_CONDITIONAL(TIST, test "${enable_tist}" != "no")
 307 AM_CONDITIONAL(TIST_BUILTIN, test "${enable_tist}" = "builtin")
 308
 309 AC_ARG_WITH(stats-max-file-size, AC_HELP_STRING([--with-stats-max-file-size=SIZE],
 310                         [Maximal size of a statistics round robin file]),
 311                         [stats_max_file_size=${withval}])
 312
 313 if (test -z "${stats_max_file_size}"); then
 314    # default size is 16 kByte
 315    stats_max_file_size="16 * 8 * 128"
 316 fi
 317
 318 AC_DEFINE_UNQUOTED([STATS_MAX_FILE_SIZE], (${stats_max_file_size}), [Maximal size of a statistics round robin file])
 319
 320 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.22, dummy=yes,
 321                                 AC_MSG_ERROR(GLib >= 2.22 is required))
 322 AC_SUBST(GLIB_CFLAGS)
 323 AC_SUBST(GLIB_LIBS)
 324
 325 if (test "${enable_threads}" = "yes"); then
 326         AC_DEFINE(NEED_THREADS, 1, [Define if threading support is required])
 327         PKG_CHECK_MODULES(GTHREAD, gthread-2.0 >= 2.16, dummy=yes,
 328                                 AC_MSG_ERROR(GThread >= 2.16 is required))
 329         GLIB_CFLAGS="$GLIB_CFLAGS $GTHREAD_CFLAGS"
 330         GLIB_LIBS="$GLIB_LIBS $GTHREAD_LIBS"
 331 fi
 332
 333 PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.4, dummy=yes,
 334                                 AC_MSG_ERROR(D-Bus >= 1.4 is required))
 335 AC_SUBST(DBUS_CFLAGS)
 336 AC_SUBST(DBUS_LIBS)
 337
 338 AC_ARG_WITH(dbusconfdir, AC_HELP_STRING([--with-dbusconfdir=PATH],
 339         [path to D-Bus config directory]), [path_dbusconf=${withval}],
 340                 [path_dbusconf="`$PKG_CONFIG --variable=sysconfdir dbus-1`"])
 341 if (test -z "${path_dbusconf}"); then
 342         DBUS_CONFDIR="${sysconfdir}/dbus-1/system.d"
 343 else
 344         DBUS_CONFDIR="${path_dbusconf}/dbus-1/system.d"
 345 fi
 346 AC_SUBST(DBUS_CONFDIR)
 347
 348 AC_ARG_WITH(dbusdatadir, AC_HELP_STRING([--with-dbusdatadir=PATH],
 349         [path to D-Bus data directory]), [path_dbusdata=${withval}],
 350                 [path_dbusdata="`$PKG_CONFIG --variable=datadir dbus-1`"])
 351 if (test -z "${path_dbusdata}"); then
 352         DBUS_DATADIR="${datadir}/dbus-1/system-services"
 353 else
 354         DBUS_DATADIR="${path_dbusdata}/dbus-1/system-services"
 355 fi
 356 AC_SUBST(DBUS_DATADIR)
 357
 358 AC_ARG_WITH([systemdunitdir], AC_HELP_STRING([--with-systemdunitdir=DIR],
 359         [path to systemd service directory]), [path_systemdunit=${withval}],
 360                 [path_systemdunit="`$PKG_CONFIG --variable=systemdsystemunitdir systemd`"])
 361 if (test -n "${path_systemdunit}"); then
 362         SYSTEMD_UNITDIR="${path_systemdunit}"
 363         AC_SUBST(SYSTEMD_UNITDIR)
 364 fi
 365 AM_CONDITIONAL(SYSTEMD, test -n "${path_systemdunit}")
 366
 367 PKG_CHECK_MODULES(XTABLES, xtables, dummy=yes,
 368                                 AC_MSG_ERROR(Xtables library is required))
 369 AC_SUBST(XTABLES_CFLAGS)
 370 AC_SUBST(XTABLES_LIBS)
 371
 372 AC_ARG_ENABLE(polkit,
 373         AC_HELP_STRING([--enable-polkit], [enable PolicyKit support]),
 374                         [enable_polkit=${enableval}], [enable_polkit="no"])
 375 if (test "${enable_polkit}" != "no"); then
 376         POLKIT_DATADIR="`$PKG_CONFIG --variable=actiondir polkit`"
 377         POLKIT_DATADIR=""
 378         if (test -z "${POLKIT_DATADIR}"); then
 379                 POLKIT_DATADIR="${datadir}/polkit-1/actions"
 380         fi
 381         AC_SUBST(POLKIT_DATADIR)
 382 fi
 383 AM_CONDITIONAL(POLKIT, test "${enable_polkit}" != "no")
 384 AM_CONDITIONAL(POLKIT_BUILTIN, test "${enable_polkit}" = "builtin")
 385
 386 AC_ARG_ENABLE(client, AC_HELP_STRING([--enable-client],
 387                 [enable command line client]), [enable_client=${enableval}])
 388 AM_CONDITIONAL(CLIENT, test "${enable_client}" = "yes")
 389
 390 AC_ARG_ENABLE(tools, AC_HELP_STRING([--enable-tools],
 391                 [enable testing tools]), [enable_tools=${enableval}])
 392 if (test "${enable_tools}" = "yes"); then
 393         PKG_CHECK_MODULES(GNUTLS, gnutls, dummy=yes,
 394                                 AC_MSG_ERROR(GnuTLS library is required))
 395         AC_SUBST(GNUTLS_CFLAGS)
 396         AC_SUBST(GNUTLS_LIBS)
 397
 398         AC_CHECK_HEADERS(linux/if_alg.h, dummy=yes,
 399                 AC_MSG_ERROR(User-space algorithm header files are required))
 400 fi
 401 AM_CONDITIONAL(TOOLS, test "${enable_tools}" = "yes")
 402
 403 AC_ARG_ENABLE(test, AC_HELP_STRING([--enable-test],
 404                 [enable test/example scripts]), [enable_test=${enableval}])
 405 AM_CONDITIONAL(TEST, test "${enable_test}" = "yes")
 406
 407 AC_ARG_ENABLE(fake, AC_HELP_STRING([--enable-fake],
 408                 [enable fake device support]), [enable_fake=${enableval}])
 409 AM_CONDITIONAL(FAKE, test "${enable_fake}" = "yes")
 410
 411 AC_ARG_ENABLE(capng, AC_HELP_STRING([--enable-capng],
 412                 [enable capabilities support]), [enable_capng=${enableval}])
 413 if (test "${enable_capng}" = "yes"); then
 414         PKG_CHECK_MODULES(CAPNG, libcap-ng, dummy=yes,
 415                                 AC_MSG_ERROR(Capabilities library is required))
 416         AC_SUBST(CAPNG_CFLAGS)
 417         AC_SUBST(CAPNG_LIBS)
 418         AC_DEFINE(HAVE_CAPNG, 1, [Define to 1 if you have capabilities library.])
 419 fi
 420
 421 AC_ARG_ENABLE(datafiles, AC_HELP_STRING([--disable-datafiles],
 422                         [don't install configuration and data files]),
 423                                         [enable_datafiles=${enableval}])
 424 AM_CONDITIONAL(DATAFILES, test "${enable_datafiles}" != "no")
 425
 426 AC_OUTPUT(Makefile include/version.h src/connman.service
 427                                 scripts/connman doc/version.xml connman.pc)