CMakeLists.txt

   1 # dEQP cmake file
   2
   3 # Module FindGit requires cmake >= 2.8.2
   4 cmake_minimum_required(VERSION 2.8.2)
   5
   6 find_package(Git)
   7
   8 # dEQP Target.
   9 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
  10
  11 if (DEFINED DEQP_TARGET_TOOLCHAIN)
  12         # \note Toolchain must be included before project() command
  13         include(targets/${DEQP_TARGET}/${DEQP_TARGET_TOOLCHAIN}.cmake)
  14 endif ()
  15
  16 project(dEQP-Core-${DEQP_TARGET})
  17
  18 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  19 include(framework/delibs/cmake/CFlags.cmake)
  20
  21 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  22
  23 # dEQP-specific configuration. Target file should override these.
  24 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  25
  26 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  27 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  28 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  29
  30 # Legacy APIs that don't use run-time loading
  31 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  32 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  33 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  34 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  35
  36 set(DEQP_SUPPORT_WGL            OFF)
  37 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  38
  39 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  40
  41 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  42
  43 # Delibs include directories
  44 include_directories(
  45         framework/delibs/debase
  46         framework/delibs/decpp
  47         framework/delibs/depool
  48         framework/delibs/dethread
  49         framework/delibs/deutil
  50         framework/delibs/destream
  51         )
  52
  53 # Include target-specific definitions
  54 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  55
  56 # zlib
  57 find_path(ZLIB_INCLUDE_PATH     zlib.h)
  58 find_library(ZLIB_LIBRARY       z)
  59
  60 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  61         message(STATUS "System version of zlib not found, using external/zlib")
  62         add_subdirectory(external/zlib)
  63         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  64 endif ()
  65
  66 include_directories(${ZLIB_INCLUDE_PATH})
  67
  68 # libpng
  69 #
  70 # The FindPNG module defines PNG_INCLUDE_DIRS and PNG_LIBRARIES. But dEQP's
  71 # CMake files expect the non-standard PNG_INCLUDE_PATH and PNG_LIBRARY. Set the
  72 # non-standard variables here to retain compatibility with dEQP's existing
  73 # CMake files.
  74 include(FindPNG)
  75 set(PNG_INCLUDE_PATH ${PNG_INCLUDE_DIRS})
  76 set(PNG_LIBRARY ${PNG_LIBRARIES})
  77
  78 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  79         message(STATUS "System version of libpng not found, using external/libpng")
  80         add_subdirectory(external/libpng)
  81         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  82 endif ()
  83
  84 # glslang
  85 add_subdirectory(external/glslang)
  86
  87 # spirv-tools
  88 add_subdirectory(external/spirv-tools)
  89
  90 include_directories(${PNG_INCLUDE_PATH})
  91
  92 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
  93 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
  94 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
  95 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
  96 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
  97 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
  98 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
  99 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
 100 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
 101 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
 102 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
 103
 104 # Defines
 105 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
 106
 107 # Entry points loaded directly by linking to libGL*?
 108 if (DEFINED DEQP_GLES2_LIBRARIES)
 109         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
 110 endif ()
 111
 112 if (DEFINED DEQP_GLES3_LIBRARIES)
 113         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 114 endif ()
 115
 116 if (DEFINED DEQP_GLES31_LIBRARIES)
 117         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 118 endif ()
 119
 120 if (DEFINED DEQP_GLES32_LIBRARIES)
 121         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 122 endif ()
 123
 124 if (DEFINED DEQP_EGL_LIBRARIES)
 125         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 126 endif ()
 127
 128 # Legacy APIs that don't support run-time loading
 129 if (DEQP_SUPPORT_GLES1)
 130         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 131
 132         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 133                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 134         endif ()
 135 endif ()
 136
 137 if (DEQP_SUPPORT_VG)
 138         add_definitions(-DDEQP_SUPPORT_VG=1)
 139
 140         if (NOT DEFINED DEQP_VG_LIBRARIES)
 141                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 142         endif ()
 143 endif ()
 144
 145 if (DE_COMPILER_IS_MSC)
 146         # Don't nag about std::copy for example
 147         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 148 endif ()
 149
 150 # delibs projects
 151 add_subdirectory(framework/delibs/debase)
 152 add_subdirectory(framework/delibs/depool)
 153 add_subdirectory(framework/delibs/dethread)
 154 add_subdirectory(framework/delibs/destream)
 155 add_subdirectory(framework/delibs/deutil)
 156 add_subdirectory(framework/delibs/decpp)
 157
 158 # ExecServer
 159 add_subdirectory(execserver)
 160
 161 # Executor framework and tools
 162 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 163         add_subdirectory(executor)
 164 endif ()
 165
 166 # Test framework include directories
 167 include_directories(
 168         framework/common
 169         framework/qphelper
 170         framework/opengl
 171         framework/opengl/wrapper
 172         framework/referencerenderer
 173         framework/opengl/simplereference
 174         framework/randomshaders
 175         framework/egl
 176         framework/egl/wrapper
 177         external/vulkancts/framework/vulkan
 178         )
 179
 180 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 181         # On Android deqp modules are compiled as libraries and linked into final .so
 182         set(DEQP_MODULE_LIBRARIES )
 183         set(DEQP_MODULE_ENTRY_POINTS )
 184 endif ()
 185
 186 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 187 macro (target_copy_files target dep_name files)
 188         if (NOT "${files}" STREQUAL "")
 189                 set(COPY_TARGETS )
 190                 foreach (SRCNAME ${files})
 191                         get_filename_component(BASENAME ${SRCNAME} NAME)
 192                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 193                         add_custom_command(OUTPUT ${DSTNAME}
 194                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 195                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 196                 endforeach ()
 197
 198                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 199                 add_dependencies(${target} ${dep_name})
 200         endif ()
 201 endmacro (target_copy_files)
 202
 203 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 204 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 205
 206 # Macro for adding dEQP module
 207 # This adds 3 targets:
 208 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 209 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 210 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 211 macro (add_deqp_module MODULE_NAME SRCS LIBS ENTRY)
 212
 213         # Library target
 214         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 215         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 216
 217         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 218         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 219
 220         # Forward to parent scope
 221         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 222         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 223
 224         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 225                 # Executable target
 226                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 227                 target_link_libraries(${MODULE_NAME} tcutil-platform "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 228                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 229         endif ()
 230
 231         # Data file target
 232         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 233         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 234 endmacro (add_deqp_module)
 235
 236 # Macro for adding data dirs to module
 237 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 238         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 239                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 240
 241         elseif (DE_OS_IS_ANDROID)
 242                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 243
 244         elseif (DE_OS_IS_IOS)
 245                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 246         endif ()
 247 endmacro (add_data_dir)
 248
 249 # Macro for adding individual data files to module
 250 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 251         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 252                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 253
 254         elseif (DE_OS_IS_ANDROID)
 255                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 256
 257         elseif (DE_OS_IS_IOS)
 258                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 259         endif ()
 260 endmacro (add_data_file)
 261
 262 add_subdirectory(framework)
 263 add_subdirectory(external/vulkancts/framework/vulkan)
 264
 265 if (DE_COMPILER_IS_MSC)
 266         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 267 endif ()
 268
 269 add_subdirectory(modules)
 270 add_subdirectory(external/vulkancts/modules/vulkan)
 271 add_subdirectory(external/openglcts)
 272
 273 # Single-binary targets
 274 if (DE_OS_IS_ANDROID)
 275         include_directories(executor)
 276
 277         set(DEQP_SRCS
 278                 framework/platform/android/tcuAndroidMain.cpp
 279                 framework/platform/android/tcuAndroidJNI.cpp
 280                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 281                 framework/platform/android/tcuTestLogParserJNI.cpp
 282                 ${DEQP_MODULE_ENTRY_POINTS}
 283                 )
 284
 285         set(DEQP_LIBS
 286                 tcutil-platform
 287                 xecore
 288                 ${DEQP_MODULE_LIBRARIES}
 289                 )
 290
 291         add_library(deqp SHARED ${DEQP_SRCS})
 292         target_link_libraries(deqp ${DEQP_LIBS})
 293
 294         # Needed by OpenGL CTS that defines its own activity but depends on
 295         # common Android support code.
 296         target_include_directories(deqp PRIVATE framework/platform/android)
 297
 298 elseif (DE_OS_IS_IOS)
 299         # Code sign identity
 300         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 301
 302         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 303         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 304
 305         include_directories(framework/platform/ios)
 306         set(TESTERCORE_SRC_FILES
 307                 framework/platform/ios/tcuEAGLView.h
 308                 framework/platform/ios/tcuEAGLView.m
 309                 framework/platform/ios/tcuIOSAppDelegate.h
 310                 framework/platform/ios/tcuIOSAppDelegate.m
 311                 framework/platform/ios/tcuIOSViewController.h
 312                 framework/platform/ios/tcuIOSViewController.m
 313                 framework/platform/ios/tcuIOSMain.m
 314                 )
 315         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 316
 317         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 318         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 319         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 320         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 321 endif ()