configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2013 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.13.3a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([dist-xz filename-length-max=99 color-tests
  43                   no-define no-dependencies])
  44
  45 ## Keep this on a line of its own, since it must be found and processed
  46 ## by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2013
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 # Our current rule is that:
  53 # * All releases, including the prereleases, in an X.Y series
  54 #   are compatible.  So 1.5.1c is compatible with 1.5.
  55 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  56 #   aren't the same.
  57 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  58 AC_SUBST([APIVERSION])
  59
  60 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  61 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  62 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  63 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  64 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  65
  66 # Our build system is bootstrapped with the bleeding-edge versions of
  67 # aclocal and automake, hence the remake rules must use those versions
  68 # as well.  The extra quoting is to cater to cases when the build
  69 # directory contains whitespace or shell metacharacters.
  70 ACLOCAL="\"`pwd`/t/wrap/aclocal-$APIVERSION\""
  71 AUTOMAKE="\"`pwd`/t/wrap/automake-$APIVERSION\""
  72
  73 AC_PROG_LN_S
  74
  75 AC_PATH_PROG([PERL], [perl])
  76 if test -z "$PERL"; then
  77    AC_MSG_ERROR([perl not found])
  78 fi
  79 # Save details about the selected perl interpreter in config.log.
  80 AM_RUN_LOG([$PERL --version])
  81 $PERL -e 'require 5.006;' || {
  82    AC_MSG_ERROR(
  83 [perl 5.6 or better is required; perl 5.8.2 or better
  84 is recommended.  If you have several perl versions
  85 installed, select the one Automake should use using
  86   ./configure PERL=/path/to/perl])
  87 }
  88
  89 # We require ithreads support, and version 5.7.2 for CLONE.
  90 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  91 [if $PERL -e '
  92     require 5.007_002;
  93     use Config;
  94     if ($Config{useithreads})
  95       {
  96         require threads;
  97         import threads;
  98         require Thread::Queue;
  99         import Thread::Queue;
 100         exit 0;
 101       }
 102     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
 103 then
 104   am_cv_prog_PERL_ithreads=yes
 105 else
 106   am_cv_prog_PERL_ithreads=no
 107 fi])
 108 if test $am_cv_prog_PERL_ithreads = yes; then
 109   PERL_THREADS=1;
 110 else
 111   PERL_THREADS=0;
 112 fi
 113 AC_SUBST([PERL_THREADS])
 114
 115 # The test suite will skip some tests if tex is absent.
 116 AC_CHECK_PROG([TEX], [tex], [tex])
 117 # Save details about the selected TeX program in config.log.
 118 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 119 # for input from the terminal.
 120 AM_RUN_LOG([$TEX --version </dev/null])
 121
 122 # The test suite will skip some tests if no lex or yacc program is
 123 # available.
 124 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 125 #  1. we don't want flex (resp. bison) to be preferred to system lex
 126 #     (resp. system yacc);
 127 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 128 #     by default;
 129 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 130 #     LEXLIB to be calculated and/or AC_SUBST'd;
 131 #  4. we prefer that the YACC and LEX variables are not reported in the
 132 #     configure help screen.
 133 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 134 AC_CHECK_PROGS([LEX], [lex flex], [false])
 135
 136 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 137 # deletion of any files created (such as those added to
 138 # autom4te.cache).  We used to perform only the last of the three
 139 # following tests, but some users were unable to figure out that their
 140 # installation was broken since --version appeared to work.
 141
 142 AC_SUBST([required_autoconf_version], [2.65])
 143 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 144 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 145 then
 146   am_cv_autoconf_installed=yes
 147 else
 148   am_cv_autoconf_installed=no
 149 fi])
 150 if test "$am_cv_autoconf_installed" = no; then
 151   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 152     Please make sure it is installed and in your PATH.])
 153 fi
 154
 155 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 156 [mkdir conftest
 157 echo 'AC''_INIT' > conftest/conftest.ac
 158 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 159 then
 160   am_cv_autoconf_works=yes
 161 else
 162   am_cv_autoconf_works=no
 163 fi
 164 rm -rf conftest])
 165 if test "$am_cv_autoconf_works" = no; then
 166   AC_MSG_ERROR([The installed version of autoconf does not work.
 167     Please check config.log for error messages before this one.])
 168 fi
 169
 170 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 171 [mkdir conftest
 172 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 173 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 174 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 175 then
 176   am_cv_autoconf_version=yes
 177 else
 178   am_cv_autoconf_version=no
 179 fi
 180 rm -rf conftest])
 181 if test "$am_cv_autoconf_version" = no; then
 182   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 183 fi
 184
 185 # Test for ln.  We need use it to install the versioned binaries.
 186 AC_MSG_CHECKING([whether ln works])
 187 AC_CACHE_VAL([am_cv_prog_ln], [
 188 rm -f conftest conftest.file
 189 : >conftest.file
 190 if ln conftest.file conftest 2>/dev/null; then
 191   am_cv_prog_ln=ln
 192 else
 193   am_cv_prog_ln='cp -p'
 194 fi
 195 rm -f conftest conftest.file])
 196 AC_SUBST([LN], [$am_cv_prog_ln])
 197 result=no
 198 test "x$am_cv_prog_ln" = xln && result=yes
 199 AC_MSG_RESULT([$result])
 200
 201 # The amount we should wait after modifying files depends on the platform.
 202 # On Windows '95, '98 and ME, files modifications have 2-seconds
 203 # granularity and can be up to 3 seconds in the future w.r.t. the
 204 # system clock.  When it is important to ensure one file is older
 205 # than another we wait at least 5 seconds between creations.
 206 case $build in
 207   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 208   *)               MODIFICATION_DELAY=2;;
 209 esac
 210 AC_SUBST([MODIFICATION_DELAY])
 211
 212 ## ------------------------------------------- ##
 213 ##  Test for things needed by the test suite.  ##
 214 ## ------------------------------------------- ##
 215
 216 AC_PROG_EGREP
 217 AC_PROG_FGREP
 218
 219 dnl FIXME: could we extract this in a simpler way through autoconf
 220 dnl FIXME: idioms or internals?
 221 AC_DEFUN(
 222   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
 223   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
 224
 225 dnl
 226 dnl Arguments to this macro:
 227 dnl
 228 dnl   $1 - shell to test
 229 dnl   $2 - description of the tested feature
 230 dnl   $3 - shell code used to check the feature; to indicate success,
 231 dnl        it can either exit with status 77, or have the last command
 232 dnl        returning with exit status of zero
 233 dnl   $4 - shell code to execute if the check on the shell is successful
 234 dnl        (defaults to nothing)
 235 dnl   $5 - shell code to execute if the check on the shell is not
 236 dnl        successful (defaults to nothing)
 237 dnl
 238 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
 239   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
 240   AC_MSG_CHECKING([whether $1 $2])
 241   if { $1 -c "$am_bourne_compatible
 242 AS_ESCAPE([$3])
 243 test \$? -eq 0 || exit 1
 244 # Use 77 to indicate success (rather than 0), in case some shell
 245 # acts like Solaris 10's /bin/sh, exiting successfully on some
 246 # syntax errors.
 247 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
 248   then
 249     AC_MSG_RESULT([yes])
 250     $4
 251   else
 252     AC_MSG_RESULT([no])
 253     $5
 254   fi])
 255
 256 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
 257 # -----------------------------------------
 258 #
 259 # Check if the given shell is good enough to run our test scripts.
 260 # Inspired to gnulib's 'tests/init.sh'.
 261 #
 262 # We require POSIX and XSI features (e.g., '$(...)' for command
 263 # substitutions, '$((...))' for shell arithmetic, and support for
 264 # '${var#...}' and '${var%...}' parameter expansions).
 265 #
 266 # We require that the shell can correctly trap EXIT when 'set -e' is in
 267 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
 268 #
 269 # We want to able to define shell aliases with the same name of shell
 270 # builtins.
 271 #
 272 # We also prefer shells that, when 'set -x' is in effect, do not also
 273 # redirect traces upon stderr redirections.  For example,
 274 #  $ set -x; echo x 2>file
 275 # would emit "+ echo x" into file with older zsh versions.  Similarly,
 276 #   $ set -x; P=1 true 2>file
 277 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
 278 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
 279 #
 280 # Use '$am_score' to indicate the degree of acceptability of the shell.
 281 # A score of "10" means that the shell is good enough for our needs;
 282 # a score of "9" means that the shell has some minor bugs or limitation,
 283 # but is still (barely) acceptable for our uses.  Any other score means
 284 # that the shell is broken or unfit.
 285 #
 286 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
 287   [am_score=10
 288   while :; do
 289
 290     _AM_CHECK_SHELL_FEATURE([$1],
 291       [supports \$(cmd)],
 292       [test "$(echo x)" = x],
 293       [], [am_score=1; break])
 294
 295     _AM_CHECK_SHELL_FEATURE([$1],
 296       [supports \$((expr))],
 297       [test $((1 + 2 * 3)) = 7],
 298       [], [am_score=1; break])
 299
 300     _AM_CHECK_SHELL_FEATURE([$1],
 301       [supports \${@%:@var}],
 302       [zero='' one='x' twelve=' foobar baz!' \
 303         && test ${@%:@zero} -eq 0 \
 304         && test ${@%:@one} -eq 1 \
 305         && test ${@%:@twelve} -eq 12],
 306       [], [am_score=1; break])
 307
 308     _AM_CHECK_SHELL_FEATURE([$1],
 309       [supports \${var@%:@glob} and \${var%glob}],
 310       [v=a/b/c \
 311         && test ${v@%:@*/} = b/c \
 312         && test ${v@%:@@%:@*/} = c \
 313         && test ${v%/*} = a/b \
 314         && test ${v%%/*} = a],
 315       [], [am_score=1; break])
 316
 317     _AM_CHECK_SHELL_FEATURE([$1],
 318       [preserves exit traps with "set -e"],
 319       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
 320       [], [am_score=1; break])
 321
 322     _AM_CHECK_SHELL_FEATURE([$1],
 323       [can define exit traps in a shell function],
 324       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
 325       [], [am_score=1; break])
 326
 327     _AM_CHECK_SHELL_FEATURE([$1],
 328       [corrupts stderr with "set -x"],
 329       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
 330       [am_score=9], [])
 331
 332     echo 'return 34' > conftest-return.sh
 333     echo 'ok=no' >> conftest-return.sh
 334     _AM_CHECK_SHELL_FEATURE([$1],
 335       [can return early from "dot-sourced" files],
 336       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
 337       [rm -f conftest-return.sh],
 338       [rm -f conftest-return.sh; am_score=1; break])
 339
 340     echo 'alias false=echo' > conftest-alias.sh
 341     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
 342     _AM_CHECK_SHELL_FEATURE([$1],
 343       [supports alias named like shell builtins],
 344       [. ./conftest-alias.sh],
 345       [rm -f conftest-alias.sh],
 346       [rm -f conftest-alias.sh; am_score=1; break])
 347
 348     _AM_CHECK_SHELL_FEATURE([$1],
 349       [supports "test -e"],
 350       [test -e config.log && test -e . && test ! -e nonesuch],
 351       [], [am_score=1; break])
 352
 353     break
 354   done])
 355
 356 # These messages only goes to the config.log file.
 357 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
 358
 359 AC_CACHE_VAL(
 360   [ac_cv_AM_TEST_RUNNER_SHELL],
 361   [if test "$AM_TEST_RUNNER_SHELL"; then
 362     # Let the user override it.
 363     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
 364   else
 365     ac_cv_AM_TEST_RUNNER_SHELL=no
 366     am_candidate_shells=${CONFIG_SHELL-}
 367     # For the benefit of Solaris.
 368     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
 369     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
 370       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
 371       if test -n "$am_candidate_sh"; then
 372         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
 373       fi
 374       AM_SUBST_NOTMAKE([am_candidate_sh])
 375       # Must nullify these in order not to interfere with the checks in
 376       # the next loop.
 377       AS_UNSET([am_candidate_sh])
 378       AS_UNSET([ac_cv_path_am_candidate_sh])
 379     done
 380     AS_UNSET([am_PATH]) # Not required anymore
 381     for am_sh in $am_candidate_shells; do
 382       am_score=0
 383       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
 384       if test $am_score -eq 9; then
 385         # The shell is barely acceptable for our needs.  We might
 386         # still find one that is even better, so continue looking.
 387         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
 388         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 389       elif test $am_score -eq 10; then
 390         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
 391         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 392         break
 393       fi
 394     done
 395   fi
 396   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
 397
 398 if test $AM_TEST_RUNNER_SHELL = no; then
 399   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
 400                                 enough to be used in our testsuite])])
 401 else
 402   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
 403 fi
 404
 405 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
 406            [a sturdy POSIX shell for our testsuite])
 407
 408
 409 ###########################################################################
 410
 411 # Look for C, C++ and fortran compilers to be used in the testsuite.
 412
 413 dnl We don't want to abort our configuration script if no C compiler is
 414 dnl available, as such a compiler is only required to run part of the
 415 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 416 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 417 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 418
 419 dnl We want the body of this macro to expand as a single shell statement,
 420 dnl thus we wrap it into { ... } brackets.
 421 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 422   AC_MSG_WARN([$1])
 423   am__failed=yes
 424   break
 425 } ])
 426
 427 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 428   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 429   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 430   am__failed=no
 431   while :; do
 432      $1
 433      break
 434   done
 435   AS_IF([test $am__failed = yes], [$2])
 436   # We have to clear these cache variables, so that future checks on
 437   # compilers for different languages won't be confused.
 438   unset ac_cv_objext ac_cv_exeext
 439   # We also need to meddle with the autoconf internals to ensure that
 440   # checks to find object and executable extensions will be run anew.
 441   # FIXME: In the long run, the better thing to do would be to fix
 442   # FIXME: autoconf instead ...
 443   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 444   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 445   m4_popdef([AC_MSG_FAILURE])
 446   m4_popdef([AC_MSG_ERROR])
 447 ])
 448
 449 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 450   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 451
 452 # Prefer generic compilers to GNU ones when possible.  This will ensure
 453 # more testsuite coverage "in the wild".
 454 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 455 # deliberate; for more discussion and rationale, see:
 456 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 457
 458 AC_MSG_NOTICE([will now look for generic compilers])
 459
 460 # C compiler.
 461 _AM_COMPILER_CAN_FAIL(dnl
 462   [AC_PROG_CC([cc gcc])],
 463   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 464
 465 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 466
 467 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
 468 # we must avoid looking for 'CC', because that would be the same as
 469 # 'cc', and could cause $CXX to point to the C compiler, instead of
 470 # to a C++ compiler as expected (see automake bugs #11893 and #10766).
 471 # Similarly, we must avoid looking for 'RCC', as that can point to the
 472 # Qt4 "Resource Compiler": <http://doc.qt.digia.com/4.2/rcc.html>
 473 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
 474   # Case-insensitive file system, don't look for CC.
 475   am_CC= am_RCC=
 476 else
 477   am_CC=CC am_RCC=RCC
 478 fi
 479
 480 # The list of C++ compilers here has been copied, pasted and edited
 481 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 482 # Keep it in sync, or better again, find out a way to avoid this code
 483 # duplication.
 484 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 485   [aCC $am_CC FCC KCC $am_RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 486   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 487
 488 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 489
 490 # The lists of Fortran compilers here has been copied, pasted and edited
 491 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 492 # Keep it in sync, or better again, find out a way to avoid this code
 493 # duplication.
 494
 495 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 496   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 497   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 498   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 499
 500 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 501
 502 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 503   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 504   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 505
 506 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 507
 508 # Some tests will need the GNU compilers.  Searching for them here would
 509 # be overkill, since our testsuite already handles their search and setup
 510 # pretty well.  But in case the compilers already found are the GNU ones,
 511 # we want to use them in the testsuite where GNU compilers are required.
 512 # Also, in case the compilers detected above (at configure time) are not
 513 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 514 # FFLAGS detected for them with the GNU compilers too, since it's likely
 515 # they won't be compatible.  So we allow the user to define variants of
 516 # these variables for the GNU compilers separately.
 517
 518 AC_MSG_NOTICE([will now look for GNU compilers])
 519
 520 # GNU C compiler.
 521 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 522 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 523 if test $am_CC_is_GNU = yes; then
 524   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 525   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 526 else
 527   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 528 fi
 529 if test "$GNU_CC" != false; then
 530   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 531         [AC_MSG_WARN([botched installation for GNU C compiler])
 532          _AM_SKIP_COMP_TESTS([GNU C])])
 533 fi
 534
 535 # GNU C++ compiler.
 536 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 537 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 538 if test $am_CXX_is_GNU = yes; then
 539   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 540   GNU_CXX=$CXX
 541   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 542 else
 543   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 544 fi
 545 if test "$GNU_CXX" != false; then
 546   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 547         [AC_MSG_WARN([botched installation for GNU C++ compiler])
 548          _AM_SKIP_COMP_TESTS([GNU C++])])
 549 fi
 550
 551 # GNU Fortran compiler.
 552 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 553 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 554 if test $am_FC_is_GNU = yes; then
 555   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 556   GNU_FC=$FC
 557   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 558 else
 559   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 560 fi
 561 if test "$GNU_FC" != false; then
 562   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 563         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 564          _AM_SKIP_COMP_TESTS([GNU Fortran])])
 565 fi
 566
 567 # GNU Fortran 77 compiler.
 568 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 569 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 570 if test $am_F77_is_GNU = yes; then
 571   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 572   GNU_F77=$F77
 573   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 574 else
 575   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 576 fi
 577 if test "$GNU_F77" != false; then
 578   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 579         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 580         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 581 fi
 582
 583 # GNU Java compiler.
 584 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 585 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 586 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 587 if test "$GNU_GCJ" != false; then
 588   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 589         [AC_MSG_WARN([botched installation for GNU Java compiler])
 590         _AM_SKIP_COMP_TESTS([GNU Java])])
 591 fi
 592
 593 # If we have been able to find at least a working compiler above, we
 594 # know what the object and executable extensions for this platform are.
 595 OBJEXT=${ac_cv_objext-UNKNOWN}
 596 EXEEXT=${ac_cv_exeext-UNKNOWN}
 597 AC_SUBST([OBJEXT])
 598 AC_SUBST([EXEEXT])
 599
 600 ###########################################################################
 601
 602 ## ---------------------- ##
 603 ##  Create output files.  ##
 604 ## ---------------------- ##
 605
 606 AC_CONFIG_FILES([Makefile])
 607 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 608
 609 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 610                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 611                 [APIVERSION=$APIVERSION])
 612 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 613                 [chmod +x t/wrap/automake-${APIVERSION}],
 614                 [APIVERSION=$APIVERSION])
 615
 616 AC_OUTPUT
 617
 618 # Inform the user if this version of automake is a beta release or
 619 # a development snapshot.
 620 # According to HACKING, the version of a development snapshot should
 621 # end with an "odd" letter (a, c, ...), the version of a test release
 622 # should end wit an "even" letter (b, d, ...).
 623
 624 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 625 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 626
 627 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 628   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 629   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 630   { print \"development snapshot\"; }"]`
 631
 632 # '$silent' is set to yes if configure is passed the '--quiet' option.
 633 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
 634
 635 WARNING: You are about to use a $am_release_type of automake.
 636 WARNING: It might easily suffer from new bugs or regressions.
 637 WARNING: You are strongly advised not to use it in production code.
 638
 639 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 640 EOF
 641
 642 AS_EXIT([0])