CMakeLists.txt

   1 # dEQP cmake file
   2
   3 # Module FindGit requires cmake >= 2.8.2
   4 cmake_minimum_required(VERSION 3.10.2)
   5
   6 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/framework/delibs/cmake")
   7 find_package(Git)
   8 find_package(PythonInterp 3)
   9
  10 # dEQP Target.
  11 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
  12
  13 if (DEFINED DEQP_TARGET_TOOLCHAIN)
  14         # \note Toolchain must be included before project() command
  15         include(targets/${DEQP_TARGET}/${DEQP_TARGET_TOOLCHAIN}.cmake NO_POLICY_SCOPE)
  16 endif ()
  17
  18 project(dEQP-Core-${DEQP_TARGET})
  19
  20 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  21 include(framework/delibs/cmake/CFlags.cmake)
  22
  23 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  24
  25 # dEQP-specific configuration. Target file should override these.
  26 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  27
  28 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  29 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  30 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  31
  32 # Legacy APIs that don't use run-time loading
  33 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  34 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  35 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  36 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  37
  38 set(DEQP_SUPPORT_WGL            OFF)
  39 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  40
  41 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  42
  43 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  44
  45 # Delibs include directories
  46 include_directories(
  47         framework/delibs/debase
  48         framework/delibs/decpp
  49         framework/delibs/depool
  50         framework/delibs/dethread
  51         framework/delibs/deutil
  52         framework/delibs/destream
  53         )
  54
  55 # Include target-specific definitions
  56 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  57
  58 # zlib
  59 find_package(ZLIB)
  60 # dEQP CMake compatibility (as for libpng)
  61 set(ZLIB_INCLUDE_PATH ${ZLIB_INCLUDE_DIRS})
  62 set(ZLIB_LIBRARY ${ZLIB_LIBRARIES})
  63
  64 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  65         message(STATUS "System version of zlib not found, using external/zlib")
  66         add_subdirectory(external/zlib)
  67         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  68 endif ()
  69
  70 if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/external/renderdoc/src/renderdoc_app.h")
  71         message(STATUS "Renderdoc header found, integration enabled")
  72         set(DEQP_HAVE_RENDERDOC_HEADER 1)
  73 else ()
  74         message(STATUS "Renderdoc header not found, integration will not work")
  75 endif ()
  76
  77 include_directories(${ZLIB_INCLUDE_PATH})
  78
  79 # libpng
  80 #
  81 # The FindPNG module defines PNG_INCLUDE_DIRS and PNG_LIBRARIES. But dEQP's
  82 # CMake files expect the non-standard PNG_INCLUDE_PATH and PNG_LIBRARY. Set the
  83 # non-standard variables here to retain compatibility with dEQP's existing
  84 # CMake files.
  85 find_package(PNG)
  86 set(PNG_INCLUDE_PATH ${PNG_INCLUDE_DIRS})
  87 set(PNG_LIBRARY ${PNG_LIBRARIES})
  88
  89 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  90         message(STATUS "System version of libpng not found, using external/libpng")
  91         add_subdirectory(external/libpng)
  92         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  93 endif ()
  94
  95 # glslang
  96 add_subdirectory(external/glslang)
  97
  98 # spirv-tools
  99 add_subdirectory(external/spirv-tools)
 100
 101 # spirv-headers
 102 set(SPIRV_INCLUDE_PATH "${PROJECT_SOURCE_DIR}/external/spirv-headers/src/include")
 103 if (NOT EXISTS ${SPIRV_INCLUDE_PATH})
 104         message(FATAL_ERROR "SPIR-V headers not found, please run external/fetch_sources.py")
 105 endif()
 106 include_directories(${SPIRV_INCLUDE_PATH})
 107
 108 # Amber
 109 add_subdirectory(external/amber)
 110 include_directories(external/amber)
 111
 112 # jsoncpp
 113 add_subdirectory(external/jsoncpp)
 114 include_directories(external/jsoncpp/src/include)
 115
 116 # RenderDoc API
 117 include_directories(external/renderdoc/src)
 118
 119 # FFmpeg used in vulkan video won't be part of android target
 120 if (NOT DE_OS_IS_ANDROID)
 121         # FFmpeg
 122         if (DE_OS_IS_WIN32)
 123                 add_subdirectory(external/ffmpeg)
 124                 include_directories(external/ffmpeg/src/include)
 125         else()
 126                 find_package(FFmpeg REQUIRED)
 127                 # FFMPEG_FOUND - system has ffmpeg or libav
 128                 # FFMPEG_INCLUDE_DIR - the ffmpeg include directory
 129                 # FFMPEG_LIBRARIES
 130                 # FFMPEG_LIBAVCODEC
 131                 # FFMPEG_LIBAVFORMAT
 132                 # FFMPEG_LIBAVUTIL
 133                 if(FFMPEG_FOUND)
 134                         message("Found FFMPEG/LibAV libraries")
 135                         include_directories(${FFMPEG_INCLUDE_DIR})
 136                 else()
 137                         #add_subdirectory(external/ffmpeg)
 138                         include_directories(external/ffmpeg/src/include)
 139                 endif()
 140         endif()
 141 endif()
 142 include_directories(${PNG_INCLUDE_PATH})
 143
 144 # DRM (Direct Rendering Manager) Headers
 145 find_path(XF86DRM_H_PATH NAMES xf86drm.h)
 146 find_path(DRM_H_PATH NAMES drm.h PATH_SUFFIXES libdrm drm)
 147
 148 if (XF86DRM_H_PATH AND DRM_H_PATH)
 149         include_directories(${XF86DRM_H_PATH})
 150         include_directories(${DRM_H_PATH})
 151         set(DEQP_SUPPORT_DRM ON CACHE BOOL "Build code requiring the Linux/Unix Direct Rendering Manager")
 152         mark_as_advanced(XF86DRM_H_PATH)
 153         mark_as_advanced(DRM_H_PATH)
 154 else ()
 155         set(DEQP_SUPPORT_DRM OFF CACHE BOOL "Build code requiring the Linux/Unix Direct Rendering Manager")
 156 endif ()
 157
 158 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
 159 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
 160 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
 161 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
 162 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
 163 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
 164 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
 165 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
 166 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
 167 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
 168 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
 169 message(STATUS "DEQP_SUPPORT_DRM        = ${DEQP_SUPPORT_DRM}")
 170
 171 # Defines
 172 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
 173
 174 # Entry points loaded directly by linking to libGL*?
 175 if (DEFINED DEQP_GLES2_LIBRARIES)
 176         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
 177 endif ()
 178
 179 if (DEFINED DEQP_GLES3_LIBRARIES)
 180         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 181 endif ()
 182
 183 if (DEFINED DEQP_GLES31_LIBRARIES)
 184         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 185 endif ()
 186
 187 if (DEFINED DEQP_GLES32_LIBRARIES)
 188         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 189 endif ()
 190
 191 if (DEFINED DEQP_EGL_LIBRARIES)
 192         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 193 endif ()
 194
 195 # Legacy APIs that don't support run-time loading
 196 if (DEQP_SUPPORT_GLES1)
 197         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 198
 199         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 200                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 201         endif ()
 202 endif ()
 203
 204 if (DEQP_SUPPORT_VG)
 205         add_definitions(-DDEQP_SUPPORT_VG=1)
 206
 207         if (NOT DEFINED DEQP_VG_LIBRARIES)
 208                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 209         endif ()
 210 endif ()
 211
 212 if (DEQP_SUPPORT_DRM)
 213         add_definitions(-DDEQP_SUPPORT_DRM=1)
 214 else ()
 215         add_definitions(-DDEQP_SUPPORT_DRM=0)
 216 endif ()
 217
 218 if (DE_COMPILER_IS_MSC)
 219         # Don't nag about std::copy for example
 220         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 221 endif ()
 222
 223 # Precompiled header macro. Parameters are source file list and filename for pch cpp file.
 224 macro(PCH SRCS PCHCPP)
 225   if(MSVC AND CMAKE_GENERATOR MATCHES "^Visual Studio")
 226     set(PCH_NAME "$(IntDir)\\pch.pch")
 227     # make source files use/depend on PCH_NAME
 228     set_source_files_properties(${${SRCS}} PROPERTIES COMPILE_FLAGS "/Yupch.h /FIpch.h /Fp${PCH_NAME}" OBJECT_DEPENDS "${PCH_NAME}")
 229     # make PCHCPP file compile and generate PCH_NAME
 230     set_source_files_properties(${PCHCPP} PROPERTIES COMPILE_FLAGS "/Ycpch.h /Fp${PCH_NAME}" OBJECT_OUTPUTS "${PCH_NAME}")
 231     list(APPEND ${SRCS} "${PCHCPP}")
 232   endif()
 233 endmacro(PCH)
 234
 235 # delibs projects
 236 add_subdirectory(framework/delibs/debase)
 237 add_subdirectory(framework/delibs/depool)
 238 add_subdirectory(framework/delibs/dethread)
 239 add_subdirectory(framework/delibs/destream)
 240 add_subdirectory(framework/delibs/deutil)
 241 add_subdirectory(framework/delibs/decpp)
 242
 243 # ExecServer
 244 add_subdirectory(execserver)
 245
 246 # Executor framework and tools
 247 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 248         add_subdirectory(executor)
 249 endif ()
 250
 251 # Test framework include directories
 252 include_directories(
 253         framework/common
 254         framework/qphelper
 255         framework/opengl
 256         framework/opengl/wrapper
 257         framework/referencerenderer
 258         framework/opengl/simplereference
 259         framework/randomshaders
 260         framework/egl
 261         framework/egl/wrapper
 262         framework/xexml
 263         external/vulkancts/framework/vulkan
 264         external/vulkancts/framework/vulkan/generated/vulkan
 265         )
 266
 267 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 268         # On Android deqp modules are compiled as libraries and linked into final .so
 269         set(DEQP_MODULE_LIBRARIES )
 270         set(DEQP_MODULE_ENTRY_POINTS )
 271 endif ()
 272
 273 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 274 macro (target_copy_files target dep_name files)
 275         if (NOT "${files}" STREQUAL "")
 276                 set(COPY_TARGETS )
 277                 foreach (SRCNAME ${files})
 278                         get_filename_component(BASENAME ${SRCNAME} NAME)
 279                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 280                         add_custom_command(OUTPUT ${DSTNAME}
 281                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 282                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 283                 endforeach ()
 284
 285                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 286                 add_dependencies(${target} ${dep_name})
 287         endif ()
 288 endmacro (target_copy_files)
 289
 290 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 291 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 292
 293 # Macro for adding dEQP module
 294 # This adds 3 targets:
 295 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 296 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 297 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 298 macro (add_deqp_module MODULE_NAME SRCS LIBS EXECLIBS ENTRY)
 299
 300         # Library target
 301         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 302         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 303
 304         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 305         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 306
 307         # Forward to parent scope
 308         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 309         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 310
 311         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 312                 # Executable target
 313                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 314                 target_link_libraries(${MODULE_NAME} PUBLIC "${EXECLIBS}" "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 315                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 316         endif ()
 317
 318         # Data file target
 319         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 320         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 321 endmacro (add_deqp_module)
 322
 323 # Macro add_deqp_module_skip_android does not add module to DEQP_MODULE_LIBRARIES, so that it is not created on Android.
 324 # It's a temporary solution to disable Vulkan SC tests on Android, because later defined deqp library
 325 # uses both deqp-vk and deqp-vksc and this means that definitions CTS_USES_VULKAN and CTS_USES_VULKANSC
 326 # exist in deqp library at the same time which causes code to not compile.
 327 macro (add_deqp_module_skip_android MODULE_NAME SRCS LIBS EXECLIBS ENTRY)
 328
 329         # Library target
 330         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 331         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 332
 333         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 334                 # Executable target
 335                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 336                 target_link_libraries(${MODULE_NAME} PUBLIC "${EXECLIBS}" "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 337                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 338         endif ()
 339
 340         # Data file target
 341         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 342         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 343 endmacro (add_deqp_module_skip_android)
 344
 345 # Macro for adding data dirs to module
 346 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 347         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 348                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 349
 350         elseif (DE_OS_IS_ANDROID)
 351                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 352
 353         elseif (DE_OS_IS_IOS)
 354                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 355         endif ()
 356 endmacro (add_data_dir)
 357
 358 # Macro for adding individual data files to module
 359 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 360         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 361                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 362
 363         elseif (DE_OS_IS_ANDROID)
 364                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 365
 366         elseif (DE_OS_IS_IOS)
 367                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 368         endif ()
 369 endmacro (add_data_file)
 370
 371 add_subdirectory(framework)
 372 add_subdirectory(external/vulkancts/framework/vulkan)
 373
 374 if (DE_COMPILER_IS_MSC)
 375         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 376 endif ()
 377
 378 add_subdirectory(modules)
 379 add_subdirectory(external/vulkancts/modules/vulkan)
 380 add_subdirectory(external/vulkancts/vkscserver)
 381 add_subdirectory(external/vulkancts/vkscpc)
 382 add_subdirectory(external/openglcts)
 383
 384 # Single-binary targets
 385 if (DE_OS_IS_ANDROID)
 386         include_directories(executor)
 387         include_directories(${PROJECT_BINARY_DIR}/external/vulkancts/framework/vulkan)
 388
 389         set(DEQP_SRCS
 390                 framework/platform/android/tcuAndroidMain.cpp
 391                 framework/platform/android/tcuAndroidJNI.cpp
 392                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 393                 framework/platform/android/tcuTestLogParserJNI.cpp
 394                 ${DEQP_MODULE_ENTRY_POINTS}
 395                 )
 396
 397         set(DEQP_LIBS
 398                 tcutil-platform
 399                 xecore
 400                 ${DEQP_MODULE_LIBRARIES}
 401                 )
 402
 403         add_library(deqp SHARED ${DEQP_SRCS})
 404         target_link_libraries(deqp ${DEQP_LIBS})
 405
 406         # Separate out the debug information because it's enormous
 407         add_custom_command(TARGET deqp POST_BUILD
 408                 COMMAND ${CMAKE_STRIP} --only-keep-debug -o $<TARGET_FILE:deqp>.debug $<TARGET_FILE:deqp>
 409                 COMMAND ${CMAKE_STRIP} -g $<TARGET_FILE:deqp>)
 410
 411         # Needed by OpenGL CTS that defines its own activity but depends on
 412         # common Android support code.
 413         target_include_directories(deqp PRIVATE framework/platform/android)
 414
 415 elseif (DE_OS_IS_IOS)
 416         # Code sign identity
 417         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 418
 419         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 420         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 421
 422         include_directories(framework/platform/ios)
 423         set(TESTERCORE_SRC_FILES
 424                 framework/platform/ios/tcuEAGLView.h
 425                 framework/platform/ios/tcuEAGLView.m
 426                 framework/platform/ios/tcuIOSAppDelegate.h
 427                 framework/platform/ios/tcuIOSAppDelegate.m
 428                 framework/platform/ios/tcuIOSViewController.h
 429                 framework/platform/ios/tcuIOSViewController.m
 430                 framework/platform/ios/tcuIOSMain.m
 431                 )
 432         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 433
 434         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 435         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 436         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 437         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 438 endif ()
 439
 440 if (DE_OS_IS_FUCHSIA)
 441         # The default Fuchsia stack is small, so the size needs to be increased to at
 442         # least 2**20 bytes, but 2**24 is chosen for safety.
 443         set_target_properties(deqp-vk PROPERTIES LINK_FLAGS "-Wl,-z,stack-size=0x1000000")
 444 endif ()