configure.ac

   1 AC_INIT([at-spi2-core], [2.15.5], [accessibility-atspi@lists.linux-foundation.org])
   2 AC_PREREQ([2.59])
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_MACRO_DIR([m4])
   5
   6 AT_SPI_CORE_MAJOR_VERSION=0
   7 AT_SPI_CORE_MINOR_VERSION=1
   8 AT_SPI_CORE_MICRO_VERSION=3
   9 AT_SPI_CORE_VERSION="$AT_SPI_CORE_MAJOR_VERSION.$AT_SPI_CORE_MINOR_VERSION"
  10 AC_SUBST(AT_SPI_CORE_VERSION)
  11
  12 LT_RELEASE=$AT_SPI_CORE_VERSION
  13 LT_CURRENT=0
  14 LT_REVISION=1
  15 LT_AGE=0
  16 LT_VERSION_INFO='-version-info ${LT_CURRENT}:${LT_REVISION}:${LT_AGE}'
  17 AC_SUBST(LT_VERSION_INFO)
  18 AC_SUBST(LT_RELEASE)
  19 AC_SUBST(LT_CURRENT)
  20 AC_SUBST(LT_REVISION)
  21 AC_SUBST(LT_AGE)
  22
  23 AM_INIT_AUTOMAKE([1.9 -Wall foreign no-dist-gzip dist-xz])
  24
  25 # Support silent build rules. Disable
  26 # by either passing --disable-silent-rules to configure or passing V=1
  27 # to make
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 LT_INIT([disable-static])
  32 PKG_PROG_PKG_CONFIG
  33
  34 AC_CONFIG_HEADERS([config.h])
  35
  36 dnl translation of at-spi strings
  37 IT_PROG_INTLTOOL([0.40.0])
  38
  39
  40 GETTEXT_PACKAGE="${PACKAGE}"
  41 AC_SUBST(GETTEXT_PACKAGE)
  42
  43 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.0])
  44 AC_SUBST(DBUS_LIBS)
  45 AC_SUBST(DBUS_CFLAGS)
  46
  47 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.36.0])
  48 AC_SUBST(GLIB_LIBS)
  49 AC_SUBST(GLIB_CFLAGS)
  50
  51 PKG_CHECK_MODULES(GOBJ, [gobject-2.0 >= 2.0.0])
  52 AC_SUBST(GOBJ_LIBS)
  53 AC_SUBST(GOBJ_CFLAGS)
  54
  55 PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.28])
  56 AC_SUBST(GIO_LIBS)
  57 AC_SUBST(GIO_CFLAGS)
  58
  59 # --------------------------------------------------------------------
  60 # Find DL functionality
  61
  62 AC_CHECK_LIB(c, dlopen, DL_LIBS="",
  63         AC_CHECK_LIB(dl, dlopen, DL_LIBS="-ldl",
  64                 AC_MSG_ERROR([Could not find a library with the dlopen function])
  65         )
  66 )
  67
  68 AC_SUBST(DL_LIBS)
  69
  70 AC_PATH_XTRA
  71
  72 AC_ARG_ENABLE(x11,
  73               [AS_HELP_STRING([--disable-x11],
  74                               [disable the X11 backend])],,
  75                               [enable_x11=auto])
  76
  77 if test x$no_x = xyes ; then
  78         AC_MSG_WARN([X development libraries not found])
  79   AM_CONDITIONAL(USE_X11, false)
  80 elif test x$enable_x11 = xauto; then
  81         X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
  82   AC_DEFINE(HAVE_X11, 1, [Define to use X11])
  83   AM_CONDITIONAL(USE_X11, true)
  84 else
  85   AM_CONDITIONAL(USE_X11, false)
  86 fi
  87 AC_SUBST(X_LIBS)
  88 AC_SUBST(HAVE_X11)
  89
  90 save_LIBS="$LIBS"
  91 LIBS=""
  92 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
  93 AC_CHECK_LIB(Xtst, XTestFakeKeyEvent, XTST_LIBS=-lXtst,[
  94         AC_MSG_ERROR([Couldn't find the Xtst library. Check config.log])],
  95         $X_LIBS)
  96 AC_SUBST(XTST_LIBS)
  97 LIBS="$LIBS $save_LIBS"
  98
  99 save_LIBS="$LIBS"
 100 LIBS=""
 101 AC_CHECK_LIB(X11, XkbQueryExtension, have_xkb="maybe", have_xkb="no", $X_LIBS)
 102 if test "x$have_xkb" = "xmaybe"; then
 103         AC_CHECK_HEADER([X11/XKBlib.h], have_xkb=yes)
 104 fi
 105 if test "x$have_xkb" = "xyes"; then
 106         AC_DEFINE([HAVE_XKB], [], [Xkb is present])
 107 fi
 108 LIBS="$LIBS $save_LIBS"
 109
 110 save_LIBS="$LIBS"
 111 LIBS=""
 112 AC_CHECK_LIB(Xi, XOpenDevice, have_xinput="maybe", have_xinput="no", $X_LIBS)
 113 if test "x$have_xinput" = "xmaybe"; then
 114         save_LIBS="$LIBS"
 115         LIBS="$LIBS $X_LIBS"
 116         AC_CHECK_HEADER([X11/extensions/XInput.h], [have_xinput="yes"])
 117         LIBS="$save_LIBS"
 118 fi
 119 if test "x$have_xinput" != "xyes"; then
 120         AC_MSG_ERROR([Couldn't find the XInput library. Check config.log for details])
 121 fi
 122 XINPUT_LIBS="-lXi"
 123 AC_SUBST(XINPUT_LIBS)
 124 LIBS="$LIBS $save_LIBS"
 125
 126 save_LIBS="$LIBS"
 127 LIBS=""
 128 AC_ARG_ENABLE(xevie,
 129         [AS_HELP_STRING([--enable-xevie],
 130                 [Build with XEViE support [default=yes]])],
 131         enable_xevie="$enableval", enable_xevie=yes)
 132
 133 if test -z "$backend_set"; then
 134   enable_x11_backend=yes
 135 fi
 136
 137 if test x$enable_xevie = xyes ; then
 138         have_xevie=
 139         AC_CHECK_LIB(Xext, XevieStart, have_xevie="yes", have_xevie="no", $X_LIBS)
 140
 141         if test "x$have_xevie" = "xyes"; then
 142                 XEVIE_LIBS="-lXext"
 143                 AC_DEFINE([HAVE_XEVIE], [], [Xevie is present])
 144         else
 145            AC_CHECK_LIB(Xevie, XevieQueryVersion, have_xevie="maybe",,$X_LIBS)
 146            if test "x$have_xevie" = "xmaybe"; then
 147               AC_CHECK_HEADER(X11/extensions/Xevie.h, have_xevie=yes, [],
 148               [[#include <X11/Xlib.h>
 149 ]])
 150               if test "x$have_xevie" = "xyes"; then
 151                       XEVIE_LIBS="-lXext -lXevie"
 152                       AC_DEFINE([HAVE_XEVIE], [], [Xevie is present])
 153               fi
 154            fi
 155         fi
 156         AC_SUBST(XEVIE_LIBS)
 157 fi
 158 LIBS="$LIBS $save_LIBS"
 159
 160 AC_ARG_WITH([dbus_daemondir],
 161         [AS_HELP_STRING([--with-dbus-daemondir=<directory>],
 162                 [Directory where the DBUS daemon is installed])],
 163     [DBUS_DAEMON="$with_dbus_daemondir/dbus-daemon"],
 164     [AC_PATH_PROG([DBUS_DAEMON], [dbus-daemon], [XXXDBUSDAEMONNOTFOUND],
 165                 [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR]dnl
 166 [/libexec$PATH_SEPARATOR/usr/libexec$PATH_SEPARATOR/usr/local/bin]dnl
 167 [$PATH_SEPARATOR/usr/pkg/bin])]
 168         )
 169 if test "$DBUS_DAEMON" = "XXXDBUSDAEMONNOTFOUND"; then
 170         DBUS_DAEMON = "$bindir/dbus-daemon"
 171         AC_MSG_WARN([at-spi2 relies on dbus, and the dbus-daemon was not found])
 172         AC_MSG_WARN([we assume that it will be installed in "$bindir"])
 173 fi
 174 AC_SUBST(DBUS_DAEMON)
 175
 176 AC_ARG_WITH(dbus-services,
 177            [AS_HELP_STRING([--with-dbus-services=<directory>],
 178            [where D-BUS services directory is])])
 179 if ! test -z "$with_dbus_services" ; then
 180            DBUS_SERVICES_DIR="$with_dbus_services"
 181 else
 182            DBUS_SERVICES_DIR="$datadir/dbus-1/services"
 183 fi
 184 AC_SUBST(DBUS_SERVICES_DIR)
 185
 186 AC_PATH_PROG(GLIB_MKENUMS, glib-mkenums)
 187
 188 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 189
 190 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 191
 192 dnl find sizes & alignments
 193 orig_CPPFLAGS=$CPPFLAGS
 194 CPPFLAGS="$CPPFLAGS $DBUS_CFLAGS"
 195 DBIND_CHECK_ALIGNOF(char)
 196 DBIND_CHECK_ALIGNOF(dbus_bool_t)
 197 DBIND_CHECK_ALIGNOF(dbus_int16_t)
 198 DBIND_CHECK_ALIGNOF(dbus_int32_t)
 199 DBIND_CHECK_ALIGNOF(dbus_int64_t)
 200 DBIND_CHECK_ALIGNOF(double)
 201 DBIND_CHECK_ALIGNOF(dbind_pointer)
 202 DBIND_CHECK_ALIGNOF(dbind_struct)
 203
 204 GTK_DOC_CHECK([1.09])
 205
 206 if test "x$GCC" = xyes; then
 207         CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 208 fi
 209 CPPFLAGS=$orig_CPPFLAGS
 210 AC_CONFIG_FILES([Makefile po/Makefile.in
 211         xml/Makefile
 212         dbind/Makefile
 213 dbind/dbind-config.h
 214         atspi/Makefile
 215         registryd/Makefile
 216         bus/Makefile
 217 doc/Makefile
 218 doc/libatspi/Makefile
 219 doc/libatspi/version.xml
 220 test/Makefile
 221 atspi-2.pc
 222 atspi-2-uninstalled.pc
 223 ])
 224
 225 AC_OUTPUT