bus/meson.build

   1 libexec_conf = configuration_data()
   2 libexec_conf.set('libexecdir', atspi_libexecdir)
   3
   4 accessibility_conf = configuration_data()
   5 accessibility_conf.set('DATADIR', atspi_datadir)
   6
   7 busconfig_dir = join_paths(atspi_datadir, 'defaults/at-spi2')
   8 session_dir = join_paths(atspi_sysconfdir, 'xdg/autostart')
   9
  10 configure_file(input: 'accessibility.conf.in',
  11                output: 'accessibility.conf',
  12                configuration: accessibility_conf,
  13                install: true,
  14                install_dir: busconfig_dir)
  15
  16 configure_file(input: 'at-spi-dbus-bus.desktop.in',
  17                output: 'at-spi-dbus-bus.desktop',
  18                configuration: libexec_conf,
  19                install: true,
  20                install_dir: session_dir)
  21
  22 configure_file(input: 'org.a11y.Bus.service.in',
  23                output: 'org.a11y.Bus.service',
  24                configuration: libexec_conf,
  25                install: true,
  26                install_dir: dbus_services_dir)
  27
  28 configure_file(input: 'at-spi-dbus-bus.service.in',
  29                output: 'at-spi-dbus-bus.service',
  30                configuration: libexec_conf,
  31                install: true,
  32                install_dir: systemd_user_dir)
  33
  34 configure_file(input: 'at-spi-dbus-bus@.service.in',
  35                output: 'at-spi-dbus-bus@.service',
  36                configuration: libexec_conf,
  37                install: true,
  38                install_dir: systemd_system_dir)
  39
  40 launcher_args = [
  41              '-DSYSCONFDIR="@0@"'.format(atspi_sysconfdir),
  42              '-DDATADIR="@0@"'.format(atspi_datadir),
  43              '-fPIE'
  44            ]
  45
  46 if get_option('dbus_daemon') != 'default'
  47   launcher_args += '-DDBUS_DAEMON="@0@"'.format(get_option('dbus_daemon'))
  48 else
  49   dbus_daemon = find_program('dbus-daemon',
  50                              '/sbin/dbus-daemon',
  51                              '/usr/sbin/dbus-daemon',
  52                              '/libexec/dbus-daemon',
  53                              '/usr/libexec/dbus-daemon',
  54                              '/usr/pkg/bin/dbus-daemon',
  55                              required: false)
  56   if dbus_daemon.found()
  57     launcher_args += '-DDBUS_DAEMON="@0@"'.format(dbus_daemon.path())
  58   endif
  59 endif
  60
  61 if get_option('dbus_broker') != 'default'
  62   launcher_args += '-DDBUS_BROKER="@0@"'.format(get_option('dbus_broker'))
  63 else
  64   dbus_broker = find_program('dbus-broker-launch',
  65                              required: false)
  66   if dbus_broker.found()
  67     launcher_args += '-DDBUS_BROKER="@0@"'.format(dbus_broker.path())
  68   endif
  69 endif
  70
  71 if get_option('default_bus') == 'dbus-broker'
  72   launcher_args += '-DWANT_DBUS_BROKER'
  73 endif
  74
  75 executable('at-spi-bus-launcher', 'at-spi-bus-launcher.c',
  76            include_directories: [ root_inc, include_directories('.') ],
  77            dependencies: [ gio_dep, x11_deps, app_svc_dep ],
  78            c_args: launcher_args,
  79            link_args: '-pie',
  80            install: true,
  81            install_dir: atspi_libexecdir)