CMakeLists.txt

   1 # dEQP cmake file
   2
   3 cmake_minimum_required(VERSION 2.6)
   4
   5 # dEQP Target.
   6 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
   7
   8 project(dEQP-Core-${DEQP_TARGET})
   9
  10 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  11 include(framework/delibs/cmake/CFlags.cmake)
  12
  13 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  14
  15 # dEQP-specific configuration. Target file should override these.
  16 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  17
  18 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  19 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  20 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  21
  22 # Legacy APIs that don't use run-time loading
  23 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  24 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  25 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  26 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  27
  28 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  29
  30 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  31
  32 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  33
  34 # Delibs include directories
  35 include_directories(
  36         framework/delibs/debase
  37         framework/delibs/decpp
  38         framework/delibs/depool
  39         framework/delibs/dethread
  40         framework/delibs/deutil
  41         framework/delibs/destream
  42         )
  43
  44 # Include target-specific definitions
  45 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  46
  47 # zlib
  48 find_path(ZLIB_INCLUDE_PATH     zlib.h)
  49 find_library(ZLIB_LIBRARY       z)
  50
  51 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  52         message(STATUS "System version of zlib not found, using external/zlib")
  53         add_subdirectory(external/zlib)
  54         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  55 endif ()
  56
  57 include_directories(${ZLIB_INCLUDE_PATH})
  58
  59 # libpng
  60 #
  61 # The FindPNG module defines PNG_INCLUDE_DIRS and PNG_LIBRARIES. But dEQP's
  62 # CMake files expect the non-standard PNG_INCLUDE_PATH and PNG_LIBRARY. Set the
  63 # non-standard variables here to retain compatibility with dEQP's existing
  64 # CMake files.
  65 include(FindPNG)
  66 set(PNG_INCLUDE_PATH ${PNG_INCLUDE_DIRS})
  67 set(PNG_LIBRARY ${PNG_LIBRARIES})
  68
  69 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  70         message(STATUS "System version of libpng not found, using external/libpng")
  71         add_subdirectory(external/libpng)
  72         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  73 endif ()
  74
  75 # glslang
  76 add_subdirectory(external/glslang)
  77
  78 # spirv-tools
  79 add_subdirectory(external/spirv-tools)
  80
  81 include_directories(${PNG_INCLUDE_PATH})
  82
  83 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
  84 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
  85 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
  86 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
  87 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
  88 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
  89 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
  90 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
  91 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
  92
  93 # Defines
  94 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
  95
  96 if (DEQP_SUPPORT_GLES1)
  97         add_definitions(-DDEQP_SUPPORT_GLES1=1)
  98 endif ()
  99
 100 if (DEQP_SUPPORT_VG)
 101         add_definitions(-DDEQP_SUPPORT_VG=1)
 102 endif ()
 103
 104 # Entry points loaded on run-time?
 105 if (NOT DEFINED DEQP_GLES2_LIBRARIES)
 106         add_definitions(-DDEQP_GLES2_RUNTIME_LOAD=1)
 107 endif ()
 108
 109 if (NOT DEFINED DEQP_GLES3_LIBRARIES)
 110         add_definitions(-DDEQP_GLES3_RUNTIME_LOAD=1)
 111 endif ()
 112
 113 if (NOT DEFINED DEQP_EGL_LIBRARIES)
 114         add_definitions(-DDEQP_EGL_RUNTIME_LOAD=1)
 115 endif ()
 116
 117 # OpenGL entry points are always loaded on run-time
 118 add_definitions(-DDEQP_OPENGL_RUNTIME_LOAD=1)
 119
 120 # Legacy APIs that don't support run-time loading
 121 if (DEQP_SUPPORT_GLES1 AND NOT DEFINED DEQP_GLES1_LIBRARIES)
 122         message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 123 endif ()
 124
 125 if (DEQP_SUPPORT_VG AND NOT DEFINED DEQP_VG_LIBRARIES)
 126         message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 127 endif ()
 128
 129 if (DE_COMPILER_IS_MSC)
 130         # Don't nag about std::copy for example
 131         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 132 endif ()
 133
 134 # delibs projects
 135 add_subdirectory(framework/delibs/debase)
 136 add_subdirectory(framework/delibs/depool)
 137 add_subdirectory(framework/delibs/dethread)
 138 add_subdirectory(framework/delibs/destream)
 139 add_subdirectory(framework/delibs/deutil)
 140 add_subdirectory(framework/delibs/decpp)
 141
 142 # ExecServer
 143 add_subdirectory(execserver)
 144
 145 # Executor framework and tools
 146 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 147         add_subdirectory(executor)
 148 endif ()
 149
 150 # Test framework include directories
 151 include_directories(
 152         framework/common
 153         framework/qphelper
 154         framework/opengl
 155         framework/opengl/wrapper
 156         framework/referencerenderer
 157         framework/opengl/simplereference
 158         framework/randomshaders
 159         framework/egl
 160         framework/egl/wrapper
 161         external/vulkancts/framework/vulkan
 162         )
 163
 164 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 165         # On Android deqp modules are compiled as libraries and linked into final .so
 166         set(DEQP_MODULE_LIBRARIES )
 167         set(DEQP_MODULE_ENTRY_POINTS )
 168 endif ()
 169
 170 if (DE_OS_IS_WIN32)
 171         include_directories(framework/platform/win32)
 172 endif ()
 173
 174 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 175 macro (target_copy_files target dep_name files)
 176         if (NOT "${files}" STREQUAL "")
 177                 set(COPY_TARGETS )
 178                 foreach (SRCNAME ${files})
 179                         get_filename_component(BASENAME ${SRCNAME} NAME)
 180                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 181                         add_custom_command(OUTPUT ${DSTNAME}
 182                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 183                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 184                 endforeach ()
 185
 186                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 187                 add_dependencies(${target} ${dep_name})
 188         endif ()
 189 endmacro (target_copy_files)
 190
 191 # Macro for adding dEQP module
 192 macro (add_deqp_module MODULE_NAME SRCS LIBS ENTRY)
 193         if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 194                 # Single-binary targets
 195                 add_library(${MODULE_NAME} STATIC ${SRCS})
 196                 target_link_libraries(${MODULE_NAME} ${LIBS})
 197
 198                 set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} ${MODULE_NAME})
 199                 set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 200
 201                 # Forward to parent scope
 202                 set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 203                 set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 204
 205         else ()
 206                 # Separate binary per target
 207                 add_executable(${MODULE_NAME} ${CMAKE_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY} ${SRCS})
 208                 target_link_libraries(${MODULE_NAME} tcutil-platform ${LIBS})
 209                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 210         endif ()
 211
 212         # Data file target
 213         add_custom_target(${MODULE_NAME}-data)
 214         add_dependencies(${MODULE_NAME} ${MODULE_NAME}-data)
 215 endmacro (add_deqp_module)
 216
 217 # Macro for adding data dirs to module
 218 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 219         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX)
 220                 add_custom_command(TARGET ${MODULE_NAME}-data POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 221
 222         elseif (DE_OS_IS_ANDROID)
 223                 add_custom_command(TARGET ${MODULE_NAME}-data POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 224
 225         elseif (DE_OS_IS_IOS)
 226                 add_custom_command(TARGET ${MODULE_NAME}-data POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 227         endif ()
 228 endmacro (add_data_dir)
 229
 230 # Macro for adding individual data files to module
 231 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 232         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX)
 233                 add_custom_command(TARGET ${MODULE_NAME}-data POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 234
 235         elseif (DE_OS_IS_ANDROID)
 236                 add_custom_command(TARGET ${MODULE_NAME}-data POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 237
 238         elseif (DE_OS_IS_IOS)
 239                 add_custom_command(TARGET ${MODULE_NAME}-data POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 240         endif ()
 241 endmacro (add_data_file)
 242
 243 add_subdirectory(framework)
 244 add_subdirectory(external/vulkancts/framework/vulkan)
 245
 246 if (DE_COMPILER_IS_MSC)
 247         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 248 endif ()
 249
 250 add_subdirectory(modules)
 251 add_subdirectory(external/vulkancts/modules/vulkan)
 252
 253 # Single-binary targets
 254 if (DE_OS_IS_ANDROID)
 255         include_directories(executor)
 256
 257         add_library(deqp SHARED framework/platform/android/tcuAndroidMain.cpp framework/platform/android/tcuAndroidJNI.cpp framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp framework/platform/android/tcuTestLogParserJNI.cpp ${DEQP_MODULE_ENTRY_POINTS})
 258         target_link_libraries(deqp tcutil-platform xecore ${DEQP_MODULE_LIBRARIES})
 259
 260 elseif (DE_OS_IS_IOS)
 261         # Code sign identity
 262         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 263
 264         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 265         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 266
 267         include_directories(framework/platform/ios)
 268         set(TESTERCORE_SRC_FILES
 269                 framework/platform/ios/tcuEAGLView.h
 270                 framework/platform/ios/tcuEAGLView.m
 271                 framework/platform/ios/tcuIOSAppDelegate.h
 272                 framework/platform/ios/tcuIOSAppDelegate.m
 273                 framework/platform/ios/tcuIOSViewController.h
 274                 framework/platform/ios/tcuIOSViewController.m
 275                 framework/platform/ios/tcuIOSMain.m
 276                 )
 277         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 278
 279         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 280         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 281         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 282         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 283 endif ()