configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.12.1a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([dist-xz filename-length-max=99 color-tests
  43                   parallel-tests silent-rules no-define no-dependencies])
  44
  45 ## Keep this on a line of its own, since it must be found and processed
  46 ## by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2012
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 # Our current rule is that:
  53 # * All releases, including the prereleases, in an X.Y series
  54 #   are compatible.  So 1.5.1c is compatible with 1.5.
  55 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  56 #   aren't the same.
  57 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  58 AC_SUBST([APIVERSION])
  59
  60 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  61 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  62 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  63 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  64 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  65
  66 # $AUTOMAKE and $ACLOCAL are always run after a "cd $top_srcdir",
  67 # hence '.' is really what we want for perllibdir, libdir, and acdir.
  68 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  69 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  70
  71 AC_PATH_PROG([PERL], [perl])
  72 if test -z "$PERL"; then
  73    AC_MSG_ERROR([perl not found])
  74 fi
  75 # Save details about the selected perl interpreter in config.log.
  76 AM_RUN_LOG([$PERL --version])
  77 $PERL -e 'require 5.006;' || {
  78    AC_MSG_ERROR(
  79 [perl 5.6 or better is required; perl 5.8.2 or better
  80 is recommended.  If you have several perl versions
  81 installed, select the one Automake should use using
  82   ./configure PERL=/path/to/perl])
  83 }
  84
  85 # We require ithreads support, and version 5.7.2 for CLONE.
  86 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  87 [if $PERL -e '
  88     require 5.007_002;
  89     use Config;
  90     if ($Config{useithreads})
  91       {
  92         require threads;
  93         import threads;
  94         require Thread::Queue;
  95         import Thread::Queue;
  96         exit 0;
  97       }
  98     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  99 then
 100   am_cv_prog_PERL_ithreads=yes
 101 else
 102   am_cv_prog_PERL_ithreads=no
 103 fi])
 104 if test $am_cv_prog_PERL_ithreads = yes; then
 105   PERL_THREADS=1;
 106 else
 107   PERL_THREADS=0;
 108 fi
 109 AC_SUBST([PERL_THREADS])
 110
 111 # The test suite will skip some tests if tex is absent.
 112 AC_CHECK_PROG([TEX], [tex], [tex])
 113 # Save details about the selected TeX program in config.log.
 114 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 115 # for input from the terminal.
 116 AM_RUN_LOG([$TEX --version </dev/null])
 117
 118 # The test suite will skip some tests if no lex or yacc program is
 119 # available.
 120 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 121 #  1. we don't want flex (resp. bison) to be preferred to system lex
 122 #     (resp. system yacc);
 123 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 124 #     by default;
 125 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 126 #     LEXLIB to be calculated and/or AC_SUBST'd;
 127 #  4. we prefer that the YACC and LEX variables are not reported in the
 128 #     configure help screen.
 129 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 130 AC_CHECK_PROGS([LEX], [lex flex], [false])
 131
 132 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 133 # deletion of any files created (such as those added to
 134 # autom4te.cache).  We used to perform only the last of the three
 135 # following tests, but some users were unable to figure out that their
 136 # installation was broken since --version appeared to work.
 137
 138 required_autoconf_version=2.62
 139 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 140 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 141 then
 142   am_cv_autoconf_installed=yes
 143 else
 144   am_cv_autoconf_installed=no
 145 fi])
 146 if test "$am_cv_autoconf_installed" = no; then
 147   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 148     Please make sure it is installed and in your PATH.])
 149 fi
 150
 151 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 152 [mkdir conftest
 153 echo 'AC''_INIT' > conftest/conftest.ac
 154 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 155 then
 156   am_cv_autoconf_works=yes
 157 else
 158   am_cv_autoconf_works=no
 159 fi
 160 rm -rf conftest])
 161 if test "$am_cv_autoconf_works" = no; then
 162   AC_MSG_ERROR([The installed version of autoconf does not work.
 163     Please check config.log for error messages before this one.])
 164 fi
 165
 166 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 167 [mkdir conftest
 168 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 169 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 170 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 171 then
 172   am_cv_autoconf_version=yes
 173 else
 174   am_cv_autoconf_version=no
 175 fi
 176 rm -rf conftest])
 177 if test "$am_cv_autoconf_version" = no; then
 178   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 179 fi
 180
 181 # Test for ln.  We need use it to install the versioned binaries.
 182 AC_MSG_CHECKING([whether ln works])
 183 AC_CACHE_VAL([am_cv_prog_ln], [
 184 rm -f conftest conftest.file
 185 : >conftest.file
 186 if ln conftest.file conftest 2>/dev/null; then
 187   am_cv_prog_ln=ln
 188 else
 189   am_cv_prog_ln='cp -p'
 190 fi
 191 rm -f conftest conftest.file])
 192 AC_SUBST([LN], [$am_cv_prog_ln])
 193 result=no
 194 test "x$am_cv_prog_ln" = xln && result=yes
 195 AC_MSG_RESULT([$result])
 196
 197 # The amount we should wait after modifying files depends on the platform.
 198 # On Windows '95, '98 and ME, files modifications have 2-seconds
 199 # granularity and can be up to 3 seconds in the future w.r.t. the
 200 # system clock.  When it is important to ensure one file is older
 201 # than another we wait at least 5 seconds between creations.
 202 case $build in
 203   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 204   *)               MODIFICATION_DELAY=2;;
 205 esac
 206 AC_SUBST([MODIFICATION_DELAY])
 207
 208 ## ------------------------------------------- ##
 209 ##  Test for things needed by the test suite.  ##
 210 ## ------------------------------------------- ##
 211
 212 AC_PROG_EGREP
 213 AC_PROG_FGREP
 214
 215 dnl FIXME: could we extract this in a simpler way through autoconf
 216 dnl FIXME: idioms or internals?
 217 AC_DEFUN(
 218   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
 219   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
 220
 221 dnl
 222 dnl Arguments to this macro:
 223 dnl
 224 dnl   $1 - shell to test
 225 dnl   $2 - description of the tested feature
 226 dnl   $3 - shell code used to check the feature; to indicate success,
 227 dnl        it can either exit with status 77, or have the last command
 228 dnl        returning with exit status of zero
 229 dnl   $4 - shell code to execute if the check on the shell is successful
 230 dnl        (defaults to nothing)
 231 dnl   $5 - shell code to execute if the check on the shell is not
 232 dnl        successful (defaults to nothing)
 233 dnl
 234 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
 235   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
 236   AC_MSG_CHECKING([whether $1 $2])
 237   if { $1 -c "$am_bourne_compatible
 238 AS_ESCAPE([$3])
 239 test \$? -eq 0 || exit 1
 240 # Use 77 to indicate success (rather than 0), in case some shell
 241 # acts like Solaris 10's /bin/sh, exiting successfully on some
 242 # syntax errors.
 243 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
 244   then
 245     AC_MSG_RESULT([yes])
 246     $4
 247   else
 248     AC_MSG_RESULT([no])
 249     $5
 250   fi])
 251
 252 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
 253 # -----------------------------------------
 254 #
 255 # Check if the given shell is good enough to run our test scripts.
 256 # Inspired to gnulib's 'tests/init.sh'.
 257 #
 258 # We require POSIX and XSI features (e.g., '$(...)' for command
 259 # substitutions, '$((...))' for shell arithmetic, and support for
 260 # '${var#...}' and '${var%...}' parameter expansions).
 261 #
 262 # We require that the shell can correctly trap EXIT when 'set -e' is in
 263 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
 264 #
 265 # We want to able to define shell aliases with the same name of shell
 266 # builtins.
 267 #
 268 # We also prefer shells that, when 'set -x' is in effect, do not also
 269 # redirect traces upon stderr redirections.  For example,
 270 #  $ set -x; echo x 2>file
 271 # would emit "+ echo x" into file with older zsh versions.  Similarly,
 272 #   $ set -x; P=1 true 2>file
 273 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
 274 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
 275 #
 276 # Finally, we look for weird bugs and portability problems mentioned in
 277 # the Autoconf manual, and reject shells that suffers from them. (TODO)
 278 #
 279 # Use '$am_score' to indicate the degree of acceptability of the shell.
 280 # A score of "10" means that the shell is good enough for our needs;
 281 # a score of "9" means that the shell has some minor bugs or limitation,
 282 # but is still (barely) acceptable for our uses.  Any other score means
 283 # that the shell is broken or unfit.
 284 #
 285 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
 286   [am_score=10
 287   while :; do
 288
 289     _AM_CHECK_SHELL_FEATURE([$1],
 290       [supports \$(cmd)],
 291       [test "$(echo x)" = x],
 292       [], [am_score=1; break])
 293
 294     _AM_CHECK_SHELL_FEATURE([$1],
 295       [supports \$((expr))],
 296       [test $((1 + 2 * 3)) = 7],
 297       [], [am_score=1; break])
 298
 299     _AM_CHECK_SHELL_FEATURE([$1],
 300       [supports \${var@%:@glob}],
 301       [v=a/b/c; test ${v@%:@*/} = b/c],
 302       [], [am_score=1; break])
 303
 304     _AM_CHECK_SHELL_FEATURE([$1],
 305       [supports \${var@%:@@%:@glob}],
 306       [v=a/b/c; test ${v@%:@@%:@*/} = c],
 307       [], [am_score=1; break])
 308
 309     _AM_CHECK_SHELL_FEATURE([$1],
 310       [supports \${var%glob}],
 311       [v=a.b.c; test ${v%.*} = a.b],
 312       [], [am_score=1; break])
 313
 314     _AM_CHECK_SHELL_FEATURE([$1],
 315       [supports \${var%%glob}],
 316       [v=a.b.c; test ${v%%.*} = a],
 317       [], [am_score=1; break])
 318
 319     _AM_CHECK_SHELL_FEATURE([$1],
 320       ["set -e" preserves exit traps],
 321       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
 322       [], [am_score=1; break])
 323
 324     _AM_CHECK_SHELL_FEATURE([$1],
 325       ["set -x" corrupts stderr],
 326       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
 327       [am_score=9], [])
 328
 329     echo 'alias false=echo' > conftest-alias.sh
 330     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
 331     _AM_CHECK_SHELL_FEATURE([$1],
 332       [supports alias named like shell builtins],
 333       [. ./conftest-alias.sh],
 334       [rm -f conftest-alias.sh],
 335       [rm -f conftest-alias.sh; am_score=1; break])
 336
 337     _AM_CHECK_SHELL_FEATURE([$1],
 338       [supports "test -e"],
 339       [test -e configure && test -e . && test ! -e nonesuch],
 340       [], [am_score=1; break])
 341
 342     break
 343   done])
 344
 345 # These messages only goes to the config.log file.
 346 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
 347
 348 AC_CACHE_VAL(
 349   [ac_cv_AM_TEST_RUNNER_SHELL],
 350   [if test "$AM_TEST_RUNNER_SHELL"; then
 351     # Let the user override it.
 352     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
 353   else
 354     ac_cv_AM_TEST_RUNNER_SHELL=no
 355     am_candidate_shells=${CONFIG_SHELL-}
 356     # For the benefit of Solaris.
 357     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
 358     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
 359       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
 360       if test -n "$am_candidate_sh"; then
 361         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
 362       fi
 363       AM_SUBST_NOTMAKE([am_candidate_sh])
 364       # Must nullify these in order not to interfere with the checks in
 365       # the next loop.
 366       AS_UNSET([am_candidate_sh])
 367       AS_UNSET([ac_cv_path_am_candidate_sh])
 368     done
 369     AS_UNSET([am_PATH]) # Not required anymore
 370     for am_sh in $am_candidate_shells; do
 371       am_score=0
 372       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
 373       if test $am_score -eq 9; then
 374         # The shell is barely acceptable for our needs.  We might
 375         # still find one that is even better, so continue looking.
 376         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
 377         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 378       elif test $am_score -eq 10; then
 379         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
 380         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 381         break
 382       fi
 383     done
 384   fi
 385   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
 386
 387 if test $AM_TEST_RUNNER_SHELL = no; then
 388   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
 389                                 enough to be used in our testsuite])])
 390 else
 391   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
 392 fi
 393
 394 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
 395            [a sturdy POSIX shell for our testsuite])
 396
 397 ## ---------------------- ##
 398 ##  Create output files.  ##
 399 ## ---------------------- ##
 400
 401
 402 ###########################################################################
 403
 404 # Look for C, C++ and fortran compilers to be used in the testsuite.
 405
 406 dnl We don't want to abort our configuration script if no C compiler is
 407 dnl available, as such a compiler is only required to run part of the
 408 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 409 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 410 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 411
 412 dnl We want the body of this macro to expand as a single shell statement,
 413 dnl thus we wrap it into { ... } brackets.
 414 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 415   AC_MSG_WARN([$1])
 416   am__failed=yes
 417   break
 418 } ])
 419
 420 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 421   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 422   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 423   am__failed=no
 424   while :; do
 425      $1
 426      break
 427   done
 428   AS_IF([test $am__failed = yes], [$2])
 429   # We have to clear these cache variables, so that future checks on
 430   # compilers for different languages won't be confused.
 431   unset ac_cv_objext ac_cv_exeext
 432   # We also need to meddle with the autoconf internals to ensure that
 433   # checks to find object and executable extensions will be run anew.
 434   # FIXME: In the long run, the better thing to do would be to fix
 435   # FIXME: autoconf instead ...
 436   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 437   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 438   m4_popdef([AC_MSG_FAILURE])
 439   m4_popdef([AC_MSG_ERROR])
 440 ])
 441
 442 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 443   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 444
 445 # Prefer generic compilers to GNU ones when possible.  This will ensure
 446 # more testsuite coverage "in the wild".
 447 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 448 # deliberate; for more discussion and rationale, see:
 449 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 450
 451 AC_MSG_NOTICE([will now look for generic compilers])
 452
 453 # C compiler.
 454 _AM_COMPILER_CAN_FAIL(dnl
 455   [AC_PROG_CC([cc gcc])],
 456   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 457
 458 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 459
 460 # The list of C++ compilers here has been copied, pasted and edited
 461 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 462 # Keep it in sync, or better again, find out a way to avoid this code
 463 # duplication.
 464 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 465   [aCC CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 466   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 467
 468 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 469
 470 # The lists of Fortran compilers here has been copied, pasted and edited
 471 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 472 # Keep it in sync, or better again, find out a way to avoid this code
 473 # duplication.
 474
 475 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 476   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 477   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 478   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 479
 480 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 481
 482 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 483   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 484   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 485
 486 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 487
 488 # Some tests will need the GNU compilers.  Searching for them here would
 489 # be overkill, since our testsuite already handles their search and setup
 490 # pretty well.  But in case the compilers already found are the GNU ones,
 491 # we want to use them in the testsuite where GNU compilers are required.
 492 # Also, in case the compilers detected above (at configure time) are not
 493 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 494 # FFLAGS detected for them with the GNU compilers too, since it's likely
 495 # they won't be compatible.  So we allow the user to define variants of
 496 # these variables for the GNU compilers separately.
 497
 498 AC_MSG_NOTICE([will now look for GNU compilers])
 499
 500 # GNU C compiler.
 501 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 502 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 503 if test $am_CC_is_GNU = yes; then
 504   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 505   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 506 else
 507   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 508 fi
 509 AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 510       [AC_MSG_WARN([botched installation for GNU C compiler])
 511        _AM_SKIP_COMP_TESTS([GNU C])])
 512
 513 # GNU C++ compiler.
 514 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 515 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 516 if test $am_CXX_is_GNU = yes; then
 517   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 518   GNU_CXX=$CXX
 519   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 520 else
 521   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 522 fi
 523 AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 524       [AC_MSG_WARN([botched installation for GNU C++ compiler])
 525        _AM_SKIP_COMP_TESTS([GNU C++])])
 526
 527 # GNU Fortran compiler.
 528 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 529 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 530 if test $am_FC_is_GNU = yes; then
 531   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 532   GNU_FC=$FC
 533   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 534 else
 535   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 536 fi
 537 AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 538       [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 539        _AM_SKIP_COMP_TESTS([GNU Fortran])])
 540
 541 # GNU Fortran 77 compiler.
 542 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 543 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 544 if test $am_F77_is_GNU = yes; then
 545   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 546   GNU_F77=$F77
 547   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 548 else
 549   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 550 fi
 551 AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 552       [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 553       _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 554
 555 # GNU Java compiler.
 556 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 557 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 558 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 559 AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 560       [AC_MSG_WARN([botched installation for GNU Java compiler])
 561       _AM_SKIP_COMP_TESTS([GNU Java])])
 562
 563 # If we have been able to find at least a working compiler above, we
 564 # know what the object and executable extensions for this platform are.
 565 OBJEXT=${ac_cv_objext-UNKNOWN}
 566 EXEEXT=${ac_cv_exeext-UNKNOWN}
 567 AC_SUBST([OBJEXT])
 568 AC_SUBST([EXEEXT])
 569
 570 ###########################################################################
 571
 572 AC_CONFIG_FILES([Makefile])
 573
 574 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 575 AC_CONFIG_LINKS([defs:defs])
 576
 577 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 578                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 579                 [APIVERSION=$APIVERSION])
 580 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 581                 [chmod +x t/wrap/automake-${APIVERSION}],
 582                 [APIVERSION=$APIVERSION])
 583
 584 AC_OUTPUT
 585
 586 # Inform the user if this version of automake is a beta release or
 587 # a development snapshot.
 588 # According to HACKING, the version of a development snapshot should
 589 # end with an "odd" letter (a, c, ...), the version of a test release
 590 # should end wit an "even" letter (b, d, ...).
 591
 592 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 593 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 594
 595 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 596   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 597   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 598   { print \"development snapshot\"; }"]`
 599
 600 test "$am_release_type" = stable || cat <<EOF
 601
 602 WARNING: You are about to use a $am_release_type of automake.
 603 WARNING: It might easily suffer from new bugs or regressions.
 604 WARNING: You are strongly advised not to use it in production code.
 605
 606 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 607 EOF
 608
 609 AS_EXIT([0])