CMakeLists.txt

   1 # dEQP cmake file
   2
   3 # Module FindGit requires cmake >= 2.8.2
   4 cmake_minimum_required(VERSION 3.10.2)
   5
   6 find_package(Git)
   7 find_package(PythonInterp 3)
   8
   9 # dEQP Target.
  10 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
  11
  12 if (DEFINED DEQP_TARGET_TOOLCHAIN)
  13         # \note Toolchain must be included before project() command
  14         include(targets/${DEQP_TARGET}/${DEQP_TARGET_TOOLCHAIN}.cmake NO_POLICY_SCOPE)
  15 endif ()
  16
  17 project(dEQP-Core-${DEQP_TARGET})
  18
  19 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  20 include(framework/delibs/cmake/CFlags.cmake)
  21
  22 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  23
  24 # dEQP-specific configuration. Target file should override these.
  25 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  26
  27 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  28 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  29 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  30
  31 # Legacy APIs that don't use run-time loading
  32 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  33 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  34 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  35 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  36
  37 set(DEQP_SUPPORT_WGL            OFF)
  38 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  39
  40 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  41
  42 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  43
  44 # Delibs include directories
  45 include_directories(
  46         framework/delibs/debase
  47         framework/delibs/decpp
  48         framework/delibs/depool
  49         framework/delibs/dethread
  50         framework/delibs/deutil
  51         framework/delibs/destream
  52         )
  53
  54 # Include target-specific definitions
  55 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  56
  57 # zlib
  58 find_package(ZLIB)
  59 # dEQP CMake compatibility (as for libpng)
  60 set(ZLIB_INCLUDE_PATH ${ZLIB_INCLUDE_DIRS})
  61 set(ZLIB_LIBRARY ${ZLIB_LIBRARIES})
  62
  63 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  64         message(STATUS "System version of zlib not found, using external/zlib")
  65         add_subdirectory(external/zlib)
  66         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  67 endif ()
  68
  69 include_directories(${ZLIB_INCLUDE_PATH})
  70
  71 # libpng
  72 #
  73 # The FindPNG module defines PNG_INCLUDE_DIRS and PNG_LIBRARIES. But dEQP's
  74 # CMake files expect the non-standard PNG_INCLUDE_PATH and PNG_LIBRARY. Set the
  75 # non-standard variables here to retain compatibility with dEQP's existing
  76 # CMake files.
  77 find_package(PNG)
  78 set(PNG_INCLUDE_PATH ${PNG_INCLUDE_DIRS})
  79 set(PNG_LIBRARY ${PNG_LIBRARIES})
  80
  81 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  82         message(STATUS "System version of libpng not found, using external/libpng")
  83         add_subdirectory(external/libpng)
  84         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  85 endif ()
  86
  87 # glslang
  88 add_subdirectory(external/glslang)
  89
  90 # spirv-tools
  91 add_subdirectory(external/spirv-tools)
  92
  93 # spirv-headers
  94 set(SPIRV_INCLUDE_PATH "${PROJECT_SOURCE_DIR}/external/spirv-headers/src/include")
  95 if (NOT EXISTS ${SPIRV_INCLUDE_PATH})
  96         message(FATAL_ERROR "SPIR-V headers not found, please run external/fetch_sources.py")
  97 endif()
  98 include_directories(${SPIRV_INCLUDE_PATH})
  99
 100 # Amber
 101 add_subdirectory(external/amber)
 102 include_directories(external/amber)
 103
 104 # RenderDoc API
 105 include_directories(external/renderdoc/src)
 106
 107 include_directories(${PNG_INCLUDE_PATH})
 108
 109 # DRM (Direct Rendering Manager) Headers
 110 find_path(XF86DRM_H_PATH NAMES xf86drm.h)
 111 find_path(DRM_H_PATH NAMES drm.h PATH_SUFFIXES libdrm drm)
 112
 113 if (XF86DRM_H_PATH AND DRM_H_PATH)
 114         include_directories(${XF86DRM_H_PATH})
 115         include_directories(${DRM_H_PATH})
 116         set(DEQP_SUPPORT_DRM ON CACHE BOOL "Build code requiring the Linux/Unix Direct Rendering Manager")
 117         mark_as_advanced(XF86DRM_H_PATH)
 118         mark_as_advanced(DRM_H_PATH)
 119 else ()
 120         set(DEQP_SUPPORT_DRM OFF CACHE BOOL "Build code requiring the Linux/Unix Direct Rendering Manager")
 121 endif ()
 122
 123 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
 124 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
 125 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
 126 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
 127 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
 128 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
 129 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
 130 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
 131 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
 132 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
 133 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
 134 message(STATUS "DEQP_SUPPORT_DRM        = ${DEQP_SUPPORT_DRM}")
 135
 136 # Defines
 137 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
 138
 139 # Entry points loaded directly by linking to libGL*?
 140 if (DEFINED DEQP_GLES2_LIBRARIES)
 141         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
 142 endif ()
 143
 144 if (DEFINED DEQP_GLES3_LIBRARIES)
 145         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 146 endif ()
 147
 148 if (DEFINED DEQP_GLES31_LIBRARIES)
 149         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 150 endif ()
 151
 152 if (DEFINED DEQP_GLES32_LIBRARIES)
 153         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 154 endif ()
 155
 156 if (DEFINED DEQP_EGL_LIBRARIES)
 157         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 158 endif ()
 159
 160 # Legacy APIs that don't support run-time loading
 161 if (DEQP_SUPPORT_GLES1)
 162         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 163
 164         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 165                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 166         endif ()
 167 endif ()
 168
 169 if (DEQP_SUPPORT_VG)
 170         add_definitions(-DDEQP_SUPPORT_VG=1)
 171
 172         if (NOT DEFINED DEQP_VG_LIBRARIES)
 173                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 174         endif ()
 175 endif ()
 176
 177 if (DEQP_SUPPORT_DRM)
 178         add_definitions(-DDEQP_SUPPORT_DRM=1)
 179 else ()
 180         add_definitions(-DDEQP_SUPPORT_DRM=0)
 181 endif ()
 182
 183 if (DE_COMPILER_IS_MSC)
 184         # Don't nag about std::copy for example
 185         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 186 endif ()
 187
 188 # Precompiled header macro. Parameters are source file list and filename for pch cpp file.
 189 macro(PCH SRCS PCHCPP)
 190   if(MSVC AND CMAKE_GENERATOR MATCHES "^Visual Studio")
 191     set(PCH_NAME "$(IntDir)\\pch.pch")
 192     # make source files use/depend on PCH_NAME
 193     set_source_files_properties(${${SRCS}} PROPERTIES COMPILE_FLAGS "/Yupch.h /FIpch.h /Fp${PCH_NAME}" OBJECT_DEPENDS "${PCH_NAME}")
 194     # make PCHCPP file compile and generate PCH_NAME
 195     set_source_files_properties(${PCHCPP} PROPERTIES COMPILE_FLAGS "/Ycpch.h /Fp${PCH_NAME}" OBJECT_OUTPUTS "${PCH_NAME}")
 196     list(APPEND ${SRCS} "${PCHCPP}")
 197   endif()
 198 endmacro(PCH)
 199
 200 # delibs projects
 201 add_subdirectory(framework/delibs/debase)
 202 add_subdirectory(framework/delibs/depool)
 203 add_subdirectory(framework/delibs/dethread)
 204 add_subdirectory(framework/delibs/destream)
 205 add_subdirectory(framework/delibs/deutil)
 206 add_subdirectory(framework/delibs/decpp)
 207
 208 # ExecServer
 209 add_subdirectory(execserver)
 210
 211 # Executor framework and tools
 212 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 213         add_subdirectory(executor)
 214 endif ()
 215
 216 # Test framework include directories
 217 include_directories(
 218         framework/common
 219         framework/qphelper
 220         framework/opengl
 221         framework/opengl/wrapper
 222         framework/referencerenderer
 223         framework/opengl/simplereference
 224         framework/randomshaders
 225         framework/egl
 226         framework/egl/wrapper
 227         framework/xexml
 228         external/vulkancts/framework/vulkan
 229         )
 230
 231 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 232         # On Android deqp modules are compiled as libraries and linked into final .so
 233         set(DEQP_MODULE_LIBRARIES )
 234         set(DEQP_MODULE_ENTRY_POINTS )
 235 endif ()
 236
 237 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 238 macro (target_copy_files target dep_name files)
 239         if (NOT "${files}" STREQUAL "")
 240                 set(COPY_TARGETS )
 241                 foreach (SRCNAME ${files})
 242                         get_filename_component(BASENAME ${SRCNAME} NAME)
 243                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 244                         add_custom_command(OUTPUT ${DSTNAME}
 245                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 246                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 247                 endforeach ()
 248
 249                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 250                 add_dependencies(${target} ${dep_name})
 251         endif ()
 252 endmacro (target_copy_files)
 253
 254 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 255 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 256
 257 # Macro for adding dEQP module
 258 # This adds 3 targets:
 259 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 260 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 261 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 262 macro (add_deqp_module MODULE_NAME SRCS LIBS ENTRY)
 263
 264         # Library target
 265         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 266         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 267
 268         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 269         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 270
 271         # Forward to parent scope
 272         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 273         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 274
 275         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 276                 # Executable target
 277                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 278                 target_link_libraries(${MODULE_NAME} tcutil-platform "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 279                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 280         endif ()
 281
 282         # Data file target
 283         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 284         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 285 endmacro (add_deqp_module)
 286
 287 # Macro for adding data dirs to module
 288 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 289         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 290                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 291
 292         elseif (DE_OS_IS_ANDROID)
 293                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 294
 295         elseif (DE_OS_IS_IOS)
 296                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 297         endif ()
 298 endmacro (add_data_dir)
 299
 300 # Macro for adding individual data files to module
 301 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 302         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 303                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 304
 305         elseif (DE_OS_IS_ANDROID)
 306                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 307
 308         elseif (DE_OS_IS_IOS)
 309                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 310         endif ()
 311 endmacro (add_data_file)
 312
 313 add_subdirectory(framework)
 314 add_subdirectory(external/vulkancts/framework/vulkan)
 315
 316 if (DE_COMPILER_IS_MSC)
 317         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 318 endif ()
 319
 320 add_subdirectory(modules)
 321 add_subdirectory(external/vulkancts/modules/vulkan)
 322 add_subdirectory(external/openglcts)
 323
 324 # Single-binary targets
 325 if (DE_OS_IS_ANDROID)
 326         include_directories(executor)
 327
 328         set(DEQP_SRCS
 329                 framework/platform/android/tcuAndroidMain.cpp
 330                 framework/platform/android/tcuAndroidJNI.cpp
 331                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 332                 framework/platform/android/tcuTestLogParserJNI.cpp
 333                 ${DEQP_MODULE_ENTRY_POINTS}
 334                 )
 335
 336         set(DEQP_LIBS
 337                 tcutil-platform
 338                 xecore
 339                 ${DEQP_MODULE_LIBRARIES}
 340                 )
 341
 342         add_library(deqp SHARED ${DEQP_SRCS})
 343         target_link_libraries(deqp ${DEQP_LIBS})
 344
 345         # Separate out the debug information because it's enormous
 346         add_custom_command(TARGET deqp POST_BUILD
 347                 COMMAND ${CMAKE_STRIP} --only-keep-debug -o $<TARGET_FILE:deqp>.debug $<TARGET_FILE:deqp>
 348                 COMMAND ${CMAKE_STRIP} -g $<TARGET_FILE:deqp>)
 349
 350         # Needed by OpenGL CTS that defines its own activity but depends on
 351         # common Android support code.
 352         target_include_directories(deqp PRIVATE framework/platform/android)
 353
 354 elseif (DE_OS_IS_IOS)
 355         # Code sign identity
 356         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 357
 358         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 359         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 360
 361         include_directories(framework/platform/ios)
 362         set(TESTERCORE_SRC_FILES
 363                 framework/platform/ios/tcuEAGLView.h
 364                 framework/platform/ios/tcuEAGLView.m
 365                 framework/platform/ios/tcuIOSAppDelegate.h
 366                 framework/platform/ios/tcuIOSAppDelegate.m
 367                 framework/platform/ios/tcuIOSViewController.h
 368                 framework/platform/ios/tcuIOSViewController.m
 369                 framework/platform/ios/tcuIOSMain.m
 370                 )
 371         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 372
 373         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 374         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 375         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 376         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 377 endif ()