CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.7)
   2 if(POLICY CMP0046)
   3   cmake_policy(SET CMP0046 NEW)
   4 endif()
   5 if(POLICY CMP0054)
   6   cmake_policy(SET CMP0054 NEW)
   7 endif()
   8
   9 # ---[ Caffe project
  10 project(Caffe C CXX)
  11
  12 # ---[ Caffe version
  13 set(CAFFE_TARGET_VERSION "1.0.0-rc5" CACHE STRING "Caffe logical version")
  14 set(CAFFE_TARGET_SOVERSION "1.0.0-rc5" CACHE STRING "Caffe soname version")
  15 add_definitions(-DCAFFE_VERSION=${CAFFE_TARGET_VERSION})
  16
  17 # ---[ Using cmake scripts and modules
  18 list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake/Modules)
  19
  20 include(ExternalProject)
  21
  22 include(cmake/Utils.cmake)
  23 include(cmake/Targets.cmake)
  24 include(cmake/Misc.cmake)
  25 include(cmake/Summary.cmake)
  26 include(cmake/ConfigGen.cmake)
  27
  28 # ---[ Options
  29 caffe_option(CPU_ONLY  "Build Caffe without CUDA support" OFF) # TODO: rename to USE_CUDA
  30 caffe_option(USE_CUDNN "Build Caffe with cuDNN library support" ON IF NOT CPU_ONLY)
  31 caffe_option(USE_NCCL "Build Caffe with NCCL library support" OFF)
  32 caffe_option(BUILD_SHARED_LIBS "Build shared libraries" ON)
  33 caffe_option(BUILD_python "Build Python wrapper" ON)
  34 set(python_version "2" CACHE STRING "Specify which Python version to use")
  35 caffe_option(BUILD_matlab "Build Matlab wrapper" OFF IF UNIX OR APPLE)
  36 caffe_option(BUILD_docs   "Build documentation" ON IF UNIX OR APPLE)
  37 caffe_option(BUILD_python_layer "Build the Caffe Python layer" ON)
  38 caffe_option(USE_OPENCV "Build with OpenCV support" ON)
  39 caffe_option(USE_LEVELDB "Build with levelDB" ON)
  40 caffe_option(USE_LMDB "Build with lmdb" ON)
  41 caffe_option(ALLOW_LMDB_NOLOCK "Allow MDB_NOLOCK when reading LMDB files (only if necessary)" OFF)
  42 caffe_option(USE_OPENMP "Link with OpenMP (when your BLAS wants OpenMP and you get linker errors)" OFF)
  43
  44 # ---[ Dependencies
  45 include(cmake/Dependencies.cmake)
  46
  47 # ---[ Flags
  48 if(UNIX OR APPLE)
  49   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC -Wall")
  50 endif()
  51
  52 caffe_set_caffe_link()
  53
  54 if(USE_libstdcpp)
  55   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libstdc++")
  56   message("-- Warning: forcing libstdc++ (controlled by USE_libstdcpp option in cmake)")
  57 endif()
  58
  59 # ---[ Warnings
  60 caffe_warnings_disable(CMAKE_CXX_FLAGS -Wno-sign-compare -Wno-uninitialized)
  61
  62 # ---[ Config generation
  63 configure_file(cmake/Templates/caffe_config.h.in "${PROJECT_BINARY_DIR}/caffe_config.h")
  64
  65 # ---[ Includes
  66 set(Caffe_INCLUDE_DIR ${PROJECT_SOURCE_DIR}/include)
  67 set(Caffe_SRC_DIR ${PROJECT_SOURCE_DIR}/src)
  68 include_directories(${PROJECT_BINARY_DIR})
  69
  70 # ---[ Includes & defines for CUDA
  71
  72 # cuda_compile() does not have per-call dependencies or include pathes
  73 # (cuda_compile() has per-call flags, but we set them here too for clarity)
  74 #
  75 # list(REMOVE_ITEM ...) invocations remove PRIVATE and PUBLIC keywords from collected definitions and include pathes
  76 if(HAVE_CUDA)
  77   # pass include pathes to cuda_include_directories()
  78   set(Caffe_ALL_INCLUDE_DIRS ${Caffe_INCLUDE_DIRS})
  79   list(REMOVE_ITEM Caffe_ALL_INCLUDE_DIRS PRIVATE PUBLIC)
  80   cuda_include_directories(${Caffe_INCLUDE_DIR} ${Caffe_SRC_DIR} ${Caffe_ALL_INCLUDE_DIRS})
  81
  82   # add definitions to nvcc flags directly
  83   set(Caffe_ALL_DEFINITIONS ${Caffe_DEFINITIONS})
  84   list(REMOVE_ITEM Caffe_ALL_DEFINITIONS PRIVATE PUBLIC)
  85   list(APPEND CUDA_NVCC_FLAGS ${Caffe_ALL_DEFINITIONS})
  86 endif()
  87
  88 # ---[ Subdirectories
  89 add_subdirectory(src/gtest)
  90 add_subdirectory(src/caffe)
  91 add_subdirectory(tools)
  92 add_subdirectory(examples)
  93 add_subdirectory(python)
  94 add_subdirectory(matlab)
  95 add_subdirectory(docs)
  96
  97 # ---[ Linter target
  98 add_custom_target(lint COMMAND ${CMAKE_COMMAND} -P ${PROJECT_SOURCE_DIR}/cmake/lint.cmake)
  99
 100 # ---[ pytest target
 101 if(BUILD_python)
 102   add_custom_target(pytest COMMAND python${python_version} -m unittest discover -s caffe/test WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/python )
 103   add_dependencies(pytest pycaffe)
 104 endif()
 105
 106 # ---[ Configuration summary
 107 caffe_print_configuration_summary()
 108
 109 # ---[ Export configs generation
 110 caffe_generate_export_configs()