configure.ac

   1 AC_INIT([btrfs-progs],
   2         m4_esyscmd([./version.sh --configure]),
   3         [linux-btrfs@vger.kernel.org],,
   4         [http://btrfs.wiki.kernel.org])
   5
   6 if test "x$PACKAGE_URL" = "x"; then
   7         AC_DEFINE([PACKAGE_URL], ["http://btrfs.wiki.kernel.org"], [URL])
   8 fi
   9
  10 dnl library version
  11 LIBBTRFS_MAJOR=0
  12 LIBBTRFS_MINOR=1
  13 LIBBTRFS_PATCHLEVEL=1
  14
  15 CFLAGS=${CFLAGS:-"-g -O1 -Wall -D_FORTIFY_SOURCE=2"}
  16 AC_SUBST([CFLAGS])
  17
  18 AC_PREREQ([2.60])
  19
  20 AC_CONFIG_AUX_DIR([config])
  21 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  22 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  23 AC_USE_SYSTEM_EXTENSIONS
  24
  25 AC_CONFIG_SRCDIR([btrfs.c])
  26 AC_PREFIX_DEFAULT([/usr/local])
  27
  28 AC_PROG_CC
  29 AC_CANONICAL_HOST
  30 AC_C_CONST
  31 AC_C_VOLATILE
  32 AC_C_BIGENDIAN
  33
  34 AC_SYS_LARGEFILE
  35
  36 AC_PROG_INSTALL
  37 AC_PROG_LN_S
  38 AC_CHECK_TOOL([AR], [ar])
  39 AC_PATH_PROG([RM], [rm], [rm])
  40 AC_PATH_PROG([RMDIR], [rmdir], [rmdir])
  41
  42 AC_CHECK_FUNCS([openat], [],
  43         [AC_MSG_ERROR([cannot find openat() function])])
  44
  45 m4_ifndef([PKG_PROG_PKG_CONFIG],
  46   [m4_fatal([Could not locate the pkg-config autoconf
  47     macros. These are usually located in /usr/share/aclocal/pkg.m4.
  48     If your macros are in a different location, try setting the
  49     environment variable AL_OPTS="-I/other/macro/dir" before running
  50     ./autogen.sh or autoreconf again.])])
  51 PKG_PROG_PKG_CONFIG
  52
  53
  54 dnl
  55 dnl Calls pkg-config --static
  56 dnl
  57 AC_DEFUN([PKG_STATIC], [
  58   if AC_RUN_LOG([pkg-config --exists --print-errors "$2"]); then
  59     $1=`pkg-config --libs --static "$2"`
  60     AC_SUBST([$1])
  61   else
  62     AC_MSG_ERROR([pkg-config description of $2, needed for static build, is not available])
  63   fi
  64 ])
  65
  66
  67 AC_ARG_ENABLE([backtrace],
  68   AS_HELP_STRING([--disable-backtrace], [disable btrfs backtrace]),
  69   [], [enable_backtrace=yes]
  70 )
  71
  72 AS_IF([test "x$enable_backtrace" = xno], [
  73   AC_DEFINE([BTRFS_DISABLE_BACKTRACE], [1], [disable backtrace stuff in kerncompat.h ])
  74 ])
  75
  76 if test "x$enable_backtrace" = xyes; then
  77         AC_CHECK_HEADERS([execinfo.h])
  78         AC_CHECK_FUNCS([backtrace backtrace_symbols_fd], [],
  79               AC_MSG_ERROR([standard library does not have backtrace support]))
  80 fi
  81
  82
  83 AC_ARG_ENABLE([documentation],
  84               AS_HELP_STRING([--disable-documentation], [do not build domumentation]),
  85   [], [enable_documentation=yes]
  86 )
  87 AS_IF([test "x$enable_documentation" = xyes], [DISABLE_DOCUMENTATION=0], [DISABLE_DOCUMENTATION=1])
  88 AC_SUBST([DISABLE_DOCUMENTATION])
  89
  90 dnl detect tools to build documentation
  91 if test "x$enable_documentation" = xyes; then
  92         AC_PATH_PROG([ASCIIDOC], [asciidoc], [asciidoc])
  93         AC_PATH_PROG([XMLTO], [xmlto], [xmlto])
  94         AC_PATH_PROG([GZIP], [gzip], [gzip])
  95         AC_PATH_PROG([MV], [mv], [mv])
  96         AC_PROG_SED
  97 fi
  98
  99 AC_ARG_ENABLE([convert],
 100               AS_HELP_STRING([--disable-convert], [do not build btrfs-convert]),
 101   [], [enable_convert=yes]
 102 )
 103
 104 AS_IF([test "x$enable_convert" = xyes], [DISABLE_BTRFSCONVERT=0], [DISABLE_BTRFSCONVERT=1])
 105 AC_SUBST([DISABLE_BTRFSCONVERT])
 106
 107 if test "x$enable_convert" = xyes; then
 108         PKG_CHECK_MODULES(EXT2FS, [ext2fs >= 1.42],,
 109                 [PKG_CHECK_MODULES(EXT2FS, [ext2fs],
 110                         [AC_DEFINE([HAVE_OLD_E2FSPROGS], [1],
 111                                   [E2fsprogs does not support BIGALLOC])]
 112                         )])
 113         PKG_CHECK_MODULES(COM_ERR, [com_err])
 114 fi
 115
 116
 117 dnl Define <NAME>_LIBS= and <NAME>_CFLAGS= by pkg-config
 118 dnl
 119 dnl The default PKG_CHECK_MODULES() action-if-not-found is end the
 120 dnl execution with error. The static libs are optional.
 121
 122 PKG_CHECK_MODULES(BLKID, [blkid])
 123 PKG_STATIC(BLKID_LIBS_STATIC, [blkid])
 124
 125 PKG_CHECK_MODULES(UUID, [uuid])
 126 PKG_STATIC(UUID_LIBS_STATIC, [uuid])
 127
 128 PKG_CHECK_MODULES(ZLIB, [zlib])
 129 PKG_STATIC(ZLIB_LIBS_STATIC, [zlib])
 130
 131 UDEVDIR="$(pkg-config udev --variable=udevdir)"
 132 AC_SUBST(UDEVDIR)
 133
 134 dnl lzo library does not provide pkg-config, let use classic way
 135 AC_CHECK_LIB([lzo2], [lzo_version], [
 136         LZO2_LIBS="-llzo2"
 137         LZO2_CFLAGS=""
 138         LZO2_LIBS_STATIC="-llzo2"],[
 139         AC_MSG_ERROR([cannot find lzo2 library])
 140 ])
 141 AC_SUBST([LZO2_LIBS])
 142 AC_SUBST([LZO2_LIBS_STATIC])
 143 AC_SUBST([LZO2_CFLAGS])
 144
 145
 146 dnl library stuff
 147 AC_SUBST([LIBBTRFS_MAJOR])
 148 AC_SUBST([LIBBTRFS_MINOR])
 149 AC_SUBST([LIBBTRFS_PATCHLEVEL])
 150
 151 AC_CONFIG_HEADERS([config.h])
 152
 153 AC_CONFIG_FILES([
 154 Makefile
 155 Documentation/Makefile
 156 version.h
 157 ])
 158
 159 AC_OUTPUT
 160
 161 AC_MSG_RESULT([
 162         ${PACKAGE_NAME} ${PACKAGE_VERSION}
 163
 164         prefix:            ${prefix}
 165         exec prefix:       ${exec_prefix}
 166
 167         bindir:            ${bindir}
 168         libdir:            ${libdir}
 169         includedir:        ${includedir}
 170
 171         compiler:          ${CC}
 172         cflags:            ${CFLAGS}
 173         ldflags:           ${LDFLAGS}
 174
 175         documentation:     ${enable_documentation}
 176         backtrace support: ${enable_backtrace}
 177         btrfs-convert:     ${enable_convert}
 178
 179         Type 'make' to compile.
 180 ])
 181