configure.ac

   1 AC_INIT([btrfs-progs],
   2         m4_chomp(m4_include([VERSION])),
   3         [linux-btrfs@vger.kernel.org],,
   4         [http://btrfs.wiki.kernel.org])
   5
   6 if test "x$PACKAGE_URL" = "x"; then
   7         AC_DEFINE([PACKAGE_URL], ["http://btrfs.wiki.kernel.org"], [URL])
   8 fi
   9
  10 dnl library version
  11 LIBBTRFS_MAJOR=0
  12 LIBBTRFS_MINOR=1
  13 LIBBTRFS_PATCHLEVEL=2
  14
  15 CFLAGS=${CFLAGS:-"-g -O1 -Wall -D_FORTIFY_SOURCE=2"}
  16 AC_SUBST([CFLAGS])
  17
  18 AC_PREREQ([2.60])
  19
  20 AC_CONFIG_AUX_DIR([config])
  21 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  22 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  23 AC_USE_SYSTEM_EXTENSIONS
  24
  25 AC_CONFIG_SRCDIR([btrfs.c])
  26 AC_PREFIX_DEFAULT([/usr/local])
  27
  28 AC_PROG_CC
  29 AC_CANONICAL_HOST
  30 AC_C_CONST
  31 AC_C_VOLATILE
  32 AC_C_BIGENDIAN
  33
  34 AC_SYS_LARGEFILE
  35
  36 AC_PROG_INSTALL
  37 AC_PROG_LN_S
  38 AC_CHECK_TOOL([AR], [ar])
  39 AC_PATH_PROG([RM], [rm], [rm])
  40 AC_PATH_PROG([RMDIR], [rmdir], [rmdir])
  41
  42
  43 AC_CHECK_FUNCS([openat], [],
  44         [AC_MSG_ERROR([cannot find openat() function])])
  45
  46 m4_ifndef([PKG_PROG_PKG_CONFIG],
  47   [m4_fatal([Could not locate the pkg-config autoconf
  48     macros. These are usually located in /usr/share/aclocal/pkg.m4.
  49     If your macros are in a different location, try setting the
  50     environment variable AL_OPTS="-I/other/macro/dir" before running
  51     ./autogen.sh or autoreconf again.])])
  52 PKG_PROG_PKG_CONFIG
  53
  54
  55 dnl
  56 dnl Calls pkg-config --static
  57 dnl
  58 AC_DEFUN([PKG_STATIC], [
  59   if AC_RUN_LOG([${PKG_CONFIG} --exists --print-errors "$2"]); then
  60     $1=`${PKG_CONFIG} --libs --static "$2"`
  61     AC_SUBST([$1])
  62   else
  63     AC_MSG_ERROR([pkg-config description of $2, needed for static build, is not available])
  64   fi
  65 ])
  66
  67
  68 AC_ARG_ENABLE([backtrace],
  69   AS_HELP_STRING([--disable-backtrace], [disable btrfs backtrace]),
  70   [], [enable_backtrace=yes]
  71 )
  72
  73 AS_IF([test "x$enable_backtrace" = xno], [
  74   AC_DEFINE([BTRFS_DISABLE_BACKTRACE], [1], [disable backtrace stuff in kerncompat.h ])
  75 ])
  76
  77 if test "x$enable_backtrace" = xyes; then
  78         AC_CHECK_HEADERS([execinfo.h])
  79         AC_CHECK_FUNCS([backtrace backtrace_symbols_fd], [],
  80               AC_MSG_ERROR([standard library does not have backtrace support]))
  81 fi
  82
  83
  84 AC_ARG_ENABLE([documentation],
  85               AS_HELP_STRING([--disable-documentation], [do not build domumentation]),
  86   [], [enable_documentation=yes]
  87 )
  88 AS_IF([test "x$enable_documentation" = xyes], [DISABLE_DOCUMENTATION=0], [DISABLE_DOCUMENTATION=1])
  89 AC_SUBST([DISABLE_DOCUMENTATION])
  90
  91 dnl detect tools to build documentation
  92 ASCIIDOC_TOOL="none"
  93 if test "x$enable_documentation" = xyes; then
  94         AC_PATH_PROG([XMLTO], [xmlto], [xmlto])
  95         AC_PATH_PROG([GZIP], [gzip], [gzip])
  96         AC_PATH_PROG([MV], [mv], [mv])
  97         AC_PROG_SED
  98         AC_PATH_PROG([ASCIIDOC], [asciidoc])
  99         AC_PATH_PROG([ASCIIDOCTOR], [asciidoctor])
 100
 101         dnl asciidoc is preferred
 102         if test -n "$ASCIIDOC"; then
 103                 ASCIIDOC_TOOL="asciidoc"
 104         else
 105                 if test -n "$ASCIIDOCTOR"; then
 106                         ASCIIDOC_TOOL="asciidoctor"
 107                 else
 108                         AC_MSG_ERROR([cannot find asciidoc or asciidoctor, cannot build documentation])
 109                 fi
 110         fi
 111 fi
 112 AC_SUBST([ASCIIDOC_TOOL])
 113
 114 AC_ARG_ENABLE([convert],
 115               AS_HELP_STRING([--disable-convert], [do not build btrfs-convert]),
 116   [], [enable_convert=yes]
 117 )
 118
 119 AS_IF([test "x$enable_convert" = xyes], [DISABLE_BTRFSCONVERT=0], [DISABLE_BTRFSCONVERT=1])
 120 AC_SUBST([DISABLE_BTRFSCONVERT])
 121
 122 AC_ARG_WITH([convert],
 123             AS_HELP_STRING([[[]--with-convert[[=auto]]]], [built-in filesystems for convert (default: auto)
 124 supported (comma separated list): ext2,reiserfs]),
 125   [], [with_convert=auto]
 126 )
 127
 128 if test "$with_convert" = "yes"; then
 129         with_convert=auto
 130 fi
 131
 132 if test "$with_convert" = "no"; then
 133         with_convert=
 134 fi
 135
 136 convertfs=
 137 BTRFSCONVERT_EXT2=0
 138 BTRFSCONVERT_REISERFS=0
 139 if test "x$enable_convert" = xyes; then
 140         if test "x$with_convert" = "xauto" || echo "$with_convert" | grep -q "ext2"; then
 141                 PKG_CHECK_MODULES(EXT2FS, [ext2fs >= 1.42],,
 142                         [PKG_CHECK_MODULES(EXT2FS, [ext2fs],
 143                                 [AC_DEFINE([HAVE_OLD_E2FSPROGS], [1],
 144                                           [E2fsprogs does not support BIGALLOC])]
 145                                 )])
 146                 PKG_CHECK_MODULES(COM_ERR, [com_err])
 147                 convertfs="${convertfs:+$convertfs,}ext2"
 148                 BTRFSCONVERT_EXT2=1
 149         fi
 150         if test "x$with_convert" = "xauto"; then
 151                 PKG_CHECK_MODULES(REISERFS, [reiserfscore >= 3.6.27],
 152                                   [BTRFSCONVERT_REISERFS=1],
 153                                   [BTRFSCONVERT_REISERFS=0])
 154         elif echo "$with_convert" | grep -q "reiserfs"; then
 155                 PKG_CHECK_MODULES(REISERFS, [reiserfscore >= 3.6.27],
 156                                   [BTRFSCONVERT_REISERFS=1],[])
 157         fi
 158         if test "$BTRFSCONVERT_REISERFS" = 1; then
 159                 convertfs="${convertfs:+$convertfs,}reiserfs"
 160         fi
 161 fi
 162 AC_SUBST([BTRFSCONVERT_EXT2])
 163 AC_SUBST([BTRFSCONVERT_REISERFS])
 164
 165 # catch typos
 166 tmp=$(echo "$with_convert" | sed -e 's/auto//' | sed -e 's/ext2//' | sed -e 's/reiserfs//' | sed -e 's/,\+//')
 167 if ! test "x$tmp" = "x"; then
 168         AC_MSG_ERROR([unknown tokens for --with-convert: $tmp])
 169 fi
 170
 171 if test "$DISABLE_BTRFSCONVERT" = 0 && test "x$convertfs" = "x"; then
 172         AC_MSG_ERROR([no filesystems for convert, use --disable-convert instead])
 173 fi
 174
 175 HAVE_OWN_FIEMAP_EXTENT_SHARED_DEFINE=0
 176 AX_CHECK_DEFINE([linux/fiemap.h], [FIEMAP_EXTENT_SHARED], [],
 177                 [HAVE_OWN_FIEMAP_EXTENT_SHARED_DEFINE=1
 178                  AC_MSG_WARN([no definition of FIEMAP_EXTENT_SHARED found, probably old kernel, will use own defintion, 'btrfs fi du' might report wrong numbers])])
 179
 180 if test "x$HAVE_OWN_FIEMAP_EXTENT_SHARED_DEFINE" == "x1"; then
 181 AC_DEFINE([HAVE_OWN_FIEMAP_EXTENT_SHARED_DEFINE], [1], [We defined FIEMAP_EXTENT_SHARED])
 182 else
 183 AC_DEFINE([HAVE_OWN_FIEMAP_EXTENT_SHARED_DEFINE], [0], [We did not define FIEMAP_EXTENT_SHARED])
 184 fi
 185
 186 dnl Define <NAME>_LIBS= and <NAME>_CFLAGS= by pkg-config
 187 dnl
 188 dnl The default PKG_CHECK_MODULES() action-if-not-found is end the
 189 dnl execution with error. The static libs are optional.
 190
 191 PKG_CHECK_MODULES(BLKID, [blkid])
 192 PKG_STATIC(BLKID_LIBS_STATIC, [blkid])
 193
 194 PKG_CHECK_MODULES(UUID, [uuid])
 195 PKG_STATIC(UUID_LIBS_STATIC, [uuid])
 196
 197 PKG_CHECK_MODULES(ZLIB, [zlib])
 198 PKG_STATIC(ZLIB_LIBS_STATIC, [zlib])
 199
 200 AC_ARG_ENABLE([zstd],
 201         AS_HELP_STRING([--disable-zstd], [build without zstd support]),
 202         [], [enable_zstd=yes]
 203 )
 204
 205 if test "x$enable_zstd" = xyes; then
 206         PKG_CHECK_MODULES(ZSTD, [libzstd >= 1.0.0])
 207         PKG_STATIC(ZSTD_LIBS_STATIC, [libzstd])
 208 fi
 209
 210 AS_IF([test "x$enable_zstd" = xyes], [BTRFSRESTORE_ZSTD=1], [BTRFSRESTORE_ZSTD=0])
 211 AC_SUBST(BTRFSRESTORE_ZSTD)
 212
 213 AC_ARG_ENABLE([python],
 214         AS_HELP_STRING([--disable-python], [do not build libbtrfsutil Python bindings]),
 215         [], [enable_python=yes]
 216 )
 217
 218 if test "x$enable_python" = xyes; then
 219         AM_PATH_PYTHON([3.4])
 220 fi
 221
 222 AS_IF([test "x$enable_python" = xyes], [PYTHON_BINDINGS=1], [PYTHON_BINDINGS=0])
 223 AC_SUBST(PYTHON_BINDINGS)
 224 AC_SUBST(PYTHON)
 225
 226 # udev v190 introduced the btrfs builtin and a udev rule to use it.
 227 # Our udev rule gives us the friendly dm names but isn't required (or valid)
 228 # on earlier releases.
 229 UDEVDIR=
 230 if ${PKG_CONFIG} udev --atleast-version 190; then
 231         UDEVDIR="$(${PKG_CONFIG} udev --variable=udevdir)"
 232 fi
 233 AC_SUBST(UDEVDIR)
 234
 235 dnl lzo library does not provide pkg-config, let use classic way
 236 AC_CHECK_LIB([lzo2], [lzo_version], [
 237         LZO2_LIBS="-llzo2"
 238         LZO2_CFLAGS=""
 239         LZO2_LIBS_STATIC="-llzo2"],[
 240         AC_MSG_ERROR([cannot find lzo2 library])
 241 ])
 242 AC_SUBST([LZO2_LIBS])
 243 AC_SUBST([LZO2_LIBS_STATIC])
 244 AC_SUBST([LZO2_CFLAGS])
 245
 246
 247 dnl library stuff
 248 AC_SUBST([LIBBTRFS_MAJOR])
 249 AC_SUBST([LIBBTRFS_MINOR])
 250 AC_SUBST([LIBBTRFS_PATCHLEVEL])
 251
 252 AC_CONFIG_HEADERS([config.h])
 253
 254 AC_CONFIG_FILES([
 255 Makefile.inc
 256 Documentation/Makefile
 257 version.h
 258 ])
 259
 260 AC_OUTPUT
 261
 262 AC_MSG_RESULT([
 263         ${PACKAGE_NAME} ${PACKAGE_VERSION}
 264
 265         prefix:             ${prefix}
 266         exec prefix:        ${exec_prefix}
 267
 268         bindir:             ${bindir}
 269         libdir:             ${libdir}
 270         includedir:         ${includedir}
 271
 272         compiler:           ${CC}
 273         cflags:             ${CFLAGS}
 274         ldflags:            ${LDFLAGS}
 275
 276         documentation:      ${enable_documentation}
 277         doc generator:      ${ASCIIDOC_TOOL}
 278         backtrace support:  ${enable_backtrace}
 279         btrfs-convert:      ${enable_convert} ${convertfs:+($convertfs)}
 280         btrfs-restore zstd: ${enable_zstd}
 281         Python bindings:    ${enable_python}
 282         Python interpreter: ${PYTHON}
 283
 284         Type 'make' to compile.
 285 ])