CMakeLists.txt

   1 # dEQP cmake file
   2
   3 # Module FindGit requires cmake >= 2.8.2
   4 cmake_minimum_required(VERSION 2.8.2)
   5
   6 find_package(Git)
   7
   8 # dEQP Target.
   9 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
  10
  11 if (DEFINED DEQP_TARGET_TOOLCHAIN)
  12         # \note Toolchain must be included before project() command
  13         include(targets/${DEQP_TARGET}/${DEQP_TARGET_TOOLCHAIN}.cmake)
  14 endif ()
  15
  16 project(dEQP-Core-${DEQP_TARGET})
  17
  18 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  19 include(framework/delibs/cmake/CFlags.cmake)
  20
  21 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  22
  23 # dEQP-specific configuration. Target file should override these.
  24 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  25
  26 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  27 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  28 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  29
  30 # Legacy APIs that don't use run-time loading
  31 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  32 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  33 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  34 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  35
  36 set(DEQP_SUPPORT_WGL            OFF)
  37 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  38
  39 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  40
  41 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  42
  43 # Delibs include directories
  44 include_directories(
  45         framework/delibs/debase
  46         framework/delibs/decpp
  47         framework/delibs/depool
  48         framework/delibs/dethread
  49         framework/delibs/deutil
  50         framework/delibs/destream
  51         )
  52
  53 # Include target-specific definitions
  54 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  55
  56 # zlib
  57 find_path(ZLIB_INCLUDE_PATH     zlib.h)
  58 find_library(ZLIB_LIBRARY       z)
  59
  60 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  61         message(STATUS "System version of zlib not found, using external/zlib")
  62         add_subdirectory(external/zlib)
  63         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  64 endif ()
  65
  66 include_directories(${ZLIB_INCLUDE_PATH})
  67
  68 # libpng
  69 find_path(PNG_INCLUDE_PATH      png.h)
  70 find_library(PNG_LIBRARY        png)
  71
  72 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  73         message(STATUS "System version of libpng not found, using external/libpng")
  74         add_subdirectory(external/libpng)
  75         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  76 endif ()
  77
  78 # glslang
  79 add_subdirectory(external/glslang)
  80
  81 # spirv-tools
  82 add_subdirectory(external/spirv-tools)
  83
  84 include_directories(${PNG_INCLUDE_PATH})
  85
  86 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
  87 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
  88 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
  89 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
  90 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
  91 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
  92 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
  93 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
  94 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
  95 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
  96 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
  97
  98 # Defines
  99 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
 100
 101 # Entry points loaded directly by linking to libGL*?
 102 if (DEFINED DEQP_GLES2_LIBRARIES)
 103         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
 104 endif ()
 105
 106 if (DEFINED DEQP_GLES3_LIBRARIES)
 107         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 108 endif ()
 109
 110 if (DEFINED DEQP_GLES31_LIBRARIES)
 111         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 112 endif ()
 113
 114 if (DEFINED DEQP_GLES32_LIBRARIES)
 115         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 116 endif ()
 117
 118 if (DEFINED DEQP_EGL_LIBRARIES)
 119         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 120 endif ()
 121
 122 # Legacy APIs that don't support run-time loading
 123 if (DEQP_SUPPORT_GLES1)
 124         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 125
 126         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 127                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 128         endif ()
 129 endif ()
 130
 131 if (DEQP_SUPPORT_VG)
 132         add_definitions(-DDEQP_SUPPORT_VG=1)
 133
 134         if (NOT DEFINED DEQP_VG_LIBRARIES)
 135                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 136         endif ()
 137 endif ()
 138
 139 if (DE_COMPILER_IS_MSC)
 140         # Don't nag about std::copy for example
 141         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 142 endif ()
 143
 144 # delibs projects
 145 add_subdirectory(framework/delibs/debase)
 146 add_subdirectory(framework/delibs/depool)
 147 add_subdirectory(framework/delibs/dethread)
 148 add_subdirectory(framework/delibs/destream)
 149 add_subdirectory(framework/delibs/deutil)
 150 add_subdirectory(framework/delibs/decpp)
 151
 152 # ExecServer
 153 add_subdirectory(execserver)
 154
 155 # Executor framework and tools
 156 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 157         add_subdirectory(executor)
 158 endif ()
 159
 160 # Test framework include directories
 161 include_directories(
 162         framework/common
 163         framework/qphelper
 164         framework/opengl
 165         framework/opengl/wrapper
 166         framework/referencerenderer
 167         framework/opengl/simplereference
 168         framework/randomshaders
 169         framework/egl
 170         framework/egl/wrapper
 171         external/vulkancts/framework/vulkan
 172         )
 173
 174 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 175         # On Android deqp modules are compiled as libraries and linked into final .so
 176         set(DEQP_MODULE_LIBRARIES )
 177         set(DEQP_MODULE_ENTRY_POINTS )
 178 endif ()
 179
 180 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 181 macro (target_copy_files target dep_name files)
 182         if (NOT "${files}" STREQUAL "")
 183                 set(COPY_TARGETS )
 184                 foreach (SRCNAME ${files})
 185                         get_filename_component(BASENAME ${SRCNAME} NAME)
 186                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 187                         add_custom_command(OUTPUT ${DSTNAME}
 188                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 189                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 190                 endforeach ()
 191
 192                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 193                 add_dependencies(${target} ${dep_name})
 194         endif ()
 195 endmacro (target_copy_files)
 196
 197 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 198 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 199
 200 # Macro for adding dEQP module
 201 # This adds 3 targets:
 202 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 203 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 204 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 205 macro (add_deqp_module MODULE_NAME SRCS LIBS ENTRY)
 206
 207         # Library target
 208         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 209         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 210
 211         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 212         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 213
 214         # Forward to parent scope
 215         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 216         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 217
 218         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 219                 # Executable target
 220                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 221                 target_link_libraries(${MODULE_NAME} tcutil-platform "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 222                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 223         endif ()
 224
 225         # Data file target
 226         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 227         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 228 endmacro (add_deqp_module)
 229
 230 # Macro for adding data dirs to module
 231 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 232         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 233                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 234
 235         elseif (DE_OS_IS_ANDROID)
 236                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 237
 238         elseif (DE_OS_IS_IOS)
 239                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 240         endif ()
 241 endmacro (add_data_dir)
 242
 243 # Macro for adding individual data files to module
 244 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 245         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 246                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 247
 248         elseif (DE_OS_IS_ANDROID)
 249                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 250
 251         elseif (DE_OS_IS_IOS)
 252                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 253         endif ()
 254 endmacro (add_data_file)
 255
 256 add_subdirectory(framework)
 257 add_subdirectory(external/vulkancts/framework/vulkan)
 258
 259 if (DE_COMPILER_IS_MSC)
 260         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 261 endif ()
 262
 263 add_subdirectory(modules)
 264 add_subdirectory(external/vulkancts/modules/vulkan)
 265 add_subdirectory(external/openglcts)
 266
 267 # Single-binary targets
 268 if (DE_OS_IS_ANDROID)
 269         include_directories(executor)
 270
 271         set(DEQP_SRCS
 272                 framework/platform/android/tcuAndroidMain.cpp
 273                 framework/platform/android/tcuAndroidJNI.cpp
 274                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 275                 framework/platform/android/tcuTestLogParserJNI.cpp
 276                 ${DEQP_MODULE_ENTRY_POINTS}
 277                 )
 278
 279         set(DEQP_LIBS
 280                 tcutil-platform
 281                 xecore
 282                 ${DEQP_MODULE_LIBRARIES}
 283                 )
 284
 285         add_library(deqp SHARED ${DEQP_SRCS})
 286         target_link_libraries(deqp ${DEQP_LIBS})
 287
 288         # Needed by OpenGL CTS that defines its own activity but depends on
 289         # common Android support code.
 290         target_include_directories(deqp PRIVATE framework/platform/android)
 291
 292 elseif (DE_OS_IS_IOS)
 293         # Code sign identity
 294         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 295
 296         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 297         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 298
 299         include_directories(framework/platform/ios)
 300         set(TESTERCORE_SRC_FILES
 301                 framework/platform/ios/tcuEAGLView.h
 302                 framework/platform/ios/tcuEAGLView.m
 303                 framework/platform/ios/tcuIOSAppDelegate.h
 304                 framework/platform/ios/tcuIOSAppDelegate.m
 305                 framework/platform/ios/tcuIOSViewController.h
 306                 framework/platform/ios/tcuIOSViewController.m
 307                 framework/platform/ios/tcuIOSMain.m
 308                 )
 309         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 310
 311         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 312         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 313         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 314         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 315 endif ()