bus/meson.build

   1 libexec_conf = configuration_data()
   2 libexec_conf.set('libexecdir', atspi_libexecdir)
   3
   4 accessibility_conf = configuration_data()
   5 accessibility_conf.set('DATADIR', atspi_datadir)
   6
   7 busconfig_dir = join_paths(atspi_datadir, 'defaults/at-spi2')
   8 session_dir = join_paths(atspi_sysconfdir, 'xdg/autostart')
   9
  10 configure_file(input: 'accessibility.conf.in',
  11                output: 'accessibility.conf',
  12                configuration: accessibility_conf,
  13                install: true,
  14                install_dir: busconfig_dir)
  15
  16 configure_file(input: 'at-spi-dbus-bus.desktop.in',
  17                output: 'at-spi-dbus-bus.desktop',
  18                configuration: libexec_conf,
  19                install: true,
  20                install_dir: session_dir)
  21
  22 configure_file(input: 'org.a11y.Bus.service.in',
  23                output: 'org.a11y.Bus.service',
  24                configuration: libexec_conf,
  25                install: true,
  26                install_dir: dbus_services_dir)
  27
  28 configure_file(input: 'at-spi-dbus-bus.service.in',
  29                output: 'at-spi-dbus-bus.service',
  30                configuration: libexec_conf,
  31                install: true,
  32                install_dir: systemd_user_dir)
  33
  34 launcher_args = [
  35              '-DSYSCONFDIR="@0@"'.format(atspi_sysconfdir),
  36              '-DDATADIR="@0@"'.format(atspi_datadir),
  37              '-fPIE'
  38            ]
  39
  40 if get_option('dbus_daemon') != 'default'
  41   launcher_args += '-DDBUS_DAEMON="@0@"'.format(get_option('dbus_daemon'))
  42 else
  43   dbus_daemon = find_program('dbus-daemon',
  44                              '/sbin/dbus-daemon',
  45                              '/usr/sbin/dbus-daemon',
  46                              '/libexec/dbus-daemon',
  47                              '/usr/libexec/dbus-daemon',
  48                              '/usr/pkg/bin/dbus-daemon',
  49                              required: false)
  50   if dbus_daemon.found()
  51     launcher_args += '-DDBUS_DAEMON="@0@"'.format(dbus_daemon.path())
  52   endif
  53 endif
  54
  55 if get_option('dbus_broker') != 'default'
  56   launcher_args += '-DDBUS_BROKER="@0@"'.format(get_option('dbus_broker'))
  57 else
  58   dbus_broker = find_program('dbus-broker-launch',
  59                              required: false)
  60   if dbus_broker.found()
  61     launcher_args += '-DDBUS_BROKER="@0@"'.format(dbus_broker.path())
  62   endif
  63 endif
  64
  65 if get_option('default_bus') == 'dbus-broker'
  66   launcher_args += '-DWANT_DBUS_BROKER'
  67 endif
  68
  69 executable('at-spi-bus-launcher', 'at-spi-bus-launcher.c',
  70            include_directories: [ root_inc, include_directories('.') ],
  71            dependencies: [ gio_dep, x11_deps, app_svc_dep ],
  72            c_args: launcher_args,
  73            link_args: '-pie',
  74            install: true,
  75            install_dir: atspi_libexecdir)