configure.ac

   1 AC_INIT([at-spi2-core], [2.25.90], [accessibility-atspi@lists.linux-foundation.org])
   2 AC_PREREQ([2.59])
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_MACRO_DIR([m4])
   5
   6 AT_SPI_CORE_MAJOR_VERSION=0
   7 AT_SPI_CORE_MINOR_VERSION=1
   8 AT_SPI_CORE_MICRO_VERSION=3
   9 AT_SPI_CORE_VERSION="$AT_SPI_CORE_MAJOR_VERSION.$AT_SPI_CORE_MINOR_VERSION"
  10 AC_SUBST(AT_SPI_CORE_VERSION)
  11
  12 LT_RELEASE=$AT_SPI_CORE_VERSION
  13 LT_CURRENT=0
  14 LT_REVISION=1
  15 LT_AGE=0
  16 LT_VERSION_INFO='-version-info ${LT_CURRENT}:${LT_REVISION}:${LT_AGE}'
  17 AC_SUBST(LT_VERSION_INFO)
  18 AC_SUBST(LT_RELEASE)
  19 AC_SUBST(LT_CURRENT)
  20 AC_SUBST(LT_REVISION)
  21 AC_SUBST(LT_AGE)
  22
  23 AM_INIT_AUTOMAKE([1.13 -Wall -Wno-portability foreign subdir-objects no-dist-gzip dist-xz])
  24
  25 # Support silent build rules. Disable
  26 # by either passing --disable-silent-rules to configure or passing V=1
  27 # to make
  28 AM_SILENT_RULES([yes])
  29
  30 AM_PROG_CC_C_O
  31 LT_INIT([disable-static])
  32 PKG_PROG_PKG_CONFIG
  33
  34 AC_CONFIG_HEADERS([config.h])
  35
  36 AC_PROG_SED
  37
  38 AM_GNU_GETTEXT_VERSION([0.19.8])
  39 AM_GNU_GETTEXT([external])
  40
  41 GETTEXT_PACKAGE="${PACKAGE}"
  42 AC_SUBST(GETTEXT_PACKAGE)
  43 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
  44                    ["$GETTEXT_PACKAGE"],
  45                    [The prefix for our gettext translation domains.])
  46
  47 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.0])
  48 AC_SUBST(DBUS_LIBS)
  49 AC_SUBST(DBUS_CFLAGS)
  50
  51 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.36.0])
  52 AC_SUBST(GLIB_LIBS)
  53 AC_SUBST(GLIB_CFLAGS)
  54
  55 # Use pkg-config to find the glib-mkenums script
  56 GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
  57 AC_SUBST(GLIB_MKENUMS)
  58
  59 PKG_CHECK_MODULES(GOBJ, [gobject-2.0 >= 2.0.0])
  60 AC_SUBST(GOBJ_LIBS)
  61 AC_SUBST(GOBJ_CFLAGS)
  62
  63 PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.28])
  64 AC_SUBST(GIO_LIBS)
  65 AC_SUBST(GIO_CFLAGS)
  66
  67 # --------------------------------------------------------------------
  68 # Find DL functionality
  69
  70 AC_CHECK_LIB(c, dlopen, DL_LIBS="",
  71         AC_CHECK_LIB(dl, dlopen, DL_LIBS="-ldl",
  72                 AC_MSG_ERROR([Could not find a library with the dlopen function])
  73         )
  74 )
  75
  76 AC_SUBST(DL_LIBS)
  77
  78 AC_ARG_ENABLE(x11,
  79               [AS_HELP_STRING([--disable-x11],
  80                               [disable the X11 backend])],,
  81                               [enable_x11=auto])
  82
  83 AS_IF([test "x$enable_x11" = xno], [
  84   AM_CONDITIONAL(USE_X11, false)
  85 ], [
  86   PKG_CHECK_MODULES(X11, [x11], [
  87     AC_DEFINE(HAVE_X11, 1, [Define to use X11])
  88     AC_SUBST(HAVE_X11)
  89     have_x11=yes
  90   ], [
  91     AS_IF([test "x$enable_x11" = xyes], [
  92       AC_MSG_ERROR([Unable to find X11 development files])
  93     ])
  94     have_x11=no
  95   ])
  96
  97   # Check for additional X11 extensions
  98   AS_IF([test "x$have_x11" = xyes], [
  99     # XTest (mandatory)
 100     PKG_CHECK_MODULES(XTST, [xtst])
 101     X11_CFLAGS="$X11_CFLAGS $XTST_CFLAGS"
 102     X11_LIBS="$X11_LIBS $XTST_LIBS"
 103
 104     # XInput (mandatory)
 105     PKG_CHECK_MODULES(XINPUT, [xi])
 106     X11_CFLAGS="$X11_CFLAGS $XINPUT_CFLAGS"
 107     X11_LIBS="$X11_LIBS $XINPUT_LIBS"
 108
 109     # XKB (optional)
 110     PKG_CHECK_MODULES(XKB, [xkbcommon-x11], [
 111       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB])
 112       X11_CFLAGS="$X11_CFLAGS $XKB_CFLAGS"
 113       X11_LIBS="$X11_LIBS $XKB_LIBS"
 114     ], [])
 115   ])
 116
 117   AC_SUBST(X11_CFLAGS)
 118   AC_SUBST(X11_LIBS)
 119
 120   AM_CONDITIONAL(USE_X11, test "x$have_x11" = xyes)
 121 ])
 122
 123 AC_ARG_WITH([dbus_daemondir],
 124         [AS_HELP_STRING([--with-dbus-daemondir=<directory>],
 125                 [Directory where the DBUS daemon is installed])],
 126     [DBUS_DAEMON="$with_dbus_daemondir/dbus-daemon"],
 127     [AC_PATH_PROG([DBUS_DAEMON], [dbus-daemon], [XXXDBUSDAEMONNOTFOUND],
 128                 [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR]dnl
 129 [/libexec$PATH_SEPARATOR/usr/libexec$PATH_SEPARATOR/usr/local/bin]dnl
 130 [$PATH_SEPARATOR/usr/pkg/bin])]
 131         )
 132 if test "$DBUS_DAEMON" = "XXXDBUSDAEMONNOTFOUND"; then
 133         DBUS_DAEMON = "$bindir/dbus-daemon"
 134         AC_MSG_WARN([at-spi2 relies on dbus, and the dbus-daemon was not found])
 135         AC_MSG_WARN([we assume that it will be installed in "$bindir"])
 136 fi
 137 AC_SUBST(DBUS_DAEMON)
 138
 139 AC_ARG_WITH(dbus-services,
 140            [AS_HELP_STRING([--with-dbus-services=<directory>],
 141            [where D-BUS services directory is])])
 142 if ! test -z "$with_dbus_services" ; then
 143            DBUS_SERVICES_DIR="$with_dbus_services"
 144 else
 145            DBUS_SERVICES_DIR="$datadir/dbus-1/services"
 146 fi
 147 AC_SUBST(DBUS_SERVICES_DIR)
 148
 149 GOBJECT_INTROSPECTION_CHECK([1.32.0])
 150
 151 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 152
 153 dnl find sizes & alignments
 154 orig_CPPFLAGS=$CPPFLAGS
 155 CPPFLAGS="$CPPFLAGS $DBUS_CFLAGS"
 156 AC_CHECK_ALIGNOF(char)
 157 AC_CHECK_ALIGNOF(dbus_bool_t, [#include <dbus/dbus.h>])
 158 AC_CHECK_ALIGNOF(dbus_int16_t, [#include <dbus/dbus.h>])
 159 AC_CHECK_ALIGNOF(dbus_int32_t, [#include <dbus/dbus.h>])
 160 AC_CHECK_ALIGNOF(dbus_int64_t, [#include <dbus/dbus.h>])
 161 AC_CHECK_ALIGNOF(double, [#include <dbus/dbus.h>])
 162 AC_CHECK_ALIGNOF(dbind_pointer, [AC_INCLUDES_DEFAULT
 163 typedef void *dbind_pointer;])
 164 AC_CHECK_ALIGNOF(dbind_struct, [AC_INCLUDES_DEFAULT
 165 typedef struct {char s1;} dbind_struct;])
 166
 167 GTK_DOC_CHECK([1.25])
 168
 169 if test "x$GCC" = xyes; then
 170         CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 171 fi
 172
 173 CPPFLAGS=$orig_CPPFLAGS
 174
 175 AC_CONFIG_FILES([
 176         Makefile
 177         po/Makefile.in
 178         xml/Makefile
 179         dbind/Makefile
 180         atspi/Makefile
 181         registryd/Makefile
 182         bus/Makefile
 183         doc/Makefile
 184         doc/libatspi/Makefile
 185         doc/libatspi/version.xml
 186         test/Makefile
 187         atspi-2.pc
 188 ])
 189
 190 AC_OUTPUT