arch/m68k/cpu/mcf52x2/start.S

   1 /*
   2  * Copyright (C) 2003   Josef Baumgartner <josef.baumgartner@telex.de>
   3  * Based on code from Bernhard Kuhn <bkuhn@metrowerks.com>
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 #include <asm-offsets.h>
   9 #include <config.h>
  10 #include "version.h"
  11 #include <asm/cache.h>
  12
  13 #ifndef  CONFIG_IDENT_STRING
  14 #define  CONFIG_IDENT_STRING ""
  15 #endif
  16
  17 #define _START  _start
  18 #define _FAULT  _fault
  19
  20
  21 #define SAVE_ALL                                                \
  22         move.w  #0x2700,%sr;            /* disable intrs */     \
  23         subl    #60,%sp;                /* space for 15 regs */ \
  24         moveml  %d0-%d7/%a0-%a6,%sp@;                           \
  25
  26 #define RESTORE_ALL                                             \
  27         moveml  %sp@,%d0-%d7/%a0-%a6;                           \
  28         addl    #60,%sp;                /* space for 15 regs */ \
  29         rte
  30
  31 /* If we come from a pre-loader we don't need an initial exception
  32  * table.
  33  */
  34 #if !defined(CONFIG_MONITOR_IS_IN_RAM)
  35
  36 .text
  37
  38 /*
  39  * Vector table. This is used for initial platform startup.
  40  * These vectors are to catch any un-intended traps.
  41  */
  42 _vectors:
  43 .long   0x00000000              /* Flash offset is 0 until we setup CS0 */
  44 #if defined(CONFIG_M5282) && (CONFIG_SYS_TEXT_BASE == CONFIG_SYS_INT_FLASH_BASE)
  45 .long   _start - CONFIG_SYS_TEXT_BASE
  46 #else
  47 .long   _START
  48 #endif
  49
  50 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  51 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  52 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  53 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  54 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  55 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  56 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  57 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  58
  59 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  60 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  61 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  62 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  63 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  64 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  65 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  66 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  67
  68 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  69 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  70 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  71 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  72 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  73 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  74 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  75 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  76
  77 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  78 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  79 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  80 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  81 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  82 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  83 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  84 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  85
  86 #endif
  87
  88 .text
  89
  90 #if defined(CONFIG_SYS_INT_FLASH_BASE) && \
  91     (defined(CONFIG_M5282) || defined(CONFIG_M5281))
  92 #if (CONFIG_SYS_TEXT_BASE == CONFIG_SYS_INT_FLASH_BASE)
  93 .long   0x55AA55AA,0xAA55AA55           /* CFM Backdoorkey */
  94 .long   0xFFFFFFFF                      /* all sectors protected */
  95 .long   0x00000000                      /* supervisor/User restriction */
  96 .long   0x00000000                      /* programm/data space restriction */
  97 .long   0x00000000                      /* Flash security */
  98 #endif
  99 #endif
 100
 101 .globl _start
 102 _start:
 103         nop
 104         nop
 105         move.w  #0x2700,%sr
 106
 107 #if defined(CONFIG_M5208)
 108         /* Initialize RAMBAR: locate SRAM and validate it */
 109         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_RAM_CTRL), %d0
 110         movec   %d0, %RAMBAR1
 111 #endif
 112
 113 #if defined(CONFIG_M5272) || defined(CONFIG_M5249) || defined(CONFIG_M5253)
 114         /* set MBAR address + valid flag */
 115         move.l  #(CONFIG_SYS_MBAR + 1), %d0
 116         move.c  %d0, %MBAR
 117
 118         /*** The 5249 has MBAR2 as well ***/
 119 #ifdef CONFIG_SYS_MBAR2
 120         /* Get MBAR2 address */
 121         move.l  #(CONFIG_SYS_MBAR2 + 1), %d0
 122          /* Set MBAR2 */
 123         movec   %d0, #0xc0e
 124 #endif
 125         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + 1), %d0
 126         movec   %d0, %RAMBAR0
 127 #endif /* CONFIG_M5272 || CONFIG_M5249 || CONFIG_M5253 */
 128
 129 #if defined(CONFIG_M5282) || defined(CONFIG_M5271)
 130         /* set MBAR address + valid flag */
 131         move.l  #(CONFIG_SYS_MBAR + 1), %d0
 132         move.l  %d0, 0x40000000
 133
 134         /* Initialize RAMBAR1: locate SRAM and validate it */
 135         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + 0x21), %d0
 136         movec   %d0, %RAMBAR1
 137
 138 #if defined(CONFIG_M5282)
 139 #if (CONFIG_SYS_TEXT_BASE == CONFIG_SYS_INT_FLASH_BASE)
 140         /*
 141          * Setup code in SRAM to initialize FLASHBAR,
 142          * if start from internal Flash
 143          */
 144         move.l  #(_flashbar_setup-CONFIG_SYS_INT_FLASH_BASE), %a0
 145         move.l  #(_flashbar_setup_end-CONFIG_SYS_INT_FLASH_BASE), %a1
 146         move.l  #(CONFIG_SYS_INIT_RAM_ADDR), %a2
 147 _copy_flash:
 148         move.l  (%a0)+, (%a2)+
 149         cmp.l   %a0, %a1
 150         bgt.s   _copy_flash
 151         jmp     CONFIG_SYS_INIT_RAM_ADDR
 152
 153 _flashbar_setup:
 154         /* Initialize FLASHBAR: locate internal Flash and validate it */
 155         move.l  #(CONFIG_SYS_INT_FLASH_BASE + CONFIG_SYS_INT_FLASH_ENABLE), %d0
 156         movec   %d0, %FLASHBAR
 157         jmp     _after_flashbar_copy.L  /* Force jump to absolute address */
 158 _flashbar_setup_end:
 159         nop
 160 _after_flashbar_copy:
 161 #else
 162         /* Setup code to initialize FLASHBAR, if start from external Memory */
 163         move.l  #(CONFIG_SYS_INT_FLASH_BASE + CONFIG_SYS_INT_FLASH_ENABLE), %d0
 164         movec   %d0, %FLASHBAR
 165 #endif /* (CONFIG_SYS_TEXT_BASE == CONFIG_SYS_INT_FLASH_BASE) */
 166
 167 #endif
 168 #endif
 169         /*
 170          * if we come from a pre-loader we have no exception table and
 171          * therefore no VBR to set
 172          */
 173 #if !defined(CONFIG_MONITOR_IS_IN_RAM)
 174 #if defined(CONFIG_M5282) && (CONFIG_SYS_TEXT_BASE == CONFIG_SYS_INT_FLASH_BASE)
 175         move.l  #CONFIG_SYS_INT_FLASH_BASE, %d0
 176 #else
 177         move.l  #CONFIG_SYS_FLASH_BASE, %d0
 178 #endif
 179         movec   %d0, %VBR
 180 #endif
 181
 182 #ifdef CONFIG_M5275
 183         /* set MBAR address + valid flag */
 184         move.l  #(CONFIG_SYS_MBAR + 1), %d0
 185         move.l  %d0, 0x40000000
 186 /*      movec   %d0, %MBAR */
 187
 188         /* Initialize RAMBAR: locate SRAM and validate it */
 189         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + 0x21), %d0
 190         movec   %d0, %RAMBAR1
 191 #endif
 192
 193         /* initialize general use internal ram */
 194         move.l  #0, %d0
 195         move.l  #(ICACHE_STATUS), %a1   /* icache */
 196         move.l  #(DCACHE_STATUS), %a2   /* icache */
 197         move.l  %d0, (%a1)
 198         move.l  %d0, (%a2)
 199
 200         /* put relocation table address to a5 */
 201         move.l  #__got_start, %a5
 202
 203         /* setup stack initially on top of internal static ram  */
 204         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_RAM_SIZE), %sp
 205
 206         /*
 207          * if configured, malloc_f arena will be reserved first,
 208          * then (and always) gd struct space will be reserved
 209          */
 210         move.l  %sp, -(%sp)
 211         move.l  #board_init_f_alloc_reserve, %a1
 212         jsr     (%a1)
 213
 214         /* update stack and frame-pointers */
 215         move.l  %d0, %sp
 216         move.l  %sp, %fp
 217
 218         /* initialize reserved area */
 219         move.l  %d0, -(%sp)
 220         move.l  #board_init_f_init_reserve, %a1
 221         jsr     (%a1)
 222
 223         /* run low-level CPU init code (from flash) */
 224         move.l  #cpu_init_f, %a1
 225         jsr     (%a1)
 226
 227         /* run low-level board init code (from flash) */
 228         clr.l   %sp@-
 229         move.l  #board_init_f, %a1
 230         jsr     (%a1)
 231
 232         /* board_init_f() does not return */
 233
 234 /******************************************************************************/
 235
 236 /*
 237  * void relocate_code (addr_sp, gd, addr_moni)
 238  *
 239  * This "function" does not return, instead it continues in RAM
 240  * after relocating the monitor code.
 241  *
 242  * r3 = dest
 243  * r4 = src
 244  * r5 = length in bytes
 245  * r6 = cachelinesize
 246  */
 247 .globl relocate_code
 248 relocate_code:
 249         link.w  %a6,#0
 250         move.l  8(%a6), %sp             /* set new stack pointer */
 251
 252         move.l  12(%a6), %d0            /* Save copy of Global Data pointer */
 253         move.l  16(%a6), %a0            /* Save copy of Destination Address */
 254
 255         move.l  #CONFIG_SYS_MONITOR_BASE, %a1
 256         move.l  #__init_end, %a2
 257         move.l  %a0, %a3
 258         /* copy the code to RAM */
 259 1:
 260         move.l  (%a1)+, (%a3)+
 261         cmp.l   %a1,%a2
 262         bgt.s   1b
 263
 264 /*
 265  * We are done. Do not return, instead branch to second part of board
 266  * initialization, now running from RAM.
 267  */
 268         move.l  %a0, %a1
 269         add.l   #(in_ram - CONFIG_SYS_MONITOR_BASE), %a1
 270         jmp     (%a1)
 271
 272 in_ram:
 273
 274 clear_bss:
 275         /*
 276          * Now clear BSS segment
 277          */
 278         move.l  %a0, %a1
 279         add.l   #(_sbss - CONFIG_SYS_MONITOR_BASE),%a1
 280         move.l  %a0, %d1
 281         add.l   #(_ebss - CONFIG_SYS_MONITOR_BASE),%d1
 282 6:
 283         clr.l   (%a1)+
 284         cmp.l   %a1,%d1
 285         bgt.s   6b
 286
 287         /*
 288          * fix got table in RAM
 289          */
 290         move.l  %a0, %a1
 291         add.l   #(__got_start - CONFIG_SYS_MONITOR_BASE),%a1
 292         move.l  %a1,%a5                 /* fix got pointer register a5 */
 293
 294         move.l  %a0, %a2
 295         add.l   #(__got_end - CONFIG_SYS_MONITOR_BASE),%a2
 296
 297 7:
 298         move.l  (%a1),%d1
 299         sub.l   #_start,%d1
 300         add.l   %a0,%d1
 301         move.l  %d1,(%a1)+
 302         cmp.l   %a2, %a1
 303         bne     7b
 304
 305         /* calculate relative jump to board_init_r in ram */
 306         move.l  %a0, %a1
 307         add.l   #(board_init_r - CONFIG_SYS_MONITOR_BASE), %a1
 308
 309         /* set parameters for board_init_r */
 310         move.l  %a0,-(%sp)              /* dest_addr */
 311         move.l  %d0,-(%sp)              /* gd */
 312 #if defined(DEBUG) && (CONFIG_SYS_TEXT_BASE != CONFIG_SYS_INT_FLASH_BASE) && \
 313     defined(CONFIG_SYS_HALT_BEFOR_RAM_JUMP)
 314         halt
 315 #endif
 316         jsr     (%a1)
 317
 318 /******************************************************************************/
 319
 320 /* exception code */
 321 .globl _fault
 322 _fault:
 323         bra     _fault
 324
 325 .globl _exc_handler
 326 _exc_handler:
 327         SAVE_ALL
 328         movel   %sp,%sp@-
 329         bsr     exc_handler
 330         addql   #4,%sp
 331         RESTORE_ALL
 332
 333 .globl _int_handler
 334 _int_handler:
 335         SAVE_ALL
 336         movel   %sp,%sp@-
 337         bsr     int_handler
 338         addql   #4,%sp
 339         RESTORE_ALL
 340
 341 /******************************************************************************/
 342
 343 .globl version_string
 344 version_string:
 345 .ascii U_BOOT_VERSION_STRING, "\0"
 346 .align 4