bus/meson.build

   1 libexec_conf = configuration_data()
   2 libexec_conf.set('libexecdir', atspi_libexecdir)
   3
   4 accessibility_conf = configuration_data()
   5 accessibility_conf.set('DATADIR', atspi_datadir)
   6
   7 busconfig_dir = join_paths(atspi_datadir, 'defaults/at-spi2')
   8 session_dir = join_paths(atspi_sysconfdir, 'xdg/autostart')
   9
  10 configure_file(input: 'accessibility.conf.in',
  11                output: 'accessibility.conf',
  12                configuration: accessibility_conf,
  13                install: true,
  14                install_dir: busconfig_dir)
  15
  16 configure_file(input: 'at-spi-dbus-bus.desktop.in',
  17                output: 'at-spi-dbus-bus.desktop',
  18                configuration: libexec_conf,
  19                install: true,
  20                install_dir: session_dir)
  21
  22 configure_file(input: 'org.a11y.Bus.service.in',
  23                output: 'org.a11y.Bus.service',
  24                configuration: libexec_conf,
  25                install: true,
  26                install_dir: dbus_services_dir)
  27
  28 configure_file(input: 'at-spi-dbus-bus.service.in',
  29                output: 'at-spi-dbus-bus.service',
  30                configuration: libexec_conf,
  31                install: true,
  32                install_dir: systemd_user_dir)
  33
  34 launcher_args = [
  35              '-DSYSCONFDIR="@0@"'.format(atspi_sysconfdir),
  36              '-DDATADIR="@0@"'.format(atspi_datadir),
  37            ]
  38
  39 if get_option('dbus_daemon') != 'default'
  40   launcher_args += '-DDBUS_DAEMON="@0@"'.format(get_option('dbus_daemon'))
  41 else
  42   dbus_daemon = find_program('dbus-daemon',
  43                              '/sbin/dbus-daemon',
  44                              '/usr/sbin/dbus-daemon',
  45                              '/libexec/dbus-daemon',
  46                              '/usr/libexec/dbus-daemon',
  47                              '/usr/pkg/bin/dbus-daemon',
  48                              required: false)
  49   if dbus_daemon.found()
  50     launcher_args += '-DDBUS_DAEMON="@0@"'.format(dbus_daemon.path())
  51   endif
  52 endif
  53
  54 if get_option('dbus_broker') != 'default'
  55   launcher_args += '-DDBUS_BROKER="@0@"'.format(get_option('dbus_broker'))
  56 else
  57   dbus_broker = find_program('dbus-broker-launch',
  58                              required: false)
  59   if dbus_broker.found()
  60     launcher_args += '-DDBUS_BROKER="@0@"'.format(dbus_broker.path())
  61   endif
  62 endif
  63
  64 if get_option('default_bus') == 'dbus-broker'
  65   launcher_args += '-DWANT_DBUS_BROKER'
  66 endif
  67
  68 executable('at-spi-bus-launcher', 'at-spi-bus-launcher.c',
  69            include_directories: [ root_inc, include_directories('.') ],
  70            dependencies: [ gio_dep, x11_deps, app_svc_dep ],
  71            c_args: launcher_args,
  72            install: true,
  73            install_dir: atspi_libexecdir)