automake.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # automake - create Makefile.in from Makefile.am
   9 # Copyright (C) 1994-2013 Free Software Foundation, Inc.
  10
  11 # This program is free software; you can redistribute it and/or modify
  12 # it under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 2, or (at your option)
  14 # any later version.
  15
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 # Originally written by David Mackenzie <djm@gnu.ai.mit.edu>.
  25 # Perl reimplementation by Tom Tromey <tromey@redhat.com>, and
  26 # Alexandre Duret-Lutz <adl@gnu.org>.
  27
  28 package Language;
  29
  30 BEGIN
  31 {
  32   @Automake::perl_libdirs = ('@datadir@/@PACKAGE@-@APIVERSION@')
  33     unless @Automake::perl_libdirs;
  34   unshift @INC, @Automake::perl_libdirs;
  35
  36   # Override SHELL.  This is required on DJGPP so that system() uses
  37   # bash, not COMMAND.COM which doesn't quote arguments properly.
  38   # Other systems aren't expected to use $SHELL when Automake
  39   # runs, but it should be safe to drop the "if DJGPP" guard if
  40   # it turns up other systems need the same thing.  After all,
  41   # if SHELL is used, ./configure's SHELL is always better than
  42   # the user's SHELL (which may be something like tcsh).
  43   $ENV{'SHELL'} = '@SHELL@' if exists $ENV{'DJDIR'};
  44 }
  45
  46 use Class::Struct ();
  47 Class::Struct::struct (
  48         # Short name of the language (c, f77...).
  49         'name' => "\$",
  50         # Nice name of the language (C, Fortran 77...).
  51         'Name' => "\$",
  52
  53         # List of configure variables which must be defined.
  54         'config_vars' => '@',
  55
  56         # 'pure' is '1' or ''.  A 'pure' language is one where, if
  57         # all the files in a directory are of that language, then we
  58         # do not require the C compiler or any code to call it.
  59         'pure'   => "\$",
  60
  61         'autodep' => "\$",
  62
  63         # Name of the compiling variable (COMPILE).
  64         'compiler'  => "\$",
  65         # Content of the compiling variable.
  66         'compile'  => "\$",
  67         # Flag to require compilation without linking (-c).
  68         'compile_flag' => "\$",
  69         'extensions' => '@',
  70         # A subroutine to compute a list of possible extensions of
  71         # the product given the input extensions.
  72         # (defaults to a subroutine which returns ('.$(OBJEXT)', '.lo'))
  73         'output_extensions' => "\$",
  74         # A list of flag variables used in 'compile'.
  75         # (defaults to [])
  76         'flags' => "@",
  77
  78         # Any tag to pass to libtool while compiling.
  79         'libtool_tag' => "\$",
  80
  81         # The file to use when generating rules for this language.
  82         # The default is 'depend2'.
  83         'rule_file' => "\$",
  84
  85         # Name of the linking variable (LINK).
  86         'linker' => "\$",
  87         # Content of the linking variable.
  88         'link' => "\$",
  89
  90         # Name of the compiler variable (CC).
  91         'ccer' => "\$",
  92
  93         # Name of the linker variable (LD).
  94         'lder' => "\$",
  95         # Content of the linker variable ($(CC)).
  96         'ld' => "\$",
  97
  98         # Flag to specify the output file (-o).
  99         'output_flag' => "\$",
 100         '_finish' => "\$",
 101
 102         # This is a subroutine which is called whenever we finally
 103         # determine the context in which a source file will be
 104         # compiled.
 105         '_target_hook' => "\$",
 106
 107         # If TRUE, nodist_ sources will be compiled using specific rules
 108         # (i.e. not inference rules).  The default is FALSE.
 109         'nodist_specific' => "\$");
 110
 111
 112 sub finish ($)
 113 {
 114   my ($self) = @_;
 115   if (defined $self->_finish)
 116     {
 117       &{$self->_finish} (@_);
 118     }
 119 }
 120
 121 sub target_hook ($$$$%)
 122 {
 123     my ($self) = @_;
 124     if (defined $self->_target_hook)
 125     {
 126         &{$self->_target_hook} (@_);
 127     }
 128 }
 129
 130 package Automake;
 131
 132 use strict;
 133 use Automake::Config;
 134 BEGIN
 135 {
 136   if ($perl_threads)
 137     {
 138       require threads;
 139       import threads;
 140       require Thread::Queue;
 141       import Thread::Queue;
 142     }
 143 }
 144 use Automake::General;
 145 use Automake::XFile;
 146 use Automake::Channels;
 147 use Automake::ChannelDefs;
 148 use Automake::Configure_ac;
 149 use Automake::FileUtils;
 150 use Automake::Location;
 151 use Automake::Condition qw/TRUE FALSE/;
 152 use Automake::DisjConditions;
 153 use Automake::Options;
 154 use Automake::Variable;
 155 use Automake::VarDef;
 156 use Automake::Rule;
 157 use Automake::RuleDef;
 158 use Automake::Wrap 'makefile_wrap';
 159 use File::Basename;
 160 use File::Spec;
 161 use Carp;
 162
 163 ## ----------- ##
 164 ## Constants.  ##
 165 ## ----------- ##
 166
 167 # Some regular expressions.  One reason to put them here is that it
 168 # makes indentation work better in Emacs.
 169
 170 # Writing singled-quoted-$-terminated regexes is a pain because
 171 # perl-mode thinks of $' as the ${'} variable (instead of a $ followed
 172 # by a closing quote.  Letting perl-mode think the quote is not closed
 173 # leads to all sort of misindentations.  On the other hand, defining
 174 # regexes as double-quoted strings is far less readable.  So usually
 175 # we will write:
 176 #
 177 #  $REGEX = '^regex_value' . "\$";
 178
 179 my $IGNORE_PATTERN = '^\s*##([^#\n].*)?\n';
 180 my $WHITE_PATTERN = '^\s*' . "\$";
 181 my $COMMENT_PATTERN = '^#';
 182 my $TARGET_PATTERN='[$a-zA-Z0-9_.@%][-.a-zA-Z0-9_(){}/$+@%]*';
 183 # A rule has three parts: a list of targets, a list of dependencies,
 184 # and optionally actions.
 185 my $RULE_PATTERN =
 186   "^($TARGET_PATTERN(?:(?:\\\\\n|\\s)+$TARGET_PATTERN)*) *:([^=].*|)\$";
 187
 188 # Only recognize leading spaces, not leading tabs.  If we recognize
 189 # leading tabs here then we need to make the reader smarter, because
 190 # otherwise it will think rules like 'foo=bar; \' are errors.
 191 my $ASSIGNMENT_PATTERN = '^ *([^ \t=:+]*)\s*([:+]?)=\s*(.*)' . "\$";
 192 # This pattern recognizes a Gnits version id and sets $1 if the
 193 # release is an alpha release.  We also allow a suffix which can be
 194 # used to extend the version number with a "fork" identifier.
 195 my $GNITS_VERSION_PATTERN = '\d+\.\d+([a-z]|\.\d+)?(-[A-Za-z0-9]+)?';
 196
 197 my $IF_PATTERN = '^if\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*)\s*(?:#.*)?' . "\$";
 198 my $ELSE_PATTERN =
 199   '^else(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 200 my $ENDIF_PATTERN =
 201   '^endif(?:\s+(!?)\s*([A-Za-z][A-Za-z0-9_]*))?\s*(?:#.*)?' . "\$";
 202 my $PATH_PATTERN = '(\w|[+/.-])+';
 203 # This will pass through anything not of the prescribed form.
 204 my $INCLUDE_PATTERN = ('^include\s+'
 205                        . '((\$\(top_srcdir\)/' . $PATH_PATTERN . ')'
 206                        . '|(\$\(srcdir\)/' . $PATH_PATTERN . ')'
 207                        . '|([^/\$]' . $PATH_PATTERN . '))\s*(#.*)?' . "\$");
 208
 209 # Directories installed during 'install-exec' phase.
 210 my $EXEC_DIR_PATTERN =
 211   '^(?:bin|sbin|libexec|sysconf|localstate|lib|pkglib|.*exec.*)' . "\$";
 212
 213 # Values for AC_CANONICAL_*
 214 use constant AC_CANONICAL_BUILD  => 1;
 215 use constant AC_CANONICAL_HOST   => 2;
 216 use constant AC_CANONICAL_TARGET => 3;
 217
 218 # Values indicating when something should be cleaned.
 219 use constant MOSTLY_CLEAN     => 0;
 220 use constant CLEAN            => 1;
 221 use constant DIST_CLEAN       => 2;
 222 use constant MAINTAINER_CLEAN => 3;
 223
 224 # Libtool files.
 225 my @libtool_files = qw(ltmain.sh config.guess config.sub);
 226 # ltconfig appears here for compatibility with old versions of libtool.
 227 my @libtool_sometimes = qw(ltconfig ltcf-c.sh ltcf-cxx.sh ltcf-gcj.sh);
 228
 229 # Commonly found files we look for and automatically include in
 230 # DISTFILES.
 231 my @common_files =
 232     (qw(ABOUT-GNU ABOUT-NLS AUTHORS BACKLOG COPYING COPYING.DOC COPYING.LIB
 233         COPYING.LESSER ChangeLog INSTALL NEWS README THANKS TODO
 234         ar-lib compile config.guess config.rpath
 235         config.sub depcomp install-sh libversion.in mdate-sh
 236         missing mkinstalldirs py-compile texinfo.tex ylwrap),
 237      @libtool_files, @libtool_sometimes);
 238
 239 # Commonly used files we auto-include, but only sometimes.  This list
 240 # is used for the --help output only.
 241 my @common_sometimes =
 242   qw(aclocal.m4 acconfig.h config.h.top config.h.bot configure
 243      configure.ac configure.in stamp-vti);
 244
 245 # Standard directories from the GNU Coding Standards, and additional
 246 # pkg* directories from Automake.  Stored in a hash for fast member check.
 247 my %standard_prefix =
 248     map { $_ => 1 } (qw(bin data dataroot doc dvi exec html include info
 249                         lib libexec lisp locale localstate man man1 man2
 250                         man3 man4 man5 man6 man7 man8 man9 oldinclude pdf
 251                         pkgdata pkginclude pkglib pkglibexec ps sbin
 252                         sharedstate sysconf));
 253
 254 # Copyright on generated Makefile.ins.
 255 my $gen_copyright = "\
 256 # Copyright (C) 1994-$RELEASE_YEAR Free Software Foundation, Inc.
 257
 258 # This Makefile.in is free software; the Free Software Foundation
 259 # gives unlimited permission to copy and/or distribute it,
 260 # with or without modifications, as long as this notice is preserved.
 261
 262 # This program is distributed in the hope that it will be useful,
 263 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 264 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 265 # PARTICULAR PURPOSE.
 266 ";
 267
 268 # These constants are returned by the lang_*_rewrite functions.
 269 # LANG_SUBDIR means that the resulting object file should be in a
 270 # subdir if the source file is.  In this case the file name cannot
 271 # have '..' components.
 272 use constant LANG_IGNORE  => 0;
 273 use constant LANG_PROCESS => 1;
 274 use constant LANG_SUBDIR  => 2;
 275
 276 # These are used when keeping track of whether an object can be built
 277 # by two different paths.
 278 use constant COMPILE_LIBTOOL  => 1;
 279 use constant COMPILE_ORDINARY => 2;
 280
 281 # We can't always associate a location to a variable or a rule,
 282 # when it's defined by Automake.  We use INTERNAL in this case.
 283 use constant INTERNAL => new Automake::Location;
 284
 285 # Serialization keys for message queues.
 286 use constant QUEUE_MESSAGE   => "msg";
 287 use constant QUEUE_CONF_FILE => "conf file";
 288 use constant QUEUE_LOCATION  => "location";
 289 use constant QUEUE_STRING    => "string";
 290
 291 ## ---------------------------------- ##
 292 ## Variables related to the options.  ##
 293 ## ---------------------------------- ##
 294
 295 # TRUE if we should always generate Makefile.in.
 296 my $force_generation = 1;
 297
 298 # From the Perl manual.
 299 my $symlink_exists = (eval 'symlink ("", "");', $@ eq '');
 300
 301 # TRUE if missing standard files should be installed.
 302 my $add_missing = 0;
 303
 304 # TRUE if we should copy missing files; otherwise symlink if possible.
 305 my $copy_missing = 0;
 306
 307 # TRUE if we should always update files that we know about.
 308 my $force_missing = 0;
 309
 310
 311 ## ---------------------------------------- ##
 312 ## Variables filled during files scanning.  ##
 313 ## ---------------------------------------- ##
 314
 315 # Name of the configure.ac file.
 316 my $configure_ac;
 317
 318 # Files found by scanning configure.ac for LIBOBJS.
 319 my %libsources = ();
 320
 321 # Names used in AC_CONFIG_HEADERS call.
 322 my @config_headers = ();
 323
 324 # Names used in AC_CONFIG_LINKS call.
 325 my @config_links = ();
 326
 327 # List of Makefile.am's to process, and their corresponding outputs.
 328 my @input_files = ();
 329 my %output_files = ();
 330
 331 # Complete list of Makefile.am's that exist.
 332 my @configure_input_files = ();
 333
 334 # List of files in AC_CONFIG_FILES/AC_OUTPUT without Makefile.am's,
 335 # and their outputs.
 336 my @other_input_files = ();
 337 # Where each AC_CONFIG_FILES/AC_OUTPUT/AC_CONFIG_LINK/AC_CONFIG_HEADERS
 338 # appears.  The keys are the files created by these macros.
 339 my %ac_config_files_location = ();
 340 # The condition under which AC_CONFIG_FOOS appears.
 341 my %ac_config_files_condition = ();
 342
 343 # Directory to search for configure-required files.  This
 344 # will be computed by &locate_aux_dir and can be set using
 345 # AC_CONFIG_AUX_DIR in configure.ac.
 346 # $CONFIG_AUX_DIR is the 'raw' directory, valid only in the source-tree.
 347 my $config_aux_dir = '';
 348 my $config_aux_dir_set_in_configure_ac = 0;
 349 # $AM_CONFIG_AUX_DIR is prefixed with $(top_srcdir), so it can be used
 350 # in Makefiles.
 351 my $am_config_aux_dir = '';
 352
 353 # Directory to search for AC_LIBSOURCE files, as set by AC_CONFIG_LIBOBJ_DIR
 354 # in configure.ac.
 355 my $config_libobj_dir = '';
 356
 357 # Whether AM_GNU_GETTEXT has been seen in configure.ac.
 358 my $seen_gettext = 0;
 359 # Whether AM_GNU_GETTEXT([external]) is used.
 360 my $seen_gettext_external = 0;
 361 # Where AM_GNU_GETTEXT appears.
 362 my $ac_gettext_location;
 363 # Whether AM_GNU_GETTEXT_INTL_SUBDIR has been seen.
 364 my $seen_gettext_intl = 0;
 365
 366 # The arguments of the AM_EXTRA_RECURSIVE_TARGETS call (if any).
 367 my @extra_recursive_targets = ();
 368
 369 # Lists of tags supported by Libtool.
 370 my %libtool_tags = ();
 371 # 1 if Libtool uses LT_SUPPORTED_TAG.  If it does, then it also
 372 # uses AC_REQUIRE_AUX_FILE.
 373 my $libtool_new_api = 0;
 374
 375 # Most important AC_CANONICAL_* macro seen so far.
 376 my $seen_canonical = 0;
 377
 378 # Where AM_MAINTAINER_MODE appears.
 379 my $seen_maint_mode;
 380
 381 # Actual version we've seen.
 382 my $package_version = '';
 383
 384 # Where version is defined.
 385 my $package_version_location;
 386
 387 # TRUE if we've seen AM_PROG_AR
 388 my $seen_ar = 0;
 389
 390 # TRUE if we've seen AM_PROG_CC_C_O
 391 my $seen_cc_c_o = 0;
 392
 393 # Location of AC_REQUIRE_AUX_FILE calls, indexed by their argument.
 394 my %required_aux_file = ();
 395
 396 # Where AM_INIT_AUTOMAKE is called;
 397 my $seen_init_automake = 0;
 398
 399 # TRUE if we've seen AM_AUTOMAKE_VERSION.
 400 my $seen_automake_version = 0;
 401
 402 # Hash table of discovered configure substitutions.  Keys are names,
 403 # values are 'FILE:LINE' strings which are used by error message
 404 # generation.
 405 my %configure_vars = ();
 406
 407 # Ignored configure substitutions (i.e., variables not to be output in
 408 # Makefile.in)
 409 my %ignored_configure_vars = ();
 410
 411 # Files included by $configure_ac.
 412 my @configure_deps = ();
 413
 414 # Greatest timestamp of configure's dependencies.
 415 my $configure_deps_greatest_timestamp = 0;
 416
 417 # Hash table of AM_CONDITIONAL variables seen in configure.
 418 my %configure_cond = ();
 419
 420 # This maps extensions onto language names.
 421 my %extension_map = ();
 422
 423 # List of the DIST_COMMON files we discovered while reading
 424 # configure.ac.
 425 my $configure_dist_common = '';
 426
 427 # This maps languages names onto objects.
 428 my %languages = ();
 429 # Maps each linker variable onto a language object.
 430 my %link_languages = ();
 431
 432 # maps extensions to needed source flags.
 433 my %sourceflags = ();
 434
 435 # List of targets we must always output.
 436 # FIXME: Complete, and remove falsely required targets.
 437 my %required_targets =
 438   (
 439    'all'          => 1,
 440    'dvi'          => 1,
 441    'pdf'          => 1,
 442    'ps'           => 1,
 443    'info'         => 1,
 444    'install-info' => 1,
 445    'install'      => 1,
 446    'install-data' => 1,
 447    'install-exec' => 1,
 448    'uninstall'    => 1,
 449
 450    # FIXME: Not required, temporary hacks.
 451    # Well, actually they are sort of required: the -recursive
 452    # targets will run them anyway...
 453    'html-am'         => 1,
 454    'dvi-am'          => 1,
 455    'pdf-am'          => 1,
 456    'ps-am'           => 1,
 457    'info-am'         => 1,
 458    'install-data-am' => 1,
 459    'install-exec-am' => 1,
 460    'install-html-am' => 1,
 461    'install-dvi-am'  => 1,
 462    'install-pdf-am'  => 1,
 463    'install-ps-am'   => 1,
 464    'install-info-am' => 1,
 465    'installcheck-am' => 1,
 466    'uninstall-am'    => 1,
 467    'tags-am'         => 1,
 468    'ctags-am'        => 1,
 469    'cscopelist-am'   => 1,
 470    'install-man'     => 1,
 471   );
 472
 473 # Queue to push require_conf_file requirements to.
 474 my $required_conf_file_queue;
 475
 476 # The name of the Makefile currently being processed.
 477 my $am_file = 'BUG';
 478
 479 ################################################################
 480
 481 ## ------------------------------------------ ##
 482 ## Variables reset by &initialize_per_input.  ##
 483 ## ------------------------------------------ ##
 484
 485 # Relative dir of the output makefile.
 486 my $relative_dir;
 487
 488 # Greatest timestamp of the output's dependencies (excluding
 489 # configure's dependencies).
 490 my $output_deps_greatest_timestamp;
 491
 492 # These variables are used when generating each Makefile.in.
 493 # They hold the Makefile.in until it is ready to be printed.
 494 my $output_vars;
 495 my $output_all;
 496 my $output_header;
 497 my $output_rules;
 498 my $output_trailer;
 499
 500 # This is the conditional stack, updated on if/else/endif, and
 501 # used to build Condition objects.
 502 my @cond_stack;
 503
 504 # This holds the set of included files.
 505 my @include_stack;
 506
 507 # List of dependencies for the obvious targets.
 508 my @all;
 509 my @check;
 510 my @check_tests;
 511
 512 # Keys in this hash table are files to delete.  The associated
 513 # value tells when this should happen (MOSTLY_CLEAN, DIST_CLEAN, etc.)
 514 my %clean_files;
 515
 516 # Keys in this hash table are object files or other files in
 517 # subdirectories which need to be removed.  This only holds files
 518 # which are created by compilations.  The value in the hash indicates
 519 # when the file should be removed.
 520 my %compile_clean_files;
 521
 522 # Keys in this hash table are directories where we expect to build a
 523 # libtool object.  We use this information to decide what directories
 524 # to delete.
 525 my %libtool_clean_directories;
 526
 527 # Value of $(SOURCES), used by tags.am.
 528 my @sources;
 529 # Sources which go in the distribution.
 530 my @dist_sources;
 531
 532 # This hash maps object file names onto their corresponding source
 533 # file names.  This is used to ensure that each object is created
 534 # by a single source file.
 535 my %object_map;
 536
 537 # This hash maps object file names onto an integer value representing
 538 # whether this object has been built via ordinary compilation or
 539 # libtool compilation (the COMPILE_* constants).
 540 my %object_compilation_map;
 541
 542
 543 # This keeps track of the directories for which we've already
 544 # created dirstamp code.  Keys are directories, values are stamp files.
 545 # Several keys can share the same stamp files if they are equivalent
 546 # (as are './/foo' and 'foo').
 547 my %directory_map;
 548
 549 # All .P files.
 550 my %dep_files;
 551
 552 # This is a list of all targets to run during "make dist".
 553 my @dist_targets;
 554
 555 # Keep track of all programs declared in this Makefile, without
 556 # $(EXEEXT).  @substitutions@ are not listed.
 557 my %known_programs;
 558 my %known_libraries;
 559
 560 # This keeps track of which extensions we've seen (that we care
 561 # about).
 562 my %extension_seen;
 563
 564 # This is random scratch space for the language finish functions.
 565 # Don't randomly overwrite it; examine other uses of keys first.
 566 my %language_scratch;
 567
 568 # We keep track of which objects need special (per-executable)
 569 # handling on a per-language basis.
 570 my %lang_specific_files;
 571
 572 # This is set when 'handle_dist' has finished.  Once this happens,
 573 # we should no longer push on dist_common.
 574 my $handle_dist_run;
 575
 576 # Used to store a set of linkers needed to generate the sources currently
 577 # under consideration.
 578 my %linkers_used;
 579
 580 # True if we need 'LINK' defined.  This is a hack.
 581 my $need_link;
 582
 583 # Does the generated Makefile have to build some compiled object
 584 # (for binary programs, or plain or libtool libraries)?
 585 my $must_handle_compiled_objects;
 586
 587 # Record each file processed by make_paragraphs.
 588 my %transformed_files;
 589
 590 ################################################################
 591
 592 ## ---------------------------------------------- ##
 593 ## Variables not reset by &initialize_per_input.  ##
 594 ## ---------------------------------------------- ##
 595
 596 # Cache each file processed by make_paragraphs.
 597 # (This is different from %transformed_files because
 598 # %transformed_files is reset for each file while %am_file_cache
 599 # it global to the run.)
 600 my %am_file_cache;
 601
 602 ################################################################
 603
 604 # var_SUFFIXES_trigger ($TYPE, $VALUE)
 605 # ------------------------------------
 606 # This is called by Automake::Variable::define() when SUFFIXES
 607 # is defined ($TYPE eq '') or appended ($TYPE eq '+').
 608 # The work here needs to be performed as a side-effect of the
 609 # macro_define() call because SUFFIXES definitions impact
 610 # on $KNOWN_EXTENSIONS_PATTERN which is used used when parsing
 611 # the input am file.
 612 sub var_SUFFIXES_trigger ($$)
 613 {
 614     my ($type, $value) = @_;
 615     accept_extensions (split (' ', $value));
 616 }
 617 Automake::Variable::hook ('SUFFIXES', \&var_SUFFIXES_trigger);
 618
 619 ################################################################
 620
 621 ## --------------------------------- ##
 622 ## Forward subroutine declarations.  ##
 623 ## --------------------------------- ##
 624 sub register_language (%);
 625 sub file_contents_internal ($$$%);
 626 sub define_files_variable ($\@$$);
 627
 628
 629 # &initialize_per_input ()
 630 # ------------------------
 631 # (Re)-Initialize per-Makefile.am variables.
 632 sub initialize_per_input ()
 633 {
 634     reset_local_duplicates ();
 635
 636     $relative_dir = undef;
 637
 638     $output_deps_greatest_timestamp = 0;
 639
 640     $output_vars = '';
 641     $output_all = '';
 642     $output_header = '';
 643     $output_rules = '';
 644     $output_trailer = '';
 645
 646     Automake::Options::reset;
 647     Automake::Variable::reset;
 648     Automake::Rule::reset;
 649
 650     @cond_stack = ();
 651
 652     @include_stack = ();
 653
 654     @all = ();
 655     @check = ();
 656     @check_tests = ();
 657
 658     %clean_files = ();
 659     %compile_clean_files = ();
 660
 661     # We always include '.'.  This isn't strictly correct.
 662     %libtool_clean_directories = ('.' => 1);
 663
 664     @sources = ();
 665     @dist_sources = ();
 666
 667     %object_map = ();
 668     %object_compilation_map = ();
 669
 670     %directory_map = ();
 671
 672     %dep_files = ();
 673
 674     @dist_targets = ();
 675
 676     %known_programs = ();
 677     %known_libraries= ();
 678
 679     %extension_seen = ();
 680
 681     %language_scratch = ();
 682
 683     %lang_specific_files = ();
 684
 685     $handle_dist_run = 0;
 686
 687     $need_link = 0;
 688
 689     $must_handle_compiled_objects = 0;
 690
 691     %transformed_files = ();
 692 }
 693
 694
 695 ################################################################
 696
 697 # Initialize our list of languages that are internally supported.
 698
 699 # C.
 700 register_language ('name' => 'c',
 701                    'Name' => 'C',
 702                    'config_vars' => ['CC'],
 703                    'autodep' => '',
 704                    'flags' => ['CFLAGS', 'CPPFLAGS'],
 705                    'ccer' => 'CC',
 706                    'compiler' => 'COMPILE',
 707                    'compile' => '$(CC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CFLAGS) $(CFLAGS)',
 708                    'lder' => 'CCLD',
 709                    'ld' => '$(CC)',
 710                    'linker' => 'LINK',
 711                    'link' => '$(CCLD) $(AM_CFLAGS) $(CFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 712                    'compile_flag' => '-c',
 713                    'libtool_tag' => 'CC',
 714                    'extensions' => ['.c']);
 715
 716 # C++.
 717 register_language ('name' => 'cxx',
 718                    'Name' => 'C++',
 719                    'config_vars' => ['CXX'],
 720                    'linker' => 'CXXLINK',
 721                    'link' => '$(CXXLD) $(AM_CXXFLAGS) $(CXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 722                    'autodep' => 'CXX',
 723                    'flags' => ['CXXFLAGS', 'CPPFLAGS'],
 724                    'compile' => '$(CXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CXXFLAGS) $(CXXFLAGS)',
 725                    'ccer' => 'CXX',
 726                    'compiler' => 'CXXCOMPILE',
 727                    'compile_flag' => '-c',
 728                    'output_flag' => '-o',
 729                    'libtool_tag' => 'CXX',
 730                    'lder' => 'CXXLD',
 731                    'ld' => '$(CXX)',
 732                    'pure' => 1,
 733                    'extensions' => ['.c++', '.cc', '.cpp', '.cxx', '.C']);
 734
 735 # Objective C.
 736 register_language ('name' => 'objc',
 737                    'Name' => 'Objective C',
 738                    'config_vars' => ['OBJC'],
 739                    'linker' => 'OBJCLINK',
 740                    'link' => '$(OBJCLD) $(AM_OBJCFLAGS) $(OBJCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 741                    'autodep' => 'OBJC',
 742                    'flags' => ['OBJCFLAGS', 'CPPFLAGS'],
 743                    'compile' => '$(OBJC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCFLAGS) $(OBJCFLAGS)',
 744                    'ccer' => 'OBJC',
 745                    'compiler' => 'OBJCCOMPILE',
 746                    'compile_flag' => '-c',
 747                    'output_flag' => '-o',
 748                    'lder' => 'OBJCLD',
 749                    'ld' => '$(OBJC)',
 750                    'pure' => 1,
 751                    'extensions' => ['.m']);
 752
 753 # Objective C++.
 754 register_language ('name' => 'objcxx',
 755                    'Name' => 'Objective C++',
 756                    'config_vars' => ['OBJCXX'],
 757                    'linker' => 'OBJCXXLINK',
 758                    'link' => '$(OBJCXXLD) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 759                    'autodep' => 'OBJCXX',
 760                    'flags' => ['OBJCXXFLAGS', 'CPPFLAGS'],
 761                    'compile' => '$(OBJCXX) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_OBJCXXFLAGS) $(OBJCXXFLAGS)',
 762                    'ccer' => 'OBJCXX',
 763                    'compiler' => 'OBJCXXCOMPILE',
 764                    'compile_flag' => '-c',
 765                    'output_flag' => '-o',
 766                    'lder' => 'OBJCXXLD',
 767                    'ld' => '$(OBJCXX)',
 768                    'pure' => 1,
 769                    'extensions' => ['.mm']);
 770
 771 # Unified Parallel C.
 772 register_language ('name' => 'upc',
 773                    'Name' => 'Unified Parallel C',
 774                    'config_vars' => ['UPC'],
 775                    'linker' => 'UPCLINK',
 776                    'link' => '$(UPCLD) $(AM_UPCFLAGS) $(UPCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 777                    'autodep' => 'UPC',
 778                    'flags' => ['UPCFLAGS', 'CPPFLAGS'],
 779                    'compile' => '$(UPC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_UPCFLAGS) $(UPCFLAGS)',
 780                    'ccer' => 'UPC',
 781                    'compiler' => 'UPCCOMPILE',
 782                    'compile_flag' => '-c',
 783                    'output_flag' => '-o',
 784                    'lder' => 'UPCLD',
 785                    'ld' => '$(UPC)',
 786                    'pure' => 1,
 787                    'extensions' => ['.upc']);
 788
 789 # Headers.
 790 register_language ('name' => 'header',
 791                    'Name' => 'Header',
 792                    'extensions' => ['.h', '.H', '.hxx', '.h++', '.hh',
 793                                     '.hpp', '.inc'],
 794                    # No output.
 795                    'output_extensions' => sub { return () },
 796                    # Nothing to do.
 797                    '_finish' => sub { });
 798
 799 # Vala
 800 register_language ('name' => 'vala',
 801                    'Name' => 'Vala',
 802                    'config_vars' => ['VALAC'],
 803                    'flags' => [],
 804                    'compile' => '$(VALAC) $(AM_VALAFLAGS) $(VALAFLAGS)',
 805                    'ccer' => 'VALAC',
 806                    'compiler' => 'VALACOMPILE',
 807                    'extensions' => ['.vala'],
 808                    'output_extensions' => sub { (my $ext = $_[0]) =~ s/vala$/c/;
 809                                                 return ($ext,) },
 810                    'rule_file' => 'vala',
 811                    '_finish' => \&lang_vala_finish,
 812                    '_target_hook' => \&lang_vala_target_hook,
 813                    'nodist_specific' => 1);
 814
 815 # Yacc (C & C++).
 816 register_language ('name' => 'yacc',
 817                    'Name' => 'Yacc',
 818                    'config_vars' => ['YACC'],
 819                    'flags' => ['YFLAGS'],
 820                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 821                    'ccer' => 'YACC',
 822                    'compiler' => 'YACCCOMPILE',
 823                    'extensions' => ['.y'],
 824                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 825                                                 return ($ext,) },
 826                    'rule_file' => 'yacc',
 827                    '_finish' => \&lang_yacc_finish,
 828                    '_target_hook' => \&lang_yacc_target_hook,
 829                    'nodist_specific' => 1);
 830 register_language ('name' => 'yaccxx',
 831                    'Name' => 'Yacc (C++)',
 832                    'config_vars' => ['YACC'],
 833                    'rule_file' => 'yacc',
 834                    'flags' => ['YFLAGS'],
 835                    'ccer' => 'YACC',
 836                    'compiler' => 'YACCCOMPILE',
 837                    'compile' => '$(YACC) $(AM_YFLAGS) $(YFLAGS)',
 838                    'extensions' => ['.y++', '.yy', '.yxx', '.ypp'],
 839                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/y/c/;
 840                                                 return ($ext,) },
 841                    '_finish' => \&lang_yacc_finish,
 842                    '_target_hook' => \&lang_yacc_target_hook,
 843                    'nodist_specific' => 1);
 844
 845 # Lex (C & C++).
 846 register_language ('name' => 'lex',
 847                    'Name' => 'Lex',
 848                    'config_vars' => ['LEX'],
 849                    'rule_file' => 'lex',
 850                    'flags' => ['LFLAGS'],
 851                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 852                    'ccer' => 'LEX',
 853                    'compiler' => 'LEXCOMPILE',
 854                    'extensions' => ['.l'],
 855                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 856                                                 return ($ext,) },
 857                    '_finish' => \&lang_lex_finish,
 858                    '_target_hook' => \&lang_lex_target_hook,
 859                    'nodist_specific' => 1);
 860 register_language ('name' => 'lexxx',
 861                    'Name' => 'Lex (C++)',
 862                    'config_vars' => ['LEX'],
 863                    'rule_file' => 'lex',
 864                    'flags' => ['LFLAGS'],
 865                    'compile' => '$(LEX) $(AM_LFLAGS) $(LFLAGS)',
 866                    'ccer' => 'LEX',
 867                    'compiler' => 'LEXCOMPILE',
 868                    'extensions' => ['.l++', '.ll', '.lxx', '.lpp'],
 869                    'output_extensions' => sub { (my $ext = $_[0]) =~ tr/l/c/;
 870                                                 return ($ext,) },
 871                    '_finish' => \&lang_lex_finish,
 872                    '_target_hook' => \&lang_lex_target_hook,
 873                    'nodist_specific' => 1);
 874
 875 # Assembler.
 876 register_language ('name' => 'asm',
 877                    'Name' => 'Assembler',
 878                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 879
 880                    'flags' => ['CCASFLAGS'],
 881                    # Users can set AM_CCASFLAGS to include DEFS, INCLUDES,
 882                    # or anything else required.  They can also set CCAS.
 883                    # Or simply use Preprocessed Assembler.
 884                    'compile' => '$(CCAS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 885                    'ccer' => 'CCAS',
 886                    'compiler' => 'CCASCOMPILE',
 887                    'compile_flag' => '-c',
 888                    'output_flag' => '-o',
 889                    'extensions' => ['.s']);
 890
 891 # Preprocessed Assembler.
 892 register_language ('name' => 'cppasm',
 893                    'Name' => 'Preprocessed Assembler',
 894                    'config_vars' => ['CCAS', 'CCASFLAGS'],
 895
 896                    'autodep' => 'CCAS',
 897                    'flags' => ['CCASFLAGS', 'CPPFLAGS'],
 898                    'compile' => '$(CCAS) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_CCASFLAGS) $(CCASFLAGS)',
 899                    'ccer' => 'CPPAS',
 900                    'compiler' => 'CPPASCOMPILE',
 901                    'compile_flag' => '-c',
 902                    'output_flag' => '-o',
 903                    'extensions' => ['.S', '.sx']);
 904
 905 # Fortran 77
 906 register_language ('name' => 'f77',
 907                    'Name' => 'Fortran 77',
 908                    'config_vars' => ['F77'],
 909                    'linker' => 'F77LINK',
 910                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 911                    'flags' => ['FFLAGS'],
 912                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS)',
 913                    'ccer' => 'F77',
 914                    'compiler' => 'F77COMPILE',
 915                    'compile_flag' => '-c',
 916                    'output_flag' => '-o',
 917                    'libtool_tag' => 'F77',
 918                    'lder' => 'F77LD',
 919                    'ld' => '$(F77)',
 920                    'pure' => 1,
 921                    'extensions' => ['.f', '.for']);
 922
 923 # Fortran
 924 register_language ('name' => 'fc',
 925                    'Name' => 'Fortran',
 926                    'config_vars' => ['FC'],
 927                    'linker' => 'FCLINK',
 928                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 929                    'flags' => ['FCFLAGS'],
 930                    'compile' => '$(FC) $(AM_FCFLAGS) $(FCFLAGS)',
 931                    'ccer' => 'FC',
 932                    'compiler' => 'FCCOMPILE',
 933                    'compile_flag' => '-c',
 934                    'output_flag' => '-o',
 935                    'libtool_tag' => 'FC',
 936                    'lder' => 'FCLD',
 937                    'ld' => '$(FC)',
 938                    'pure' => 1,
 939                    'extensions' => ['.f90', '.f95', '.f03', '.f08']);
 940
 941 # Preprocessed Fortran
 942 register_language ('name' => 'ppfc',
 943                    'Name' => 'Preprocessed Fortran',
 944                    'config_vars' => ['FC'],
 945                    'linker' => 'FCLINK',
 946                    'link' => '$(FCLD) $(AM_FCFLAGS) $(FCFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 947                    'lder' => 'FCLD',
 948                    'ld' => '$(FC)',
 949                    'flags' => ['FCFLAGS', 'CPPFLAGS'],
 950                    'ccer' => 'PPFC',
 951                    'compiler' => 'PPFCCOMPILE',
 952                    'compile' => '$(FC) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FCFLAGS) $(FCFLAGS)',
 953                    'compile_flag' => '-c',
 954                    'output_flag' => '-o',
 955                    'libtool_tag' => 'FC',
 956                    'pure' => 1,
 957                    'extensions' => ['.F90','.F95', '.F03', '.F08']);
 958
 959 # Preprocessed Fortran 77
 960 #
 961 # The current support for preprocessing Fortran 77 just involves
 962 # passing "$(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS)
 963 # $(CPPFLAGS)" as additional flags to the Fortran 77 compiler, since
 964 # this is how GNU Make does it; see the "GNU Make Manual, Edition 0.51
 965 # for 'make' Version 3.76 Beta" (specifically, from info file
 966 # '(make)Catalogue of Rules').
 967 #
 968 # A better approach would be to write an Autoconf test
 969 # (i.e. AC_PROG_FPP) for a Fortran 77 preprocessor, because not all
 970 # Fortran 77 compilers know how to do preprocessing.  The Autoconf
 971 # macro AC_PROG_FPP should test the Fortran 77 compiler first for
 972 # preprocessing capabilities, and then fall back on cpp (if cpp were
 973 # available).
 974 register_language ('name' => 'ppf77',
 975                    'Name' => 'Preprocessed Fortran 77',
 976                    'config_vars' => ['F77'],
 977                    'linker' => 'F77LINK',
 978                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 979                    'lder' => 'F77LD',
 980                    'ld' => '$(F77)',
 981                    'flags' => ['FFLAGS', 'CPPFLAGS'],
 982                    'ccer' => 'PPF77',
 983                    'compiler' => 'PPF77COMPILE',
 984                    'compile' => '$(F77) $(DEFS) $(DEFAULT_INCLUDES) $(INCLUDES) $(AM_CPPFLAGS) $(CPPFLAGS) $(AM_FFLAGS) $(FFLAGS)',
 985                    'compile_flag' => '-c',
 986                    'output_flag' => '-o',
 987                    'libtool_tag' => 'F77',
 988                    'pure' => 1,
 989                    'extensions' => ['.F']);
 990
 991 # Ratfor.
 992 register_language ('name' => 'ratfor',
 993                    'Name' => 'Ratfor',
 994                    'config_vars' => ['F77'],
 995                    'linker' => 'F77LINK',
 996                    'link' => '$(F77LD) $(AM_FFLAGS) $(FFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
 997                    'lder' => 'F77LD',
 998                    'ld' => '$(F77)',
 999                    'flags' => ['RFLAGS', 'FFLAGS'],
1000                    # FIXME also FFLAGS.
1001                    'compile' => '$(F77) $(AM_FFLAGS) $(FFLAGS) $(AM_RFLAGS) $(RFLAGS)',
1002                    'ccer' => 'F77',
1003                    'compiler' => 'RCOMPILE',
1004                    'compile_flag' => '-c',
1005                    'output_flag' => '-o',
1006                    'libtool_tag' => 'F77',
1007                    'pure' => 1,
1008                    'extensions' => ['.r']);
1009
1010 # Java via gcj.
1011 register_language ('name' => 'java',
1012                    'Name' => 'Java',
1013                    'config_vars' => ['GCJ'],
1014                    'linker' => 'GCJLINK',
1015                    'link' => '$(GCJLD) $(AM_GCJFLAGS) $(GCJFLAGS) $(AM_LDFLAGS) $(LDFLAGS) -o $@',
1016                    'autodep' => 'GCJ',
1017                    'flags' => ['GCJFLAGS'],
1018                    'compile' => '$(GCJ) $(AM_GCJFLAGS) $(GCJFLAGS)',
1019                    'ccer' => 'GCJ',
1020                    'compiler' => 'GCJCOMPILE',
1021                    'compile_flag' => '-c',
1022                    'output_flag' => '-o',
1023                    'libtool_tag' => 'GCJ',
1024                    'lder' => 'GCJLD',
1025                    'ld' => '$(GCJ)',
1026                    'pure' => 1,
1027                    'extensions' => ['.java', '.class', '.zip', '.jar']);
1028
1029 ################################################################
1030
1031 # Error reporting functions.
1032
1033 # err_am ($MESSAGE, [%OPTIONS])
1034 # -----------------------------
1035 # Uncategorized errors about the current Makefile.am.
1036 sub err_am ($;%)
1037 {
1038   msg_am ('error', @_);
1039 }
1040
1041 # err_ac ($MESSAGE, [%OPTIONS])
1042 # -----------------------------
1043 # Uncategorized errors about configure.ac.
1044 sub err_ac ($;%)
1045 {
1046   msg_ac ('error', @_);
1047 }
1048
1049 # msg_am ($CHANNEL, $MESSAGE, [%OPTIONS])
1050 # ---------------------------------------
1051 # Messages about about the current Makefile.am.
1052 sub msg_am ($$;%)
1053 {
1054   my ($channel, $msg, %opts) = @_;
1055   msg $channel, "${am_file}.am", $msg, %opts;
1056 }
1057
1058 # msg_ac ($CHANNEL, $MESSAGE, [%OPTIONS])
1059 # ---------------------------------------
1060 # Messages about about configure.ac.
1061 sub msg_ac ($$;%)
1062 {
1063   my ($channel, $msg, %opts) = @_;
1064   msg $channel, $configure_ac, $msg, %opts;
1065 }
1066
1067 ################################################################
1068
1069 # subst ($TEXT)
1070 # -------------
1071 # Return a configure-style substitution using the indicated text.
1072 # We do this to avoid having the substitutions directly in automake.in;
1073 # when we do that they are sometimes removed and this causes confusion
1074 # and bugs.
1075 sub subst ($)
1076 {
1077     my ($text) = @_;
1078     return '@' . $text . '@';
1079 }
1080
1081 ################################################################
1082
1083
1084 # $BACKPATH
1085 # &backname ($RELDIR)
1086 # --------------------
1087 # If I "cd $RELDIR", then to come back, I should "cd $BACKPATH".
1088 # For instance 'src/foo' => '../..'.
1089 # Works with non strictly increasing paths, i.e., 'src/../lib' => '..'.
1090 sub backname ($)
1091 {
1092     my ($file) = @_;
1093     my @res;
1094     foreach (split (/\//, $file))
1095     {
1096         next if $_ eq '.' || $_ eq '';
1097         if ($_ eq '..')
1098         {
1099             pop @res
1100               or prog_error ("trying to reverse path '$file' pointing outside tree");
1101         }
1102         else
1103         {
1104             push (@res, '..');
1105         }
1106     }
1107     return join ('/', @res) || '.';
1108 }
1109
1110 ################################################################
1111
1112 # Silent rules handling functions.
1113
1114 # verbose_var (NAME)
1115 # ------------------
1116 # The public variable stem used to implement silent rules.
1117 sub verbose_var ($)
1118 {
1119     my ($name) = @_;
1120     return 'AM_V_' . $name;
1121 }
1122
1123 # verbose_private_var (NAME)
1124 # --------------------------
1125 # The naming policy for the private variables for silent rules.
1126 sub verbose_private_var ($)
1127 {
1128     my ($name) = @_;
1129     return 'am__v_' . $name;
1130 }
1131
1132 # define_verbose_var (NAME, VAL-IF-SILENT, [VAL-IF-VERBOSE])
1133 # ----------------------------------------------------------
1134 # For  silent rules, setup VAR and dispatcher, to expand to
1135 # VAL-IF-SILENT if silent, to VAL-IF-VERBOSE (defaulting to
1136 # empty) if not.
1137 sub define_verbose_var ($$;$)
1138 {
1139     my ($name, $silent_val, $verbose_val) = @_;
1140     $verbose_val = '' unless defined $verbose_val;
1141     my $var = verbose_var ($name);
1142     my $pvar = verbose_private_var ($name);
1143     my $silent_var = $pvar . '_0';
1144     my $verbose_var = $pvar . '_1';
1145     # For typical 'make's, 'configure' replaces AM_V (inside @@) with $(V)
1146     # and AM_DEFAULT_V (inside @@) with $(AM_DEFAULT_VERBOSITY).
1147     # For strict POSIX 2008 'make's, it replaces them with 0 or 1 instead.
1148     # See AM_SILENT_RULES in m4/silent.m4.
1149     define_variable ($var, '$(' . $pvar . '_@'.'AM_V'.'@)', INTERNAL);
1150     define_variable ($pvar . '_', '$(' . $pvar . '_@'.'AM_DEFAULT_V'.'@)',
1151                      INTERNAL);
1152     Automake::Variable::define ($silent_var, VAR_AUTOMAKE, '', TRUE,
1153                                 $silent_val, '', INTERNAL, VAR_ASIS)
1154       if (! vardef ($silent_var, TRUE));
1155     Automake::Variable::define ($verbose_var, VAR_AUTOMAKE, '', TRUE,
1156                                 $verbose_val, '', INTERNAL, VAR_ASIS)
1157       if (! vardef ($verbose_var, TRUE));
1158 }
1159
1160 # Above should not be needed in the general automake code.
1161
1162 # verbose_flag (NAME)
1163 # -------------------
1164 # Contents of %VERBOSE%: variable to expand before rule command.
1165 sub verbose_flag ($)
1166 {
1167     my ($name) = @_;
1168     return '$(' . verbose_var ($name) . ')';
1169 }
1170
1171 sub verbose_nodep_flag ($)
1172 {
1173     my ($name) = @_;
1174     return '$(' . verbose_var ($name) . subst ('am__nodep') . ')';
1175 }
1176
1177 # silent_flag
1178 # -----------
1179 # Contents of %SILENT%: variable to expand to '@' when silent.
1180 sub silent_flag ()
1181 {
1182     return verbose_flag ('at');
1183 }
1184
1185 # define_verbose_tagvar (NAME)
1186 # ----------------------------
1187 # Engage the needed silent rules machinery for tag NAME.
1188 sub define_verbose_tagvar ($)
1189 {
1190     my ($name) = @_;
1191     define_verbose_var ($name, '@echo "  '. $name . ' ' x (8 - length ($name)) . '" $@;');
1192 }
1193
1194 # define_verbose_texinfo
1195 # ----------------------
1196 # Engage the needed silent rules machinery for assorted texinfo commands.
1197 sub define_verbose_texinfo ()
1198 {
1199   my @tagvars = ('DVIPS', 'MAKEINFO', 'INFOHTML', 'TEXI2DVI', 'TEXI2PDF');
1200   foreach my $tag (@tagvars)
1201     {
1202       define_verbose_tagvar($tag);
1203     }
1204   define_verbose_var('texinfo', '-q');
1205   define_verbose_var('texidevnull', '> /dev/null');
1206 }
1207
1208 # define_verbose_libtool
1209 # ----------------------
1210 # Engage the needed silent rules machinery for 'libtool --silent'.
1211 sub define_verbose_libtool ()
1212 {
1213     define_verbose_var ('lt', '--silent');
1214     return verbose_flag ('lt');
1215 }
1216
1217 sub handle_silent ()
1218 {
1219     # Define "$(AM_V_P)", expanding to a shell conditional that can be
1220     # used in make recipes to determine whether we are being run in
1221     # silent mode or not.  The choice of the name derives from the LISP
1222     # convention of appending the letter 'P' to denote a predicate (see
1223     # also "the '-P' convention" in the Jargon File); we do so for lack
1224     # of a better convention.
1225     define_verbose_var ('P', 'false', ':');
1226     # *Always* provide the user with '$(AM_V_GEN)', unconditionally.
1227     define_verbose_tagvar ('GEN');
1228     define_verbose_var ('at', '@');
1229 }
1230
1231
1232 ################################################################
1233
1234
1235 # Handle AUTOMAKE_OPTIONS variable.  Return 1 on error, 0 otherwise.
1236 sub handle_options
1237 {
1238   my $var = var ('AUTOMAKE_OPTIONS');
1239   if ($var)
1240     {
1241       if ($var->has_conditional_contents)
1242         {
1243           msg_var ('unsupported', $var,
1244                    "'AUTOMAKE_OPTIONS' cannot have conditional contents");
1245         }
1246       my @options = map { { option => $_->[1], where => $_->[0] } }
1247                         $var->value_as_list_recursive (cond_filter => TRUE,
1248                                                        location => 1);
1249       return 1 if process_option_list (@options);
1250     }
1251
1252   if ($strictness == GNITS)
1253     {
1254       set_option ('readme-alpha', INTERNAL);
1255       set_option ('std-options', INTERNAL);
1256       set_option ('check-news', INTERNAL);
1257     }
1258
1259   return 0;
1260 }
1261
1262 # shadow_unconditionally ($varname, $where)
1263 # -----------------------------------------
1264 # Return a $(variable) that contains all possible values
1265 # $varname can take.
1266 # If the VAR wasn't defined conditionally, return $(VAR).
1267 # Otherwise we create an am__VAR_DIST variable which contains
1268 # all possible values, and return $(am__VAR_DIST).
1269 sub shadow_unconditionally ($$)
1270 {
1271   my ($varname, $where) = @_;
1272   my $var = var $varname;
1273   if ($var->has_conditional_contents)
1274     {
1275       $varname = "am__${varname}_DIST";
1276       my @files = uniq ($var->value_as_list_recursive);
1277       define_pretty_variable ($varname, TRUE, $where, @files);
1278     }
1279   return "\$($varname)"
1280 }
1281
1282 # check_user_variables (@LIST)
1283 # ----------------------------
1284 # Make sure each variable VAR in @LIST does not exist, suggest using AM_VAR
1285 # otherwise.
1286 sub check_user_variables (@)
1287 {
1288   my @dont_override = @_;
1289   foreach my $flag (@dont_override)
1290     {
1291       my $var = var $flag;
1292       if ($var)
1293         {
1294           for my $cond ($var->conditions->conds)
1295             {
1296               if ($var->rdef ($cond)->owner == VAR_MAKEFILE)
1297                 {
1298                   msg_cond_var ('gnu', $cond, $flag,
1299                                 "'$flag' is a user variable, "
1300                                 . "you should not override it;\n"
1301                                 . "use 'AM_$flag' instead");
1302                 }
1303             }
1304         }
1305     }
1306 }
1307
1308 # Call finish function for each language that was used.
1309 sub handle_languages
1310 {
1311     if (! option 'no-dependencies')
1312     {
1313         # Include auto-dep code.  Don't include it if DEP_FILES would
1314         # be empty.
1315         if (keys %extension_seen && keys %dep_files)
1316         {
1317             # Set location of depcomp.
1318             &define_variable ('depcomp',
1319                               "\$(SHELL) $am_config_aux_dir/depcomp",
1320                               INTERNAL);
1321             &define_variable ('am__depfiles_maybe', 'depfiles', INTERNAL);
1322
1323             require_conf_file ("$am_file.am", FOREIGN, 'depcomp');
1324
1325             my @deplist = sort keys %dep_files;
1326             # Generate each 'include' individually.  Irix 6 make will
1327             # not properly include several files resulting from a
1328             # variable expansion; generating many separate includes
1329             # seems safest.
1330             $output_rules .= "\n";
1331             foreach my $iter (@deplist)
1332             {
1333                 $output_rules .= (subst ('AMDEP_TRUE')
1334                                   . subst ('am__include')
1335                                   . ' '
1336                                   . subst ('am__quote')
1337                                   . $iter
1338                                   . subst ('am__quote')
1339                                   . "\n");
1340             }
1341
1342             # Compute the set of directories to remove in distclean-depend.
1343             my @depdirs = uniq (map { dirname ($_) } @deplist);
1344             $output_rules .= &file_contents ('depend',
1345                                              new Automake::Location,
1346                                              DEPDIRS => "@depdirs");
1347         }
1348     }
1349     else
1350     {
1351         &define_variable ('depcomp', '', INTERNAL);
1352         &define_variable ('am__depfiles_maybe', '', INTERNAL);
1353     }
1354
1355     my %done;
1356
1357     # Is the C linker needed?
1358     my $needs_c = 0;
1359     foreach my $ext (sort keys %extension_seen)
1360     {
1361         next unless $extension_map{$ext};
1362
1363         my $lang = $languages{$extension_map{$ext}};
1364
1365         my $rule_file = $lang->rule_file || 'depend2';
1366
1367         # Get information on $LANG.
1368         my $pfx = $lang->autodep;
1369         my $fpfx = ($pfx eq '') ? 'CC' : $pfx;
1370
1371         my ($AMDEP, $FASTDEP) =
1372           (option 'no-dependencies' || $lang->autodep eq 'no')
1373           ? ('FALSE', 'FALSE') : ('AMDEP', "am__fastdep$fpfx");
1374
1375         my $verbose = verbose_flag ($lang->ccer || 'GEN');
1376         my $verbose_nodep = ($AMDEP eq 'FALSE')
1377           ? $verbose : verbose_nodep_flag ($lang->ccer || 'GEN');
1378         my $silent = silent_flag ();
1379
1380         my %transform = ('EXT'     => $ext,
1381                          'PFX'     => $pfx,
1382                          'FPFX'    => $fpfx,
1383                          'AMDEP'   => $AMDEP,
1384                          'FASTDEP' => $FASTDEP,
1385                          '-c'      => $lang->compile_flag || '',
1386                          # These are not used, but they need to be defined
1387                          # so &transform do not complain.
1388                          SUBDIROBJ     => 0,
1389                          'DERIVED-EXT' => 'BUG',
1390                          DIST_SOURCE   => 1,
1391                          VERBOSE   => $verbose,
1392                          'VERBOSE-NODEP' => $verbose_nodep,
1393                          SILENT    => $silent,
1394                         );
1395
1396         # Generate the appropriate rules for this extension.
1397         if (((! option 'no-dependencies') && $lang->autodep ne 'no')
1398             || defined $lang->compile)
1399         {
1400             # Some C compilers don't support -c -o.  Use it only if really
1401             # needed.
1402             my $output_flag = $lang->output_flag || '';
1403             $output_flag = '-o'
1404               if (! $output_flag
1405                   && $lang->name eq 'c'
1406                   && option 'subdir-objects');
1407
1408             # Compute a possible derived extension.
1409             # This is not used by depend2.am.
1410             my $der_ext = (&{$lang->output_extensions} ($ext))[0];
1411
1412             # When we output an inference rule like '.c.o:' we
1413             # have two cases to consider: either subdir-objects
1414             # is used, or it is not.
1415             #
1416             # In the latter case the rule is used to build objects
1417             # in the current directory, and dependencies always
1418             # go into './$(DEPDIR)/'.  We can hard-code this value.
1419             #
1420             # In the former case the rule can be used to build
1421             # objects in sub-directories too.  Dependencies should
1422             # go into the appropriate sub-directories, e.g.,
1423             # 'sub/$(DEPDIR)/'.  The value of this directory
1424             # needs to be computed on-the-fly.
1425             #
1426             # DEPBASE holds the name of this directory, plus the
1427             # basename part of the object file (extensions Po, TPo,
1428             # Plo, TPlo will be added later as appropriate).  It is
1429             # either hardcoded, or a shell variable ('$depbase') that
1430             # will be computed by the rule.
1431             my $depbase =
1432               option ('subdir-objects') ? '$$depbase' : '$(DEPDIR)/$*';
1433             $output_rules .=
1434               file_contents ($rule_file,
1435                              new Automake::Location,
1436                              %transform,
1437                              GENERIC   => 1,
1438
1439                              'DERIVED-EXT' => $der_ext,
1440
1441                              DEPBASE   => $depbase,
1442                              BASE      => '$*',
1443                              SOURCE    => '$<',
1444                              SOURCEFLAG => $sourceflags{$ext} || '',
1445                              OBJ       => '$@',
1446                              OBJOBJ    => '$@',
1447                              LTOBJ     => '$@',
1448
1449                              COMPILE   => '$(' . $lang->compiler . ')',
1450                              LTCOMPILE => '$(LT' . $lang->compiler . ')',
1451                              -o        => $output_flag,
1452                              SUBDIROBJ => !! option 'subdir-objects');
1453         }
1454
1455         # Now include code for each specially handled object with this
1456         # language.
1457         my %seen_files = ();
1458         foreach my $file (@{$lang_specific_files{$lang->name}})
1459         {
1460             my ($derived, $source, $obj, $myext, $srcext, %file_transform) = @$file;
1461
1462             # We might see a given object twice, for instance if it is
1463             # used under different conditions.
1464             next if defined $seen_files{$obj};
1465             $seen_files{$obj} = 1;
1466
1467             prog_error ("found " . $lang->name .
1468                         " in handle_languages, but compiler not defined")
1469               unless defined $lang->compile;
1470
1471             my $obj_compile = $lang->compile;
1472
1473             # Rewrite each occurrence of 'AM_$flag' in the compile
1474             # rule into '${derived}_$flag' if it exists.
1475             for my $flag (@{$lang->flags})
1476               {
1477                 my $val = "${derived}_$flag";
1478                 $obj_compile =~ s/\(AM_$flag\)/\($val\)/
1479                   if set_seen ($val);
1480               }
1481
1482             my $libtool_tag = '';
1483             if ($lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag})
1484               {
1485                 $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
1486               }
1487
1488             my $ptltflags = "${derived}_LIBTOOLFLAGS";
1489             $ptltflags = 'AM_LIBTOOLFLAGS' unless set_seen $ptltflags;
1490
1491             my $ltverbose = define_verbose_libtool ();
1492             my $obj_ltcompile =
1493               "\$(LIBTOOL) $ltverbose $libtool_tag\$($ptltflags) \$(LIBTOOLFLAGS) "
1494               . "--mode=compile $obj_compile";
1495
1496             # We _need_ '-o' for per object rules.
1497             my $output_flag = $lang->output_flag || '-o';
1498
1499             my $depbase = dirname ($obj);
1500             $depbase = ''
1501                 if $depbase eq '.';
1502             $depbase .= '/'
1503                 unless $depbase eq '';
1504             $depbase .= '$(DEPDIR)/' . basename ($obj);
1505
1506             $output_rules .=
1507               file_contents ($rule_file,
1508                              new Automake::Location,
1509                              %transform,
1510                              GENERIC   => 0,
1511
1512                              DEPBASE   => $depbase,
1513                              BASE      => $obj,
1514                              SOURCE    => $source,
1515                              SOURCEFLAG => $sourceflags{$srcext} || '',
1516                              # Use $myext and not '.o' here, in case
1517                              # we are actually building a new source
1518                              # file -- e.g. via yacc.
1519                              OBJ       => "$obj$myext",
1520                              OBJOBJ    => "$obj.obj",
1521                              LTOBJ     => "$obj.lo",
1522
1523                              VERBOSE   => $verbose,
1524                              'VERBOSE-NODEP'  => $verbose_nodep,
1525                              SILENT    => $silent,
1526                              COMPILE   => $obj_compile,
1527                              LTCOMPILE => $obj_ltcompile,
1528                              -o        => $output_flag,
1529                              %file_transform);
1530         }
1531
1532         # The rest of the loop is done once per language.
1533         next if defined $done{$lang};
1534         $done{$lang} = 1;
1535
1536         # Load the language dependent Makefile chunks.
1537         my %lang = map { uc ($_) => 0 } keys %languages;
1538         $lang{uc ($lang->name)} = 1;
1539         $output_rules .= file_contents ('lang-compile',
1540                                         new Automake::Location,
1541                                         %transform, %lang);
1542
1543         # If the source to a program consists entirely of code from a
1544         # 'pure' language, for instance C++ or Fortran 77, then we
1545         # don't need the C compiler code.  However if we run into
1546         # something unusual then we do generate the C code.  There are
1547         # probably corner cases here that do not work properly.
1548         # People linking Java code to Fortran code deserve pain.
1549         $needs_c ||= ! $lang->pure;
1550
1551         define_compiler_variable ($lang)
1552           if ($lang->compile);
1553
1554         define_linker_variable ($lang)
1555           if ($lang->link);
1556
1557         require_variables ("$am_file.am", $lang->Name . " source seen",
1558                            TRUE, @{$lang->config_vars});
1559
1560         # Call the finisher.
1561         $lang->finish;
1562
1563         # Flags listed in '->flags' are user variables (per GNU Standards),
1564         # they should not be overridden in the Makefile...
1565         my @dont_override = @{$lang->flags};
1566         # ... and so is LDFLAGS.
1567         push @dont_override, 'LDFLAGS' if $lang->link;
1568
1569         check_user_variables @dont_override;
1570     }
1571
1572     # If the project is entirely C++ or entirely Fortran 77 (i.e., 1
1573     # suffix rule was learned), don't bother with the C stuff.  But if
1574     # anything else creeps in, then use it.
1575     my @languages_seen = map { $languages{$extension_map{$_}}->name }
1576                              (keys %extension_seen);
1577     @languages_seen = uniq (@languages_seen);
1578     $needs_c = 1 if @languages_seen > 1;
1579     if ($need_link || $needs_c)
1580       {
1581         &define_compiler_variable ($languages{'c'})
1582           unless defined $done{$languages{'c'}};
1583         define_linker_variable ($languages{'c'});
1584       }
1585 }
1586
1587
1588 # append_exeext { PREDICATE } $MACRO
1589 # ----------------------------------
1590 # Append $(EXEEXT) to each filename in $F appearing in the Makefile
1591 # variable $MACRO if &PREDICATE($F) is true.  @substitutions@ are
1592 # ignored.
1593 #
1594 # This is typically used on all filenames of *_PROGRAMS, and filenames
1595 # of TESTS that are programs.
1596 sub append_exeext (&$)
1597 {
1598   my ($pred, $macro) = @_;
1599
1600   transform_variable_recursively
1601     ($macro, $macro, 'am__EXEEXT', 0, INTERNAL,
1602      sub {
1603        my ($subvar, $val, $cond, $full_cond) = @_;
1604        # Append $(EXEEXT) unless the user did it already, or it's a
1605        # @substitution@.
1606        $val .= '$(EXEEXT)'
1607          if $val !~ /(?:\$\(EXEEXT\)$|^[@]\w+[@]$)/ && &$pred ($val);
1608        return $val;
1609      });
1610 }
1611
1612
1613 # Check to make sure a source defined in LIBOBJS is not explicitly
1614 # mentioned.  This is a separate function (as opposed to being inlined
1615 # in handle_source_transform) because it isn't always appropriate to
1616 # do this check.
1617 sub check_libobjs_sources
1618 {
1619   my ($one_file, $unxformed) = @_;
1620
1621   foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
1622                       'dist_EXTRA_', 'nodist_EXTRA_')
1623     {
1624       my @files;
1625       my $varname = $prefix . $one_file . '_SOURCES';
1626       my $var = var ($varname);
1627       if ($var)
1628         {
1629           @files = $var->value_as_list_recursive;
1630         }
1631       elsif ($prefix eq '')
1632         {
1633           @files = ($unxformed . '.c');
1634         }
1635       else
1636         {
1637           next;
1638         }
1639
1640       foreach my $file (@files)
1641         {
1642           err_var ($prefix . $one_file . '_SOURCES',
1643                    "automatically discovered file '$file' should not" .
1644                    " be explicitly mentioned")
1645             if defined $libsources{$file};
1646         }
1647     }
1648 }
1649
1650
1651 # @OBJECTS
1652 # handle_single_transform ($VAR, $TOPPARENT, $DERIVED, $OBJ, $FILE, %TRANSFORM)
1653 # -----------------------------------------------------------------------------
1654 # Does much of the actual work for handle_source_transform.
1655 # Arguments are:
1656 #   $VAR is the name of the variable that the source filenames come from
1657 #   $TOPPARENT is the name of the _SOURCES variable which is being processed
1658 #   $DERIVED is the name of resulting executable or library
1659 #   $OBJ is the object extension (e.g., '.lo')
1660 #   $FILE the source file to transform
1661 #   %TRANSFORM contains extras arguments to pass to file_contents
1662 #     when producing explicit rules
1663 # Result is a list of the names of objects
1664 # %linkers_used will be updated with any linkers needed
1665 sub handle_single_transform ($$$$$%)
1666 {
1667     my ($var, $topparent, $derived, $obj, $_file, %transform) = @_;
1668     my @files = ($_file);
1669     my @result = ();
1670
1671     # Turn sources into objects.  We use a while loop like this
1672     # because we might add to @files in the loop.
1673     while (scalar @files > 0)
1674     {
1675         $_ = shift @files;
1676
1677         # Configure substitutions in _SOURCES variables are errors.
1678         if (/^\@.*\@$/)
1679         {
1680           my $parent_msg = '';
1681           $parent_msg = "\nand is referred to from '$topparent'"
1682             if $topparent ne $var->name;
1683           err_var ($var,
1684                    "'" . $var->name . "' includes configure substitution '$_'"
1685                    . $parent_msg . ";\nconfigure " .
1686                    "substitutions are not allowed in _SOURCES variables");
1687           next;
1688         }
1689
1690         # If the source file is in a subdirectory then the '.o' is put
1691         # into the current directory, unless the subdir-objects option
1692         # is in effect.
1693
1694         # Split file name into base and extension.
1695         next if ! /^(?:(.*)\/)?([^\/]*)($KNOWN_EXTENSIONS_PATTERN)$/;
1696         my $full = $_;
1697         my $directory = $1 || '';
1698         my $base = $2;
1699         my $extension = $3;
1700
1701         # We must generate a rule for the object if it requires its own flags.
1702         my $renamed = 0;
1703         my ($linker, $object);
1704
1705         # This records whether we've seen a derived source file (e.g.
1706         # yacc output).
1707         my $derived_source = 0;
1708
1709         # This holds the 'aggregate context' of the file we are
1710         # currently examining.  If the file is compiled with
1711         # per-object flags, then it will be the name of the object.
1712         # Otherwise it will be 'AM'.  This is used by the target hook
1713         # language function.
1714         my $aggregate = 'AM';
1715
1716         $extension = &derive_suffix ($extension, $obj);
1717         my $lang;
1718         if ($extension_map{$extension} &&
1719             ($lang = $languages{$extension_map{$extension}}))
1720         {
1721             # Found the language, so see what it says.
1722             &saw_extension ($extension);
1723
1724             # Do we have per-executable flags for this executable?
1725             my $have_per_exec_flags = 0;
1726             my @peflags = @{$lang->flags};
1727             push @peflags, 'LIBTOOLFLAGS' if $obj eq '.lo';
1728             foreach my $flag (@peflags)
1729               {
1730                 if (set_seen ("${derived}_$flag"))
1731                   {
1732                     $have_per_exec_flags = 1;
1733                     last;
1734                   }
1735               }
1736
1737             # Note: computed subr call.  The language rewrite function
1738             # should return one of the LANG_* constants.  It could
1739             # also return a list whose first value is such a constant
1740             # and whose second value is a new source extension which
1741             # should be applied.  This means this particular language
1742             # generates another source file which we must then process
1743             # further.
1744             my $subr = \&{'lang_' . $lang->name . '_rewrite'};
1745             defined &$subr or $subr = \&lang_sub_obj;
1746             my ($r, $source_extension)
1747                 = &$subr ($directory, $base, $extension,
1748                           $obj, $have_per_exec_flags, $var);
1749             # Skip this entry if we were asked not to process it.
1750             next if $r == LANG_IGNORE;
1751
1752             # Now extract linker and other info.
1753             $linker = $lang->linker;
1754
1755             my $this_obj_ext;
1756             if (defined $source_extension)
1757             {
1758                 $this_obj_ext = $source_extension;
1759                 $derived_source = 1;
1760             }
1761             else
1762             {
1763                 $this_obj_ext = $obj;
1764             }
1765             $object = $base . $this_obj_ext;
1766
1767             if ($have_per_exec_flags)
1768             {
1769                 # We have a per-executable flag in effect for this
1770                 # object.  In this case we rewrite the object's
1771                 # name to ensure it is unique.
1772
1773                 # We choose the name 'DERIVED_OBJECT' to ensure
1774                 # (1) uniqueness, and (2) continuity between
1775                 # invocations.  However, this will result in a
1776                 # name that is too long for losing systems, in
1777                 # some situations.  So we provide _SHORTNAME to
1778                 # override.
1779
1780                 my $dname = $derived;
1781                 my $var = var ($derived . '_SHORTNAME');
1782                 if ($var)
1783                 {
1784                     # FIXME: should use the same Condition as
1785                     # the _SOURCES variable.  But this is really
1786                     # silly overkill -- nobody should have
1787                     # conditional shortnames.
1788                     $dname = $var->variable_value;
1789                 }
1790                 $object = $dname . '-' . $object;
1791
1792                 prog_error ($lang->name . " flags defined without compiler")
1793                   if ! defined $lang->compile;
1794
1795                 $renamed = 1;
1796             }
1797
1798             # If rewrite said it was ok, put the object into a
1799             # subdir.
1800             if ($r == LANG_SUBDIR && $directory ne '')
1801             {
1802                 $object = $directory . '/' . $object;
1803             }
1804
1805             # If the object file has been renamed (because per-target
1806             # flags are used) we cannot compile the file with an
1807             # inference rule: we need an explicit rule.
1808             #
1809             # If the source is in a subdirectory and the object is in
1810             # the current directory, we also need an explicit rule.
1811             #
1812             # If both source and object files are in a subdirectory
1813             # (this happens when the subdir-objects option is used),
1814             # then the inference will work.
1815             #
1816             # The latter case deserves a historical note.  When the
1817             # subdir-objects option was added on 1999-04-11 it was
1818             # thought that inferences rules would work for
1819             # subdirectory objects too.  Later, on 1999-11-22,
1820             # automake was changed to output explicit rules even for
1821             # subdir-objects.  Nobody remembers why, but this occurred
1822             # soon after the merge of the user-dep-gen-branch so it
1823             # might be related.  In late 2003 people complained about
1824             # the size of the generated Makefile.ins (libgcj, with
1825             # 2200+ subdir objects was reported to have a 9MB
1826             # Makefile), so we now rely on inference rules again.
1827             # Maybe we'll run across the same issue as in the past,
1828             # but at least this time we can document it.  However since
1829             # dependency tracking has evolved it is possible that
1830             # our old problem no longer exists.
1831             # Using inference rules for subdir-objects has been tested
1832             # with GNU make, Solaris make, Ultrix make, BSD make,
1833             # HP-UX make, and OSF1 make successfully.
1834             if ($renamed
1835                 || ($directory ne '' && ! option 'subdir-objects')
1836                 # We must also use specific rules for a nodist_ source
1837                 # if its language requests it.
1838                 || ($lang->nodist_specific && ! $transform{'DIST_SOURCE'}))
1839             {
1840                 my $obj_sans_ext = substr ($object, 0,
1841                                            - length ($this_obj_ext));
1842                 my $full_ansi;
1843                 if ($directory ne '')
1844                   {
1845                         $full_ansi = $directory . '/' . $base . $extension;
1846                   }
1847                 else
1848                   {
1849                         $full_ansi = $base . $extension;
1850                   }
1851
1852                 my @specifics = ($full_ansi, $obj_sans_ext,
1853                                  # Only use $this_obj_ext in the derived
1854                                  # source case because in the other case we
1855                                  # *don't* want $(OBJEXT) to appear here.
1856                                  ($derived_source ? $this_obj_ext : '.o'),
1857                                  $extension);
1858
1859                 # If we renamed the object then we want to use the
1860                 # per-executable flag name.  But if this is simply a
1861                 # subdir build then we still want to use the AM_ flag
1862                 # name.
1863                 if ($renamed)
1864                   {
1865                     unshift @specifics, $derived;
1866                     $aggregate = $derived;
1867                   }
1868                 else
1869                   {
1870                     unshift @specifics, 'AM';
1871                   }
1872
1873                 # Each item on this list is a reference to a list consisting
1874                 # of four values followed by additional transform flags for
1875                 # file_contents.  The four values are the derived flag prefix
1876                 # (e.g. for 'foo_CFLAGS', it is 'foo'), the name of the
1877                 # source file, the base name of the output file, and
1878                 # the extension for the object file.
1879                 push (@{$lang_specific_files{$lang->name}},
1880                       [@specifics, %transform]);
1881             }
1882         }
1883         elsif ($extension eq $obj)
1884         {
1885             # This is probably the result of a direct suffix rule.
1886             # In this case we just accept the rewrite.
1887             $object = "$base$extension";
1888             $object = "$directory/$object" if $directory ne '';
1889             $linker = '';
1890         }
1891         else
1892         {
1893             # No error message here.  Used to have one, but it was
1894             # very unpopular.
1895             # FIXME: we could potentially do more processing here,
1896             # perhaps treating the new extension as though it were a
1897             # new source extension (as above).  This would require
1898             # more restructuring than is appropriate right now.
1899             next;
1900         }
1901
1902         err_am "object '$object' created by '$full' and '$object_map{$object}'"
1903           if (defined $object_map{$object}
1904               && $object_map{$object} ne $full);
1905
1906         my $comp_val = (($object =~ /\.lo$/)
1907                         ? COMPILE_LIBTOOL : COMPILE_ORDINARY);
1908         (my $comp_obj = $object) =~ s/\.lo$/.\$(OBJEXT)/;
1909         if (defined $object_compilation_map{$comp_obj}
1910             && $object_compilation_map{$comp_obj} != 0
1911             # Only see the error once.
1912             && ($object_compilation_map{$comp_obj}
1913                 != (COMPILE_LIBTOOL | COMPILE_ORDINARY))
1914             && $object_compilation_map{$comp_obj} != $comp_val)
1915           {
1916             err_am "object '$comp_obj' created both with libtool and without";
1917           }
1918         $object_compilation_map{$comp_obj} |= $comp_val;
1919
1920         if (defined $lang)
1921         {
1922             # Let the language do some special magic if required.
1923             $lang->target_hook ($aggregate, $object, $full, %transform);
1924         }
1925
1926         if ($derived_source)
1927           {
1928             prog_error ($lang->name . " has automatic dependency tracking")
1929               if $lang->autodep ne 'no';
1930             # Make sure this new source file is handled next.  That will
1931             # make it appear to be at the right place in the list.
1932             unshift (@files, $object);
1933             # Distribute derived sources unless the source they are
1934             # derived from is not.
1935             &push_dist_common ($object)
1936               unless ($topparent =~ /^(?:nobase_)?nodist_/);
1937             next;
1938           }
1939
1940         $linkers_used{$linker} = 1;
1941
1942         push (@result, $object);
1943
1944         if (! defined $object_map{$object})
1945         {
1946             my @dep_list = ();
1947             $object_map{$object} = $full;
1948
1949             # If resulting object is in subdir, we need to make
1950             # sure the subdir exists at build time.
1951             if ($object =~ /\//)
1952             {
1953                 # FIXME: check that $DIRECTORY is somewhere in the
1954                 # project
1955
1956                 # For Java, the way we're handling it right now, a
1957                 # '..' component doesn't make sense.
1958                 if ($lang && $lang->name eq 'java' && $object =~ /(\/|^)\.\.\//)
1959                   {
1960                     err_am "'$full' should not contain a '..' component";
1961                   }
1962
1963                 # Make sure *all* objects files in the subdirectory are
1964                 # removed by "make mostlyclean".  Not only this is more
1965                 # efficient than listing the object files to be removed
1966                 # individually (which would cause an 'rm' invocation for
1967                 # each of them -- very inefficient, see bug#10697), it
1968                 # would also leave stale object files in the subdirectory
1969                 # whenever a source file there is removed or renamed.
1970                 $compile_clean_files{"$directory/*.\$(OBJEXT)"} = MOSTLY_CLEAN;
1971                 if ($object =~ /\.lo$/)
1972                   {
1973                     # If we have a libtool object, then we also must remove
1974                     # any '.lo' objects in its same subdirectory.
1975                     $compile_clean_files{"$directory/*.lo"} = MOSTLY_CLEAN;
1976                     # Remember to cleanup .libs/ in this directory.
1977                     $libtool_clean_directories{$directory} = 1;
1978                   }
1979
1980                 push (@dep_list, require_build_directory ($directory));
1981
1982                 # If we're generating dependencies, we also want
1983                 # to make sure that the appropriate subdir of the
1984                 # .deps directory is created.
1985                 push (@dep_list,
1986                       require_build_directory ($directory . '/$(DEPDIR)'))
1987                   unless option 'no-dependencies';
1988             }
1989
1990             &pretty_print_rule ($object . ':', "\t", @dep_list)
1991                 if scalar @dep_list > 0;
1992         }
1993
1994         # Transform .o or $o file into .P file (for automatic
1995         # dependency code).
1996         # Properly flatten multiple adjacent slashes, as Solaris 10 make
1997         # might fail over them in an include statement.
1998         # Leading double slashes may be special, as per Posix, so deal
1999         # with them carefully.
2000         if ($lang && $lang->autodep ne 'no')
2001         {
2002             my $depfile = $object;
2003             $depfile =~ s/\.([^.]*)$/.P$1/;
2004             $depfile =~ s/\$\(OBJEXT\)$/o/;
2005             my $maybe_extra_leading_slash = '';
2006             $maybe_extra_leading_slash = '/' if $depfile =~ m,^//[^/],;
2007             $depfile =~ s,/+,/,g;
2008             my $basename = basename ($depfile);
2009             # This might make $dirname empty, but we account for that below.
2010             (my $dirname = dirname ($depfile)) =~ s/\/*$//;
2011             $dirname = $maybe_extra_leading_slash . $dirname;
2012             $dep_files{$dirname . '/$(DEPDIR)/' . $basename} = 1;
2013         }
2014     }
2015
2016     return @result;
2017 }
2018
2019
2020 # $LINKER
2021 # define_objects_from_sources ($VAR, $OBJVAR, $NODEFINE, $ONE_FILE,
2022 #                              $OBJ, $PARENT, $TOPPARENT, $WHERE, %TRANSFORM)
2023 # ---------------------------------------------------------------------------
2024 # Define an _OBJECTS variable for a _SOURCES variable (or subvariable)
2025 #
2026 # Arguments are:
2027 #   $VAR is the name of the _SOURCES variable
2028 #   $OBJVAR is the name of the _OBJECTS variable if known (otherwise
2029 #     it will be generated and returned).
2030 #   $NODEFINE is a boolean: if true, $OBJVAR will not be defined (but
2031 #     work done to determine the linker will be).
2032 #   $ONE_FILE is the canonical (transformed) name of object to build
2033 #   $OBJ is the object extension (i.e. either '.o' or '.lo').
2034 #   $TOPPARENT is the _SOURCES variable being processed.
2035 #   $WHERE context into which this definition is done
2036 #   %TRANSFORM extra arguments to pass to file_contents when producing
2037 #     rules
2038 #
2039 # Result is a pair ($LINKER, $OBJVAR):
2040 #    $LINKER is a boolean, true if a linker is needed to deal with the objects
2041 sub define_objects_from_sources ($$$$$$$%)
2042 {
2043   my ($var, $objvar, $nodefine, $one_file,
2044       $obj, $topparent, $where, %transform) = @_;
2045
2046   my $needlinker = "";
2047
2048   transform_variable_recursively
2049     ($var, $objvar, 'am__objects', $nodefine, $where,
2050      # The transform code to run on each filename.
2051      sub {
2052        my ($subvar, $val, $cond, $full_cond) = @_;
2053        my @trans = handle_single_transform ($subvar, $topparent,
2054                                             $one_file, $obj, $val,
2055                                             %transform);
2056        $needlinker = "true" if @trans;
2057        return @trans;
2058      });
2059
2060   return $needlinker;
2061 }
2062
2063
2064 # handle_source_transform ($CANON_TARGET, $TARGET, $OBJEXT, $WHERE, %TRANSFORM)
2065 # -----------------------------------------------------------------------------
2066 # Handle SOURCE->OBJECT transform for one program or library.
2067 # Arguments are:
2068 #   canonical (transformed) name of target to build
2069 #   actual target of object to build
2070 #   object extension (i.e., either '.o' or '$o')
2071 #   location of the source variable
2072 #   extra arguments to pass to file_contents when producing rules
2073 # Return the name of the linker variable that must be used.
2074 # Empty return means just use 'LINK'.
2075 sub handle_source_transform ($$$$%)
2076 {
2077     # one_file is canonical name.  unxformed is given name.  obj is
2078     # object extension.
2079     my ($one_file, $unxformed, $obj, $where, %transform) = @_;
2080
2081     my $linker = '';
2082
2083     # No point in continuing if _OBJECTS is defined.
2084     return if reject_var ($one_file . '_OBJECTS',
2085                           $one_file . '_OBJECTS should not be defined');
2086
2087     my %used_pfx = ();
2088     my $needlinker;
2089     %linkers_used = ();
2090     foreach my $prefix ('', 'EXTRA_', 'dist_', 'nodist_',
2091                         'dist_EXTRA_', 'nodist_EXTRA_')
2092     {
2093         my $varname = $prefix . $one_file . "_SOURCES";
2094         my $var = var $varname;
2095         next unless $var;
2096
2097         # We are going to define _OBJECTS variables using the prefix.
2098         # Then we glom them all together.  So we can't use the null
2099         # prefix here as we need it later.
2100         my $xpfx = ($prefix eq '') ? 'am_' : $prefix;
2101
2102         # Keep track of which prefixes we saw.
2103         $used_pfx{$xpfx} = 1
2104           unless $prefix =~ /EXTRA_/;
2105
2106         push @sources, "\$($varname)";
2107         push @dist_sources, shadow_unconditionally ($varname, $where)
2108           unless (option ('no-dist') || $prefix =~ /^nodist_/);
2109
2110         $needlinker |=
2111             define_objects_from_sources ($varname,
2112                                          $xpfx . $one_file . '_OBJECTS',
2113                                          $prefix =~ /EXTRA_/,
2114                                          $one_file, $obj, $varname, $where,
2115                                          DIST_SOURCE => ($prefix !~ /^nodist_/),
2116                                          %transform);
2117     }
2118     if ($needlinker)
2119     {
2120         $linker ||= &resolve_linker (%linkers_used);
2121     }
2122
2123     my @keys = sort keys %used_pfx;
2124     if (scalar @keys == 0)
2125     {
2126         # The default source for libfoo.la is libfoo.c, but for
2127         # backward compatibility we first look at libfoo_la.c,
2128         # if no default source suffix is given.
2129         my $old_default_source = "$one_file.c";
2130         my $ext_var = var ('AM_DEFAULT_SOURCE_EXT');
2131         my $default_source_ext = $ext_var ? variable_value ($ext_var) : '.c';
2132         msg_var ('unsupported', $ext_var, $ext_var->name . " can assume at most one value")
2133           if $default_source_ext =~ /[\t ]/;
2134         (my $default_source = $unxformed) =~ s,(\.[^./\\]*)?$,$default_source_ext,;
2135         # TODO: Remove this backward-compatibility hack in Automake 2.0.
2136         if ($old_default_source ne $default_source
2137             && !$ext_var
2138             && (rule $old_default_source
2139                 || rule '$(srcdir)/' . $old_default_source
2140                 || rule '${srcdir}/' . $old_default_source
2141                 || -f $old_default_source))
2142           {
2143             my $loc = $where->clone;
2144             $loc->pop_context;
2145             msg ('obsolete', $loc,
2146                  "the default source for '$unxformed' has been changed "
2147                  . "to '$default_source'.\n(Using '$old_default_source' for "
2148                  . "backward compatibility.)");
2149             $default_source = $old_default_source;
2150           }
2151         # If a rule exists to build this source with a $(srcdir)
2152         # prefix, use that prefix in our variables too.  This is for
2153         # the sake of BSD Make.
2154         if (rule '$(srcdir)/' . $default_source
2155             || rule '${srcdir}/' . $default_source)
2156           {
2157             $default_source = '$(srcdir)/' . $default_source;
2158           }
2159
2160         &define_variable ($one_file . "_SOURCES", $default_source, $where);
2161         push (@sources, $default_source);
2162         push (@dist_sources, $default_source);
2163
2164         %linkers_used = ();
2165         my (@result) =
2166           handle_single_transform ($one_file . '_SOURCES',
2167                                    $one_file . '_SOURCES',
2168                                    $one_file, $obj,
2169                                    $default_source, %transform);
2170         $linker ||= &resolve_linker (%linkers_used);
2171         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @result);
2172     }
2173     else
2174     {
2175         @keys = map { '$(' . $_ . $one_file . '_OBJECTS)' } @keys;
2176         define_pretty_variable ($one_file . '_OBJECTS', TRUE, $where, @keys);
2177     }
2178
2179     # If we want to use 'LINK' we must make sure it is defined.
2180     if ($linker eq '')
2181     {
2182         $need_link = 1;
2183     }
2184
2185     return $linker;
2186 }
2187
2188
2189 # handle_lib_objects ($XNAME, $VAR)
2190 # ---------------------------------
2191 # Special-case ALLOCA and LIBOBJS substitutions in _LDADD or _LIBADD variables.
2192 # Also, generate _DEPENDENCIES variable if appropriate.
2193 # Arguments are:
2194 #   transformed name of object being built, or empty string if no object
2195 #   name of _LDADD/_LIBADD-type variable to examine
2196 # Returns 1 if LIBOBJS seen, 0 otherwise.
2197 sub handle_lib_objects
2198 {
2199   my ($xname, $varname) = @_;
2200
2201   my $var = var ($varname);
2202   prog_error "'$varname' undefined"
2203     unless $var;
2204   prog_error "unexpected variable name '$varname'"
2205     unless $varname =~ /^(.*)(?:LIB|LD)ADD$/;
2206   my $prefix = $1 || 'AM_';
2207
2208   my $seen_libobjs = 0;
2209   my $flagvar = 0;
2210
2211   transform_variable_recursively
2212     ($varname, $xname . '_DEPENDENCIES', 'am__DEPENDENCIES',
2213      ! $xname, INTERNAL,
2214      # Transformation function, run on each filename.
2215      sub {
2216        my ($subvar, $val, $cond, $full_cond) = @_;
2217
2218        if ($val =~ /^-/)
2219          {
2220            # Skip -lfoo and -Ldir silently; these are explicitly allowed.
2221            if ($val !~ /^-[lL]/ &&
2222                # Skip -dlopen and -dlpreopen; these are explicitly allowed
2223                # for Libtool libraries or programs.  (Actually we are a bit
2224                # lax here since this code also applies to non-libtool
2225                # libraries or programs, for which -dlopen and -dlopreopen
2226                # are pure nonsense.  Diagnosing this doesn't seem very
2227                # important: the developer will quickly get complaints from
2228                # the linker.)
2229                $val !~ /^-dl(?:pre)?open$/ &&
2230                # Only get this error once.
2231                ! $flagvar)
2232              {
2233                $flagvar = 1;
2234                # FIXME: should display a stack of nested variables
2235                # as context when $var != $subvar.
2236                err_var ($var, "linker flags such as '$val' belong in "
2237                         . "'${prefix}LDFLAGS'");
2238              }
2239            return ();
2240          }
2241        elsif ($val !~ /^\@.*\@$/)
2242          {
2243            # Assume we have a file of some sort, and output it into the
2244            # dependency variable.  Autoconf substitutions are not output;
2245            # rarely is a new dependency substituted into e.g. foo_LDADD
2246            # -- but bad things (e.g. -lX11) are routinely substituted.
2247            # Note that LIBOBJS and ALLOCA are exceptions to this rule,
2248            # and handled specially below.
2249            return $val;
2250          }
2251        elsif ($val =~ /^\@(LT)?LIBOBJS\@$/)
2252          {
2253            handle_LIBOBJS ($subvar, $cond, $1);
2254            $seen_libobjs = 1;
2255            return $val;
2256          }
2257        elsif ($val =~ /^\@(LT)?ALLOCA\@$/)
2258          {
2259            handle_ALLOCA ($subvar, $cond, $1);
2260            return $val;
2261          }
2262        else
2263          {
2264            return ();
2265          }
2266      });
2267
2268   return $seen_libobjs;
2269 }
2270
2271 # handle_LIBOBJS_or_ALLOCA ($VAR)
2272 # -------------------------------
2273 # Definitions common to LIBOBJS and ALLOCA.
2274 # VAR should be one of LIBOBJS, LTLIBOBJS, ALLOCA, or LTALLOCA.
2275 sub handle_LIBOBJS_or_ALLOCA ($)
2276 {
2277   my ($var) = @_;
2278
2279   my $dir = '';
2280
2281   # If LIBOBJS files must be built in another directory we have
2282   # to define LIBOBJDIR and ensure the files get cleaned.
2283   # Otherwise LIBOBJDIR can be left undefined, and the cleaning
2284   # is achieved by 'rm -f *.$(OBJEXT)' in compile.am.
2285   if ($config_libobj_dir
2286       && $relative_dir ne $config_libobj_dir)
2287     {
2288       if (option 'subdir-objects')
2289         {
2290           # In the top-level Makefile we do not use $(top_builddir), because
2291           # we are already there, and since the targets are built without
2292           # a $(top_builddir), it helps BSD Make to match them with
2293           # dependencies.
2294           $dir = "$config_libobj_dir/"
2295             if $config_libobj_dir ne '.';
2296           $dir = backname ($relative_dir) . "/$dir"
2297             if $relative_dir ne '.';
2298           define_variable ('LIBOBJDIR', "$dir", INTERNAL);
2299           $clean_files{"\$($var)"} = MOSTLY_CLEAN;
2300           # If LTLIBOBJS is used, we must also clear LIBOBJS (which might
2301           # be created by libtool as a side-effect of creating LTLIBOBJS).
2302           $clean_files{"\$($var)"} = MOSTLY_CLEAN if $var =~ s/^LT//;
2303         }
2304       else
2305         {
2306           error ("'\$($var)' cannot be used outside '$config_libobj_dir' if"
2307                  . " 'subdir-objects' is not set");
2308         }
2309     }
2310
2311   return $dir;
2312 }
2313
2314 sub handle_LIBOBJS ($$$)
2315 {
2316   my ($var, $cond, $lt) = @_;
2317   my $myobjext = $lt ? 'lo' : 'o';
2318   $lt ||= '';
2319
2320   $var->requires_variables ("\@${lt}LIBOBJS\@ used", $lt . 'LIBOBJS')
2321     if ! keys %libsources;
2322
2323   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}LIBOBJS";
2324
2325   foreach my $iter (keys %libsources)
2326     {
2327       if ($iter =~ /\.[cly]$/)
2328         {
2329           &saw_extension ($&);
2330           &saw_extension ('.c');
2331         }
2332
2333       if ($iter =~ /\.h$/)
2334         {
2335           require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2336         }
2337       elsif ($iter ne 'alloca.c')
2338         {
2339           my $rewrite = $iter;
2340           $rewrite =~ s/\.c$/.P$myobjext/;
2341           $dep_files{$dir . '$(DEPDIR)/' . $rewrite} = 1;
2342           $rewrite = "^" . quotemeta ($iter) . "\$";
2343           # Only require the file if it is not a built source.
2344           my $bs = var ('BUILT_SOURCES');
2345           if (! $bs || ! grep (/$rewrite/, $bs->value_as_list_recursive))
2346             {
2347               require_libsource_with_macro ($cond, $var, FOREIGN, $iter);
2348             }
2349         }
2350     }
2351 }
2352
2353 sub handle_ALLOCA ($$$)
2354 {
2355   my ($var, $cond, $lt) = @_;
2356   my $myobjext = $lt ? 'lo' : 'o';
2357   $lt ||= '';
2358   my $dir = handle_LIBOBJS_or_ALLOCA "${lt}ALLOCA";
2359
2360   $var->requires_variables ("\@${lt}ALLOCA\@ used", $lt . 'ALLOCA');
2361   $dep_files{$dir . '$(DEPDIR)/alloca.P' . $myobjext} = 1;
2362   require_libsource_with_macro ($cond, $var, FOREIGN, 'alloca.c');
2363   &saw_extension ('.c');
2364 }
2365
2366 # Canonicalize the input parameter
2367 sub canonicalize
2368 {
2369     my ($string) = @_;
2370     $string =~ tr/A-Za-z0-9_\@/_/c;
2371     return $string;
2372 }
2373
2374 # Canonicalize a name, and check to make sure the non-canonical name
2375 # is never used.  Returns canonical name.  Arguments are name and a
2376 # list of suffixes to check for.
2377 sub check_canonical_spelling
2378 {
2379   my ($name, @suffixes) = @_;
2380
2381   my $xname = &canonicalize ($name);
2382   if ($xname ne $name)
2383     {
2384       foreach my $xt (@suffixes)
2385         {
2386           reject_var ("$name$xt", "use '$xname$xt', not '$name$xt'");
2387         }
2388     }
2389
2390   return $xname;
2391 }
2392
2393
2394 # handle_compile ()
2395 # -----------------
2396 # Set up the compile suite.
2397 sub handle_compile ()
2398 {
2399    return if ! $must_handle_compiled_objects;
2400
2401     # Boilerplate.
2402     my $default_includes = '';
2403     if (! option 'nostdinc')
2404       {
2405         my @incs = ('-I.', subst ('am__isrc'));
2406
2407         my $var = var 'CONFIG_HEADER';
2408         if ($var)
2409           {
2410             foreach my $hdr (split (' ', $var->variable_value))
2411               {
2412                 push @incs, '-I' . dirname ($hdr);
2413               }
2414           }
2415         # We want '-I. -I$(srcdir)', but the latter -I is redundant
2416         # and unaesthetic in non-VPATH builds.  We use `-I.@am__isrc@`
2417         # instead.  It will be replaced by '-I.' or '-I. -I$(srcdir)'.
2418         # Items in CONFIG_HEADER are never in $(srcdir) so it is safe
2419         # to just put @am__isrc@ right after '-I.', without a space.
2420         ($default_includes = ' ' . uniq (@incs)) =~ s/ @/@/;
2421       }
2422
2423     my (@mostly_rms, @dist_rms);
2424     foreach my $item (sort keys %compile_clean_files)
2425     {
2426         if ($compile_clean_files{$item} == MOSTLY_CLEAN)
2427         {
2428             push (@mostly_rms, "\t-rm -f $item");
2429         }
2430         elsif ($compile_clean_files{$item} == DIST_CLEAN)
2431         {
2432             push (@dist_rms, "\t-rm -f $item");
2433         }
2434         else
2435         {
2436           prog_error 'invalid entry in %compile_clean_files';
2437         }
2438     }
2439
2440     my ($coms, $vars, $rules) =
2441       &file_contents_internal (1, "$libdir/am/compile.am",
2442                                new Automake::Location,
2443                                ('DEFAULT_INCLUDES' => $default_includes,
2444                                 'MOSTLYRMS' => join ("\n", @mostly_rms),
2445                                 'DISTRMS' => join ("\n", @dist_rms)));
2446     $output_vars .= $vars;
2447     $output_rules .= "$coms$rules";
2448 }
2449
2450 # handle_libtool ()
2451 # -----------------
2452 # Handle libtool rules.
2453 sub handle_libtool
2454 {
2455   return unless var ('LIBTOOL');
2456
2457   # Libtool requires some files, but only at top level.
2458   # (Starting with Libtool 2.0 we do not have to bother.  These
2459   # requirements are done with AC_REQUIRE_AUX_FILE.)
2460   require_conf_file_with_macro (TRUE, 'LIBTOOL', FOREIGN, @libtool_files)
2461     if $relative_dir eq '.' && ! $libtool_new_api;
2462
2463   my @libtool_rms;
2464   foreach my $item (sort keys %libtool_clean_directories)
2465     {
2466       my $dir = ($item eq '.') ? '' : "$item/";
2467       # .libs is for Unix, _libs for DOS.
2468       push (@libtool_rms, "\t-rm -rf ${dir}.libs ${dir}_libs");
2469     }
2470
2471   check_user_variables 'LIBTOOLFLAGS';
2472
2473   # Output the libtool compilation rules.
2474   $output_rules .= &file_contents ('libtool',
2475                                    new Automake::Location,
2476                                    LTRMS => join ("\n", @libtool_rms));
2477 }
2478
2479 # handle_programs ()
2480 # ------------------
2481 # Handle C programs.
2482 sub handle_programs
2483 {
2484   my @proglist = &am_install_var ('progs', 'PROGRAMS',
2485                                   'bin', 'sbin', 'libexec', 'pkglibexec',
2486                                   'noinst', 'check');
2487   return if ! @proglist;
2488   $must_handle_compiled_objects = 1;
2489
2490   my $seen_global_libobjs =
2491     var ('LDADD') && &handle_lib_objects ('', 'LDADD');
2492
2493   foreach my $pair (@proglist)
2494     {
2495       my ($where, $one_file) = @$pair;
2496
2497       my $seen_libobjs = 0;
2498       my $obj = '.$(OBJEXT)';
2499
2500       $known_programs{$one_file} = $where;
2501
2502       # Canonicalize names and check for misspellings.
2503       my $xname = &check_canonical_spelling ($one_file, '_LDADD', '_LDFLAGS',
2504                                              '_SOURCES', '_OBJECTS',
2505                                              '_DEPENDENCIES');
2506
2507       $where->push_context ("while processing program '$one_file'");
2508       $where->set (INTERNAL->get);
2509
2510       my $linker = &handle_source_transform ($xname, $one_file, $obj, $where,
2511                                              NONLIBTOOL => 1, LIBTOOL => 0);
2512
2513       if (var ($xname . "_LDADD"))
2514         {
2515           $seen_libobjs = &handle_lib_objects ($xname, $xname . '_LDADD');
2516         }
2517       else
2518         {
2519           # User didn't define prog_LDADD override.  So do it.
2520           &define_variable ($xname . '_LDADD', '$(LDADD)', $where);
2521
2522           # This does a bit too much work.  But we need it to
2523           # generate _DEPENDENCIES when appropriate.
2524           if (var ('LDADD'))
2525             {
2526               $seen_libobjs = &handle_lib_objects ($xname, 'LDADD');
2527             }
2528         }
2529
2530       reject_var ($xname . '_LIBADD',
2531                   "use '${xname}_LDADD', not '${xname}_LIBADD'");
2532
2533       set_seen ($xname . '_DEPENDENCIES');
2534       set_seen ('EXTRA_' . $xname . '_DEPENDENCIES');
2535       set_seen ($xname . '_LDFLAGS');
2536
2537       # Determine program to use for link.
2538       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xname);
2539       $vlink = verbose_flag ($vlink || 'GEN');
2540
2541       # If the resulting program lies in a subdirectory,
2542       # ensure that the directory exists before we need it.
2543       my $dirstamp = require_build_directory_maybe ($one_file);
2544
2545       $libtool_clean_directories{dirname ($one_file)} = 1;
2546
2547       $output_rules .= &file_contents ('program',
2548                                        $where,
2549                                        PROGRAM  => $one_file,
2550                                        XPROGRAM => $xname,
2551                                        XLINK    => $xlink,
2552                                        VERBOSE  => $vlink,
2553                                        DIRSTAMP => $dirstamp,
2554                                        EXEEXT   => '$(EXEEXT)');
2555
2556       if ($seen_libobjs || $seen_global_libobjs)
2557         {
2558           if (var ($xname . '_LDADD'))
2559             {
2560               &check_libobjs_sources ($xname, $xname . '_LDADD');
2561             }
2562           elsif (var ('LDADD'))
2563             {
2564               &check_libobjs_sources ($xname, 'LDADD');
2565             }
2566         }
2567     }
2568 }
2569
2570
2571 # handle_libraries ()
2572 # -------------------
2573 # Handle libraries.
2574 sub handle_libraries
2575 {
2576   my @liblist = &am_install_var ('libs', 'LIBRARIES',
2577                                  'lib', 'pkglib', 'noinst', 'check');
2578   return if ! @liblist;
2579   $must_handle_compiled_objects = 1;
2580
2581   my @prefix = am_primary_prefixes ('LIBRARIES', 0, 'lib', 'pkglib',
2582                                     'noinst', 'check');
2583
2584   if (@prefix)
2585     {
2586       my $var = rvar ($prefix[0] . '_LIBRARIES');
2587       $var->requires_variables ('library used', 'RANLIB');
2588     }
2589
2590   &define_variable ('AR', 'ar', INTERNAL);
2591   &define_variable ('ARFLAGS', 'cru', INTERNAL);
2592   &define_verbose_tagvar ('AR');
2593
2594   foreach my $pair (@liblist)
2595     {
2596       my ($where, $onelib) = @$pair;
2597
2598       my $seen_libobjs = 0;
2599       # Check that the library fits the standard naming convention.
2600       my $bn = basename ($onelib);
2601       if ($bn !~ /^lib.*\.a$/)
2602         {
2603           $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.a/;
2604           my $suggestion = dirname ($onelib) . "/$bn";
2605           $suggestion =~ s|^\./||g;
2606           msg ('error-gnu/warn', $where,
2607                "'$onelib' is not a standard library name\n"
2608                . "did you mean '$suggestion'?")
2609         }
2610
2611       ($known_libraries{$onelib} = $bn) =~ s/\.a$//;
2612
2613       $where->push_context ("while processing library '$onelib'");
2614       $where->set (INTERNAL->get);
2615
2616       my $obj = '.$(OBJEXT)';
2617
2618       # Canonicalize names and check for misspellings.
2619       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_SOURCES',
2620                                             '_OBJECTS', '_DEPENDENCIES',
2621                                             '_AR');
2622
2623       if (! var ($xlib . '_AR'))
2624         {
2625           &define_variable ($xlib . '_AR', '$(AR) $(ARFLAGS)', $where);
2626         }
2627
2628       # Generate support for conditional object inclusion in
2629       # libraries.
2630       if (var ($xlib . '_LIBADD'))
2631         {
2632           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2633             {
2634               $seen_libobjs = 1;
2635             }
2636         }
2637       else
2638         {
2639           &define_variable ($xlib . "_LIBADD", '', $where);
2640         }
2641
2642       reject_var ($xlib . '_LDADD',
2643                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2644
2645       # Make sure we at look at this.
2646       set_seen ($xlib . '_DEPENDENCIES');
2647       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2648
2649       &handle_source_transform ($xlib, $onelib, $obj, $where,
2650                                 NONLIBTOOL => 1, LIBTOOL => 0);
2651
2652       # If the resulting library lies in a subdirectory,
2653       # make sure this directory will exist.
2654       my $dirstamp = require_build_directory_maybe ($onelib);
2655       my $verbose = verbose_flag ('AR');
2656       my $silent = silent_flag ();
2657
2658       $output_rules .= &file_contents ('library',
2659                                        $where,
2660                                        VERBOSE  => $verbose,
2661                                        SILENT   => $silent,
2662                                        LIBRARY  => $onelib,
2663                                        XLIBRARY => $xlib,
2664                                        DIRSTAMP => $dirstamp);
2665
2666       if ($seen_libobjs)
2667         {
2668           if (var ($xlib . '_LIBADD'))
2669             {
2670               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2671             }
2672         }
2673
2674       if (! $seen_ar)
2675         {
2676           msg ('extra-portability', $where,
2677                "'$onelib': linking libraries using a non-POSIX\n"
2678                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2679         }
2680     }
2681 }
2682
2683
2684 # handle_ltlibraries ()
2685 # ---------------------
2686 # Handle shared libraries.
2687 sub handle_ltlibraries
2688 {
2689   my @liblist = &am_install_var ('ltlib', 'LTLIBRARIES',
2690                                  'noinst', 'lib', 'pkglib', 'check');
2691   return if ! @liblist;
2692   $must_handle_compiled_objects = 1;
2693
2694   my @prefix = am_primary_prefixes ('LTLIBRARIES', 0, 'lib', 'pkglib',
2695                                     'noinst', 'check');
2696
2697   if (@prefix)
2698     {
2699       my $var = rvar ($prefix[0] . '_LTLIBRARIES');
2700       $var->requires_variables ('Libtool library used', 'LIBTOOL');
2701     }
2702
2703   my %instdirs = ();
2704   my %instsubdirs = ();
2705   my %instconds = ();
2706   my %liblocations = ();        # Location (in Makefile.am) of each library.
2707
2708   foreach my $key (@prefix)
2709     {
2710       # Get the installation directory of each library.
2711       my $dir = $key;
2712       my $strip_subdir = 1;
2713       if ($dir =~ /^nobase_/)
2714         {
2715           $dir =~ s/^nobase_//;
2716           $strip_subdir = 0;
2717         }
2718       my $var = rvar ($key . '_LTLIBRARIES');
2719
2720       # We reject libraries which are installed in several places
2721       # in the same condition, because we can only specify one
2722       # '-rpath' option.
2723       $var->traverse_recursively
2724         (sub
2725          {
2726            my ($var, $val, $cond, $full_cond) = @_;
2727            my $hcond = $full_cond->human;
2728            my $where = $var->rdef ($cond)->location;
2729            my $ldir = '';
2730            $ldir = '/' . dirname ($val)
2731              if (!$strip_subdir);
2732            # A library cannot be installed in different directories
2733            # in overlapping conditions.
2734            if (exists $instconds{$val})
2735              {
2736                my ($msg, $acond) =
2737                  $instconds{$val}->ambiguous_p ($val, $full_cond);
2738
2739                if ($msg)
2740                  {
2741                    error ($where, $msg, partial => 1);
2742                    my $dirtxt = "installed " . ($strip_subdir ? "in" : "below") . " '$dir'";
2743                    $dirtxt = "built for '$dir'"
2744                      if $dir eq 'EXTRA' || $dir eq 'noinst' || $dir eq 'check';
2745                    my $dircond =
2746                      $full_cond->true ? "" : " in condition $hcond";
2747
2748                    error ($where, "'$val' should be $dirtxt$dircond ...",
2749                           partial => 1);
2750
2751                    my $hacond = $acond->human;
2752                    my $adir = $instdirs{$val}{$acond};
2753                    my $adirtxt = "installed in '$adir'";
2754                    $adirtxt = "built for '$adir'"
2755                      if ($adir eq 'EXTRA' || $adir eq 'noinst'
2756                          || $adir eq 'check');
2757                    my $adircond = $acond->true ? "" : " in condition $hacond";
2758
2759                    my $onlyone = ($dir ne $adir) ?
2760                      ("\nLibtool libraries can be built for only one "
2761                       . "destination") : "";
2762
2763                    error ($liblocations{$val}{$acond},
2764                           "... and should also be $adirtxt$adircond.$onlyone");
2765                    return;
2766                  }
2767              }
2768            else
2769              {
2770                $instconds{$val} = new Automake::DisjConditions;
2771              }
2772            $instdirs{$val}{$full_cond} = $dir;
2773            $instsubdirs{$val}{$full_cond} = $ldir;
2774            $liblocations{$val}{$full_cond} = $where;
2775            $instconds{$val} = $instconds{$val}->merge ($full_cond);
2776          },
2777          sub
2778          {
2779            return ();
2780          },
2781          skip_ac_subst => 1);
2782     }
2783
2784   foreach my $pair (@liblist)
2785     {
2786       my ($where, $onelib) = @$pair;
2787
2788       my $seen_libobjs = 0;
2789       my $obj = '.lo';
2790
2791       # Canonicalize names and check for misspellings.
2792       my $xlib = &check_canonical_spelling ($onelib, '_LIBADD', '_LDFLAGS',
2793                                             '_SOURCES', '_OBJECTS',
2794                                             '_DEPENDENCIES');
2795
2796       # Check that the library fits the standard naming convention.
2797       my $libname_rx = '^lib.*\.la';
2798       my $ldvar = var ("${xlib}_LDFLAGS") || var ('AM_LDFLAGS');
2799       my $ldvar2 = var ('LDFLAGS');
2800       if (($ldvar && grep (/-module/, $ldvar->value_as_list_recursive))
2801           || ($ldvar2 && grep (/-module/, $ldvar2->value_as_list_recursive)))
2802         {
2803           # Relax name checking for libtool modules.
2804           $libname_rx = '\.la';
2805         }
2806
2807       my $bn = basename ($onelib);
2808       if ($bn !~ /$libname_rx$/)
2809         {
2810           my $type = 'library';
2811           if ($libname_rx eq '\.la')
2812             {
2813               $bn =~ s/^(lib|)(.*?)(?:\.[^.]*)?$/$1$2.la/;
2814               $type = 'module';
2815             }
2816           else
2817             {
2818               $bn =~ s/^(?:lib)?(.*?)(?:\.[^.]*)?$/lib$1.la/;
2819             }
2820           my $suggestion = dirname ($onelib) . "/$bn";
2821           $suggestion =~ s|^\./||g;
2822           msg ('error-gnu/warn', $where,
2823                "'$onelib' is not a standard libtool $type name\n"
2824                . "did you mean '$suggestion'?")
2825         }
2826
2827       ($known_libraries{$onelib} = $bn) =~ s/\.la$//;
2828
2829       $where->push_context ("while processing Libtool library '$onelib'");
2830       $where->set (INTERNAL->get);
2831
2832       # Make sure we look at these.
2833       set_seen ($xlib . '_LDFLAGS');
2834       set_seen ($xlib . '_DEPENDENCIES');
2835       set_seen ('EXTRA_' . $xlib . '_DEPENDENCIES');
2836
2837       # Generate support for conditional object inclusion in
2838       # libraries.
2839       if (var ($xlib . '_LIBADD'))
2840         {
2841           if (&handle_lib_objects ($xlib, $xlib . '_LIBADD'))
2842             {
2843               $seen_libobjs = 1;
2844             }
2845         }
2846       else
2847         {
2848           &define_variable ($xlib . "_LIBADD", '', $where);
2849         }
2850
2851       reject_var ("${xlib}_LDADD",
2852                   "use '${xlib}_LIBADD', not '${xlib}_LDADD'");
2853
2854
2855       my $linker = &handle_source_transform ($xlib, $onelib, $obj, $where,
2856                                              NONLIBTOOL => 0, LIBTOOL => 1);
2857
2858       # Determine program to use for link.
2859       my($xlink, $vlink) = &define_per_target_linker_variable ($linker, $xlib);
2860       $vlink = verbose_flag ($vlink || 'GEN');
2861
2862       my $rpathvar = "am_${xlib}_rpath";
2863       my $rpath = "\$($rpathvar)";
2864       foreach my $rcond ($instconds{$onelib}->conds)
2865         {
2866           my $val;
2867           if ($instdirs{$onelib}{$rcond} eq 'EXTRA'
2868               || $instdirs{$onelib}{$rcond} eq 'noinst'
2869               || $instdirs{$onelib}{$rcond} eq 'check')
2870             {
2871               # It's an EXTRA_ library, so we can't specify -rpath,
2872               # because we don't know where the library will end up.
2873               # The user probably knows, but generally speaking automake
2874               # doesn't -- and in fact configure could decide
2875               # dynamically between two different locations.
2876               $val = '';
2877             }
2878           else
2879             {
2880               $val = ('-rpath $(' . $instdirs{$onelib}{$rcond} . 'dir)');
2881               $val .= $instsubdirs{$onelib}{$rcond}
2882                 if defined $instsubdirs{$onelib}{$rcond};
2883             }
2884           if ($rcond->true)
2885             {
2886               # If $rcond is true there is only one condition and
2887               # there is no point defining an helper variable.
2888               $rpath = $val;
2889             }
2890           else
2891             {
2892               define_pretty_variable ($rpathvar, $rcond, INTERNAL, $val);
2893             }
2894         }
2895
2896       # If the resulting library lies in a subdirectory,
2897       # make sure this directory will exist.
2898       my $dirstamp = require_build_directory_maybe ($onelib);
2899
2900       # Remember to cleanup .libs/ in this directory.
2901       my $dirname = dirname $onelib;
2902       $libtool_clean_directories{$dirname} = 1;
2903
2904       $output_rules .= &file_contents ('ltlibrary',
2905                                        $where,
2906                                        LTLIBRARY  => $onelib,
2907                                        XLTLIBRARY => $xlib,
2908                                        RPATH      => $rpath,
2909                                        XLINK      => $xlink,
2910                                        VERBOSE    => $vlink,
2911                                        DIRSTAMP   => $dirstamp);
2912       if ($seen_libobjs)
2913         {
2914           if (var ($xlib . '_LIBADD'))
2915             {
2916               &check_libobjs_sources ($xlib, $xlib . '_LIBADD');
2917             }
2918         }
2919
2920       if (! $seen_ar)
2921         {
2922           msg ('extra-portability', $where,
2923                "'$onelib': linking libtool libraries using a non-POSIX\n"
2924                . "archiver requires 'AM_PROG_AR' in '$configure_ac'")
2925         }
2926     }
2927 }
2928
2929 # See if any _SOURCES variable were misspelled.
2930 sub check_typos ()
2931 {
2932   # It is ok if the user sets this particular variable.
2933   set_seen 'AM_LDFLAGS';
2934
2935   foreach my $primary ('SOURCES', 'LIBADD', 'LDADD', 'LDFLAGS', 'DEPENDENCIES')
2936     {
2937       foreach my $var (variables $primary)
2938         {
2939           my $varname = $var->name;
2940           # A configure variable is always legitimate.
2941           next if exists $configure_vars{$varname};
2942
2943           for my $cond ($var->conditions->conds)
2944             {
2945               $varname =~ /^(?:EXTRA_)?(?:nobase_)?(?:dist_|nodist_)?(.*)_[[:alnum:]]+$/;
2946               msg_var ('syntax', $var, "variable '$varname' is defined but no"
2947                        . " program or\nlibrary has '$1' as canonical name"
2948                        . " (possible typo)")
2949                 unless $var->rdef ($cond)->seen;
2950             }
2951         }
2952     }
2953 }
2954
2955
2956 # Handle scripts.
2957 sub handle_scripts
2958 {
2959     # NOTE we no longer automatically clean SCRIPTS, because it is
2960     # useful to sometimes distribute scripts verbatim.  This happens
2961     # e.g. in Automake itself.
2962     &am_install_var ('-candist', 'scripts', 'SCRIPTS',
2963                      'bin', 'sbin', 'libexec', 'pkglibexec', 'pkgdata',
2964                      'noinst', 'check');
2965 }
2966
2967
2968
2969
2970 ## ------------------------ ##
2971 ## Handling Texinfo files.  ##
2972 ## ------------------------ ##
2973
2974 # ($OUTFILE, $VFILE)
2975 # &scan_texinfo_file ($FILENAME)
2976 # ------------------------------
2977 # $OUTFILE     - name of the info file produced by $FILENAME.
2978 # $VFILE       - name of the version.texi file used (undef if none).
2979 sub scan_texinfo_file ($)
2980 {
2981   my ($filename) = @_;
2982
2983   my $texi = new Automake::XFile "< $filename";
2984   verb "reading $filename";
2985
2986   my ($outfile, $vfile);
2987   while ($_ = $texi->getline)
2988     {
2989       if (/^\@setfilename +(\S+)/)
2990         {
2991           # Honor only the first @setfilename.  (It's possible to have
2992           # more occurrences later if the manual shows examples of how
2993           # to use @setfilename...)
2994           next if $outfile;
2995
2996           $outfile = $1;
2997           if (index ($outfile, '.') < 0)
2998             {
2999               msg 'obsolete', "$filename:$.",
3000                   "use of suffix-less info files is discouraged"
3001             }
3002           elsif ($outfile !~ /\.info$/)
3003             {
3004               error ("$filename:$.",
3005                      "output '$outfile' has unrecognized extension");
3006               return;
3007             }
3008         }
3009       # A "version.texi" file is actually any file whose name matches
3010       # "vers*.texi".
3011       elsif (/^\@include\s+(vers[^.]*\.texi)\s*$/)
3012         {
3013           $vfile = $1;
3014         }
3015     }
3016
3017   if (! $outfile)
3018     {
3019       err_am "'$filename' missing \@setfilename";
3020       return;
3021     }
3022
3023   return ($outfile, $vfile);
3024 }
3025
3026
3027 # ($DIRSTAMP, @CLEAN_FILES)
3028 # output_texinfo_build_rules ($SOURCE, $DEST, $INSRC, @DEPENDENCIES)
3029 # ------------------------------------------------------------------
3030 # SOURCE - the source Texinfo file
3031 # DEST - the destination Info file
3032 # INSRC - whether DEST should be built in the source tree
3033 # DEPENDENCIES - known dependencies
3034 sub output_texinfo_build_rules ($$$@)
3035 {
3036   my ($source, $dest, $insrc, @deps) = @_;
3037
3038   # Split 'a.texi' into 'a' and '.texi'.
3039   my ($spfx, $ssfx) = ($source =~ /^(.*?)(\.[^.]*)?$/);
3040   my ($dpfx, $dsfx) = ($dest =~ /^(.*?)(\.[^.]*)?$/);
3041
3042   $ssfx ||= "";
3043   $dsfx ||= "";
3044
3045   # We can output two kinds of rules: the "generic" rules use Make
3046   # suffix rules and are appropriate when $source and $dest do not lie
3047   # in a sub-directory; the "specific" rules are needed in the other
3048   # case.
3049   #
3050   # The former are output only once (this is not really apparent here,
3051   # but just remember that some logic deeper in Automake will not
3052   # output the same rule twice); while the later need to be output for
3053   # each Texinfo source.
3054   my $generic;
3055   my $makeinfoflags;
3056   my $sdir = dirname $source;
3057   if ($sdir eq '.' && dirname ($dest) eq '.')
3058     {
3059       $generic = 1;
3060       $makeinfoflags = '-I $(srcdir)';
3061     }
3062   else
3063     {
3064       $generic = 0;
3065       $makeinfoflags = "-I $sdir -I \$(srcdir)/$sdir";
3066     }
3067
3068   # A directory can contain two kinds of info files: some built in the
3069   # source tree, and some built in the build tree.  The rules are
3070   # different in each case.  However we cannot output two different
3071   # set of generic rules.  Because in-source builds are more usual, we
3072   # use generic rules in this case and fall back to "specific" rules
3073   # for build-dir builds.  (It should not be a problem to invert this
3074   # if needed.)
3075   $generic = 0 unless $insrc;
3076
3077   # We cannot use a suffix rule to build info files with an empty
3078   # extension.  Otherwise we would output a single suffix inference
3079   # rule, with separate dependencies, as in
3080   #
3081   #    .texi:
3082   #             $(MAKEINFO) ...
3083   #    foo.info: foo.texi
3084   #
3085   # which confuse Solaris make.  (See the Autoconf manual for
3086   # details.)  Therefore we use a specific rule in this case.  This
3087   # applies to info files only (dvi and pdf files always have an
3088   # extension).
3089   my $generic_info = ($generic && $dsfx) ? 1 : 0;
3090
3091   # If the resulting file lies in a subdirectory,
3092   # make sure this directory will exist.
3093   my $dirstamp = require_build_directory_maybe ($dest);
3094
3095   my $dipfx = ($insrc ? '$(srcdir)/' : '') . $dpfx;
3096
3097   $output_rules .= file_contents ('texibuild',
3098                                   new Automake::Location,
3099                                   AM_V_MAKEINFO    => verbose_flag('MAKEINFO'),
3100                                   AM_V_TEXI2DVI    => verbose_flag('TEXI2DVI'),
3101                                   AM_V_TEXI2PDF    => verbose_flag('TEXI2PDF'),
3102                                   DEPS             => "@deps",
3103                                   DEST_PREFIX      => $dpfx,
3104                                   DEST_INFO_PREFIX => $dipfx,
3105                                   DEST_SUFFIX      => $dsfx,
3106                                   DIRSTAMP         => $dirstamp,
3107                                   GENERIC          => $generic,
3108                                   GENERIC_INFO     => $generic_info,
3109                                   INSRC            => $insrc,
3110                                   MAKEINFOFLAGS    => $makeinfoflags,
3111                                   SILENT           => silent_flag(),
3112                                   SOURCE           => ($generic
3113                                                        ? '$<' : $source),
3114                                   SOURCE_INFO      => ($generic_info
3115                                                        ? '$<' : $source),
3116                                   SOURCE_REAL      => $source,
3117                                   SOURCE_SUFFIX    => $ssfx,
3118                                   TEXIQUIET        => verbose_flag('texinfo'),
3119                                   TEXIDEVNULL      => verbose_flag('texidevnull'),
3120                                   );
3121   return ($dirstamp, "$dpfx.dvi", "$dpfx.pdf", "$dpfx.ps", "$dpfx.html");
3122 }
3123
3124
3125 # ($MOSTLYCLEAN, $TEXICLEAN, $MAINTCLEAN)
3126 # handle_texinfo_helper ($info_texinfos)
3127 # --------------------------------------
3128 # Handle all Texinfo source; helper for handle_texinfo.
3129 sub handle_texinfo_helper ($)
3130 {
3131   my ($info_texinfos) = @_;
3132   my (@infobase, @info_deps_list, @texi_deps);
3133   my %versions;
3134   my $done = 0;
3135   my (@mostly_cleans, @texi_cleans, @maint_cleans) = ('', '', '');
3136
3137   # Build a regex matching user-cleaned files.
3138   my $d = var 'DISTCLEANFILES';
3139   my $c = var 'CLEANFILES';
3140   my @f = ();
3141   push @f, $d->value_as_list_recursive (inner_expand => 1) if $d;
3142   push @f, $c->value_as_list_recursive (inner_expand => 1) if $c;
3143   @f = map { s|[^A-Za-z_0-9*\[\]\-]|\\$&|g; s|\*|[^/]*|g; $_; } @f;
3144   my $user_cleaned_files = '^(?:' . join ('|', @f) . ')$';
3145
3146   foreach my $texi
3147       ($info_texinfos->value_as_list_recursive (inner_expand => 1))
3148     {
3149       my $infobase = $texi;
3150       if ($infobase =~ s/\.texi$//)
3151         {
3152           1; # Nothing more to do.
3153         }
3154       elsif ($infobase =~ s/\.(txi|texinfo)$//)
3155         {
3156           msg_var 'obsolete', $info_texinfos,
3157                   "suffix '.$1' for Texinfo files is discouraged;" .
3158                   " use '.texi' instead";
3159         }
3160       else
3161         {
3162           # FIXME: report line number.
3163           err_am "texinfo file '$texi' has unrecognized extension";
3164           next;
3165         }
3166
3167       push @infobase, $infobase;
3168
3169       # If 'version.texi' is referenced by input file, then include
3170       # automatic versioning capability.
3171       my ($out_file, $vtexi) =
3172         scan_texinfo_file ("$relative_dir/$texi")
3173         or next;
3174       # Directory of auxiliary files and build by-products used by texi2dvi
3175       # and texi2pdf.
3176       push @mostly_cleans, "$infobase.t2d";
3177       push @mostly_cleans, "$infobase.t2p";
3178
3179       # If the Texinfo source is in a subdirectory, create the
3180       # resulting info in this subdirectory.  If it is in the current
3181       # directory, try hard to not prefix "./" because it breaks the
3182       # generic rules.
3183       my $outdir = dirname ($texi) . '/';
3184       $outdir = "" if $outdir eq './';
3185       $out_file =  $outdir . $out_file;
3186
3187       # Until Automake 1.6.3, .info files were built in the
3188       # source tree.  This was an obstacle to the support of
3189       # non-distributed .info files, and non-distributed .texi
3190       # files.
3191       #
3192       # * Non-distributed .texi files is important in some packages
3193       #   where .texi files are built at make time, probably using
3194       #   other binaries built in the package itself, maybe using
3195       #   tools or information found on the build host.  Because
3196       #   these files are not distributed they are always rebuilt
3197       #   at make time; they should therefore not lie in the source
3198       #   directory.  One plan was to support this using
3199       #   nodist_info_TEXINFOS or something similar.  (Doing this
3200       #   requires some sanity checks.  For instance Automake should
3201       #   not allow:
3202       #      dist_info_TEXINFOS = foo.texi
3203       #      nodist_foo_TEXINFOS = included.texi
3204       #   because a distributed file should never depend on a
3205       #   non-distributed file.)
3206       #
3207       # * If .texi files are not distributed, then .info files should
3208       #   not be distributed either.  There are also cases where one
3209       #   wants to distribute .texi files, but does not want to
3210       #   distribute the .info files.  For instance the Texinfo package
3211       #   distributes the tool used to build these files; it would
3212       #   be a waste of space to distribute them.  It's not clear
3213       #   which syntax we should use to indicate that .info files should
3214       #   not be distributed.  Akim Demaille suggested that eventually
3215       #   we switch to a new syntax:
3216       #   |  Maybe we should take some inspiration from what's already
3217       #   |  done in the rest of Automake.  Maybe there is too much
3218       #   |  syntactic sugar here, and you want
3219       #   |     nodist_INFO = bar.info
3220       #   |     dist_bar_info_SOURCES = bar.texi
3221       #   |     bar_texi_DEPENDENCIES = foo.texi
3222       #   |  with a bit of magic to have bar.info represent the whole
3223       #   |  bar*info set.  That's a lot more verbose that the current
3224       #   |  situation, but it is # not new, hence the user has less
3225       #   |  to learn.
3226       #   |
3227       #   |  But there is still too much room for meaningless specs:
3228       #   |     nodist_INFO = bar.info
3229       #   |     dist_bar_info_SOURCES = bar.texi
3230       #   |     dist_PS = bar.ps something-written-by-hand.ps
3231       #   |     nodist_bar_ps_SOURCES = bar.texi
3232       #   |     bar_texi_DEPENDENCIES = foo.texi
3233       #   |  here bar.texi is dist_ in line 2, and nodist_ in 4.
3234       #
3235       # Back to the point, it should be clear that in order to support
3236       # non-distributed .info files, we need to build them in the
3237       # build tree, not in the source tree (non-distributed .texi
3238       # files are less of a problem, because we do not output build
3239       # rules for them).  In Automake 1.7 .info build rules have been
3240       # largely cleaned up so that .info files get always build in the
3241       # build tree, even when distributed.  The idea was that
3242       #   (1) if during a VPATH build the .info file was found to be
3243       #       absent or out-of-date (in the source tree or in the
3244       #       build tree), Make would rebuild it in the build tree.
3245       #       If an up-to-date source-tree of the .info file existed,
3246       #       make would not rebuild it in the build tree.
3247       #   (2) having two copies of .info files, one in the source tree
3248       #       and one (newer) in the build tree is not a problem
3249       #       because 'make dist' always pick files in the build tree
3250       #       first.
3251       # However it turned out the be a bad idea for several reasons:
3252       #   * Tru64, OpenBSD, and FreeBSD (not NetBSD) Make do not behave
3253       #     like GNU Make on point (1) above.  These implementations
3254       #     of Make would always rebuild .info files in the build
3255       #     tree, even if such files were up to date in the source
3256       #     tree.  Consequently, it was impossible to perform a VPATH
3257       #     build of a package containing Texinfo files using these
3258       #     Make implementations.
3259       #     (Refer to the Autoconf Manual, section "Limitation of
3260       #     Make", paragraph "VPATH", item "target lookup", for
3261       #     an account of the differences between these
3262       #     implementations.)
3263       #   * The GNU Coding Standards require these files to be built
3264       #     in the source-tree (when they are distributed, that is).
3265       #   * Keeping a fresher copy of distributed files in the
3266       #     build tree can be annoying during development because
3267       #     - if the files is kept under CVS, you really want it
3268       #       to be updated in the source tree
3269       #     - it is confusing that 'make distclean' does not erase
3270       #       all files in the build tree.
3271       #
3272       # Consequently, starting with Automake 1.8, .info files are
3273       # built in the source tree again.  Because we still plan to
3274       # support non-distributed .info files at some point, we
3275       # have a single variable ($INSRC) that controls whether
3276       # the current .info file must be built in the source tree
3277       # or in the build tree.  Actually this variable is switched
3278       # off for .info files that appear to be cleaned; this is
3279       # for backward compatibility with package such as Texinfo,
3280       # which do things like
3281       #   info_TEXINFOS = texinfo.txi info-stnd.texi info.texi
3282       #   DISTCLEANFILES = texinfo texinfo-* info*.info*
3283       #   # Do not create info files for distribution.
3284       #   dist-info:
3285       # in order not to distribute .info files.
3286       my $insrc = ($out_file =~ $user_cleaned_files) ? 0 : 1;
3287
3288       my $soutdir = '$(srcdir)/' . $outdir;
3289       $outdir = $soutdir if $insrc;
3290
3291       # If user specified file_TEXINFOS, then use that as explicit
3292       # dependency list.
3293       @texi_deps = ();
3294       push (@texi_deps, "$soutdir$vtexi") if $vtexi;
3295
3296       my $canonical = canonicalize ($infobase);
3297       if (var ($canonical . "_TEXINFOS"))
3298         {
3299           push (@texi_deps, '$(' . $canonical . '_TEXINFOS)');
3300           push_dist_common ('$(' . $canonical . '_TEXINFOS)');
3301         }
3302
3303       my ($dirstamp, @cfiles) =
3304         output_texinfo_build_rules ($texi, $out_file, $insrc, @texi_deps);
3305       push (@texi_cleans, @cfiles);
3306
3307       push (@info_deps_list, $out_file);
3308
3309       # If a vers*.texi file is needed, emit the rule.
3310       if ($vtexi)
3311         {
3312           err_am ("'$vtexi', included in '$texi', "
3313                   . "also included in '$versions{$vtexi}'")
3314             if defined $versions{$vtexi};
3315           $versions{$vtexi} = $texi;
3316
3317           # We number the stamp-vti files.  This is doable since the
3318           # actual names don't matter much.  We only number starting
3319           # with the second one, so that the common case looks nice.
3320           my $vti = ($done ? $done : 'vti');
3321           ++$done;
3322
3323           # This is ugly, but it is our historical practice.
3324           if ($config_aux_dir_set_in_configure_ac)
3325             {
3326               require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3327                                             'mdate-sh');
3328             }
3329           else
3330             {
3331               require_file_with_macro (TRUE, 'info_TEXINFOS',
3332                                        FOREIGN, 'mdate-sh');
3333             }
3334
3335           my $conf_dir;
3336           if ($config_aux_dir_set_in_configure_ac)
3337             {
3338               $conf_dir = "$am_config_aux_dir/";
3339             }
3340           else
3341             {
3342               $conf_dir = '$(srcdir)/';
3343             }
3344           $output_rules .= file_contents ('texi-vers',
3345                                           new Automake::Location,
3346                                           TEXI     => $texi,
3347                                           VTI      => $vti,
3348                                           STAMPVTI => "${soutdir}stamp-$vti",
3349                                           VTEXI    => "$soutdir$vtexi",
3350                                           MDDIR    => $conf_dir,
3351                                           DIRSTAMP => $dirstamp);
3352         }
3353     }
3354
3355   # Handle location of texinfo.tex.
3356   my $need_texi_file = 0;
3357   my $texinfodir;
3358   if (var ('TEXINFO_TEX'))
3359     {
3360       # The user defined TEXINFO_TEX so assume he knows what he is
3361       # doing.
3362       $texinfodir = ('$(srcdir)/'
3363                      . dirname (variable_value ('TEXINFO_TEX')));
3364     }
3365   elsif ($config_aux_dir_set_in_configure_ac)
3366     {
3367       $texinfodir = $am_config_aux_dir;
3368       define_variable ('TEXINFO_TEX', "$texinfodir/texinfo.tex", INTERNAL);
3369       $need_texi_file = 2; # so that we require_conf_file later
3370     }
3371   else
3372     {
3373       $texinfodir = '$(srcdir)';
3374       $need_texi_file = 1;
3375     }
3376   define_variable ('am__TEXINFO_TEX_DIR', $texinfodir, INTERNAL);
3377
3378   push (@dist_targets, 'dist-info');
3379
3380   if (! option 'no-installinfo')
3381     {
3382       # Make sure documentation is made and installed first.  Use
3383       # $(INFO_DEPS), not 'info', because otherwise recursive makes
3384       # get run twice during "make all".
3385       unshift (@all, '$(INFO_DEPS)');
3386     }
3387
3388   define_files_variable ("DVIS", @infobase, 'dvi', INTERNAL);
3389   define_files_variable ("PDFS", @infobase, 'pdf', INTERNAL);
3390   define_files_variable ("PSS", @infobase, 'ps', INTERNAL);
3391   define_files_variable ("HTMLS", @infobase, 'html', INTERNAL);
3392
3393   # This next isn't strictly needed now -- the places that look here
3394   # could easily be changed to look in info_TEXINFOS.  But this is
3395   # probably better, in case noinst_TEXINFOS is ever supported.
3396   define_variable ("TEXINFOS", variable_value ('info_TEXINFOS'), INTERNAL);
3397
3398   # Do some error checking.  Note that this file is not required
3399   # when in Cygnus mode; instead we defined TEXINFO_TEX explicitly
3400   # up above.
3401   if ($need_texi_file && ! option 'no-texinfo.tex')
3402     {
3403       if ($need_texi_file > 1)
3404         {
3405           require_conf_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3406                                         'texinfo.tex');
3407         }
3408       else
3409         {
3410           require_file_with_macro (TRUE, 'info_TEXINFOS', FOREIGN,
3411                                    'texinfo.tex');
3412         }
3413     }
3414
3415   return (makefile_wrap ("", "\t  ", @mostly_cleans),
3416           makefile_wrap ("", "\t  ", @texi_cleans),
3417           makefile_wrap ("", "\t  ", @maint_cleans));
3418 }
3419
3420
3421 # handle_texinfo ()
3422 # -----------------
3423 # Handle all Texinfo source.
3424 sub handle_texinfo ()
3425 {
3426   reject_var 'TEXINFOS', "'TEXINFOS' is an anachronism; use 'info_TEXINFOS'";
3427   # FIXME: I think this is an obsolete future feature name.
3428   reject_var 'html_TEXINFOS', "HTML generation not yet supported";
3429
3430   my $info_texinfos = var ('info_TEXINFOS');
3431   my ($mostlyclean, $clean, $maintclean) = ('', '', '');
3432   if ($info_texinfos)
3433     {
3434       define_verbose_texinfo;
3435       ($mostlyclean, $clean, $maintclean) = handle_texinfo_helper ($info_texinfos);
3436       chomp $mostlyclean;
3437       chomp $clean;
3438       chomp $maintclean;
3439     }
3440
3441   $output_rules .=  file_contents ('texinfos',
3442                                    new Automake::Location,
3443                                    AM_V_DVIPS    => verbose_flag('DVIPS'),
3444                                    MOSTLYCLEAN   => $mostlyclean,
3445                                    TEXICLEAN     => $clean,
3446                                    MAINTCLEAN    => $maintclean,
3447                                    'LOCAL-TEXIS' => !!$info_texinfos,
3448                                    TEXIQUIET     => verbose_flag('texinfo'));
3449 }
3450
3451
3452 # Handle any man pages.
3453 sub handle_man_pages
3454 {
3455   reject_var 'MANS', "'MANS' is an anachronism; use 'man_MANS'";
3456
3457   # Find all the sections in use.  We do this by first looking for
3458   # "standard" sections, and then looking for any additional
3459   # sections used in man_MANS.
3460   my (%sections, %notrans_sections, %trans_sections,
3461       %notrans_vars, %trans_vars, %notrans_sect_vars, %trans_sect_vars);
3462   # We handle nodist_ for uniformity.  man pages aren't distributed
3463   # by default so it isn't actually very important.
3464   foreach my $npfx ('', 'notrans_')
3465     {
3466       foreach my $pfx ('', 'dist_', 'nodist_')
3467         {
3468           # Add more sections as needed.
3469           foreach my $section ('0'..'9', 'n', 'l')
3470             {
3471               my $varname = $npfx . $pfx . 'man' . $section . '_MANS';
3472               if (var ($varname))
3473                 {
3474                   $sections{$section} = 1;
3475                   $varname = '$(' . $varname . ')';
3476                   if ($npfx eq 'notrans_')
3477                     {
3478                       $notrans_sections{$section} = 1;
3479                       $notrans_sect_vars{$varname} = 1;
3480                     }
3481                   else
3482                     {
3483                       $trans_sections{$section} = 1;
3484                       $trans_sect_vars{$varname} = 1;
3485                     }
3486
3487                   &push_dist_common ($varname)
3488                     if $pfx eq 'dist_';
3489                 }
3490             }
3491
3492           my $varname = $npfx . $pfx . 'man_MANS';
3493           my $var = var ($varname);
3494           if ($var)
3495             {
3496               foreach ($var->value_as_list_recursive)
3497                 {
3498                   # A page like 'foo.1c' goes into man1dir.
3499                   if (/\.([0-9a-z])([a-z]*)$/)
3500                     {
3501                       $sections{$1} = 1;
3502                       if ($npfx eq 'notrans_')
3503                         {
3504                           $notrans_sections{$1} = 1;
3505                         }
3506                       else
3507                         {
3508                           $trans_sections{$1} = 1;
3509                         }
3510                     }
3511                 }
3512
3513               $varname = '$(' . $varname . ')';
3514               if ($npfx eq 'notrans_')
3515                 {
3516                   $notrans_vars{$varname} = 1;
3517                 }
3518               else
3519                 {
3520                   $trans_vars{$varname} = 1;
3521                 }
3522               &push_dist_common ($varname)
3523                 if $pfx eq 'dist_';
3524             }
3525         }
3526     }
3527
3528   return unless %sections;
3529
3530   my @unsorted_deps;
3531
3532   # Build section independent variables.
3533   my $have_notrans = %notrans_vars;
3534   my @notrans_list = sort keys %notrans_vars;
3535   my $have_trans = %trans_vars;
3536   my @trans_list = sort keys %trans_vars;
3537
3538   # Now for each section, generate an install and uninstall rule.
3539   # Sort sections so output is deterministic.
3540   foreach my $section (sort keys %sections)
3541     {
3542       # Build section dependent variables.
3543       my $notrans_mans = $have_notrans || exists $notrans_sections{$section};
3544       my $trans_mans = $have_trans || exists $trans_sections{$section};
3545       my (%notrans_this_sect, %trans_this_sect);
3546       my $expr = 'man' . $section . '_MANS';
3547       foreach my $varname (keys %notrans_sect_vars)
3548         {
3549           if ($varname =~ /$expr/)
3550             {
3551               $notrans_this_sect{$varname} = 1;
3552             }
3553         }
3554       foreach my $varname (keys %trans_sect_vars)
3555         {
3556           if ($varname =~ /$expr/)
3557             {
3558               $trans_this_sect{$varname} = 1;
3559             }
3560         }
3561       my @notrans_sect_list = sort keys %notrans_this_sect;
3562       my @trans_sect_list = sort keys %trans_this_sect;
3563       @unsorted_deps = (keys %notrans_vars, keys %trans_vars,
3564                         keys %notrans_this_sect, keys %trans_this_sect);
3565       my @deps = sort @unsorted_deps;
3566       $output_rules .= &file_contents ('mans',
3567                                        new Automake::Location,
3568                                        SECTION           => $section,
3569                                        DEPS              => "@deps",
3570                                        NOTRANS_MANS      => $notrans_mans,
3571                                        NOTRANS_SECT_LIST => "@notrans_sect_list",
3572                                        HAVE_NOTRANS      => $have_notrans,
3573                                        NOTRANS_LIST      => "@notrans_list",
3574                                        TRANS_MANS        => $trans_mans,
3575                                        TRANS_SECT_LIST   => "@trans_sect_list",
3576                                        HAVE_TRANS        => $have_trans,
3577                                        TRANS_LIST        => "@trans_list");
3578     }
3579
3580   @unsorted_deps  = (keys %notrans_vars, keys %trans_vars,
3581                      keys %notrans_sect_vars, keys %trans_sect_vars);
3582   my @mans = sort @unsorted_deps;
3583   $output_vars .= file_contents ('mans-vars',
3584                                  new Automake::Location,
3585                                  MANS => "@mans");
3586
3587   push (@all, '$(MANS)')
3588     unless option 'no-installman';
3589 }
3590
3591 # Handle DATA variables.
3592 sub handle_data
3593 {
3594     &am_install_var ('-noextra', '-candist', 'data', 'DATA',
3595                      'data', 'dataroot', 'doc', 'dvi', 'html', 'pdf',
3596                      'ps', 'sysconf', 'sharedstate', 'localstate',
3597                      'pkgdata', 'lisp', 'noinst', 'check');
3598 }
3599
3600 # Handle TAGS.
3601 sub handle_tags
3602 {
3603     my @config;
3604     foreach my $spec (@config_headers)
3605       {
3606         my ($out, @ins) = split_config_file_spec ($spec);
3607         foreach my $in (@ins)
3608           {
3609             # If the config header source is in this directory,
3610             # require it.
3611             push @config, basename ($in)
3612               if $relative_dir eq dirname ($in);
3613            }
3614       }
3615
3616     define_variable ('am__tagged_files',
3617                      '$(HEADERS) $(SOURCES) $(TAGS_FILES) $(LISP)'
3618                      . "@config", INTERNAL);
3619
3620     if (rvar('am__tagged_files')->value_as_list_recursive
3621           || var ('ETAGS_ARGS') || var ('SUBDIRS'))
3622       {
3623         $output_rules .= &file_contents ('tags', new Automake::Location);
3624         set_seen 'TAGS_DEPENDENCIES';
3625       }
3626     else
3627       {
3628         reject_var ('TAGS_DEPENDENCIES',
3629                     "it doesn't make sense to define 'TAGS_DEPENDENCIES'"
3630                     . " without\nsources or 'ETAGS_ARGS'");
3631         # Every Makefile must define some sort of TAGS rule.
3632         # Otherwise, it would be possible for a top-level "make TAGS"
3633         # to fail because some subdirectory failed.  Ditto ctags and
3634         # cscope.
3635         $output_rules .=
3636           "tags TAGS:\n\n" .
3637           "ctags CTAGS:\n\n" .
3638           "cscope cscopelist:\n\n";
3639       }
3640 }
3641
3642
3643 # user_phony_rule ($NAME)
3644 # -----------------------
3645 # Return false if rule $NAME does not exist.  Otherwise,
3646 # declare it as phony, complete its definition (in case it is
3647 # conditional), and return its Automake::Rule instance.
3648 sub user_phony_rule ($)
3649 {
3650   my ($name) = @_;
3651   my $rule = rule $name;
3652   if ($rule)
3653     {
3654       depend ('.PHONY', $name);
3655       # Define $NAME in all condition where it is not already defined,
3656       # so that it is always OK to depend on $NAME.
3657       for my $c ($rule->not_always_defined_in_cond (TRUE)->conds)
3658         {
3659           Automake::Rule::define ($name, 'internal', RULE_AUTOMAKE,
3660                                   $c, INTERNAL);
3661           $output_rules .= $c->subst_string . "$name:\n";
3662         }
3663     }
3664   return $rule;
3665 }
3666
3667
3668 # handle_dist
3669 # -----------
3670 # Handle 'dist' target.
3671 sub handle_dist ()
3672 {
3673   # Substitutions for distdir.am
3674   my %transform;
3675
3676   # Define DIST_SUBDIRS.  This must always be done, regardless of the
3677   # no-dist setting: target like 'distclean' or 'maintainer-clean' use it.
3678   my $subdirs = var ('SUBDIRS');
3679   if ($subdirs)
3680     {
3681       # If SUBDIRS is conditionally defined, then set DIST_SUBDIRS
3682       # to all possible directories, and use it.  If DIST_SUBDIRS is
3683       # defined, just use it.
3684
3685       # Note that we check DIST_SUBDIRS first on purpose, so that
3686       # we don't call has_conditional_contents for now reason.
3687       # (In the past one project used so many conditional subdirectories
3688       # that calling has_conditional_contents on SUBDIRS caused
3689       # automake to grow to 150Mb -- this should not happen with
3690       # the current implementation of has_conditional_contents,
3691       # but it's more efficient to avoid the call anyway.)
3692       if (var ('DIST_SUBDIRS'))
3693         {
3694         }
3695       elsif ($subdirs->has_conditional_contents)
3696         {
3697           define_pretty_variable
3698             ('DIST_SUBDIRS', TRUE, INTERNAL,
3699              uniq ($subdirs->value_as_list_recursive));
3700         }
3701       else
3702         {
3703           # We always define this because that is what 'distclean'
3704           # wants.
3705           define_pretty_variable ('DIST_SUBDIRS', TRUE, INTERNAL,
3706                                   '$(SUBDIRS)');
3707         }
3708     }
3709
3710   # The remaining definitions are only required when a dist target is used.
3711   return if option 'no-dist';
3712
3713   # At least one of the archive formats must be enabled.
3714   if ($relative_dir eq '.')
3715     {
3716       my $archive_defined = option 'no-dist-gzip' ? 0 : 1;
3717       $archive_defined ||=
3718         grep { option "dist-$_" } qw(shar zip tarZ bzip2 lzip xz);
3719       error (option 'no-dist-gzip',
3720              "no-dist-gzip specified but no dist-* specified,\n"
3721              . "at least one archive format must be enabled")
3722         unless $archive_defined;
3723     }
3724
3725   # Look for common files that should be included in distribution.
3726   # If the aux dir is set, and it does not have a Makefile.am, then
3727   # we check for these files there as well.
3728   my $check_aux = 0;
3729   if ($relative_dir eq '.'
3730       && $config_aux_dir_set_in_configure_ac)
3731     {
3732       if (! &is_make_dir ($config_aux_dir))
3733         {
3734           $check_aux = 1;
3735         }
3736     }
3737   foreach my $cfile (@common_files)
3738     {
3739       if (dir_has_case_matching_file ($relative_dir, $cfile)
3740           # The file might be absent, but if it can be built it's ok.
3741           || rule $cfile)
3742         {
3743           &push_dist_common ($cfile);
3744         }
3745
3746       # Don't use 'elsif' here because a file might meaningfully
3747       # appear in both directories.
3748       if ($check_aux && dir_has_case_matching_file ($config_aux_dir, $cfile))
3749         {
3750           &push_dist_common ("$config_aux_dir/$cfile")
3751         }
3752     }
3753
3754   # We might copy elements from $configure_dist_common to
3755   # %dist_common if we think we need to.  If the file appears in our
3756   # directory, we would have discovered it already, so we don't
3757   # check that.  But if the file is in a subdir without a Makefile,
3758   # we want to distribute it here if we are doing '.'.  Ugly!
3759   # Also, in some corner cases, it's possible that the following code
3760   # will cause the same file to appear in the $(DIST_COMMON) variables
3761   # of two distinct Makefiles; but this is not a problem, since the
3762   # 'distdir' target in 'lib/am/distdir.am' can deal with the same
3763   # file being distributed multiple times.
3764   # See also automake bug#9651.
3765   if ($relative_dir eq '.')
3766     {
3767       foreach my $file (split (' ' , $configure_dist_common))
3768         {
3769           my $dir = dirname ($file);
3770           push_dist_common ($file)
3771             if ($dir eq '.' || ! is_make_dir ($dir));
3772         }
3773     }
3774
3775   # Files to distributed.  Don't use ->value_as_list_recursive
3776   # as it recursively expands '$(dist_pkgdata_DATA)' etc.
3777   my @dist_common = split (' ', rvar ('DIST_COMMON')->variable_value);
3778   @dist_common = uniq @dist_common;
3779   variable_delete 'DIST_COMMON';
3780   define_pretty_variable ('DIST_COMMON', TRUE, INTERNAL, @dist_common);
3781
3782   # Now that we've processed DIST_COMMON, disallow further attempts
3783   # to set it.
3784   $handle_dist_run = 1;
3785
3786   $transform{'DISTCHECK-HOOK'} = !! rule 'distcheck-hook';
3787   $transform{'GETTEXT'} = $seen_gettext && !$seen_gettext_external;
3788
3789   # If the target 'dist-hook' exists, make sure it is run.  This
3790   # allows users to do random weird things to the distribution
3791   # before it is packaged up.
3792   push (@dist_targets, 'dist-hook')
3793     if user_phony_rule 'dist-hook';
3794   $transform{'DIST-TARGETS'} = join (' ', @dist_targets);
3795
3796   my $flm = option ('filename-length-max');
3797   my $filename_filter = $flm ? '.' x $flm->[1] : '';
3798
3799   $output_rules .= &file_contents ('distdir',
3800                                    new Automake::Location,
3801                                    %transform,
3802                                    FILENAME_FILTER => $filename_filter);
3803 }
3804
3805
3806 # check_directory ($NAME, $WHERE [, $RELATIVE_DIR = "."])
3807 # -------------------------------------------------------
3808 # Ensure $NAME is a directory (in $RELATIVE_DIR), and that it uses a sane
3809 # name.  Use $WHERE as a location in the diagnostic, if any.
3810 sub check_directory ($$;$)
3811 {
3812   my ($dir, $where, $reldir) = @_;
3813   $reldir = '.' unless defined $reldir;
3814
3815   error $where, "required directory $reldir/$dir does not exist"
3816     unless -d "$reldir/$dir";
3817
3818   # If an 'obj/' directory exists, BSD make will enter it before
3819   # reading 'Makefile'.  Hence the 'Makefile' in the current directory
3820   # will not be read.
3821   #
3822   #  % cat Makefile
3823   #  all:
3824   #          echo Hello
3825   #  % cat obj/Makefile
3826   #  all:
3827   #          echo World
3828   #  % make      # GNU make
3829   #  echo Hello
3830   #  Hello
3831   #  % pmake     # BSD make
3832   #  echo World
3833   #  World
3834   msg ('portability', $where,
3835        "naming a subdirectory 'obj' causes troubles with BSD make")
3836     if $dir eq 'obj';
3837
3838   # 'aux' is probably the most important of the following forbidden name,
3839   # since it's tempting to use it as an AC_CONFIG_AUX_DIR.
3840   msg ('portability', $where,
3841        "name '$dir' is reserved on W32 and DOS platforms")
3842     if grep (/^\Q$dir\E$/i, qw/aux lpt1 lpt2 lpt3 com1 com2 com3 com4 con prn/);
3843 }
3844
3845 # check_directories_in_var ($VARIABLE)
3846 # ------------------------------------
3847 # Recursively check all items in variables $VARIABLE as directories
3848 sub check_directories_in_var ($)
3849 {
3850   my ($var) = @_;
3851   $var->traverse_recursively
3852     (sub
3853      {
3854        my ($var, $val, $cond, $full_cond) = @_;
3855        check_directory ($val, $var->rdef ($cond)->location, $relative_dir);
3856        return ();
3857      },
3858      undef,
3859      skip_ac_subst => 1);
3860 }
3861
3862 # &handle_subdirs ()
3863 # ------------------
3864 # Handle subdirectories.
3865 sub handle_subdirs ()
3866 {
3867   my $subdirs = var ('SUBDIRS');
3868   return
3869     unless $subdirs;
3870
3871   check_directories_in_var $subdirs;
3872
3873   my $dsubdirs = var ('DIST_SUBDIRS');
3874   check_directories_in_var $dsubdirs
3875     if $dsubdirs;
3876
3877   $output_rules .= &file_contents ('subdirs', new Automake::Location);
3878   rvar ('RECURSIVE_TARGETS')->rdef (TRUE)->{'pretty'} = VAR_SORTED; # Gross!
3879 }
3880
3881
3882 # ($REGEN, @DEPENDENCIES)
3883 # &scan_aclocal_m4
3884 # ----------------
3885 # If aclocal.m4 creation is automated, return the list of its dependencies.
3886 sub scan_aclocal_m4 ()
3887 {
3888   my $regen_aclocal = 0;
3889
3890   set_seen 'CONFIG_STATUS_DEPENDENCIES';
3891   set_seen 'CONFIGURE_DEPENDENCIES';
3892
3893   if (-f 'aclocal.m4')
3894     {
3895       &define_variable ("ACLOCAL_M4", '$(top_srcdir)/aclocal.m4', INTERNAL);
3896
3897       my $aclocal = new Automake::XFile "< aclocal.m4";
3898       my $line = $aclocal->getline;
3899       $regen_aclocal = $line =~ 'generated automatically by aclocal';
3900     }
3901
3902   my @ac_deps = ();
3903
3904   if (set_seen ('ACLOCAL_M4_SOURCES'))
3905     {
3906       push (@ac_deps, '$(ACLOCAL_M4_SOURCES)');
3907       msg_var ('obsolete', 'ACLOCAL_M4_SOURCES',
3908                "'ACLOCAL_M4_SOURCES' is obsolete.\n"
3909                . "It should be safe to simply remove it");
3910     }
3911
3912   # Note that it might be possible that aclocal.m4 doesn't exist but
3913   # should be auto-generated.  This case probably isn't very
3914   # important.
3915
3916   return ($regen_aclocal, @ac_deps);
3917 }
3918
3919
3920 # Helper function for substitute_ac_subst_variables.
3921 sub substitute_ac_subst_variables_worker($)
3922 {
3923   my ($token) = @_;
3924   return "\@$token\@" if var $token;
3925   return "\${$token\}";
3926 }
3927
3928 # substitute_ac_subst_variables ($TEXT)
3929 # -------------------------------------
3930 # Replace any occurrence of ${FOO} in $TEXT by @FOO@ if FOO is an AC_SUBST
3931 # variable.
3932 sub substitute_ac_subst_variables ($)
3933 {
3934   my ($text) = @_;
3935   $text =~ s/\${([^ \t=:+{}]+)}/&substitute_ac_subst_variables_worker ($1)/ge;
3936   return $text;
3937 }
3938
3939 # @DEPENDENCIES
3940 # &prepend_srcdir (@INPUTS)
3941 # -------------------------
3942 # Prepend $(srcdir) or $(top_srcdir) to all @INPUTS.  The idea is that
3943 # if an input file has a directory part the same as the current
3944 # directory, then the directory part is simply replaced by $(srcdir).
3945 # But if the directory part is different, then $(top_srcdir) is
3946 # prepended.
3947 sub prepend_srcdir (@)
3948 {
3949   my (@inputs) = @_;
3950   my @newinputs;
3951
3952   foreach my $single (@inputs)
3953     {
3954       if (dirname ($single) eq $relative_dir)
3955         {
3956           push (@newinputs, '$(srcdir)/' . basename ($single));
3957         }
3958       else
3959         {
3960           push (@newinputs, '$(top_srcdir)/' . $single);
3961         }
3962     }
3963   return @newinputs;
3964 }
3965
3966 # @DEPENDENCIES
3967 # rewrite_inputs_into_dependencies ($OUTPUT, @INPUTS)
3968 # ---------------------------------------------------
3969 # Compute a list of dependencies appropriate for the rebuild
3970 # rule of
3971 #   AC_CONFIG_FILES($OUTPUT:$INPUT[0]:$INPUTS[1]:...)
3972 # Also distribute $INPUTs which are not built by another AC_CONFIG_FOOs.
3973 sub rewrite_inputs_into_dependencies ($@)
3974 {
3975   my ($file, @inputs) = @_;
3976   my @res = ();
3977
3978   for my $i (@inputs)
3979     {
3980       # We cannot create dependencies on shell variables.
3981       next if (substitute_ac_subst_variables $i) =~ /\$/;
3982
3983       if (exists $ac_config_files_location{$i} && $i ne $file)
3984         {
3985           my $di = dirname $i;
3986           if ($di eq $relative_dir)
3987             {
3988               $i = basename $i;
3989             }
3990           # In the top-level Makefile we do not use $(top_builddir), because
3991           # we are already there, and since the targets are built without
3992           # a $(top_builddir), it helps BSD Make to match them with
3993           # dependencies.
3994           elsif ($relative_dir ne '.')
3995             {
3996               $i = '$(top_builddir)/' . $i;
3997             }
3998         }
3999       else
4000         {
4001           msg ('error', $ac_config_files_location{$file},
4002                "required file '$i' not found")
4003             unless $i =~ /\$/ || exists $output_files{$i} || -f $i;
4004           ($i) = prepend_srcdir ($i);
4005           push_dist_common ($i);
4006         }
4007       push @res, $i;
4008     }
4009   return @res;
4010 }
4011
4012
4013
4014 # &handle_configure ($MAKEFILE_AM, $MAKEFILE_IN, $MAKEFILE, @INPUTS)
4015 # ------------------------------------------------------------------
4016 # Handle remaking and configure stuff.
4017 # We need the name of the input file, to do proper remaking rules.
4018 sub handle_configure ($$$@)
4019 {
4020   my ($makefile_am, $makefile_in, $makefile, @inputs) = @_;
4021
4022   prog_error 'empty @inputs'
4023     unless @inputs;
4024
4025   my ($rel_makefile_am, $rel_makefile_in) = prepend_srcdir ($makefile_am,
4026                                                             $makefile_in);
4027   my $rel_makefile = basename $makefile;
4028
4029   my $colon_infile = ':' . join (':', @inputs);
4030   $colon_infile = '' if $colon_infile eq ":$makefile.in";
4031   my @rewritten = rewrite_inputs_into_dependencies ($makefile, @inputs);
4032   my ($regen_aclocal_m4, @aclocal_m4_deps) = scan_aclocal_m4;
4033   define_pretty_variable ('am__aclocal_m4_deps', TRUE, INTERNAL,
4034                           @configure_deps, @aclocal_m4_deps,
4035                           '$(top_srcdir)/' . $configure_ac);
4036   my @configuredeps = ('$(am__aclocal_m4_deps)', '$(CONFIGURE_DEPENDENCIES)');
4037   push @configuredeps, '$(ACLOCAL_M4)' if -f 'aclocal.m4';
4038   define_pretty_variable ('am__configure_deps', TRUE, INTERNAL,
4039                           @configuredeps);
4040
4041   my $automake_options = '--' . $strictness_name .
4042                          (global_option 'no-dependencies' ? ' --ignore-deps' : '');
4043
4044   $output_rules .= file_contents
4045     ('configure',
4046      new Automake::Location,
4047      MAKEFILE              => $rel_makefile,
4048      'MAKEFILE-DEPS'       => "@rewritten",
4049      'CONFIG-MAKEFILE'     => ($relative_dir eq '.') ? '$@' : '$(subdir)/$@',
4050      'MAKEFILE-IN'         => $rel_makefile_in,
4051      'HAVE-MAKEFILE-IN-DEPS' => (@include_stack > 0),
4052      'MAKEFILE-IN-DEPS'    => "@include_stack",
4053      'MAKEFILE-AM'         => $rel_makefile_am,
4054      'AUTOMAKE-OPTIONS'    => $automake_options,
4055      'MAKEFILE-AM-SOURCES' => "$makefile$colon_infile",
4056      'REGEN-ACLOCAL-M4'    => $regen_aclocal_m4,
4057      VERBOSE               => verbose_flag ('GEN'));
4058
4059   if ($relative_dir eq '.')
4060     {
4061       &push_dist_common ('acconfig.h')
4062         if -f 'acconfig.h';
4063     }
4064
4065   # If we have a configure header, require it.
4066   my $hdr_index = 0;
4067   my @distclean_config;
4068   foreach my $spec (@config_headers)
4069     {
4070       $hdr_index += 1;
4071       # $CONFIG_H_PATH: config.h from top level.
4072       my ($config_h_path, @ins) = split_config_file_spec ($spec);
4073       my $config_h_dir = dirname ($config_h_path);
4074
4075       # If the header is in the current directory we want to build
4076       # the header here.  Otherwise, if we're at the topmost
4077       # directory and the header's directory doesn't have a
4078       # Makefile, then we also want to build the header.
4079       if ($relative_dir eq $config_h_dir
4080           || ($relative_dir eq '.' && ! &is_make_dir ($config_h_dir)))
4081         {
4082           my ($cn_sans_dir, $stamp_dir);
4083           if ($relative_dir eq $config_h_dir)
4084             {
4085               $cn_sans_dir = basename ($config_h_path);
4086               $stamp_dir = '';
4087             }
4088           else
4089             {
4090               $cn_sans_dir = $config_h_path;
4091               if ($config_h_dir eq '.')
4092                 {
4093                   $stamp_dir = '';
4094                 }
4095               else
4096                 {
4097                   $stamp_dir = $config_h_dir . '/';
4098                 }
4099             }
4100
4101           # This will also distribute all inputs.
4102           @ins = rewrite_inputs_into_dependencies ($config_h_path, @ins);
4103
4104           # Cannot define rebuild rules for filenames with shell variables.
4105           next if (substitute_ac_subst_variables $config_h_path) =~ /\$/;
4106
4107           # Header defined in this directory.
4108           my @files;
4109           if (-f $config_h_path . '.top')
4110             {
4111               push (@files, "$cn_sans_dir.top");
4112             }
4113           if (-f $config_h_path . '.bot')
4114             {
4115               push (@files, "$cn_sans_dir.bot");
4116             }
4117
4118           push_dist_common (@files);
4119
4120           # For now, acconfig.h can only appear in the top srcdir.
4121           if (-f 'acconfig.h')
4122             {
4123               push (@files, '$(top_srcdir)/acconfig.h');
4124             }
4125
4126           my $stamp = "${stamp_dir}stamp-h${hdr_index}";
4127           $output_rules .=
4128             file_contents ('remake-hdr',
4129                            new Automake::Location,
4130                            FILES            => "@files",
4131                            'FIRST-HDR'      => ($hdr_index == 1),
4132                            CONFIG_H         => $cn_sans_dir,
4133                            CONFIG_HIN       => $ins[0],
4134                            CONFIG_H_DEPS    => "@ins",
4135                            CONFIG_H_PATH    => $config_h_path,
4136                            STAMP            => "$stamp");
4137
4138           push @distclean_config, $cn_sans_dir, $stamp;
4139         }
4140     }
4141
4142   $output_rules .= file_contents ('clean-hdr',
4143                                   new Automake::Location,
4144                                   FILES => "@distclean_config")
4145     if @distclean_config;
4146
4147   # Distribute and define mkinstalldirs only if it is already present
4148   # in the package, for backward compatibility (some people may still
4149   # use $(mkinstalldirs)).
4150   # TODO: start warning about this in Automake 1.14, and have
4151   # TODO: Automake 2.0 drop it (and the mkinstalldirs script
4152   # TODO: as well).
4153   my $mkidpath = "$config_aux_dir/mkinstalldirs";
4154   if (-f $mkidpath)
4155     {
4156       # Use require_file so that any existing script gets updated
4157       # by --force-missing.
4158       require_conf_file ($mkidpath, FOREIGN, 'mkinstalldirs');
4159       define_variable ('mkinstalldirs',
4160                        "\$(SHELL) $am_config_aux_dir/mkinstalldirs", INTERNAL);
4161     }
4162   else
4163     {
4164       # Use $(install_sh), not $(MKDIR_P) because the latter requires
4165       # at least one argument, and $(mkinstalldirs) used to work
4166       # even without arguments (e.g. $(mkinstalldirs) $(conditional_dir)).
4167       define_variable ('mkinstalldirs', '$(install_sh) -d', INTERNAL);
4168     }
4169
4170   reject_var ('CONFIG_HEADER',
4171               "'CONFIG_HEADER' is an anachronism; now determined "
4172               . "automatically\nfrom '$configure_ac'");
4173
4174   my @config_h;
4175   foreach my $spec (@config_headers)
4176     {
4177       my ($out, @ins) = split_config_file_spec ($spec);
4178       # Generate CONFIG_HEADER define.
4179       if ($relative_dir eq dirname ($out))
4180         {
4181           push @config_h, basename ($out);
4182         }
4183       else
4184         {
4185           push @config_h, "\$(top_builddir)/$out";
4186         }
4187     }
4188   define_variable ("CONFIG_HEADER", "@config_h", INTERNAL)
4189     if @config_h;
4190
4191   # Now look for other files in this directory which must be remade
4192   # by config.status, and generate rules for them.
4193   my @actual_other_files = ();
4194   # These get cleaned only in a VPATH build.
4195   my @actual_other_vpath_files = ();
4196   foreach my $lfile (@other_input_files)
4197     {
4198       my $file;
4199       my @inputs;
4200       if ($lfile =~ /^([^:]*):(.*)$/)
4201         {
4202           # This is the ":" syntax of AC_OUTPUT.
4203           $file = $1;
4204           @inputs = split (':', $2);
4205         }
4206       else
4207         {
4208           # Normal usage.
4209           $file = $lfile;
4210           @inputs = $file . '.in';
4211         }
4212
4213       # Automake files should not be stored in here, but in %MAKE_LIST.
4214       prog_error ("$lfile in \@other_input_files\n"
4215                   . "\@other_input_files = (@other_input_files)")
4216         if -f $file . '.am';
4217
4218       my $local = basename ($file);
4219
4220       # We skip files that aren't in this directory.  However, if
4221       # the file's directory does not have a Makefile, and we are
4222       # currently doing '.', then we create a rule to rebuild the
4223       # file in the subdir.
4224       my $fd = dirname ($file);
4225       if ($fd ne $relative_dir)
4226         {
4227           if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4228             {
4229               $local = $file;
4230             }
4231           else
4232             {
4233               next;
4234             }
4235         }
4236
4237       my @rewritten_inputs = rewrite_inputs_into_dependencies ($file, @inputs);
4238
4239       # Cannot output rules for shell variables.
4240       next if (substitute_ac_subst_variables $local) =~ /\$/;
4241
4242       my $condstr = '';
4243       my $cond = $ac_config_files_condition{$lfile};
4244       if (defined $cond)
4245         {
4246           $condstr = $cond->subst_string;
4247           Automake::Rule::define ($local, $configure_ac, RULE_AUTOMAKE, $cond,
4248                                   $ac_config_files_location{$file});
4249         }
4250       $output_rules .= ($condstr . $local . ': '
4251                         . '$(top_builddir)/config.status '
4252                         . "@rewritten_inputs\n"
4253                         . $condstr . "\t"
4254                         . 'cd $(top_builddir) && '
4255                         . '$(SHELL) ./config.status '
4256                         . ($relative_dir eq '.' ? '' : '$(subdir)/')
4257                         . '$@'
4258                         . "\n");
4259       push (@actual_other_files, $local);
4260     }
4261
4262   # For links we should clean destinations and distribute sources.
4263   foreach my $spec (@config_links)
4264     {
4265       my ($link, $file) = split /:/, $spec;
4266       # Some people do AC_CONFIG_LINKS($computed).  We only handle
4267       # the DEST:SRC form.
4268       next unless $file;
4269       my $where = $ac_config_files_location{$link};
4270
4271       # Skip destinations that contain shell variables.
4272       if ((substitute_ac_subst_variables $link) !~ /\$/)
4273         {
4274           # We skip links that aren't in this directory.  However, if
4275           # the link's directory does not have a Makefile, and we are
4276           # currently doing '.', then we add the link to CONFIG_CLEAN_FILES
4277           # in '.'s Makefile.in.
4278           my $local = basename ($link);
4279           my $fd = dirname ($link);
4280           if ($fd ne $relative_dir)
4281             {
4282               if ($relative_dir eq '.' && ! &is_make_dir ($fd))
4283                 {
4284                   $local = $link;
4285                 }
4286               else
4287                 {
4288                   $local = undef;
4289                 }
4290             }
4291           if ($file ne $link)
4292             {
4293               push @actual_other_files, $local if $local;
4294             }
4295           else
4296             {
4297               push @actual_other_vpath_files, $local if $local;
4298             }
4299         }
4300
4301       # Do not process sources that contain shell variables.
4302       if ((substitute_ac_subst_variables $file) !~ /\$/)
4303         {
4304           my $fd = dirname ($file);
4305
4306           # We distribute files that are in this directory.
4307           # At the top-level ('.') we also distribute files whose
4308           # directory does not have a Makefile.
4309           if (($fd eq $relative_dir)
4310               || ($relative_dir eq '.' && ! &is_make_dir ($fd)))
4311             {
4312               # The following will distribute $file as a side-effect when
4313               # it is appropriate (i.e., when $file is not already an output).
4314               # We do not need the result, just the side-effect.
4315               rewrite_inputs_into_dependencies ($link, $file);
4316             }
4317         }
4318     }
4319
4320   # These files get removed by "make distclean".
4321   define_pretty_variable ('CONFIG_CLEAN_FILES', TRUE, INTERNAL,
4322                           @actual_other_files);
4323   define_pretty_variable ('CONFIG_CLEAN_VPATH_FILES', TRUE, INTERNAL,
4324                           @actual_other_vpath_files);
4325 }
4326
4327 # Handle C headers.
4328 sub handle_headers
4329 {
4330     my @r = &am_install_var ('-defaultdist', 'header', 'HEADERS', 'include',
4331                              'oldinclude', 'pkginclude',
4332                              'noinst', 'check');
4333     foreach (@r)
4334     {
4335       next unless $_->[1] =~ /\..*$/;
4336       &saw_extension ($&);
4337     }
4338 }
4339
4340 sub handle_gettext
4341 {
4342   return if ! $seen_gettext || $relative_dir ne '.';
4343
4344   my $subdirs = var 'SUBDIRS';
4345
4346   if (! $subdirs)
4347     {
4348       err_ac "AM_GNU_GETTEXT used but SUBDIRS not defined";
4349       return;
4350     }
4351
4352   # Perform some sanity checks to help users get the right setup.
4353   # We disable these tests when po/ doesn't exist in order not to disallow
4354   # unusual gettext setups.
4355   #
4356   # Bruno Haible:
4357   # | The idea is:
4358   # |
4359   # |  1) If a package doesn't have a directory po/ at top level, it
4360   # |     will likely have multiple po/ directories in subpackages.
4361   # |
4362   # |  2) It is useful to warn for the absence of intl/ if AM_GNU_GETTEXT
4363   # |     is used without 'external'. It is also useful to warn for the
4364   # |     presence of intl/ if AM_GNU_GETTEXT([external]) is used. Both
4365   # |     warnings apply only to the usual layout of packages, therefore
4366   # |     they should both be disabled if no po/ directory is found at
4367   # |     top level.
4368
4369   if (-d 'po')
4370     {
4371       my @subdirs = $subdirs->value_as_list_recursive;
4372
4373       msg_var ('syntax', $subdirs,
4374                "AM_GNU_GETTEXT used but 'po' not in SUBDIRS")
4375         if ! grep ($_ eq 'po', @subdirs);
4376
4377       # intl/ is not required when AM_GNU_GETTEXT is called with the
4378       # 'external' option and AM_GNU_GETTEXT_INTL_SUBDIR is not called.
4379       msg_var ('syntax', $subdirs,
4380                "AM_GNU_GETTEXT used but 'intl' not in SUBDIRS")
4381         if (! ($seen_gettext_external && ! $seen_gettext_intl)
4382             && ! grep ($_ eq 'intl', @subdirs));
4383
4384       # intl/ should not be used with AM_GNU_GETTEXT([external]), except
4385       # if AM_GNU_GETTEXT_INTL_SUBDIR is called.
4386       msg_var ('syntax', $subdirs,
4387                "'intl' should not be in SUBDIRS when "
4388                . "AM_GNU_GETTEXT([external]) is used")
4389         if ($seen_gettext_external && ! $seen_gettext_intl
4390             && grep ($_ eq 'intl', @subdirs));
4391     }
4392
4393   require_file ($ac_gettext_location, GNU, 'ABOUT-NLS');
4394 }
4395
4396 # Handle footer elements.
4397 sub handle_footer
4398 {
4399     reject_rule ('.SUFFIXES',
4400                  "use variable 'SUFFIXES', not target '.SUFFIXES'");
4401
4402     # Note: AIX 4.1 /bin/make will fail if any suffix rule appears
4403     # before .SUFFIXES.  So we make sure that .SUFFIXES appears before
4404     # anything else, by sticking it right after the default: target.
4405     $output_header .= ".SUFFIXES:\n";
4406     my $suffixes = var 'SUFFIXES';
4407     my @suffixes = Automake::Rule::suffixes;
4408     if (@suffixes || $suffixes)
4409     {
4410         # Make sure SUFFIXES has unique elements.  Sort them to ensure
4411         # the output remains consistent.  However, $(SUFFIXES) is
4412         # always at the start of the list, unsorted.  This is done
4413         # because make will choose rules depending on the ordering of
4414         # suffixes, and this lets the user have some control.  Push
4415         # actual suffixes, and not $(SUFFIXES).  Some versions of make
4416         # do not like variable substitutions on the .SUFFIXES line.
4417         my @user_suffixes = ($suffixes
4418                              ? $suffixes->value_as_list_recursive : ());
4419
4420         my %suffixes = map { $_ => 1 } @suffixes;
4421         delete @suffixes{@user_suffixes};
4422
4423         $output_header .= (".SUFFIXES: "
4424                            . join (' ', @user_suffixes, sort keys %suffixes)
4425                            . "\n");
4426     }
4427
4428     $output_trailer .= file_contents ('footer', new Automake::Location);
4429 }
4430
4431
4432 # Generate 'make install' rules.
4433 sub handle_install ()
4434 {
4435   $output_rules .= &file_contents
4436     ('install',
4437      new Automake::Location,
4438      maybe_BUILT_SOURCES => (set_seen ('BUILT_SOURCES')
4439                              ? (" \$(BUILT_SOURCES)\n"
4440                                 . "\t\$(MAKE) \$(AM_MAKEFLAGS)")
4441                              : ''),
4442      'installdirs-local' => (user_phony_rule 'installdirs-local'
4443                              ? ' installdirs-local' : ''),
4444      am__installdirs => variable_value ('am__installdirs') || '');
4445 }
4446
4447
4448 # Deal with all and all-am.
4449 sub handle_all ($)
4450 {
4451     my ($makefile) = @_;
4452
4453     # Output 'all-am'.
4454
4455     # Put this at the beginning for the sake of non-GNU makes.  This
4456     # is still wrong if these makes can run parallel jobs.  But it is
4457     # right enough.
4458     unshift (@all, basename ($makefile));
4459
4460     foreach my $spec (@config_headers)
4461       {
4462         my ($out, @ins) = split_config_file_spec ($spec);
4463         push (@all, basename ($out))
4464           if dirname ($out) eq $relative_dir;
4465       }
4466
4467     # Install 'all' hooks.
4468     push (@all, "all-local")
4469       if user_phony_rule "all-local";
4470
4471     &pretty_print_rule ("all-am:", "\t\t", @all);
4472     &depend ('.PHONY', 'all-am', 'all');
4473
4474
4475     # Output 'all'.
4476
4477     my @local_headers = ();
4478     push @local_headers, '$(BUILT_SOURCES)'
4479       if var ('BUILT_SOURCES');
4480     foreach my $spec (@config_headers)
4481       {
4482         my ($out, @ins) = split_config_file_spec ($spec);
4483         push @local_headers, basename ($out)
4484           if dirname ($out) eq $relative_dir;
4485       }
4486
4487     if (@local_headers)
4488       {
4489         # We need to make sure config.h is built before we recurse.
4490         # We also want to make sure that built sources are built
4491         # before any ordinary 'all' targets are run.  We can't do this
4492         # by changing the order of dependencies to the "all" because
4493         # that breaks when using parallel makes.  Instead we handle
4494         # things explicitly.
4495         $output_all .= ("all: @local_headers"
4496                         . "\n\t"
4497                         . '$(MAKE) $(AM_MAKEFLAGS) '
4498                         . (var ('SUBDIRS') ? 'all-recursive' : 'all-am')
4499                         . "\n\n");
4500         depend ('.MAKE', 'all');
4501       }
4502     else
4503       {
4504         $output_all .= "all: " . (var ('SUBDIRS')
4505                                   ? 'all-recursive' : 'all-am') . "\n\n";
4506       }
4507 }
4508
4509 # Generate helper targets for user recursion, where needed.
4510 sub handle_user_recursion ()
4511 {
4512   return unless @extra_recursive_targets;
4513
4514   define_pretty_variable ('am__extra_recursive_targets', TRUE, INTERNAL,
4515                           map { "$_-recursive" } @extra_recursive_targets);
4516   my $aux = var ('SUBDIRS') ? 'recursive' : 'am';
4517   foreach my $target (@extra_recursive_targets)
4518     {
4519       # This allows the default target's rules to be overridden in
4520       # Makefile.am.
4521       user_phony_rule ($target);
4522       depend ("$target", "$target-$aux");
4523       depend ("$target-am", "$target-local");
4524       # Every user-defined recursive target 'foo' *must* have a valid
4525       # associated 'foo-local' rule; we define it as an empty rule by
4526       # default, so that the user can transparently extend it in his
4527       # own Makefile.am.
4528       pretty_print_rule ("$target-local:");
4529       # $target-recursive might as well be undefined, so do not add
4530       # it here; it's taken care of in subdirs.am anyway.
4531       depend (".PHONY", "$target-am", "$target-local");
4532     }
4533 }
4534
4535
4536 # &do_check_merge_target ()
4537 # -------------------------
4538 # Handle check merge target specially.
4539 sub do_check_merge_target ()
4540 {
4541   # Include user-defined local form of target.
4542   push @check_tests, 'check-local'
4543     if user_phony_rule 'check-local';
4544
4545   # The check target must depend on the local equivalent of
4546   # 'all', to ensure all the primary targets are built.  Then it
4547   # must build the local check rules.
4548   $output_rules .= "check-am: all-am\n";
4549   if (@check)
4550     {
4551       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ", @check);
4552       depend ('.MAKE', 'check-am');
4553     }
4554
4555   if (@check_tests)
4556     {
4557       pretty_print_rule ("\t\$(MAKE) \$(AM_MAKEFLAGS)", "\t  ",
4558                          @check_tests);
4559       depend ('.MAKE', 'check-am');
4560     }
4561
4562   depend '.PHONY', 'check', 'check-am';
4563   # Handle recursion.  We have to honor BUILT_SOURCES like for 'all:'.
4564   $output_rules .= ("check: "
4565                     . (var ('BUILT_SOURCES')
4566                        ? "\$(BUILT_SOURCES)\n\t\$(MAKE) \$(AM_MAKEFLAGS) "
4567                        : '')
4568                     . (var ('SUBDIRS') ? 'check-recursive' : 'check-am')
4569                     . "\n");
4570   depend ('.MAKE', 'check')
4571     if var ('BUILT_SOURCES');
4572 }
4573
4574 # handle_clean ($MAKEFILE)
4575 # ------------------------
4576 # Handle all 'clean' targets.
4577 sub handle_clean ($)
4578 {
4579   my ($makefile) = @_;
4580
4581   # Clean the files listed in user variables if they exist.
4582   $clean_files{'$(MOSTLYCLEANFILES)'} = MOSTLY_CLEAN
4583     if var ('MOSTLYCLEANFILES');
4584   $clean_files{'$(CLEANFILES)'} = CLEAN
4585     if var ('CLEANFILES');
4586   $clean_files{'$(DISTCLEANFILES)'} = DIST_CLEAN
4587     if var ('DISTCLEANFILES');
4588   $clean_files{'$(MAINTAINERCLEANFILES)'} = MAINTAINER_CLEAN
4589     if var ('MAINTAINERCLEANFILES');
4590
4591   # Built sources are automatically removed by maintainer-clean.
4592   $clean_files{'$(BUILT_SOURCES)'} = MAINTAINER_CLEAN
4593     if var ('BUILT_SOURCES');
4594
4595   # Compute a list of "rm"s to run for each target.
4596   my %rms = (MOSTLY_CLEAN, [],
4597              CLEAN, [],
4598              DIST_CLEAN, [],
4599              MAINTAINER_CLEAN, []);
4600
4601   foreach my $file (keys %clean_files)
4602     {
4603       my $when = $clean_files{$file};
4604       prog_error 'invalid entry in %clean_files'
4605         unless exists $rms{$when};
4606
4607       my $rm = "rm -f $file";
4608       # If file is a variable, make sure when don't call 'rm -f' without args.
4609       $rm ="test -z \"$file\" || $rm"
4610         if ($file =~ /^\s*\$(\(.*\)|\{.*\})\s*$/);
4611
4612       push @{$rms{$when}}, "\t-$rm\n";
4613     }
4614
4615   $output_rules .= &file_contents
4616     ('clean',
4617      new Automake::Location,
4618      MOSTLYCLEAN_RMS      => join ('', sort @{$rms{&MOSTLY_CLEAN}}),
4619      CLEAN_RMS            => join ('', sort @{$rms{&CLEAN}}),
4620      DISTCLEAN_RMS        => join ('', sort @{$rms{&DIST_CLEAN}}),
4621      MAINTAINER_CLEAN_RMS => join ('', sort @{$rms{&MAINTAINER_CLEAN}}),
4622      MAKEFILE             => basename $makefile,
4623      );
4624 }
4625
4626
4627 # &target_cmp ($A, $B)
4628 # --------------------
4629 # Subroutine for &handle_factored_dependencies to let '.PHONY' and
4630 # other '.TARGETS' be last.
4631 sub target_cmp
4632 {
4633   return 0 if $a eq $b;
4634
4635   my $a1 = substr ($a, 0, 1);
4636   my $b1 = substr ($b, 0, 1);
4637   if ($a1 ne $b1)
4638     {
4639       return -1 if $b1 eq '.';
4640       return 1 if $a1 eq '.';
4641     }
4642   return $a cmp $b;
4643 }
4644
4645
4646 # &handle_factored_dependencies ()
4647 # --------------------------------
4648 # Handle everything related to gathered targets.
4649 sub handle_factored_dependencies
4650 {
4651   # Reject bad hooks.
4652   foreach my $utarg ('uninstall-data-local', 'uninstall-data-hook',
4653                      'uninstall-exec-local', 'uninstall-exec-hook',
4654                      'uninstall-dvi-local',
4655                      'uninstall-html-local',
4656                      'uninstall-info-local',
4657                      'uninstall-pdf-local',
4658                      'uninstall-ps-local')
4659     {
4660       my $x = $utarg;
4661       $x =~ s/-.*-/-/;
4662       reject_rule ($utarg, "use '$x', not '$utarg'");
4663     }
4664
4665   reject_rule ('install-local',
4666                "use 'install-data-local' or 'install-exec-local', "
4667                . "not 'install-local'");
4668
4669   reject_rule ('install-hook',
4670                "use 'install-data-hook' or 'install-exec-hook', "
4671                . "not 'install-hook'");
4672
4673   # Install the -local hooks.
4674   foreach (keys %dependencies)
4675     {
4676       # Hooks are installed on the -am targets.
4677       s/-am$// or next;
4678       depend ("$_-am", "$_-local")
4679         if user_phony_rule "$_-local";
4680     }
4681
4682   # Install the -hook hooks.
4683   # FIXME: Why not be as liberal as we are with -local hooks?
4684   foreach ('install-exec', 'install-data', 'uninstall')
4685     {
4686       if (user_phony_rule "$_-hook")
4687         {
4688           depend ('.MAKE', "$_-am");
4689           register_action("$_-am",
4690                           ("\t\@\$(NORMAL_INSTALL)\n"
4691                            . "\t\$(MAKE) \$(AM_MAKEFLAGS) $_-hook"));
4692         }
4693     }
4694
4695   # All the required targets are phony.
4696   depend ('.PHONY', keys %required_targets);
4697
4698   # Actually output gathered targets.
4699   foreach (sort target_cmp keys %dependencies)
4700     {
4701       # If there is nothing about this guy, skip it.
4702       next
4703         unless (@{$dependencies{$_}}
4704                 || $actions{$_}
4705                 || $required_targets{$_});
4706
4707       # Define gathered targets in undefined conditions.
4708       # FIXME: Right now we must handle .PHONY as an exception,
4709       # because people write things like
4710       #    .PHONY: myphonytarget
4711       # to append dependencies.  This would not work if Automake
4712       # refrained from defining its own .PHONY target as it does
4713       # with other overridden targets.
4714       # Likewise for '.MAKE'.
4715       my @undefined_conds = (TRUE,);
4716       if ($_ ne '.PHONY' && $_ ne '.MAKE')
4717         {
4718           @undefined_conds =
4719             Automake::Rule::define ($_, 'internal',
4720                                     RULE_AUTOMAKE, TRUE, INTERNAL);
4721         }
4722       my @uniq_deps = uniq (sort @{$dependencies{$_}});
4723       foreach my $cond (@undefined_conds)
4724         {
4725           my $condstr = $cond->subst_string;
4726           &pretty_print_rule ("$condstr$_:", "$condstr\t", @uniq_deps);
4727           $output_rules .= $actions{$_} if defined $actions{$_};
4728           $output_rules .= "\n";
4729         }
4730     }
4731 }
4732
4733
4734 # &handle_tests_dejagnu ()
4735 # ------------------------
4736 sub handle_tests_dejagnu
4737 {
4738     push (@check_tests, 'check-DEJAGNU');
4739     $output_rules .= file_contents ('dejagnu', new Automake::Location);
4740 }
4741
4742 sub handle_per_suffix_test
4743 {
4744   my ($test_suffix, %transform) = @_;
4745   my ($pfx, $generic, $am_exeext);
4746   if ($test_suffix eq '')
4747     {
4748       $pfx = '';
4749       $generic = 0;
4750       $am_exeext = 'FALSE';
4751     }
4752   else
4753     {
4754       prog_error ("test suffix '$test_suffix' lacks leading dot")
4755         unless $test_suffix =~ m/^\.(.*)/;
4756       $pfx = uc ($1) . '_';
4757       $generic = 1;
4758       $am_exeext = exists $configure_vars{'EXEEXT'} ? 'am__EXEEXT'
4759                                                     : 'FALSE';
4760     }
4761   # The "test driver" program, deputed to handle tests protocol used by
4762   # test scripts.  By default, it's assumed that no protocol is used, so
4763   # we fall back to the old behaviour, implemented by the 'test-driver'
4764   # auxiliary script.
4765   if (! var "${pfx}LOG_DRIVER")
4766     {
4767       require_conf_file ("parallel-tests", FOREIGN, 'test-driver');
4768       define_variable ("${pfx}LOG_DRIVER",
4769                        "\$(SHELL) $am_config_aux_dir/test-driver",
4770                        INTERNAL);
4771     }
4772   my $driver = '$(' . $pfx . 'LOG_DRIVER)';
4773   my $driver_flags = '$(AM_' . $pfx . 'LOG_DRIVER_FLAGS)'
4774                        . ' $(' . $pfx . 'LOG_DRIVER_FLAGS)';
4775   my $compile = "${pfx}LOG_COMPILE";
4776   define_variable ($compile,
4777                    '$(' . $pfx . 'LOG_COMPILER)'
4778                       . ' $(AM_' .  $pfx . 'LOG_FLAGS)'
4779                       . ' $(' . $pfx . 'LOG_FLAGS)',
4780                      INTERNAL);
4781   $output_rules .= file_contents ('check2', new Automake::Location,
4782                                    GENERIC => $generic,
4783                                    DRIVER => $driver,
4784                                    DRIVER_FLAGS => $driver_flags,
4785                                    COMPILE => '$(' . $compile . ')',
4786                                    EXT => $test_suffix,
4787                                    am__EXEEXT => $am_exeext,
4788                                    %transform);
4789 }
4790
4791 # is_valid_test_extension ($EXT)
4792 # ------------------------------
4793 # Return true if $EXT can appear in $(TEST_EXTENSIONS), return false
4794 # otherwise.
4795 sub is_valid_test_extension ($)
4796 {
4797   my $ext = shift;
4798   return 1
4799     if ($ext =~ /^\.[a-zA-Z_][a-zA-Z0-9_]*$/);
4800   return 1
4801     if (exists $configure_vars{'EXEEXT'} && $ext eq subst ('EXEEXT'));
4802   return 0;
4803 }
4804
4805 # Handle TESTS variable and other checks.
4806 sub handle_tests
4807 {
4808   if (option 'dejagnu')
4809     {
4810       &handle_tests_dejagnu;
4811     }
4812   else
4813     {
4814       foreach my $c ('DEJATOOL', 'RUNTEST', 'RUNTESTFLAGS')
4815         {
4816           reject_var ($c, "'$c' defined but 'dejagnu' not in "
4817                       . "'AUTOMAKE_OPTIONS'");
4818         }
4819     }
4820
4821   if (var ('TESTS'))
4822     {
4823       push (@check_tests, 'check-TESTS');
4824       my $check_deps = "@check";
4825       $output_rules .= &file_contents ('check', new Automake::Location,
4826                                        SERIAL_TESTS => !! option 'serial-tests',
4827                                        CHECK_DEPS => $check_deps);
4828
4829       # Tests that are known programs should have $(EXEEXT) appended.
4830       # For matching purposes, we need to adjust XFAIL_TESTS as well.
4831       append_exeext { exists $known_programs{$_[0]} } 'TESTS';
4832       append_exeext { exists $known_programs{$_[0]} } 'XFAIL_TESTS'
4833         if (var ('XFAIL_TESTS'));
4834
4835       if (! option 'serial-tests')
4836         {
4837           define_variable ('TEST_SUITE_LOG', 'test-suite.log', INTERNAL);
4838           my $suff = '.test';
4839           my $at_exeext = '';
4840           my $handle_exeext = exists $configure_vars{'EXEEXT'};
4841           if ($handle_exeext)
4842             {
4843               $at_exeext = subst ('EXEEXT');
4844               $suff = $at_exeext  . ' ' . $suff;
4845             }
4846           if (! var 'TEST_EXTENSIONS')
4847             {
4848               define_variable ('TEST_EXTENSIONS', $suff, INTERNAL);
4849             }
4850           my $var = var 'TEST_EXTENSIONS';
4851           # Currently, we are not able to deal with conditional contents
4852           # in TEST_EXTENSIONS.
4853           if ($var->has_conditional_contents)
4854            {
4855              msg_var 'unsupported', $var,
4856                      "'TEST_EXTENSIONS' cannot have conditional contents";
4857            }
4858           my @test_suffixes = $var->value_as_list_recursive;
4859           if ((my @invalid_test_suffixes =
4860                   grep { !is_valid_test_extension $_ } @test_suffixes) > 0)
4861             {
4862               error $var->rdef (TRUE)->location,
4863                     "invalid test extensions: @invalid_test_suffixes";
4864             }
4865           @test_suffixes = grep { is_valid_test_extension $_ } @test_suffixes;
4866           if ($handle_exeext)
4867             {
4868               unshift (@test_suffixes, $at_exeext)
4869                 unless $test_suffixes[0] eq $at_exeext;
4870             }
4871           unshift (@test_suffixes, '');
4872
4873           transform_variable_recursively
4874             ('TESTS', 'TEST_LOGS', 'am__testlogs', 1, INTERNAL,
4875               sub {
4876                 my ($subvar, $val, $cond, $full_cond) = @_;
4877                 my $obj = $val;
4878                 return $obj
4879                   if $val =~ /^\@.*\@$/;
4880                 $obj =~ s/\$\(EXEEXT\)$//o;
4881
4882                 if ($val =~ /(\$\((top_)?srcdir\))\//o)
4883                   {
4884                     msg ('error', $subvar->rdef ($cond)->location,
4885                          "using '$1' in TESTS is currently broken: '$val'");
4886                   }
4887
4888                 foreach my $test_suffix (@test_suffixes)
4889                   {
4890                     next
4891                       if $test_suffix eq $at_exeext || $test_suffix eq '';
4892                     return substr ($obj, 0, length ($obj) - length ($test_suffix)) . '.log'
4893                       if substr ($obj, - length ($test_suffix)) eq $test_suffix;
4894                   }
4895                 my $base = $obj;
4896                 $obj .= '.log';
4897                 handle_per_suffix_test ('',
4898                                         OBJ => $obj,
4899                                         BASE => $base,
4900                                         SOURCE => $val);
4901                 return $obj;
4902               });
4903
4904           my $nhelper=1;
4905           my $prev = 'TESTS';
4906           my $post = '';
4907           my $last_suffix = $test_suffixes[$#test_suffixes];
4908           my $cur = '';
4909           foreach my $test_suffix (@test_suffixes)
4910             {
4911               if ($test_suffix eq $last_suffix)
4912                 {
4913                   $cur = 'TEST_LOGS';
4914                 }
4915               else
4916                 {
4917                   $cur = 'am__test_logs' . $nhelper;
4918                 }
4919               define_variable ($cur,
4920                 '$(' . $prev . ':' . $test_suffix . $post . '=.log)', INTERNAL);
4921               $post = '.log';
4922               $prev = $cur;
4923               $nhelper++;
4924               if ($test_suffix ne $at_exeext && $test_suffix ne '')
4925                 {
4926                   handle_per_suffix_test ($test_suffix,
4927                                           OBJ => '',
4928                                           BASE => '$*',
4929                                           SOURCE => '$<');
4930                 }
4931             }
4932           $clean_files{'$(TEST_LOGS)'} = MOSTLY_CLEAN;
4933           $clean_files{'$(TEST_LOGS:.log=.trs)'} = MOSTLY_CLEAN;
4934           $clean_files{'$(TEST_SUITE_LOG)'} = MOSTLY_CLEAN;
4935         }
4936     }
4937 }
4938
4939 # Handle Emacs Lisp.
4940 sub handle_emacs_lisp
4941 {
4942   my @elfiles = &am_install_var ('-candist', 'lisp', 'LISP',
4943                                  'lisp', 'noinst');
4944
4945   return if ! @elfiles;
4946
4947   define_pretty_variable ('am__ELFILES', TRUE, INTERNAL,
4948                           map { $_->[1] } @elfiles);
4949   define_pretty_variable ('am__ELCFILES', TRUE, INTERNAL,
4950                           '$(am__ELFILES:.el=.elc)');
4951   # This one can be overridden by users.
4952   define_pretty_variable ('ELCFILES', TRUE, INTERNAL, '$(LISP:.el=.elc)');
4953
4954   push @all, '$(ELCFILES)';
4955
4956   require_variables ($elfiles[0][0], "Emacs Lisp sources seen", TRUE,
4957                      'EMACS', 'lispdir');
4958 }
4959
4960 # Handle Python
4961 sub handle_python
4962 {
4963   my @pyfiles = &am_install_var ('-defaultdist', 'python', 'PYTHON',
4964                                  'noinst');
4965   return if ! @pyfiles;
4966
4967   require_variables ($pyfiles[0][0], "Python sources seen", TRUE, 'PYTHON');
4968   require_conf_file ($pyfiles[0][0], FOREIGN, 'py-compile');
4969   &define_variable ('py_compile', "$am_config_aux_dir/py-compile", INTERNAL);
4970 }
4971
4972 # Handle Java.
4973 sub handle_java
4974 {
4975     my @sourcelist = &am_install_var ('-candist',
4976                                       'java', 'JAVA',
4977                                       'noinst', 'check');
4978     return if ! @sourcelist;
4979
4980     my @prefixes = am_primary_prefixes ('JAVA', 1,
4981                                         'noinst', 'check');
4982
4983     my $dir;
4984     my @java_sources = ();
4985     foreach my $prefix (@prefixes)
4986       {
4987         (my $curs = $prefix) =~ s/^(?:nobase_)?(?:dist_|nodist_)?//;
4988
4989         next
4990           if $curs eq 'EXTRA';
4991
4992         push @java_sources, '$(' . $prefix . '_JAVA' . ')';
4993
4994         if (defined $dir)
4995           {
4996             err_var "${curs}_JAVA", "multiple _JAVA primaries in use"
4997              unless $curs eq $dir;
4998           }
4999
5000         $dir = $curs;
5001       }
5002
5003     define_pretty_variable ('am__java_sources', TRUE, INTERNAL,
5004                             "@java_sources");
5005
5006     if ($dir eq 'check')
5007       {
5008         push (@check, "class$dir.stamp");
5009       }
5010     else
5011       {
5012         push (@all, "class$dir.stamp");
5013       }
5014 }
5015
5016
5017 # Handle some of the minor options.
5018 sub handle_minor_options
5019 {
5020   if (option 'readme-alpha')
5021     {
5022       if ($relative_dir eq '.')
5023         {
5024           if ($package_version !~ /^$GNITS_VERSION_PATTERN$/)
5025             {
5026               msg ('error-gnits', $package_version_location,
5027                    "version '$package_version' doesn't follow " .
5028                    "Gnits standards");
5029             }
5030           if (defined $1 && -f 'README-alpha')
5031             {
5032               # This means we have an alpha release.  See
5033               # GNITS_VERSION_PATTERN for details.
5034               push_dist_common ('README-alpha');
5035             }
5036         }
5037     }
5038 }
5039
5040 ################################################################
5041
5042 # ($OUTPUT, @INPUTS)
5043 # &split_config_file_spec ($SPEC)
5044 # -------------------------------
5045 # Decode the Autoconf syntax for config files (files, headers, links
5046 # etc.).
5047 sub split_config_file_spec ($)
5048 {
5049   my ($spec) = @_;
5050   my ($output, @inputs) = split (/:/, $spec);
5051
5052   push @inputs, "$output.in"
5053     unless @inputs;
5054
5055   return ($output, @inputs);
5056 }
5057
5058 # $input
5059 # locate_am (@POSSIBLE_SOURCES)
5060 # -----------------------------
5061 # AC_CONFIG_FILES allow specifications such as Makefile:top.in:mid.in:bot.in
5062 # This functions returns the first *.in file for which a *.am exists.
5063 # It returns undef otherwise.
5064 sub locate_am (@)
5065 {
5066   my (@rest) = @_;
5067   my $input;
5068   foreach my $file (@rest)
5069     {
5070       if (($file =~ /^(.*)\.in$/) && -f "$1.am")
5071         {
5072           $input = $file;
5073           last;
5074         }
5075     }
5076   return $input;
5077 }
5078
5079 my %make_list;
5080
5081 # &scan_autoconf_config_files ($WHERE, $CONFIG-FILES)
5082 # ---------------------------------------------------
5083 # Study $CONFIG-FILES which is the first argument to AC_CONFIG_FILES
5084 # (or AC_OUTPUT).
5085 sub scan_autoconf_config_files ($$)
5086 {
5087   my ($where, $config_files) = @_;
5088
5089   # Look at potential Makefile.am's.
5090   foreach (split ' ', $config_files)
5091     {
5092       # Must skip empty string for Perl 4.
5093       next if $_ eq "\\" || $_ eq '';
5094
5095       # Handle $local:$input syntax.
5096       my ($local, @rest) = split (/:/);
5097       @rest = ("$local.in",) unless @rest;
5098       # Keep in sync with test 'conffile-leading-dot.sh'.
5099       msg ('unsupported', $where,
5100            "omit leading './' from config file names such as '$local';"
5101            . "\nremake rules might be subtly broken otherwise")
5102         if ($local =~ /^\.\//);
5103       my $input = locate_am @rest;
5104       if ($input)
5105         {
5106           # We have a file that automake should generate.
5107           $make_list{$input} = join (':', ($local, @rest));
5108         }
5109       else
5110         {
5111           # We have a file that automake should cause to be
5112           # rebuilt, but shouldn't generate itself.
5113           push (@other_input_files, $_);
5114         }
5115       $ac_config_files_location{$local} = $where;
5116       $ac_config_files_condition{$local} =
5117         new Automake::Condition (@cond_stack)
5118           if (@cond_stack);
5119     }
5120 }
5121
5122
5123 # &scan_autoconf_traces ($FILENAME)
5124 # ---------------------------------
5125 sub scan_autoconf_traces ($)
5126 {
5127   my ($filename) = @_;
5128
5129   # Macros to trace, with their minimal number of arguments.
5130   #
5131   # IMPORTANT: If you add a macro here, you should also add this macro
5132   # =========  to Automake-preselection in autoconf/lib/autom4te.in.
5133   my %traced = (
5134                 AC_CANONICAL_BUILD => 0,
5135                 AC_CANONICAL_HOST => 0,
5136                 AC_CANONICAL_TARGET => 0,
5137                 AC_CONFIG_AUX_DIR => 1,
5138                 AC_CONFIG_FILES => 1,
5139                 AC_CONFIG_HEADERS => 1,
5140                 AC_CONFIG_LIBOBJ_DIR => 1,
5141                 AC_CONFIG_LINKS => 1,
5142                 AC_FC_SRCEXT => 1,
5143                 AC_INIT => 0,
5144                 AC_LIBSOURCE => 1,
5145                 AC_REQUIRE_AUX_FILE => 1,
5146                 AC_SUBST_TRACE => 1,
5147                 AM_AUTOMAKE_VERSION => 1,
5148                 AM_PROG_MKDIR_P => 0,
5149                 AM_CONDITIONAL => 2,
5150                 AM_EXTRA_RECURSIVE_TARGETS => 1,
5151                 AM_GNU_GETTEXT => 0,
5152                 AM_GNU_GETTEXT_INTL_SUBDIR => 0,
5153                 AM_INIT_AUTOMAKE => 0,
5154                 AM_MAINTAINER_MODE => 0,
5155                 AM_PROG_AR => 0,
5156                 AM_PROG_CC_C_O => 0,
5157                 _AM_SUBST_NOTMAKE => 1,
5158                 _AM_COND_IF => 1,
5159                 _AM_COND_ELSE => 1,
5160                 _AM_COND_ENDIF => 1,
5161                 LT_SUPPORTED_TAG => 1,
5162                 _LT_AC_TAGCONFIG => 0,
5163                 m4_include => 1,
5164                 m4_sinclude => 1,
5165                 sinclude => 1,
5166               );
5167
5168   my $traces = ($ENV{AUTOCONF} || '@am_AUTOCONF@') . " ";
5169
5170   # Use a separator unlikely to be used, not ':', the default, which
5171   # has a precise meaning for AC_CONFIG_FILES and so on.
5172   $traces .= join (' ',
5173                    map { "--trace=$_" . ':\$f:\$l::\$d::\$n::\${::}%' }
5174                    (keys %traced));
5175
5176   my $tracefh = new Automake::XFile ("$traces $filename |");
5177   verb "reading $traces";
5178
5179   @cond_stack = ();
5180   my $where;
5181
5182   while ($_ = $tracefh->getline)
5183     {
5184       chomp;
5185       my ($here, $depth, @args) = split (/::/);
5186       $where = new Automake::Location $here;
5187       my $macro = $args[0];
5188
5189       prog_error ("unrequested trace '$macro'")
5190         unless exists $traced{$macro};
5191
5192       # Skip and diagnose malformed calls.
5193       if ($#args < $traced{$macro})
5194         {
5195           msg ('syntax', $where, "not enough arguments for $macro");
5196           next;
5197         }
5198
5199       # Alphabetical ordering please.
5200       if ($macro eq 'AC_CANONICAL_BUILD')
5201         {
5202           if ($seen_canonical <= AC_CANONICAL_BUILD)
5203             {
5204               $seen_canonical = AC_CANONICAL_BUILD;
5205             }
5206         }
5207       elsif ($macro eq 'AC_CANONICAL_HOST')
5208         {
5209           if ($seen_canonical <= AC_CANONICAL_HOST)
5210             {
5211               $seen_canonical = AC_CANONICAL_HOST;
5212             }
5213         }
5214       elsif ($macro eq 'AC_CANONICAL_TARGET')
5215         {
5216           $seen_canonical = AC_CANONICAL_TARGET;
5217         }
5218       elsif ($macro eq 'AC_CONFIG_AUX_DIR')
5219         {
5220           if ($seen_init_automake)
5221             {
5222               error ($where, "AC_CONFIG_AUX_DIR must be called before "
5223                      . "AM_INIT_AUTOMAKE ...", partial => 1);
5224               error ($seen_init_automake, "... AM_INIT_AUTOMAKE called here");
5225             }
5226           $config_aux_dir = $args[1];
5227           $config_aux_dir_set_in_configure_ac = 1;
5228           check_directory ($config_aux_dir, $where);
5229         }
5230       elsif ($macro eq 'AC_CONFIG_FILES')
5231         {
5232           # Look at potential Makefile.am's.
5233           scan_autoconf_config_files ($where, $args[1]);
5234         }
5235       elsif ($macro eq 'AC_CONFIG_HEADERS')
5236         {
5237           foreach my $spec (split (' ', $args[1]))
5238             {
5239               my ($dest, @src) = split (':', $spec);
5240               $ac_config_files_location{$dest} = $where;
5241               push @config_headers, $spec;
5242             }
5243         }
5244       elsif ($macro eq 'AC_CONFIG_LIBOBJ_DIR')
5245         {
5246           $config_libobj_dir = $args[1];
5247           check_directory ($config_libobj_dir, $where);
5248         }
5249       elsif ($macro eq 'AC_CONFIG_LINKS')
5250         {
5251           foreach my $spec (split (' ', $args[1]))
5252             {
5253               my ($dest, $src) = split (':', $spec);
5254               $ac_config_files_location{$dest} = $where;
5255               push @config_links, $spec;
5256             }
5257         }
5258       elsif ($macro eq 'AC_FC_SRCEXT')
5259         {
5260           my $suffix = $args[1];
5261           # These flags are used as %SOURCEFLAG% in depend2.am,
5262           # where the trailing space is important.
5263           $sourceflags{'.' . $suffix} = '$(FCFLAGS_' . $suffix . ') '
5264             if ($suffix eq 'f90' || $suffix eq 'f95' || $suffix eq 'f03' || $suffix eq 'f08');
5265         }
5266       elsif ($macro eq 'AC_INIT')
5267         {
5268           if (defined $args[2])
5269             {
5270               $package_version = $args[2];
5271               $package_version_location = $where;
5272             }
5273         }
5274       elsif ($macro eq 'AC_LIBSOURCE')
5275         {
5276           $libsources{$args[1]} = $here;
5277         }
5278       elsif ($macro eq 'AC_REQUIRE_AUX_FILE')
5279         {
5280           # Only remember the first time a file is required.
5281           $required_aux_file{$args[1]} = $where
5282             unless exists $required_aux_file{$args[1]};
5283         }
5284       elsif ($macro eq 'AC_SUBST_TRACE')
5285         {
5286           # Just check for alphanumeric in AC_SUBST_TRACE.  If you do
5287           # AC_SUBST(5), then too bad.
5288           $configure_vars{$args[1]} = $where
5289             if $args[1] =~ /^\w+$/;
5290         }
5291       elsif ($macro eq 'AM_AUTOMAKE_VERSION')
5292         {
5293           error ($where,
5294                  "version mismatch.  This is Automake $VERSION,\n" .
5295                  "but the definition used by this AM_INIT_AUTOMAKE\n" .
5296                  "comes from Automake $args[1].  You should recreate\n" .
5297                  "aclocal.m4 with aclocal and run automake again.\n",
5298                  # $? = 63 is used to indicate version mismatch to missing.
5299                  exit_code => 63)
5300             if $VERSION ne $args[1];
5301
5302           $seen_automake_version = 1;
5303         }
5304       elsif ($macro eq 'AM_PROG_MKDIR_P')
5305         {
5306           msg 'obsolete', $where, <<'EOF';
5307 The 'AM_PROG_MKDIR_P' macro is deprecated, and its use is discouraged.
5308 You should use the Autoconf-provided 'AC_PROG_MKDIR_P' macro instead,
5309 and use '$(MKDIR_P)' instead of '$(mkdir_p)'in your Makefile.am files.
5310 EOF
5311         }
5312       elsif ($macro eq 'AM_CONDITIONAL')
5313         {
5314           $configure_cond{$args[1]} = $where;
5315         }
5316       elsif ($macro eq 'AM_EXTRA_RECURSIVE_TARGETS')
5317         {
5318           # Empty leading/trailing fields might be produced by split,
5319           # hence the grep is really needed.
5320           push @extra_recursive_targets,
5321                grep (/./, (split /\s+/, $args[1]));
5322         }
5323       elsif ($macro eq 'AM_GNU_GETTEXT')
5324         {
5325           $seen_gettext = $where;
5326           $ac_gettext_location = $where;
5327           $seen_gettext_external = grep ($_ eq 'external', @args);
5328         }
5329       elsif ($macro eq 'AM_GNU_GETTEXT_INTL_SUBDIR')
5330         {
5331           $seen_gettext_intl = $where;
5332         }
5333       elsif ($macro eq 'AM_INIT_AUTOMAKE')
5334         {
5335           $seen_init_automake = $where;
5336           if (defined $args[2])
5337             {
5338               msg 'obsolete', $where, <<'EOF';
5339 AM_INIT_AUTOMAKE: two- and three-arguments forms are deprecated.  For more info, see:
5340 http://www.gnu.org/software/automake/manual/automake.html#Modernize-AM_005fINIT_005fAUTOMAKE-invocation
5341 EOF
5342               $package_version = $args[2];
5343               $package_version_location = $where;
5344             }
5345           elsif (defined $args[1])
5346             {
5347               my @opts = split (' ', $args[1]);
5348               @opts = map { { option => $_, where => $where } } @opts;
5349               exit $exit_code if process_global_option_list (@opts);
5350             }
5351         }
5352       elsif ($macro eq 'AM_MAINTAINER_MODE')
5353         {
5354           $seen_maint_mode = $where;
5355         }
5356       elsif ($macro eq 'AM_PROG_AR')
5357         {
5358           $seen_ar = $where;
5359         }
5360       elsif ($macro eq 'AM_PROG_CC_C_O')
5361         {
5362           $seen_cc_c_o = $where;
5363         }
5364       elsif ($macro eq '_AM_COND_IF')
5365         {
5366           cond_stack_if ('', $args[1], $where);
5367           error ($where, "missing m4 quoting, macro depth $depth")
5368             if ($depth != 1);
5369         }
5370       elsif ($macro eq '_AM_COND_ELSE')
5371         {
5372           cond_stack_else ('!', $args[1], $where);
5373           error ($where, "missing m4 quoting, macro depth $depth")
5374             if ($depth != 1);
5375         }
5376       elsif ($macro eq '_AM_COND_ENDIF')
5377         {
5378           cond_stack_endif (undef, undef, $where);
5379           error ($where, "missing m4 quoting, macro depth $depth")
5380             if ($depth != 1);
5381         }
5382       elsif ($macro eq '_AM_SUBST_NOTMAKE')
5383         {
5384           $ignored_configure_vars{$args[1]} = $where;
5385         }
5386       elsif ($macro eq 'm4_include'
5387              || $macro eq 'm4_sinclude'
5388              || $macro eq 'sinclude')
5389         {
5390           # Skip missing 'sinclude'd files.
5391           next if $macro ne 'm4_include' && ! -f $args[1];
5392
5393           # Some modified versions of Autoconf don't use
5394           # frozen files.  Consequently it's possible that we see all
5395           # m4_include's performed during Autoconf's startup.
5396           # Obviously we don't want to distribute Autoconf's files
5397           # so we skip absolute filenames here.
5398           push @configure_deps, '$(top_srcdir)/' . $args[1]
5399             unless $here =~ m,^(?:\w:)?[\\/],;
5400           # Keep track of the greatest timestamp.
5401           if (-e $args[1])
5402             {
5403               my $mtime = mtime $args[1];
5404               $configure_deps_greatest_timestamp = $mtime
5405                 if $mtime > $configure_deps_greatest_timestamp;
5406             }
5407         }
5408       elsif ($macro eq 'LT_SUPPORTED_TAG')
5409         {
5410           $libtool_tags{$args[1]} = 1;
5411           $libtool_new_api = 1;
5412         }
5413       elsif ($macro eq '_LT_AC_TAGCONFIG')
5414         {
5415           # _LT_AC_TAGCONFIG is an old macro present in Libtool 1.5.
5416           # We use it to detect whether tags are supported.  Our
5417           # preferred interface is LT_SUPPORTED_TAG, but it was
5418           # introduced in Libtool 1.6.
5419           if (0 == keys %libtool_tags)
5420             {
5421               # Hardcode the tags supported by Libtool 1.5.
5422               %libtool_tags = (CC => 1, CXX => 1, GCJ => 1, F77 => 1);
5423             }
5424         }
5425     }
5426
5427   error ($where, "condition stack not properly closed")
5428     if (@cond_stack);
5429
5430   $tracefh->close;
5431 }
5432
5433
5434 # &scan_autoconf_files ()
5435 # -----------------------
5436 # Check whether we use 'configure.ac' or 'configure.in'.
5437 # Scan it (and possibly 'aclocal.m4') for interesting things.
5438 # We must scan aclocal.m4 because there might be AC_SUBSTs and such there.
5439 sub scan_autoconf_files ()
5440 {
5441   # Reinitialize libsources here.  This isn't really necessary,
5442   # since we currently assume there is only one configure.ac.  But
5443   # that won't always be the case.
5444   %libsources = ();
5445
5446   # Keep track of the youngest configure dependency.
5447   $configure_deps_greatest_timestamp = mtime $configure_ac;
5448   if (-e 'aclocal.m4')
5449     {
5450       my $mtime = mtime 'aclocal.m4';
5451       $configure_deps_greatest_timestamp = $mtime
5452         if $mtime > $configure_deps_greatest_timestamp;
5453     }
5454
5455   scan_autoconf_traces ($configure_ac);
5456
5457   @configure_input_files = sort keys %make_list;
5458   # Set input and output files if not specified by user.
5459   if (! @input_files)
5460     {
5461       @input_files = @configure_input_files;
5462       %output_files = %make_list;
5463     }
5464
5465
5466   if (! $seen_init_automake)
5467     {
5468       err_ac ("no proper invocation of AM_INIT_AUTOMAKE was found.\nYou "
5469               . "should verify that $configure_ac invokes AM_INIT_AUTOMAKE,"
5470               . "\nthat aclocal.m4 is present in the top-level directory,\n"
5471               . "and that aclocal.m4 was recently regenerated "
5472               . "(using aclocal)");
5473     }
5474   else
5475     {
5476       if (! $seen_automake_version)
5477         {
5478           if (-f 'aclocal.m4')
5479             {
5480               error ($seen_init_automake,
5481                      "your implementation of AM_INIT_AUTOMAKE comes from " .
5482                      "an\nold Automake version.  You should recreate " .
5483                      "aclocal.m4\nwith aclocal and run automake again",
5484                      # $? = 63 is used to indicate version mismatch to missing.
5485                      exit_code => 63);
5486             }
5487           else
5488             {
5489               error ($seen_init_automake,
5490                      "no proper implementation of AM_INIT_AUTOMAKE was " .
5491                      "found,\nprobably because aclocal.m4 is missing.\n" .
5492                      "You should run aclocal to create this file, then\n" .
5493                      "run automake again");
5494             }
5495         }
5496     }
5497
5498   locate_aux_dir ();
5499
5500   # Look for some files we need.  Always check for these.  This
5501   # check must be done for every run, even those where we are only
5502   # looking at a subdir Makefile.  We must set relative_dir for
5503   # push_required_file to work.
5504   # Sort the files for stable verbose output.
5505   $relative_dir = '.';
5506   foreach my $file (sort keys %required_aux_file)
5507     {
5508       require_conf_file ($required_aux_file{$file}->get, FOREIGN, $file)
5509     }
5510   err_am "'install.sh' is an anachronism; use 'install-sh' instead"
5511     if -f $config_aux_dir . '/install.sh';
5512
5513   # Preserve dist_common for later.
5514   $configure_dist_common = variable_value ('DIST_COMMON') || '';
5515
5516 }
5517
5518 ################################################################
5519
5520 # Do any extra checking for GNU standards.
5521 sub check_gnu_standards
5522 {
5523   if ($relative_dir eq '.')
5524     {
5525       # In top level (or only) directory.
5526       require_file ("$am_file.am", GNU,
5527                     qw/INSTALL NEWS README AUTHORS ChangeLog/);
5528
5529       # Accept one of these three licenses; default to COPYING.
5530       # Make sure we do not overwrite an existing license.
5531       my $license;
5532       foreach (qw /COPYING COPYING.LIB COPYING.LESSER/)
5533         {
5534           if (-f $_)
5535             {
5536               $license = $_;
5537               last;
5538             }
5539         }
5540       require_file ("$am_file.am", GNU, 'COPYING')
5541         unless $license;
5542     }
5543
5544   for my $opt ('no-installman', 'no-installinfo')
5545     {
5546       msg ('error-gnu', option $opt,
5547            "option '$opt' disallowed by GNU standards")
5548         if option $opt;
5549     }
5550 }
5551
5552 # Do any extra checking for GNITS standards.
5553 sub check_gnits_standards
5554 {
5555   if ($relative_dir eq '.')
5556     {
5557       # In top level (or only) directory.
5558       require_file ("$am_file.am", GNITS, 'THANKS');
5559     }
5560 }
5561
5562 ################################################################
5563 #
5564 # Functions to handle files of each language.
5565
5566 # Each 'lang_X_rewrite($DIRECTORY, $BASE, $EXT)' function follows a
5567 # simple formula: Return value is LANG_SUBDIR if the resulting object
5568 # file should be in a subdir if the source file is, LANG_PROCESS if
5569 # file is to be dealt with, LANG_IGNORE otherwise.
5570
5571 # Much of the actual processing is handled in
5572 # handle_single_transform.  These functions exist so that
5573 # auxiliary information can be recorded for a later cleanup pass.
5574 # Note that the calls to these functions are computed, so don't bother
5575 # searching for their precise names in the source.
5576
5577 # This is just a convenience function that can be used to determine
5578 # when a subdir object should be used.
5579 sub lang_sub_obj
5580 {
5581     return option 'subdir-objects' ? LANG_SUBDIR : LANG_PROCESS;
5582 }
5583
5584 # Rewrite a single C source file.
5585 sub lang_c_rewrite
5586 {
5587   my ($directory, $base, $ext, $obj, $have_per_exec_flags, $var) = @_;
5588
5589   my $r = LANG_PROCESS;
5590   if (option 'subdir-objects')
5591     {
5592       $r = LANG_SUBDIR;
5593       if ($directory && $directory ne '.')
5594         {
5595           $base = $directory . '/' . $base;
5596
5597           # libtool is always able to put the object at the proper place,
5598           # so we do not have to require AM_PROG_CC_C_O when building .lo files.
5599           msg_var ('portability', $var,
5600                    "compiling '$base.c' in subdir requires "
5601                    . "'AM_PROG_CC_C_O' in '$configure_ac'",
5602                    uniq_scope => US_GLOBAL,
5603                    uniq_part => 'AM_PROG_CC_C_O subdir')
5604             unless $seen_cc_c_o || $obj eq '.lo';
5605         }
5606     }
5607
5608   if (! $seen_cc_c_o
5609       && $have_per_exec_flags
5610       && ! option 'subdir-objects'
5611       && $obj ne '.lo')
5612     {
5613       msg_var ('portability',
5614                $var, "compiling '$base.c' with per-target flags requires "
5615                . "'AM_PROG_CC_C_O' in '$configure_ac'",
5616                uniq_scope => US_GLOBAL,
5617                uniq_part => 'AM_PROG_CC_C_O per-target')
5618     }
5619
5620     return $r;
5621 }
5622
5623 # Rewrite a single header file.
5624 sub lang_header_rewrite
5625 {
5626     # Header files are simply ignored.
5627     return LANG_IGNORE;
5628 }
5629
5630 # Rewrite a single Vala source file.
5631 sub lang_vala_rewrite
5632 {
5633     my ($directory, $base, $ext) = @_;
5634
5635     (my $newext = $ext) =~ s/vala$/c/;
5636     return (LANG_SUBDIR, $newext);
5637 }
5638
5639 # Rewrite a single yacc/yacc++ file.
5640 sub lang_yacc_rewrite
5641 {
5642     my ($directory, $base, $ext) = @_;
5643
5644     my $r = &lang_sub_obj;
5645     (my $newext = $ext) =~ tr/y/c/;
5646     return ($r, $newext);
5647 }
5648 sub lang_yaccxx_rewrite { lang_yacc_rewrite (@_); };
5649
5650 # Rewrite a single lex/lex++ file.
5651 sub lang_lex_rewrite
5652 {
5653     my ($directory, $base, $ext) = @_;
5654
5655     my $r = &lang_sub_obj;
5656     (my $newext = $ext) =~ tr/l/c/;
5657     return ($r, $newext);
5658 }
5659 sub lang_lexxx_rewrite { lang_lex_rewrite (@_); };
5660
5661 # Rewrite a single Java file.
5662 sub lang_java_rewrite
5663 {
5664     return LANG_SUBDIR;
5665 }
5666
5667 # The lang_X_finish functions are called after all source file
5668 # processing is done.  Each should handle defining rules for the
5669 # language, etc.  A finish function is only called if a source file of
5670 # the appropriate type has been seen.
5671
5672 sub lang_vala_finish_target ($$)
5673 {
5674   my ($self, $name) = @_;
5675
5676   my $derived = canonicalize ($name);
5677   my $var = var "${derived}_SOURCES";
5678   return unless $var;
5679
5680   my @vala_sources = grep { /\.(vala|vapi)$/ } ($var->value_as_list_recursive);
5681
5682   # For automake bug#11229.
5683   return unless @vala_sources;
5684
5685   foreach my $vala_file (@vala_sources)
5686     {
5687       my $c_file = $vala_file;
5688       if ($c_file =~ s/(.*)\.vala$/$1.c/)
5689         {
5690           $c_file = "\$(srcdir)/$c_file";
5691           $output_rules .= "$c_file: \$(srcdir)/${derived}_vala.stamp\n"
5692             . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5693             . "\t\@if test -f \$@; then :; else \\\n"
5694             . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5695             . "\tfi\n";
5696           $clean_files{$c_file} = MAINTAINER_CLEAN;
5697         }
5698     }
5699
5700   # Add rebuild rules for generated header and vapi files
5701   my $flags = var ($derived . '_VALAFLAGS');
5702   if ($flags)
5703     {
5704       my $lastflag = '';
5705       foreach my $flag ($flags->value_as_list_recursive)
5706         {
5707           if (grep (/$lastflag/, ('-H', '-h', '--header', '--internal-header',
5708                                   '--vapi', '--internal-vapi', '--gir')))
5709             {
5710               my $headerfile = "\$(srcdir)/$flag";
5711               $output_rules .= "$headerfile: \$(srcdir)/${derived}_vala.stamp\n"
5712                 . "\t\@if test -f \$@; then :; else rm -f \$(srcdir)/${derived}_vala.stamp; fi\n"
5713                 . "\t\@if test -f \$@; then :; else \\\n"
5714                 . "\t  \$(MAKE) \$(AM_MAKEFLAGS) \$(srcdir)/${derived}_vala.stamp; \\\n"
5715                 . "\tfi\n";
5716
5717               # valac is not used when building from dist tarballs
5718               # distribute the generated files
5719               push_dist_common ($headerfile);
5720               $clean_files{$headerfile} = MAINTAINER_CLEAN;
5721             }
5722           $lastflag = $flag;
5723         }
5724     }
5725
5726   my $compile = $self->compile;
5727
5728   # Rewrite each occurrence of 'AM_VALAFLAGS' in the compile
5729   # rule into '${derived}_VALAFLAGS' if it exists.
5730   my $val = "${derived}_VALAFLAGS";
5731   $compile =~ s/\(AM_VALAFLAGS\)/\($val\)/
5732     if set_seen ($val);
5733
5734   # VALAFLAGS is a user variable (per GNU Standards),
5735   # it should not be overridden in the Makefile...
5736   check_user_variables 'VALAFLAGS';
5737
5738   my $dirname = dirname ($name);
5739
5740   # Only generate C code, do not run C compiler
5741   $compile .= " -C";
5742
5743   my $verbose = verbose_flag ('VALAC');
5744   my $silent = silent_flag ();
5745   my $stampfile = "\$(srcdir)/${derived}_vala.stamp";
5746
5747   $output_rules .=
5748     "\$(srcdir)/${derived}_vala.stamp: @vala_sources\n".
5749 # Since the C files generated from the vala sources depend on the
5750 # ${derived}_vala.stamp file, we must ensure its timestamp is older than
5751 # those of the C files generated by the valac invocation below (this is
5752 # especially important on systems with sub-second timestamp resolution).
5753 # Thus we need to create the stamp file *before* invoking valac, and to
5754 # move it to its final location only after valac has been invoked.
5755     "\t${silent}rm -f \$\@ && echo stamp > \$\@-t\n".
5756     "\t${verbose}\$(am__cd) \$(srcdir) && $compile @vala_sources\n".
5757     "\t${silent}mv -f \$\@-t \$\@\n";
5758
5759   push_dist_common ($stampfile);
5760
5761   $clean_files{$stampfile} = MAINTAINER_CLEAN;
5762 }
5763
5764 # Add output rules to invoke valac and create stamp file as a witness
5765 # to handle multiple outputs. This function is called after all source
5766 # file processing is done.
5767 sub lang_vala_finish
5768 {
5769   my ($self) = @_;
5770
5771   foreach my $prog (keys %known_programs)
5772     {
5773       lang_vala_finish_target ($self, $prog);
5774     }
5775
5776   while (my ($name) = each %known_libraries)
5777     {
5778       lang_vala_finish_target ($self, $name);
5779     }
5780 }
5781
5782 # The built .c files should be cleaned only on maintainer-clean
5783 # as the .c files are distributed. This function is called for each
5784 # .vala source file.
5785 sub lang_vala_target_hook
5786 {
5787   my ($self, $aggregate, $output, $input, %transform) = @_;
5788
5789   $clean_files{$output} = MAINTAINER_CLEAN;
5790 }
5791
5792 # This is a yacc helper which is called whenever we have decided to
5793 # compile a yacc file.
5794 sub lang_yacc_target_hook
5795 {
5796     my ($self, $aggregate, $output, $input, %transform) = @_;
5797
5798     # If some relevant *YFLAGS variable contains the '-d' flag, we'll
5799     # have to to generate special code.
5800     my $yflags_contains_minus_d = 0;
5801
5802     foreach my $pfx ("", "${aggregate}_")
5803       {
5804         my $yflagsvar = var ("${pfx}YFLAGS");
5805         next unless $yflagsvar;
5806         # We cannot work reliably with conditionally-defined YFLAGS.
5807         if ($yflagsvar->has_conditional_contents)
5808           {
5809             msg_var ('unsupported', $yflagsvar,
5810                      "'${pfx}YFLAGS' cannot have conditional contents");
5811           }
5812         else
5813           {
5814             $yflags_contains_minus_d = 1
5815               if grep (/^-d$/, $yflagsvar->value_as_list_recursive);
5816           }
5817       }
5818
5819     if ($yflags_contains_minus_d)
5820       {
5821         # Found a '-d' that applies to the compilation of this file.
5822         # Add a dependency for the generated header file, and arrange
5823         # for that file to be included in the distribution.
5824
5825         # The extension of the output file (e.g., '.c' or '.cxx').
5826         # We'll need it to compute the name of the generated header file.
5827         (my $output_ext = basename ($output)) =~ s/.*(\.[^.]+)$/$1/;
5828
5829         # We know that a yacc input should be turned into either a C or
5830         # C++ output file.  We depend on this fact (here and in yacc.am),
5831         # so check that it really holds.
5832         my $lang = $languages{$extension_map{$output_ext}};
5833         prog_error "invalid output name '$output' for yacc file '$input'"
5834           if (!$lang || ($lang->name ne 'c' && $lang->name ne 'cxx'));
5835
5836         (my $header_ext = $output_ext) =~ s/c/h/g;
5837         # Quote $output_ext in the regexp, so that dots in it are taken
5838         # as literal dots, not as metacharacters.
5839         (my $header = $output) =~ s/\Q$output_ext\E$/$header_ext/;
5840
5841         foreach my $cond (Automake::Rule::define (${header}, 'internal',
5842                                                   RULE_AUTOMAKE, TRUE,
5843                                                   INTERNAL))
5844           {
5845             my $condstr = $cond->subst_string;
5846             $output_rules .=
5847               "$condstr${header}: $output\n"
5848               # Recover from removal of $header
5849               . "$condstr\t\@if test ! -f \$@; then rm -f $output; else :; fi\n"
5850               . "$condstr\t\@if test ! -f \$@; then \$(MAKE) \$(AM_MAKEFLAGS) $output; else :; fi\n";
5851           }
5852         # Distribute the generated file, unless its .y source was
5853         # listed in a nodist_ variable.  (&handle_source_transform
5854         # will set DIST_SOURCE.)
5855         &push_dist_common ($header)
5856           if $transform{'DIST_SOURCE'};
5857
5858         # The GNU rules say that yacc/lex output files should be removed
5859         # by maintainer-clean.  However, if the files are not distributed,
5860         # then we want to remove them with "make clean"; otherwise,
5861         # "make distcheck" will fail.
5862         $clean_files{$header} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5863       }
5864     # See the comment above for $HEADER.
5865     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5866 }
5867
5868 # This is a lex helper which is called whenever we have decided to
5869 # compile a lex file.
5870 sub lang_lex_target_hook
5871 {
5872     my ($self, $aggregate, $output, $input, %transform) = @_;
5873     # The GNU rules say that yacc/lex output files should be removed
5874     # by maintainer-clean.  However, if the files are not distributed,
5875     # then we want to remove them with "make clean"; otherwise,
5876     # "make distcheck" will fail.
5877     $clean_files{$output} = $transform{'DIST_SOURCE'} ? MAINTAINER_CLEAN : CLEAN;
5878 }
5879
5880 # This is a helper for both lex and yacc.
5881 sub yacc_lex_finish_helper
5882 {
5883   return if defined $language_scratch{'lex-yacc-done'};
5884   $language_scratch{'lex-yacc-done'} = 1;
5885
5886   # FIXME: for now, no line number.
5887   require_conf_file ($configure_ac, FOREIGN, 'ylwrap');
5888   &define_variable ('YLWRAP', "$am_config_aux_dir/ylwrap", INTERNAL);
5889 }
5890
5891 sub lang_yacc_finish
5892 {
5893   return if defined $language_scratch{'yacc-done'};
5894   $language_scratch{'yacc-done'} = 1;
5895
5896   reject_var 'YACCFLAGS', "'YACCFLAGS' obsolete; use 'YFLAGS' instead";
5897
5898   yacc_lex_finish_helper;
5899 }
5900
5901
5902 sub lang_lex_finish
5903 {
5904   return if defined $language_scratch{'lex-done'};
5905   $language_scratch{'lex-done'} = 1;
5906
5907   yacc_lex_finish_helper;
5908 }
5909
5910
5911 # Given a hash table of linker names, pick the name that has the most
5912 # precedence.  This is lame, but something has to have global
5913 # knowledge in order to eliminate the conflict.  Add more linkers as
5914 # required.
5915 sub resolve_linker
5916 {
5917     my (%linkers) = @_;
5918
5919     foreach my $l (qw(GCJLINK OBJCXXLINK CXXLINK F77LINK FCLINK OBJCLINK UPCLINK))
5920     {
5921         return $l if defined $linkers{$l};
5922     }
5923     return 'LINK';
5924 }
5925
5926 # Called to indicate that an extension was used.
5927 sub saw_extension
5928 {
5929     my ($ext) = @_;
5930     $extension_seen{$ext} = 1;
5931 }
5932
5933 # register_language (%ATTRIBUTE)
5934 # ------------------------------
5935 # Register a single language.
5936 # Each %ATTRIBUTE is of the form ATTRIBUTE => VALUE.
5937 sub register_language (%)
5938 {
5939   my (%option) = @_;
5940
5941   # Set the defaults.
5942   $option{'autodep'} = 'no'
5943     unless defined $option{'autodep'};
5944   $option{'linker'} = ''
5945     unless defined $option{'linker'};
5946   $option{'flags'} = []
5947     unless defined $option{'flags'};
5948   $option{'output_extensions'} = sub { return ( '.$(OBJEXT)', '.lo' ) }
5949     unless defined $option{'output_extensions'};
5950   $option{'nodist_specific'} = 0
5951     unless defined $option{'nodist_specific'};
5952
5953   my $lang = new Language (%option);
5954
5955   # Fill indexes.
5956   $extension_map{$_} = $lang->name foreach @{$lang->extensions};
5957   $languages{$lang->name} = $lang;
5958   my $link = $lang->linker;
5959   if ($link)
5960     {
5961       if (exists $link_languages{$link})
5962         {
5963           prog_error ("'$link' has different definitions in "
5964                       . $lang->name . " and " . $link_languages{$link}->name)
5965             if $lang->link ne $link_languages{$link}->link;
5966         }
5967       else
5968         {
5969           $link_languages{$link} = $lang;
5970         }
5971     }
5972
5973   # Update the pattern of known extensions.
5974   accept_extensions (@{$lang->extensions});
5975
5976   # Update the suffix rules map.
5977   foreach my $suffix (@{$lang->extensions})
5978     {
5979       foreach my $dest (&{$lang->output_extensions} ($suffix))
5980         {
5981           register_suffix_rule (INTERNAL, $suffix, $dest);
5982         }
5983     }
5984 }
5985
5986 # derive_suffix ($EXT, $OBJ)
5987 # --------------------------
5988 # This function is used to find a path from a user-specified suffix $EXT
5989 # to $OBJ or to some other suffix we recognize internally, e.g. 'cc'.
5990 sub derive_suffix ($$)
5991 {
5992   my ($source_ext, $obj) = @_;
5993
5994   while (!$extension_map{$source_ext} && $source_ext ne $obj)
5995     {
5996       my $new_source_ext = next_in_suffix_chain ($source_ext, $obj);
5997       last if not defined $new_source_ext;
5998       $source_ext = $new_source_ext;
5999     }
6000
6001   return $source_ext;
6002 }
6003
6004
6005 ################################################################
6006
6007 # Pretty-print something and append to output_rules.
6008 sub pretty_print_rule
6009 {
6010     $output_rules .= &makefile_wrap (@_);
6011 }
6012
6013
6014 ################################################################
6015
6016
6017 ## -------------------------------- ##
6018 ## Handling the conditional stack.  ##
6019 ## -------------------------------- ##
6020
6021
6022 # $STRING
6023 # make_conditional_string ($NEGATE, $COND)
6024 # ----------------------------------------
6025 sub make_conditional_string ($$)
6026 {
6027   my ($negate, $cond) = @_;
6028   $cond = "${cond}_TRUE"
6029     unless $cond =~ /^TRUE|FALSE$/;
6030   $cond = Automake::Condition::conditional_negate ($cond)
6031     if $negate;
6032   return $cond;
6033 }
6034
6035
6036 my %_am_macro_for_cond =
6037   (
6038   AMDEP => "one of the compiler tests\n"
6039            . "    AC_PROG_CC, AC_PROG_CXX, AC_PROG_OBJC, AC_PROG_OBJCXX,\n"
6040            . "    AM_PROG_AS, AM_PROG_GCJ, AM_PROG_UPC",
6041   am__fastdepCC => 'AC_PROG_CC',
6042   am__fastdepCCAS => 'AM_PROG_AS',
6043   am__fastdepCXX => 'AC_PROG_CXX',
6044   am__fastdepGCJ => 'AM_PROG_GCJ',
6045   am__fastdepOBJC => 'AC_PROG_OBJC',
6046   am__fastdepOBJCXX => 'AC_PROG_OBJCXX',
6047   am__fastdepUPC => 'AM_PROG_UPC'
6048   );
6049
6050 # $COND
6051 # cond_stack_if ($NEGATE, $COND, $WHERE)
6052 # --------------------------------------
6053 sub cond_stack_if ($$$)
6054 {
6055   my ($negate, $cond, $where) = @_;
6056
6057   if (! $configure_cond{$cond} && $cond !~ /^TRUE|FALSE$/)
6058     {
6059       my $text = "$cond does not appear in AM_CONDITIONAL";
6060       my $scope = US_LOCAL;
6061       if (exists $_am_macro_for_cond{$cond})
6062         {
6063           my $mac = $_am_macro_for_cond{$cond};
6064           $text .= "\n  The usual way to define '$cond' is to add ";
6065           $text .= ($mac =~ / /) ? $mac : "'$mac'";
6066           $text .= "\n  to '$configure_ac' and run 'aclocal' and 'autoconf' again";
6067           # These warnings appear in Automake files (depend2.am),
6068           # so there is no need to display them more than once:
6069           $scope = US_GLOBAL;
6070         }
6071       error $where, $text, uniq_scope => $scope;
6072     }
6073
6074   push (@cond_stack, make_conditional_string ($negate, $cond));
6075
6076   return new Automake::Condition (@cond_stack);
6077 }
6078
6079
6080 # $COND
6081 # cond_stack_else ($NEGATE, $COND, $WHERE)
6082 # ----------------------------------------
6083 sub cond_stack_else ($$$)
6084 {
6085   my ($negate, $cond, $where) = @_;
6086
6087   if (! @cond_stack)
6088     {
6089       error $where, "else without if";
6090       return FALSE;
6091     }
6092
6093   $cond_stack[$#cond_stack] =
6094     Automake::Condition::conditional_negate ($cond_stack[$#cond_stack]);
6095
6096   # If $COND is given, check against it.
6097   if (defined $cond)
6098     {
6099       $cond = make_conditional_string ($negate, $cond);
6100
6101       error ($where, "else reminder ($negate$cond) incompatible with "
6102              . "current conditional: $cond_stack[$#cond_stack]")
6103         if $cond_stack[$#cond_stack] ne $cond;
6104     }
6105
6106   return new Automake::Condition (@cond_stack);
6107 }
6108
6109
6110 # $COND
6111 # cond_stack_endif ($NEGATE, $COND, $WHERE)
6112 # -----------------------------------------
6113 sub cond_stack_endif ($$$)
6114 {
6115   my ($negate, $cond, $where) = @_;
6116   my $old_cond;
6117
6118   if (! @cond_stack)
6119     {
6120       error $where, "endif without if";
6121       return TRUE;
6122     }
6123
6124   # If $COND is given, check against it.
6125   if (defined $cond)
6126     {
6127       $cond = make_conditional_string ($negate, $cond);
6128
6129       error ($where, "endif reminder ($negate$cond) incompatible with "
6130              . "current conditional: $cond_stack[$#cond_stack]")
6131         if $cond_stack[$#cond_stack] ne $cond;
6132     }
6133
6134   pop @cond_stack;
6135
6136   return new Automake::Condition (@cond_stack);
6137 }
6138
6139
6140
6141
6142
6143 ## ------------------------ ##
6144 ## Handling the variables.  ##
6145 ## ------------------------ ##
6146
6147
6148 # &define_pretty_variable ($VAR, $COND, $WHERE, @VALUE)
6149 # -----------------------------------------------------
6150 # Like define_variable, but the value is a list, and the variable may
6151 # be defined conditionally.  The second argument is the condition
6152 # under which the value should be defined; this should be the empty
6153 # string to define the variable unconditionally.  The third argument
6154 # is a list holding the values to use for the variable.  The value is
6155 # pretty printed in the output file.
6156 sub define_pretty_variable ($$$@)
6157 {
6158     my ($var, $cond, $where, @value) = @_;
6159
6160     if (! vardef ($var, $cond))
6161     {
6162         Automake::Variable::define ($var, VAR_AUTOMAKE, '', $cond, "@value",
6163                                     '', $where, VAR_PRETTY);
6164         rvar ($var)->rdef ($cond)->set_seen;
6165     }
6166 }
6167
6168
6169 # define_variable ($VAR, $VALUE, $WHERE)
6170 # --------------------------------------
6171 # Define a new Automake Makefile variable VAR to VALUE, but only if
6172 # not already defined.
6173 sub define_variable ($$$)
6174 {
6175     my ($var, $value, $where) = @_;
6176     define_pretty_variable ($var, TRUE, $where, $value);
6177 }
6178
6179
6180 # define_files_variable ($VAR, \@BASENAME, $EXTENSION, $WHERE)
6181 # ------------------------------------------------------------
6182 # Define the $VAR which content is the list of file names composed of
6183 # a @BASENAME and the $EXTENSION.
6184 sub define_files_variable ($\@$$)
6185 {
6186   my ($var, $basename, $extension, $where) = @_;
6187   define_variable ($var,
6188                    join (' ', map { "$_.$extension" } @$basename),
6189                    $where);
6190 }
6191
6192
6193 # Like define_variable, but define a variable to be the configure
6194 # substitution by the same name.
6195 sub define_configure_variable ($)
6196 {
6197   my ($var) = @_;
6198   # Some variables we do not want to output.  For instance it
6199   # would be a bad idea to output `U = @U@` when `@U@` can be
6200   # substituted as `\`.
6201   my $pretty = exists $ignored_configure_vars{$var} ? VAR_SILENT : VAR_ASIS;
6202   Automake::Variable::define ($var, VAR_CONFIGURE, '', TRUE, subst $var,
6203                               '', $configure_vars{$var}, $pretty);
6204 }
6205
6206
6207 # define_compiler_variable ($LANG)
6208 # --------------------------------
6209 # Define a compiler variable.  We also handle defining the 'LT'
6210 # version of the command when using libtool.
6211 sub define_compiler_variable ($)
6212 {
6213     my ($lang) = @_;
6214
6215     my ($var, $value) = ($lang->compiler, $lang->compile);
6216     my $libtool_tag = '';
6217     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6218       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6219     &define_variable ($var, $value, INTERNAL);
6220     if (var ('LIBTOOL'))
6221       {
6222         my $verbose = define_verbose_libtool ();
6223         &define_variable ("LT$var",
6224                           "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6225                           . "\$(LIBTOOLFLAGS) --mode=compile $value",
6226                           INTERNAL);
6227       }
6228     define_verbose_tagvar ($lang->ccer || 'GEN');
6229 }
6230
6231
6232 # define_linker_variable ($LANG)
6233 # ------------------------------
6234 # Define linker variables.
6235 sub define_linker_variable ($)
6236 {
6237     my ($lang) = @_;
6238
6239     my $libtool_tag = '';
6240     $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6241       if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6242     # CCLD = $(CC).
6243     &define_variable ($lang->lder, $lang->ld, INTERNAL);
6244     # CCLINK = $(CCLD) blah blah...
6245     my $link = '';
6246     if (var ('LIBTOOL'))
6247       {
6248         my $verbose = define_verbose_libtool ();
6249         $link = "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) "
6250                 . "\$(LIBTOOLFLAGS) --mode=link ";
6251       }
6252     &define_variable ($lang->linker, $link . $lang->link, INTERNAL);
6253     &define_variable ($lang->compiler,  $lang);
6254     &define_verbose_tagvar ($lang->lder || 'GEN');
6255 }
6256
6257 sub define_per_target_linker_variable ($$)
6258 {
6259   my ($linker, $target) = @_;
6260
6261   # If the user wrote a custom link command, we don't define ours.
6262   return "${target}_LINK"
6263     if set_seen "${target}_LINK";
6264
6265   my $xlink = $linker ? $linker : 'LINK';
6266
6267   my $lang = $link_languages{$xlink};
6268   prog_error "Unknown language for linker variable '$xlink'"
6269     unless $lang;
6270
6271   my $link_command = $lang->link;
6272   if (var 'LIBTOOL')
6273     {
6274       my $libtool_tag = '';
6275       $libtool_tag = '--tag=' . $lang->libtool_tag . ' '
6276         if $lang->libtool_tag && exists $libtool_tags{$lang->libtool_tag};
6277
6278       my $verbose = define_verbose_libtool ();
6279       $link_command =
6280         "\$(LIBTOOL) $verbose $libtool_tag\$(AM_LIBTOOLFLAGS) \$(LIBTOOLFLAGS) "
6281         . "--mode=link " . $link_command;
6282     }
6283
6284   # Rewrite each occurrence of 'AM_$flag' in the link
6285   # command into '${derived}_$flag' if it exists.
6286   my $orig_command = $link_command;
6287   my @flags = (@{$lang->flags}, 'LDFLAGS');
6288   push @flags, 'LIBTOOLFLAGS' if var 'LIBTOOL';
6289   for my $flag (@flags)
6290     {
6291       my $val = "${target}_$flag";
6292       $link_command =~ s/\(AM_$flag\)/\($val\)/
6293         if set_seen ($val);
6294     }
6295
6296   # If the computed command is the same as the generic command, use
6297   # the command linker variable.
6298   return ($lang->linker, $lang->lder)
6299     if $link_command eq $orig_command;
6300
6301   &define_variable ("${target}_LINK", $link_command, INTERNAL);
6302   return ("${target}_LINK", $lang->lder);
6303 }
6304
6305 ################################################################
6306
6307 # &check_trailing_slash ($WHERE, $LINE)
6308 # -------------------------------------
6309 # Return 1 iff $LINE ends with a slash.
6310 # Might modify $LINE.
6311 sub check_trailing_slash ($\$)
6312 {
6313   my ($where, $line) = @_;
6314
6315   # Ignore '##' lines.
6316   return 0 if $$line =~ /$IGNORE_PATTERN/o;
6317
6318   # Catch and fix a common error.
6319   msg "syntax", $where, "whitespace following trailing backslash"
6320     if $$line =~ s/\\\s+\n$/\\\n/;
6321
6322   return $$line =~ /\\$/;
6323 }
6324
6325
6326 # &read_am_file ($AMFILE, $WHERE)
6327 # -------------------------------
6328 # Read Makefile.am and set up %contents.  Simultaneously copy lines
6329 # from Makefile.am into $output_trailer, or define variables as
6330 # appropriate.  NOTE we put rules in the trailer section.  We want
6331 # user rules to come after our generated stuff.
6332 sub read_am_file ($$)
6333 {
6334     my ($amfile, $where) = @_;
6335
6336     my $am_file = new Automake::XFile ("< $amfile");
6337     verb "reading $amfile";
6338
6339     # Keep track of the youngest output dependency.
6340     my $mtime = mtime $amfile;
6341     $output_deps_greatest_timestamp = $mtime
6342       if $mtime > $output_deps_greatest_timestamp;
6343
6344     my $spacing = '';
6345     my $comment = '';
6346     my $blank = 0;
6347     my $saw_bk = 0;
6348     my $var_look = VAR_ASIS;
6349
6350     use constant IN_VAR_DEF => 0;
6351     use constant IN_RULE_DEF => 1;
6352     use constant IN_COMMENT => 2;
6353     my $prev_state = IN_RULE_DEF;
6354
6355     while ($_ = $am_file->getline)
6356     {
6357         $where->set ("$amfile:$.");
6358         if (/$IGNORE_PATTERN/o)
6359         {
6360             # Merely delete comments beginning with two hashes.
6361         }
6362         elsif (/$WHITE_PATTERN/o)
6363         {
6364             error $where, "blank line following trailing backslash"
6365               if $saw_bk;
6366             # Stick a single white line before the incoming macro or rule.
6367             $spacing = "\n";
6368             $blank = 1;
6369             # Flush all comments seen so far.
6370             if ($comment ne '')
6371             {
6372                 $output_vars .= $comment;
6373                 $comment = '';
6374             }
6375         }
6376         elsif (/$COMMENT_PATTERN/o)
6377         {
6378             # Stick comments before the incoming macro or rule.  Make
6379             # sure a blank line precedes the first block of comments.
6380             $spacing = "\n" unless $blank;
6381             $blank = 1;
6382             $comment .= $spacing . $_;
6383             $spacing = '';
6384             $prev_state = IN_COMMENT;
6385         }
6386         else
6387         {
6388             last;
6389         }
6390         $saw_bk = check_trailing_slash ($where, $_);
6391     }
6392
6393     # We save the conditional stack on entry, and then check to make
6394     # sure it is the same on exit.  This lets us conditionally include
6395     # other files.
6396     my @saved_cond_stack = @cond_stack;
6397     my $cond = new Automake::Condition (@cond_stack);
6398
6399     my $last_var_name = '';
6400     my $last_var_type = '';
6401     my $last_var_value = '';
6402     my $last_where;
6403     # FIXME: shouldn't use $_ in this loop; it is too big.
6404     while ($_)
6405     {
6406         $where->set ("$amfile:$.");
6407
6408         # Make sure the line is \n-terminated.
6409         chomp;
6410         $_ .= "\n";
6411
6412         # Don't look at MAINTAINER_MODE_TRUE here.  That shouldn't be
6413         # used by users.  @MAINT@ is an anachronism now.
6414         $_ =~ s/\@MAINT\@//g
6415             unless $seen_maint_mode;
6416
6417         my $new_saw_bk = check_trailing_slash ($where, $_);
6418
6419         if (/$IGNORE_PATTERN/o)
6420         {
6421             # Merely delete comments beginning with two hashes.
6422
6423             # Keep any backslash from the previous line.
6424             $new_saw_bk = $saw_bk;
6425         }
6426         elsif (/$WHITE_PATTERN/o)
6427         {
6428             # Stick a single white line before the incoming macro or rule.
6429             $spacing = "\n";
6430             error $where, "blank line following trailing backslash"
6431               if $saw_bk;
6432         }
6433         elsif (/$COMMENT_PATTERN/o)
6434         {
6435             error $where, "comment following trailing backslash"
6436               if $saw_bk && $prev_state != IN_COMMENT;
6437
6438             # Stick comments before the incoming macro or rule.
6439             $comment .= $spacing . $_;
6440             $spacing = '';
6441             $prev_state = IN_COMMENT;
6442         }
6443         elsif ($saw_bk)
6444         {
6445             if ($prev_state == IN_RULE_DEF)
6446             {
6447               my $cond = new Automake::Condition @cond_stack;
6448               $output_trailer .= $cond->subst_string;
6449               $output_trailer .= $_;
6450             }
6451             elsif ($prev_state == IN_COMMENT)
6452             {
6453                 # If the line doesn't start with a '#', add it.
6454                 # We do this because a continued comment like
6455                 #   # A = foo \
6456                 #         bar \
6457                 #         baz
6458                 # is not portable.  BSD make doesn't honor
6459                 # escaped newlines in comments.
6460                 s/^#?/#/;
6461                 $comment .= $spacing . $_;
6462             }
6463             else # $prev_state == IN_VAR_DEF
6464             {
6465               $last_var_value .= ' '
6466                 unless $last_var_value =~ /\s$/;
6467               $last_var_value .= $_;
6468
6469               if (!/\\$/)
6470                 {
6471                   Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6472                                               $last_var_type, $cond,
6473                                               $last_var_value, $comment,
6474                                               $last_where, VAR_ASIS)
6475                     if $cond != FALSE;
6476                   $comment = $spacing = '';
6477                 }
6478             }
6479         }
6480
6481         elsif (/$IF_PATTERN/o)
6482           {
6483             $cond = cond_stack_if ($1, $2, $where);
6484           }
6485         elsif (/$ELSE_PATTERN/o)
6486           {
6487             $cond = cond_stack_else ($1, $2, $where);
6488           }
6489         elsif (/$ENDIF_PATTERN/o)
6490           {
6491             $cond = cond_stack_endif ($1, $2, $where);
6492           }
6493
6494         elsif (/$RULE_PATTERN/o)
6495         {
6496             # Found a rule.
6497             $prev_state = IN_RULE_DEF;
6498
6499             # For now we have to output all definitions of user rules
6500             # and can't diagnose duplicates (see the comment in
6501             # Automake::Rule::define). So we go on and ignore the return value.
6502             Automake::Rule::define ($1, $amfile, RULE_USER, $cond, $where);
6503
6504             check_variable_expansions ($_, $where);
6505
6506             $output_trailer .= $comment . $spacing;
6507             my $cond = new Automake::Condition @cond_stack;
6508             $output_trailer .= $cond->subst_string;
6509             $output_trailer .= $_;
6510             $comment = $spacing = '';
6511         }
6512         elsif (/$ASSIGNMENT_PATTERN/o)
6513         {
6514             # Found a macro definition.
6515             $prev_state = IN_VAR_DEF;
6516             $last_var_name = $1;
6517             $last_var_type = $2;
6518             $last_var_value = $3;
6519             $last_where = $where->clone;
6520             if ($3 ne '' && substr ($3, -1) eq "\\")
6521               {
6522                 # We preserve the '\' because otherwise the long lines
6523                 # that are generated will be truncated by broken
6524                 # 'sed's.
6525                 $last_var_value = $3 . "\n";
6526               }
6527             # Normally we try to output variable definitions in the
6528             # same format they were input.  However, POSIX compliant
6529             # systems are not required to support lines longer than
6530             # 2048 bytes (most notably, some sed implementation are
6531             # limited to 4000 bytes, and sed is used by config.status
6532             # to rewrite Makefile.in into Makefile).  Moreover nobody
6533             # would really write such long lines by hand since it is
6534             # hardly maintainable.  So if a line is longer that 1000
6535             # bytes (an arbitrary limit), assume it has been
6536             # automatically generated by some tools, and flatten the
6537             # variable definition.  Otherwise, keep the variable as it
6538             # as been input.
6539             $var_look = VAR_PRETTY if length ($last_var_value) >= 1000;
6540
6541             if (!/\\$/)
6542               {
6543                 Automake::Variable::define ($last_var_name, VAR_MAKEFILE,
6544                                             $last_var_type, $cond,
6545                                             $last_var_value, $comment,
6546                                             $last_where, $var_look)
6547                   if $cond != FALSE;
6548                 $comment = $spacing = '';
6549                 $var_look = VAR_ASIS;
6550               }
6551         }
6552         elsif (/$INCLUDE_PATTERN/o)
6553         {
6554             my $path = $1;
6555
6556             if ($path =~ s/^\$\(top_srcdir\)\///)
6557               {
6558                 push (@include_stack, "\$\(top_srcdir\)/$path");
6559                 # Distribute any included file.
6560
6561                 # Always use the $(top_srcdir) prefix in DIST_COMMON,
6562                 # otherwise OSF make will implicitly copy the included
6563                 # file in the build tree during "make distdir" to satisfy
6564                 # the dependency.
6565                 # (subdir-am-cond.sh and subdir-ac-cond.sh will fail)
6566                 push_dist_common ("\$\(top_srcdir\)/$path");
6567               }
6568             else
6569               {
6570                 $path =~ s/\$\(srcdir\)\///;
6571                 push (@include_stack, "\$\(srcdir\)/$path");
6572                 # Always use the $(srcdir) prefix in DIST_COMMON,
6573                 # otherwise OSF make will implicitly copy the included
6574                 # file in the build tree during "make distdir" to satisfy
6575                 # the dependency.
6576                 # (subdir-am-cond.sh and subdir-ac-cond.sh will fail)
6577                 push_dist_common ("\$\(srcdir\)/$path");
6578                 $path = $relative_dir . "/" . $path if $relative_dir ne '.';
6579               }
6580             $where->push_context ("'$path' included from here");
6581             &read_am_file ($path, $where);
6582             $where->pop_context;
6583         }
6584         else
6585         {
6586             # This isn't an error; it is probably a continued rule.
6587             # In fact, this is what we assume.
6588             $prev_state = IN_RULE_DEF;
6589             check_variable_expansions ($_, $where);
6590             $output_trailer .= $comment . $spacing;
6591             my $cond = new Automake::Condition @cond_stack;
6592             $output_trailer .= $cond->subst_string;
6593             $output_trailer .= $_;
6594             $comment = $spacing = '';
6595             error $where, "'#' comment at start of rule is unportable"
6596               if $_ =~ /^\t\s*\#/;
6597         }
6598
6599         $saw_bk = $new_saw_bk;
6600         $_ = $am_file->getline;
6601     }
6602
6603     $output_trailer .= $comment;
6604
6605     error ($where, "trailing backslash on last line")
6606       if $saw_bk;
6607
6608     error ($where, (@cond_stack ? "unterminated conditionals: @cond_stack"
6609                     : "too many conditionals closed in include file"))
6610       if "@saved_cond_stack" ne "@cond_stack";
6611 }
6612
6613
6614 # define_standard_variables ()
6615 # ----------------------------
6616 # A helper for read_main_am_file which initializes configure variables
6617 # and variables from header-vars.am.
6618 sub define_standard_variables
6619 {
6620   my $saved_output_vars = $output_vars;
6621   my ($comments, undef, $rules) =
6622     file_contents_internal (1, "$libdir/am/header-vars.am",
6623                             new Automake::Location);
6624
6625   foreach my $var (sort keys %configure_vars)
6626     {
6627       &define_configure_variable ($var);
6628     }
6629
6630   $output_vars .= $comments . $rules;
6631 }
6632
6633 # Read main am file.
6634 sub read_main_am_file ($$)
6635 {
6636     my ($amfile, $infile) = @_;
6637
6638     # This supports the strange variable tricks we are about to play.
6639     prog_error ("variable defined before read_main_am_file\n" . variables_dump ())
6640       if (scalar (variables) > 0);
6641
6642     # Generate copyright header for generated Makefile.in.
6643     # We do discard the output of predefined variables, handled below.
6644     $output_vars = ("# " . basename ($infile) . " generated by automake "
6645                    . $VERSION . " from " . basename ($amfile) . ".\n");
6646     $output_vars .= '# ' . subst ('configure_input') . "\n";
6647     $output_vars .= $gen_copyright;
6648
6649     # We want to predefine as many variables as possible.  This lets
6650     # the user set them with '+=' in Makefile.am.
6651     &define_standard_variables;
6652
6653     # Read user file, which might override some of our values.
6654     &read_am_file ($amfile, new Automake::Location);
6655 }
6656
6657
6658
6659 ################################################################
6660
6661 # $FLATTENED
6662 # &flatten ($STRING)
6663 # ------------------
6664 # Flatten the $STRING and return the result.
6665 sub flatten
6666 {
6667   $_ = shift;
6668
6669   s/\\\n//somg;
6670   s/\s+/ /g;
6671   s/^ //;
6672   s/ $//;
6673
6674   return $_;
6675 }
6676
6677
6678 # transform_token ($TOKEN, \%PAIRS, $KEY)
6679 # =======================================
6680 # Return the value associated to $KEY in %PAIRS, as used on $TOKEN
6681 # (which should be ?KEY? or any of the special %% requests)..
6682 sub transform_token ($$$)
6683 {
6684   my ($token, $transform, $key) = @_;
6685   my $res = $transform->{$key};
6686   prog_error "Unknown key '$key' in '$token'" unless defined $res;
6687   return $res;
6688 }
6689
6690
6691 # transform ($TOKEN, \%PAIRS)
6692 # ===========================
6693 # If ($TOKEN, $VAL) is in %PAIRS:
6694 #   - replaces %KEY% with $VAL,
6695 #   - enables/disables ?KEY? and ?!KEY?,
6696 #   - replaces %?KEY% with TRUE or FALSE.
6697 sub transform ($$)
6698 {
6699   my ($token, $transform) = @_;
6700
6701   # %KEY%.
6702   # Must be before the following pattern to exclude the case
6703   # when there is neither IFTRUE nor IFFALSE.
6704   if ($token =~ /^%([\w\-]+)%$/)
6705     {
6706       return transform_token ($token, $transform, $1);
6707     }
6708   # %?KEY%.
6709   elsif ($token =~ /^%\?([\w\-]+)%$/)
6710     {
6711       return transform_token ($token, $transform, $1) ? 'TRUE' : 'FALSE';
6712     }
6713   # ?KEY? and ?!KEY?.
6714   elsif ($token =~ /^ \? (!?) ([\w\-]+) \? $/x)
6715     {
6716       my $neg = ($1 eq '!') ? 1 : 0;
6717       my $val = transform_token ($token, $transform, $2);
6718       return (!!$val == $neg) ? '##%' : '';
6719     }
6720   else
6721     {
6722       prog_error "Unknown request format: $token";
6723     }
6724 }
6725
6726 # $TEXT
6727 # preprocess_file ($MAKEFILE, [%TRANSFORM])
6728 # -----------------------------------------
6729 # Load a $MAKEFILE, apply the %TRANSFORM, and return the result.
6730 # No extra parsing or post-processing is done (i.e., recognition of
6731 # rules declaration or of make variables definitions).
6732 sub preprocess_file ($%)
6733 {
6734   my ($file, %transform) = @_;
6735
6736   # Complete %transform with global options.
6737   # Note that %transform goes last, so it overrides global options.
6738   %transform = ( 'MAINTAINER-MODE'
6739                  => $seen_maint_mode ? subst ('MAINTAINER_MODE_TRUE') : '',
6740
6741                  'XZ'          => !! option 'dist-xz',
6742                  'LZIP'        => !! option 'dist-lzip',
6743                  'BZIP2'       => !! option 'dist-bzip2',
6744                  'COMPRESS'    => !! option 'dist-tarZ',
6745                  'GZIP'        =>  ! option 'no-dist-gzip',
6746                  'SHAR'        => !! option 'dist-shar',
6747                  'ZIP'         => !! option 'dist-zip',
6748
6749                  'INSTALL-INFO' =>  ! option 'no-installinfo',
6750                  'INSTALL-MAN'  =>  ! option 'no-installman',
6751                  'CK-NEWS'      => !! option 'check-news',
6752
6753                  'SUBDIRS'      => !! var ('SUBDIRS'),
6754                  'TOPDIR_P'     => $relative_dir eq '.',
6755
6756                  'BUILD'    => ($seen_canonical >= AC_CANONICAL_BUILD),
6757                  'HOST'     => ($seen_canonical >= AC_CANONICAL_HOST),
6758                  'TARGET'   => ($seen_canonical >= AC_CANONICAL_TARGET),
6759
6760                  'LIBTOOL'      => !! var ('LIBTOOL'),
6761                  'NONLIBTOOL'   => 1,
6762                 %transform);
6763
6764   if (! defined ($_ = $am_file_cache{$file}))
6765     {
6766       verb "reading $file";
6767       # Swallow the whole file.
6768       my $fc_file = new Automake::XFile "< $file";
6769       my $saved_dollar_slash = $/;
6770       undef $/;
6771       $_ = $fc_file->getline;
6772       $/ = $saved_dollar_slash;
6773       $fc_file->close;
6774       # Remove ##-comments.
6775       # Besides we don't need more than two consecutive new-lines.
6776       s/(?:$IGNORE_PATTERN|(?<=\n\n)\n+)//gom;
6777       # Remember the contents of the just-read file.
6778       $am_file_cache{$file} = $_;
6779     }
6780
6781   # Substitute Automake template tokens.
6782   s/(?: % \?? [\w\-]+ %
6783       | \? !? [\w\-]+ \?
6784     )/transform($&, \%transform)/gex;
6785   # transform() may have added some ##%-comments to strip.
6786   # (we use '##%' instead of '##' so we can distinguish ##%##%##% from
6787   # ####### and do not remove the latter.)
6788   s/^[ \t]*(?:##%)+.*\n//gm;
6789
6790   return $_;
6791 }
6792
6793
6794 # @PARAGRAPHS
6795 # &make_paragraphs ($MAKEFILE, [%TRANSFORM])
6796 # ------------------------------------------
6797 # Load a $MAKEFILE, apply the %TRANSFORM, and return it as a list of
6798 # paragraphs.
6799 sub make_paragraphs ($%)
6800 {
6801   my ($file, %transform) = @_;
6802   $transform{FIRST} = !$transformed_files{$file};
6803   $transformed_files{$file} = 1;
6804
6805   my @lines = split /(?<!\\)\n/, preprocess_file ($file, %transform);
6806   my @res;
6807
6808   while (defined ($_ = shift @lines))
6809     {
6810       my $paragraph = $_;
6811       # If we are a rule, eat as long as we start with a tab.
6812       if (/$RULE_PATTERN/smo)
6813         {
6814           while (defined ($_ = shift @lines) && $_ =~ /^\t/)
6815             {
6816               $paragraph .= "\n$_";
6817             }
6818           unshift (@lines, $_);
6819         }
6820
6821       # If we are a comments, eat as much comments as you can.
6822       elsif (/$COMMENT_PATTERN/smo)
6823         {
6824           while (defined ($_ = shift @lines)
6825                  && $_ =~ /$COMMENT_PATTERN/smo)
6826             {
6827               $paragraph .= "\n$_";
6828             }
6829           unshift (@lines, $_);
6830         }
6831
6832       push @res, $paragraph;
6833     }
6834
6835   return @res;
6836 }
6837
6838
6839
6840 # ($COMMENT, $VARIABLES, $RULES)
6841 # &file_contents_internal ($IS_AM, $FILE, $WHERE, [%TRANSFORM])
6842 # -------------------------------------------------------------
6843 # Return contents of a file from $libdir/am, automatically skipping
6844 # macros or rules which are already known. $IS_AM iff the caller is
6845 # reading an Automake file (as opposed to the user's Makefile.am).
6846 sub file_contents_internal ($$$%)
6847 {
6848     my ($is_am, $file, $where, %transform) = @_;
6849
6850     $where->set ($file);
6851
6852     my $result_vars = '';
6853     my $result_rules = '';
6854     my $comment = '';
6855     my $spacing = '';
6856
6857     # The following flags are used to track rules spanning across
6858     # multiple paragraphs.
6859     my $is_rule = 0;            # 1 if we are processing a rule.
6860     my $discard_rule = 0;       # 1 if the current rule should not be output.
6861
6862     # We save the conditional stack on entry, and then check to make
6863     # sure it is the same on exit.  This lets us conditionally include
6864     # other files.
6865     my @saved_cond_stack = @cond_stack;
6866     my $cond = new Automake::Condition (@cond_stack);
6867
6868     foreach (make_paragraphs ($file, %transform))
6869     {
6870         # FIXME: no line number available.
6871         $where->set ($file);
6872
6873         # Sanity checks.
6874         error $where, "blank line following trailing backslash:\n$_"
6875           if /\\$/;
6876         error $where, "comment following trailing backslash:\n$_"
6877           if /\\#/;
6878
6879         if (/^$/)
6880         {
6881             $is_rule = 0;
6882             # Stick empty line before the incoming macro or rule.
6883             $spacing = "\n";
6884         }
6885         elsif (/$COMMENT_PATTERN/mso)
6886         {
6887             $is_rule = 0;
6888             # Stick comments before the incoming macro or rule.
6889             $comment = "$_\n";
6890         }
6891
6892         # Handle inclusion of other files.
6893         elsif (/$INCLUDE_PATTERN/o)
6894         {
6895             if ($cond != FALSE)
6896               {
6897                 my $file = ($is_am ? "$libdir/am/" : '') . $1;
6898                 $where->push_context ("'$file' included from here");
6899                 # N-ary '.=' fails.
6900                 my ($com, $vars, $rules)
6901                   = file_contents_internal ($is_am, $file, $where, %transform);
6902                 $where->pop_context;
6903                 $comment .= $com;
6904                 $result_vars .= $vars;
6905                 $result_rules .= $rules;
6906               }
6907         }
6908
6909         # Handling the conditionals.
6910         elsif (/$IF_PATTERN/o)
6911           {
6912             $cond = cond_stack_if ($1, $2, $file);
6913           }
6914         elsif (/$ELSE_PATTERN/o)
6915           {
6916             $cond = cond_stack_else ($1, $2, $file);
6917           }
6918         elsif (/$ENDIF_PATTERN/o)
6919           {
6920             $cond = cond_stack_endif ($1, $2, $file);
6921           }
6922
6923         # Handling rules.
6924         elsif (/$RULE_PATTERN/mso)
6925         {
6926           $is_rule = 1;
6927           $discard_rule = 0;
6928           # Separate relationship from optional actions: the first
6929           # `new-line tab" not preceded by backslash (continuation
6930           # line).
6931           my $paragraph = $_;
6932           /^(.*?)(?:(?<!\\)\n(\t.*))?$/s;
6933           my ($relationship, $actions) = ($1, $2 || '');
6934
6935           # Separate targets from dependencies: the first colon.
6936           $relationship =~ /^([^:]+\S+) *: *(.*)$/som;
6937           my ($targets, $dependencies) = ($1, $2);
6938           # Remove the escaped new lines.
6939           # I don't know why, but I have to use a tmp $flat_deps.
6940           my $flat_deps = &flatten ($dependencies);
6941           my @deps = split (' ', $flat_deps);
6942
6943           foreach (split (' ', $targets))
6944             {
6945               # FIXME: 1. We are not robust to people defining several targets
6946               # at once, only some of them being in %dependencies.  The
6947               # actions from the targets in %dependencies are usually generated
6948               # from the content of %actions, but if some targets in $targets
6949               # are not in %dependencies the ELSE branch will output
6950               # a rule for all $targets (i.e. the targets which are both
6951               # in %dependencies and $targets will have two rules).
6952
6953               # FIXME: 2. The logic here is not able to output a
6954               # multi-paragraph rule several time (e.g. for each condition
6955               # it is defined for) because it only knows the first paragraph.
6956
6957               # FIXME: 3. We are not robust to people defining a subset
6958               # of a previously defined "multiple-target" rule.  E.g.
6959               # 'foo:' after 'foo bar:'.
6960
6961               # Output only if not in FALSE.
6962               if (defined $dependencies{$_} && $cond != FALSE)
6963                 {
6964                   &depend ($_, @deps);
6965                   register_action ($_, $actions);
6966                 }
6967               else
6968                 {
6969                   # Free-lance dependency.  Output the rule for all the
6970                   # targets instead of one by one.
6971                   my @undefined_conds =
6972                     Automake::Rule::define ($targets, $file,
6973                                             $is_am ? RULE_AUTOMAKE : RULE_USER,
6974                                             $cond, $where);
6975                   for my $undefined_cond (@undefined_conds)
6976                     {
6977                       my $condparagraph = $paragraph;
6978                       $condparagraph =~ s/^/$undefined_cond->subst_string/gme;
6979                       $result_rules .= "$spacing$comment$condparagraph\n";
6980                     }
6981                   if (scalar @undefined_conds == 0)
6982                     {
6983                       # Remember to discard next paragraphs
6984                       # if they belong to this rule.
6985                       # (but see also FIXME: #2 above.)
6986                       $discard_rule = 1;
6987                     }
6988                   $comment = $spacing = '';
6989                   last;
6990                 }
6991             }
6992         }
6993
6994         elsif (/$ASSIGNMENT_PATTERN/mso)
6995         {
6996             my ($var, $type, $val) = ($1, $2, $3);
6997             error $where, "variable '$var' with trailing backslash"
6998               if /\\$/;
6999
7000             $is_rule = 0;
7001
7002             Automake::Variable::define ($var,
7003                                         $is_am ? VAR_AUTOMAKE : VAR_MAKEFILE,
7004                                         $type, $cond, $val, $comment, $where,
7005                                         VAR_ASIS)
7006               if $cond != FALSE;
7007
7008             $comment = $spacing = '';
7009         }
7010         else
7011         {
7012             # This isn't an error; it is probably some tokens which
7013             # configure is supposed to replace, such as '@SET-MAKE@',
7014             # or some part of a rule cut by an if/endif.
7015             if (! $cond->false && ! ($is_rule && $discard_rule))
7016               {
7017                 s/^/$cond->subst_string/gme;
7018                 $result_rules .= "$spacing$comment$_\n";
7019               }
7020             $comment = $spacing = '';
7021         }
7022     }
7023
7024     error ($where, @cond_stack ?
7025            "unterminated conditionals: @cond_stack" :
7026            "too many conditionals closed in include file")
7027       if "@saved_cond_stack" ne "@cond_stack";
7028
7029     return ($comment, $result_vars, $result_rules);
7030 }
7031
7032
7033 # $CONTENTS
7034 # &file_contents ($BASENAME, $WHERE, [%TRANSFORM])
7035 # ------------------------------------------------
7036 # Return contents of a file from $libdir/am, automatically skipping
7037 # macros or rules which are already known.
7038 sub file_contents ($$%)
7039 {
7040     my ($basename, $where, %transform) = @_;
7041     my ($comments, $variables, $rules) =
7042       file_contents_internal (1, "$libdir/am/$basename.am", $where,
7043                               %transform);
7044     return "$comments$variables$rules";
7045 }
7046
7047
7048 # @PREFIX
7049 # &am_primary_prefixes ($PRIMARY, $CAN_DIST, @PREFIXES)
7050 # -----------------------------------------------------
7051 # Find all variable prefixes that are used for install directories.  A
7052 # prefix 'zar' qualifies iff:
7053 #
7054 # * 'zardir' is a variable.
7055 # * 'zar_PRIMARY' is a variable.
7056 #
7057 # As a side effect, it looks for misspellings.  It is an error to have
7058 # a variable ending in a "reserved" suffix whose prefix is unknown, e.g.
7059 # "bni_PROGRAMS".  However, unusual prefixes are allowed if a variable
7060 # of the same name (with "dir" appended) exists.  For instance, if the
7061 # variable "zardir" is defined, then "zar_PROGRAMS" becomes valid.
7062 # This is to provide a little extra flexibility in those cases which
7063 # need it.
7064 sub am_primary_prefixes ($$@)
7065 {
7066   my ($primary, $can_dist, @prefixes) = @_;
7067
7068   local $_;
7069   my %valid = map { $_ => 0 } @prefixes;
7070   $valid{'EXTRA'} = 0;
7071   foreach my $var (variables $primary)
7072     {
7073       # Automake is allowed to define variables that look like primaries
7074       # but which aren't.  E.g. INSTALL_sh_DATA.
7075       # Autoconf can also define variables like INSTALL_DATA, so
7076       # ignore all configure variables (at least those which are not
7077       # redefined in Makefile.am).
7078       # FIXME: We should make sure that these variables are not
7079       # conditionally defined (or else adjust the condition below).
7080       my $def = $var->def (TRUE);
7081       next if $def && $def->owner != VAR_MAKEFILE;
7082
7083       my $varname = $var->name;
7084
7085       if ($varname =~ /^(nobase_)?(dist_|nodist_)?(.*)_[[:alnum:]]+$/)
7086         {
7087           my ($base, $dist, $X) = ($1 || '', $2 || '', $3 || '');
7088           if ($dist ne '' && ! $can_dist)
7089             {
7090               err_var ($var,
7091                        "invalid variable '$varname': 'dist' is forbidden");
7092             }
7093           # Standard directories must be explicitly allowed.
7094           elsif (! defined $valid{$X} && exists $standard_prefix{$X})
7095             {
7096               err_var ($var,
7097                        "'${X}dir' is not a legitimate directory " .
7098                        "for '$primary'");
7099             }
7100           # A not explicitly valid directory is allowed if Xdir is defined.
7101           elsif (! defined $valid{$X} &&
7102                  $var->requires_variables ("'$varname' is used", "${X}dir"))
7103             {
7104               # Nothing to do.  Any error message has been output
7105               # by $var->requires_variables.
7106             }
7107           else
7108             {
7109               # Ensure all extended prefixes are actually used.
7110               $valid{"$base$dist$X"} = 1;
7111             }
7112         }
7113       else
7114         {
7115           prog_error "unexpected variable name: $varname";
7116         }
7117     }
7118
7119   # Return only those which are actually defined.
7120   return sort grep { var ($_ . '_' . $primary) } keys %valid;
7121 }
7122
7123
7124 # Handle 'where_HOW' variable magic.  Does all lookups, generates
7125 # install code, and possibly generates code to define the primary
7126 # variable.  The first argument is the name of the .am file to munge,
7127 # the second argument is the primary variable (e.g. HEADERS), and all
7128 # subsequent arguments are possible installation locations.
7129 #
7130 # Returns list of [$location, $value] pairs, where
7131 # $value's are the values in all where_HOW variable, and $location
7132 # there associated location (the place here their parent variables were
7133 # defined).
7134 #
7135 # FIXME: this should be rewritten to be cleaner.  It should be broken
7136 # up into multiple functions.
7137 #
7138 # Usage is: am_install_var (OPTION..., file, HOW, where...)
7139 sub am_install_var
7140 {
7141   my (@args) = @_;
7142
7143   my $do_require = 1;
7144   my $can_dist = 0;
7145   my $default_dist = 0;
7146   while (@args)
7147     {
7148       if ($args[0] eq '-noextra')
7149         {
7150           $do_require = 0;
7151         }
7152       elsif ($args[0] eq '-candist')
7153         {
7154           $can_dist = 1;
7155         }
7156       elsif ($args[0] eq '-defaultdist')
7157         {
7158           $default_dist = 1;
7159           $can_dist = 1;
7160         }
7161       elsif ($args[0] !~ /^-/)
7162         {
7163           last;
7164         }
7165       shift (@args);
7166     }
7167
7168   my ($file, $primary, @prefix) = @args;
7169
7170   # Now that configure substitutions are allowed in where_HOW
7171   # variables, it is an error to actually define the primary.  We
7172   # allow 'JAVA', as it is customarily used to mean the Java
7173   # interpreter.  This is but one of several Java hacks.  Similarly,
7174   # 'PYTHON' is customarily used to mean the Python interpreter.
7175   reject_var $primary, "'$primary' is an anachronism"
7176     unless $primary eq 'JAVA' || $primary eq 'PYTHON';
7177
7178   # Get the prefixes which are valid and actually used.
7179   @prefix = am_primary_prefixes ($primary, $can_dist, @prefix);
7180
7181   # If a primary includes a configure substitution, then the EXTRA_
7182   # form is required.  Otherwise we can't properly do our job.
7183   my $require_extra;
7184
7185   my @used = ();
7186   my @result = ();
7187
7188   foreach my $X (@prefix)
7189     {
7190       my $nodir_name = $X;
7191       my $one_name = $X . '_' . $primary;
7192       my $one_var = var $one_name;
7193
7194       my $strip_subdir = 1;
7195       # If subdir prefix should be preserved, do so.
7196       if ($nodir_name =~ /^nobase_/)
7197         {
7198           $strip_subdir = 0;
7199           $nodir_name =~ s/^nobase_//;
7200         }
7201
7202       # If files should be distributed, do so.
7203       my $dist_p = 0;
7204       if ($can_dist)
7205         {
7206           $dist_p = (($default_dist && $nodir_name !~ /^nodist_/)
7207                      || (! $default_dist && $nodir_name =~ /^dist_/));
7208           $nodir_name =~ s/^(dist|nodist)_//;
7209         }
7210
7211
7212       # Use the location of the currently processed variable.
7213       # We are not processing a particular condition, so pick the first
7214       # available.
7215       my $tmpcond = $one_var->conditions->one_cond;
7216       my $where = $one_var->rdef ($tmpcond)->location->clone;
7217
7218       # Append actual contents of where_PRIMARY variable to
7219       # @result, skipping @substitutions@.
7220       foreach my $locvals ($one_var->value_as_list_recursive (location => 1))
7221         {
7222           my ($loc, $value) = @$locvals;
7223           # Skip configure substitutions.
7224           if ($value =~ /^\@.*\@$/)
7225             {
7226               if ($nodir_name eq 'EXTRA')
7227                 {
7228                   error ($where,
7229                          "'$one_name' contains configure substitution, "
7230                          . "but shouldn't");
7231                 }
7232               # Check here to make sure variables defined in
7233               # configure.ac do not imply that EXTRA_PRIMARY
7234               # must be defined.
7235               elsif (! defined $configure_vars{$one_name})
7236                 {
7237                   $require_extra = $one_name
7238                     if $do_require;
7239                 }
7240             }
7241           else
7242             {
7243               # Strip any $(EXEEXT) suffix the user might have added, or this
7244               # will confuse &handle_source_transform and &check_canonical_spelling.
7245               # We'll add $(EXEEXT) back later anyway.
7246               # Do it here rather than in handle_programs so the uniquifying at the
7247               # end of this function works.
7248               ${$locvals}[1] =~ s/\$\(EXEEXT\)$//
7249                 if $primary eq 'PROGRAMS';
7250
7251               push (@result, $locvals);
7252             }
7253         }
7254       # A blatant hack: we rewrite each _PROGRAMS primary to include
7255       # EXEEXT.
7256       append_exeext { 1 } $one_name
7257         if $primary eq 'PROGRAMS';
7258       # "EXTRA" shouldn't be used when generating clean targets,
7259       # all, or install targets.  We used to warn if EXTRA_FOO was
7260       # defined uselessly, but this was annoying.
7261       next
7262         if $nodir_name eq 'EXTRA';
7263
7264       if ($nodir_name eq 'check')
7265         {
7266           push (@check, '$(' . $one_name . ')');
7267         }
7268       else
7269         {
7270           push (@used, '$(' . $one_name . ')');
7271         }
7272
7273       # Is this to be installed?
7274       my $install_p = $nodir_name ne 'noinst' && $nodir_name ne 'check';
7275
7276       # If so, with install-exec? (or install-data?).
7277       my $exec_p = ($nodir_name =~ /$EXEC_DIR_PATTERN/o);
7278
7279       my $check_options_p = $install_p && !! option 'std-options';
7280
7281       # Use the location of the currently processed variable as context.
7282       $where->push_context ("while processing '$one_name'");
7283
7284       # The variable containing all files to distribute.
7285       my $distvar = "\$($one_name)";
7286       $distvar = shadow_unconditionally ($one_name, $where)
7287         if ($dist_p && $one_var->has_conditional_contents);
7288
7289       # Singular form of $PRIMARY.
7290       (my $one_primary = $primary) =~ s/S$//;
7291       $output_rules .= &file_contents ($file, $where,
7292                                        PRIMARY     => $primary,
7293                                        ONE_PRIMARY => $one_primary,
7294                                        DIR         => $X,
7295                                        NDIR        => $nodir_name,
7296                                        BASE        => $strip_subdir,
7297
7298                                        EXEC      => $exec_p,
7299                                        INSTALL   => $install_p,
7300                                        DIST      => $dist_p,
7301                                        DISTVAR   => $distvar,
7302                                        'CK-OPTS' => $check_options_p);
7303     }
7304
7305   # The JAVA variable is used as the name of the Java interpreter.
7306   # The PYTHON variable is used as the name of the Python interpreter.
7307   if (@used && $primary ne 'JAVA' && $primary ne 'PYTHON')
7308     {
7309       # Define it.
7310       define_pretty_variable ($primary, TRUE, INTERNAL, @used);
7311       $output_vars .= "\n";
7312     }
7313
7314   err_var ($require_extra,
7315            "'$require_extra' contains configure substitution,\n"
7316            . "but 'EXTRA_$primary' not defined")
7317     if ($require_extra && ! var ('EXTRA_' . $primary));
7318
7319   # Push here because PRIMARY might be configure time determined.
7320   push (@all, '$(' . $primary . ')')
7321     if @used && $primary ne 'JAVA' && $primary ne 'PYTHON';
7322
7323   # Make the result unique.  This lets the user use conditionals in
7324   # a natural way, but still lets us program lazily -- we don't have
7325   # to worry about handling a particular object more than once.
7326   # We will keep only one location per object.
7327   my %result = ();
7328   for my $pair (@result)
7329     {
7330       my ($loc, $val) = @$pair;
7331       $result{$val} = $loc;
7332     }
7333   my @l = sort keys %result;
7334   return map { [$result{$_}->clone, $_] } @l;
7335 }
7336
7337
7338 ################################################################
7339
7340 # Each key in this hash is the name of a directory holding a
7341 # Makefile.in.  These variables are local to 'is_make_dir'.
7342 my %make_dirs = ();
7343 my $make_dirs_set = 0;
7344
7345 sub is_make_dir
7346 {
7347     my ($dir) = @_;
7348     if (! $make_dirs_set)
7349     {
7350         foreach my $iter (@configure_input_files)
7351         {
7352             $make_dirs{dirname ($iter)} = 1;
7353         }
7354         # We also want to notice Makefile.in's.
7355         foreach my $iter (@other_input_files)
7356         {
7357             if ($iter =~ /Makefile\.in$/)
7358             {
7359                 $make_dirs{dirname ($iter)} = 1;
7360             }
7361         }
7362         $make_dirs_set = 1;
7363     }
7364     return defined $make_dirs{$dir};
7365 }
7366
7367 ################################################################
7368
7369 # Find the aux dir.  This should match the algorithm used by
7370 # ./configure. (See the Autoconf documentation for for
7371 # AC_CONFIG_AUX_DIR.)
7372 sub locate_aux_dir ()
7373 {
7374   if (! $config_aux_dir_set_in_configure_ac)
7375     {
7376       # The default auxiliary directory is the first
7377       # of ., .., or ../.. that contains install-sh.
7378       # Assume . if install-sh doesn't exist yet.
7379       for my $dir (qw (. .. ../..))
7380         {
7381           if (-f "$dir/install-sh")
7382             {
7383               $config_aux_dir = $dir;
7384               last;
7385             }
7386         }
7387       $config_aux_dir = '.' unless $config_aux_dir;
7388     }
7389   # Avoid unsightly '/.'s.
7390   $am_config_aux_dir =
7391     '$(top_srcdir)' . ($config_aux_dir eq '.' ? "" : "/$config_aux_dir");
7392   $am_config_aux_dir =~ s,/*$,,;
7393 }
7394
7395
7396 # &push_required_file ($DIR, $FILE, $FULLFILE)
7397 # --------------------------------------------------
7398 # Push the given file onto DIST_COMMON.
7399 sub push_required_file
7400 {
7401   my ($dir, $file, $fullfile) = @_;
7402
7403   # If the file to be distributed is in the same directory of the
7404   # currently processed Makefile.am, then we want to distribute it
7405   # from this same Makefile.am.
7406   if ($dir eq $relative_dir)
7407     {
7408       push_dist_common ($file);
7409     }
7410   # This is needed to allow a construct in a non-top-level Makefile.am
7411   # to require a file in the build-aux directory (see at least the test
7412   # script 'test-driver-is-distributed.sh').  This is related to the
7413   # automake bug#9546.  Note that the use of $config_aux_dir instead
7414   # of $am_config_aux_dir here is deliberate and necessary.
7415   elsif ($dir eq $config_aux_dir)
7416     {
7417       push_dist_common ("$am_config_aux_dir/$file");
7418     }
7419   # FIXME: another spacial case, for AC_LIBOBJ/AC_LIBSOURCE support.
7420   # We probably need some refactoring of this function and its callers,
7421   # to have a more explicit and systematic handling of all the special
7422   # cases; but, since there are only two of them, this is low-priority
7423   # ATM.
7424   elsif ($config_libobj_dir && $dir eq $config_libobj_dir)
7425     {
7426       # Avoid unsightly '/.'s.
7427       my $am_config_libobj_dir =
7428         '$(top_srcdir)' .
7429         ($config_libobj_dir eq '.' ? "" : "/$config_libobj_dir");
7430       $am_config_libobj_dir =~ s|/*$||;
7431       push_dist_common ("$am_config_libobj_dir/$file");
7432     }
7433   elsif ($relative_dir eq '.' && ! &is_make_dir ($dir))
7434     {
7435       # If we are doing the topmost directory, and the file is in a
7436       # subdir which does not have a Makefile, then we distribute it
7437       # here.
7438
7439       # If a required file is above the source tree, it is important
7440       # to prefix it with '$(srcdir)' so that no VPATH search is
7441       # performed.  Otherwise problems occur with Make implementations
7442       # that rewrite and simplify rules whose dependencies are found in a
7443       # VPATH location.  Here is an example with OSF1/Tru64 Make.
7444       #
7445       #   % cat Makefile
7446       #   VPATH = sub
7447       #   distdir: ../a
7448       #           echo ../a
7449       #   % ls
7450       #   Makefile a
7451       #   % make
7452       #   echo a
7453       #   a
7454       #
7455       # Dependency '../a' was found in 'sub/../a', but this make
7456       # implementation simplified it as 'a'.  (Note that the sub/
7457       # directory does not even exist.)
7458       #
7459       # This kind of VPATH rewriting seems hard to cancel.  The
7460       # distdir.am hack against VPATH rewriting works only when no
7461       # simplification is done, i.e., for dependencies which are in
7462       # subdirectories, not in enclosing directories.  Hence, in
7463       # the latter case we use a full path to make sure no VPATH
7464       # search occurs.
7465       $fullfile = '$(srcdir)/' . $fullfile
7466         if $dir =~ m,^\.\.(?:$|/),;
7467
7468       push_dist_common ($fullfile);
7469     }
7470   else
7471     {
7472       prog_error "a Makefile in relative directory $relative_dir " .
7473                  "can't add files in directory $dir to DIST_COMMON";
7474     }
7475 }
7476
7477
7478 # If a file name appears as a key in this hash, then it has already
7479 # been checked for.  This allows us not to report the same error more
7480 # than once.
7481 my %required_file_not_found = ();
7482
7483 # &required_file_check_or_copy ($WHERE, $DIRECTORY, $FILE)
7484 # --------------------------------------------------------
7485 # Verify that the file must exist in $DIRECTORY, or install it.
7486 sub required_file_check_or_copy ($$$)
7487 {
7488   my ($where, $dir, $file) = @_;
7489
7490   my $fullfile = "$dir/$file";
7491   my $found_it = 0;
7492   my $dangling_sym = 0;
7493
7494   if (-l $fullfile && ! -f $fullfile)
7495     {
7496       $dangling_sym = 1;
7497     }
7498   elsif (dir_has_case_matching_file ($dir, $file))
7499     {
7500       $found_it = 1;
7501     }
7502
7503   # '--force-missing' only has an effect if '--add-missing' is
7504   # specified.
7505   return
7506     if $found_it && (! $add_missing || ! $force_missing);
7507
7508   # If we've already looked for it, we're done.  You might
7509   # wonder why we don't do this before searching for the
7510   # file.  If we do that, then something like
7511   # AC_OUTPUT(subdir/foo foo) will fail to put foo.in into
7512   # DIST_COMMON.
7513   if (! $found_it)
7514     {
7515       return if defined $required_file_not_found{$fullfile};
7516       $required_file_not_found{$fullfile} = 1;
7517     }
7518   if ($dangling_sym && $add_missing)
7519     {
7520       unlink ($fullfile);
7521     }
7522
7523   my $trailer = '';
7524   my $trailer2 = '';
7525   my $suppress = 0;
7526
7527   # Only install missing files according to our desired
7528   # strictness level.
7529   my $message = "required file '$fullfile' not found";
7530   if ($add_missing)
7531     {
7532       if (-f "$libdir/$file")
7533         {
7534           $suppress = 1;
7535
7536           # Install the missing file.  Symlink if we
7537           # can, copy if we must.  Note: delete the file
7538           # first, in case it is a dangling symlink.
7539           $message = "installing '$fullfile'";
7540
7541           # The license file should not be volatile.
7542           if ($file eq "COPYING")
7543             {
7544               $message .= " using GNU General Public License v3 file";
7545               $trailer2 = "\n    Consider adding the COPYING file"
7546                         . " to the version control system"
7547                         . "\n    for your code, to avoid questions"
7548                         . " about which license your project uses";
7549             }
7550
7551           # Windows Perl will hang if we try to delete a
7552           # file that doesn't exist.
7553           unlink ($fullfile) if -f $fullfile;
7554           if ($symlink_exists && ! $copy_missing)
7555             {
7556               if (! symlink ("$libdir/$file", $fullfile)
7557                   || ! -e $fullfile)
7558                 {
7559                   $suppress = 0;
7560                   $trailer = "; error while making link: $!";
7561                 }
7562             }
7563           elsif (system ('cp', "$libdir/$file", $fullfile))
7564             {
7565               $suppress = 0;
7566               $trailer = "\n    error while copying";
7567             }
7568           set_dir_cache_file ($dir, $file);
7569         }
7570     }
7571   else
7572     {
7573       $trailer = "\n  'automake --add-missing' can install '$file'"
7574         if -f "$libdir/$file";
7575     }
7576
7577   # If --force-missing was specified, and we have
7578   # actually found the file, then do nothing.
7579   return
7580     if $found_it && $force_missing;
7581
7582   # If we couldn't install the file, but it is a target in
7583   # the Makefile, don't print anything.  This allows files
7584   # like README, AUTHORS, or THANKS to be generated.
7585   return
7586     if !$suppress && rule $file;
7587
7588   msg ($suppress ? 'note' : 'error', $where, "$message$trailer$trailer2");
7589 }
7590
7591
7592 # &require_file_internal ($WHERE, $MYSTRICT, $DIRECTORY, $QUEUE, @FILES)
7593 # ----------------------------------------------------------------------
7594 # Verify that the file must exist in $DIRECTORY, or install it.
7595 # $MYSTRICT is the strictness level at which this file becomes required.
7596 # Worker threads may queue up the action to be serialized by the master,
7597 # if $QUEUE is true
7598 sub require_file_internal ($$$@)
7599 {
7600   my ($where, $mystrict, $dir, $queue, @files) = @_;
7601
7602   return
7603     unless $strictness >= $mystrict;
7604
7605   foreach my $file (@files)
7606     {
7607       push_required_file ($dir, $file, "$dir/$file");
7608       if ($queue)
7609         {
7610           queue_required_file_check_or_copy ($required_conf_file_queue,
7611                                              QUEUE_CONF_FILE, $relative_dir,
7612                                              $where, $mystrict, @files);
7613         }
7614       else
7615         {
7616           required_file_check_or_copy ($where, $dir, $file);
7617         }
7618     }
7619 }
7620
7621 # &require_file ($WHERE, $MYSTRICT, @FILES)
7622 # -----------------------------------------
7623 sub require_file ($$@)
7624 {
7625     my ($where, $mystrict, @files) = @_;
7626     require_file_internal ($where, $mystrict, $relative_dir, 0, @files);
7627 }
7628
7629 # &require_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7630 # -----------------------------------------------------------
7631 sub require_file_with_macro ($$$@)
7632 {
7633     my ($cond, $macro, $mystrict, @files) = @_;
7634     $macro = rvar ($macro) unless ref $macro;
7635     require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7636 }
7637
7638 # &require_libsource_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7639 # ----------------------------------------------------------------
7640 # Require an AC_LIBSOURCEd file.  If AC_CONFIG_LIBOBJ_DIR was called, it
7641 # must be in that directory.  Otherwise expect it in the current directory.
7642 sub require_libsource_with_macro ($$$@)
7643 {
7644     my ($cond, $macro, $mystrict, @files) = @_;
7645     $macro = rvar ($macro) unless ref $macro;
7646     if ($config_libobj_dir)
7647       {
7648         require_file_internal ($macro->rdef ($cond)->location, $mystrict,
7649                                $config_libobj_dir, 0, @files);
7650       }
7651     else
7652       {
7653         require_file ($macro->rdef ($cond)->location, $mystrict, @files);
7654       }
7655 }
7656
7657 # &queue_required_file_check_or_copy ($QUEUE, $KEY, $DIR, $WHERE,
7658 #                                     $MYSTRICT, @FILES)
7659 # ---------------------------------------------------------------
7660 sub queue_required_file_check_or_copy ($$$$@)
7661 {
7662     my ($queue, $key, $dir, $where, $mystrict, @files) = @_;
7663     my @serial_loc;
7664     if (ref $where)
7665       {
7666         @serial_loc = (QUEUE_LOCATION, $where->serialize ());
7667       }
7668     else
7669       {
7670         @serial_loc = (QUEUE_STRING, $where);
7671       }
7672     $queue->enqueue ($key, $dir, @serial_loc, $mystrict, 0 + @files, @files);
7673 }
7674
7675 # &require_queued_file_check_or_copy ($QUEUE)
7676 # -------------------------------------------
7677 sub require_queued_file_check_or_copy ($)
7678 {
7679     my ($queue) = @_;
7680     my $where;
7681     my $dir = $queue->dequeue ();
7682     my $loc_key = $queue->dequeue ();
7683     if ($loc_key eq QUEUE_LOCATION)
7684       {
7685         $where = Automake::Location::deserialize ($queue);
7686       }
7687     elsif ($loc_key eq QUEUE_STRING)
7688       {
7689         $where = $queue->dequeue ();
7690       }
7691     else
7692       {
7693         prog_error "unexpected key $loc_key";
7694       }
7695     my $mystrict = $queue->dequeue ();
7696     my $nfiles = $queue->dequeue ();
7697     my @files;
7698     push @files, $queue->dequeue ()
7699       foreach (1 .. $nfiles);
7700     return
7701       unless $strictness >= $mystrict;
7702     foreach my $file (@files)
7703       {
7704         required_file_check_or_copy ($where, $config_aux_dir, $file);
7705       }
7706 }
7707
7708 # &require_conf_file ($WHERE, $MYSTRICT, @FILES)
7709 # ----------------------------------------------
7710 # Looks in configuration path, as specified by AC_CONFIG_AUX_DIR.
7711 sub require_conf_file ($$@)
7712 {
7713     my ($where, $mystrict, @files) = @_;
7714     my $queue = defined $required_conf_file_queue ? 1 : 0;
7715     require_file_internal ($where, $mystrict, $config_aux_dir,
7716                            $queue, @files);
7717 }
7718
7719
7720 # &require_conf_file_with_macro ($COND, $MACRO, $MYSTRICT, @FILES)
7721 # ----------------------------------------------------------------
7722 sub require_conf_file_with_macro ($$$@)
7723 {
7724     my ($cond, $macro, $mystrict, @files) = @_;
7725     require_conf_file (rvar ($macro)->rdef ($cond)->location,
7726                        $mystrict, @files);
7727 }
7728
7729 ################################################################
7730
7731 # &require_build_directory ($DIRECTORY)
7732 # -------------------------------------
7733 # Emit rules to create $DIRECTORY if needed, and return
7734 # the file that any target requiring this directory should be made
7735 # dependent upon.
7736 # We don't want to emit the rule twice, and want to reuse it
7737 # for directories with equivalent names (e.g., 'foo/bar' and './foo//bar').
7738 sub require_build_directory ($)
7739 {
7740   my $directory = shift;
7741
7742   return $directory_map{$directory} if exists $directory_map{$directory};
7743
7744   my $cdir = File::Spec->canonpath ($directory);
7745
7746   if (exists $directory_map{$cdir})
7747     {
7748       my $stamp = $directory_map{$cdir};
7749       $directory_map{$directory} = $stamp;
7750       return $stamp;
7751     }
7752
7753   my $dirstamp = "$cdir/\$(am__dirstamp)";
7754
7755   $directory_map{$directory} = $dirstamp;
7756   $directory_map{$cdir} = $dirstamp;
7757
7758   # Set a variable for the dirstamp basename.
7759   define_pretty_variable ('am__dirstamp', TRUE, INTERNAL,
7760                           '$(am__leading_dot)dirstamp');
7761
7762   # Directory must be removed by 'make distclean'.
7763   $clean_files{$dirstamp} = DIST_CLEAN;
7764
7765   $output_rules .= ("$dirstamp:\n"
7766                     . "\t\@\$(MKDIR_P) $directory\n"
7767                     . "\t\@: > $dirstamp\n");
7768
7769   return $dirstamp;
7770 }
7771
7772 # &require_build_directory_maybe ($FILE)
7773 # --------------------------------------
7774 # If $FILE lies in a subdirectory, emit a rule to create this
7775 # directory and return the file that $FILE should be made
7776 # dependent upon.  Otherwise, just return the empty string.
7777 sub require_build_directory_maybe ($)
7778 {
7779     my $file = shift;
7780     my $directory = dirname ($file);
7781
7782     if ($directory ne '.')
7783     {
7784         return require_build_directory ($directory);
7785     }
7786     else
7787     {
7788         return '';
7789     }
7790 }
7791
7792 ################################################################
7793
7794 # Push a list of files onto dist_common.
7795 sub push_dist_common
7796 {
7797   prog_error "push_dist_common run after handle_dist"
7798     if $handle_dist_run;
7799   Automake::Variable::define ('DIST_COMMON', VAR_AUTOMAKE, '+', TRUE, "@_",
7800                               '', INTERNAL, VAR_PRETTY);
7801 }
7802
7803
7804 ################################################################
7805
7806 # generate_makefile ($MAKEFILE_AM, $MAKEFILE_IN)
7807 # ----------------------------------------------
7808 # Generate a Makefile.in given the name of the corresponding Makefile and
7809 # the name of the file output by config.status.
7810 sub generate_makefile ($$)
7811 {
7812   my ($makefile_am, $makefile_in) = @_;
7813
7814   # Reset all the Makefile.am related variables.
7815   initialize_per_input;
7816
7817   # AUTOMAKE_OPTIONS can contains -W flags to disable or enable
7818   # warnings for this file.  So hold any warning issued before
7819   # we have processed AUTOMAKE_OPTIONS.
7820   buffer_messages ('warning');
7821
7822   # $OUTPUT is encoded.  If it contains a ":" then the first element
7823   # is the real output file, and all remaining elements are input
7824   # files.  We don't scan or otherwise deal with these input files,
7825   # other than to mark them as dependencies.  See
7826   # &scan_autoconf_files for details.
7827   my ($makefile, @inputs) = split (/:/, $output_files{$makefile_in});
7828
7829   $relative_dir = dirname ($makefile);
7830
7831   read_main_am_file ($makefile_am, $makefile_in);
7832   if (handle_options)
7833     {
7834       # Process buffered warnings.
7835       flush_messages;
7836       # Fatal error.  Just return, so we can continue with next file.
7837       return;
7838     }
7839   # Process buffered warnings.
7840   flush_messages;
7841
7842   # There are a few install-related variables that you should not define.
7843   foreach my $var ('PRE_INSTALL', 'POST_INSTALL', 'NORMAL_INSTALL')
7844     {
7845       my $v = var $var;
7846       if ($v)
7847         {
7848           my $def = $v->def (TRUE);
7849           prog_error "$var not defined in condition TRUE"
7850             unless $def;
7851           reject_var $var, "'$var' should not be defined"
7852             if $def->owner != VAR_AUTOMAKE;
7853         }
7854     }
7855
7856   # Catch some obsolete variables.
7857   msg_var ('obsolete', 'INCLUDES',
7858            "'INCLUDES' is the old name for 'AM_CPPFLAGS' (or '*_CPPFLAGS')")
7859     if var ('INCLUDES');
7860
7861   # Must do this after reading .am file.
7862   define_variable ('subdir', $relative_dir, INTERNAL);
7863
7864   # If DIST_SUBDIRS is defined, make sure SUBDIRS is, so that
7865   # recursive rules are enabled.
7866   define_pretty_variable ('SUBDIRS', TRUE, INTERNAL, '')
7867     if var 'DIST_SUBDIRS' && ! var 'SUBDIRS';
7868
7869   # Check first, because we might modify some state.
7870   check_gnu_standards;
7871   check_gnits_standards;
7872
7873   handle_configure ($makefile_am, $makefile_in, $makefile, @inputs);
7874   handle_gettext;
7875   handle_libraries;
7876   handle_ltlibraries;
7877   handle_programs;
7878   handle_scripts;
7879
7880   handle_silent;
7881
7882   # These must be run after all the sources are scanned.  They
7883   # use variables defined by &handle_libraries, &handle_ltlibraries,
7884   # or &handle_programs.
7885   handle_compile;
7886   handle_languages;
7887   handle_libtool;
7888
7889   # Variables used by distdir.am and tags.am.
7890   define_pretty_variable ('SOURCES', TRUE, INTERNAL, @sources);
7891   if (! option 'no-dist')
7892     {
7893       define_pretty_variable ('DIST_SOURCES', TRUE, INTERNAL, @dist_sources);
7894     }
7895
7896   handle_texinfo;
7897   handle_emacs_lisp;
7898   handle_python;
7899   handle_java;
7900   handle_man_pages;
7901   handle_data;
7902   handle_headers;
7903   handle_subdirs;
7904   handle_user_recursion;
7905   handle_tags;
7906   handle_minor_options;
7907   # Must come after handle_programs so that %known_programs is up-to-date.
7908   handle_tests;
7909
7910   # This must come after most other rules.
7911   handle_dist;
7912
7913   handle_footer;
7914   do_check_merge_target;
7915   handle_all ($makefile);
7916
7917   # FIXME: Gross!
7918   if (var ('lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7919     {
7920       $output_rules .= "install-binPROGRAMS: install-libLTLIBRARIES\n\n";
7921     }
7922   if (var ('nobase_lib_LTLIBRARIES') && var ('bin_PROGRAMS'))
7923     {
7924       $output_rules .= "install-binPROGRAMS: install-nobase_libLTLIBRARIES\n\n";
7925     }
7926
7927   handle_install;
7928   handle_clean ($makefile);
7929   handle_factored_dependencies;
7930
7931   # Comes last, because all the above procedures may have
7932   # defined or overridden variables.
7933   $output_vars .= output_variables;
7934
7935   check_typos;
7936
7937   if ($exit_code != 0)
7938     {
7939       verb "not writing $makefile_in because of earlier errors";
7940       return;
7941     }
7942
7943   my $am_relative_dir = dirname ($makefile_am);
7944   mkdir ($am_relative_dir, 0755) if ! -d $am_relative_dir;
7945
7946   # We make sure that 'all:' is the first target.
7947   my $output =
7948     "$output_vars$output_all$output_header$output_rules$output_trailer";
7949
7950   # Decide whether we must update the output file or not.
7951   # We have to update in the following situations.
7952   #  * $force_generation is set.
7953   #  * any of the output dependencies is younger than the output
7954   #  * the contents of the output is different (this can happen
7955   #    if the project has been populated with a file listed in
7956   #    @common_files since the last run).
7957   # Output's dependencies are split in two sets:
7958   #  * dependencies which are also configure dependencies
7959   #    These do not change between each Makefile.am
7960   #  * other dependencies, specific to the Makefile.am being processed
7961   #    (such as the Makefile.am itself, or any Makefile fragment
7962   #    it includes).
7963   my $timestamp = mtime $makefile_in;
7964   if (! $force_generation
7965       && $configure_deps_greatest_timestamp < $timestamp
7966       && $output_deps_greatest_timestamp < $timestamp
7967       && $output eq contents ($makefile_in))
7968     {
7969       verb "$makefile_in unchanged";
7970       # No need to update.
7971       return;
7972     }
7973
7974   if (-e $makefile_in)
7975     {
7976       unlink ($makefile_in)
7977         or fatal "cannot remove $makefile_in: $!";
7978     }
7979
7980   my $gm_file = new Automake::XFile "> $makefile_in";
7981   verb "creating $makefile_in";
7982   print $gm_file $output;
7983 }
7984
7985 ################################################################
7986
7987
7988
7989
7990 ################################################################
7991
7992 # Helper function for usage().
7993 sub print_autodist_files (@)
7994 {
7995   my @lcomm = sort (&uniq (@_));
7996
7997   my @four;
7998   format USAGE_FORMAT =
7999   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<   @<<<<<<<<<<<<<<<<
8000   $four[0],           $four[1],           $four[2],           $four[3]
8001 .
8002   local $~ = "USAGE_FORMAT";
8003
8004   my $cols = 4;
8005   my $rows = int(@lcomm / $cols);
8006   my $rest = @lcomm % $cols;
8007
8008   if ($rest)
8009     {
8010       $rows++;
8011     }
8012   else
8013     {
8014       $rest = $cols;
8015     }
8016
8017   for (my $y = 0; $y < $rows; $y++)
8018     {
8019       @four = ("", "", "", "");
8020       for (my $x = 0; $x < $cols; $x++)
8021         {
8022           last if $y + 1 == $rows && $x == $rest;
8023
8024           my $idx = (($x > $rest)
8025                ?  ($rows * $rest + ($rows - 1) * ($x - $rest))
8026                : ($rows * $x));
8027
8028           $idx += $y;
8029           $four[$x] = $lcomm[$idx];
8030         }
8031       write;
8032     }
8033 }
8034
8035
8036 # Print usage information.
8037 sub usage ()
8038 {
8039     print "Usage: $0 [OPTION]... [Makefile]...
8040
8041 Generate Makefile.in for configure from Makefile.am.
8042
8043 Operation modes:
8044       --help               print this help, then exit
8045       --version            print version number, then exit
8046   -v, --verbose            verbosely list files processed
8047       --no-force           only update Makefile.in's that are out of date
8048   -W, --warnings=CATEGORY  report the warnings falling in CATEGORY
8049
8050 Dependency tracking:
8051   -i, --ignore-deps      disable dependency tracking code
8052       --include-deps     enable dependency tracking code
8053
8054 Flavors:
8055       --foreign          set strictness to foreign
8056       --gnits            set strictness to gnits
8057       --gnu              set strictness to gnu
8058
8059 Library files:
8060   -a, --add-missing      add missing standard files to package
8061       --libdir=DIR       set directory storing library files
8062       --print-libdir     print directory storing library files
8063   -c, --copy             with -a, copy missing files (default is symlink)
8064   -f, --force-missing    force update of standard files
8065
8066 ";
8067     Automake::ChannelDefs::usage;
8068
8069     print "\nFiles automatically distributed if found " .
8070           "(always):\n";
8071     print_autodist_files @common_files;
8072     print "\nFiles automatically distributed if found " .
8073           "(under certain conditions):\n";
8074     print_autodist_files @common_sometimes;
8075
8076     print '
8077 Report bugs to <@PACKAGE_BUGREPORT@>.
8078 GNU Automake home page: <@PACKAGE_URL@>.
8079 General help using GNU software: <http://www.gnu.org/gethelp/>.
8080 ';
8081
8082     # --help always returns 0 per GNU standards.
8083     exit 0;
8084 }
8085
8086
8087 # &version ()
8088 # -----------
8089 # Print version information
8090 sub version ()
8091 {
8092   print <<EOF;
8093 automake (GNU $PACKAGE) $VERSION
8094 Copyright (C) $RELEASE_YEAR Free Software Foundation, Inc.
8095 License GPLv2+: GNU GPL version 2 or later <http://gnu.org/licenses/gpl-2.0.html>
8096 This is free software: you are free to change and redistribute it.
8097 There is NO WARRANTY, to the extent permitted by law.
8098
8099 Written by Tom Tromey <tromey\@redhat.com>
8100        and Alexandre Duret-Lutz <adl\@gnu.org>.
8101 EOF
8102   # --version always returns 0 per GNU standards.
8103   exit 0;
8104 }
8105
8106 ################################################################
8107
8108 # Parse command line.
8109 sub parse_arguments ()
8110 {
8111   my $strict = 'gnu';
8112   my $ignore_deps = 0;
8113   my @warnings = ();
8114
8115   my %cli_options =
8116     (
8117      'version' => \&version,
8118      'help'    => \&usage,
8119      'libdir=s' => \$libdir,
8120      'print-libdir'     => sub { print "$libdir\n"; exit 0; },
8121      'gnu'              => sub { $strict = 'gnu'; },
8122      'gnits'            => sub { $strict = 'gnits'; },
8123      'foreign'          => sub { $strict = 'foreign'; },
8124      'include-deps'     => sub { $ignore_deps = 0; },
8125      'i|ignore-deps'    => sub { $ignore_deps = 1; },
8126      'no-force' => sub { $force_generation = 0; },
8127      'f|force-missing'  => \$force_missing,
8128      'a|add-missing'    => \$add_missing,
8129      'c|copy'           => \$copy_missing,
8130      'v|verbose'        => sub { setup_channel 'verb', silent => 0; },
8131      'W|warnings=s'     => \@warnings,
8132      );
8133
8134   use Automake::Getopt ();
8135   Automake::Getopt::parse_options %cli_options;
8136
8137   set_strictness ($strict);
8138   my $cli_where = new Automake::Location;
8139   set_global_option ('no-dependencies', $cli_where) if $ignore_deps;
8140   for my $warning (@warnings)
8141     {
8142       &parse_warnings ('-W', $warning);
8143     }
8144
8145   return unless @ARGV;
8146
8147   my $errspec = 0;
8148   foreach my $arg (@ARGV)
8149     {
8150       fatal ("empty argument\nTry '$0 --help' for more information")
8151         if ($arg eq '');
8152
8153       # Handle $local:$input syntax.
8154       my ($local, @rest) = split (/:/, $arg);
8155       @rest = ("$local.in",) unless @rest;
8156       my $input = locate_am @rest;
8157       if ($input)
8158         {
8159           push @input_files, $input;
8160           $output_files{$input} = join (':', ($local, @rest));
8161         }
8162       else
8163         {
8164           error "no Automake input file found for '$arg'";
8165           $errspec = 1;
8166         }
8167     }
8168   fatal "no input file found among supplied arguments"
8169     if $errspec && ! @input_files;
8170 }
8171
8172
8173 # handle_makefile ($MAKEFILE_IN)
8174 # ------------------------------
8175 # Deal with $MAKEFILE_IN.
8176 sub handle_makefile ($)
8177 {
8178   my ($file) =  @_;
8179   ($am_file = $file) =~ s/\.in$//;
8180   if (! -f ($am_file . '.am'))
8181     {
8182       error "'$am_file.am' does not exist";
8183     }
8184   else
8185     {
8186       # Any warning setting now local to this Makefile.am.
8187       dup_channel_setup;
8188
8189       generate_makefile ($am_file . '.am', $file);
8190
8191       # Back out any warning setting.
8192       drop_channel_setup;
8193     }
8194 }
8195
8196 # handle_makefiles_serial ()
8197 # --------------------------
8198 # Deal with all makefiles, without threads.
8199 sub handle_makefiles_serial ()
8200 {
8201   foreach my $file (@input_files)
8202     {
8203       handle_makefile ($file);
8204     }
8205 }
8206
8207 # get_number_of_threads ()
8208 # ------------------------
8209 # Logic for deciding how many worker threads to use.
8210 sub get_number_of_threads
8211 {
8212   my $nthreads = $ENV{'AUTOMAKE_JOBS'} || 0;
8213
8214   $nthreads = 0
8215     unless $nthreads =~ /^[0-9]+$/;
8216
8217   # It doesn't make sense to use more threads than makefiles,
8218   my $max_threads = @input_files;
8219
8220   if ($nthreads > $max_threads)
8221     {
8222       $nthreads = $max_threads;
8223     }
8224   return $nthreads;
8225 }
8226
8227 # handle_makefiles_threaded ($NTHREADS)
8228 # -------------------------------------
8229 # Deal with all makefiles, using threads.  The general strategy is to
8230 # spawn NTHREADS worker threads, dispatch makefiles to them, and let the
8231 # worker threads push back everything that needs serialization:
8232 # * warning and (normal) error messages, for stable stderr output
8233 #   order and content (avoiding duplicates, for example),
8234 # * races when installing aux files (and respective messages),
8235 # * races when collecting aux files for distribution.
8236 #
8237 # The latter requires that the makefile that deals with the aux dir
8238 # files be handled last, done by the master thread.
8239 sub handle_makefiles_threaded ($)
8240 {
8241   my ($nthreads) = @_;
8242
8243   # The file queue distributes all makefiles, the message queues
8244   # collect all serializations needed for respective files.
8245   my $file_queue = Thread::Queue->new;
8246   my %msg_queues;
8247   foreach my $file (@input_files)
8248     {
8249       $msg_queues{$file} = Thread::Queue->new;
8250     }
8251
8252   verb "spawning $nthreads worker threads";
8253   my @threads = (1 .. $nthreads);
8254   foreach my $t (@threads)
8255     {
8256       $t = threads->new (sub
8257         {
8258           while (my $file = $file_queue->dequeue)
8259             {
8260               verb "handling $file";
8261               my $queue = $msg_queues{$file};
8262               setup_channel_queue ($queue, QUEUE_MESSAGE);
8263               $required_conf_file_queue = $queue;
8264               handle_makefile ($file);
8265               $queue->enqueue (undef);
8266               setup_channel_queue (undef, undef);
8267               $required_conf_file_queue = undef;
8268             }
8269           return $exit_code;
8270         });
8271     }
8272
8273   # Queue all makefiles.
8274   verb "queuing " . @input_files . " input files";
8275   $file_queue->enqueue (@input_files, (undef) x @threads);
8276
8277   # Collect and process serializations.
8278   foreach my $file (@input_files)
8279     {
8280       verb "dequeuing messages for " . $file;
8281       reset_local_duplicates ();
8282       my $queue = $msg_queues{$file};
8283       while (my $key = $queue->dequeue)
8284         {
8285           if ($key eq QUEUE_MESSAGE)
8286             {
8287               pop_channel_queue ($queue);
8288             }
8289           elsif ($key eq QUEUE_CONF_FILE)
8290             {
8291               require_queued_file_check_or_copy ($queue);
8292             }
8293           else
8294             {
8295               prog_error "unexpected key $key";
8296             }
8297         }
8298     }
8299
8300   foreach my $t (@threads)
8301     {
8302       my @exit_thread = $t->join;
8303       $exit_code = $exit_thread[0]
8304         if ($exit_thread[0] > $exit_code);
8305     }
8306 }
8307
8308 ################################################################
8309
8310 # Parse the WARNINGS environment variable.
8311 parse_WARNINGS;
8312
8313 # Parse command line.
8314 parse_arguments;
8315
8316 $configure_ac = require_configure_ac;
8317
8318 # Do configure.ac scan only once.
8319 scan_autoconf_files;
8320
8321 if (! @input_files)
8322   {
8323     my $msg = '';
8324     $msg = "\nDid you forget AC_CONFIG_FILES([Makefile]) in $configure_ac?"
8325       if -f 'Makefile.am';
8326     fatal ("no 'Makefile.am' found for any configure output$msg");
8327   }
8328
8329 my $nthreads = get_number_of_threads ();
8330
8331 if ($perl_threads && $nthreads >= 1)
8332   {
8333     handle_makefiles_threaded ($nthreads);
8334   }
8335 else
8336   {
8337     handle_makefiles_serial ();
8338   }
8339
8340 exit $exit_code;
8341
8342
8343 ### Setup "GNU" style for perl-mode and cperl-mode.
8344 ## Local Variables:
8345 ## perl-indent-level: 2
8346 ## perl-continued-statement-offset: 2
8347 ## perl-continued-brace-offset: 0
8348 ## perl-brace-offset: 0
8349 ## perl-brace-imaginary-offset: 0
8350 ## perl-label-offset: -2
8351 ## cperl-indent-level: 2
8352 ## cperl-brace-offset: 0
8353 ## cperl-continued-brace-offset: 0
8354 ## cperl-label-offset: -2
8355 ## cperl-extra-newline-before-brace: t
8356 ## cperl-merge-trailing-else: nil
8357 ## cperl-continued-statement-offset: 2
8358 ## End: