m4/missing.m4

   1 # Fake the existence of programs that GNU maintainers use.  -*- Autoconf -*-
   2
   3 # Copyright (C) 1997-2013 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # AM_MISSING_PROG(NAME, PROGRAM)
  10 # ------------------------------
  11 AC_DEFUN([AM_MISSING_PROG],
  12 [AC_REQUIRE([AM_MISSING_HAS_RUN])
  13 $1=${$1-"${am_missing_run}$2"}
  14 AC_SUBST($1)])
  15
  16 # AM_MISSING_HAS_RUN
  17 # ------------------
  18 # Define MISSING if not defined so far and test if it is modern enough.
  19 # If it is, set am_missing_run to use it, otherwise, to nothing.
  20 AC_DEFUN([AM_MISSING_HAS_RUN],
  21 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
  22 AC_REQUIRE_AUX_FILE([missing])dnl
  23 if test x"${MISSING+set}" != xset; then
  24   case $am_aux_dir in
  25   *\ * | *\     *)
  26     MISSING="\${SHELL} \"$am_aux_dir/missing\"" ;;
  27   *)
  28     MISSING="\${SHELL} $am_aux_dir/missing" ;;
  29   esac
  30 fi
  31 # Use eval to expand $SHELL
  32 if eval "$MISSING --is-lightweight"; then
  33   am_missing_run="$MISSING "
  34 else
  35   am_missing_run=
  36   AC_MSG_WARN(['missing' script is too old or missing])
  37 fi
  38 ])