Modules/FindCUDA/make2cmake.cmake

   1 #  James Bigler, NVIDIA Corp (nvidia.com - jbigler)
   2 #  Abe Stephens, SCI Institute -- http://www.sci.utah.edu/~abe/FindCuda.html
   3 #
   4 #  Copyright (c) 2008 - 2009 NVIDIA Corporation.  All rights reserved.
   5 #
   6 #  Copyright (c) 2007-2009
   7 #  Scientific Computing and Imaging Institute, University of Utah
   8 #
   9 #  This code is licensed under the MIT License.  See the FindCUDA.cmake script
  10 #  for the text of the license.
  11
  12 # The MIT License
  13 #
  14 # License for the specific language governing rights and limitations under
  15 # Permission is hereby granted, free of charge, to any person obtaining a
  16 # copy of this software and associated documentation files (the "Software"),
  17 # to deal in the Software without restriction, including without limitation
  18 # the rights to use, copy, modify, merge, publish, distribute, sublicense,
  19 # and/or sell copies of the Software, and to permit persons to whom the
  20 # Software is furnished to do so, subject to the following conditions:
  21 #
  22 # The above copyright notice and this permission notice shall be included
  23 # in all copies or substantial portions of the Software.
  24 #
  25 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  26 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
  28 # THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 # DEALINGS IN THE SOFTWARE.
  32 #
  33
  34 #######################################################################
  35 # This converts a file written in makefile syntax into one that can be included
  36 # by CMake.
  37
  38 file(READ ${input_file} depend_text)
  39
  40 if (${depend_text} MATCHES ".+")
  41
  42   # message("FOUND DEPENDS")
  43
  44   # Remember, four backslashes is escaped to one backslash in the string.
  45   string(REGEX REPLACE "\\\\ " " " depend_text ${depend_text})
  46
  47   # This works for the nvcc -M generated dependency files.
  48   string(REGEX REPLACE "^.* : " "" depend_text ${depend_text})
  49   string(REGEX REPLACE "[ \\\\]*\n" ";" depend_text ${depend_text})
  50
  51   set(dependency_list "")
  52
  53   foreach(file ${depend_text})
  54
  55     string(REGEX REPLACE "^ +" "" file ${file})
  56
  57     # OK, now if we had a UNC path, nvcc has a tendency to only output the first '/'
  58     # instead of '//'.  Here we will test to see if the file exists, if it doesn't then
  59     # try to prepend another '/' to the path and test again.  If it still fails remove the
  60     # path.
  61
  62     if(NOT EXISTS "${file}")
  63       if (EXISTS "/${file}")
  64         set(file "/${file}")
  65       else()
  66         message(WARNING " Removing non-existent dependency file: ${file}")
  67         set(file "")
  68       endif()
  69     endif()
  70
  71     if(NOT IS_DIRECTORY "${file}")
  72       # If softlinks start to matter, we should change this to REALPATH.  For now we need
  73       # to flatten paths, because nvcc can generate stuff like /bin/../include instead of
  74       # just /include.
  75       get_filename_component(file_absolute "${file}" ABSOLUTE)
  76       list(APPEND dependency_list "${file_absolute}")
  77     endif()
  78
  79   endforeach()
  80
  81 else()
  82   # message("FOUND NO DEPENDS")
  83 endif()
  84
  85 # Remove the duplicate entries and sort them.
  86 list(REMOVE_DUPLICATES dependency_list)
  87 list(SORT dependency_list)
  88
  89 foreach(file ${dependency_list})
  90   set(cuda_nvcc_depend "${cuda_nvcc_depend} \"${file}\"\n")
  91 endforeach()
  92
  93 file(WRITE ${output_file} "# Generated by: make2cmake.cmake\nSET(CUDA_NVCC_DEPEND\n ${cuda_nvcc_depend})\n\n")